         TITLE 'IEAAAD0K  /  ABDUMP 13  /  IGC0K05A'                    00060021
IGC0K05A CSECT                                                          00070021
*STATUS CHANGE LEVEL=0                                                  00100021
*   ROUTINE NAME-                                                       00150021
*        IEAAAD0K                                                       00200021
*   FUNCTION-                                                           00250021
*        THIS MODULE OUTPUTS THE GTF TRACE TABLE                        00300021
*   ENTRY POINT NAME-                                                   00350021
*        IGC0K05A                                                       00400021
*   ATTRIBUTES-                                                         00450021
*        TYPE IV SVC,SUPERVISOR STATE,REENTRANT                         00500021
*   APPLICABILITY-                                                      00550021
*        OPTION IV                                                      00600021
*   EXTERNAL REFERENCES-                                                00650021
*        NONE                                                           00700021
*   SVC USAGE--XCTL                                                     00750021
*   INPUT-                                                              00800021
*        1) POINTER TO THE TCB BEING DUMPED- REG 2                      00850021
*        2) POINTER TO THE ABDUMP WORK AREA- REG 13                     00900021
*   OUTPUT-                                                             00950021
*        GTF TRACE TABLE DUMPED, REGS 2 AND 13 UNCHANGED                01000021
*   ENTRY POINTS-                                                       01050021
*        1) PSW                                                         01100021
*             A) ENABLED                                                01150021
*             B) UNDER SUPERVISOR PROTECTION KEY                        01200021
*             C) IN SUPERVISOR MODE                                     01250021
*        2) REGISTERS                                                   01300021
*             A) REG 2-POINTER TO TCB BEING DUMPED                      01350021
*             B) REG 13-POINTER TO ABDUMP'S WORK AREA                   01400021
*   EXITS-                                                              01450021
*       TO ABDUMP 14 IEAAAD0M IF IT AN EXCEPTIONAL RECORD CONDITION OR  01500021
*       TO ABDUMP 8 IEAAAD04 IF THE DUMP OF THE TRACE TABLE IS COMPLETE 01550021
*   TABLE AND CONTROL BLOCK REFERENCED-                                 01600021
*        IEAAAD0K REFERENCES THE FOLLOWING CONTROL BLOCKS-              01650021
*        1) CVT                                                         01700021
*              CVTGTF-GTF FLAGS AND CMT ADDR                            01750021
*        2) CMT (CLASS MASK TABLE)                                      01800021
*              CMTCMSK- CLASS MASKS                                     01850021
*              CMTHCT- HCT ADDR                                         01900021
*        3) HCT (HOOK CONTROL TABLE)                                    01950021
*              HCTTCUR- ADDR CURRENT GTF TRACE BUFFER                   02000021
*              HCTFLG2- FLAGS                                           02050021
*              HCTFLG3- FLAGS                                           02100021
*        4) BFX (BUFFER PREFIX AND CONTROL)                             02150021
*              BPXFLGS- BUFFER PREFIX FLAGS                             02200021
*              BPXLINK- ADDR NEXT BPX                                   02250021
*              BPXBUFF- ADDR BUFFER                                     02300021
*              BPXPRLEN- PHYSICAL RECORD LENGTH                         02350021
*              BPXLRLEN- LOGICAL RECORD LENGTH OF FIRST                 02400021
*        5) TCB                                                         02450021
*              TCBDAR- GTF TRACE SUSPENDED FLAG                         02500021
*                                                                       02550021
** REGISTER EQUATES                                                     02600021
*                                                                       02650021
BASEREG  EQU   12             ROUTINE BASE REG                          02700021
WKREGA   EQU   11             WORK REG FOR CVT,CMT,HCT                  02750021
WKREGB   EQU   9              WORK REG                                  02800021
WKREG4   EQU   4                                              AB  M0805 02850021
R5       EQU   5              BALR TO OUTPUT ROUTINE                    02900021
R6       EQU   6              BASE FOR IEAQAD0A REENTRANT RTNS          02950021
R13      EQU   13             BASE FOR ABDUMP WORK AREA                 03000021
RE       EQU   14                                                       03050021
TCBREG   EQU   2              ADDR OF TCB CAUSING DUMP                  03100021
R10      EQU   10             REMAINING BUFFER LENGTH, XCTL             03150021
RF       EQU   15                                                       03200021
R15      EQU   15             WORK                                      03250021
R7       EQU   7              PTR TO RECORD IN BUFFER                   03300021
WK4      EQU   4              WORK REG                                  03350021
R3       EQU   3                                                        03400021
R0       EQU   0                   WORK REG                             03450021
R1       EQU   1                   WORK REG                             03500021
R8       EQU   8                                                        03550021
ZEROF    EQU   X'0F'                                                    03600021
HEXF8    EQU   X'F8'               MAXIMUM UNPACK COUNT-- 8 TO 15       03650021
SPACE2CC EQU   X'F0'               2 SPACE CARRIAGE CONTROL             03700021
HEX37    EQU   X'37'               1ST TOD CONTROL BYTE FOR FORMAT RTN  03750021
FF       EQU   X'FF'               TOTAL FLAG BITS MASK                 03800021
F0       EQU   X'F0'               MASK FOR 2ND BYTE SIO EID            03850021
**  GTF RECORD EQUATES                                                  03900021
PFXLENG  EQU   0                   RECORD LENGTH DISPLACEMENT           03950021
PFXAID   EQU   4                   AID DISPLACEMENT                     04000021
PFXFID   EQU   5                   FID DISPLACEMENT                     04050021
PFXTOD   EQU   6                   TOD DISPLACEMENT                     04100021
PFXNOTOD EQU   10                  TIMER UNITS DISPLACEMENT             04150021
CNTRLREC EQU   X'00'               CONTROL RECORD AID MASK              04200021
TIMESTAM EQU   X'04'               TIMESTAMP CNTRL REC FID              04250021
TCBFLG1  EQU   X'1D'                                          AB  M0805 04260021
LOSTCNT  EQU   X'06'               LOST EVENTCNTRL REC FID              04300021
BLANK    EQU   C' '                                                     04350021
FLG4BLNK EQU   X'84'               MASK FOR FORMAT FLAG AND BLNK CNT    04400021
OFFBLANK EQU   X'00'               MASK OFF FORMAT FLAG AND BLNK CNT    04450021
ZONE     EQU   X'F0'              ZONE FOR DECIMAL DIGITS               04460021
DOT      EQU   C'.'          PERIOD FOR LABEL                           04470021
** NUMBER EQUATES                                                       04500021
NINE     EQU   9              NUMBER 9                                  04550021
TEN      EQU   10             NUMBER 10                                 04600021
TWELV    EQU   12             NUMBER 12                                 04650021
FIFTN    EQU   15              NUMBER 15                                04700021
SIXTN    EQU   16             NUMBER 16                                 04750021
SEVENTN  EQU   17             NUMBER 17                                 04800021
TWENTY   EQU   20             NUMBER 20                                 04850021
TWENT2   EQU   22              NUMBER 22                                04900021
TWENT9   EQU   29              NUMBER 29                                04950021
THIRTY2  EQU   32              NUMBER 32                                05000021
FORT3    EQU   43             NUMBER 43                                 05050021
FORT9    EQU   49              NUMBER 49                                05100021
FIFT2    EQU   52              NUMBER 52                                05150021
FIFT4    EQU   54              NUMBER 54                                05200021
FIFT5    EQU   55              NUMBER 55                                05250021
FIFT8    EQU   58              NUMBER 58                                05300021
SEVENT3  EQU   73             NUMBER 73                                 05350021
EIGHT3   EQU   83             NUMBER 83                                 05400021
NINT5    EQU   95             NUMBER 95                                 05450021
ONE05    EQU   105            NUMBER 105                                05500021
ONE09    EQU   109            NUMBER 109                                05550021
ABDMP000 BALR  BASEREG,0           GET ADDRESSABILITY                   05600021
         USING *,BASEREG           FOR ROUTINE                          05650021
         LTR   R8,R8              IS ENTRY FROM 2ND LOAD-IEAAADOM       05700021
         BNZ   ABDMP100                                                 05750021
         USING ABDAREA,R13         SET UP DSECT FOR ABDUMP WORK AREA    05800021
         USING CVTDSECT,WKREGA     SET UP DSECT FOR CVT                 05850021
