 TITLE 'IEAAAT00,IGC0004B,ATTACH'                                       00020000
*041400,042800-045600,057000                                      M3319 00030019
*STATUS: CHANGE LEVEL 003                                               00040019
*                                                                       00060000
*                                                                       00080000
*    FUNCTION: THE ATTACH ROUTINE GIVES CONTROL TO A PROGRAM NAMED BY   00100000
*    THE ATTACHING PROGRAM. CONTROL IS GIVEN IN SUCH A MANNER AS TO     00120000
*    CAUSE CONTROL TO BE RETURNED TO THE ATTACH ROUTINE WHEN THE        00140000
*    ATTACHED PROGRAM COMPLETES. ATTACH THEN POSTS AN EVENT CONTROL     00160000
*    BLOCK IF THIS OPTION WAS SELECTED BY THE ATTACHING PROGRAM. ATTACH 00180000
*    THEN GIVES CONTROL TO AN ETXR EXIT ROUTINE IF THIS OPTION WAS      00200000
*    SELECTED BY THE ATTACHING PROGRAM. OTHERWISE ATTACH RETURNS        00220000
*    CONTROL TO THE ATTACHING PROGRAM.                                  00240000
*                                                                       00260000
*                                                                       00280000
*    ENTRY POINTS -                                                     00300000
*    ATTACH IS A TYPE III SVC ROUTINE. ATTACH IS ENTERED IN SUPERVISOR  00320000
*    STATE, WITH SUPERVISOR PROTECTION KEY, AND WITH INPUT/OUTPUT AND   00340000
*    EXTERNAL INTERRUPTS DISABLED. THERE ARE TWO ENTRY POINTS -         00360000
*    (1) WHEN THE ATTACH SVC INSTRUCTION (SVC 42) IS EXECUTED, ATTACH   00380000
*        IS ENTERED AT ENTRY POINT NAME IGC042                          00400000
*    (2) WHEN THE ATTACHED PROGRAM COMPLETES, ATTACH IS ENTERED AT      00420000
*        ENTRY POINT NAME IEA0AT01. THIS ENTRY POINT IS DEFINED ONLY    00440000
*        WITHIN THE ATTACH MODULE.                                      00460000
*                                                                       00480000
*                                                                       00500000
*    INPUT -                                                            00520000
*    (1) WHEN THE ATTACH SVC INSTRUCTION IS EXECUTED, REGISTER 15       00540000
*        CONTAINS THE ADDRESS OF THE ATTACH SUPERVISOR PARAMETER LIST.  00560000
*    (2) WHEN THE ATTACHED PROGRAM COMPLETES, REGISTER 15 CONTAINS A    00580000
*        COMPLETION CODE WHICH ATTACH PUTS IN THE ECB (IF THIS OPTION   00600000
*        WAS SPECIFIED IN THE ATTACH MACRO-INSTRUCTION).                00620000
*                                                                       00640000
*                                                                       00660000
*    EXITS -                                                            00680000
*    (1) ATTACH GIVES CONTROL TO THE ATTACHED PROGRAM BY EXECUTING A    00700000
*        LPSW INSTRUCTION. BYTES 0 THROUGH 4 OF THIS PSW ARE TAKEN FROM 00720000
*        THE PSW THE ATTACHING PROGRAM HAD WHEN THE ATTACH SVC          00740000
*        INSTRUCTION WAS EXECUTED.                                      00760000
*    (2) ATTACH GIVES CONTROL TO EITHER ATTACHING PROGRAM OR ETXR       00780000
*        PROGRAM BY EXECUTING AN SVC EXIT (SVC 03) INSTRUCTION.         00800000
*                                                                       00820000
*                                                                       00840000
*    OUTPUT -                                                           00860000
*    (1) WHEN ATTACH GIVES CONTROL TO THE ATTACHED PROGRAM,             00880000
*        REGISTERS 0 THROUGH 12 ARE THE SAME AS WHEN THE ATTACH SVC     00900000
*                    INSTRUCTION WAS EXECUTED.                          00920000
*        REGISTER 13 CONTAINS THE ADDRESS OF A NEW 72 BYTE SAVE AREA.   00940000
*        REGISTER 14 CONTAINS THE ADDRESS OF AN SVC EXIT INSTRUCTION    00960000
*                    (INTERNAL SUPERVISOR LOCATION).                    00980000
*        REGISTER 15 CONTAINS THE ADDRESS OF THE ATTACHED PROGRAM'S     01000000
*                    ENTRY POINT.                                       01020000
*    (2) WHEN THE ATTACHING PROGRAM RECEIVES CONTROL FROM ATTACH,       01040000
*        REGISTER 0 IS THE SAME AS WHEN THE ATTACH SVC INSTRUCTION WAS  01060000
*                    EXECUTED.                                          01080000
*        REGISTER  1 CONTAINS ZERO.                                     01100000
*        REGISTERS 2 THROUGH 13 ARE THE SAME AS WHEN THE ATTACH SVC     01120000
*                    INSTRUCTION WAS EXECUTED.                          01140000
*        REGISTER 14 I, UNPREDICTABLE.                                  01160000
*        REGISTER 15 IS UNPREDICTABLE.                                  01180000
*    (3) WHEN THE ETXR PROGRAM RECEIVES CONTROL FROM ATTACH,            01200000
*        REGISTER  0 IS THE SAME AS WHEN THE ATTACH SVC INSTRUCTION WAS 01220000
*                    EXECUTED.                                          01240000
*        REGISTER  1 CONTAINS ZERO.                                     01260000
*        REGISTERS 2 THROUGH 12 ARE THE SAME AS WHEN THE ATTACH SVC     01280000
*                    INSTRUCTION WAS EXECUTED.                          01300000
*        REGISTER 13 CONTAINS THE ADDRESS OF A NEW 72 BYTE SAVE AREA.   01320000
*        REGISTER 14 CONTAINS THE ADDRESS OF AN SVC EXIT INSTRUCTION    01340000
*                    (INTERNAL SUPERVISOR LOCATION).                    01360000
*        REGISTER 15 CONTAINS THE ADDRESS OF THE ETXR PROGRAM'S ENTRY   01380000
*                    POINT.                                             01400000
*    (4) WHEN THE ATTACHING PROGRAM RECEIVES CONTROL FROM THE ETXR      01420000
*        PROGRAM, THE REGISTERS ARE AS DESCRIBED IN (2).                01440000
*                                                                       01460000
*                                                                       01480000
*    EXTERNAL REFERENCES -                                              01500000
*    ATTACH REFERENCES THE FOLLOWING ENTRIES IN THE COMMUNICATIONS      01520000
*    VECTOR TABLE -                                                     01540000
*    SYMBOLIC OFFSET - CVTTCBP,  FROM WHICH IT OBTAINS THE ADDRESS OF   01560000
*                                THE CURRENTLY DISPATCHED TCB.          01580000
*    SYMBOLIC OFFSET - CVTFINCH, THE ADDRESS OF THE FINCH ENTRY POINT.  01600000
*    SYMBOLIC OFFSET - CVTEXIT,  THE ADDRESS OF THE EXIT  ENTRY POINT.  01620000
*    ATTACH REFERENCES THE FOLLOWING ENTRIES IN THE TCB -               01640000
*    SYMBOLIC OFFSET - TCBFSA,   THE ADDRESS OF THE FIRST 72 BYTE SAVE  01660000
*                                AREA.                                  01680000
*    SYMBOLIC OFFSET - TCBLLS,   THE ADDRESS OF THE FIRST REQUEST BLOCK 01740000
*                                ON THE LOAD LIST.                      01760000
*    SYMBOLIC OFFSET - TCBRBP,   THE ADDRESS OF THE FIRST REQUEST BLOCK 01780000
*                                ON THE REQUEST BLOCK QUEUE.            01800000
*    ATTACH REFERENCES THE FOLLOWING ENTRIES IN THE ATTACH SUPERVISOR   01820000
*    PARAMETER LIST -                                                   01840000
*    SYMBOLIC OFFSET - SPLDCB,   THE ADDRESS OF THE DCB.                01860000
*    SYMBOLIC OFFSET - SPLECB,   THE ADDRESS OF THE ECB.                01880000
*    SYMBOLIC OFFSET - SPLEP,    THE ADDRESS OF THE NAME OF THE PROGRAM 01900000
*                                TO BE ATTACHED.                        01920000
*    SYMBOLIC OFFSET - SPLETXR,  THE ADDRESS OF THE ETXR ENTRY POINT.   01940000
*    ATTACH REFERENCES THE SVC INTERRUPT NEW PSW AT DECIMAL MACHINE     01960000
*    ADDRESS 96.                                                        01980000
*    ATTACH USES 8 BYTES BEGINNING AT DECIMAL MACHINE ADDRESS 8 AS      02000000
*    TEMPORARY STORAGE IN WHICH TO BUILD A PSW.                         02020000
*                                                                       02040000
*                                                                       02060000
*    ERROR MESSAGES: NONE                                               02080000
*                                                                       02100000
*                                                                       02120000
*    TABLES/WORK AREAS -                                                02140000
*    ATTACH MAY USE PROBLEM PROGRAM MAIN STORAGE FOR -                  02160000
*    . THE ATTACHED PROGRAM'S REQUEST BLOCK                             02180000
*    . THE 72 BYTE SAVE AREA FOR THE ATTACHED PROGRAM                   02200000
*    . THE ETXR PROGRAM'S REQUEST BLOCK.                                02220000
*    ATTACH USES 8 BYTES BEGINNING AT DECIMAL MACHINE ADDRESS 8 AS      02240000
*    TEMPORARY STORAGE IN WHICH TO BUILD A PSW.                         02260000
*                                                                       02280000
*                                                                       02300000
*    OPERATION: THE ATTACH ROUTINE SEARCHES THE LOAD LIST AND THE LPA   02320019
*    IF IT IS IN THE SYSTEM FOR A USABLE COPY OF THE ATTACHED PROGRAM.  02340019
*    IF ONE IS NOT FOUND, ATTACH USES FINCH TO BRING A FRESH COPY INTO  02360000
*    MAIN STORAGE. IN EITHER CASE ATTACH INSERTS THE ATTACHED PROGRAM'S 02380000
*    REQUEST BLOCK ON THE REQUEST BLOCK QUEUE. ATTACH THEN GIVES        02400000
*    CONTROL TO THE ATTACHED PROGRAM USING THE LPSW INSTRUCTION. AT     02420000
*    THIS POINT THE REQUEST BLOCK QUEUE HAS THE FOLLOWING STRUCTURE -   02440000
*    . REQUEST BLOCK FOR THE ATTACHED PROGRAM                           02460000
*    . REQUEST BLOCK FOR ATTACH                                         02480000
*    . REQUEST BLOCK FOR THE ATTACHING PROGRAM.                         02500000
*    WHEN THE ATTACHED PROGRAM COMPLETES, THE ATTACH ROUTINE IS         02520000
*    DISPATCHED AND POSTS THE EVENT CONTROL BLOCK IF THIS OPTION WAS    02540000
*    SPECIFIED. IF THE ATTACHING PROGRAM HAS SPECIFIED AN ETXR EXIT     02560000
*    ROUTINE, ATTACH INSERTS A REQUEST BLOCK FOR THE EXIT ROUTINE ON    02580000
*    THE REQUEST BLOCK QUEUE. WHEN THE ATTACH ROUTINE COMPLETES,THE     02600000
*    ETXR EXIT PROGRAM IS DISPATCHED, IF THIS OPTION WAS SPECIFIED.     02620000
*    WHEN THE ETXR EXIT ROUTINE COMPLETES, THE ATTACHING PROGRAM IS     02640000
*    DISPATCHED.                                                        02660000
*                                                                       02680000
*                                                                       02700000
*    REMARKS -     CERTAIN UNIQUE SEPARATOR CARDS ARE USED THROUGH OUT  02720000
*              THE ASSEMBLY,AS FOLLOWS:                                 02740000
*              1.  THE FOLLOWING CARD PRECEDES AND SUCCEEDS A           02760000
*              CONDITIONAL ASSEMBLY INSTRUCTION.                        02780000
*CCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCC 02800000
*              2.  THE FOLLOWING CARD PRECEDES AND SUCCEEDS A           02820000
*              TEMPORARY OR DEBUGGING INSTRUCTION OR SET OF             02840000
*              INSTRUCTIONS.                                            02860000
*TTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTT 02880000
*              3.  THE FOLLOWING CARD PRECEDES AND SUCCEEDS A           02900000
*              SEQUENCE OF 'DC-ORG' OPERATIONS REQUIRED TO SIMULATE     02920000
*              INSTRUCTIONS WITH ADDRESSES AS EXTERNAL SYMBOLS WHERE    02940000
*              THESE SYMBOLS ARE KNOWN TO BE WITHIN THE FIRST 4095      02960000
*              BYTES OF THE MACHINE.                                    02980000
*XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX 03000000
         EJECT                                                          03020000
