         TITLE 'RESIDENT JOB Q ROUTINE FOR PCP,MFT'                     00020000
IEAAJOBQ CSECT                                                          00040000
*0051038200-038400,039600,040400,052000-054400,055600              1450 00050015
  SPACE  2                                                              00060000
* FUNCTION                                                              00080000
*  THIS ROUTINE RECEIVES CONTROL ( VIA A BRANCH) FROM IOS AFTER AN      00100000
*  EXCP REQUEST TO A D.A. DEVICE PASSES THRU THE EXCP VALIDITY          00120000
*  CHECK SUBROUTINE BUT BEFORE AN RQE IS GOTTEN.  THIS ROUTINE DETER-   00140000
*  MINES IF THE REQUEST IS A READ OR WRITE TO THE JOB Q- SEE PROG.      00160000
*  NOTES BELOW FOR A DESCRIPTION OF THE 'ACCEPTABLE' CHANNEL PROG.      00180000
*  IF NOT SUCH A REQUEST, CONTROL IS RETURNED TO IOS AND THE REQUEST    00200000
*  CONTINUES THRU EXCP (AN RQE IS GOTTEN,...).  IF IT IS 'ACCEPTABLE'   00220000
*  JOB Q REQUEST, AND THE RECORD SOUGHT IS WITHIN THE RESIDENT Q        00240000
*  AREA, THE RECORD IS MOVED AND THE BRANCH ENTRY TO POST IS            00260000
*  USED TO POST THE ECB ASSOCIATED WITH THE REQUEST.  POST THEN         00280000
*  RETURNS TO IOS AND AN EXIT IS TAKEN FROM EXCP.                       00300000
  SPACE  2                                                              00320000
*  ENTRY                                                                00340000
*  THIS ROUTINE IS ENTERED AT IEAAJOBQ WHENEVER AN EXCP REQUEST IS      00360000
*  DIRECTED TO AN D.A. DEVICE.  IT IS ENTERED IN SUPV. STATE, SUPV.     00380000
*  PROTECTION KEY AND DISABLED.                                         00400000
  SPACE  2                                                              00420000
*  INPUT                                                                00440000
*  THIS ROUTINE IS PASSED A NUMBER OF POINTERS (IN REGISTERS) FROM IOS  00460000
*  THAT ARE ASSOCIATED WITH THIS EXCP REQUEST.                          00480000
*  IOB ADDR. IN REGISTER 2                                              00500000
*  DEB ADDR. IN REGISTER 3                                              00520000
*  DCB ADDR. IN REGISTER 4                                              00540000
*  UCB ADDR. IN REGISTER 7                                              00560000
*  IOS RETURN ADDR. IN REGISTER 14                                      00580000
  SPACE  2                                                              00600000
*  OUTPUT                                                               00620000
*  IF AN 'ACCEPTABLE' JOB Q REQUEST IS HANDLED BY THIS ROUTINE, THE     00640000
*  JOB Q RECORD WILL BE MOVED TO OR FROM THE RESIDENT Q AREA, AND THE   00660000
*  ECB WILL BE POSTED WITH A '7F' COMPLETION CODE.  THE INFO NORMALLY   00680000
*  PLACED IN THE IOB AS A RESULT OF A SIO THE ENSUING INTERRUPT WILL    00700000
*  NOT BE PLACED IN THE IOB.                                            00720000
*  IF THE RECORD NUMBER SOUGHT IN THE CHANNEL PROGRAM (SID) IS NOT      00740000
*  VALID(E.G., ZERO OR SOME RECORD NUMBER GREATER THAN THE TRACK        00760000
*  CAPACITY), A CODE OF X'41' IS PLACED IN THE IOB AND POST IS          00780000
*  ENTERED TO ACCOMPLISH POSTING THE ECB.                               00800000
*  OTHERWISE, THE REQUEST WILL CONTINUE THRU IOS.                       00820000
*  THIS ROUTINE DESTROYS CONTENTS OF REGISTERS 1,6,8,9,10,11,12,15      00840000
*  (CLEARS REGISTER 9 AT EXIT AND USES 8 AS A BASE REGISTER).           00860000
  SPACE  2                                                              00880000
