IGC056   CSECT                                                          00200016
* ROUTINE NAME                                                          00400016
*        IEAAENQ0-ENQUEUE AND RESERVE SERVICE ROUTINE                   00600016
         SPACE 3                                                        00800016
* FUNCTIONS                                                             01000016
*        1-PERFORM PCP ENQ PROCESSING                                   01200016
*        2-PERFORM RESERVE PROCESSING FOR A SERIALLY REUSABLE RESOURCE  01400016
         SPACE 3                                                        01600016
* ENTRY POINT NAME                                                      01800016
*        IGC056                                                         02000016
         SPACE 3                                                        02400016
* ATTRIBUTES                                                            02600016
*        1-TRANSIENT, BUT MAY BE SPECIFIED AS RESIDENT DURING SYSGEN    02800016
*        2-REENTRANT                                                    03000016
*        3-IN SUPERVISOR STATE                                          03200016
*        4-TYPE 3 SVC WHEN TRANSIENT AND TYPE 2 WHEN RESIDENT           03400016
*        5-DISABLED                                                     03600016
         SPACE 3                                                        03800016
* APPLICABILITY                                                         04000016
*        OPTION 1 WITH SHARED DASD                                      04200016
         SPACE 3                                                        04400016
* EXTERNAL REFERENCE                                                    04600016
*        IEA0VL00-SUPERVISOR VALIDITY CHECK ROUTINE                     04800016
         SPACE 3                                                        05000016
* SVC'S USED                                                            05200016
*        1-SVC 10 REGISTER FORM OF GETMAIN                              05400016
*        2-SVC 13 ABEND                                                 05600016
         SPACE 3                                                        05800016
* INPUT                                                                 06000016
*        REGISTER ONE CONTAINS THE ADDRESS OF A PARAMETER LIST          06200016
*        BEGINNING ON A FULL WORD BOUNDARY IN CALLERS OWN STORAGE AREA. 06400016
*        THE FORMAT OF THE LIST IS SHOWN BELOW.                         06600016
         SPACE 2                                                        06800016
*              *****************************************                07000016
*              *0        *1        *2        *3        *                07200016
*              * LISTEND *MINLNGTH * PARMCDS * RETCODE *                07400016
*              *         *         *         *         *                07600016
*              *****************************************                07800016
*              *4                                      *                08000016
*              *   ADDRESS OF MAJOR RESOURCE NAME      *                08200016
*              *                                       *                08400016
*              *****************************************                08600016
*              *8                                      *                08800016
*              *   ADDRESS OF MINOR RESOURCE NAME      *                09000016
*              *                                       *                09200016
*              *****************************************                09400016
*              *12                                     *                09600016
*              *          ADDRESS OF A UCB             *                09800016
*              *                                       *                10000016
*              *****************************************                10200016
         SPACE 3                                                        10400016
* OUTPUT FOR ENQ                                                        10600016
*        ENQ IN THIS ENVIRONMENT IS A NOP AND NO OUTPUT IS GIVEN        10800016
         SPACE                                                          11000016
* OUTPUT FOR RESERVE                                                    11200016
*        A MAJOR QUEUE CONTROL BLOCK IF THE RESOURCE WAS NOT PREVIOUSLY 11400016
*        REQUESTED AND IF THE RET= PARAMETER SPECIFIES SUCH.            11600016
         SPACE                                                          11800016
*        A MINOR QUEUE CONTROL BLOCK IF THE RESOURCE WAS NOT PREVIOUSLY 12000016
*        REQUESTED AND IF THE RET= PARAMETER SPECIFIES SUCH.            12200016
         SPACE 3                                                        12400016
* ENTRY POINT                                                           12600016
*        IGC056 ENTERED FROM THE SVC INTERUPT HANDLER BY A              12800016
*          LPSW INSTRUCTION.                                            13000016
         SPACE 3                                                        13200016
* EXIT POINT                                                            13400016
*        1-NORMAL                                                       13600016
*          TO THE CALLER VIA A BRANCH ON REGISTER FOURTEEN              13800016
*        2-ERROR                                                        14000016
*          TO ABEND WITH THE FOLLOWING ERROR CODES                      14200016
*           238-INVALID RNAME LENGTH                                    14400016
*           438-INVALID PARAMETER LIST                                  14600016
*           138-A REQUEST WAS ISSUED FOR A RESOURCE ON WHICH THAT TASK  15000016
*               ALREADY HAD A REQUEST                                   15200016
         SPACE 3                                                        15400016
