IGC0001C CSECT                                                          00200017
*718000                                                          A35704 00300000
         TITLE 'IEAATM00/ ABEND FIRST LOAD/ IGC0001C '                  00400017
*      THE ABEND SVC SERVICE ROUTINE(SVC 13) TERMINATES THE TASK UNDER  00600017
*   WHICH IT IS RUNNING AND RESETS THE PARTITION SO THAT A NEW JOB STEP 00800017
*   CAN BE INITIATED USING THIS TASK CONTROL BLOCK(TCB).  ABEND IS A    01000017
*   TYPE FOUR SVC AND CONSISTS OF FOURTEEN TRANSIENT LOADS IN PCP. IT   01200017
*   CAN BE CALLED BY ABTERM OR DIRECTLY BY USE OF THE ABEND MACRO       01400017
*   INSTRUCTION.  TWO OF THESE ABEND LOADS ARE INVOKED UPON NORMAL END  01600017
*   AS WELL AS FOR ABNORMAL TERMINATION.                                01800017
*                                                                       02000017
*      THE MODULE, CSECT AND SVC LIBRARY NAMES OF THE FOURTEEN          02200017
*   TRANSIENT LOADS IN PCP ALONG WITH A BRIEF DESCRIPTION OF ITS        02400017
*   FUNCTION ARE AS FOLLOWS:                                            02600017
*                                                                       02800017
*               MODULE NAME  SVC LIB NAME         FUNCTION              03000017
*   FIRST   LOAD  IEAATM00   IGC0001C        IF NORMAL END-XCTL TO LAST 03200017
*                                        LOAD(IGC0501C)                 03400017
*                                            CHECK IF STAE CAN BE PRO-  03600017
*                                        CESSED AND IF SO GO TO ABEND/  03800017
*                                        STAE INTERFACE RTN(IGC0B01C)   04000017
*                                            ON A REGULAR ABNORMAL END  04200017
*   SECOND  LOAD  IEAATM06   IGC0601C        PURGE I/O                  04400017
*   THIRD   LOAD  IEAATM01   IGC0101C        VALIDITY CHECK SYSTEM      04600017
*                                        QUEUES                         04800017
*   FOURTH  LOAD  IEAATM0A   IGC0111C        DETERMINE HOW MUCH CORE    05000017
*                                         IS NECESSARY FOR ABEND        05200017
*                                         PROCESSING                    05400017
*   FIFTH   LOAD  IEAATM02   IGC0201C        FREE CORE ON LRB LIST      05600017
*   SIXTH   LOAD  IEAATM2A   IGC0211C        PERFORMS BASIC OVERLAY OF  05800017
*                                         P/P IF CORE IS STILL NEEDED   06000017
*   SEVENTH LOAD  IEAATM2B   IGC0221C        STACK LRB'S AND VALIDITY   06200017
*                                         CHECK QUEUES.                 06400017
*   EIGHTH  LOAD  IEAATM03   IGC0301C        SET UP INDIC DUMP          06600017
*   NINTH   LOAD  IEAATM04   IGC0401C        SET UP AND CALL ABDUMP     06800017
*   TENTH   LOAD  IEAATM05   IGC0501C        REINITIALIZE SYSTEM FOR    07000017
*                                         NEXT TASK.                    07200017
*                                                                       07400017
*      IN ADDITION TO THE ABOVE TEN TRANSIENT LOADS THE FOLLOWING       07600017
*   FOUR MODULES PERFORM ABEND/STAE PROCESSING IF IGC0001C FOUND THAT   07800017
*   STAE PROCESSING CAN BE UNDERTAKEN.                                  08000017
*                                                                       08200017
*                 IEAATM0B   IGC0B01C        PURGE I/O LINK TO EXIT RUN 08400017
*                 IEAATM0C   IGC0C01C        CLOSE DATA SETS AND        08600017
*                                         UPDATES IOB CHAIN             08800017
*                 IEAATM0D   IGC0D01C        CLEANUP AND INVOKE STAE    09000017
*                                         RETRY                         09200017
*                 IEAATM0E   IGC0E01C        ISAM AND TAM PROCESSING,   09400017
         EJECT                            AND PURGE WTOR QUEUE          09600017