*  EXTERNAL REFERENCES                                                  00900000
*  A)  THIS ROUTINE REFERENCES ENTRIES IN                               00920000
*      1)  IEFJOB, THE CSECT CONTAINING THE DCB, DEB, AND CONSTANTS     00940000
*          ASSOCIATED WITH THE JOB Q .                                  00960000
*      2)  THE DEB, IOB, AND CHANNEL PROGRAM ASSOCIATED WITH THE EXCP   00980000
*          REQUEST.                                                     01000000
*  B)  THIS ROUTINE USES THE BRANCH ENTRY TO POST TO POST AN ECB.       01020000
*  C)  THIS ROUTINE USES THE RESIDENT CONVERT ROUTINE TO CONVERT AN     01040000
*      ACTUAL D.A. ADDRESS TO A 'TTRN'.                                 01060000
  SPACE  2                                                              01080000
*  EXITS                                                                01100000
*  IOS BRANCHES TO THIS ROUTINE VIA A BALR 14,15.  THE NEXT             01120000
*  INSTRUCTION IN IOS IS A BRANCH TO THE EXCP EXIT ROUTINE.  IF THIS    01140000
*  ROUTINE INTERCEPTS AND HANDLES AN ACCEPTABLE JOB Q REQUEST, IT       01160000
*  WILL THEN BRANCH TO POST WITH REGISTER 14 POINTING TO THE IOS        01180000
*  INSTRUCTION TO BRANCH TO EXCP EXIT.  (POST THEN RETURNS TO IOS.)     01200000
*  IF THE REQUEST IS NOT ACCEPTABLE OR CAN NOT BE HANDLED, THIS         01220000
*  ROUTINE RETURNS TO IOS BEYOND THE BRANCH TO EXCP EXIT AND THE        01240000
*  REQUEST CONTINUES THRU IOS.                                          01260000
  SPACE  2                                                              01280000
*  TABLES/WORK AREAS                                                    01300000
*  A)  WITHIN THE DEB, IOB, AND CHANNEL PROGRAM ASSOCIATED WITH THE     01320000
*      EXCP REQUEST, THIS ROUTINE REFERS TO                             01340000
*      1)  DEB - DEBPRT, CONTAINS PROTECT KEY                           01360000
*                DEBUCB, CONTAINS ADDRESS OF A UCB                      01380000
*      2)  IOB - IOBECB, CONTAINS ADDRESS OF ECB                        01400000
*                IOBCC, CONTAINS ADDRESS OF A CHANNEL PROGRAM           01420000
*                IOBCCR, CONTAINS CCHHR OF THE SEEK ADDRESS             01440000
*      3)  CHANNEL PROGRAM-THE COMMAND CODES, FLAGS, AND DATA LENGTH    01460000
*                          ARE EXAMINED.                                01480000
*  B)  WITHIN IEFJOB, THE FOLLOWING FIELDS ARE EXAMINED/USED...         01500000
*      JQUCB, UCB FOR THE UNIT CONTAINING THE JOB Q                     01520000
*      JQRPT, CONSTANT DESCRIBING THE NUMBER OF 176-BYTE RECORDS THAT   01540000
*             WILL FIT ON A TRACK OF THE JOB Q                          01560000
*      JQSCATT, 'TT' FOR BEGINNING OF JOB Q VARIABLE AREA               01580000
*      JQCCHHR, AREA USED FOR MBBCCHHR FOR CONVERT ROUTINE'S USE        01600000
*      JQSAVE, 8 WORD REGISTER SAVE AREA                                01620000
*      JQRCD, 2 BYTE SAVE AREA FOR 'RN' OF A 'TTRN'                     01640000
*      JQBYRCD, BYTES/RECORD CONSTANT, EQUAL TO 176                     01660000
*      JQFLAGS, FLAG BYTES (RESERVED)                                   01680000
*      JQRSPEC, NUMBER OF RECORDS SPECIFIED TO BE MADE RESIDENT         01700000
*               (SPECIFIED AT SYSGEN, POSSIBLY OVERRIDEN AT NIP TIME)   01720000
*      JQAREA, CORE POINTER TO BEGINNING OF FIXED AREA RECORDS          01740000
*              (ESTABLISHED BY NIP)                                     01760000
*      JQLPTCB, POINTER TO LOW PRIORITY TCB(0 FOR SSS,PTR FOR SPS)      01780000
*              (ESTABLISHED BY NIP)                                     01800000
*      JQLTTR, TTR FOR FIRST RECORD BEYOND FIXED AREA                   01820000
*             (ESTABLISHED BY IEFINTQA)                                 01840000
*      JQVAREA, CORE POINTER TO VARIABLE AREA RECORDS                   01860000
*             (ESTABLISHED BY IEFINTQA)                                 01880000
*      JQWATTR, TTR FOR FIRST RECORD BEYOND THE INTERPRETER WORK AREA   01900000
*               (IWA)... THIS FIELD ALSO ESTABLISHED BY IEFINTQA        01920000
*      JQCONS, MASK TO ISOLATE BEGINNING TT                             01940000
*      JQMIN26, MINUS 26, USED AS INCREMENT TO ADDRESS RECORDS IN       01960000
*               FIXED AREA BUT BEYOND INTERPRETER WORK AREA             01980000
  SPACE  2                                                              02000000