IGC042   START 0                                                        03040000
*0831                                                              STAE 03050017
ABSLOC   EQU   8                                                        03060000
XRBNM    EQU   0                                                        03080000
XRBSZ    EQU   8                                                        03100000
XSTAB    EQU   10                                                       03120000
XRBEP    EQU   12                                                       03140000
XRBPSW   EQU   16                                                       03160000
XRBWT    EQU   28                                                       03180000
XRBLNK   EQU   28                                                       03200000
XRBREG   EQU   32                                                       03220000
CVECTCB  EQU   0                                                        03240000
CVTDISP  EQU   136                                                      03260000
CVTFNCH  EQU   76                                                       03280000
CVTEXIT  EQU   80                                                       03300000
CVTQCDSR EQU   184                 LPAQSEARCH ADDRESS              LPA  03310018
EXIT     EQU   3                                                        03320000
OLD      EQU   4                                                        03340000
CVEC     EQU   16                                                       03360000
TCBRBP   EQU   0                                                        03380000
TCBLLS   EQU   36                                                       03400000
TCBNSTAE EQU   160                                                 STAE 03430017
J0       EQU   0                                                        03440000
J1       EQU   1                                                        03460000
J2      EQU   3                                                         03480000
J3      EQU   2                                                         03500000
J4      EQU   5                                                         03520000
J5      EQU   4                                                         03540000
J6       EQU   6                                                        03560000
J7       EQU   7                                                        03580000
J8       EQU   8                                                        03600000
J9       EQU   9                                                        03620000
JA       EQU   10                                                       03640000
JB       EQU   11                                                       03660000
JC       EQU   12                                                       03680000
JD       EQU   13                                                       03700000
JE       EQU   14                                                       03720000
JF       EQU   15                                                       03740000
TCBFSA   EQU   113                                                      03760000
SPLDCB   EQU   4                                                        03780000
SPLECB   EQU   8                                                        03800000
SPLETXR  EQU   20                                                       03820000
SPLEP    EQU   0                                                        03840000
SVCNPSW  EQU   96                                                       03860000
RECRSBIT EQU   X'80'                                               STAE 03866017
RETCODE4 EQU   4                                                   STAE 03872017
         SPACE 4                                                        03880000
         DS    0D                                                       03900000
         BALR  JE,0                                                     03920000
         USING *,JE                                                     03940000