* TABLES AND CONTROL BLOCKS REFERENCED                                  15600016
*        1-CVT                                                          15800016
*           ADDRESS OF VALIDITY CHECK ROUTINE                           16000016
*           ADDRESS OF MAJOR QCB ORIGIN                                 16200016
*        2-TCB                                                          16400016
*           PROTECT KEY                                                 16600016
*           RESERVE COUNT                                               16800016
*        3-UCB                                                          17000016
*           RESERVE COUNT                                               17200016
*           UCB IDENTIFIER                                              17400016
*        4-REQUEST BLOCK                                                17500016
*           RESUME PSW                                                  17600016
*           LINK FIELD                                                  17700016
*        5-MAJOR QCB                                                    18000016
*           ALL FIELDS                                                  18200016
*        6-MINOR QCB                                                    18400016
*           ALL FIELDS                                                  18600016
         SPACE 3                                                        18800016
* NOTES                                                                 19000016
*        NONE                                                           19200016
         EJECT                                                          19400016
*   REGISTER ASSIGNMENT                                                 19800016
WORKREG0 EQU   0                        GENERAL USE                     20000016
ABENDREG EQU   1                        ABEND CODE REGISTER             20200016
PARMREG  EQU   1                        PARAMETER LIST REGISTER         20400016
CVTREG   EQU   3                        ADDRESS OF CVT                  20600016
TCBREG   EQU   4                        ADDRESS OF TCB                  20800016
TESTREG  EQU   5                        USED FOR COMPARAND              21000016
TEMPREG  EQU   5                        USED TO HOLD TEMPORARY DATA     21100016
RBREG    EQU   5                        ADDRESS OF RB                   21200016
CHKREG   EQU   6                        USED FOR COMPARAND              21300016
WORKREG1 EQU   6                        GENERAL USE                     21400016
INPUTREG EQU   7                        INPUT TO VALIDITY CHECK         21600016
WORKREG2 EQU   7                        GENERAL USE                     21800016
CHKBASE  EQU   8                        VALIDITY CHECK BASE             22000016
WORKREG3 EQU   8                        GENERAL USE                     22200016
TCBCREG  EQU   9                        TCB REG FOR VALIDITY CHECK      22400016
CURMAJ   EQU   9                        CURRENT MAJOR QCB               22600016
WORKREG4 EQU   9                        GENERAL USE                SDA2 22700017
CURMIN   EQU   10                       CURRENT MINOR TCB               22800016
LKREG2   EQU   10                       LINK TO SUBROUTINES             23000016
BASE     EQU   12                       BASE REGISTER                   23200016
LKREG    EQU   11                       LINK TO SUBROUTINES             23400016
RETREG   EQU   14                       RETURN ADDRESS REGISTER         23600016
CODEREG  EQU   15                       RETURN CODE REGISTER            23800016
*   DISPLACEMENTS IN PARAMETER LIST                                     24000016
MINLNGTH EQU   1                        LENGTH BYTE IN PARAMETER LIST   24200016
RNAMELTH EQU   1                        LENGTH OF RNAME IN PARM LIST    24400016
PARMCDS  EQU   2                        FLAG BYTE IN PARAMETER          24600016
RETCODE  EQU   3                        RETURN CODE IN PARAMETER LIST   24800016
RETURN   EQU   3                        RETURN CODE BYTE IN PARM LIST   25000016
MAJNAME  EQU   4                        QNAME IN PARAMETER LIST         25200016
MINNAME  EQU   8                        ADDRESS OF RNAME IN PARM LIST   25400016
UCBADDR  EQU   12                       UCB ADDRESS IN PARAMETER LIST   25600016
*   DISPLACEMENTS IN MAJOR QCB                                          25800016
NEXTMAJ  EQU   0                        ADDRESS OF NEXT MAJOR           25900016
PREVMAJ  EQU   4                        ADDRESS OF PREVIOUS MAJOR       26000016
QCBMIN   EQU   8                        ADDRESS OF MINOR QCB IN MAJOR   26200016
QNAME    EQU   12                       QNAME IN MAJOR QCB              26400016
*   DISPLACEMENTS IN MINOR QCB                                          26600016
MINUCB   EQU   0                        ADDRESS OF UCB IN MINOR         26800016
PREVMIN  EQU   4                        ADDRESS OF PREVIOUS MINOR       27000016
MINMINOR EQU   8                        ADDRESS OF NEXT MINOR           27200016
MINLNTH  EQU   12                       RNAME LENGTH IN MINOR QCB       27400016
PTKEY    EQU   13                       PROTECT KEY IN MINOR            27600016
MINAME   EQU   14                                                       27700016
*   DISPLACEMENTS IN TCB                                                27800016
TCBRESV  EQU   34                       RESERVE COUNT IN TCB            28000016
TCBPKF   EQU   28                       PROTECT KEY IN TCB              28200016
*   DISPLACEMENTS IN CVT                                                28400016
CVT0VL00 EQU   24                       ADDRESS OF VALIDITY CHECK       28600016
CVTNUCB  EQU   128                     ADR LOWEST BOUNDARY NOT IN NUC   28700017
CVTQCBO  EQU   148                      QCB ORIGIN IN CVT               28800016
CVTMZ00  EQU   164                      HIGH MACHINE ADDRESS            28900016
*   DISPLACEMENT IN UCB                                                 29000016
UCBID    EQU   2                        ID FIELD IN UCB                 29060016
UCBTYP   EQU   16                       DEVICE TYPE FIELD IN UCB        29120016
UCBRESV  EQU   40                       RESERVE COUNT IN UCB            29200016
DCELBBNR EQU   0                        BIN # IN SUB-UCB           SDA2 29250017
UCBSIZE  EQU   56                       SIZE OF MAIN UCB           SDA2 29300017
*   DISPLACEMENTS IN RB                                                 29360016
RBPSW    EQU   16                       USER'S OLD PSW                  29370016
RBLINK   EQU   28                       LINK FIELD                      29380016
*   GENERAL OFFSETS                                                     29382016
ZERO     EQU   0                                                        29384016
ONE      EQU   1                                                        29386016
SEVEN    EQU   7                                                        29388016
END      EQU   15                                                       29390016
         EJECT                                                          29392016
         BALR  BASE,0                   ESTABLISH ADDRESSABILITY        29400016
         USING *,BASE                                                   29600016
