         TITLE 'IEAAAD0H / TCAM ABDUMP LOAD 2 / IGC0H05A'               00610020
IGC0H05A CSECT                                                          00620020
*                                                                       00630020
* MODULE NAME -                                                         00640020
*                                                                       00650020
*        IEAAAD0H                                                       00660020
*                                                                       00670020
* FUNCTION -                                                            00680020
*                                                                       00690020
*        TO FORMAT AND PRINT THE TERMINAL NAMES AS THEY EXIST IN        00700020
*        THE TERMINAL NAME TABLE (TNT) ALONG WITH THEIR                 00710020
*        ASSOCIATED ENTRIES IN THE TERMINAL TABLE (TRM) - WITH          00720021
*        THE EXCEPTION OF LGB TYPE TERMINAL TABLE ENTRIES.              00722021
*                                                                       00730020
* ATTRIBUTES -                                                          00740020
*                                                                       00750020
*        REENTRANT, REFRESHABLE                                         00760020
*                                                                       00770020
* ENTRY -                                                               00780020
*                                                                       00790020
*        1) ENTRY POINT - IGC0H05A                                      00791020
*                                                                       00792020
*        2) PSW - ENABLED                                               00793020
*               - IN SUPERVISOR STATE                                   00794020
*               - UNDER SUPERVISOR PROTECTION KEY                       00795020
*                                                                       00796020
*        3) REGISTERS -                                                 00797020
*                       2 - TCB ADDR OF TASK BEING DUMPED               00798020
*                       7 - ADDR OF TCAM AVT                            00799020
*                      10 - ADDR OF TCAM TNT                            00799120
*                      13 - ADDR OF ABDUMP'S WORK AREA                  00799220
*                                                                       00799320
* EXTERNAL REFERENCES -                                                 00799420
*                                                                       00799520
*        1) TCAM AVT -                                                  00799620
*                       AVTOPTPT - ADDR OF OPTION TABLE                 00799720
*                                                                       00799820
*        2) TCAM TNT -                                                  00799920
*                       TNTLEN - NUMBER OF TNT ENTRIES                  00800020
*                       TNTENLEN - LENGTH OF TERMINAL NAMES             00800120
*                       ALL TNT TERMINAL ENTRIES                        00800220
*                                                                       00800320
*        3) TCAM TRM -                                                  00800420
*                       ALL FIELDS                                      00800520
*                                                                       00800620
* EXIT -                                                                00800720
*                                                                       00800820
*        TO MODULE IEAAAD0I AT ENTRY POINT IGC0I05A VIA AN XCTL.        00800920
*                                                                       00801020
* ERROR MESSAGES -                                                      00801120
*                                                                       00801220
*        NONE                                                           00801320
*                                                                       00801420
* OPERATION -                                                           00801520
*                                                                       00801620
*        IEAAAD0H FIRST EXAMINES THE 'TNTENLEN' AND 'TNTLEN'            00801720
*        FIELDS OF THE TNT IN ORDER TO DETERMINE THE LENGTH AND         00801820
*        NUMBER OF ENTRIES IN THE TNT.  THEN, THE FIRST TNT             00802020
*        ENTRY IS ACCESSED AND THE TERMINAL NAME IS EXTRACTED           00802120
*        FROM IT ALONG WITH THE ADDRESS OF ITS ASSOCIATED TRM           00802221
*        ENTRY.  IF THIS TRM ENTRY IS AN LGB, FURTHER                   00802321
*        PROCESSING OF THIS ENTRY IS DEFERRED UNTIL THE NEXT            00802421
*        LOAD.  IF, HOWEVER, THIS TRM ENTRY IS NOT AN LGB, IT           00807221
*        IS FORMATTED ALONG WITH THE TERMINAL NAME ASSOCIATED           00809221
*        WITH IT.                                                       00811221
*                                                                       00812821
*        THE FORMATTING OF THE TRM ENTRIES IS HANDLED                   00817621
*        DIFFERENTLY DEPENDING ON WHICH TYPE OF ENTRY IS BEING          00822421
*        FORMATTED AND WHICH OPTIONAL FIELDS ARE PRESENT.  THE          00827221
*        SEQUENCE OF EVENTS IN FORMATTING A TRM ENTRY IS AS             00832021
*        FOLLOWS:                                                       00836821
*             FIRST, THE 'TRMSTATE' FIELD IS CHECKED TO SEE             00841621
*        IF THE TRM ENTRY IS OF THE LIST TYPE.  IF IT IS, THE           00846421
*        TRM ENTRY IS FORMATTED ACCORDINGLY ALONG WITH THE NAMES        00851221
*        OF THE TERMINALS ASSOCIATED WITH THE DISTRIBUTION OR           00856021
*        CASCADE LIST.  THESE NAMES ARE ACCESSED VIA INDICIES TO        00860821
*        THE TNT THAT ARE PRESENT IN THE LIST TYPE TRM ENTRIES.         00865621
*             IF THE TRM ENTRY IS NOT OF THE LIST TYPE, THE             00870421
*        PART OF THE TRM ENTRY CONSISTING OF REQUIRED FIELDS IS         00875221
*        FORMATTED.  THEN, THE 'TRMSTATE' FIELD IS CHECKED TO           00880021
*        SEE IF OPTION FIELDS ARE ASSOCIATED WITH THIS ENTRY.           00884821
*        IF SO, THEY ARE FORMATTED ALONG WITH THEIR ADDRESSES           00889621
*        AND OPTION NAMES.  NOTE THAT THE OPTION FIELDS ARE NOT         00894421
*        ACTUALLY A PART OF THE TRM ENTRY ITSELF BUT ARE LOCATED        00899221
*        IN THE OPTION TABLE AND ARE REFERENCED VIA OFFSETS IN          00904021
*        THE TRM ENTRY.                                                 00908821
*             AFTER THE OPTION FIELDS ARE HANDLED, THE                  00913621
*        'TRMDEVFL' FIELD IS CHECKED TO DETERMINE WHICH, IF ANY,        00918421
*        DEVICE DEPENDENT FIELDS ARE PRESENT.  THOSE WHICH ARE          00923221
*        PRESENT ARE FORMATTED ALONG WITH A LABEL IDENTIFYING           00928021
*        WHICH TYPE OF FIELD IT IS.  NOTE THAT THE DEVICE               00932821
*        DEPENDENT FIELDS ARE ACTUALLY PART OF THE TRM ENTRY            00937621
*        ITSELF.                                                        00942421
*                                                                       00947221
*        AFTER THE FORMATTING OF A TRM ENTRY IS COMPLETED, THE          00952021
*        NEXT TNT ENTRY IS LOCATED AND FORMATTED ALONG WITH ITS         00956821
*        ASSOCIATED TRM ENTRY (IF IT IS NOT AN LGB TYPE ENTRY)          00961621
*        AND THIS PROCESS CONTINUES UNTIL ALL TNT ENTRIES HAVE          00963621
*        BEEN PROCESSED.                                                00966421
*                                                                       00971221
*        FINALLY, CONTROL IS TRANSFERRED TO MODULE IEAAAD0I AT          00976021
*        ENTRY POINT IGC0I05A VIA AN XCTL.                              00980821
         EJECT                                                          00985621