*                                                                       09800017
*   MODULE NAME    ...  IEAATM00                                        10000017
*   CSECT  NAME    ...  IGC0001C                                        10200017
*   SVC LIBRARY NAME... IGC0001C                                        10400017
*                                                                       10600017
*                                                                       10800017
*   APPLICABILITY ...  PRIMARY CONTROL PROGRAM (PCP)                    11000017
*                                                                       11200017
*   FUNCTION                                                            11400017
*                                                                       11600017
*        CHECK FOR NORMAL END, CHECK IF STAE HAS BEEN SPECIFIED AND     11800017
*     CAN BE PROCESSED, AND STORE THE COMPLETION CODE IN THE TCB.       12000017
*                                                                       12200017
*   ENTRY                                                               12400017
*                                                                       12600017
*        THE FIRST LOAD OF ABEND IS ENTERED IN SUPERVISOR STATE, WITH   12800017
*     A PROTECTION KEY OF ZERO AND WITH INPUT/OUTPUT INTERRUPTS         13000017
*     DISABLED.  THE FIRST LOAD IS ENTERED AT ENTRY POINT NAME IGC0001C 13200017
*     WHEN THE ABEND SVC INSTRUCTION (SVC 13) IS EXECUTED.              13400017
*                                                                       13600017
*   INPUT                                                               13800017
*                                                                       14000017
*      NORMAL END                                                       14200017
*                                                                       14400017
*        THE RESIDENT EXIT ROUTINE SETS THE NORMAL TERMINATION BIT TO   14600017
*        ONE IN THE TCB.  NORMAL END REQUIRES THAT REGISTER 15 CONTAIN  14800017
*        THE COMPLETION CODE.  REGISTER 1 MUST CONTAIN ALL ONES.        15000017
*                                                                       15200017
*      ABNORMAL END                                                     15400017
*                                                                       15600017
*        IF ABTERM WAS ENTERED TO INITIATE THIS ABNORMAL TASK TERMIN-   15800017
*        ATION, ABTERM HAS STORED THE FOLLOWING INFORMATION IN THE TCB  16000017
*        COMPLETION CODE FIELD(TCBCMP).  OTHERWISE THIS INFORMATION     16200017
*        MUST BE IN REGISTER 1 ON ENTRY TO ABEND:                       16400017
*                                                                       16600017
*          BIT 0    DUMP INDICATOR.  A DUMP IS REQUESTED IF THIS BIT    16800017
*                   IS SET TO 1.                                        17000017
*          BIT 1    IS IGNORED                                          17200017
*          BITS 2-6 MUST BE ZERO                                        17400017
*          BIT 7    IS USED TO INDICATE THE PRESENCE OF AN ABEND        17600017
*                   MESSAGE TO BE PRINTED(SET BY CALLER OF ABEND).      17800017
*          BITS 8-31  COMPRISE THE COMPLETION CODE FIELD.               18000017
*               IF A SYSTEM ROUTINE INITIATED THIS TASK TERMINATION,    18200017
*               BITS 8-19 MUST CONTAIN THE SYSTEM COMPLETION CODE. BITS 18400017
*               20-31 MUST BE ZERO.                                     18600017
*               IF A PROBLEM PROGRAM INITIATED THIS TASK TERMINATION,   18800017
*               BITS 20-31 CONTAIN THE PROBLEM PROGRAM COMPLETION CODE. 19000017
*               BITS 8-19 MUST BE ZERO.                                 19200017
*                                                                       19400017
*   OUTPUT         ...   NONE                                           19600017
*                                                                       19800017
*   EXTERNAL REFERENCES                                                 20000017
*                                                                       20200017
*        THE FIRST LOAD OF ABEND REFERENCES ENTRIES IN THE CVT,TCB,SVRB 20400017
*     FOR ABEND, AND THE SVRB FOR THE CALLER OF ABEND                   20600017
*     A. COMMUNICATIONS VECTOR TABLE (CVT)                              20800017
*        CVTTCBP -  THE ADDRESS OF THE CURRENTLY DISPATCHED TASK IS     21000017
*                   OBTAINED USING THIS LOCATION.                       21200017
*        CVTEXIT - AN SVC 3 INSTRUCTION IN THE CVT                      21400017
*                                                                       21600017
*     B. TASK CONTROL BLOCK (TCB)                                       21800017
*        TCBRBP  - ADDRESS OF THE ACTIVE REQUEST BLOCK QUEUE            22000017
*        TCBPIE  - ADDRESS OF THE PROGRAM INTERRUPTION ELEMENT(PIE)     22200017
*        TCBCMP  - COMPLETION CODE FIELD                                22400017
*        TCBNSTAE- ADDRESS OF THE FIRST STAE CONTROL BLOCK              22600017
*        TCBFLGS - FLAG BYTES                                           22800017
*                                                                       23000017
*     C. SVRB                                                           23200017
*        XRBLNK  -ADDRESS OF THE NEXT RB ON THE ACTIVE RB QUEUE         23400017
*        XRBPSW  -RESUME PSW FOR THE RB                                 23600017
*        RBESA   -ADDRESS OF THE EXTENDED SAVE AREA OF THE SVRB         23800017
*                                                                       24000017
*                                                                       24200017
*     ABEND STATUS BITS (IF BIT IS ONE,THE FOLLOWING IS TRUE)           24400017
*                                                                       24600017
*        TCBFLGS (DISPLACEMENT  HEX '1D' )                              24800017
*          BIT       MEANING                                            25000017
*           0   -   ABNORMAL TERMINATION IN PROCESS (ABEND BIT)         25200017
*           1   -   NORMAL TERMINATION IN PROCESS   (NORMAL END BIT)    25400017
*           2   -   ABEND WAS INITIATED BY ABTERM                       25600017
*           3   -   SECOND ENTRY INTO ABEND IS PERMISSIBLE              25800017
*           4   -   RESERVED                                            26000017
*           5   -   CLOSE HAS BEEN INITIATED BY ABEND                   26200017
*           6   -   STORAGE HAS BEEN OVERLAID TO PROCESS ABEND          26400017
*           7   -   PROHIBIT QUEUEING OF ASYNCHRONOUS EXITS FOR THISTCB 26600017
*                                                                       26800017
*        TCBFLGS+1  (DISPLACEMENT HEX '1E' )                            27000017
*                                                                       27200017
*           0   -   THIS TASK CANNOT BE TERMINATED                      27400017
*           5   -   ABEND INITIATED ABDUMP FOR THIS TASK                27600017
*                                                                       27800017
*        TCBCMP                                                         28000017
*                                                                       28200017
*           0   -   A DUMP IS REQUESTED FOR THIS TASK                   28400017
*           1   -   RESERVED                                            28600017
*           2   -   STORAGE WAS OVERLAID TO REACH ABEND SECOND LOAD     28800017
*           3   -   ABEND HAS INITIATED A WTO AND WILL LOAD A WAIT      29000017
*                   STATE PSW WHEN RETURNED                             29200017
*           4   -   ABEND HAS BEEN ENTERED A SECOND TIME                29400017
*           5   -   A DUMP MESSAGE IS REQUIRED                          29600017
*           6   -   AN INDICATIVE DUMP IS PROVIDED                      29800017
*           7   -   AN ABEND MESSAGE IS PROVIDED                        30000017
*                                                                       30200017
*        TCBNSTAE                                                       30400017
*                                                                       30600017
*           0   -   STAE PROCESSING HAS BEEN ATTEMPTED BUT COULD NOT    30800017
*                   FUNCTION (STAE RECURSION BIT)                       31000017
*           1   -   PURGE FAILED IN STAE PROCESSING                     31200017
*           2   -   CONTINUE STAE ACCROSS XCTL                          31400017
*           3   -   MVT ONLY                                            31600017
*           4   -   QUIESCE I/O FAILED- HALT I/O COMPLETED              31800017
*           5   -   ISSUER OF STAE WAS SUPERVISOR ROUTINE               32000017
*           6   -   STAE RETRY WITH NO RB PURGE                         32200017
*           7   -   VALIDITY CHECK SWITCH                               32400017
*                                                                       32600017
*   EXITS                                                               32800017
*                                                                       33000017
*        IF NORMAL END, CONYROL IS PASSED TO THE LAST LOAD-IEAATM05.    33200017
*     (IGC0501C). IF STAE PROCESSING CAN BE PERFORMED, CONTROL IS       33400017
*     PASSED TO THE FIRST ABEND/STAE INTERFACE ROUTINE-IEAATM0B         33600017
*     (IGC0B01C). IF ABNORMAL END WITH NO STAE PROCESSING,  CONTROL     33800017
*     IS PASSED TO THE SECOND LOAD OF ABEND-IEAATM06(IGC0601C)          34000017
*                                                                       34200017
*   ERROR MESSAGES  ...    NONE                                         34400017
*                                                                       34600017
*   NOTES                                                               34800017
*                                                                       35000017
*       ABEND/MAIN STORAGE SUPERVISOR INTERFACE                         35200017
*                                                                       35400017
*        THE ABEND AND ABTERM BITS IN THE TCB ARE TESTED BY THE         35600017
*        REGISTER FORM OF GETMAIN/FREEMAIN.  IF AN ERROR IS ENCOUNTERED 35800017
*        AND EITHER OF THESE BITS IS SET GETMAIN/FREEMAIN RETURNS       36000017
*        CONTROL TO THE CALLER WITH AN ERROR CODE (4) IN REGISTER 15    36200017
*        INSTEAD OF INITIATING ANOTHER ABEND.                           36400017
*                                                                       36600017
*       SVC HANDLER/ABEND INTERFACE                                     36800017
*                                                                       37000017
*        WHEN AN ABEND SVC IS ISSUED, THE SVC HANDLER MAY BE UNABLE TO  37200017
*        ACQUIRE THE 96 BYTES OF CORE REQUIRED TO FETCH ABEND INTO THE  37400017
*        TRANSIENT AREA.  IF THIS IS THE CASE, THE SVC HANDLER WILL     37600017
*        OVERLAY 96 BYTES OF PROBLEM PROGRAM CORE AT 32 BYTES PAST THE  37800017
*        LOWER BOUND OF THE PARTITION.  THIS ACTION WILL BE NOTED BY    38000017
*        SETTING A BIT IN THE TCBFLGS FIELD OF THE TCB                  38200017
*                                                                       38400017
********     STAE   INTERFACE???????    HERE ****           *********** 38600017
*   OPERATION                                                           38800017
*                                                                       39000017
*        IF THE NORMAL END BIT IS ON, THE ABTERM BIT IS OFF, REG 1      39200017
*     CONTAINS ALL ONES, AND IF THE CALLER IS IN SUPERVISOR STATE,      39400017
*     NORMAL END IS INDICATED.  FOR NORMAL END THIS ROUTINE STORES THE  39600017
*     NORMAL COMPLETION CODE PASSED IN REG 15 INTO THE TCB, TURNS OFF   39800017
*     THE NORMAL END BIT IN THE TCB AND TRANSFERS CONTROL TO THE LAST   40000017
*     LOAD-IEAATM05(IGC0501C).                                          40200017
*                                                                       40400017
*        IF ANY OF THE ABOVE CONDITIONS FOR NORMAL END IS NOT TRUE,     40600017
*     ABNORMAL END IS INDICATED.  THE ROUTINE CHECKS IF A STAE IS IN    40800017
*     EFFECT AND CAN BE PROCESSED.  A STAE IS NOT PROCESSED IF THE      41000017
*     STAE RECURSION BIT IS ON, OR IF THE ABEND WAS AN OPERATOR CANCEL  41200017
*     OR TIMER EXPIRATION,  OR IF CORE MUST BE OVERLAID TO XCTL TO THE  41400017
*     NEXT LOAD.  IN THESE CASES REGULAR ABNORMAL END PROCESSING        41600017
*     CONTINUES                                                         41800017
*        IF THE ABEND IS CAUSED BY PURGE FAILURE IN STAE PROCESSING,    42000017
*     THE RESUME PSW IN THE PURGE SVRB IS SET TO POINT TO THE SVC 3     42200017
*     (EXIT) IN THE CVT.  THIS ROUTINE THEN ISSUES AN SVC 3.  THIS HAS  42400017
*     THE EFFECT OF WIPING OUT THIS ABEND SVRB, THE PURGE SVRB AND      42600017
*     GIVING CONTROL BACK TO THE ABEND/STAE ROUTINE RIGHT AFTER IT      42800017
*     ISSUED THE PURGE SVC.  IN THIS WAY THE ROUTINE KNOWS THAT PURGE   43000017
*     FAILED.                                                           43200017
*        IF STAE PROCESSING IS TO TAKE PLACE, THE PIE IS FREED IF A     43400017
*     PIE IS IN EFFECT AND THE TCBPIE FIELD IS CLEARED.  CONTROL IS     43600017
*     PASSED TO THE FIRST ABEND/STAE INTERFACE ROUTINE-IEAATM0B         43800017
*     (IGC0B01C).                                                       44000017
*        IF REGULAR ABEND PROCESSING IS TO TAKE PLACE, CONTROL IS       44200017
*     PASSED TO THE SECOND LOAD OF ABEND-IEAATM06(IGC0601C).            44400017
*                                                                       44600017
*********************************************************************** 44800017
*               THIS PROLOGUE COMMENTARY UPDATED FOR RELEASE 17   *DGM* 45000017
*********************************************************************** 45200017
R1       EQU   1                                                   STAD 45400017
R2       EQU   2                                                   STAD 45600017
R3       EQU   3                                                   STAD 45800017
R4       EQU   4                                                   STAD 46000017
R5       EQU   5                                                   STAD 46200017
R6       EQU   6                                                   STAD 46400017
R7       EQU   7                                                   STAD 46600017
R8       EQU   8                                                   STAD 46800017
R9       EQU   9                                                   STAD 47000017
RA       EQU   10                                                  STAD 47200017
RB       EQU   11                                                  STAD 47400017
RC       EQU   12                                                  STAD 47600017
RD       EQU   13                                                  STAD 47800017
RE       EQU   14                                                  STAD 48000017
RF       EQU   15                                                  STAD 48200017
CVTPTR   EQU   16                                                  STAD 48400017
CVTTCBP  EQU   0                                                   STAD 48600017
CVTEXIT  EQU   80                      ADDR OF SVC 3 IN CVT        STAD 48800017
TCBRBP   EQU   0                                                        49000017
TCBPIE   EQU   4                                                   STAD 49200017
TCBCMP   EQU   16                                                  STAD 49400017
TCBNSTAE EQU   160                                                      49600017
TCBFLGS  EQU   28                                                       49800017
XRBLNK   EQU   28                                                  STAD 50000017
XRBPSW   EQU   16                                                  STAD 50200017
XSTAB    EQU   10                                                 19272 50300019
RBESA    EQU   96                                                  STAD 50400017
EXIT     EQU   3                                                   STAD 50600017
NEW      EQU   4                                                   STAD 50800017
LBND     EQU   4                                                        51000017
BBOX2    EQU   12                                                       51200017
STOPTT   EQU   20                                                A27771 51210019
TCBMSS   EQU   24                                                       51400017
PRBXT    EQU   32                                                       51600017
RBSIZE   EQU   96                                                       51800017
SVRBXT   EQU   144                                                      52000017
STAEREC  EQU   X'80'                                               STAD 52200017
SECSTEAL EQU   X'20'                                                    52400017
TCBFS    EQU   X'02'                                                    52600017
DBNDRY   EQU   X'01'                   MASK TO TEST FOR LCS             52800017
NORMAL   EQU   X'40'                                               STAD 53000017
PURGEBIT EQU   X'40'                                               STAD 53200017
TCBABTRM EQU   X'20'                                               STAD 53400017
PPSTATE  EQU   X'01'                                               STAD 53600017
TCBDAR   EQU   172                     DAR FLAGS                   DAR  53700018
         EJECT                                                     STAD 53800017
         BALR  R6,0                                                STAD 54000017
         USING *,R6                                                STAD 54200017
         LR    RB,R1                   SAVE ABNORMAL COMP CODE     STAD 54400017
         LR    RA,RF                   SAVE NORMAL COMP CODE       STAD 54600017
         L     R3,CVTPTR               LOAD CVT ADDR               STAD 54800017
         L     R4,CVTTCBP(R3)          LOAD OLD/NEW ADDR           STAD 55000017
         L     R4,NEW(R4)              GET CURRENT TCB ADDR        STAD 55200017
         OI    TCBFLGS+1(R4),X'01'     SET PREVENT ASYCH EXIT BIT  DAR  55210018
         TM    TCBDAR(R4),X'10'        DID CLOSE FAIL AFTER DAR?   DAR  55220018
         BO    DAREND                  YES, GO TO LAST LOAD - 501C DAR  55230018
         TM    TCBDAR(R4),X'80'        DAR RECURSION?              DAR  55240018
         BZ    NODAR                   NO, BRANCH                  DAR  55250018
          LA    R8,DARNAME             NAME OF DAR MODULE          DAR  55260018
          BAL   RE,CKCORE              CHECK FOR STEAL CORE        DAR  55270018
          B     XCTL                                               DAR  55280018
          B     XCTL                                               DAR  55290018
