IGC043   CSECT                                                          00200013
         ENTRY IGC043A0                                           19021 00220019
         ENTRY IGC043A1                                           19021 00240019
IGC043A0 EQU   *                                                  19021 00260019
*1542560000,734000                                                 RORI 00300015
*460000,470000-472000,476000,480000,492000-494000,582000-638000,   MO19 00310019
*650000-654000                                                     MO19 00320019
         TITLE 'STAGE 1 - EXIT EFFECTOR FOR PCP, OPTION 2, AND OPTION 4*00400013
                - (CIRB)'                                               00600019
         EJECT                                                          00800013
*        ROUTINE NAME -                                                 01000013
         SPACE                                                          01200013
*              IGC043 - CIRB                                            01400019
*              (STAGE 1 OF THE EXIT EFFECTOR)                           01600013
         SPACE 2                                                        01800013
*        CHANGE LEVEL-                                                  02000013
         SPACE                                                          02200013
*              ***002***                                                02400019
         SPACE                                                          02600013
*        NOTE-                                                          02800013
*              THIS ENTIRE MODULE HAS BEEN CHANGED UNDER APAR# 4587     03000013
*              DIRB CODE WAS DELETED UNDER MO19                         03010019
         SPACE 2                                                        03200013
*        FUNCTION -                                                     03400013
         SPACE                                                          03600013
*                CREATES AND INITIALIZES AN IRB, BASED UPON INPUT       03800019
*              PARAMETERS.  OBTAINS A WORK AREA (IN WHICH IQE'S MAY     04000013
*              BE CONSTRUCTED) AND A 72 BYTE REGISTER SAVE AREA, IF     04200013
*              REQUESTED BY CALLER.                                     04400013
         SPACE 2                                                        05000013
*        CONTAINED IN MODULE -                                          05200013
         SPACE                                                          05400013
*              IEAAEF00, CIRB FOR PCP AND OPTION 2                      05600019
*              IEAQEF00, CIRB FOR OPTION 4                              05800019
         SPACE 2                                                        06000013
*        ATTRIBUTES -                                                   06200013
         SPACE                                                          06400013
*              TYPE 2 SVC ROUTINE, REENTRANT.                           06600013
         SPACE 2                                                        06800013
*        APPLICABILITY -                                                07000013
         SPACE                                                          07200013
*              PCP, OPTION 2, AND OPTION 4 SYSTEMS.                     07400013
         SPACE 2                                                        07600013
*        EXTERNAL REFERENCES -                                          07800013
         SPACE                                                          08000013
*              NONE                                                     08200013
         SPACE 2                                                        08400013
*        SVC USAGE -                                                    08600013
         SPACE                                                          08800013
*              GETMAIN, SUBPOOLS 250 AND 253                            09000013
*              SUBPOOL 250 IS A SUPERVISOR SYNONYM FOR SUBPOOL 0        09400013
         EJECT                                                          09600013
*        INPUT -                                                        09800013
         SPACE                                                          10000013
*              REGISTER 0-                                              10200013
*                  ENTRY POINT ADDRESS TO EXIT ROUTINE USING IRB        10400013
*              REGISTER 1-                                              10600013
*                  TWO HIGH ORDER BYTES CONTAIN OPTION INDICATOR BITS.  10800013
*              BIT                        BIT                           11000013
*              0    FLAG, 1=DIRB,0=CIRB   8-10  ALWAYS '000'            11200013
*              1-4  ALWAYS '1000'         11    RESCHED.                11400013
*              5    KEY, 1=PP,0=SUPR      12-13 IQE TYPE                11600013
*              6    STATE, 1=PP,0=SUPR    14    DYNAMIC INDICATOR FLAG  11800013
*              7    S/A, 1=YES,0=NO       15    ALWAYS '0'              12000013
* NOTE-        IF BIT ZERO IN REGISTER 1 IS ON, ALL OTHER INFORMATION   12200013
*              IN REGISTER 1 IS IGNORED.                                12400013
         SPACE                                                          12600013
*                  THE TWO LOW ORDER BYTES CONTAIN THE SIZE (IN DOUBLE  12800013
*                  WORDS) OF THE WORK AREA TO BE APPENDED TO THE IRB.   13000013
         SPACE 2                                                        13200013
*        OUTPUT -                                                       13400013
         SPACE                                                          13600013
