IGC048   CSECT                                                          00200016
* ROUTINE NAME                                                          00400016
*        IEAADEQ0-DEQUEUE SERVICE ROUTINE                               00600016
         SPACE 3                                                        00800016
* FUNCTIONS                                                             01000016
*        1-PERFORM PCP DEQ PROCESSING                                   01200016
*        2-PERFORM RELEASE PROCESSING FOR A SERIALLY REUSABLE RESOURCE  01400016
         SPACE 3                                                        01600016
* ENTRY POINT NAME                                                      01800016
*        IGC048                                                         02000016
         SPACE 3                                                        02400016
* ATTRIBUTES                                                            02600016
*        1-TRANSIENT, BUT MAY BE SPECIFIED AS RESIDENT DURING SYSGEN    02800016
*        2-RE-ENTRANT                                                   03000016
*        3-IN SUPERVISOR STATE                                          03200016
*        4-TYPE 3 SVC WHEN TRANSIENT AND TYPE 2 WHEN RESIDENT           03400016
*        5-PARTIALLY DISABLED. I/O INTERRUTIONS ARE ALLOWED WHEN A      03600016
*          DEVICE RELEASE IS NECESSARY.                                 03800016
         SPACE 3                                                        04000016
* APPLICABILITY                                                         04200016
*        OPTION 1 WITH SHARED DASD                                      04400016
         SPACE 3                                                        04600016
* EXTERNAL REFERENCES                                                   04800016
*        IEA0VL00-SUPERVISOR VALIDITY CHECK ROUTINE                     05000016
         SPACE 3                                                        05200016
* SVC'S USED                                                            05400016
*        1-SVC 10 REGISTER FORM OF FREEMAIN                             05600016
*        2-SVC 0 EXCP                                                   05800016
*        3-SVC 13 ABEND                                                 05900016
         SPACE 3                                                        06000016
* INPUT                                                                 06200016
*        REGISTER ONE CONTAINS THE ADDRESS OF A PARAMETER LIST          06400016
*        BEGINNING ON A FULL WORD BOUNDARY IN CALLER'S OWN STORAGE      06600016
*        AREA. THE FORMAT OF THE LIST IS SHOWN BELOW.                   06800016
         SPACE 2                                                        07000016
*              *****************************************                07200016
*              *0        *1        *2        *3        *                07400016
*              * LISTEND * MINLNGTH* PARMCDS * RETCODE *                07600016
*              *         *         *                   *                07800016
*              *****************************************                08000016
*              *4                                      *                08200016
*              *   ADDRESS OF MAJOR RESOURCE NAME      *                08400016
*              *                                       *                08600016
*              *****************************************                08800016
*              *8                                      *                09000016
*              *   ADDRESS OF MINOR RESOURCE NAME      *                09200016
*              *                                       *                09400016
*              *****************************************                09600016
*              *12                                     *                09800016
*              *           ADDRESS OF A UCB            *                10000016
*              *                                       *                10200016
*              *****************************************                10400016
         SPACE 3                                                        10600016
* OUTPUT FOR DEQ                                                        10800016
*        DEQ IN THIS ENVIRONMENT IS A NOP AND NO OUTPUT IS GIVEN        11000016
         SPACE                                                          11200016
* OUTPUT FOR RELEASE                                                    11400016
*        THE REMOVAL OF AND FREEING OF SPACE OCCUPIED BY CONTROL BLOCKS 11600016
*        CREATED BY THE RESERVE(ENQ) ROUTINE. ALSO WHEN THE UCB RESERVE 11800016
*        COUNT GOES TO ZERO, THE RELEASING OF THE DEVICE                12000016
         SPACE 3                                                        12200016
* ENTRY POINT                                                           12400016
*        IGC048 ENTERED FROM THE SVC INTERRUPT HANDLER BY A LPSW        12600016
*        INSTRUCTION.                                                   12800016
         SPACE 3                                                        13000016
