         TITLE 'IEAAAD0D / ABDUMP LOAD 2 / IGC0D05A'                    00200019
IGC0D05A CSECT                                                          00400019
         SPACE 2                                                        00600019
*THIS MODULE WAS ENTERED NEW IN RELEASE 19. IT HAD FORMERLY BEEN A PART 00800019
*OF MODULES IEAAAD00 AND IEAAAD0A.                                      01000019
         SPACE 2                                                        01200019
*STATUS-                                                                01400019
*        CHANGE LEVEL 001                                               01600019
         SPACE 2                                                        01800019
*MODULE NAME-                                                           02000019
*        IEAAAD0D (ALSO CALLED ABDUMP2)                                 02200019
         SPACE 2                                                        02400019
*FUNCTION-                                                              02600019
*        1) TO OUTPUT THE HEADING LINE OF THE DUMP                      02800019
*        2) TO OUTPUT THE COMPLETION CODE                               03000019
*        3) TO OUTPUT AN INFORMATIVE MESSAGE ACCOMPANYING AN ABEND CODE 03200019
*             IF SUCH MESSAGE EXISTS                                    03400019
*        4) TO OUTPUT A MESSAGE INDICATING THE TYPE OF INTERRUPTION ON  03600019
*             0C1, 0C2, 0C3, 0C4, 0C5, 0C6, AND 0C7 INTERRUPTS          03800019
*        5) TO OUTPUT THE TRUE ADDRESS OF THE PROGRAM INTERRUPT IF THE  04000019
*             INTERRUPT IS OF A TYPE SPECIFIED IN (4)                   04200019
*        6) TO OUTPUT THE RESUME ADDRESS AT THE TIME OF THE INTERRUPT   04400019
*        7) TO OUTPUT THE PSW AT ENTRY TO ABEND/SNAP                    04600019
         SPACE 2                                                        04800019
*ENTRY-                                                                 05000019
*        ABDUMP2 IS ENTERED AT ENTRY POINT IGC0D05A WHEN XCTL'D TO FROM 05200019
*        ABDUMP1 (IEAAAD00). IT IS ENTERED IN SUPERVISOR STATE WITH     05400019
*        SUPERVISOR PROTECTION KEY, AND WITH I/O AND EXTERNAL           05600019
*        INTERRUPTS ENABLED.                                            05800019
         SPACE 2                                                        06000019
*INPUT-                                                                 06200019
*        1) A POINTER IN REG 2 TO THE TCB OF THE TASK BEING DUMPED      06400019
*        2) A POINTER IN REG 5 TO ABDUMP'S SVRB                         06600019
*        3) A POINTER IN REG 13 TO ABDUMP'S WORK AREA                   06800019
         SPACE 2                                                        07000019
*OUTPUT-                                                                07200019
*        ABDUMP2 PROVIDES THE INDICATIVE INFORMATION MENTIONED ABOVE IN 07400019
*        'FUNCTION'. ALL INFORMATION IS IN PRINTABLE FORMAT.            07600019
         SPACE 2                                                        07800019
*EXTERNAL REFERENCES-                                                   08000019
*        ABDUMP2 REFERENCES THE FOLLOWING CONTROL BLOCKS-               08200019
*          1) TCB                                                       08400019
*                   TCBCMP - TASK COMPLETION CODE                       08600019
*                   TCBTIOT - ADDRESS OF TIOT                           08800019
*          2) RB                                                        09000019
*                   RBSTAB - STATUS AND ATTRIBUTE BITS                  09200019
*                   RBOPSW - PSW SAVE AREA                              09400019
*                   RBLINK - ADDRESS OF PREVIOUS RB ON CHAIN            09600019
*                   RBREGS - REGISTER SAVE AREA                         09800019
*          3) TIOT                                                      10000019
*                   TIOTJOB - JOB NAME                                  10200019
*                   TIOTSTEP - STEP NAME                                10400019
         SPACE 2                                                        10600019