*              THE IRB IS INITIALIZED AS FOLLOWS-                       13800013
*                  WORD 1- SAVE AREA ADDRESS OR ZERO                    14000013
*                  WORD 2- ZEROS                                        14200013
*                  WORD 3- RB SIZE AND STAB                             14400013
*                  WORD 4- ENTRY POINT TO EXIT ROUTINE                  14600013
*                  WORD 5,6- INITIALIZED PSW                            14800013
*                  WORD 7,8- ZEROS                                      15000013
*                  WORDS 9-24- UNDETERMINED (NOT CLEARED)               15200013
*              THE WORK AREA, IF REQUESTED, FOLLOWS IRB WITH FIRST      15400013
*              WORD CONTAINING THE ADDRESS OF THE SECOND WORD OF THE    15600013
*              WORK AREA.  THE REMAINDER OF THE WORK AREA IS NOT        15800013
*              CLEARED.                                                 16000013
*              THE SAVE AREA, IF REQUESTED, IS POINTED TO BY THE FIRST  16200013
*              WORD OF THE IRB.  THE SAVE AREA IS NOT CLEARED.          16400013
         EJECT                                                          16600013
*        ENTRY POINT -                                                  16800013
         SPACE                                                          17000013
*              IGC043 FROM THE SVC INTERRUPT HANDLER.                   17200013
         SPACE                                                          17400013
*              WHEN IGC043 IS ENTERED, THE FOLLOWING REGISTER SET UP    17600013
*              IS ASSUMED-                                              17800013
*                  REG 0-  ENTRY POINT OF EXIT ROUTINE (PARAMETER)      18000013
*                  REG 1-  OPTION BITS AND WORK AREA SIZE (PARAMETER)   18200013
*                  REG 3-  CVT ADDRESS                                  18400013
*                  REG 4-  CURRENT TCB ADDRESS                          18600013
*                  REG 5-  CURRENT RB ADDRESS                           18800013
*                  REG 14- RETURN ADDRESS                               19000013
*                  REGS 2, 6 TO 13, AND 15- IRRELEVANT                  19200013
*                  PSW-  DISABLED FOR SYSTEM INTERRUPTS AND IN          19400013
*                  SUPERVISOR MODE.                                     19600013
         SPACE 2                                                        19800013
*        EXIT POINT -                                                   20000013
         SPACE                                                          20200013
*              BRANCH TO ADDRESS IN REGISTER 14                         20400013
*              REGISTER 1 CONTAINS THE ADDRESS OF THE CREATED IRB.      20600013
*              REGISTERS 0, 2 THRU 14 CONTENTS ARE IRRELEVANT.          20800013
         SPACE 2                                                        22800013
*        TABLES AND CONTROL -                                           23000013
         SPACE                                                          23200013
*              SVRB UNDER WHICH IGC043 IS RUNNING.                      23400013
         SPACE 2                                                        23600013
*        BLOCKS REFERENCED -                                            23800013
         SPACE                                                          24000013
*              USERS INPUT REGISTERS 0 AND 1 AS FOUND IN SVRB REGISTER  24200013
*              SAVE AREA.  NO ALTERATIONS PERFORMED.                    24400013
         SPACE 2                                                        24600013
*        LIST ORIGINS AND TABLES -                                      24800013
         SPACE                                                          25000013
*              NONE                                                     25200013
         SPACE 2                                                        25400013
*        RESTRICTIONS -                                                 25600013
         SPACE                                                          25800013
*              NONE                                                     26000013
         EJECT                                                          26200013
*        THE IRB'S FOR PCP AND OPTION 2 LOOK LIKE THIS-                 26400013
         SPACE                                                          26600013