ENTRY   L     J2,CVEC                                                   03960000
         L     J3,CVECTCB(J2)           J3 -PTR TO TCB                  03980000
         L     J3,OLD(J3)               PTR TO CURR T C B               04000000
         L     JA,TCBRBP(J3)            JA -PTR TO ATTACH'S SVRB        04020000
*                                       JF -PTR TO SUPV PARAMETER LIST  04040000
         L     JB,XRBLNK(JA)            JB -PTR TO ATTACHOR'S PRB       04060000
         TM    TCBNSTAE(J3),RECRSBIT   WAS ATTACH ISSUED IN STAE   STAE 04063017
         BZ    NOSCB                   ROUTINE--IF NOT,BRANCH      STAE 04066017
         LA    JF,RETCODE4             IF SO, SET RETURN CODE 4    STAE 04069017
         SVC   EXIT                    AND RETURN TO ATTACHOR.     STAE 04072017
NOSCB    DS    0H                      ACCEPT REQUEST AND CONTINUE STAE 04075017
         L     J9,TCBLLS(J3)           CHECK LOAD LIST FOR PROGRAM.     04080000
         L     J1,SPLEP(JF)             PTR TO REQ NAME                 04100000
XXL21    LTR   J9,J9                    J9 -PTR TO LOAD LIST CHAIN      04120000
         BC    8,XGETCOPY               IF 0 NEED A NEW COPY      M3319 04140019
         LA    JC,8(J9)                 JC -PTR TO NAME FIELD OF LOADED 04160000
         CLC   XRBNM(8,JC),0(J1)        PROGRAM ID = REQ ID             04180000
         BC    8,XATTACH1               YES SEE IF ACTIVE               04200000
         L     J9,0(J9)                 J9 -CHANGE J9 TO PT TO NEXT     04220000
         BC    15,XXL21                 LOADED PROGRAM AND CONTINUE     04240000
         SPACE 4                                                        04260000