*EXIT-                                                                  10800019
*        ABDUMP2 XCTL'S TO ABDUMP3 AT ENTRY POINT IGC0A05A IF           11000019
*        SUPERVISOR DATA IS REQUESTED. IF SUPERVISOR DATA IS NOT        11200019
*        REQUESTED BUT THE SAVE AREA TRACE IS, ABDUMP2 XCTL'S TO        11400019
*        ABDUMP5 AT ENTRY POINT IGC0205A. IF NEITHER SUPERVISOR DATA    11600019
*        NOR THE SAVE AREA TRACE IS REQUESTED, ABDUMP2 XCTL'S TO        11800019
*        ABDUMP6 AT ENTRY POINT IGC0305A.                               12000019
         SPACE 2                                                        12200019
*TABLES/WORK AREAS-                                                     12400019
*        ABDUMP2 USES THE CONTROL BLOCKS MENTIONED ABOVE IN 'EXTERNAL   12600019
*        REFERENCES' AND USES THE WORK AREA OBTAINED BY ABDUMP 1. IN    12800019
*        ADDITION, IT USES AN INTERNAL TABLE WHICH ALLOWS IT TO         13000019
*        DETERMINE WHICH MESSAGE TO OUTPUT IN CASE OF A 0CX TYPE        13200019
*        COMPLETION CODE.                                               13400019
         SPACE 2                                                        13600019
*OPERATION-                                                             13800019
*        ABDUMP2 FIRST FORMATS AND OUTPUTS THE HEADING LINE OF THE      14000019
*        DUMP. IT THEN OUTPUTS THE COMPLETION CODE IF ABEND IS THE      14200019
*        CALLER. NEXT, IT OUTPUTS AN INFORMATIVE MESSAGE IF ONE WAS SET 14400019
*        UP BY ABEND. IT THEN OUTPUTS A MESSAGE INDICATING THE TYPE OF  14600019
*        INTERRUPT FOR 0C1-0C7 INTERRUPTS. NEXT, IT OUTPUTS THE TRUE    14800019
*        ADDRESS OF THE INTERRUPT FOR 0C1-0C7 TYPE INTERRUPTS. THEN IT  15000019
*        OUTPUTS THE RESUME ADDRESS AT THE TIME OF THE INTERRUPT. NEXT, 15200019
*        IT FORMATS AND OUTPUTS THE PSW AT ENTRY TO ABEND/SNAP.         15400019
*        FINALLY IT XCTL'S TO THE NEXT ABDUMP LOAD (SEE 'EXIT' ABOVE).  15600019
         EJECT                                                          15800019
*        REGISTERS                                                      16000019
R0       EQU   0                                                        16200019
R1       EQU   1                                                        16400019
R2       EQU   2                                                        16600019
R3       EQU   3                                                        16800019
R4       EQU   4                                                        17000019
R5       EQU   5                                                        17200019
R6       EQU   6                                                        17400019
R7       EQU   7                                                        17600019
PARREG   EQU   7                                                        17800019
R8       EQU   8                                                        18000019
R9       EQU   9                                                        18200019
RA       EQU   10                                                       18400019
RB       EQU   11                                                       18600019
RC       EQU   12                                                       18800019
RD       EQU   13                                                       19000019
RE       EQU   14                                                       19200019
RF       EQU   15                                                       19400019
* DISPLACEMENTS FROM BEGINNING OF TIOT TO                               19600019
TIOTJOB  EQU   0         JOB NAME                                       19800019
TIOTSTEP EQU   8         STEP NAME                                      20000019
* DISPLACEMENTS FROM BEGINNING OF TCB TO                                20200019
TCBTIOT  EQU   12        PTR TO TIOT                                    20400019
TCBCMP   EQU   16        TASK COMPLETION CODE                           20600019
TCBFLGS2 EQU   174       TCB FLAGS                                 I250 20800019
* DISPLACEMENTS FROM BEGINNING OF RB TO                                 21000019
RBSTAB   EQU   10        RB STATUS AND ATTRIBUTE BITS                   21200019
RBOPSW   EQU   16        PSW SAVE AREA                                  21400019
RBLINK   EQU   28        RB CHAIN ADDR                                  21600019
RBREGS   EQU   32                                                       21800019
XRBLNK   EQU   28                                                       22000019
XRBPSW   EQU   20                                                       22200019
REGFAREA EQU   92                                                       22400019
ISMESG   EQU   1                                                        22600019
ONE      EQU   1                                                        22800019
TESTTASK EQU   X'80'                                               I250 23000019
HDCC     EQU   C'0'           FOR CAR CONTROL CHARACTER                 23200019
PFABEND  EQU   X'80'                   OFF-ABEND,ON-SNAP IS THE CALLER  23400019
PFSUPDAT EQU   X'20'                   ON-ALL SUPERVISOR DATA           23600019
PFPSW    EQU   X'04'                   ON-PSW IS WANTED                 23800019
PFID     EQU   X'02'                   ON-AN ID GIVEN                   24000019
PFSAVE   EQU   X'80'                   ON-SAVE AREA WANTED              24200019
         EJECT                                                          24400019
         BALR  RC,0          ESTABLISH ADDRESSABILITY                   24600019
         USING *,RC                                                     24800019
         USING ABDAREA,RD                                               25000019
         USING PARDSECT,PARREG                                          25200019