*                                                                       29800016
*   SET INTERFACE BETWEEN VALIDITY CHECK ROUTINES                       30000016
*                                                                       30200016
         TM    PARMCDS(PARMREG),X'40'   DETERMINE IF REQUEST IS RESERVE 30400016
*                                       OR ENQ                          30600016
         BO    ENQEXIT                  TAKE BRANCH IF ENQ REQUEST      30800016
         TM    PARMCDS(PARMREG),X'08'   IS RESERVE BIT ON               31000016
         BZ    ENQEXIT                  TAKE BRANCH IF NOT              31200016
*                                                                       31400016
*   AT THIS POINT WE HAVE DETERMINED THAT THIS REQUEST IS A RESERVE     31600016
*                                                                       31800016
ENQTOP   BAL   LKREG,VALTEST            GO TO VALIDITY TEST ROUTINE     32000016
         BAL   LKREG,FINDMAJ            GO LOOK FOR MAJOR QCB           32200016
         LTR   CURMAJ,CURMAJ            DOES ONE EXIST                  32400016
         BP    ENQTOP1                  YES GO LOOK FOR MINOR           32600016
         TM    PARMCDS(PARMREG),X'07'   WAS RET=TEST SPECIFIED          32800016
         BO    RET0                     YES GO SET RETURN CODE AND EXIT 33000016
         B     CREATE1                  GO CREATE MAJOR AND MINOR QCB   33200016
ENQTOP1  BAL   LKREG,FINDMIN            GO LOOK FOR MINOR QCB           33400016
         LTR   CURMIN,CURMIN            DOES MINOR EXIST                33600016
         BP    ENQTOP2                  TAKE BRANCH IF YES              33800016
         TM    PARMCDS(PARMREG),X'07'   WAS RET=TEST SPECIFIED          34000016
         BO    RET0                     YES GO SET AVAILABLE CODE       34200016
         B     CREATE2                  GO CREATE MINOR QCB             34400016