* EXIT POINTS                                                           13080016
*        1-NORMAL                                                       13160016
*           TO THE CALLER VIA A BRANCH ON REGISTER FOURTEEN             13240016
*        2-ERROR                                                        13320016
*           TO ABEND WITH THE FOLLOWING ERROR CODE                      13400016
*            430 INVALID PARAMETER LIST                                 13480016
         SPACE 3                                                        13600016
* TABLES AND CONTROL BLOCKS REFERENCED                                  13800016
*        1-CVT                                                          14000016
*           ADDRESS OF VALIDITY CHECK ROUTINE                           14200016
*           ADDRESS OF MAJOR QCB ORIGIN                                 14400016
*        2-TCB                                                          14600016
*           PROTECK KEY                                                 14800016
*           RESERVE COUNT                                               15000016
*        3-UCB                                                          15200016
*           RESERVE COUNT                                               15400016
*           UCB IDENTIFIER                                              15600016
*        4-REQUEST BLOCK                                                15700016
*           USER'S RESUME PSW                                           15800016
*           LINK FIELD                                                  15900016
*        5-MAJOR QCB                                                    16200016
*           ALL FIELDS                                                  16400016
*        6-MINOR QCB                                                    16600016
*           ALL FIELDS                                                  16800016
         SPACE 3                                                        17000016
* NOTES                                                                 17200016
*        NONE                                                           17400016
         EJECT                                                          17600016