*** GET ADDRESSABILITY TO HCT; CVT->CMT->HCT                            05900021
         L     WKREGA,CVTPTR       GET CVT PTR                          05950021
         L     WKREGA,CVTGTF       GET CMT ADDR                         06000021
         LA    WKREGA,ZERO(WKREGA) CLEAR HI BYTE                        06050021
         USING CMTDSECT,WKREGA     SET UP CMT DSECT                     06100021
         L     WKREGA,CMTHCT       GET HCT ADDR                         06150021
         LA    WKREGA,ZERO(WKREGA) CLEAR HI BYTE                        06200021
         USING HCTDSECT,WKREGA     SET UP HCT DSECT                     06250021
*** PRINT HEADER RECORD AND GET OLDEST BUFFER                           06350021
ABDMP010 MVC   ABDCC(L'TRACHEAD),TRACHEAD  SET UP CARR CNTRL,HEADER     06400021
         BAL   R5,ABDOUT                AND GO PRINT                    06450021
         MVI   ABDCC,SPACE2CC      RESET CARR CNTRL TO SPACE 2          06500021
         L     WKREGB,HCTTCUR      GET ADDR CURRENT TRACE BUFFER PREFIX 06550021
         LA    WKREGB,ZERO(WKREGB) CLEAR HI BYTE                        06600021
         USING BPXDSECT,WKREGB     SET UP BPX DSECT                     06650021
         L     WKREGB,BPXLINK      GET OLDEST BUFFER                    06700021
         LA    WKREGB,ZERO(WKREGB)  ZERO HI BYTE                        06750021
         LR    R6,WKREGB           SAVE OLDEST BUFFER                   06800021
         B     ABDMP050            GO CHECK BUFFER                      06850021
*** IF YES, THEN                                                        06900021
*** ALL BUFFERS HAVE BEEN FORMATTED. PRINT TRAILER,UNFREEZE GTF,        06950021
***                                  AND EXIT TO WHERE-TO-GO RTN        07000021
          USING TCBSECT,TCBREG     SET UP FOR TCB ADDRESSABILITY        07050021
ABDMP025 L     WKREG4,CVTPTR       GET CVT POINTER            AB  M0805 07060021
         L     WKREG4,0(WKREG4)    GET NEW/OLD POINTER        AB  M0805 07070021
         L     WKREG4,4(WKREG4)    GET CURRENT TCB POINTER    AB  M0805 07080021
         TM    TCBFLG1(WKREG4),TCBGTOFM  IS ABEND THE CALLER? AB  M0805 07100021
         BZ    ABDMP030            IF N, DONT ISSUE HOOK                07150021
         HOOK  EID=IHLMABON        IF YES, RESUME GTF TRACE             07200021
         NI    TCBFLG1(WKREG4),FF-TCBGTOFM  RESET FREEZE FLAG AB  M0805 07250021
ABDMP030 LA    R1,LOAD08           PREPARE CSECT-NAME PARM FOR XCTL     07300021
         B     XCTL                PROCEED TO NEXT LOAD OF ABDUMP       07350021
*** CHECK FOR ACTIVE BUFFER, SET UP TOTAL GTF REC LENGTH IN BUFFER      07400021
ABDMP040 L     WKREGB,BPXLINK      GET NEXT BUFFER                      07410021
         LA    WKREGB,ZERO(WKREGB) ZERO HI BYTE                         07420021
         CR    R6,WKREGB          DOES OLDEST=NEXT?                     07440021
         BE    ABDMP025           YES                                   07442021
ABDMP050 TM    BPXFLGS,BPXFULL+BPXSCED+BPXCURR  IS BUFFER IN USE        07450021
         BZ    ABDMP040            NO GO GET NEXT                       07500021
         L     R10,BPXPRLEN        GET BLOCK DESCRIPTOR WORD            07550021
         SRL   R10,SIXTN           RIGHT ALIGN LENGTH FIELD             07600021
         SH    R10,FOURDC          GET ONLY GTF TOTAL RECORDS LENGTH    07650021
         LA    R7,BPXLRLEN         GET ADDR 1ST REC IN BUFFER           07700021
ABDMP060 LTR   R10,R10             HAVE ALL RECORDS IN BUFFER BEEN DONE 07750021
         BNH   ABDMP040            YES                                  07800021
*** CHECK FOR GTF CONTROL REC                                           07850021
         CLI   PFXAID(R7),CNTRLREC IS THIS A CNTRL REC                  07900021
         BNE   ABDMP200            NO                                   07950021
         LA    R8,FOUR            INIT REG 8 FOR 2ND LOAD-CONTROL REC   08000021
         CLI   PFXFID(R7),TIMESTAM IS IT FOR TIMESTAMP                  08050021
         BE    ABDMP600           YES                                   08100021
         CLI   PFXFID(R7),LOSTCNT  IS IT FOR LOST EVENT CNT             08150021
         BE    ABDMP600           YES                                   08200021
ABDMP075 LA    R8,EIGHT           INIT REG 8 FOR 2ND LOAD-ERROR REC     08250021
       B       ABDMP600           GO XCTL                               08300021
*** TEST FOR VALID EID                                                  08350021
ABDMP200 LA    WK4,SIX(R7)         POINT TO EID- NO TIMESTAMP           08400021
         TM    HCTFLG3,HCTTIME     IS THERE A TIMESTAMP IN RECORD       08450021
         BZ    ABDMP205            NO                                   08500021
         LA    WK4,EIGHT(WK4)      YES UP PTR                           08550021
ABDMP205 LA    R15,EIDTABLE        GET ADDR EID LIST                    08600021
         LA    R0,EIDEND          POINT TO END OF TABLE                 08650021
ABDMP210 CR    R15,R0          IS TABLE END REACHED                     08700021
         BE    ABDMP075            YES, EID INVALID, PRINT ERR MSG      08750021
         CLC   ZERO(TWO,R15),ZERO(WK4)  DO EIDS MATCH                   08800021
         BE    ABDMP220            DO EIDS MATCH                        08850021
         LA    R15,FIVE(R15)       POINT TO NEXT EID                    08900021
         B     ABDMP210            GO CHECK EID                         08950021
*** A VALID EID HAS BEEN FOUND                                          09000021
ABDMP220 LA    WK4,TWO(WK4)        GET ADDR OF DATA IN RECORD           09050021
         ST    R15,ABDWORK2       SAVE ADDR OF EID AND LABEL            09100021
         ST    WK4,ABDWORK1        SAVE BEGIN OF DATA                   09150021
*** CHECK TRACE RECORD FOR ERROR -X'EEEE' IN DATA FIELD                 09200021
         CLC   ZERO(TWO,WK4),EES  IS RECORD BAD                         09250021
         BNE   ABDMP225            NO                                   09300021
         LA    R8,TWELV           SET UP FOR 2ND LOAD- EE REC           09350021
         LR    R5,R15             GET EID,LABEL FOR 2ND LOAD            09360021
         B     ABDMP600           GO XCTL                               09400021
*** REPLACE CHARACTER FIELDS **** OR N/A WITH ZEROS FOR FORMAT          09450021
ABDMP225 LA    R3,GTFLINE          GET ADDR GTF LAYOUT LINE             09500021
*** REGS 2 AND 3 HAVE BEEN INITIALIZED FOR FORMAT RTN                   09550021
***  GO FORMAT RECORD                                                   09600021
ABDMP240 BAL   R5,FORMAT           FORMAT 1ST HALF PSW                  09700021
         BAL   R5,FORMAT           FORMAT 2ND HALF PSW AND R15          09750021
         BAL   R5,FORMAT           FORMAT R0,R1, AND TCB                09800021
         L     R15,ABDWORK2       GET ADDR EID AND LABEL                09900021
         MVC   ABDLINE(THREE),TWO(R15)  MOVE IN LABEL                   09950021
         LA    R5,ABDMP280         GET ADDR FOR GO OUTPUT               10000021
         L     WK4,ABDWORK1        LOAD SAVED DATA ADDR                 10050021
*** CHANGE EID-DEPENDENT LABELS                                         10100021
         CLC   ZERO(TWO,R15),PGMEID IS IT PGM                           10150021
         BCR   EIGHT,R5            YES                                  10200021
         CLC   ZERO(TWO,R15),SVCEID IS IT SVC                           10250021
         BCR   EIGHT,R5            YES                                  10300021
         CLC   ZERO(TWO,R15),DSPEID IS IT DSP                           10350021
         BNE   ABDMP250            NO                                   10400021
         MVC   ABDLINE+TEN(THREE),NEWLAB  CHANGE PSW LABEL              10450021
         MVC   ABDLINE+NINT5(THREE),NEWLAB CHANGE TCB LABEL             10500021
         BR    R5                  GO OUTPUT                            10550021
ABDMP250 CLC   ZERO(TWO,R15),EXTEID  IS IT EXTERNAL                     10600021
         BNE   ABDMP260            NO                                   10650021
         CLC   TWENTY(FOUR,WK4),ASTERS  IS TQE  ****                    10700021
         BNE   ABDMP252      NO                                         10750021
         MVC   ABDLINE+ONE05(EIGHT),ASTERS   MOVE ****INTO RECORD       10800021
         B     ABDMP255           GO FINISH RECORD                      10850021
ABDMP252 CLC   TWENTY(FOUR,WK4),NOTAPPL   IS TQE  N/A                   10900021
         BNE   ABDMP255           NO                                    10950021
         MVC    ABDLINE+ONE05(EIGHT),NOTAPPL  MOVE N/A INTO RECORD      11000021
ABDMP255 MVC   ABDLINE+NINT5(THREE),TQE   CHANGE TCB LABEL              11050021
         BR    R5                  GO OUTPUT                            11100021
ABDMP260 CLC   SIXTN(FOUR,WK4),ASTERS    IS RQE TCB ****                11150021
         BNE   ABDMP262           NO                                    11200021
         MVC   ABDLINE+EIGHT3(EIGHT),ASTERS   MOVE **** INTO RECORD     11250021
         B     ABDMP265           GO FINISH RECORD                      11300021
ABDMP262 CLC   SIXTN(FOUR,WK4),NOTAPPL   IS RQE TCB N/A                 11350021
         BNE   ABDMP265           NO                                    11400021
         MVC   ABDLINE+EIGHT3(EIGHT),NOTAPPL  MOVE N/A INTO RECORD      11450021
ABDMP265 CLC   ZERO(TWO,R15),PCIEID IS IT PCI                           11500021
         BE    ABDMP270            YES                                  11550021
         TM    ONE(R15),F0         IS IT SIO1 OR SIO2                   11600021
         BNO   ABDMP275           NO, I/O EID                           11650021
ABDMP270 MVC   ABDLINE+TEN(TEN),CCDEVCAW  MOVE IN IO INFO               11700021
ABDMP275 MVC   ABDLINE+SEVENT3(SEVEN),RQETCB   MOVE IN RQE LABEL        11750021
         MVC   ABDLINE+FORT3(SIX),CSW        MOVE IN CSW LABEL          11800021
ABDMP280 BAL   R5,ABDOUT           GO OUTPUT FORMATTED RECORD           11850021
*** PUT OUT TIMESTAMP IF TIME OPTION CHOSEN                             11900021
ABDMP080 TM    HCTFLG3,HCTTIME     DOES TIMESTAMP EXIST FOR EACH RECORD 11950021
         BZ    ABDMP100            NO                                   12000021
* THE TIMESTAMP OUTPUT IS OF THE FORM SSSSS.TTTMMM -SECOND.MICROSEC     12010021
         MVC   ABDLINE(FOUR),TIMEDC     MOVE LABEL TO BUFFER            12020021
         MVC   ABDWORK1(EIGHT),PFXTOD(R7) GET TIME ON FULLWORD BNDRY    12030021
         TM    HCTFLG2,HCTTODCK         Q- TOD CLOCK                    12040021
         BO    ABDMP085                 YES, READY FOR CONVERSION       12050021
         SR    WK4,WK4                  NO, CONVERT TU TO MICROSECONDS  12060021
         L     R5,ABDWORK1+FOUR         GET TIME IN TU                  12070021
         M     WK4,TUCONV               1 TU IS 26.04 MICROSECONDS      12080021
         D     WK4,DECPOINT             CORRECT DECIMAL POINT           12090021
         SR    WK4,WK4                  ZERO OUT REMAINDER              12100021
         M     WK4,ADJUST               AVOID FIXED POINT OVERFLOW      12110021
         B     ABDMP090                GO CONVERT                       12120021
ABDMP085 LM    WK4,R5,ABDWORK1          GET TIME IN TOD CLOCK FORMAT    12130021
         SRDL  WK4,TWELV                SHIFT OUT UNUSED BITS           12140021
ABDMP090 D     WK4,SIXTYMIL            WK2 NOW HAS NUMBER OF SECONDS    12150021
*                                        IN MICROSECONDS AND R3 HAS     12160021
*                                        NUMBER OF MINUTES SINCE EPIC   12170021
         LR    R0,R5                    SAVE MINUTES                    12180021
         LR    R5,WK4                   MOVE SECONDS TO ODD REG         12190021
         LA    R3,ABDMP097              SET ADDRESS TO COME OUT OF LOOP 12200021
         LA    R8,ABDLINE+SEVENTN       ADDRESS OF END OF FIELD         12210021
         LA    R1,SIX                   SET LOOP CONTROL                12220021
ABDMP095 SR    WK4,WK4                  CLEAR EVEN REG FOR DIVIDE       12230021
         D     WK4,TENDC                CONVERT TO DECIMAL              12240021
         STC   WK4,ZERO(R8)             STORE IN BUFFER                 12250021
         OI    ZERO(R8),ZONE            CONVERT TO EBCDIC               12260021
         BCTR  R8,ZERO                  DECREMENT BUFFER POINTER        12270021
        BCT    R1,ABDMP095             LOOP CONTROL                     12280021
         BR    R3                       RETURN TO CALLER                12290021
ABDMP097 MVI   ZERO(R8),DOT             PUT DECIMAL POINT IN BUFFER     12300021
         BCTR  R8,ZERO                  DECREMENT BUFFER POINTER        12310021
         LR    R1,R5                    SAVE SECONDS                    12320021
         SR    WK4,WK4                  CLEAR EVEN REG FOR DIVIDE       12330021
         LR    R5,R0                    GET MINUTES                     12340021
         D     WK4,MINPRDAY             GET MINUTES LEFT IN DAY         12350021
         LR    R5,WK4                   SAVE MINUTES PER DAY            12360021
         SR    WK4,WK4                  CLEAR REG FOR MULTIPLY          12370021
         M     WK4,SIXTYDC              CONVERT TO SECONDS              12380021
         AR    R5,R1                    ADD SECONDS                     12390021
         LA    R1,FIVE                  SET COUNTER FOR LOOP            12400021
         BAL   R3,ABDMP095              CONVERT SECONDS TO EBCDIC       12410021
ABDMP087 BAL   R5,ABDOUT          GO OUTPUT TIMESTAMP                   12550021
*** UPDATE POINTER TO NEXT RECORD AND GO GET NEXT RECORD                12600021
ABDMP100 SH    R10,ZERO(R7)        GET REMAINING LENGTH OF RECS IN BUFF 12650021
         AH    R7,ZERO(R7)         POINT TO NEXT RECORD                 12700021
         B     ABDMP060            GO TEST RECORD                       12750021
ABDMP600 LA    R1,LOADOM          POINT TO LOAD NAME                    12800021
XCTL     LA    R15,ABDWORK3       SET UP FOR XCTL                       12850021
         XCTL  EPLOC=(R1),SF=(E,(R15))    XCTL TO IGC0M05A              12900021
*********************************************************************   12950021
*        FORMAT ROUTINE                                                 13000021
*********************************************************************   13050021
FORMAT   LA    R8,ABDLINE              GET ADDR OF OUTPUT BUFFER        13100021
         SR    R1,R1                                                    13150021
         IC    R1,0(R3)   GET SPACING FACTOR                            13200021
         AR    R8,R1                   UPDATE THE POINTERS              13250021
         LA    R3,1(R3)                                                 13300021
FORMAT01 CLI   0(R3),X'FF'             IS THIS A DELEMETER              13350021
         BC    8,FORMAT3               YES,BRANCH                       13400021
         SR    RE,RE                                                    13450021
         SR    RF,RF                                                    13500021
         SR    R0,R0                                                    13550021
         SR    R1,R1                                                    13600021
         IC    RE,0(R3)                GET FIRST CONTROL BYTE           13650021
         IC    R0,1(R3)                GET SECOND CONTROL BYTE          13700021
         SRDL  RE,4                    RE=SIZE OF LABEL-1               13750021
         SRL   RF,28                   RF=SIZE OF FIELD-1               13800021
         SRDL  R0,4                    R0=UPDATE REG 4 FACTOR           13850021
         SRL   R1,28                   R1=DIST BETWEEN LABEL AND FIELD  13900021
         AR    WK4,R0                   BUMP THE POINTER                13950021
         EX    RE,MOVE1                                                 14000021
         AR    R1,RE                                                    14050021
         LA    R8,1(R1,R8)             UPDATE POINTER                   14100021
         EX    RF,MOVE2                                                 14150021
         UNPK  ABDWORK4(9),ABDWORK4(5)                                  14200021
         TR    ABDWORK4(8),HEXTAB-240                                   14250021
         LA    RF,1(RF,RF)    RF =(SIZE OF UNPACKED FIELD)- 1           14300021
         EX    RF,MOVE3                                                 14350021
         LA    R8,5(RF,R8)  POINT TO FIRST BLANK FOLLOW. FIELD          14400021
         LA    R3,3(RE,R3)   UPDATE PTR TO LAYOUT LINE                  14450021
         B     FORMAT01       FORMAT NEXT FIELD                         14500021
FORMAT3  LA    R3,1(R3)                                                 14550021
         BR     R5             RETURN TO CALLER                         14600021
*                                                                       14650021
MOVE1    MVC   0(1,R8),2(R3)           MOVE LABEL TO OUTPUT BUFFER      14700021
MOVE2    MVC   ABDWORK4(1),0(WK4)       MOVE PACKED FIELD TO WORK AREA  14750021
MOVE3    MVC   0(1,R8),ABDWORK4        UNPACKED FILED TO OUTPUT BUFFER  14800021
HEXTAB   DC    C'0123456789ABCDEF'                                      14850021
***                                                                     14900021
***   G T F   C O N S T A N T S                                         14950021
***                                                                     15000021
SIXTYMIL DC    F'60000000'        DIVIDER FOR MINUTES AND SECONDS       15006021
TENDC    DC    F'10'              DIVIDER FOR HEX TO DECIMAL            15012021
ADJUST   DC    F'100'             CONSTANTS FOR TIMER                   15018021
DECPOINT DC    F'100000000'                 UNIT CONVERSION             15024021
TUCONV   DC    F'26041667'                            TO MICROSECONDS   15030021
MINPRDAY DC    F'1440'                  MINUTES PER DAY                 15036021
SIXTYDC  DC    F'60'              SECONDS PER MINUTE                    15042021
TRACHEAD DC    C'-GTF TRACE TABLE' HEADER FOR GTF TRACE                 15050021
EES      DC    X'EEEE'             INDICATOR OF BAD RECORD              15100021
NEWLAB  DC    C'NEW'               NEW LABEL                            15150021
TQE      DC    C'TQE'              TQE LABEL                            15200021
CCDEVCAW DC    C'CC/DEV/CAW'       IO LABEL                             15250021
RQETCB   DC    C'RQE TCB'          RQETCB LABEL                         15300021
CSW      DC    C'CSW   '              CSW LABEL                         15350021
ASTERS   DC    C'********'         INDICATES ERROR IN GETTING TCB ADDR  15400021
NOTAPPL  DC    C'N/A     '         INDICATES TCB ADDR NOT APPLICABLE    15450021
FOURDC   DC    H'4'                CONSTANT 4                           15500021
LOADOM   DC    C'IGC0M05A'         NAME OF 2ND GTF TRACE FORMAT LOAD    15550021
LOAD08   DC    C'IGC0405A'         NAME OF ABDUMP LOAD 8                15600021
***                                                                     15650021
***  GTF TRACE TABLE LAYOUT LINE                                        15700021
***                                                                     15750021
GTFLINE  DC    AL1(10)             DISPLACEMENT TO PSW LABEL            15800021
         DC    X'6305'             CONTROL BYTES FOR FORMAT RTN         15850021
         DC    C'OLD PSW'          1ST LABEL                            15900021
         DC    X'FF'               RETURN,MORE THAN 4 BYTES TO FORMAT   15950021
         DC    AL1(30)             DISPLACEMENT TO 2ND HALF PSW         16000021
         DC    X'0340'             CONTROL BYTES                        16050021
         DC    C' '                BLANK                                16100021
         DC    X'5343'             CONTROL BYTES                        16150021
         DC    C'R15/R0'           2ND LABEL                            16200021
         DC    X'FF'               RETURN, MORE THAN 4 BYTES TO FORMAT  16250021
         DC    AL1(60)             DISPLACEMENT TO R0                   16300021
         DC    X'0340'             CONTROL BYTES                        16350021
         DC    C' '                BLANK                                16400021
         DC    X'1348'             CONTROL BYTES                        16450021
         DC    C'R1'              3RD LABEL                             16500021
         DC    X'6343'             CONTROL BYTES                        16550021
         DC    C'OLD TCB'          4TH LABEL                            16600021
         DC    X'FF'               END OF GTF TRACE LINE                16650021
***  THESE EIDS AND THEIR LABELS MUST BE KEPT CONTIGUOUS                16700021
EIDTABLE EQU   *                   ADDR EID TABLE                       16750021
PCIEID   DC    X'2FDF'             PCI EID                              16800021
         DC    C'PCI'              PCI LABEL                            16850021
SVCEID   DC    X'3FFF'             SVC EID                              16900021
         DC    C'SVC'              SVC LABEL                            16950021
DSPEID   DC    X'4FE7'             DSP EID                              17000021
         DC    C'DSP'              DSP LABEL                            17050021
IOEID1   DC    X'5FEE'             I/O EID1                             17100021
         DC    C'I/O'              I/O LABEL                            17150021
IOEID2   DC    X'5FEF'             I/O EID2                             17200021
         DC    C'I/O'              I/O LABEL                            17250021
SIOEID1  DC    X'5FF0'             SIO EID1                             17300021
         DC    C'SIO'              SIO LABEL                            17350021
PGMEID   DC    X'DFFD'             PGM EID                              17500021
         DC    C'PGM'              PGM LABEL                            17550021
EXTEID   DC    X'DFFE'             EXT EID                              17600021
         DC    C'EXT'              EXT LABEL                            17650021
EIDEND   EQU   *                   END OF TABLE ADDR                    17700021
TIMEDC   DC    C'TIME'             TIME LABEL                           17850021
***                                                                     18150021
          IHBMFTAB                                                      18200021
***                                                                     18250021
CMTDSECT CMT                                                            18300021
***                                                                     18350021
HCTDSECT HCT                                                            18400021
***                                                                     18450021
PARDSECT DSECT                                                          18500021
PID      DS    1C                      ID NUMBER LT 128                 18550021
         DS    1C                      RESERVED                         18600021
PFLAGS   DS    2C                      OPTION FLAGS                     18650021
PDCBPTR  DS    1F                      DCB ADDRESS                      18700021
         DS    1F                      IGNORED IN SSS SYSTEM            18750021
PSNAPPTR DS    1F                      ADDRESS OF SNAPSHOT LIST         18800021
ABDAREA  DSECT                                                          18850021
ABDSAVE  DS    18F           SAVE AREA                                  18900021
ABDECB   DS    1F            DECB-ECB                                   18950021
ABDTYPE  DS    1H            TYPE FIELD                                 19000021
ABDLEN   DS    1H            LENGTH FIELD                               19050021
ABDDCB   DS    1F            POINTER TO DCB                             19100021
ABDPTR   DS    1F            AREA ADDRESS                               19150021
ABDSTAT  DS    1F            POINTER TO STATUS INDICATORS               19200021
*                                                                       19250021
ABDCTR1  DS    1H            LINE CTR                                   19300021
ABDCTR2  DS    1H            PAGE CTR                                   19350021
*                                                                       19400021
ABDOUT   DS    55F           220 BYTES FOR OUTPUT ROUTINE               19450021
*                                                                       19500021
ABDPARA  DS    1F   PTR TO PARAMETER LIST                               19550021
ABDRSV   DS    1F         SAVE 'LAST' TRACE ENTRY                       19600021
ABDWORK3 DS    1C       FLAG BYTE                                       19650021
ABDWORK4 DS    11C      UNPACK AREA                                     19700021
ABDWORK1 DS    1D       CONVERT TO DEC., REG SAVE                       19750021
ABDWORK2 DS    1F       REG SAVE, CONTIG. WITH ABDWORK1                 19800021
ABDPTRS  DS    3F   BUFFER PTRS USED BY OUTPUT ROUTINE                  19850021
*                                                                       19900021
*                            OUTPUT BUFFER                              19950021
ABDPHY   DS    2C            PHYSICAL RECORD LENGTH                     20000021
ABDSRC1  DS    2C            SYSTEM-RESERVED CHAR                       20050021
ABDLOG   DS    2C            LOGICAL REC LENGTH                         20100021
ABDSRC2  DS    2C            SYSTEM RESERVED CHAR                       20150021
ABDCC    DS    1C            CARRIAGE CONTROL CHARACTER                 20200021
ABDLINE  DS    CL32          120 CHAR PRINT LINE                        20250021
         DS    CL32                                                     20300021
         DS    CL32                                                     20350021
         DS    CL24                                                     20400021
         DS    7C                  RESERVED                             20450021
LIMIT    DS    1F                  SAVE UPPER PARTITION ADDRESS         20650021
***                                                                     20700021
BPXDSECT BPX                                                            20750021
         END                                                            20800021