ENQTOP2  TM    PARMCDS(PARMREG),X'07'   RET=TEST, USE, OR HAVE          34600016
         BZ    ERREXIT1                 NO ABEND THE REQUESTOR          34800016
         MVI   RETURN(PARMREG),X'08'    SET RETURN CODE (HAS RESOURCE)  35000016
         LR    CODEREG,PARMREG          POINT RET CODE TO PARM LIST     35100016
EXIT     BR    RETREG                   RETURN TO CALLER                35200016
ENQEXIT  SR    CODEREG,CODEREG          SET RETURN CODE TO ZERO         35260016
         BR    RETREG                   RETURN TO CALLER                35320016
*                                                                       35400016
*   THIS ROUTINE PERFORMS ALL VALIDITY CHECKING                         35600016
*                                                                       35800016
VALTEST  L     CHKREG,RBLINK(RBREG)     GET ISSUING RB                  36000016
         TM    RBPSW+1(CHKREG),X'F0'    IS PROTECT KEY ZERO             36200016
         BC    8,TESTUCB                GO TEST UCB FOR DIRECT ACCESS   36400016
*                                       AND SHARED CHARACTERISTICS      36600016
         TM    ZERO(PARMREG),X'FF'                                      36650016
         BC    12,ERREXIT               PARM LIST WITHOUT FF IN 1ST     36700016
*                                       BYTE                            36750016
         LR    INPUTREG,PARMREG         ADDRESS TO CHECK                36800016
         LA    INPUTREG,ZERO(INPUTREG)  CLEAR HI ORDER BYTE             36900016
         EX    INPUTREG,CHKALIGN        GO CHECK ALIGNMENT              37000016
         BC    7,ERREXIT                BAD-TAKE BRANCH                 37200016
         L     CHKBASE,CVT0VL00(CVTREG) ADDRESS OF VALIDITY CHECK       37400016
         LR    TCBCREG,TCBREG                                           37600016
         BAL   WORKREG1,ENTER           GO TO VALIDITY CHECK            37800016
         LA    INPUTREG,END(INPUTREG)   GET LAST BYTE OF ENTRY          38000016
         BAL   WORKREG1,ENTER           GO CHECK IT                     38200016
         L     INPUTREG,MAJNAME(PARMREG) ADDRESS OF MAJOR NAME          38400016
         LA    INPUTREG,ZERO(INPUTREG)  CLEAR HI ORDER BYTE             38700016
         BAL   WORKREG1,CHKSIZE         CHECK TO SEE IF IN MACHINE      38900016
         L     INPUTREG,MAJNAME(PARMREG) ADDRESS OF MAJOR NAME          39200016
         LA    INPUTREG,SEVEN(INPUTREG) GET LAST BYTE OF NAME           39400016
         BAL   WORKREG1,CHKSIZE         CHECK TO SEE IF IN MACHINE      39600016
         L     INPUTREG,MINNAME(PARMREG)  ADDRESS OF MINOR NAME         39800016
         LA    INPUTREG,ZERO(INPUTREG)  CLEAR HI ORDER BYTE             40100016
         BAL   WORKREG1,CHKSIZE         CHECK TO SEE IF IN MACHINE      40300016
         L     WORKREG1,MINNAME(PARMREG)                                40600016
         LA    WORKREG1,ZERO(INPUTREG)  CLEAR HI ORDER BYTE             40700016
         SR    INPUTREG,INPUTREG        CLEAR FOR INSERT CHARACTER      40800016
         IC    INPUTREG,MINLNGTH(PARMREG) PICK UP LENGTH OF MINOR       41000016
         LTR   INPUTREG,INPUTREG        IS IT ZERO                      41200016
         BC    7,ADDIT                  NO, ADD IT TO ADDRESS           41400016
         IC    INPUTREG,ZERO(WORKREG1)  PICK UP LENGTH FROM NAME FIELD  41600016
         LTR   INPUTREG,INPUTREG        IS IT ZERO                      41800016
         BZ    BADLTH                   YES ABEND THE TASK              42000016