*       **********************************************                  26800013
*        *        ADDRESS OF PP REGISTER SAVE        *                  27000013
*        *              AREA (OR ZEROS)              *                  27200013
*       **********************************************                  27400013
*        *                                           *                  27600013
*        *                                           *                  27800013
*       **********************************************                  28000013
*        *      IRB SIZE       *     STATUS AND      *                  28200013
*        *   IN DOUBLE WORDS   *   ATTRIBUTE BITS    *                  28400013
*       **********************************************                  28600013
*        *   USE    *         EXIT ROUTINE'S         *                  28800013
*        *  COUNT   *       ENTRY POINT ADDRESS      *                  29000013
*       **********************************************                  29200013
*        *          SAVE                             *                  29400013
*        *               AREA                        *                  29600013
*       **                    FOR                    *                  29800013
*        *                        RESUME             *                  30000013
*        *                               PSW         *                  30200013
*       **********************************************                  30400013
*        *                 ADDRESS OF                *                  30600013
*        *                   IQE'S                   *                  30800013
*       **********************************************                  31000013
*        *   WAIT   *          PREVIOUS RB           *                  31200013
*        *   COUNT  *         FOR THIS TASK          *                  31400013
*       **********************************************                  31600013
*        *                                           *                  31800013
*        *                                           *                  32000013
*        *                                           *                  32200013
*        *     64 BYTE GENERAL REGISTER SAVE AREA    *                  32400013
*        *                                           *                  32600013
*        *                                           *                  32800013
*        *                                           *                  33000013
*        *                                           *                  33200013
*        - - - - - - - - - - - - - - - - - - - - - - -                  33400013
*                         E T C.                                        33600013
*        - - - - - - - - - - - - - - - - - - - - - - -                  33800013
*        *                                           *                  34000013
*        *                                           *                  34200013
*        *                                           *                  34400013
*        *                                           *                  34600013
*       **********************************************                  34800013
         EJECT                                                          35000013
*        THE IRB'S FOR OPTION 4 LOOK LIKE THIS-                         35200013
         SPACE                                                          35400013
*       **********************************************                  35600013
*        *        ADDRESS OF PP REGISTER SAVE        *                  35800013
*        *              AREA (OR ZEROS)              *                  36000013
*       **********************************************                  36200013
*        *        BITS 32 - 63 OF USER'S PSW         *                  36400013
*        *        (SAVED BY ABTERM AND ABEND)        *                  36600013
*       **********************************************                  36800013
*        *WAIT COUNT* IRB SIZE *     STATUS AND      *                  37000013
*        *   SAVE   *(DBL WRDS)*   ATTRIBUTE BITS    *                  37200013
*       **********************************************                  37400013
*        *               EXIT ROUTINE'S              *                  37600013
*        *            ENTRY POINT ADDRESS            *                  37800013
*       **********************************************                  38000013
*        *          SAVE                             *                  38200013
*        *               AREA                        *                  38400013
*       **                    FOR                    *                  38600013
*        *                        RESUME             *                  38800013
*        *                               PSW         *                  39000013
*       **********************************************                  39200013
*        * ATTATCH  *           ADDRESS OF           *                  39400013
*        *USE COUNT *              IQE'S             *                  39600013
*       **********************************************                  39800013
*        *   WAIT   *           POINTER TO           *                  40000013
*        *  COUNT   *        NEXT RB ON QUEUE        *                  40200013
*       **********************************************                  40400013
*        *                                           *                  40600013
*        *                                           *                  40800013
*        *                                           *                  41000013
*        *     64 BYTE GENERAL REGISTER SAVE AREA    *                  41200013
*        *                                           *                  41400013
*        *                                           *                  41600013
*        *                                           *                  41800013
*        *                                           *                  42000013
*        - - - - - - - - - - - - - - - - - - - - - - -                  42200013
*                         E T C .                                       42400013
*        - - - - - - - - - - - - - - - - - - - - - - -                  42600013
*        *                                           *                  42800013
*        *                                           *                  43000013
*        *                                           *                  43200013
*        *                                           *                  43400013
*       **********************************************                  43600013
         EJECT                                                          43800013
*********************************************************************** 44000013
*        * * *  R E G I S T E R S  A N D  O F F S E T S  * * *        * 44200013
*********************************************************************** 44400013
         SPACE                                                          44600013
R0       EQU   0                   PARAMETER REGISTER                   44800013
RPARAM   EQU   1                   PARAMETER REGISTER FOR GET/FREEMAIN  45000013
RCVT     EQU   3                   ADDRESS OF CVT                  MO19 45010019
RTCB     EQU   4                   ADDRESS OF TCB                       45200013
RB       EQU   5                   ADDRESS OF CURRENT RB                45400013
RWK1     EQU   6                   WORK REGISTER                        45600013
RWK2     EQU   7                   WORK REGISTER                        45800013
RIRB     EQU   8                   ADDRESS OF CREATED OR DELETED IRB    46000013
RBASE    EQU   12                  BASE REGISTER FOR THIS CSECT         46200013
RETURN   EQU   14                  ADDRESS OF RETURN POINT              46400013
         SPACE 2                                                        46800013