NODAR    EQU   *                                                   DAR  55300018
         TM    TCBFLGS+1(R4),X'80'     ABEND RECURSION?            DAR  55310018
          BZ    NOREC                  NO, BRANCH                  DAR  55320018
         OI    TCBCMP(R4),X'08'        SET SECOND ENTRY SWITCH     DAR  55330018
         OI    TCBFLGS+1(R4),X'20'     SET ABTERM BIT TO PREVENT   DAR  55340018
*                                      SECOND STORING OF COMP CODE DAR  55350018
         B     NOSTAE                  BYPASS STAE TESTING         DAR  55360018
NOREC    EQU    *                                                  DAR  55370018
          NI    TCBCMP(R4),X'C1'       SET CC FLAGS TO ZERO        DAR  55380018
         L     R5,TCBRBP(R4)           GET CURRENT RB ADDR         STAD 55600017
         TM    TCBFLGS+1(R4),NORMAL    IS THIS NORMAL END?              55800017
         BZ    STAEPROC                NO,BRANCH AND TEST FOR STAE STAD 56000017
         TM    TCBFLGS+1(R4),TCBABTRM  IS ABTERM BIT ON?                56200017
         BO    STAEPROC                YES,BRANCH TO TEST FOR STAE STAD 56400017
         C     R1,EXITMASK             IS REG ONE ALL ONES         STAD 56600017
         BNE   STAEPROC                NO,BRANCH TO TEST FOR STAE  STAD 56800017
         L     R8,XRBLNK(R5)           LOAD PREV RB ADDR                57000017
         TM    XRBPSW+1(R8),PPSTATE    IS CALLER IN SUPV STATE          57200017
         BZ    NORMALND                NORMAL END BRANCH                57400017