ADDIT    BCTR  INPUTREG,0               REDUCE BY ONE                   42200016
NOSUB    AR    INPUTREG,WORKREG1        COMPUTE ADDR OF LAST BYTE       42400016
         BAL   WORKREG1,CHKSIZE         CHECK TO SEE IF IN MACHINE      42600016
TESTUCB  L     INPUTREG,UCBADDR(PARMREG) PICK UP PTR TO UCB             42800016
         EX    INPUTREG,CHKALIGN        TEST FOR WORD BOUNDARY          42840016
         BC    7,ERREXIT                NO-TAKE BRANCH                  42880016
         BAL   WORKREG1,CHKSIZE         CHECK TO SEE IF IN MACHINE      42940016
         L     INPUTREG,ZERO(INPUTREG)  PICK UP UCB ADDRESS             43000016
         BAL   WORKREG1,CHKSIZE         CHECK TO SEE IF IN MACHINE      43060016
         BH    ERREXIT                  NO-TAKE BRANCH                  43120016
         TM    UCBID(INPUTREG),X'FF'    IS THIS A UCB                   43200016
         BC    14,SUBUCB                TEST FOR SUB-UCB           SDA2 43400017
GOODUCB  EX    INPUTREG,CHKALIGN        CHECK ALIGNMENT            SDA2 43600017
         BC    7,ERREXIT                BAD-TAKE BRANCH                 43800016
         TM    UCBTYP+1(INPUTREG),X'20' IS THIS A SHARABLE DEVICE       44000016
         BZ    ENQEXIT                  NO-TURN REQUEST INTO AN ENQ     44200016
         TM    UCBTYP+2(INPUTREG),X'20' IS THIS A DIRECT ACCESS DEVICE  44400016
         BZ    ENQEXIT                  NO-TURN REQUEST INTO AN ENQ     44700016
*                                                                       45000016
*   VALID LIST, PREPARE TO RETURN                                       45200016
*                                                                       45400016
         BR    LKREG                    RETURN TO MAINLINE              45600016
SUBUCB   LH    WORKREG3,DCELBBNR(INPUTREG) GET BIN #               SDA2 45603017
         SLL   WORKREG3,4               MULTIPLY BY 16             SDA2 45606017
         LA    WORKREG3,UCBSIZE(WORKREG3)   ADD SIZE OF MAIN UCB   SDA2 45609017
         SR    INPUTREG,WORKREG3                                   SDA2 45612017
         TM    UCBID(INPUTREG),X'FF'    IS THIS A UCB              SDA2 45615017
         BC    14,ERREXIT               NO-ABEND                   SDA2 45618017
         L     WORKREG1,UCBADDR(PARMREG) GET PTR TO UCB            SDA2 45621017
         ST    INPUTREG,ZERO(WORKREG1)  ALTER PARAMETER LIST       SDA2 45624017
         B     GOODUCB                                             SDA2 45627017
CHKSIZE  LA    INPUTREG,ZERO(INPUTREG)                                  45630016
         CL    INPUTREG,CVTMZ00(CVTREG) IS ADDRESS IN MACHINE           45660016
         BC    2,ERREXIT                NO-TAKE BRANCH                  45700016
         BR    WORKREG1                 RETURN TO MAINLINE              45750016
BADLTH   LA    ABENDREG,X'238'          INVALID RNAME LENGTH            45800016
          B     ABEND                                                   46000016
ENTER    BALR  LKREG2,CHKBASE           GO TO IEA0VL00                  46200016
         BC    7,ERREXIT               BAD LIST-BRANCH              LCS 46300017
         CL    INPUTREG,CVTNUCB(CVTREG) IS ADR ABOVE NUCLEUS        LCS 46400017
         BCR   11,WORKREG1             GOOD LIST                    LCS 46500017
ERREXIT  LA    ABENDREG,X'438'          BAD INPUT LIST                  46600016
         B     ABEND                    SCHEDULE ABNORMAL TERMINATION   46800016
ERREXIT1 LA    ABENDREG,X'138'                                          47300016
ABEND    SLL   ABENDREG,12                                              47800016
         ABEND (1),DUMP                                                 48000016