XGETCOPY EQU   *                                                   LPA  04561018
         L     J7,CVEC             LOAD CVT PTR                    LPA  04562018
         TM    116(J7),X'40'       IS SYSTEM PCP                   LPA  04563018
         BC    1,XFINCH            YES,BYPASS LPA CODE              LPA 04564018
         L     J7,CVTQCDSR(J7)     LOAD LPA SEARCH RTNE ADDRESS    LPA  04565018
         LTR   J7,J7               IS LPA ON SYSTEM?               LPA  04566018
         BC    8,XFINCH            IF NOT, GET NEW COPY            LPA  04567018
         LR    J6,JF               ELSE SAVE REGS OVER SEARCH      LPA  04568018
         LR    J4,JA                                               LPA  04569018
         LR    J5,JB                                               LPA  04570018
         L     JC,0(JF)            LOAD PTR TO REQUESTED NAME      LPA  04571018
         SR    J0,J0               SET SUBPOOL REG FOR LPA SEARCH M4928 04571421
         LA    J7,6(J7)            BR TO 2 INSTRUCTIONS AFTER EP  M4928 04572021
         BALR  JD,J7               BRANCH TO SEARCH ROUTINE        LPA  04573018
         B     FOUND                                                LPA 04574018
         TM    ZERO,RECRSBIT       SET C.C. TO 0                   LPA  04575018
         B     CONTINUE            BRANCH AROUND FOUND CODE        LPA  04576018