REG0     EQU   0                                                        18000016
PARMREG  EQU   1                        PARAMETER LIST REGISTER         18200016
ABENDREG EQU   1                        ABEND CODE REGISTER             18400016
UCBREG   EQU   2                        ADDRESS OF UCB                  18600016
CVTREG   EQU   3                        ADDRESS OF CVT                  18800016
TCBREG   EQU   4                        ADDRESS OF CURRENT TCB          19000016
TESTREG  EQU   5                        USED FOR COMPARAND              19200016
TEMPREG  EQU   5                        USED TO HOLD TEMPORARY DATA     19300016
RBREG    EQU   5                        ADDRESS OF RB                   19400016
CHKREG   EQU   6                        USED FOR COMPARAND              19500016
WORKREG1 EQU   6                        GENERAL USE                     19600016
WORKREG2 EQU   7                        GENERAL USE                     19800016
INPUTREG EQU   7                        INPUT TO VALIDITY CHECK         20000016
WORKREG3 EQU   8                        GENERAL USE                     20200016
CHKBASE  EQU   8                        VALIDITY CHECK BASE             20400016
TCBCREG  EQU   9                        TCB REG FOR VALIDITY CHECK      20600016
CURMAJ   EQU   9                        CURRENT MAJOR QCB               20800016
CURMIN   EQU   10                       CURRENT MINOR QCB               21000016
LKREG2   EQU   10                       LINK TO SUBROUTINE              21200016
LKREG1   EQU   11                       LINK TO SUBROUTINES             21400016
BASE     EQU   12                       BASE REGISTER                   21600016
RETREG   EQU   14                       LINK TO SUBROUTINES             21800016
CODEREG  EQU   15                       RETURN CODE                     21900016
*   DISPLACEMENTS IN PARAMETER LIST                                     22200016
RNAMELTH EQU   1                        LENGTH  OF RNAME                22400016
PARMCDS  EQU   2                         FLAG BYTE IN PARAMETER LIST    22600016
RETURN   EQU   3                        RETURN CODES IN PARM LIST       22800016
RETCODE  EQU   3                        RETURN CODES IN PARM LIST       23000016
MAJNAME  EQU   4                        ADDRESS OF MAJOR NAME           23200016
MINNAME  EQU   8                        ADDRESS OF MINOR NAME           23400016
PARMUCB  EQU   12                       ADDRESS OF UCB                  23600016
*   DISPLACEMENTS IN MAJOR QCB                                          23800016
NEXTMAJ  EQU   0                        ADDRESS OF NEXT MAJOR           24000016
PREVMAJ  EQU   4                        ADDRESS OF PREVIOUS MAJOR       24200016
QCBMIN   EQU   8                        ADDRESS OF MINOR                24400016
QNAME    EQU   12                       QNAME IN MAJOR                  24600016
*   DISPLACEMENTS IN MINOR QCB                                          24800016
UCBADDR  EQU   0                        UCB ADDRESS                     25000016
PREVMIN  EQU   4                        ADDRESS OF PREVIOUS MINOR       25200016
NEXTMIN  EQU   8                        ADDRESS OF NEXT MINOR           25400016
MINLNTH  EQU   12                       RNAME LENGTH                    25600016
PTKEY    EQU   13                       PROTECT KEY                     25800016
MINAME   EQU   14                       RNAME IN MINOR                  26000016
*   DISPLACEMENT IN UCB                                                 26200016
UCBRESV  EQU   40                       UCB RESERVE COUNT               26400016
UCBSKA   EQU   48                       BIN NUMBER                      26600016
*   DISPLACEMENTS IN CVT                                                26800016
CVTXAPG  EQU   20                       ADDR OF APPENDAGE VECTOR TABLE  26900016
CVT0VL00 EQU   24                       ADDRESS OF VALIDITY CHECK       27000016
CVTNUCB  EQU   128                     ADR LOWEST BOUNDARY NOT IN NUC   27100017
CVTQCBO  EQU   148                      MAJOR QCB ORIGIN                27200016
CVTMZ00  EQU   164                      MACHINE SIZE                    27300016
*   DISPLACEMENTS IN TCB                                                27400016
TCBPKF   EQU   28                       PROTECT KEY FIELD               27600016
TCBRESV  EQU   34                       TCB RESERVE COUNT               27800016
*   DISPLACEMENTS IN RB                                                 27850016
RBPSW    EQU   16                       USER'S OLD PSW                  27900016
RBLINK   EQU   28                       LINK FIELD                      27950016
* GENERAL OFFSETS                                                       27958016
ZERO     EQU   0                                                        27966016
ONE      EQU   1                                                        27974016
ELEVEN   EQU   11                                                       27982016
         EJECT                                                          27990016
         BALR  BASE,0                   INITIALIZE BASE                 28000016
         USING *,BASE                                                   28200016
         BAL   LKREG1,VALTEST           BRANCH TO VALIDITY CHECK        30200016
*                                                                       30400016
*   WHEN WE REACH THIS POINT, ALL ADDRESSES HAVE BEEN CHECKED AND ARE   30600016
*   VALID. WE NOW LOOK FOR A MAJOR AND MINOR QCB THAT REPRESENTS THE    30800016
*   SPECIFIED RESOURCE.                                                 31000016
*                                                                       31200016
         BAL   LKREG1,FINDMAJ           GO LOOK FOR MAJOR QCB           31400016
         LTR   CURMAJ,CURMAJ            WAS MAJOR FOUND                 31600016
         BC    13,EXIT                  TAKE BRANCH IF NOT FOUND        31800016
         BAL   LKREG1,FINDMIN           GO LOOK FOR MINOR QCB           32000016
         LTR   CURMIN,CURMIN            WAS MINOR FOUND                 32200016
         BC    13,EXIT                  TAKE BRANCH IF NOT FOUND        32400016
         L     UCBREG,UCBADDR(CURMIN)   PICK UP UCB FROM MINOR          32600016
         LA    UCBREG,ZERO(UCBREG)      CLEAR HI ORDER BYTE             32700016
         SR    WORKREG1,WORKREG1                                        32800016
         IC    WORKREG1,UCBRESV(UCBREG) GET RESERVE COUNT FROM UCB      33000016
         BCTR  WORKREG1,0               DECREMENT BY ONE                33200016
         STC   WORKREG1,UCBRESV(UCBREG) PUT IT BACK                     33400016
         LTR   WORKREG1,WORKREG1        IS IT ZERO                      33600016
         BC    7,GO                     NO-DON'T RELEASE DEVICE         33700016
         CLI   UCBRESV+1(UCBREG),X'00'  IS HARDWARE RESERVE IN EFFECT   33800016
         BC    7,RELEASE                YES GO RELEASE DEVICE           33900016