*                                                                       48200016
*   AT THIS POINT, THE RESOURCE IS AVAILABLE AND RET=TEST WAS SPECIFIED 48400016
*                                                                       48600016
RET0     MVI   RETCODE(PARMREG),X'00'   SET AVAILABLE RETURN CODE       48800016
         SR    CODEREG,CODEREG                                          48900016
         BR    RETREG                                                   49000016
*********************************************************************** 49200016
*   THIS ROUTINE ATTEMPTS TO FIND A MAJOR QCB BY THE SAME NAME AS THAT* 49400016
*   GIVEN IN THE CURRENT PARAMETER LIST ENTRY. IF SUCCESSFUL, THE     * 49600016
*   ROUTINE EXITS WITH 'CURMAJ' POINTING TO THE MAJOR QCB WITH THE    * 49800016
*   SAME NAME. IF NOT SUCCESSFUL, THE ROUTINE EXITS WITH CURMAJ       * 50000016
*   HAVING THE COMPLEMENT ADDRESS OF LAST MAJOR QCB ON QUEUE.         * 50200016
*********************************************************************** 50400016
FINDMAJ  SR    WORKREG3,WORKREG3        CLEAR FOR COMPARAND             50600016
         L     CURMAJ,CVTQCBO(CVTREG)   GET QCB ORIGIN FROM CVT         50800016
         LTR   CURMAJ,CURMAJ                                            51000016
         BCR   8,LKREG                  RETURN WITH NO MAJOR            51200016
         L     WORKREG1,MAJNAME(PARMREG) GET ADDRESS OF MAJOR NAME      51400016
FINDMAJ1 CLC   ZERO(8,WORKREG1),QNAME(CURMAJ) SAME MAJOR NAME           51600016
         BCR   8,LKREG             RETURN WITH ADDRESS OF MAJOR         51800016
         C     WORKREG3,NEXTMAJ(CURMAJ) IS THIS LAST ON CHAIN           52000016
          BE   FINDMAJ2                  YES-GO COMPLEMENT ADDRESS      52200016
         L     CURMAJ,NEXTMAJ(CURMAJ)   PICK UP NEXT MAJOR QCB          52400016
         B     FINDMAJ1                 GO BACK THROUGH LOOP            52600016
FINDMAJ2 LCR   CURMAJ,CURMAJ             COMPLEMENT ADDRESS TO INDICATE 52800016
         BR    LKREG                    NO MAJOR QCB AND RETURN         53000016
*********************************************************************** 53200016
*   THIS ROUTINE ATTEMPTS TO FIND A MINOR QCB BY THE SAME NAME AS THAT* 53400016
*   GIVEN IN THE CURRENT PARAMETER LIST ENTRY. IF SUCCESSFUL, THE     * 53600016
*   ROUTINE EXITS WITH 'CURMIN' POINTING TO THE MINOR QCB OF THE SAME * 53800016
*   NAME. IF NOT SUCCESSFUL, THIS ROUTINE EXITS WITH 'CURMIN'         * 54000016
*   HAVING COMPLEMENT ADDRESS OF LAST MINOR QCB.                      * 54200016
*********************************************************************** 54400016
FINDMIN  SR    WORKREG1,WORKREG1        CLEAR FOR INSERT CHARACTER      54600016
         LR    WORKREG3,WORKREG1                                        54800016
          L    WORKREG2,MINNAME(PARMREG) ADDRESS OF MINOR NAME          55000016
         IC    WORKREG1,RNAMELTH(PARMREG) PICK UP LENGTH OF RNAME       55200016
         LTR   WORKREG1,WORKREG1        IS IT ZERO                      55400016
         BC    7,SUBTRACT               TAKE BRANCH IF NO               55600016
         IC    WORKREG1,ZERO(WORKREG2)  PICK UP LENGTH FROM NAME FIELD  56000016
         LA    WORKREG2,ONE(WORKREG2)   SKIP OVER LENGTH BYTE           56300016
SUBTRACT BCTR  WORKREG1,0               DECREMENT LENGTH FOR EXECUTE    56600016
         L     CURMIN,QCBMIN(CURMAJ)    PICK UP FIRST MINOR QCB         56800016
         LTR   CURMIN,CURMIN            IS THERE A MINOR                57000016
         BCR   8,LKREG                                                  57200016
         SR    TESTREG,TESTREG          CLEAR FOR INSERT CHARACTER      57400016