STAEPROC EQU   *                                                   STAD 57600017
         NC    TCBNSTAE(4,R4),TCBNSTAE(R4)  ** IS THERE A STAE          57800017
         BZ    NOSTAE                  NO,BRANCH                   STAD 58000017
         TM    TCBNSTAE(R4),PURGEBIT   DID PURGE FAIL?             STAD 58200017
         BZ    COMCODCK                NO,BRANCH                   STAD 58400017
         LA    R7,CVTEXIT(R3)          GET ADDR OF SVC 3 INSTR     STAD 58600017
         L     R8,XRBLNK(R5)           GET PURGE RB ADDR           STAD 58800017
         ST    R7,XRBPSW+4(R8)         SET XRBPSW TO SVC 3         STAD 59000017
         SVC   EXIT                    EXIT                        STAD 59200017
COMCODCK EQU   *                                                   STAD 59400017
         TM    TCBFLGS+1(R4),TCBABTRM  COMP CODE STORED?                59600017
         BO    CKCANCEL                YES,BRANCH                  STAD 59800017
         ST    RB,TCBCMP(R4)           STORE COMPLETION CODE IN TCBSTAD 60000017
         L     R2,0(R4)                 GET PRES RB              A27227 60010019
         L     R2,XRBLNK(R2)            GET PREV RB              A27227 60020019
         L     R9,TCBMSS(R4)            GET BB PTR               A27227 60030019
         SH    R9,HALF8                 GET PTR TO AB APP        A27227 60040019
         MVC   XRBPSW+4(4,R2),0(R9)     RESTORE PSW              A27227 60050019
         OI    TCBFLGS+1(R4),TCBABTRM  IND COMP CODE STORED             60200017