GETMAIN  EQU   10                  OPERAND FOR GETMAIN SVC              47400013
MVT      EQU   X'10'               CONFIGURATION FLAG FOR MVT      MO19 47410019
TCBPKF   EQU   28                  PROTECT KEY OFFSET IN TCB            47800013
REUS     EQU   X'EF'               FLAG TO RESET RB REUSEABLE FLAG MO19 47810019
CVTDCB   EQU   116                 DISP OF SYS CONFIGURATION FLAGS M019 47830019
         SPACE 2                                                        48200013
         BALR  RBASE,0             SET UP BASE REGISTER                 48400013
         USING *,RBASE                                                  48600013
         USING CURSVRB,RB                                               48800013
         USING IRB,RIRB                                                 49000013
         EJECT                                                          49600013
*********************************************************************** 49800013
*              * * * * *  C R E A T E  I R B  * * * * *               * 50000013
*********************************************************************** 50200013
         SPACE                                                          50400013
         LH    R0,PARMWORK         GET WORK AREA SIZE FROM PARAM LIST   50600013
         SLL   R0,3                MULTIPLY BY 8 FOR SIZE IN BYTES      50800013
         AL    R0,RBBYTES          ADD IRB SIZE AND SP 253 INDICATOR    51000013
         BAL   1,*+4               INDICATE GETMAIN                     51200013
         SVC   GETMAIN             ISSUE GETMAIN SVC                    51400013
         LR    RIRB,RPARAM         SAVE IRB ADDRESS                     51600013
         XC    XRBNM(32),XRBNM     CLEAR 32 BYTES OF IRB                51800013
         MVC   XRBEPA,EXITEP       PLACE EP ADDRESS IN CREATED IRB      52000013
         TM    PARMFLG1,PARMSAVE   IS SAVE AREA REQUESTED               52200013
         BZ    RBNOSAVE            BRANCH IF NO                         52400013
         L     R0,RBSAVE           PUT SP VALUE AND S/A IN REGISTER     52600013
         BAL   1,*+4               INDICATE GETMAIN                     52800013
         SVC   GETMAIN             ISSUE GETMAIN SVC                    53000013
         ST    RPARAM,XRBSAVE      STORE SAVE ADDRESS IN IRB            53200013
         LR    RPARAM,RIRB         PLACE ADDR OF IRB IN REG 1 FOR USER  53400013
         SPACE                                                          53600013
RBNOSAVE LH    RWK1,PARMWORK       LOAD WORK AREA SIZE                  53800013
         LA    RWK2,12(RWK1)       ADD IRB LENGTH TO WORK AREA LENGTH   54000013
         STH   RWK2,XRBSZ          STORE TOTAL LENGTH INTO IRB          54200013
         LTR   RWK1,RWK1           WAS THERE A WORK AREA REQUESTED      54400013
         BZ    RBINIT              IF NO, GO INITIALIZE FLAGS           54600013
         LA    RWK1,XRBEXSA+4      ELSE, DEVELOP ADDR OF FIRST IQE      54800013
         ST    RWK1,XRBEXSA        INITIALIZE 'NEXT AVAILABLE'          55000013
         SPACE                                                          55200013
RBINIT   MVC   XSTAB,REG1          MOVE FLAGS TO IRB                    55400013
         NI    XSTAB,X'F0'         CLEAR KEY, PRIV, & SAVE AREA FLAGS   55600013
         TM    CVTDCB(RCVT),MVT    IS THIS A MVT SYSTEM            MO19 55610019
         BZ    RBRETIQE            NO, BRANCH                      MO19 55620019
         NI    XRBFLAG2,REUS       TURN OFF REUSEABLE FLAG IF MVT  MO19 55630019
RBRETIQE EQU   *                                                   MO19 55640019
         TM    PARMFLG2,PARMIQE    IS RETIQE BIT SET               RORI 55660015
         BO    RBTSTKEY                                            RORI 55720015
         OI    XRBFLAG2,X'04'      SET IQE TYPE FOR 12(16) *'S          55800013
RBTSTKEY TM    PARMFLG1,PARMKEY    IS KEY SET FOR PP               RORI 56000015
         BZ    RBSUPKEY            IF NO, BRANCH                        56200013
         MVZ   XRBPSW+1(1),TCBPKF(RTCB)  SET PP PROTECT KEY             56400013
         SPACE                                                          56600013