*                                                                       25400019
* HEADING LINE TO OUTPUT LINE                                           25600019
*       JOB NAME,STEP NAME,DATE IN HEADING LINE.                        25800019
*       FORMAT ROUTINE USED TO INSERT LABELS, THEN IT RETURNS VIA       26000019
*       LINKAGE REGISTER, R5.                                           26200019
*                                                                       26400019
         MVC   ABDCC(L'MESS1),MESS1                                     26600019
         LR    R9,R5          SAVE PTR TO CURRENT RB FOR 'INTMSG'       26800019
         L     R3,TCBTIOT(R2)          GET TIOT ADDRESS                 27000019
         MVC   ABDLINE+4(8),TIOTJOB(R3)  GET JOB NAME FROM THE TIOT     27200019
         MVC   ABDLINE+21(L'MESS2),MESS2                                27400019
         MVC   ABDLINE+26(8),TIOTSTEP(R3)  GET STEP NAME FROM THE TIOT  27600019
         TIME  DEC                                                      27800019
         STM   R0,R1,ABDWORK1          GET TIME/DATE                    28000019
         LA    R3,LINE1                GET ADDR OF THE LAYOUT LINE      28200019
         LA    R4,ABDWORK1             GET FIELD ADDRESS                28400019
         BAL   R5,FORMAT               LINK TO FORMAT ROUTINE           28600019
         MVI   ABDLINE+66,C' '                                          28800019
         MVC   ABDLINE+108(L'MESS3),MESS3                               29000019
         L     PARREG,ABDPARA          GET PTR TO PARAM LIST            29200019
         TM    PFLAGS,PFID             IS ID SPECIFIED                  29400019
         BC    8,NOID                  NO,BRANCH                        29600019
         MVC   ABDLINE+70(L'IDMESS),IDMESS                              29800019
         SR    R3,R3                                                    30000019
         IC    R3,PID                  GET ID NUMBER                    30200019
         CVD   R3,ABDWORK1             CONVERT ID TO DECIMAL            30400019
         UNPK  ABDLINE+75(3),ABDWORK1+6(2)   UNPACK ID                  30600019
         OI    ABDLINE+77,X'F0'              CHANGE SIGN TO 'F'         30800019
NOID     EQU   *                                                        31000019
         TM    PFLAGS,PFABEND          IS ABEND THE CALLER OF ABDUMP    31200019
         BO    ABD012                  NO,BRANCH                        31400019
         TM    ABDFLAG,TESTTASK        IS DUMP FOR CURRENT TASK    I250 31600019
         BO    PRINTLN                 NO,BRANCH                   I250 31800019
         MVI   ABDCC,C'0'          DBL SPACE- AVOID OVERLAYING ABENDS   32000019
         BAL   R5,ABDOUT           OUTPUT THE HEADING                   32200019
*                                                                       32400019
* FORMAT TASK COMPLETION CODE                                           32600019
*       1)  IF SYSTEM ROUTINE ASSIGNED CODE, CODE FORMATTED IN HEX.     32800019
*       2)  IF USER ROUTINE ASSIGNED CODE, CODE IN DECIMAL.             33000019
*               *******************************************             33200019
*       TCBCMP  *  BITS 0-7  *  BITS 8-19   *  BITS 20-31 *             33400019
*               *  ABEND BYTE*  SYSTEM CODE *  USER CODE  *             33600019
*               *******************************************             33800019
* NOTE - ONE OF THE CODE FIELDS MUST BE ZERO.                           34000019
*                                                                       34200019
*       PTR TO TCB IN R2                                                34400019
*                                                                       34600019
         MVC   ABDCC(L'MESS4),MESS4                                     34800019
         SR    RA,RA                                               4029 35000019
         L     RB,TCBCMP(R2)       LOAD TASK COMPLETION CODE       4029 35200019
         SLL   RB,8                GET RID OF ABEND BYTE           4029 35400019
         SLDL  RA,12               SHIFT SYSTEM CODE INTO RA       4029 35600019
         LTR   RA,RA               TEST SYSTEM CODE IN RA          4029 35800019
         BZ    ABD011              BRANCH IF NO SYSTEM CODE        4029 36000019
         SLL   RA,12                                                    36200019
         ST    RA,ABDWORK1              SET UP CODE IN WORK AREA SO     36400019
         LA    R3,LINE2A               GET ADDRESS OF THE LAYOUT LINE   36600019
         LA    R4,ABDWORK1+1           GET ADDR OF THE FIELD            36800019
         BAL   R5,FORMAT               LINK TO FORMAT ROUTINE           37000019
         MVI   ABDLINE+33,C' '                                          37200019
         B     ABD012                   LINE READY TO BE WRITTEN        37400019
*                                                                       37600019
*                                                                       37800019
ABD011   SRL   RB,20                    USER TERMINATION CODE IN RB     38000019
         CVD   RB,ABDWORK1             CONVERT USER CODE TO DEC.        38200019
         LA    R3,LINE2B               GET LAYOUT LINE ADDRESS          38400019
         LA    R4,ABDWORK1+5       GET ADDR OF CONVERTED CODE           38600019
         BAL   R5,FORMAT               LINK TO FORMAT ROUTINE           38800019
         MVI   ABDLINE+27,C' '     BLANK OUT 5TH DIDIT                  39000019
         MVI   ABDLINE+32,C' '     BLANK OUT SIGN                       39200019
ABD012   BAL   R5,ABDOUT                LINK TO WRITE COMP CODE LINE    39400019
         SR    RB,RB                                                    39600019
         L     RA,XRBLNK(R9)           GET SVRB FOR ABEND               39800019
NOMESS   CLI   TCBCMP+1(R2),X'0C'      WAS IT A PROGRAM INTERRUPT  1804 41600019
         BC    7,PRTINT                  NO BRANCH                      41800019
         TM    TCBCMP+2(R2),X'80'      IS CODE DIGIT 8 OR GREATER       42000019
         BC    1,PRTINT                 YES BRANCH                      42200019
         SR    RF,RF                                                    42400019
         IC    RF,TCBCMP+2(R2)         GET NUMERIC DIGET OF COMP CODE   42600019
         SRL   RF,3                    SET UP INDEX FACTOR              42800019
         LA    R5,TABLE-2              GET INDEX FACTOR TO TABLE        43000019
         IC    RB,0(R5,RF)             GET INDEX FACTOR TO MESSAGE      43200019
         IC    RF,1(R5,RF)             GET LENGTH OF MESSAGE            43400019
         LA    R1,INTMESS              GET ADDRESS OF TABLE OF MESSAGES 43600019
         AR    R1,RB                   GET ADDRESS OF MESSAGE WANTED    43800019
         MVC   ABDLINE-1(23),MESS-1    MOVE MSG TO PRINT AREA           44000019
         EX    RF,MOVECODE             MOVE TYPE INTERRUPTION           44200019
         LA    RF,ABDLINE+23(RF)       UP POINTER IN OUTPUT BUFFER      44400019
         MVC   0(13,RF),LOCA           MOVE NEXT PART OF MESSAGE        44600019
         LA    R8,13(RF)               UP POINTER IN BUFFER             44800019
         L     RA,XRBLNK(RA)           GET LOWEST PRB ON CHAIN     1804 45000019
         L     RF,XRBPSW(RA)           PICK UP RIGHT HALF PSW FROM RB   45200019
         SR    RE,RE                                                    45400019
         SLDL  RE,2                    GET INST LENGTH IN RE            45600019
         SRL   RF,2                    REPOSITION PSW MINUS IL          45800019
         SLL   RE,1                    GET INST LENGTH IN RE            46000019
         SR    RF,RE                   ADDR OF INTERRUPT IN RF          46200019
         ST    RF,REGFAREA(R9)         STORE ADDRESS                    46400019
         LA    R4,REGFAREA+1(R9)                                        46600019
         LA    R3,INTADDR              SET UP PARAMETER LIST REG        46800019
         BAL   R5,FORMAT01             GO UNPACK ADDR INTO BUFFER       47000019
         BAL   R5,ABDOUT               PRINT A LINE                     47200019
*********************************************************************** 47400019
*                        INTERRUPT CODE                               * 47600019
*********************************************************************** 47800019
PRTINT   TM    PFLAGS,PFABEND          IS ABEND REQUESTER               48000019
         BO    NOINT                   NO, SKIP INT CODE                48200019
RBCHK    CR    R2,R9                   HAVE ALL RB'S BEEN INTERROGATED  48400019
         BE    NOINT                   YES, NO INT MSG TO BE PUT OUT    48600019
         TM    RBSTAB(R9),X'C0'        IS THIS PRB OR LPRB              48800019
         BZ    GETPSW                  YES, GET ADDR FROM PSW           49000019
         TM    RBSTAB(R9),X'E0'        IS THIS LPRB MINOR ENTRY         49200019
         BO    GETPSW                  YES, GET ADDR FROM PSW           49400019
         L     R9,RBLINK(R9)           GET ADDR OF NEXT RB              49600019
         B     RBCHK                   LOOP                             49800019
GETPSW   LA    R4,RBOPSW+5(R9)         GET ADDR FROM PSW                50000019
         LA    R3,INTMSG               GET ADDR OF LAYOUT LINE          50200019
         BAL   R5,FORMAT               FORMAT MSG&ADDR                  50400019
         MVI   ABDCC,C'0'                        DOUBLE SPACE           50600019
         BAL   R5,ABDOUT               PRINT A LINE                     50800019
NOINT    EQU   *                                                        51000019
         L     PARREG,ABDPARA          GET PTR TO PARAM LIST            51200019
         TM    PFLAGS+1,PFPSW          IS PSW WANTED                    51400019
         BZ    NOPSW                   NO,BRANCH                        51600019
*                                                                       51800019
* FORMAT AND OUTPUT PSW AT ENTRY TO ABEND/SNAP                          52000019
*                                                                       52200019
         MVC   ABDCC(L'MESS5),MESS5                                     52400019
         TM    PFLAGS,PFABEND          IS DUMP CALLED BY ABEND          52600019
         BO    PSW1                    NO,BRANCH                        52800019
         MVC   ABDLINE+16(L'MESS6),MESS6  CHANGE 'SNAP' TO 'ABEND'      53000019
         CLI   TCBCMP+1(R2),X'0C'      WAS THERE A PROG INTERRUPT  6859 53200019
         BNE   GETRB                   NO,BRANCH                   6859 53400019
         TM    TCBCMP+2(R2),X'80'      IS CODE DIGIT 8 OR MORE     6859 53600019
         BZ    PSW1                    NO,BRANCH                   6859 53800019
GETRB    EQU   *                                                        54000019
         L     RA,XRBLNK(RA)           GET LOWEST PRB ON CHAIN     1804 54200019
PSW1     LA    R4,RBOPSW(RA)           GET ADDR OF PSW IN RB            54400019
         LA    R3,PSWLINE              GET ADDR OF LAYOUT LINE          54600019
         BAL   R5,FORMAT               FORMAT 1ST HALF OF PSW           54800019
         BAL   R5,FORMAT               FORMAT 2ND HALF OF PSW           55000019
PRINTLN  BAL   R5,ABDOUT               PRINT A LINE                I250 55200019
NOPSW    EQU   *                                                        55400019
         TM    PFLAGS,PFSUPDAT         IS SUP DATA REQUESTED       I250 55600019
         BZ    NOSUPDAT                NO,BRANCH                   I250 55800019
         LA    RA,NMLOAD3              YES,POINT TO NAME LOAD 3    I250 56000019
         B     XCTLOUT                                                  56200019
NOSUPDAT TM    PFLAGS+1,PFSAVE         IS SAVE AREA WANTED         I250 56400019
         BZ    GETLOAD6                NO,BRANCH                   I250 56600019
         LA    RA,NMLOAD5              POINT TO NAME OF LOAD 5     I250 56800019
         B     XCTLOUT                                             I250 57000019
GETLOAD6 LA    RA,NMLOAD6              POINT TO NAME OF LOAD 6     I250 57200019
XCTLOUT  LA    RF,ABDWORK3                                              57400019
         XCTL  EPLOC=(10),SF=(E,(15))                                   57600019
NMLOAD3  DC    C'IGC0A05A'             NAME OF ABDUMP LOAD 3       I250 57800019
NMLOAD5  DC    C'IGC0205A'             NAME OF ABDUMP LOAD 5       I250 58000019
NMLOAD6  DC    C'IGC0305A'             NAME OF ABDUMP LOAD 6       I250 58200019
         EJECT                                                          58400019
* FORMAT ROUTINE                                                        58600019
*       THIS ROUTINE ESTABLISHES A HEX-FORMATTED LINE IN AN OUTPUT      58800019
*       AREA ACCORDING TO A SERIES OF CONSTANTS WHICH DESCRIBE THE      59000019
*       LINE.  LABELED AND UNLABELED FIELDS WITHIN THE LINE CAN BE      59200019
*       HANDLED.  CHANGING THE CONSTANTS CHANGES THE LAYOUT OF A        59400019
*        LINE, WITH THE EXCEPTION THAT A FIXED AMOUNT EXISTS BETWEEN    59600019
*       A LABEL AND ITS FIELD.  PRESENTLY, A LABEL IS FOLLOWED BY 1     59800019
*       BLANK, THEN THE FIELD.                                          60000019
*       IF THE FIELDS THAT MAKE UP A LINE ARE FROM CONTIGUOUS           60200019
*       ASCENDING LOCATIONS (NORMAL CASE), ONE ENTRY TO THE ROUTINE     60400019
*       WILL SUFFICE.  WHEN AN END OF LINE CONSTANT IS RECOGNIZED,      60600019
*       THIS ROUTINE GIVES CONTROL TO AN OUTPUT ROUTINE WHICH WILL      60800019
*       RETURN CONTROL TO THE ROUTINE WHICH LINKED TO THE FORMAT        61000019
*       ROUTINE.                                                        61200019
*       IF THE FIELDS ARE NOT FROM CONTIGUOUS ASCENDING LOCATIONS,      61400019
*       THIS ROUTINE RETURNS (VIA 'BR R5') TO THE ROUTINE WHICH         61600019
*       LINKED TO THE FORMAT ROUTINE.                                   61800019
*       AFTER HANDLING THE SPECIAL CASE, THE FORMAT ROUTINE IS          62000019
*       REENTERED.                                                      62200019
*                                                                       62400019
FORMAT   LA    R8,ABDLINE              GET ADDR OF OUTPUT BUFFER        62600019
         SR    R1,R1                                                    62800019
         IC    R1,0(R3)                GET INDENTATION FACTOR           63000019
         AR    R8,R1                   UPDATE THE POINTERS              63200019
         LA    R3,1(R3)                                                 63400019
FORMAT01 CLI   0(R3),X'FF'             IS THIS A DELEMETER              63600019
         BC    8,FORMAT3               YES,BRANCH                       63800019
         SR    RE,RE                                                    64000019
         SR    RF,RF                                                    64200019
         SR    R0,R0                                                    64400019
         SR    R1,R1                                                    64600019
         IC    RE,0(R3)                GET FIRST CONTROL BYTE           64800019
         IC    R0,1(R3)                GET SECOND CONTROL BYTE          65000019
         SRDL  RE,4                    RE=SIZE OF LABEL-1               65200019
         SRL   RF,28                   RF=SIZE OF FIELD-1               65400019
         SRDL  R0,4                    R0=UPDATE REG 4 FACTOR           65600019
         SRL   R1,28                   R1=DIST BETWEEN LABEL AND FIELD  65800019
         AR    R4,R0                   BUMP THE POINTER                 66000019
         EX    RE,MOVE1                                                 66200019
         AR    R1,RE                                                    66400019
         LA    R8,1(R1,R8)             UPDATE POINTER                   66600019
         EX    RF,MOVE2                                                 66800019
         UNPK  ABDWORK4(9),ABDWORK4(5)                                  67000019
         TR    ABDWORK4(8),HEXTAB-240                                   67200019
         LA    RF,1(RF,RF)             RF=SIZE OF UNPACKED FIELD-1      67400019
         EX    RF,MOVE3                                                 67600019
         LA    R8,4(RF,R8)             UPDATE POINTER                   67800019
         LA    R3,3(RE,R3)             UPDATE POINTER                   68000019
         BC    15,FORMAT01             FORMAT NEXT FIELD                68200019
FORMAT3  LA    R3,1(R3)                                                 68400019
         BCR   15,R5                   RETURN                           68600019
MOVE1    MVC   0(1,R8),2(R3)           MOVE LABEL TO OUTPUT BUFFER      68800019
MOVE2    MVC   ABDWORK4(1),0(R4)       MOVE PACKED FIELD TO WORK AREA   69000019
MOVE3    MVC   0(1,R8),ABDWORK4        UNPACKED FILED TO OUTPUT BUFFER  69200019
         EJECT                                                          69400019
MOVECODE MVC   ABDLINE+22(1),0(R1)     MOVE INTERRUPT CODE INTO MESSAGE 70000019
TABLE    DC    X'000809131D0624092E09380C4503'                          70400019
HEXTAB   DC    C'0123456789ABCDEF'                                      70600019
MESS1    DC    C'1JOB'                                                  70800019
MESS2    DC    C'STEP'                                                  71000019
MESS3    DC    C'PAGE 0001'                                             71200019
MESS4    DC    C'0COMPLETION CODE'                                      71400019
MESS5    DC    C'0PSW AT ENTRY TO SNAP'                                 71600019
MESS6    DC    C'ABEND'                                                 71800019
IDMESS   DC    C'ID ='                                                  72000019
         DC    C'0'                CARRIAGE CONTROL CHAR                72200019
MESS     DC    C'PROGRAM INTERRUPTION ('                                72400019
LOCA     DC    C') AT LOCATION'                                         72600019
INTMESS  DC    C'OPERATION'                                             72800019
         DC    C'PRIVILEGED OPERATION'                                  73000019
         DC    C'EXECUTE'                                               73200019
         DC    C'PROTECTION'                                            73400019
         DC    C'ADDRESSING'                                            73600019
         DC    C'SPECIFICATION'                                         73800019
         DC    C'DATA'                                                  74000019
INTADDR  DC    X'0200' SIZE OF LABEL-SIZE OF FIELD-UPDATE BUF-DIS LB-FD 74200019
         DC    C' '                                                     74400019
         DC    X'FF'                                                    74600019
INTMSG   DC    X'00'                   IDENT                            74800019
         DC    X'B201'                                                  75000019
         DC    C'INTERRUPT AT'                                          75200019
         DC    X'FF'                                                    75400019
*                                                                       75600019
*                                                                       75800019
* THE LAYOUT OF A PRINT LINE IS DESCRIBED BY A SERIES OF CONSTANTS.     76000019
* EACH LABEL IS PRECEDED BY 4 HEX DIGITS-X'ABCD' WHERE                  76200019
* 1) A= SIZE OF THE LABEL -1                                            76400019
* 2) B=SIZE OF THE FIELD -1                                             76600019
* 3) C= NUMBER OF BYTES TO BE ADDED TO REG 4(FIELD POINTER)             76800019
* 4) D=DISTANCE BETWEEN THE LABEL AND THE FIELD                         77000019
* HEX X'FF' IS USED AS AN END OF LINE INDICATOR OR AS A DELEMETER       77200019
LINE1    DC    X'2A'                   INDENTATION FACTOR               77400019
         DC    X'3201'                                                  77600019
         DC    C'TIME'                                                  77800019
         DC    X'3251'                                                  78000019
         DC    C'DATE'                                                  78200019
         DC    X'FF'                                                    78400019
LINE2A   DC    X'15'                                                    78600019
         DC    X'7101'                                                  78800019
         DC    C'SYSTEM ='                                              79000019
         DC    X'FF'                                                    79200019
LINE2B   DC    X'15'                                                    79400019
         DC    X'5200'                                                  79600019
         DC    C'USER ='                                                79800019
         DC    X'FF'                                                    80000019
PSWLINE  DC    X'16'                                                    80200019
         DC    X'0300'                                                  80400019
         DC    C' '                                                     80600019
         DC    X'FF'                                                    80800019
         DC    X'1F'                                                    81000019
         DC    X'0340'                                                  81200019
         DC    C' '                                                     81400019
         DC    X'FF'                                                    81600019
         EJECT                                                          81800019
ABDAREA  DSECT                                                          82000019
ABDSAVE  DS    18F                     SAVE AREA                        82200019
ABDECB   DS    1F                      DECB-ECB                         82400019
ABDTYPE  DS    1H                      TYPE FIELD                       82600019
ABDLEN   DS    1H                      LENGTH FIELD                     82800019
ABDDCB   DS    1F                      PTR TO DCB                       83000019
ABDPTR   DS    1F                      AREA ADDRESS                     83200019
ABDSTAT  DS    1F                      PTR TO STATUS INDICATORS         83400019
ABDCTR1  DS    1H                      LINE CTR                         83600019
ABDCTR2  DS    1H                      PAGE CTR                         83800019
*              OUTPUT ROUTINE                                           84000019
ABDOUT   DS    55F                     220 BYTES RESERVED FOR OUTPUT    84200019
*                                        ROUTINE                        84400019
ABDPARA  DS    1F                      PTR TO PARAMETER LIST SAVED HERE 84600019
ABDENDLL DS    1F                      COMPARAND TO END LOAD LIST TRACE 84800019
ABDWORK3 DS    1C                      USED TO MAINTAIN RB SEQUENCE     85000019
*                                        COMPLEX PREFIX                 85200019
ABDWORK4 DS    11C                     9 BYTES USED FOR UNPACK AREA     85400019
ABDWORK1 DS    1D                      CONVERT TO DECIMAL AREA, SV AREA 85600019
ABDWORK2 DS    1F                      SAVE AREA FOR LINK ADDRESS       85800019
ABDPTRS  DS    3F                      BUFFER POINTERS USED BY OUTPUT   86000019
*                                        ROUTINE                        86200019
*              OUTPUT LINE                                              86400019
ABDPHY   DS    2C                      PHYSICAL RECORD LENGTH           86600019
ABDSRC1  DS    2C                      SYSTEM RESERVED CHAR             86800019
ABDLOG   DS    2C                      LOGICAL RECORD LENGTH            87000019
ABDSRC2  DS    2C                      SYSTEM RESERVED CHAR             87200019
ABDCC    DS    1C                      CARRIAGE-CONTROL CHAR            87400019
ABDLINE  DS    CL32                    120 CHAR PRINT LINE              87600019
         DS    CL32                                                     87800019
         DS    CL32                                                     88000019
         DS    CL24                                                     88200019
         DS    1C                      ONE BYTE FOLLOWING OUTPUT LINE   88400019
*                                        TO BE USED AS 'OVERFLOW' BYTE  88600019
*                                        WHEN UNPACKING INTO LINE       88800019
         DS    2C                                                       89000019
ABDFLAG  DS    1C                      BIT 0 = 1 MEANS DUMP IS     I250 89060019
*                                                FOR NON-CURRENT   I250 89120019
*                                                TASK              I250 89180019
*                                            = 0 MEANS DUMP IS     I250 89240019
*                                                FOR CURR TASK     I250 89300019
PARDSECT DSECT                                                          89400019
PID      DS    1C                      ID NUMBER LT 128                 89600019
         DS    1C                      RESERVED                         89800019
PFLAGS   DS    2C                      OPTION FLAGS                     90000019
PDCBPTR  DS    1F                      DCB ADDRESS                      90200019
PTCBPTR  DS    1F                      TCB ADDRESS                      90400019
PSNAPPTR DS    1F                      ADDRESS OF SANPSHOT LIST         90600019
CVTDSECT DSECT                                                          90800019
         CVT   SYS=INT                                                  91000019
         END                                                            91200019