*                                                                       00990421
* REGISTER EQUATES                                                      00995221
*                                                                       01000020
ENDLINE  EQU   0                   PTR TO STOP ADDR IN LINE             01200020
ENTRYLEN EQU   1                   LENGTH OF TNT ENTRY                  01600020
OPTPTR   EQU   1                   PTR TO OPTION FIELD OFFSET           01800020
LOOKUP   EQU   1                   PTR TO OPTION LOOK-UP TABLE          02000020
BYTECTR  EQU   1                   COUNT OF BYTES IN GROUPING           02200020
TCB      EQU   2                   PTR TO TCB                           02800020
LAYOUT   EQU   3                   PTR TO LAYOUT LINE                   03000020
LABLREG  EQU   3                   PTR TO LABEL TABLE                   03200020
OPTABLE  EQU   3                   PTR TO OPTION TABLE                  03400020
TNTENTRY EQU   3                   PTR TO TNT ENTRY                     03450021
FORMREG  EQU   4                   PTR TO FLD BEING FORMATTED           03600020
LINKREG  EQU   5                   LINK REG USED IN BAL                 03800020
MASKREG  EQU   6                   MASK TO TEST TRMDEVFL FIELD          04000020
OPTCTR   EQU   6                   COUNT OF OPTION ENTRIES              04200020
LISTCTR  EQU   6                   COUNT OF LIST ENTRIES                04400020
AVT      EQU   7                   PTR TO AVT                           04600020
OUTAREA  EQU   8                   PTR TO OUTPUT LINE                   04800020
NAMELEN  EQU   8                   LENGTH OF TNT NAME FIELD             05000020
TRM      EQU   9                   PTR TO TRM                           05400020
TNT      EQU   10                  PTR TO BEGINNING OF TNT              05600020
SWITCH   EQU   10                  SWITCH PASSED TO LOAD 3    CI  22024 05650021
NAMECTR  EQU   11                  COUNT OF TNT TERMINAL NAMES          05800020
BASE     EQU   12                  BASE REG USED BY ABDUMP              06000020
WORKAREA EQU   13                  PTR TO ABDUMP'S WORK AREA            06200020
FORMLINK EQU   14                  LINK REG USED BY FORMFLD RTN         06400020
NMNXTLD  EQU   14                  PTR TO NAME NEXT ABDUMP LOAD         06800020
MULTREG  EQU   14                  REG USED WHEN MULTIPLYING            07000020
PRODUCT  EQU   15                  PRODUCT AFTER MULTIPLICATION         07200020
WORKREG  EQU   15                  WORK REGISTER                        07400020
XCTLREG  EQU   15                  REG USED WHEN XCTL'ING               07600020
TNTINDEX EQU   15                  INDEX TO TNT ENTRY                   07800020
LABLEN   EQU   15                  LENGTH OF LABEL                      08000020
FLDLEN   EQU   15                  LENGTH OF DEV DEPENDENT FIELD        08400020
*                                                                       08600020
* OTHER EQUATES                                                         08800020
*                                                                       09000020
DBLSPACE EQU   C'0'                CARRIAGE CONTROL CHAR-SPACE 2        09200020
DIST     EQU   X'40'               MASK FOR DISTRIBUTION ENTRY          09400020
TSINGLE  EQU   X'E0'               MASK FOR SINGLE TYPE ENTRY CI  22024 09450021
TLINE    EQU   X'80'               MASK FOR LINE ENTRY        CI  22024 09500021
T3705    EQU   X'08'               MASK FOR 3705 ENTRY        AB  22024 09550021
UNUSED   EQU   X'FF'               INDICATES NO OPTION OFFSET           09800020
TNTNMIND EQU   5                   INDENT FACTOR-TNT NAME               10200020
LSTNMIND EQU   15                  INDENT FACTOR-LIST NAME              10400020
LISTIND  EQU   13                  INDENT FACTOR-LIST HEADING           10600020
LABLIND  EQU   13                  INDENT FACTOR-LABTABL NAMES          10800020
FLDIND   EQU   29                  IDENT FACTOR-OPTION FIELD            11000020
OPNMIND  EQU   13                  INDENT FACTOR-OPTION NAME            11200020
OPADIND  EQU   22                  INDENT FACTOR-OPTION ADDR            11400020
LGBAIND  EQU   13                  INDENT FACTOR-LGBA LABEL   CI  22024 11450021
RSIDIND  EQU   36                  INDENT FACTOR-RSID LABEL   CI  22024 11500021
SCBAIND  EQU   79                  INDENT FACTOR-SCBA LABEL   CI  22024 11550021
STATIND  EQU   95                  INDENT FACTOR-STAT LABEL   CI  22024 11560021
NOMORE   EQU   8                                                        11600020
CHAR0    EQU   C'0'                                                     11800020
BLANK    EQU   C' '                                                     12000020
ZERO     EQU   0                                                        12800020
ONE      EQU   1                                                        13000020
TWO      EQU   2                                                        13200020
THREE    EQU   3                                                        13400020
FOUR     EQU   4                                                        13600020
SIX      EQU   6                                                        14000020
SEVEN    EQU   7                                                        14200020
EIGHT    EQU   8                                                        14400020
SIXTEEN  EQU   16                                             CI  22024 14600021
STOPADDR EQU   101                                                      14800020
         EJECT                                                          15000020
         BALR  BASE,ZERO               ESTABLISH ADDRESSABILITY         15200020
         USING *,BASE                                                   15400020
         USING ABDAREA,WORKAREA                                         15600020
         USING IEDQAVTD,AVT                                             15800020
         USING IEDQTNTD,TNT                                             16000020
         USING IEDQTRM,TRM                                              16200020