GO       SR    WORKREG2,WORKREG2                                        34000016
         IC    WORKREG2,TCBRESV(TCBREG) PICK UP TCB RESERVE COUNT       34200016
         BCTR  WORKREG2,0               DECREMENT BY ONE                34400016
         STC   WORKREG2,TCBRESV(TCBREG) PUT IT BACK                     34600016
         LM    WORKREG1,WORKREG2,PREVMIN(CURMIN)                        34800016
         LTR   WORKREG2,WORKREG2        IS THIS LAST MINOR              35000016
         BC    8,LAST                   TAKE BRANCH IF YES              35200016
         ST    WORKREG1,PREVMIN(WORKREG2) SET NEW PREVIOUS IN NEXT QCB  35400016
LAST     ST    WORKREG2,NEXTMIN(WORKREG1) SET NEW NEXT IN PREVIOUS QCB  35600016
         CR    WORKREG1,CURMAJ          IS THIS FIRST MINOR ON QUEUE    35800016
         BNE   FREEMIN                  NO-DON'T DEQUEUE MAJOR          36000016
         LTR   WORKREG2,WORKREG2        IS THIS ALSO LAST MINOR ON QUE  36200016
         BC    7,FREEMIN                NO-DON'T DEQUEUE MAJOR          36400016
*                                                                       36600016
*   AT THIS POINT, THE SPECIFIED MINOR IS THE ONLY ONE ON THE QUEUE,    36800016
*   HENCE WE WILL ALSO DEQUEUE AND FREE THE MAJOR                       37000016
         LM    WORKREG1,WORKREG2,NEXTMAJ(CURMAJ)                        37200016
         LA    WORKREG3,CVTQCBO(CVTREG) ADDRESS OF QCB ORIGIN IN CVT    37400016
         LTR   WORKREG1,WORKREG1        IS THIS LAST MAJOR ON QUEUE     37600016
         BC    8,END                    TAKE BRANCH IF YES              37800016
         ST    WORKREG2,PREVMAJ(WORKREG1) SET NEW PREVIOUS IN NEXT      38000016
END      ST    WORKREG1,NEXTMAJ(WORKREG2) SET NEW NEXT IN PREVIOUS      38200016
*                                                                       38400016
*   FREE MAJOR QUEUE CONTROL BLOCK                                      38600016
*                                                                       38800016
         LR    TEMPREG,PARMREG          SAVE INPUT PARAMETERS           39000016
         LR    PARMREG,CURMAJ           ADDRESS OF MAJOR TO BE FREED    39200016
         FREEMAIN R,LV=20,A=(1)                                         39400016
*                                                                       39600016
*   FREE MINOR QUEUE CONTROL BLOCK                                      39800016
*                                                                       40000016
FREEMIN  SR    WORKREG1,WORKREG1                                        40200016
         IC    WORKREG1,MINLNTH(CURMIN) GET LENGTH OF RNAME             40400016
         LA    REG0,MINAME(WORKREG1)                                    40600016
         LR    PARMREG,CURMIN           ADDRESS OF MINOR TO BE FREED    40800016
         FREEMAIN R,LV=(0),A=(1)                                        41000016
EXIT     SR    CODEREG,CODEREG          SET RETURN CODE                 41100016
         BR    RETREG                   RETURN TO CALLER                41200016