CKCANCEL EQU   *                                                   STAD 60400017
         CLC   TCBCMP+1(2,R4),CC122    OPERATOR CANCEL?            STAD 60600017
         BE    NOSTAE                  YES,DO NOT INVOKE STAE      STAD 60800017
         CLC   TCBCMP+1(2,R4),CC222    OPERATOR CANCEL?            STAD 61000017
         BE    NOSTAE                  YES-DO NOT INVOKE STAE      STAD 61200017
         CLC   TCBCMP+1(2,R4),CC322    TIMES EXPIRED?                   61400017
         BE    NOSTAE                  YES-DO NOT INVOKE STAE      STAD 61600017
         TM    TCBNSTAE(R4),STAEREC    STAE RECURSION?             STAD 61800017
         BO    NOSTAE                                              STAD 62000017
         NC    TCBPIE+1(3,R4),TCBPIE+1(R4) *DOES A PIE EXIST            62200017
         BZ    NOPIE                   NO,BRANCH                   STAD 62400017
         L     R1,TCBPIE(R4)           SET UP R1 FOR FREEMAIN      STAD 62600017
         FREEMAIN   R,LV=32,A=(1)      FREE THE PIE                STAD 62800017
         XC    TCBPIE(4,R4),TCBPIE(R4) PURGE PIE                   STAD 63000017