FOUND    TM    ERRCD,RECRSBIT      SET CC TO 1                     LPA  04577018
CONTINUE LR    JC,JA               RESTORE REGS. JC MUST HOLD      LPA  04578018
         LR    JA,J4               NEW LPRB NAME PTR IF FOUND      LPA  04579018
         LR    JF,J6                                               LPA  04580018
         LR    JB,J5                                               LPA  04581018
         BC    7,XQRB              IF FOUND C.C.,AVOID FINCH       LPA  04582018
XFINCH   MVC   XRBREG+64(8,JA),SPLEP(JF)  FINCH PARM LIST          LPA  04583018
         STM   JA,JF,XRBREG+72(JA)     SAVE JA, JB, JE AND JF.          04600000
         LR    J4,JA                                                    04620000
         LR    J5,J3                                                    04640000
         LR    J3,JB                                                    04660000
         L     J7,CVTFNCH(J2)                                           04680000
         BALR  J8,J7                                                    04700000
         USING *,J8                                                     04720000
         DC    X'0000'                                                  04740000
         TM    XSTAB(JA),X'F0'          TEST  L R B                     04760000
         BC    12,SAVE                  IF NOT CONTINUE                 04780000
         L     J1,ERRCD                 L R B  ERROR CODE               04800000
         ABEND (1)                                                      04820000
SAVE     ST    JA,XRBREG+80(J4)         SAVE ATTACHED RB IN REG JC SLOT 04840000
         LA    JA,IEA0AT01             INITIALIZE ATTACH SVRB RESUME    04860000
         ST    JA,XRBPSW+4(J4)         PSW FOR ENTRY FROM DISPATCHER.   04880000
         MVC   XRBPSW(4,J4),SVCNPSW    GO TO DISPATCHER TO DISPATCH ANY 04900000
         L     JA,CVTDISP(J2)          IRB'S WHICH MAY HAVE BEEN        04920000
         BCR   15,JA                    SCHED. WHILE FINCH HAD CONTROL  04940000
         DROP  J8                                                       04960000
         SPACE 4                                                        04980000
IEA0AT01 LR    J3,J5                   RESTORE J3, PTR TO CURRENT TCB.  05000000
         LM    JA,JF,XRBREG+72(J4)     RESTORE JA, JB, JC, JE AND JF.   05020000