*                                                                       41400016
*   THIS ROUTINE PERFORMS ALL VALIDITY CHECKING AND PROVIDES THE        41600016
*   INTERFACE WITH IEA0VL00                                             41800016
*                                                                       42000016
VALTEST  L     CHKREG,RBLINK(RBREG)     GET ISSUING RB                  42200016
         TM    RBPSW+1(CHKREG),X'F0'    IS PEOTECT KEY ZERO             42400016
         BCR   8,LKREG1                 IF ZERO RETURN WITH NO FARTHER  42600016
*                                       CHECKING                        42800016
         L     CHKBASE,CVT0VL00(CVTREG) ADDRESS OF VALIDITY CHECK       43000016
         LR    TCBCREG,TCBREG           ADDR OF TCB FOR VALIDITY CHECK  43200016
         LR    INPUTREG,PARMREG         ADDRESS TO CHECK                43400016
         LA    INPUTREG,ZERO(INPUTREG)  CLEAR HI ORDER BYTE             43500016
         EX    INPUTREG,CHKALIGN        GO CHECK ALIGNMENT              43600016
         BC    7,ABEND                  BAD ALIGNMENT-TAKE BRANCH       43800016
         BALR  LKREG2,CHKBASE           GO TO IEA0VL00                  44000016
         BC    7,ABEND                  BAD RETURN-ABEND                44200016
         CL    INPUTREG,CVTNUCB(CVTREG) IS ADR ABOVE NUCLEUS        LCS 44210017
         BC    4,ABEND                 NO                           LCS 44220017
         LA    INPUTREG,ELEVEN(PARMREG) GET LAST BYTE OF ENTRY          44250016
         CL    INPUTREG,CVTMZ00(CVTREG) IS ADDRESS IN MACHINE           44300016
         BH    ABEND                    NO TAKE BRANCH                  44350016
         L     INPUTREG,MAJNAME(PARMREG) GET ADDR OF MAJOR NAME         44400016
         LA    INPUTREG,ZERO(INPUTREG)  CLEAR HI ORDER BYTE             44700016
         CL    INPUTREG,CVTMZ00(CVTREG) IS ADDRESS IN MACHINE           44900016
         BH    ABEND                    NO-TAKE BRANCH                  45100016
         L     INPUTREG,MINNAME(PARMREG) GET MINOR NAME ADDRESS         45400016
         LA    INPUTREG,ZERO(INPUTREG)  CLEAR HI ORDER BYTE             45700016
         CL    INPUTREG,CVTMZ00(CVTREG) IS ADDRESS IN MACHINE           46700016
         BH    ABEND                                                    47700016
*                                                                       48800016
*   AT THIS POINT, THE PARAMETERS ARE ALL VALID. PREPARE TO RETURN.     49000016
*                                                                       49200016
         BR    LKREG1                   RETURN TO MAINLINE              49400016
ABEND    ABEND 430,DUMP                                                 49500016
*********************************************************************** 49600016
*   THIS ROUTINE ATTEMPTS TO FIND A MAJOR QCB BY THE SAME NAME AS THAT* 49800016
*   GIVEN IN THE CURRENT PARAMETER LIST ENTRY. IF SUCCESSFUL, THE     * 50000016
*   ROUTINE EXITS WITH 'CURMAJ' POINTING TO THE MAJOR QCB WITH THE    * 50200016
*   SAME NAME. IF NOT SUCCESSFUL, THE ROUTINE EXITS WITH CURMAJ       * 50400016
*   HAVING THE COMPLEMENT ADDRESS OF LAST MAJOR QCB ON QUEUE.         * 50600016
*********************************************************************** 50800016
FINDMAJ  SR    WORKREG3,WORKREG3        CLEAR FOR COMPARAND             51000016
         L     CURMAJ,CVTQCBO(CVTREG)   GET QCB ORIGIN FROM CVT         51200016
         LTR   CURMAJ,CURMAJ            IS QUEUE EMPTY                  51400016
         BCR   8,LKREG1                 RETURN WITH NO MAJOR            51600016
         L     WORKREG1,MAJNAME(PARMREG) PICK UP MAJOR NAME ADDRESS     51800016