NOPIE    EQU   *                                                   STAD 63200017
         LA    R8,STAENAME             GET NAME ADDR OF STAE LOAD  STAD 63400017
          BAL   RE,CKCORE              CHECK FOR STEAL CORE        DAR  63430018
          B     XCTL                                               DAR  63460018
          LA    R8,NEXTLOAD            CORE STOLEN-STAE NOT ALLOWED DAR 63490018
         OI    STOPTT,X'01'             STOP TRACE TABLE         A27771 63500019
          OI    TCBFLGS+1(R4),X'80'    SET 'ABEND IN PROCESS' BIT  DAR  63520018
          B     XCTL                                               DAR  63550018
CKCORE   EQU   *                                                        63600017
         GETMAIN  R,LV=96                                               63800017
         LTR   RF,RF                                                    64000017
*  CHECK IF ENOUGH CORE TO GET NEXT ABEND LOAD                          64200017
*                                                                       64400017
         BNZ   WSTEAL                  CORE MUST BE STOLEN FOR RB       64600017
         FREEMAIN R,LV=(0),A=(1)       IF ENOUGH CORE,FREE IT           64800017
         BR    RE                      NORM RETURN - NO STEAL      DAR  65000018
WSTEAL   EQU   *                                                        65200017
*   MUST PROVIDE 96 BYTES FOR AN SVRB USED BY XCTL                      65400017
         L     R9,TCBMSS(R4)           LOAD BOUNDRY BOX ADDR            65600017
         TM    0(R9),DBNDRY            LCS IN SYSTEM?                   65800017
         BZ    NOLCS                                                    66000017
         NC    4(8,R9),4(R9)           IS H0 BEING USED?                66200017
         BNZ   NOLCS                   NO,PROCEED AS NORMAL-BRANCH      66400017
         LA    R9,BBOX2(R9)            RESET PTR TO SECOND BOX          66600017