*                                                                       16400020
* PREPARE TO FORMAT THE TNT ENTRIES                                     16600020
*                                                                       16800020
         LH    NAMECTR,TNTLEN          GET NUMBER OF TNT ENTRIES        17000020
         N     NAMECTR,CLRSIGN         INSURE A POSITIVE SIGN           17200020
         LTR   NAMECTR,NAMECTR         ARE THERE ANY                    17400020
         BZ    EXIT                    NO,BRANCH                        17600020
         LA    TNTENTRY,TNTFIRST       GET ADDR FIRST TNT ENTRY         17800020
         SR    NAMELEN,NAMELEN                                          18000020
         IC    NAMELEN,TNTENLEN        GET LENGTH TERMINAL NAME         18200020
         B     SAVEADDR                BRANCH TO FORMAT NAME            18400020
*                                                                       18600020
* LOCATE NEXT TNT ENTRY                                                 18800020
*                                                                       19000020
FORMNAME SR    NAMELEN,NAMELEN                                          19200020
         IC    NAMELEN,TNTENLEN        GET LENGTH TERMINAL NAME         19400020
         LA    TNTENTRY,THREE(NAMELEN) GET LENGTH TNT ENTRY             19600020
         A     TNTENTRY,ABDWORK2       POINT TO NEXT TNT ENTRY          19800020
SAVEADDR ST    TNTENTRY,ABDWORK2       SAVE ADDR OF TNT ENTRY           20000020
*                                                             CI  22024 20050021
* LOCATE TRM ENTRY ASSOCIATED WITH CURRENT TNT ENTRY          CI  22024 20100021
*                                                             CI  22024 20150021
         LR    FORMREG,TNTENTRY                               CI  22024 20160021
         AR    FORMREG,NAMELEN         POINT TO TRM ADDR      CI  22024 20170021
         MVC   ABDWORK1+ONE(THREE),ZERO(FORMREG)  MOVE ADDR   CI  22024 20180021
*                                                 TO FULLWORD CI  22024 20190021
         L     TRM,ABDWORK1            GET TRM ADDR           CI  22024 20192021
*                                                             CI  22024 20192421
* CHECK IF ENTRY IS AN LGB                                    CI  22024 20192821
*                                                             CI  22024 20193221
         TM    TRMSTATE,TSINGLE        Q. SINGLE OR LGB ENTRY CI  22024 20194021
         BNZ   NOTLGB                  NO,BRANCH              CI  22024 20196021
         TM    TRMDSORG,TRMLGB         Q. LGB TYPE ENTRY      CI  22024 20198021
         BZ    NOTLGB                  NO, BRANCH             CI  22024 20198421
         O     BASE,HIORDER            INDICATE LGB PRESENT   CI  22024 20198821
         B     NEXTTNT                 SKIP LGB'S THIS PASS   CI  22024 20199221