FINDMAJ1 CLC   ZERO(8,WORKREG1),QNAME(CURMAJ) COMPARE NAMES             52000016
         BCR   8,LKREG1                 RETURN WITH ADDRESS OF MAJOR    52200016
         C     WORKREG3,NEXTMAJ(CURMAJ) IS THIS LAST ON CHAIN           52400016
         BE    FINDMAJ2                 YES-GO COMPLEMENT ADDRESS       52600016
         L     CURMAJ,NEXTMAJ(CURMAJ)   PICK UP NEXT MAJOR QCB          52800016
         B     FINDMAJ1                 GO BACK THROUGH LOOP            53000016
FINDMAJ2 LCR   CURMAJ,CURMAJ            COMPLEMENT ADDRESS TO INDICATE  53200016
         BR    LKREG1                   NO MAJOR QCB AND RETURN         53400016
*********************************************************************** 53600016
*   THIS ROUTINE ATTEMPTS TO FIND A MINOR QCB BY THE SAME NAME AS THAT* 53800016
*   GIVEN IN THE CURRENT PARAMETER LIST ENTRY. IF SUCCESSFUL, THE     * 54000016
*   ROUTINE EXITS WITH 'CURMIN' POINTING TO THE MINOR QCB OF THE SAME * 54200016
*   NAME. IF NOT SUCCESSFUL, THIS ROUTINE EXITS WITH 'CURMIN' HAVING  * 54400016
*   THE COMPLEMENT ADDRESS OF LAST MINOR QCB.                         * 54600016
*********************************************************************** 54800016
FINDMIN  SR    WORKREG1,WORKREG1        CLEAR FOR INSERT CHARACTER      55000016
         LR    WORKREG3,WORKREG1                                        55200016
         L     WORKREG2,MINNAME(PARMREG) ADDRESS OF MINOR NAME          55400016
         IC    WORKREG1,RNAMELTH(PARMREG) PICK UP LENGTH                55600016
         LTR   WORKREG1,WORKREG1        IS IT ZERO                      55800016
         BC    7,SUBTRACT               TAKE BRANCH IF NOT              56000016
         IC    WORKREG1,ZERO(WORKREG2)                                  56200016
         LTR   WORKREG1,WORKREG1        IS IT ZERO                      56400016
         BC    8,ABEND                  YES-ISSUE ABEND                 56600016
         LA    WORKREG2,ONE(WORKREG2)   INCREMENT OVER LENGTH BYTE      56800016
SUBTRACT BCTR  WORKREG1,0               DECREMENT LENGTH FOR EXECUTE    57000016
         L     CURMIN,QCBMIN(CURMAJ)    GET FIRST MINOR QCB             57200016
FINDMIN1 SR    TESTREG,TESTREG          CLEAR FOR INSERT CHARACTER      57400016
         IC    TESTREG,MINLNTH(CURMIN)  GET LENGTH FROM MINOR           57600016
         BCTR  TESTREG,0                DECREMENT BY ONE                57800016
         CR    TESTREG,WORKREG1         COMPARE LENGTHS                 58000016
         BNE   TESTNEXT                 UNEQUAL TAKE BRANCH             58200016
         EX    WORKREG1,CHEKNAME        GO COMPARE NAMES                58400016
         BCR   8,LKREG1                 RETURN WITH ADDRESS OF MINOR IF 58600016
*                                       EQUAL                           58800016
TESTNEXT C     WORKREG3,NEXTMIN(CURMIN) TEST FOR NEXT MINOR             59000016
         BE    FINDMIN2                 LAST TAKE BRANCH                59200016
         L     CURMIN,NEXTMIN(CURMIN)   PICK UP NEXT MINOR              59400016
         B     FINDMIN1                 GO BACK THROUGH LOOP            59600016