NOLCS    EQU   *                                                        66800017
         L     RA,LBND(R9)             LOAD LOWER BOUND ADDRESS         67000017
         LA    R7,PRBXT(RA)            ESTABLISH FIRST STEAL AREA       67200017
         TM    TCBFLGS+1(R4),TCBFS     HAS CORE BEEN STOLEN             67400017
         BZ    STEAL2                  IF NO,BRANCH                     67600017
         TM    TCBCMP(R4),SECSTEAL      CORE ALREADY STOLEN TWICE 19272 67620019
         BZ    STEAL1                   NO-BRANCH                 19272 67640019
         L     RD,TCBRBP(R4)            GET MY RB ADDR            19272 67660019
         ST    R4,XRBLNK(RD)            DEQUE ALL OTHER RBS       19272 67680019
         OI    XSTAB+1(RD),X'80'        SET LAST RB FLAG          19272 67700019
STEAL1   EQU   *                                                  19272 67720019
         OI    TCBCMP(R4),SECSTEAL     SET SECOND STEAL BIT             67800017
         LA    R7,SVRBXT(R7)           INCREMENT OVER ABEND SVRB        68000017
STEAL2   EQU   *                                                        68200017
         ST    R7,0(R7)                STORE NEW MSS QUEUE              68400017
         MVC   1(3,R9),1(R7)                                            68600017
         XC    0(4,R7),0(R7)           ZERO OUT MSS FREE QUEUE          68800017
         LA    RC,RBSIZE               ESTABLISH SIZE OF FREE QUEUE     69000017
         ST    RC,4(R7)                STORE SIZE IN MSS QUEUE          69200017
         OI    TCBFLGS+1(R4),TCBFS     SET  FIRST STEAL BIT             69400017
         B     4(RE)                   RETURN - CORE STOLEN        DAR  69800018