*  PROGRAMMING NOTES                                                    02020000
*  THE CHANNEL PROGRAM USED BY THE SYSTEM ROUTINES WHICH ACCESS THE     02040000
*  JOB Q CONSISTS OF SID, TIC, RD/WRITE KEY&DATA.  THE RD/WRITE IS NOT  02060000
*  COMMAND CHAINED. FOR A WRITE, THE LENGTH MUST BE EQUAL TO 176 BYTES. 02080015
*  A READ COMMAND MUST BE EQUAL TO OR LESS THAN 176. ANY OTHER CCW      02100015
*  USED TO ACCESS THE JOB Q WILL PASS THRU IOS AND THE SUBSEQUENT       02120000
*  RECORD READ MAY NOT AGREE WITH THE ACTUAL RECORD IF IT RESIDES IN    02140000
*  THE RESIDENT Q.                                                      02160000
  SPACE  2                                                              02180000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 02200000
*                                                                       02220000
* THE FOLLOWING ARE DISPLACEMENTS FROM THE BEGINNING OF IEFJOB TO -     02240000
JQSCATT EQU    104            TT OF BEG. OF VARIABLE AREA               02260000
JQDEB    EQU   52             DEB FOR JOB Q                             02280000
JQUCB    EQU   JQDEB+34       UCB FOR JOB Q                             02300000
JQRPT    EQU   JQUCB+22       REC/TRK                                   02320000
JQCCHHR  EQU   JQRPT+16       SAVE AREA FOR MBBCCHHR ADDRESS            02340000
JQSAVE   EQU   JQCCHHR+8      REG SAVE AREA                             02360000
JQRCD    EQU   JQSAVE+32      SAVE 'RN' OF TTRN                         02380000
JQBYRCD  EQU   JQRCD+2        BYTES/RECORD                              02400000
JQFLAGS  EQU   JQBYRCD+2      FLAG BYTES                                02420000
JQRSPEC  EQU   JQFLAGS+2      NO. REC SPECIFIED TO BE RESIDENT          02440000
JQAREA   EQU   JQRSPEC+2      PTR TO FIXED AREA REC IN CORE             02460000
JQRRES   EQU   JQAREA+4       RESERVED                                  02480000
JQRHIGH  EQU   JQRRES+2       RESERVED                                  02500000
JQLPTCB  EQU   JQRHIGH+2      LOW PRIORITY TCB(0 FOR SSS,PTR FOR SPS)   02520000
JQFRSTTR EQU   JQLPTCB+4      RESERVED                                  02540000
JQLTTR   EQU   JQFRSTTR+4     TTR/FIRST REC BEYOND FIXED AREA           02560000
JQVAREA  EQU   JQLTTR+4       PTR TO VARIABLE AREA REC - NOT USED       02580000
JQCONS   EQU   JQVAREA+4      MASK TO ISOLATE BEG TT                    02600000
JQWATTR  EQU   JQCONS+4       TTR/FIRST RECORD BEYOND IWA               02620000
JQMIN26 EQU    JQWATTR+4      MINUS 26                                  02640000
  SPACE  2                                                              02660000
* DISPLACEMENTS FROM THE BEG. OF AN IOB TO -                            02680000
IOBECB   EQU   5   PTR TO ECB                                           02700000
IOBCC    EQU   16  PTR TO CHANNEL PROG                                  02720000
IOBCCR   EQU   35     CCHHR OF MBBCCHHR FIELD                           02740000
  SPACE  2                                                              02760000