NOTLGB   EQU   *                                              CI  22024 20199621
*                                                                       20200020
* FORMAT TERMINAL NAME                                                  20400020
*                                                                       20600020
         MVC   ABDCC(L'NAMELABL),NAMELABL  MOVE LABEL TO LINE           20800020
         BCTR  NAMELEN,ZERO                GET NAME LENGTH-1  CI  22024 21200021
         EX    NAMELEN,MVCTNTNM            MOVE TERMINAL NAME CI  22024 21400021
         BAL   LINKREG,ABDOUT              PRINT THE LINE               21600020
*                                                                       21800020
* FORMAT CORRESPONDING TRM ENTRY                                        22000020
*                                                                       22200020
         LA    LAYOUT,$TRMLINE         ADDR TRM LAYOUT LINE   AI  22024 23400021
         BAL   LINKREG,FORMAT          FORMAT TRM ADDR                  23600020
         LR    FORMREG,TRM             PREPARE TO FORMAT TRM            23800020
         TM    TRMSTATE,DIST           IS THIS A DISTRIBUTION OR        24000020
*                                        CASCADE TYPE TRM ENTRY         24200020
         BO    DISTEN                  YES,BRANCH                       24400020
         BAL   LINKREG,FORMAT          FORMAT PART OF TRM LINE          24600020
         TM    TRMDEVFL+ONE,TRMRNTRM   Q. ENTRY FOR 3705      AB  22024 24650021
         BZ    CHECKOPT                NO, BRANCH             CI  22024 24700021
         TM    TRMSTATE,TLINE          Q. LINE ENTRY          CI  22024 24750021
         BNO   NOTLINE                 NO, BRANCH             CI  22024 24760021
         TM    TRMSTATE,X'E0'-TLINE    Q. LINE ENTRY          CI  22024 24770021
         BNZ   NOTLINE                 NO FOR SURE, BRANCH    CI  22024 24780021
*                                                             CI  22024 24790021
* CHANGE LABELS FOR 3705 LINE ENTRY                           CI  22024 24792021
*                                                             CI  22024 24794021
         MVC   ABDLINE+LGBAIND(L'LGBALABL),LGBALABL           CI  22024 24796021
         MVC   ABDLINE+RSIDIND(L'RSIDLABL),RSIDLABL           CI  22024 24798021
         B     CHECKOPT                CHECK OPTION FIELDS    CI  22024 24798421
NOTLINE  EQU   *                                              CI  22024 24798821
*                                                             CI  22024 24799221
* CHANGE LABELS FOR 3705 TERMINAL ENTRY                       CI  22024 24799621
*                                                             CI  22024 24799721
         MVC   ABDLINE+SCBAIND(L'SCBALABL),SCBALABL           CI  22024 24799821
         MVC   ABDLINE+STATIND(L'STATLABL),STATLABL           CI  22024 24799921
CHECKOPT EQU   *                                              CI  22024 24849921
         LA    FORMREG,TRMCHCIN        POINT TO TRMCHCIN FIELD          24899921
         TM    TRMSTATE,TRMOPTFN       ARE OPTION FIELDS USED           25000020
         BZ    NOOPT                   NO,BRANCH                        25200020
*                                                                       25400020
* PREPARE TO FORMAT THE OPTION FIELDS                                   25600020
*                                                                       25800020
         BAL   LINKREG,FORMAT          FORMAT REST OF TRM LINE          26000020
         BAL   LINKREG,ABDOUT          PRINT TRM LINE                   26200020
         MVI   ABDCC,DBLSPACE          DOUBLE SPACE PRINT LINE          26400020
         MVC   ABDLINE+OPNMIND(L'OPTLABEL),OPTLABEL  MOVE LABEL         26600020
         BAL   LINKREG,ABDOUT                        PRINT IT           26800020
         L     OPTABLE,AVTOPTPT        GET ADDR OF OPTION TABLE         27000020
         SR    OPTCTR,OPTCTR           INITIALIZE COUNTER               27200020
         B     FIRSTOPT                BRANCH TO FORMAT 1ST FLD         27400020
NEXTOPT  LA    OPTCTR,ONE(OPTCTR)      INCREMENT COUNTER                27600020
FIRSTOPT LA    OPTPTR,TRMOPT               GET ADDR OF NEXT             27800020
         LA    OPTPTR,ZERO(OPTPTR,OPTCTR)  OPTION OFFSET                28000020
         EX    OPTCTR,CHKOPNO          ANY MORE OPTION FIELDS           28200020
         BNH   ENDOPT                  NO,BRANCH                        28400020
         CLI   ZERO(OPTPTR),UNUSED     IS OPTION FIELD USED             28600020
         BE    NEXTOPT                 NO,BRANCH                        28800020
         LH    WORKREG,TRMOPTBL        GET 2-BYTE OFFSET                29000020
         N     WORKREG,CLRSIGN         INSURE A POSITIVE SIGN           29200020
         SR    FORMREG,FORMREG                                          29400020
         IC    FORMREG,ZERO(OPTPTR)    GET 1-BYTE OFFSET                29600020
         AR    FORMREG,WORKREG         DETERMINE ADDR OF CURRENT        29800020
         AR    FORMREG,OPTABLE           OPTION FIELD                   30000020
*                                                                       30200020
* FORMAT ADDRESS OF OPTION FIELD                                        30400020
*                                                                       30600020
         ST    FORMREG,ABDWORK1                                         30800020
         MVC   ABDLINE+OPADIND(THREE),ABDWORK1+ONE                      31000020
         UNPK  ABDLINE+OPADIND(SEVEN),ABDLINE+OPADIND(FOUR)             31200020
         TR    ABDLINE+OPADIND(SIX),HEXTAB-CHAR0                        31400020
         MVI   ABDLINE+OPADIND+SIX,BLANK                                31600020
*                                                                       31800020
* LOCATE THE APPROPIATE ENTRY IN THE OPTION LOOK-UP TABLE               32000020
*                                                                       32200020
         L     LOOKUP,FOUR(OPTABLE)    GET ADDR LOOK-UP TABLE           32400020
         LR    WORKREG,OPTCTR          DETERMINE ADDR OF LOOK-UP        32600020
         MH    WORKREG,TABLEN            TABLE ENTRY ASSOCIATED         32800020
         AR    LOOKUP,WORKREG            WITH CURRENT OPTION FLD        33000020
*                                                                       33200020
* FORMAT NAME OF OPTION FIELD                                           33400020
*                                                                       33600020
         MVC   ABDLINE+OPNMIND(EIGHT),TWO(LOOKUP)                       33800020
*                                                                       34000020
* FORMAT THE OPTION FIELD ITSELF                                        34200020
*                                                                       34400020
         SR    FLDLEN,FLDLEN                                            34600020
         IC    FLDLEN,ZERO(LOOKUP)     GET LENGTH OF THE CURRENT        34800020
         LA    FLDLEN,ONE(FLDLEN)        OPTION FIELD                   35000020
         BAL   FORMLINK,FORMFLD        FORMAT THE OPTION FIELD          35200020
         B     NEXTOPT                 PROCESS NEXT FIELD               35400020
ENDOPT   LR    FORMREG,OPTPTR          POINT TO NEXT TRM FIELD          35600020
         B     FORMDEVF                FORMAT DEV DEPENDENT FIELDS      35800020
NOOPT    BAL   LINKREG,ABDOUT          PRINT TRM LINE                   36000020
         LA    FORMREG,ONE(FORMREG)    POINT TO NEXT TRM FIELD          36200020
*                                                                       36400020
* TEST FOR PRESENCE OF DEVICE DEPENDENT FIELDS OF TRM                   36600020
*                                                                       36800020
FORMDEVF EQU   *                                              CI  22024 37000021
         LH    MASKREG,TRMDEVFL        GET DEVICE DEP FLAGS   CI  22024 37050021
         SLL   MASKREG,SIXTEEN         LEFT JUSTIFY THEM      CI  22024 37100021
         N     MASKREG,VALIDBIT        MASK OUT UNUSED BITS   AB  22024 37150021
         LA    LABLREG,LABTABL         GET ADDR OF LABELS               37400020
         MVI   ABDCC,DBLSPACE          DOUBLE SPACE PRINT LINE          37600020
         B     TSTDEVFL                BRANCH TO TEST 1ST FLAG          37800020
NULLFLD  BAL   LINKREG,ABDOUT          PRINT LABEL AND NULL FLD         37810020
NEXTFLAG EQU   *                                              CI  22024 37860021
         SLL   MASKREG,ONE             REMOVE BIT JUST TESTED CI  22024 38000021
         SR    LABLEN,LABLEN                                            38600020
         IC    LABLEN,ZERO(LABLREG)    GET LENGTH-1 CURR LABEL          38800020
         LA    LABLREG,TWO(LABLREG)    DETERMINE ADDR OF NEXT           39000020
         AR    LABLREG,LABLEN            LENGTH BYTE IN LABTABL         39200020
TSTDEVFL EQU   *                                              CI  22024 39400021
         LTR   MASKREG,MASKREG         Q. IS THERE ANY FIELDS AB  22024 39460021
         BZ    NEXTTNT                 NO. GET OUT            AB  22024 39520021
         BP    NEXTFLAG                YES. BUT BIT UNUSED    AB  22024 39600021
*                                                                       39800020
* FORMAT DEVICE DEPENDENT FIELDS OF TRM                                 40000020
*                                                                       40200020
         SR    LABLEN,LABLEN                                            40400020
         IC    LABLEN,ZERO(LABLREG)    GET LENGTH-1 CURR LABEL          40600020
         EX    LABLEN,MOVELABL         MOVE LABEL TO OUTPUT LINE        40800020
         SR    FLDLEN,FLDLEN                                            41000020
         IC    FLDLEN,ZERO(FORMREG)    GET LENGTH OF FIELD              41200020
         LA    FORMREG,ONE(FORMREG)    POINT TO BEGINNING OF FLD        41400020
         LTR   FLDLEN,FLDLEN           IS FIELD LENGTH ZERO             41600020
         BZ    NULLFLD                 YES,BRANCH                       41800020
         BAL   FORMLINK,FORMFLD        FORMAT THE FIELD                 42000020
         B     NEXTFLAG                TEST NEXT FLAG                   42200020
*                                                                       42400020
* FORMAT DISTRIBUTION OR CASCADE TYPE TRM ENTRY                         42600020
*                                                                       42800020
DISTEN   LA    LAYOUT,DISTLINE         GET ADDR LAYOUT LINE             43000020
         BAL   LINKREG,FORMAT          FORMAT A TRM LINE                43200020
         BAL   LINKREG,ABDOUT          PRINT IT                         43400020
         LH    LISTCTR,TLISTCNT        GET NUMBER LIST INDICES          43600020
         N     LISTCTR,CLRSIGN         INSURE A POSITIVE SIGN           43800020
         LTR   LISTCTR,LISTCTR         ARE THERE ANY                    44000020
         BZ    NEXTTNT                 NO,BRANCH                        44200020
*                                                                       44400020
* FORMAT THE TERMINAL NAMES ASSOCIATED WITH CURRENT DISTRIBUTION        44600020
* OR CASCADE ENTRY                                                      44800020
*                                                                       45000020
         MVI   ABDCC,DBLSPACE          DOUBLE SPACE PRINT LINE          45200020
         MVC   ABDLINE+LISTIND(L'LISTLABL),LISTLABL  MOVE LABEL         45400020
         BAL   LINKREG,ABDOUT                        PRINT IT           45600020
FORMLIST LA    FORMREG,TWO(FORMREG)    POINT TO NEXT TNT INDEX          45800020
         SR    NAMELEN,NAMELEN                                          46000020
         IC    NAMELEN,TNTENLEN        GET LENGTH TERMINAL NAME         46200020
         LA    ENTRYLEN,THREE(NAMELEN) GET LENGTH OF TNT ENTRY          46400020
         LH    TNTINDEX,ZERO(FORMREG)  GET INDEX TO TNT ENTRY           46600020
         N     TNTINDEX,CLRSIGN        INSURE A POSITIVE SIGN           46800020
         LA    TNTENTRY,TNTFIRST       GET ADDR 1ST TNT ENTRY           47000020
         LR    MULTREG,ENTRYLEN                                         47200020
*                                      ADDR OF TNT ENTRY =              47400020
         MR    MULTREG,MULTREG         (LENGTH OF ENTRY * INDEX)        47600020
         SR    PRODUCT,ENTRYLEN        - LENGTH OF ENTRY                47800020
         AR    TNTENTRY,PRODUCT        + ADDR OF 1ST ENTRY              48000020
         BCTR  NAMELEN,ZERO            GET LENGTH-1 OF NAME             48200020
         EX    NAMELEN,MVCLSTNM        MOVE TERMINAL NAME               48400020
         BAL   LINKREG,ABDOUT          PRINT A LINE                     48600020
         BCT   LISTCTR,FORMLIST        BRANCH IF MORE ENTRIES           48800020
*                                        IN LIST                        49000020
NEXTTNT  BCT   NAMECTR,FORMNAME        BRANCH IF MORE TNT               49200020
*                                        ENTRIES TO FORMAT              49400020
*                                                                       49600020
* XCTL TO NEXT ABDUMP LOAD                                              49800020
*                                                                       50000020
EXIT     EQU   *                                              CI  22024 50050021
         LR    SWITCH,BASE             INITIALIZE SWITCH      CI  22024 50100021
         LTR   BASE,BASE               Q. ANY LGB'S FOUND     CI  22024 50150021
         BL    XCTL                    YES, BRANCH            CI  22024 50200021
         SR    SWITCH,SWITCH           INDICATE NO LGB'S      CI  22024 50250021
XCTL     EQU   *                                              CI  22024 50300021
         LA    NMNXTLD,TCAMLD3         GET NAME OF NEXT LOAD            50350021
         LA    XCTLREG,ABDWORK         POINT TO XCTL PARAM LIST         50400020
         XCTL  EPLOC=(NMNXTLD),SF=(E,(15))                              50600020
TCAMLD3  DC    C'IGC0I05A'             NAME OF NEXT ABDUMP LOAD         50605020
         EJECT                                                          50610020
*                                                                       50800020
* THE FOLLOWING RTN IS ENTERED VIA A BAL AT ENTRY POINT                 51000020
* 'FORMFLD' IN ORDER TO FORMAT THE OPTION FIELDS AND DEVICE             51200020
* DEPENDENT FIELDS ASSOCIATED WITH A TRM ENTRY.  THESE FIELDS           51400020
* ARE FORMATTED IN 4-BYTE GROUPINGS.                                    51600020
*                                                                       51800020
CHKLINE  CR    OUTAREA,ENDLINE         IS OUTPUT LINE FULL              52000020
         BL    NEXTBYTE                NO,FORMAT NEXT BYTE              52200020
PRINTLN  STM   FORMLINK,FLDLEN,ABDWORK SAVE REGS 14 AND 15              52400020
         BAL   LINKREG,ABDOUT          PRINT A LINE                     52600020
         LM    FORMLINK,FLDLEN,ABDWORK RESTORE REGS 14 AND 15           52800020
         LTR   FLDLEN,FLDLEN           ANY MORE BYTES TO FORMAT         53000020
         BCR   NOMORE,FORMLINK         NO,RETURN TO CALLING RTN         53200020
FORMFLD  LA    OUTAREA,ABDLINE+FLDIND  POINT TO OUTPUT LINE             53400020
         LA    ENDLINE,ABDLINE+STOPADDR  ESTABLISH STOP ADDR            53600020
         LA    BYTECTR,FOUR            SET COUNT OF BYTES/GROUP         53800020
NEXTBYTE MVC   ZERO(ONE,OUTAREA),ZERO(FORMREG)       MOVE 1 BYTE        54000020
         UNPK  ZERO(THREE,OUTAREA),ZERO(TWO,OUTAREA) UNPACK IT          54200020
         TR    ZERO(TWO,OUTAREA),HEXTAB-CHAR0        TRANSLATE          54400020
         MVI   TWO(OUTAREA),BLANK                    CLEAR SIGN         54410020
         LA    FORMREG,ONE(FORMREG)    POINT TO NEXT BYTE IN FLD        54600020
         LA    OUTAREA,TWO(OUTAREA)    BUMP OUTPUT LINE PTR             54800020
         BCT   BYTECTR,CHKFLDLN        BRANCH IF LESS THAN              55000020
*                                        4 BYTES IN GROUPING            55200020
         LA    OUTAREA,ONE(OUTAREA)    SPACE 1 BETWEEN GROUPINGS        55400020
         LA    BYTECTR,FOUR            RESET COUNT                      55600020
CHKFLDLN BCT   FLDLEN,CHKLINE          BRANCH IF MORE BYTES TO          55800020
*                                        BE FORMATTED                   56000020
         B     PRINTLN                 PRINT LAST LINE                  56200020
         EJECT                                                          56210020
*                                                                       56400020
* THE FOLLOWING INSTRUCTIONS ARE REACHED VIA AN EXECUTE                 56600020
*                                                                       56800020
MVCTNTNM MVC   ABDLINE+TNTNMIND(ZERO),ZERO(TNTENTRY)  MOVE TERM         57000020
*                                                     NAME WHEN         57200020
*                                                     FORMATTING        57400020
*                                                     TNT ENTRY         57600020
*                                                                       57800020
MVCLSTNM MVC   ABDLINE+LSTNMIND(ZERO),ZERO(TNTENTRY)  MOVE TERM         58000020
*                                                     NAME WHEN         58200020
*                                                     FORMATTING        58400020
*                                                     DIST LIST         58600020
*                                                                       58800020
MOVELABL MVC   ABDLINE+LABLIND(ZERO),ONE(LABLREG)  MOVE LABEL           59000020
*                                                  DESCRIBING           59200020
*                                                  DEVICE               59400020
*                                                  DEPENDENT FLD        59600020
*                                                                       59800020
CHKOPNO  CLI   TRMOPNO,ZERO            COMPARE NUMBER OF OPTION         60000020
*                                      FIELDS WITH NUMBER               60200020
*                                      ALREADY FORMATTED                60400020
         EJECT                                                          61010020
*                                                                       66010020
* LAYOUT LINES -                                                        71560020
*                                                                       71570020
*        EACH LINE TO BE FORMATTED WITH LABELED FIELDS IS               71580020
*        DESCRIBED BY A SEQUENCE OF CONSTANTS CALLED A LAYOUT           71590020
*        LINE.                                                          71600020
*                                                                       71610020
*        THE FIRST BYTE OF EACH LAYOUT LINE AND THE FIRST BYTE          71620020
*        FOLLOWING A X'FF' DELIMITER CONSISTS OF AN INDENTATION         71630020
*        FACTOR WHICH IS EQUAL TO THE NUMBER OF BYTES THAT THE          71640020
*        NEXT FIELD IS TO BE INDENTED IN THE PRINT LINE.                71650020
*                                                                       71660020
*        EACH LABELED FIELD TO BE FORMATTED IS DESCRIBED BY ITS         71670020
*        APPROPRIATE LABEL AND A SEQUENCE OF 4 HEX DIGITS WHICH         71680020
*        PRECEDE THE LABEL IN THE LAYOUT LINE.  THE 4 HEX               71690020
*        DIGITS, X'ABCD', HAVE THE FOLLOWING SIGNIFICANCE :             71700020
*                                                                       71710020
*             A = SIZE OF THE LABEL - 1                                 71720020
*                                                                       71730020
*             B = SIZE OF FIELD BEING FORMATTED - 1                     71740020
*                                                                       71750020
*             C = NUMBER OF BYTES FORMREG MUST BE INCREMENTED TO        71760020
*                 POINT TO THE FIELD BEING FORMATTED                    71770020
*                                                                       71780020
*             D = NUMBER OF BLANKS TO APPEAR BETWEEN THE LABEL          71790020
*                 AND THE FORMATTED FIELD                               71800020
*                                                                       71810020
*        THE X'FF' CONSTANT THAT APPEARS THROUGHOUT THE LAYOUT          71820020
*        LINES IS USED AS A DELIMITER.  IT INDICATES TO THE             71830020
*        FORMAT ROUTINE THAT IT SHOULD STOP FORMATTING AND              71840020
*        RETURN TO THE CALLING ROUTINE.                                 71850020
*                                                                       71860020
$TRMLINE DC    AL1(0)                                         AI  22024 72000021
         DC    X'2202'                                                  72200020
         DC    C'TRM'                                                   72400020
         DC    X'FF'                                                    72600020
         DC    AL1(13)                                                  72800020
         DC    X'A301'                                                  73000020
         DC    C'STATE/DESTQ'                                           73200020
         DC    X'8341'                                                  73400020
         DC    C'IN/OUTSEQ'                                             73600020
         DC    X'9341'                                                  73800020
         DC    C'ALTD/DEVFL'                                            74000020
         DC    X'3341'                                                  74200020
         DC    C'STAT'                                                  74400020
         DC    X'4041'                                                  74600020
         DC    C'CHCIN'                                                 74800020
         DC    X'FF'                                                    75000020
         DC    AL1(100)                                                 75200020
         DC    X'A301'                                                  75400020
         DC    C'/OPNO/OPTBL'                                           75600020
         DC    X'FF'                                                    75800020
DISTLINE DC    AL1(13)                                                  76000020
         DC    X'A301'                                                  76200020
         DC    C'STATE/DESTQ'                                           76400020
         DC    X'7141'                                                  76600020
         DC    C'TLISTCNT'                                              76800020
         DC    X'FF'                                                    77000020
         EJECT                                                          77010020
*                                                                       77080020
* THE FOLLOWING TABLE CONSISTS OF LABELS DESCRIBING THE VARIOUS         77090020
* DEVICE DEPENDENT FIELDS THAT CAN EXIST IN A TRM ENTRY.  EACH          77100020
* LABEL IS PRECEDED BY ITS LENGTH - 1.  THIS TABLE IS USED TO           77110020
* INSERT THE PROPER LABEL IN THE PRINT LINE WHEN THE DEVICE             77120020
* DEPENDENT FIELDS OF A TRM ENTRY ARE BEING FORMATTED.                  77130020
*                                                                       77140020
LABTABL  EQU   *                                                        77200020
         DC    AL1(L'LABEL1-1)                                          77250021
LABEL1   DC    C'BUFFSIZE'                                              77300021
         DC    AL1(L'LABEL2-1)                                          77350021
LABEL2   DC    C'DIAL DIGITS'                                           77400021
         DC    AL1(L'LABEL3-1)                                          77450021
LABEL3   DC    C'ADDR CHAR'                                             77500021
         DC    AL1(L'LABEL4-1)                                          77550021
LABEL4   DC    C'BLOCK'                                                 77600021
         DC    AL1(L'LABEL5-1)                                          77650021
LABEL5   DC    C'SUBBLOCK'                                              77700021
         DC    AL1(L'LABEL6-1)                                          77750021
LABEL6   DC    C'TRANS BLOCK'                                           77800021
         DC    AL1(L'LABEL7-1)                                          77850021
LABEL7   DC    C'BFDELAY'                                               77900021
         DC    AL1(L'LABEL8-1)                                          77950021
LABEL8   DC    C'TIME SHARING'                                          78000021
         DC    AL1(L'LABEL9-1)                                          78010021
LABEL9   DC    C'CONC'                                                  78020021
         DC    AL1(L'LABEL10-1)                                         78030021
LABEL10  DC    C'LMD/MB'                                                78040021
         DC    AL1(L'LABEL11-1)                                         78042021
LABEL11  DC    C'RETRY COUNT'                                           78044021
         DC    AL1(L'LABEL12-1)                               AB  22024 78050021
LABEL12  DC    C'3705 FIELD'                                  AB  22024 78100021
* THIS PART OF THE LABEL TABLE IS UNUSED AND MUST BE CHANGED            78150021
* IF BITS 12 THRU 15 ARE USED                                           78200021
         DC    AL1(0)                                                   78250021
BIT12    DC    C' '                                                     78300021
         DC    AL1(0)                                                   78350021
BIT13    DC    C' '                                                     78400021
         DC    AL1(0)                                                   78450021
BIT14    DC    C' '                                                     78500021
         DC    AL1(0)                                                   78550021
BIT15    DC    C' '                                                     78600021
         EJECT                                                          80401020
*                                                                       80410020
* CONSTANTS                                                             80420020
*                                                                       80430020
         DS    0F                                                       80600020
HIORDER  DC    X'80000000'             MASK TO SET HI BIT     CI  22024 80650021
CLRSIGN  DC    X'0000FFFF'             MASK TO CLEAR SIGN AFTER         80800020
*                                        LOADING HALFWORDS              80810020
TABLEN   DC    H'10'                   LENGTH OF LOOK-UP ENTRY          81000020
HEXTAB   DC    C'0123456789ABCDEF'     TRANSLATE TABLE                  81400020
NAMELABL DC    C'0NAME'                LABEL FOR TNT NAME FIELD         81600020
LISTLABL DC    C'LIST ENTRIES'         LABEL FOR TRM LIST FIELD         81800020
OPTLABEL DC    C'NAME      ADDR  OPTION FIELD'  LABEL FOR TRM           82000020
*                                               OPTION FIELDS           82200020
LGBALABL DC    C'LSTAT/LGBA '          LABELS FOR 3705        CI  22024 82250021
RSIDLABL DC    C'RSID/TYPE'              LINE ENTRIES         CI  22024 82300021
*                                                             CI  22024 82350021
SCBALABL DC    C'SCBA'                 LABELS FOR 3705        CI  22024 82400021
STATLABL DC    C'STAT1'                  TERMINAL ENTRIES     CI  22024 82450021
         DS    0F                                                       82500021
VALIDBIT DC    X'FFF00000'                                    AB  22024 82550021
         EJECT                                                          82899921
ABDAREA  DSECT                                                          83000020
ABDSAVE  DS    18F                 SAVE AREA                            83200020
*                                                                       83400020
* DECB                                                                  83600020
*                                                                       83800020
ABDECB   DS    1F                  ECB                                  84000020
ABDTYPE  DS    1H                  TYPE FIELD                           84200020
ABDLEN   DS    1H                  LENGTH FIELD                         84400020
ABDDCB   DS    1F                  PTR TO DCB                           84600020
ABDPTR   DS    1F                  AREA ADDRESS                         84800020
ABDSTAT  DS    1F                  PTR TO STATUS INDICATORS             85000020
*                                                                       85200020
ABDCTR1  DS    1H                  LINE CTR                             85400020
ABCDTR2  DS    1H                  PAGE CTR                             85600020
ABDOUT   DS    55F                 SPACE OCCUPIED BY OUTPUT RTN         85800020
ABDPARA  DS    1F                  PTR TO PARAM LIST                    86000020
*                                                                       86200020
* INTERNAL WORK AND SAVE AREAS                                          86400020
*                                                                       86600020
         DS    1F                  NOT USED BY THIS LOAD                86800020
ABDWORK  DS    2F                  SAVE AREA USED BY FORMFLD RTN        87000020
*                                  AND AREA FOR XCTL PARAM LIST         87200020
ABDWORK2 DS    1F                  SAVE AREA FOR TNT ENTRY PTR          87400020
ABDWORK1 DS    1D                  WORK AREA USED BY THIS LOAD          87600020
*                                  AND BY ABDOUT RTN                    87800020
         ORG   ABDWORK1            RESET LOCATION CTR                   88000020
ABDWORK4 DS    3F                  WORK AREA USED BY FORMAT RTN         88200020
*                                                                       88400020
ABDPTRS  DS    3F                  BUFFER PTRS                          88600020
*                                                                       88800020
* OUTPUT AREA                                                           89000020
*                                                                       89200020
ABDPHY   DS    2C                  PHYSICAL RECORD LENGTH               89400020
ABDSRC1  DS    2C                  SYSTEM RESERVED CHAR                 89600020
ABDLOG   DS    2C                  LOGICAL RECORD LENGTH                89800020
ABDSRC2  DS    2C                  SYSTEM RESERVED CHAR                 90000020
ABDCC    DS    1C                  CARRIAGE CONTROL CHAR                90200020
ABDLINE  DS    CL120               120 CHAR PRINT LINE                  90400020
         DS    1C                  'OVERFLOW'BYTE WHEN UNPACK-          90600020
*                                  ING INTO LINE                        90800020
*                                                                       91000020
         DS    2C                  NOT USED BY THIS LOAD                91200020
ABDFLAG  DS    1C                  FLAGS USED BY ABDUMP                 91400020
         DS    3C                  NOT USED BY THIS LOAD                91500020
FORMAT   DS    0H                                                       91600020
         DS    144C                FORMAT ROUTINE                       91700020
         DS    24C                 NOT USED BY THIS LOAD                91800020
BBADDR   DS    1F                  ADDR OF BOUNDARY BOX                 92000020
         EJECT                                                          92010020
         TAVTD                                                          92020020
         EJECT                                                          92030020
         TTNTD                                                          92040020
         EJECT                                                          92050020
         TTRMD                                                          92060020
         END                                                            97200020