XCTL     EQU   *                                                        70200017
         LR    RC,R4                   SET TCB ADDR FOR NEXT LOAD       70400017
         LA    RF,RBESA(R5)            GET ESA ADDR                STAD 70600017
         XCTL  EPLOC=(8),SF=(E,(15))                                    70800017
NOSTAE   EQU   *                                                   STAD 71000017
         LA    R8,NEXTLOAD             GET ADDR OF RES ABEND LOAD  STAD 71200017
         OI    STOPTT,X'01'             STOP TRACE TABLE         A27771 71210019
         OI    TCBFLGS+1(R4),X'80'     SET ABEND IN PROCESS BIT    DAR  71240018
          BAL   RE,CKCORE              CHECK FOR STEAL CORE        DAR  71280018
          B     XCTL                                               DAR  71320018
          B     XCTL                                               DAR  71360018
NORMALND EQU   *                                                        71600017
         ST    RA,TCBCMP(R4)           STORE NORM COMP CODE IN TCB      72000017
DAREND   EQU   *                                                   DAR  72100018
         LA    R8,LASTLOAD             GET ADDR OF LASTLOAD             72200017
         B     XCTL                                                     72400017
         DS    0F                                                  STAD 72600017
LASTLOAD DC    C'IGC0501C'                                              72800017
NEXTLOAD DC    C'IGC0601C'             NAME OF NEXT ABEND LOAD     STAD 73000017
STAENAME DC    C'IGC0111C'              NAME OF FIRST STAE LOAD    I250 73200019
EXITMASK DC    X'FFFFFFFF'                                         STAD 73400017
CC122    DC    X'1220'                 COMP CODE-OPERATOR CANCEL   STAD 73600017
CC222    DC    X'2220'                 COMP CODE-OPERATOR CANCEL   STAD 73800017
CC322    DC    X'3220'                 COMP CODE-TIMER EXPIRED     STAD 74000017
DARNAME  DC    C'IGC0801C'             NAME OF DAR MODULE          DAR  74100018
HALF8    DC    H'8'                     DISPL. TO AB APP.        A27227 74110019
         END   IGC0001C                                                 74200017