* DISPLACEMENTS FROM BEG. OF DEB TO -                                   02780000
DEBUCB   EQU   33   UCB PTR                                             02800000
DEBPRT   EQU   24                                                       02820000
  SPACE  2                                                              02840000
**********************************************************************  02860000
PPKEY    EQU   X'F0'                                                    02880000
TOTREG   EQU   0   TTRN REG                                             02900000
TSTREG   EQU   1   WHERE TO GO REG                                      02920000
IOBREG   EQU   2   PTR TO IOB                                           02940000
DEBREG   EQU   3   PTR TO DEB                                           02960000
DCBREG   EQU   4   PTR TO DCB                                           02980000
UAREG    EQU   6   PTR TO IEFJOB                                        03000000
UCBREG   EQU   7   PTR TO UCB                                           03020000
ICREG    EQU   9   CHARACTER REG                                        03040000
WKREG1   EQU   10   WORK REG                                            03060000
WKREG2   EQU   11   WORK REG                                            03080000
WKREG3   EQU   12   WORK REG                                            03100000
LNKRG3   EQU   WKREG3                                                   03120000
LNKRG2   EQU   14                                                       03140000
APBSRG   EQU   15                                                       03160000
         EJECT                                                          03180000
*                                                                     * 03200000
*                        RESIDENT JOBQUEUE ROUTINE                      03220000
         SPACE 1                                                        03240000
*              THIS ROUTINE DETERMINES IF THE IO REQUEST IS TO READ OR  03260000
*              WRITE THE JOBQ.IF NOT SUCH A REQUEST,IT CONTINUES IN IOS 03280000
*              IN THE NORMAL MANNER.IF IT IS A JOBQ REQUEST,AND THE     03300000
*              RECORD SOUGHT IS WITHIN THE AREA SPECIFIED AT SYSGEN     03320000
*              THE RECORD IS MOVED TO THE SPECIFIED DATA ADDRESS.THE    03340000
*              POST INTERFACE PORTION OF IOS IS USED TO SET UP TO GO    03360000
*              TO THE POST ROUTINE TO POST THE COMPLETION OF THE        03380000
*              EVENT AND AN EXIT IS ISSUED ON RETURN FROM POST.       * 03400000
*                                                                     * 03420000
*********************************************************************** 03440000
         SPACE 1                                                        03460000
         EXTRN IEFJOB                                                   03480000
         BALR  8,0                                                      03500000
         USING *,8                                                      03520000
         LA    UCBREG,0(0,UCBREG)  CLEAR FILE MASK                      03540000
         L     UAREG,JQIEFJOB      PTR TO IEFJOB                        03560000
         LH    WKREG1,JQUCB(UAREG)  PTR TO JQ UCB                       03580000
         CR    WKREG1,UCBREG           Q.SAME UCB                       03600000
         BC    6,4(0,14)  NO, RETURN TO IOS                             03620000
         ST    LNKRG2,SAVE   SAVE IOS RETURN ADDR                       03640000
         LA    WKREG3,JQDEB(UAREG) PTR TO JQ DEB                        03660000
         CLC   IOBCCR(4,IOBREG),DEBUCB+5(WKREG3)   SKADDR<ST EXT        03680000
         BC    4,XCPNJQ       YES-NOT JQ REQ                            03700000
         CLC   IOBCCR(4,IOBREG),DEBUCB+9(WKREG3)   SKADDR>END EXT       03720000
         BC    2,XCPNJQ       YES BRANCH                                03740000
         L     WKREG1,IOBCC(IOBREG)      ADDR OF CHAN PROG TO BE EXEC   03760000
         LA    WKREG1,0(WKREG1)     CLEAR SIOCC                         03780000
         LR    ICREG,WKREG1                                             03800000
         TM    20(ICREG),X'40'     Q. COMMAND CHAINING             1450 03820015
         BO    XCPNJQ         YES- CANNOT ACCEPT THIS              1450 03840015
         CLI   0(WKREG1),X'31'        Q. SEARCH ID                      03860000
         BC    7,XCPNJQ            NOT MINE                             03880000
         CLI   8(WKREG1),X'08'     Q. TIC COMMAND                       03900000
         BC    7,XCPNJQ          NO BRANCH                              03920000
         CLI   23(WKREG1),X'B0'       Q. CNY=176                        03940000
         BH    XCPNJQ             TOO HIGH  BR  OUT                1450 03950015
         BL    XRDTST             TOO LOW  MAY BE A READ           1450 03960015