XQRB     ST    JA,XRBLNK(JC)           ENQUEUE ATTACHED RB AFTER SVRB.  05040000
         MVI   XRBWT(JC),0              ZERO WAIT COUNT                 05060000
         OI    XSTAB+1(JC),X'40'       TURN ON THE ACTIVE BIT.          05080000
         MVC   XRBREG+64(16,JA),SPLECB(JF) SAVE SPL FOR POSSIBLE ETXR.  05100000
         ST    JC,TCBRBP(J3)            TCB POINTS TO ATTACHED RB.      05120000
         L     J0,REQ72                 GET 72 BYTES FOR SAVE AREA      05140000
         GETMAIN R,LV=(0)              FOR ATTACHED PROGRAM.            05160000
         XC    0(72,J1),0(J1) .    ZERO SAVE AREA                A36199 05170020
         LR    JD,J1                    PLACE PTR TO SAVE AREA IN REG13 05180000
         MVC   XRBREG+61(3,JA),TCBFSA(J3) SAVE OLD SAVE AREA PTR IN 15  05200000
*                                            SAVE AREA IN SVRB          05220000
         IC    J0,TCBFSA-1(J3)    SAVE TCB ID                           05240000
         ST    J1,TCBFSA-1(J3)          PLACE PTR TO SAVE AREA IN TCB   05260000
         STC   J0,TCBFSA-1(J3)    RESTORE TCB ID                        05280000
         LA    J1,IEA0AT02             INITIALIZE ATTACH SVRB RESUME    05300000
         ST    J1,XRBPSW+4(JA)         PSW FOR ENTRY FROM DISPATCHER    05320000
         MVC   XRBPSW(4,JA),SVCNPSW    WHEN ATTACHED RB EXITS.          05340000
         MVC   ABSLOC+5(3,0),XRBEP+1(JC) BUILD PSW IN LOWER CORE.       05360000
         MVC   ABSLOC(5,0),XRBPSW(JB)  INITIALIZE 1ST 5 BYTES OF PSW    05380000
*                                      FROM ATTACHING TASK'S PSW.       05400000
         MVC   XRBREG+72(5,JA),XRBPSW(JB) SAVE PSW FOR POSSIBLE ETXR    05420000
         LA    JE,CVTEXIT(J2)           SET REG 14 TO EXIT SVC ADDRESS  05440000
         LR    JF,JA                   MOVE REG JA TO ALLOW RESTORE.    05460000
         LM    J0,JC,XRBREG(JF)        RESTORE REGS 0 THROUGH 12.       05480000
         ST    JD,XRBREG+4(JF)         SAVE ADDRESS OF NEW SAVE AREA IN 05500000
*                                      THE ATTACH SVRB REG 1 SAVE AREA. 05520000
         L     JF,ABSLOC+4             INITIALIZE REG 15 WITH ENTRY PT. 05540000
         LPSW  ABSLOC                  LOAD PSW FROM LOWER CORE.        05560000
         SPACE 4                                                        05580000
XATTACH1 TM    XSTAB(JC),X'F0'          TEST  L R B                     05600000
         BC    1,ERROR                  L R B , ERROR                   05620000
         TM    XSTAB+1(JC),X'40'        TEST ACTIVE                     05640000
         BC    8,XQRB                                                   05660000
         TM    XSTAB(JC),X'C0'         TEST MINOR.                      05680000
         BC    8,XGETCOPY                                         M3319 05700019
         LR    J7,JF                    SAVE REG 7 USED BY GETMAIN      05720000
         L     J0,REQ32                 GET 32 BYTES FOR PRB            05740000
         GETMAIN R,LV=(0)                                               05760000
         LR    JF,J7                    RESTORE REG 15                  05780000
         XC    0(32,J1),0(J1)            CLEAR THE RB SPACE             05800000
         MVC   XRBNM(8,J1),XRBNM(JC)   INITIALIZE THE NAME FIELD.       05820000
         MVC   XRBSZ+1(3,J1),XPRBBITS  INITIALIZE XRBSZ AND XSTAB FIELD 05840000
         MVC   XRBEP+1(3,J1),XRBEP+1(JC) INITIALIZE THE ENTRY POINT.    05860000
         LR    JC,J1                    MAKE ATTEE PTR PT TO NEW IRB    05880000
*                                       ATTEE PTR IS REG JC             05900000
         BC    15,XQRB                                                  05920000
         SPACE 4                                                        05940000