FINDMIN1 IC    TESTREG,MINLNTH(CURMIN)                                  57600016
         BCTR  TESTREG,0                DECREMENT BY ONE                57800016
         CR    TESTREG,WORKREG1         COMPARE LENGTHS                 58000016
         BNE   TESTNEXT                 UNEQUAL TAKE BRANCH             58200016
         EX    WORKREG1,CHEKNAME                                        58400016
         BCR   8,LKREG                  RETURN WITH ADDRESS OF MINOR IF 58600016
*                                       EQUAL                           58800016
TESTNEXT C     WORKREG3,MINMINOR(CURMIN)                                59000016
         BE    FINDMIN2                                                 59200016
         L     CURMIN,MINMINOR(CURMIN)  PICK UP NEXT MINOR              59400016
          B    FINDMIN1                 GO BACK THROUGH LOOP            59600016
FINDMIN2 LCR   CURMIN,CURMIN                                            59800016
         BR    LKREG                                                    60000016
*********************************************************************** 60200016
*   THIS ROUTINE IS ENTERED WHEN A QCB WITH THE SAME MAJOR NAME AS    * 60400016
*   THAT IN THE CURRENT PARAMETER LIST DOES NOT EXIST. IT ISSUES A    * 60600016
*   GETMAIN FOR A QCB, INITIALIZES THE QCB AND QUEUES IT ON THE CHAIN * 60800016
*   OF MAJORS.                                                        * 61000016
*********************************************************************** 61200016
CREATE1  LR    TEMPREG,PARMREG          TRANSFER INPUT PARMS            61400016
         GETMAIN R,LV=20                                                61600016
         XC    ZERO(20,PARMREG),ZERO(PARMREG) CLEAR GOTTEN CORE         61800016
         LCR   CURMAJ,CURMAJ            RECOMPLEMENT LAST MAJOR ADDR    62000016
         L     WORKREG1,MAJNAME(TEMPREG) ADDRESS OF MAJOR NAME          62200016
         MVC   QNAME(8,PARMREG),0(WORKREG1)  MOVE QNAME INTO QCB        62400016
         LTR   CURMAJ,CURMAJ            ID THIS FIRST MAJOR             62600016
         BC    8,CREATE12                                               62800016
         ST    CURMAJ,PREVMAJ(PARMREG)  SET NEW TO PREVIOUS             63000016
         ST    PARMREG,NEXTMAJ(CURMAJ)  SET PREVIOUS TO NEW             63200016
         SR    WORKREG2,WORKREG2                                        63400016
         ST    WORKREG2,NEXTMAJ(PARMREG) PUT ZEROES IN NEXT             63600016
CREATE11 LR    CURMAJ,PARMREG           SET NEW CURRENT MAJOR           63800016
         LR    PARMREG,TEMPREG          RESTORE INPUT PARMS             64000016
         SR    CURMIN,CURMIN            SET CURRENT MINOR REG           64200016
         B     CREATE2                                                  64400016
CREATE12 ST    PARMREG,CVTQCBO(CVTREG)  SET QCB ORIGIN IN CVT           64600016
         ST    CURMAJ,NEXTMAJ(PARMREG)   SET NWXT TO ZERO               64800016
         LA    WORKREG2,CVTQCBO(CVTREG)                                 65000016
         ST    WORKREG2,PREVMAJ(PARMREG) SET PREVIOUS IN NEW            65200016
         B     CREATE11                                                 65400016
*********************************************************************** 65600016
*   THIS ROUTINE IS ENTERED EITHER WHEN A MAJOR QCB WAS FOUND BUT     * 65800016
*   NO MINOR EXISTED OR WHEN NO MAJOR WXISTED AND ONE WAS BUILT BY THE* 66000016
*   CREATE1 ROUTINE ABOVE. IT BUILDS, INITIALIZES, AND QUEUES THE NEW * 66200016
*   MINOR ON THE PROPER MAJOR.                                        * 66400016
*********************************************************************** 66600016
CREATE2  LR    TEMPREG,PARMREG          TRANSFER INPUT PARAMETERS       66800016
         SR    WORKREG1,WORKREG1        CLEAR FOR INSERT CHARACTER      67000016
         L     WORKREG2,MINNAME(TEMPREG)                                67100016
         IC    WORKREG1,RNAMELTH(TEMPREG) PICK UP LENGTH FROM PARM LIST 67200016
         LTR   WORKREG1,WORKREG1        IS IT ZERO                      67400016
         BC    7,OK                     TAKE BRANCH IF NOT              67600016
         LA    WORKREG2,ONE(WORKREG2)   INCREMENT OVER LENGTH BYTE      67800016
         IC    WORKREG1,ZERO(WORKREG2)                                  68000016