XTSTWRT  MVC   JQRCD+1(1,UAREG),16(WKREG1)  RESTORE CC                  03970015
         XI    JQRCD+1(UAREG),X'0D'    TEST IF WRITE                    03980015
         NI    JQRCD+1(UAREG),X'F7'                                     03990015
         BC    4,XRDTST                                            1450 04000015
         LA    TSTREG,XWRDATA          APPROPRIATE MOVE                 04008015
         BC    15,XCONVT                                                04016015
XRDTST   MVC   JQRCD+1(1,UAREG),16(WKREG1)   SEP CC                1450 04024015
         XI    JQRCD+1(UAREG),X'0E'          TEST IF READ          1450 04032015
         NI    JQRCD+1(UAREG),X'77'          ALLOW MULTI-TRACK     1450 04040015
         BC    4,XCPNJQ                      NOT A READ BR OUT     1450 04048015
         LA    TSTREG,XRDDATA          LA OF RD MOVE                    04060000
XCONVT   L     WKREG1,0(WKREG1)        GET CC AND DATA ADDRESS          04080000
         LA    WKREG1,0(WKREG1)        CLEAR CC                         04100000
         MVC   JQCCHHR+3(5,UAREG),0(WKREG1)  GET CCHHR                  04120000
         STM   0,2,JQSAVE(UAREG)   SAVE REGS USSED BY CVT RTN           04140000
         STM   9,13,JQSAVE+12(UAREG)                                    04160000
         LA    IOBREG,JQCCHHR(UAREG)     PTR TO 8 BYTE AREA             04180000
         LA    TSTREG,JQDEB(UAREG)   PTR TO DEB                         04200000
         L     APBSRG,CVTADDR      PTR TO CVT RTN                       04220000
         BALR  LNKRG2,APBSRG           CONVERT ROUTINE                  04240000
*                                                                       04260000
* REG 0 IS USED TO RETURN THE TTR0                                      04280000
*                                                                       04300000
         LM    9,13,JQSAVE+12(UAREG)   RESTORE REGS USED BY CVT RTN     04320000
         LR    WKREG2,TOTREG       SAVE TTR                             04340000
         LM    0,2,JQSAVE(UAREG)   RESTORE 0-2                          04360000
* DETERMINE IF RECORD SOUGHT ON A PARTICULAR TRACK IS WITHIN ACCEPTABLE 04380000
* LIMITS (GREATER THAN ZERO, NOT GREATER THAN TRACK CAPACITY).          04400000
         STH   WKREG2,JQRCD(0,UAREG)   SAVE 'RN'                        04420000
         CLI   JQRCD(UAREG),X'00'  REC NO. EQ ZERO                      04440000
         BC    8,ERROR   BR IF YES                                      04460000
         CLC   JQRCD(1,UAREG),JQRPT(UAREG)  CHECK, BR IF REC NO.        04480000
         BC    2,ERROR                      EXCEEDS TRACK CAPACITY      04500000
         L     14,JQAREA(UAREG)    GET Q CORE ADDRESS                   04520000
         CL    WKREG2,JQLTTR(UAREG)   Q. W/IN FIXED                     04540000
         BC    10,XRJQ0010         NO BRANCH                            04560000
         CL    WKREG2,JQWATTR(UAREG)  Q. BEYOND IWA                     04580000
         BC    10,XRJQ0015         YES BRANCH                           04600000
         SR    15,15               SET INCREMENT VALUE TO ZERO          04620000
         BC    15,XRJQ0020                                              04640000
XRJQ0015 LH    15,JQMIN26(UAREG)   SET INCREMENT VALUE TO -26           04660000
         BC    15,XRJQ0020                                              04680000
XRJQ0010 L     WKREG1,JQLPTCB(UAREG)    GET LOW TCB ADDRESS             04700000
         LTR   WKREG1,WKREG1       Q. SPS                               04720000
         BC    8,XRJQ0016   NO,BRANCH                                   04740000
         CR    WKREG1,0            Q.LOW PRIORITY TCB                   04760000
         BC    7,XCPNJQ            NO DON'T HANDLE REQ.                 04780000
XRJQ0016 L     WKREG1,JQSCATT(0,UAREG)   GET TT FOR BEGINNING           04800000
         N     WKREG1,JQCONS(UAREG)    OF VARIABLE AREA                 04820000
         SLR   WKREG2,WKREG1       SUB THIS TT                          04840000
         BC    4,XCPNJQ            NOT W/IN RESJQ                       04860000
         LA    15,16                 SET INCREMENT VALUE TO 16          04880000