FINDMIN2 LCR   CURMIN,CURMIN            COMPLEMENT ADDRESS TO INDICATE  59800016
         BR    LKREG1                   NO MINOR QCB                    60000016
*********************************************************************** 60200016
*   THIS ROUTINE PERFORMS THE DEVICE RELEASE. IT IS ENTERED WHEN THE  * 60400016
*   UCB RESERVE COUNT GOES TO ZERO ON A DEQ.                          * 60600016
*********************************************************************** 60800016
RELEASE  LR    TEMPREG,PARMREG          SAVE INPUT ADDRESS              61000016
         GETMAIN R,LV=104                                               61200016
         LR    WORKREG2,PARMREG                                         61300016
         USING RLDCB,WORKREG2           USE ADDR OF GOTTEN CORE FOR     61400016
*                                       DSECT BASE                      61600016
*                                                                       61800016
*   INITIALIZE DEB                                                      62000016
*                                                                       62200016
         XC    ZERO(104,PARMREG),ZERO(PARMREG)  CLEAR GOTTEN CORE       62400016
         L     WORKREG1,CVTXAPG(CVTREG)  ADDRESS OF IOS AVT             62600016
         MVI   DENEXT,X'02'             NUMBER OF EXTENTS               63000016
         ST    PARMREG,DEDCBAD          POINT DEB TO DCB                63600016
         MVI   DEPKID,X'0F'             SET DEB ID                      63800016
         MVZ   DEPKID,TCBPKF(TCBREG)    SET DEB PROTECT KEY             64000016
         ST    WORKREG1,DEAPPAD         STORE IN TABLE POINTER SLOT     64400016
         MVI   DEEXTSCL,X'04'           GET SIZE OF EXTENT              64600016
         ST    UCBREG,DEUCBAD-2         SET POINTER TO UCB              64800016
         MVI   DEFM,X'18'               SET FILE MASK                   65000016
         MVC   DEBB(2),UCBSKA+1(UCBREG) SET BIN NUMBER OF DEVICE        65200016
         XC    DESTART(4),DESTART       INIT START CCHH TO ZERO         65400016
         MVI   DEEND,X'FF'              INIT END C TO 'FF'              65600016
         MVC   DEEND+1(3),DEEND         PROPAGATE 'FF' TO REMAINING CHH 65800016
         LA    WORKREG1,X'01'           SET NO. ALLOCATED TRACKS TO 1   66000016
         STH   WORKREG1,DETRKS          STORE IN DEB                    66200016
*                                                                       66400016
*   INITIALIZE IOB                                                      66600016
*                                                                       66800016
         MVI   IOBFL1,X'02'             SET IOB FLAGS                   67000016
         MVI   IOBFL2,X'00'                                             67200016
         ST    PARMREG,IOBECBAD         SET ADDRESS OF ECB              67400016
         LA    WORKREG1,RLCCW           GET ADDRESS OF CHANNEL PROGRAM  67600016
         ST    WORKREG1,IOBSTART        POINT TO CHANNEL PROGRAM        67800016
         ST    PARMREG,IOBDCBAD         POINT IOB TO DCB                68000016
         XC    IOBMOD(8),IOBMOD         CLEAR FIELDS                    68200016
         MVC   IOBSK(4),UCBSKA+1(UCBREG) MOVE IN SEEK ADDRESS FROM UCB  68400016
*                                                                       68600016
*   INITIALIZE DCB                                                      68800016
*                                                                       69000016
         LA    WORKREG1,DEAPGV          GET ADDRESS OF DEB              69200016
         ST    WORKREG1,DCBDEBAD        POINT DEB TO DCB                69400016