OK       LA    WORKREG0,MINAME(WORKREG1) COMPUTE SIZE OF MINOR          68200016
         GETMAIN R,LV=(0)                                               68400016
         L     WORKREG3,UCBADDR(TEMPREG) GET UCB ADDRESS                68600016
         MVC   MINUCB(4,PARMREG),0(WORKREG3)  PUT UCB IN MINOR          68800016
         MVI   MINUCB(PARMREG),X'00'    ZERO HI ORDER BYTE              68900016
         LCR   CURMIN,CURMIN            RECOMPLEMENT CURRENT MINOR      69000016
         LTR   CURMIN,CURMIN            IS THIS FIRST MINOR             69200016
         BC    8,CREATE22               YES TAKE BRANCH                 69400016
         ST    CURMIN,PREVMIN(PARMREG)  SET NEW TO PREVIOUS             69600016
         ST    PARMREG,MINMINOR(CURMIN) SET PREVIOUS TO NEW             69800016
         SR    WORKREG3,WORKREG3                                        70000016
         ST    WORKREG3,MINMINOR(PARMREG) SET NEXT TO ZERO              70200016
CREATE21 STC   WORKREG1,MINLNTH(PARMREG) SET RNAME LENGTH               70400016
         MVC   PTKEY(1,PARMREG),TCBPKF(TCBREG)  SET PROTECT KEY         70600016
         BCTR  WORKREG1,0               REDUCE FOR EXECUTE              70800016
         L     WORKREG3,MINNAME(TEMPREG)                                71000016
         EX    WORKREG1,MOVENAME        PUT MINOR NAME IN QCB           71200016
         LR    PARMREG,TEMPREG          RESTORE INPUT                   71400016
         SR    WORKREG1,WORKREG1        CLEAR FOR INSERT CHARACTER      71600016
         IC    WORKREG1,TCBRESV(TCBREG) PICK UP RESEREVE COUNT IN TCB   71800016
         LA    WORKREG1,1(WORKREG1)     INCREMENT BY ONE                72000016
         STC   WORKREG1,TCBRESV(TCBREG) REPLACE IT                      72200016
         L     WORKREG3,UCBADDR(TEMPREG) PTR TO UCB                     72260016
         L     WORKREG3,ZERO(WORKREG3)                                  72340016
         IC    WORKREG1,UCBRESV(WORKREG3) GET UCB RESERVE COUNT         72420016
         LA    WORKREG1,ONE(WORKREG1)   INCREMENT BY ONE                72520016
         STC   WORKREG1,UCBRESV(WORKREG3) PUT IT BACK                   72620016
         TM    PARMCDS(PARMREG),X'07'   ANY RETURN CODES                73000016
         BCR   8,RETREG                 RETURN TO CALLER                73200016
         MVI   RETURN(PARMREG),X'00'    SET AVAILABLE RETURN CODE       73400016
         SR    CODEREG,CODEREG                                          73500016
         BR    RETREG                   RETURN TO CALLER                73600016
CREATE22 ST    CURMAJ,PREVMAJ(PARMREG)  SET NEW TO MAJOR                73800016
         ST    CURMIN,MINMINOR(PARMREG) SET NEXT TO ZERO                74000016
         ST    PARMREG,QCBMIN(CURMAJ)   SET MAJOR TO MINOR              74200016
         B     CREATE21                                                 74400016
CHEKNAME CLC   ZERO(0,WORKREG2),MINAME(CURMIN)                          74600016
MOVENAME MVC   MINAME(0,PARMREG),ZERO(WORKREG3)                         74800016
CHKALIGN TM    WORD,X'00'                                               75000016
WORD     DC    X'03'                    FULL WORD MASK                  75200016
         END                                                            75400016