XRJQ0020 SRL   WKREG2,16     TT TO LOW ORDER                            04900000
         XR    WKREG1,WKREG1                                            04920000
         IC    WKREG1,JQRPT(UAREG)   GET R/TRK                          04940000
         MR    WKREG1,WKREG1           TT*RCDS/TRK                      04960000
         IC    WKREG1,JQRCD(UAREG)   GET R                              04980000
         BCTR  WKREG1,0              R-1                                05000000
          AR   WKREG2,15     ADD INCREMENT VALUE                        05020000
         AR    WKREG1,WKREG2           (TT*RCDS/TRK)+(R-1)              05040000
         CH    WKREG1,JQRRES(UAREG)      Q.RES RCD                      05060000
     BC   10,XCPNJQ                                                     05080000
         MH    WKREG1,JQBYRCD(UAREG)   (TT*R/TRK)+((R/1)*B/RCD)         05100000
         AR    WKREG1,14             CORE ADDR OF RCD IN WKREG1         05120000
         L     WKREG3,16(ICREG)        GET RD OR WR CC & DATA ADDR      05140000
         LA    WKREG3,0(WKREG3)        CLEAR CC                         05160000
         BR    TSTREG                                                   05180000
         SPACE 1                                                        05280015
******************** NOT JOB QUEUE REQ. - RET TO IOS ****************   05460000
XCPNJQ   XR    ICREG,ICREG          RESTORE FOR IOS                     05480000
         L     14,SAVE   RESTORE IOS RETURN ADDR                        05500000
         BC    15,4(0,14)   RETURN TO CONTINUE THRU IOS                 05520000
*********************************************************************   05540000
         SPACE 1                                                        05544015
*                                                                       05548015
*  WKREG1 NOW POINTS TO THE RCD TO READ FROM OR WRITE INTO (TTR0)       05552015
*  WKREG3 NOW POINTS TO THE AREA TO BE READ INTO OR WRITE FROM          05556015
*                                                                       05560015
         SPACE 1                                                        05564015
XRDDATA  IC    WKREG2,23(ICREG)              GET LENGTH OF READ    1450 05568015
         BCTR  WKREG2,0                      DECREMENT 1           1450 05572015
         EX    WKREG2,MVDATA                 MOVE THE DATA         1450 05576015
         BC    15,XPOSTIO               GO TO POST                      05580000
XWRDATA  MVC   0(176,WKREG1),0(WKREG3)  MOVE DATA (WRITE)               05600000
XPOSTIO  SR    ICREG,ICREG                                              05620000
          L    WKREG1,IOBECB-1(IOBREG)  CODE, ECB PTR                   05640000
         LA    WKREG2,0(0,WKREG1)   ECB PTR                             05660000
         XR    WKREG1,WKREG2   COMP CODE IN WKREG1                      05680000
         LM    LNKRG2,APBSRG,SAVE  IOS RET ADDR,ADDR. OF BRANCH         05700000
*                                  ENTRY TO POST                        05720000
*  POST WILL RETURN TO IOS VIA REG 14, IOS WILL THEN EXIT.              05740000
         TM    DEBPRT(DEBREG),PPKEY  IS DEB KEY ZERO                    05760000
         BC    8,4(0,APBSRG)  YES,BYPASS VAL CHK IN POST                05780000
         BCR   15,APBSRG   GO THRU VAL CHK IN POST                      05800000
ERROR    MVI   IOBECB-1(IOBREG),X'41'   FLAG AS PERM I/O ERROR          05820000
         BC    15,XPOSTIO    GO TO POST INTERFACE                       05840000
MVDATA   MVC   0(0,WKREG3),0(WKREG1)    MOVE INSTRUCTION FOR A READ1450 05850015
JQIEFJOB DC    A(IEFJOB)       PTR TO JOB Q DCB,DEB,CONSTANTS, ...      05860000
CVTADDR  DC    V(IECPRLTV)                                              05880000
SAVE     DS    F     SAVE AREA FOR IOS RETURN ADDRESS                   05900000
POSTADR  DC    V(IEA0PT01)  BRANCH ENTRY TO POST                        05920000
         END                                                            05940000