*                                                                       69600016
*   INITIALIZE CHANNEL PROGRAM                                          69800016
*                                                                       70000016
         MVI   RLCCW,X'03'              NOP COMMAND CODE                70200016
         MVI   RLCCW+4,X'20'            SUPPRESS INCORRECT LENGTH IND.  70400016
         MVI   RLCCW+7,X'EE'            IDENTIFICATION, NORMALLY COUNT  70600016
         SSM   ENABLE                   ENABLE FOR I/O INTERRUPTS       70800016
         EXCP  RLIOB                    ISSUE RELEASE EXCP              71000016
         WAIT  ECB=RLECB                WAIT FOR COMPLETIOM OF I/O      71200016
         SSM   DISABLE                  DISABLE I/O INTERRUPTS          71400016
         LA    1,RLECB                 PTM FIX  5-17-68                 71500016
         FREEMAIN R,LV=104,A=(1)                                        71600016
         LR    PARMREG,TEMPREG          RESTORE INPUT                   71800016
         B     GO                      RETURN TO MAINLINE               72000016
CHKALIGN TM    WORD,X'00'               CHECK BOUNDARY                  72200016
CHEKNAME CLC   MINAME(0,CURMIN),ZERO(WORKREG2) COMPARE NAMES            72400016
ENABLE   DC    X'FD'                    MASK FOR I/O INTERRUPTS         72600016
DISABLE  DC    X'00'                    MASK AGAINST I/O INTERRUPTS     72800016
WORD     DC    X'03'                    FULL WORD MASK                  73000016
RLDCB    DSECT                                                          73200016
RLECB    DS    F                        ECB TO WAIT ON                  73400016
RLIOB    DS    0F                       START OF IOB                    73600016
IOBFL1   DS    X                        IOB FLAGS                       73800016
IOBFL2   DS    X                        IOB FLAGS                       74000016
         DS    H                        FILLER                          74200016
IOBECBAD DS    F                        ADDR OF ECB TO BE POSTED        74400016
         DS    2F                       FILLER                          74600016
IOBSTART DS    F                        ADDR OF CHANNEL PROGRAM         74800016
IOBDCBAD DS    F                       ADDR OF ASSOCIATED DCB           75000016
         DS    2F                       FILLER                          75200016
IOBMOD   DS    X                        MODIFIER-DEB EXTENT NUMBER      75400016
IOBSK    DS    CL4                      BBCC TO SEEK TO                 75600016
         DS    CL3                     FILLER                           75800016
DCBDEBAD DS    F                        2 FLAGS AND ADDR OF ASSOC. DEB  76000016
RLCCW    DS    X                        CCW OP CODE                     76200016
         DS    CL3                      FILLER                          76400016
         DS    X                        CCW FLAGS                       76600016
         DS    CL2                      FILLER                          76800016
         DS    X                        BYTE COUNT END OF IOB INDICATOR 77000016
DEAPGV   DS    4F                       APPENDAGE VECTOR TABLE          77200016
DENEXT   DS    X                        NUMBER OF EXTENTS               77400016
         DS    CL3                      REMAINDER OF AVT                77600016
DEPRIOR  DS    X                        DEB PRIORITY                    77800016
         DS    X                        FILLER BYTE                     78000016
DEVRET   DS    H                        AVT RETURN                      78200016
DEPKID   DS    0X                       USERS PROTECT KEY AND DEB ID    78400016
DEDCBAD  DS    F                        ADDR OF ASSOCIATED DCB          78600016
DEEXTSCL DS    0X                       SIZE OF EXTENTS                 78800016
DEAPPAD  DS    F                        ADDRESS OF AVT                  79000016
DEFM     DS    X                        FILE MASK                       79200016
         DS    X                        FILLER BYTE                     79400016
DEUCBAD  DS    H                        ADDRESS OF UCB                  79600016
DEBB     DS    H                        BIN # OF DEVICE                 79800016
DESTART  DS    2H                       START CCHH OF EXTENT            80000016
DEEND    DS    2H                       END CCHH OF EXTENT              80200016
DETRKS   DS    H                        NO OF TRACKS ALLOCATED          80400016
         END                                                            80600016