*        IEA0AT01 IS THE ENTRY POINT TO THE ATTACH ROUTINE UPON EXIT    05960000
*                 FROM THE ATTACHED PROGRAM.                            05980000
IEA0AT02 BALR  JE,0                    ESTABLISH ADDRESSABILITY.        06000000
        LA    J2,*-ENTRY                                                06020000
        SLR   JE,J2                                                     06040000
         L     J2,CVEC                  GET PTR TO COMM VECTOR          06060000
         L     J6,CVECTCB(J2)                                           06080000
         L     J6,OLD(J6)               J6 IS PTR TO CURRENT TCB        06100000
         L     J5,TCBRBP(J6)            J5 IS PTR TO ATTACH'S SVRB      06120000
         CLC   XRBREG+65(3,J5),ZERO    DID ATTACHOR SPECIFY AN ECB...   06140000
         BC    8,XXEND2                NO,BRANCH TO XXEND2.             06160000
         L     J3,XRBREG+64(J5)        YES, GET THE ECB ADDRESS.        06180000
         TM    0(J3),X'40'              CHECK COMPLETION FLAG           06200000
         BC    1,XXEND2                                                 06220000
         ST    JF,0(J3)                 PUT COMPLETION CODE IN ECB      06240000
         NI    0(J3),X'7F'        POST ECB                              06260000
         OI    0(J3),X'40'                 COMPLETE                     06280000
XXEND2   LA    J0,72                                                    06300000
         L     J1,XRBREG+4(J5)          FREE 72 BYTE SAVE AREA          06320000
         FREEMAIN R,LV=(0),A=(1)       GIVEN TO ATTACHED PROGRAM.       06340000
         CLC   XRBREG+77(3,J5),ZERO     IS ETXR REQUIRED?               06360000
         BC    8,XXEND3                 NO.                             06380000
         L     J0,REQ168                YES.                            06400000
         BAL   J8,XRBSETUP              GET CORE FOR IRB AND SAVE AREA. 06420000
         MVC   XRBSZ+1(3,J1),XIRBBITS   INITIALIZE SIZE AND STAB,       06440000
         MVC   XRBEP+1(3,J1),XRBREG+77(J5) ENTRY POINT,                 06460000
         MVC   XRBPSW(8,J1),XRBREG+72(J5) AND PSW FIELDS.               06480000
         MVC   XRBLNK+1(3,J1),XRBLNK+1(J5) QUEUE IRB BETWEEN SVRB       06500000
         ST    J1,XRBWT(J5)             AND ATTACHING RB.               06520000
         MVC   XRBREG(64,J1),XRBREG(J5) INITIALIZE REG SAVE AREA.       06540000
         SR    JF,JF                                                    06560000
         ST    JF,XRBREG+4(J1)                                          06580000
         L     JF,XRBEP(J1)             REG 15 HAS ETXR ENTRY POINT     06600000
         LA    J1,96(J1)                ADDRESS OF SAVE AREA.           06620000
        LA    J3,CVTEXIT(J2)          ADDRESS OF SVC EXIT INSTRUCTION   06640000
        STM   J1,J3,XRBREG+52(J5)     STORE IN SVRB                     06660000
XXEND3   L     J0,XRBREG(J5)            INITIALIZE REG 0 FROM SVRB      06680000
*                                      REGISTER SAVE AREA.              06700000
         SR    J1,J1                                                    06720000
         MVC   TCBFSA(3,J6),XRBREG+61(J5) RESTORE TCB SAVE AREA POINTER 06740000
         SVC   EXIT                                                     06760000
         SPACE 4                                                        06780000
XRBSETUP LR    J7,JF                    SAVE REG JF WHICH GETMAIN USES. 06800000
         GETMAIN R,LV=(0)                                               06820000
         LR    JF,J7                    RESTORE REG JF.                 06840000
         XC    0(40,J1),0(J1)           CLEAR THE RB                    06860000
         BCR   15,J8                    RETURN                          06880000
ERROR    L     J1,ERRCD                 ERROR CODE FOR ABEND            06900000
         ABEND (1)                                                      06920000
         SPACE 4                                                        06940000
ZERO     DC    X'000000'                                                06960000
         DS    0F                                                       06980000
ERRCD    DC    X'80406000'              L R B  ABEND ERROR CODE         07000000
REQ32    DC    X'80000020'                                              07020000
REQ72    DC    X'80000048'                                              07040000
REQ168   DC    X'800000A8'                                              07060000
XIRBBITS DC    X'154002'                                                07080000
XPRBBITS DC    X'04E002'                                                07100000
         END                                                            07120000