RBSUPKEY OI    XRBPSW+1,X'04'      SET NORMAL SUPR AMWP BITS            56800013
         TM    PARMFLG1,PARMMODE   IS PP MODE REQUESTED                 57000013
         BCR   8,RETURN            IF NOT, EXIT                         57200013
         OI    XRBPSW+1,X'01'      ELSE, TURN ON PP MODE BIT IN PSW     57400013
         MVI   XRBPSW,X'FF'        AND SET PSW ENABLED                  57600013
         BR    RETURN              RETURN                               57800013
         EJECT                                                          64000013
*********************************************************************** 64200013
*              * * *  C O N S T A N T S  &  A R E A S  * * *          * 64400013
*********************************************************************** 64600013
         SPACE                                                          64800013
         DS    0F                                                  M019 64810019
RBBYTES  DC    AL1(253)            SUBPOOL VALUE FOR IRB (253)          65600013
         DC    AL3(96)             LENGTH OF IRB                        65800013
RBSAVE   DC    AL1(250)            SAVE AREA SUBPOOL VALUE              66000013
         DC    AL3(72)             LENGTH OF SAVE AREA (IN BYTES)       66200013
IGC043A1 EQU   *                                                  19021 66300019
         EJECT                                                          66400013
IRB      DSECT                                                          66600013
XRBNM    DS    0CL8                FOR IRB, XRBNM IS NOT DEFINED        66800013
XRBSAVE  DS    0F                      LABEL TO CREATE S/A POINTER FLD  67000013
XRBSASZ  EQU   72                      SIZE OF P/P SAVE AREA            67200013
XRBTIME  DS    CL1                     TIMER FLAGS                      67400013
         DS    CL3                                                      67600013
XRBPSWSV DS    1F                      BITS 32-63 OF USER PSW  VMS      67800013
XRBSZ    DS    0H                  IRB SIZE (IN DOUBLE WORDS) FOR SSS   68000013
XRBWTSV  DS    CL1                     WAIT COUNT SAVE  VMS             68200013
XRBMSSZ  DS    CL1                     SIZE OF IRB(DBL WDS) FOR VMS     68400013
XSTAB    DS    0CL2                IRB FLAG BYTES-                      68600013
XRBFLAG1 DS    BL1                     IDENTIFIER FLAGS                 68800013
XRBFLAG2 DS    BL1                     STATUS FLAGS                     69000013
XRBEPA   DS    0F                  ENTRY POINT ADDRESS FOR VMS          69200013
XRBUSE   DS    CL1                     USE COUNT                        69400013
XRBEP    DS    CL3                     ENTRY POINT ADDRESS              69600013
XRBPSW   DS    CL8                 SAVE AREA FOR RESUME PSW             69800013
XRBQ     DS    0F                      ADDR OF 12 * REQUEST ELEMENT SSS 70000013
XRBATTCH DS    CL1                     ATTATCH USE COUNT  VMS           70200013
XRBIQE   DS    CL3                     ADDR OF 16 * REQ ELEMENT  VMS    70400013
XRBWT    DS    CL1                 WAIT COUNT                           70600013
XRBLINK  DS    CL3                 RB CHAINING FIELD                    70800013
XRBREG   DS    16F                 GENERAL REGISTER SAVE AREA           71000013
XRBEXSA  DS    2F                  EXTENDED WORK/SAVE AREA IF REQUESTED 71200013
         SPACE 2                                                        71400013
CURSVRB  DSECT                                                          71600013
         DS    8F                  PADDING TO GET TO REG SAVE AREA      71800013
EXITEP   DS    1F                  ADDR OF EP TO EXIT RTN USING RB      72000013
REG1     DS    0F                  INDICATOR BITS AND WORK AREA SIZE    72200013
PARMFLG1 DS    CL1                 FIRST FLAG BYTE                      72400013
PARMDIRB EQU   X'80'                   DIRB IS REQUESTED                72600013
PARMKEY  EQU   X'04'                   KEY IS FOR PROBLEM PROGRAM       72800013
PARMMODE EQU   X'02'                   MODE IS FOR PROBLEM STATE        73000013
PARMSAVE EQU   X'01'                   SAVE AREA IS REQUESTED           73200013
PARMFLG2 DS    CL1                 SECOND FLAG BYTE                RORI 73300015
PARMIQE  EQU   X'08'                   DO NOT RETURN IQES AT EXIT  RORI 73400015
PARMWORK DS    1H                  SIZE OF WORK AREA REQUEST (DBL WDS)  73600013
         END                                                            73800013
