IGC0101C      CSECT                                                     00020000
*2407,1352,1364-1366                                               9836 00030013
*1643087400                                                        2448 00032015
*0250056600,110400-139200                                          RPGB 00033016
*0250092400-093000,095800-096400                                   RFOB 00034016
*0250003400-003600,019800-025200,031000-031600,033600-037600,      CMTB 00035016
*     000600,002000,029000-030400,000340-000390                    CMTB 00036016
*2515069600,078815-078825,078875,078905,079200-079400,             LOOB 00037017
*    085400-085600,087400-087600,088800,109800                     LOOB 00038017
         TITLE 'IEAATM01 / ABEND LOAD 2 / IGC0101C'                     00040000
* ABEND LOAD 2- VALIDITY CHECK LOAD                                     00080000
         SPACE 2                                                        00100000
*   ROUTINE NAME ... ABEND2                                             00120000
         SPACE 2                                                        00140000
*   MODULE NAME ... IEAATM01                                            00160000
         SPACE 2                                                        00180000
         SPACE 2                                                        00220000
*   FUNCTION ...                                                        00240000
         SPACE 1                                                        00260000
*        VALIDITY CHECK SYSTEM QUEUES (RBS, DEBS, AND FQE QUEUES)       00280000
*        DEQUEUING THOSE CONTROL BLOCKS THAT HAVE INVALID CHAIN         00300000
*        ADDRESSES.                                                     00320000
*        TRANSFER CONTROL TO THE NEXT APPROPRIATE LOAD OF ABEND.        00380000
         SPACE 2                                                        00400000
*   ENTRY ...                                                           00420000
*        ABEND2 IS ENTERED IN SUPERVISOR STATE, WITH SUPERVISOR         00440000
*        PROTECTION KEY, AND WITH I/O AND EXTERNAL INTERRUPTS DISABLED. 00460000
*        ABEND2 IS ENTERED AT ENTRY POINT IGC0101C FROM ABEND1.         00480000
         SPACE 2                                                        00500000
*   INPUT ...                                                           00520000
*        GEN. REG. 12=ADDRESS OF CURRENT TCB                            00540000
*        BYTE 19 OF BOUNDARY BOX, INITIALIZED TO BINARY ZEROS.          00560000
         SPACE 2                                                        00580000
*   OUTPUT ...                                                          00600000
*        FLAG BITS ARE SET IN THE BOUNDARY BOX TO INDICATE THE RESULTS  00620000
*        OF VALIDITY CHECKING.                                          00640000
*        BYTE 19 OF BOUNDARY BOX                                        00660000
*        BIT 3 = INDICATES ONE OR MORE FREE QUEUE ELEMENTS IN FORBIDDEN 00680000
*                REGION                                                 00700000
*            4 - INDICATES INVALID RB ON LOAD LIST.                     00720000
*            5 - INDICATES INVALID DEB ON LOAD LIST.                    00740000
*            6 - INDICATES INVALID RB ON ACTIVE LIST.                   00760000
*            7 - INDICATES INVALID FREE QUEUE ELEMENT ON CHAIN.         00780000
         SPACE 2                                                        00800000
*   EXTERNAL REFERENCES ...                                             00820000
*        ABEND2 REFERENCES ENTRIES IN THE TCB AND THE VARIOUS CONTROL   00840000
*        BLOCKS.(SYMBOLIC OFFSET NOTED)                                 00860000
*        A.  TCB                                                        00880000
*        TCBRBP - ADDRESS OF ACTIVE RB                                  00900000
*        TCBDEB - POINTER TO QUEUE OF DEBS                              00920000
*        TCBTIO - POINTER TO TIOT                                       00940000
*        TCBCMP - TASK COMPLETION CODE                                  00960000
*        TCBMSS - ADDRESS OF MAIN STORAGE SUPERVISOR BOUNDARY BOX       00980000
*        TCBFLGS - TCB FLAG BITS                                        01000000
*        TCBLLS - POINTER TO LOAD LIST                                  01020000
*        B.  RB                                                         01040000
*        XSTAB - FLAG BITS                                              01060000
*        XRBPSW - SAVE AREA FOR RESUME PSW                              01080000
*        XRBWT - WAIT COUNT                                             01100000
*        XRBLNK - RB CHAIN ADDRESS                                      01120000
*        C.  LLS                                                        01140000
*        BYTE OFFSET +0 FORWARD CHAIN                                   01160000
*                    +4 BACKWARD CHAIN                                  01180000
*        (24 MINIMUM SIZE OF RB IN LOAD LIST)                           01200000
*        D.  DEB                                                        01220000
*        BYTE OFFSET +4 FORWARD CHAIN                                   01240000
*        (36 MINIMUM SIZE OF DEB)                                       01260000
*        E.  MSS                                                        01280000
*        BYTE OFFSET +0 FORWARD CHAIN                                   01300000
*                    +4 FREE AREA COUNT                                 01320000
*        (8 MINIMUM SIZE OF FQE)                                        01340000
         SPACE  2                                                       01360000
*        ABEND STATUS BITS ... (IF BIT IS 1 FOLLOWING INFO IS TRUE)     01380000
         SPACE  1                                                       01400000
*        TCBFLGS+1                                                      01420000
         SPACE  1                                                       01440000
*          BIT0-ABNORMAL TERMINATION IN PROCESS        (ABEND BIT)      01460000
*          BIT1-NORMAL TERMINATION IN PROCESS          (NORMAL END BIT) 01480000
*          BIT2-ABEND WAS INITATED BY ABTERM                            01500000
*          BIT3-SECOND ENTRY INTO ABEND IS PERMISSIBLE                  01520000
*          BIT4-RESERVED                                                01540000
*          BIT5-CLOSE HAS BEEN INITIATED BY ABEND                       01560000
*          BIT6-STORAGE HAS BEEN OVERLAID TO PROCESS ABEND              01580000
*          BIT7-PROHIBIT QUEUING OF ASYNCHRONOUS EXITS FOR THIS TCB     01600000
         SPACE  1                                                       01620000
         SPACE  1                                                       01640000
*        TCBFLGS+2                                                      01660000
*          BIT0-THIS TASK CANNOT BE TERMINATED                          01680000
*          BIT5-ABEND HAS INITIATED ABDUMP FOR THIS TASK                01700000
        SPACE  1                                                        01720000
*        TCBCMP FIELD                                                   01740000
         SPACE  1                                                       01760000
*          BIT0-A DUMP IS REQUESTED FOR THIS TASK                       01780000
*          BIT1-RESERVED                                                01800000
*          BIT2-STORAGE WAS OVERLAID TO REACH SECOND ABEND LOAD         01820000
*          BIT3-ABEND HAS INITIATED A WTO AND WILL LOAD A WAIT STATE    01840000
*                  PSW WHEN RETURNED                                    01860000
*          BIT4-ABEND HAS BEEN ENTERED A SECOND TIME                    01880000
*          BIT5-A DUMP MESSAGE IS REQUIRED                              01900000
*          BIT6-AN INDICTIVE DUMP IS PROVIDED                           01920000
         SPACE 2                                                        01940000
*   EXITS ...                                                           01960000
*       ABEND2 TRANSFERS CONTROL TO ABEND2A UNCONDITIONALLY        RFOB 02160016
         SPACE 2                                                        02540000
*   NOTES ...                                                           02560000
*        VALIDITY CHECK ROUTINE CAN FAIL IF INTERRUPTED.  THEREFORE,    02580000
*        ANY INTERRUPTS THAT MIGHT RESULT IN A MODIFICATION OF A QUEUE  02600000
*        UNDER EXAMINATION COULD CAUSE A FAILURE. HOWEVER, ALL          02620000
*        INTERRUPTS ARE ASSUMED TO BE PURGED OR IGNORED (NOT            02640000
*        DISPATCHED).  THE SINGLE TASK VERSION CURRENTLY RUNS ENTIRELY  02660000
*        DISABLED.                                                      02680000
*        BECAUSE THE PROBLEM PROGRAMMER MAY HAVE DESTROYED SOME SYSTEM  02700000
*        QUEUES OR TABLES, IT IS PERMISSABLE FOR ABEND TO BE ENTERED A  02720000
*        SECOND TIME FOR THE SAME TASK.  THIS RE-ENTRY SHOULD OCCUR     02740000
*        ONLY WHEN ABEND IS ATTEMPTING TO PRODUCE A FULL DUMP OR WHEN   02760000
*        ABEND IS ATTEMPTING TO CLOSE DATA SETS LEFT OPEN BY THE        02780000
*        PROBLEM PROGRAMMER.  THEREFORE, UPON ENTRY TO THE ABDUMP OR    02800000
*        CLOSE INTERFACE,                                               02820000
*        1.  THE FUNCTION BIT IS SET INDICATING ABDUMP OR CLOSE AND     02840000
*        2.  A SECOND ENTRY BIT IS SET.                                 02860000
*        IF ENTERED A SECOND TIME FOR THE SAME TASK, WITH THE SECOND    02880000
*       ENTRY BIT SET, ABEND2A WILL PROCESS THE RECURSION.         RFOB 02970016
         SPACE 2                                                        03060000
*   WORK AREAS...                                                       03080000
*       SIX WORDS OF THE ABEND SVRB EXTENDED SAVE AREA ARE UTILIZEDRFOB 03100016
*       BY THE VALIDITY CHECK PORTION OF ABEND2 FOR PRESERVING SOMERFOB 03120016
*       GENERAL REGISTERS. THIS CHECK IS PERFORMED AS A CROSS CHECKRFOB 03140016
*       OF MSS AGAINST RBS AND DEBS TO ELIMINATE OVERLAP.          RFOB 03160016
         SPACE 2                                                        03180000
*   OPERATION ...                                                       03200000
*        ABEND2 (IEAATM01) PERFORMS THE FOLLOWING FUNCTIONS...          03220000
         SPACE 2                                                        03240000
*        VALIDITY CHECK THE MAIN STORAGE SUPERVISOR FREE QUEUE ELEMENT, 03260000
*        ACTIVE RB, LOADED RB, AND DEB QUEUES AND, DEPENDING ON THE     03280000
*        NATURE OF THE ERROR, DEQUEUE OR TERMINATE AT THE POINT AT      03300000
*        WHICH THE QUEUE BECOMES INVALID.                               03320000
         SPACE 1                                                        03340000
*       TRANSFERS CONTROL TO ABEND2A                               RFOB 03540016
         SPACE 2                                                        03780000
*   OPERATION NARRATIVE...                                              03800000
*        THE VALIDTY CHECK ROUTINE (AUDITOS) VALIDITY CHECKS AND        03820000
*        CORRECTS THOSE QUEUES WHICH MIGHT HAVE BEEN CLOBBERED AND      03840000
*        HENCE PREVENT DUMPING OR A VALID RETURN TO THE JOB SCHEDULER.  03860000
*        THE BASIC LOGIC OF AUDITOS INCLUDES TRACING EACH CHAIN, I.E.   03880000
*        LOAD LIST, ACTIVE LIST, DEB CHAIN, AND MSS CHAIN.  EACH LINK   03900000
*        ADDRESS IS TESTED AS FOLLOWS...                                03920000
*        1.  DOES THE NEXT CONTROL BLOCK LIE WHOLLY WITHIN THE          03940000
*        PARTITION, USING MINIMUM CONTROL BLOCK SIZE? (DOES NOT APPLY   03960000
*        TO SIRB OR IRB)                                                03980000
*        2.  IS THE NEXT CONTROL BLOCK ON A PROPER WORD BOUNDARY        04000000
*        (SINGLE OR DOUBLE)?                                            04020000
*        3.  ARE THERE MORE THAN 300 CONTROL BLOCKS ON THIS CHAIN?      04040000
*        (NOT APPLICABLE TO MSS.)                                       04060000
*        THE FOLLOWING TESTS ARE APPLIED TO MAIN STORAGE SUPERVISOR     04080000
*        FREE QUEUE ELEMENTS ONLY.                                      04100000
*        1.  IS THE COUNT OF FREE BYTES A MULTIPLE OF EIGHT?            04120000
*        2.  IS THE MSS QUEUE IN DESCENDING SEQUENCE?                   04140000
*        3.  DOES THE FREE AREA OVERLAP AN ADJACENT FQE?                04160000
*        4.  DOES THE FREE AREA EXCEED THE PARTITION?                   04180000
         SPACE 2                                                        04200000
*        EACH CONTROL BLOCK THAT IS NOT A MSS OR FQE IS RECURSIVELY     04220000
*        VALIDITY CHECKED AGAINST THE MSS CHAIN SO THAT NO VALID RB OR  04240000
*        DEB RESIDES IN ANY FREE AREA.  THIS CHECKING IS ACCOMPLISHED   04260000
*        BY SAVING THE REGISTERS FROM EACH RB AND DEB SETTING UP THAT   04280000
*        PARTICULAR CONTROL BLOCK AS THE FORBIDDEN REGION AND           04300000
*        RE-ENTERING VALIDITY CHECK TO TRACE THE MSS CHAIN. (THE TERM   04320000
*        -FORBIDDEN REGION- IS USED TO REPRESENT ANY AREA IN CORE       04340000
*        THROUGH WHICH NO PORTION OF A CONTROL BLOCK MAY PASS, SEE      04360000
*        ABEND3.)                                                       04380000
         EJECT                                                          04400000
         BALR  BASEREG,0                                                04420000
         USING *,BASEREG                                                04440000
BND     EQU   12                                                        04460000
BASEREG  EQU   3                                                        04480000
R0       EQU   0                                                        04500000
COMPCON  EQU   16                                                       04520000
COMREG   EQU   1                                                        04540000
RT       EQU   12                      TCB REG                          04560000
TCBRBP   EQU   0                                                        04580000
TCBPIE   EQU   4                                                        04600000
TCBDEB   EQU   8                                                        04620000
TCBTIO   EQU   12                                                       04640000
TCBCMP   EQU   16                                                       04660000
TCBTRN   EQU   20                                                       04680000
TCBMSS   EQU   24                                                       04700000
TCBPKF   EQU   28                                                       04720000
TCBFLGS  EQU   28                                                       04740000
TCBLMP   EQU   34                                                       04760000
TCBDSP   EQU   35                                                       04780000
TCBLLS   EQU   36                                                       04800000
TCBJLB   EQU   40                                                       04820000
TCBJSE   EQU   44                                                       04840000
TCBGRS   EQU   48                                                       04860000
PRBXT    EQU   32                      SIZE OF PRB                 RFOB 04866016
SVBESA   EQU   96                      NORMAL SVRB SIZE            RFOB 04872016
TCBIDF   EQU   112                                                      04880000
TCBFSA   EQU   113                                                      04900000
TCBTCB   EQU   116                                                      04920000
TCBTME   EQU   120                                                      04940000
TCBITB   EQU   124                                                      04960000
XRBNM    EQU   0                                                        04980000
XRBSZ    EQU   8                                                        05000000
XSTAB    EQU   10                                                       05020000
XRBUSE   EQU   12                                                       05040000
XRBEP    EQU   12                                                       05060000
XRBPSW   EQU   16                                                       05080000
XRBQ     EQU   24                                                       05100000
XRBWT    EQU   28                                                       05120000
XRBLNK   EQU   28                                                       05140000
XRBREG   EQU   32                                                       05160000
TRNCNTL  EQU   128                     OFFSET TO ACCESS LAST TWO   RFOB 05165016
*                                      DBL WDS OF ABEND SVRB ESA   RFOB 05170016
SVRBXT   EQU   144                     ABEND SVRB SIZE             RFOB 05175016
RM       EQU   7                                                        05180000
RA       EQU   13                                                       05200000
RP       EQU   14                                                       05220000
R1       EQU   1              DUMP AREA                                 05240000
RC       EQU   2                                                        05260000
RV       EQU   4              WORK                                      05280000
RL       EQU   5              LOWER BND                                 05300000
RB       EQU   6              RB                                        05320000
RW       EQU   7              WORK                                      05340000
RD       EQU   8              DUMP                                      05360000
RS       EQU   9              WORK                                      05380000
RU       EQU   10             UPPER                                     05400000
RSAV     EQU   11             SAVE                                      05420000
R15     EQU   15                                                        05440000
SVCDCB   EQU   84                       DSPLMT OF SVC DCB IN CVT        05460000
********************************************************************    05480000
***************    MSS  VALIDITY  CHECK       **********************    05500000
********************************************************************    05520000
*****   VALIDITY CHECK OF RB, LRB, AND DEB QUEUES    ***************    05540000
*********ENTER VALIDITY CHECKING  FUNCTION****************************  05560000
NTRY     EQU   *                                                        05580000
         SR    2,2            SETUP THE GENERALIZED VALIDITY CHECK      05600000
         SR    4,4            ROUTINE FOR VALIDITY CHECK ONLY           05620000
*        ***                                                            05680000
**************************************                                  05700000
         EJECT                                                          05720000
*      TEST        QUEUE        INTEGRITY         ROUTINE               05740000
         SPACE  2                                                       05760000
**********************************************************************  05780000
*ROUTINE TO ASSURE SYSTEM QUEUE INTEGRITY BY TRUNCATING BAD CHAINS,     05800000
*        AND,DEQUEUEING CONTROL BLOCKS FOUND IN THE FORBIDDEN REGION.   05820000
*        THE 'FORBIDDEN REGION' IS THAT AREA IN CORE WHICH IS ABOUT TO  05840000
*        BE 'STOLEN' (FOR ABDUMP) VIA A FREEMAIN.                       05860000
* NOTE:  VALIDITY CHECK CAN FAIL IF INTERRUPTED, SINCE IT IS EXAMINING  05880000
*        QUEUES AND CHANGING THEM. THEREFORE ANY INTERRUPTS THAT MIGHT  05900000
*        RESULT IN A MODIFICATION OF A QUEUE UNDER EXAMINATION ARE      05920000
*        ASSUMED TO BE PURGED OR IGNORED BY THE DISPATCHER.             05940000
*        UPDATE    SEPTEMBER 22, 1965       D.P.JASPER                  05960000
         SPACE 2                                                        05980000
*  INPUT ,AND                                                           06000000
*   TRANSPARENT REGISTERS TO VALIDITY CHECK ROUTINE                     06020000
         SPACE 2                                                        06040000
*   REG  0 =  TOTAL MAIN STORAGE REQUIREMENT                            06060000
*   REG  2 =  LOW BOUND OF FORBIDDEN REGION                             06080000
*   REG  3 =  BASE REGISTER              *** IF BOTH R2,R4 = ZERO, SAME 06100000
*   REG  4 =  LENGTH OF FORBIDDEN REGION *** AS NO FORBIDDEN REGION.    06120000
*   REG 12 =  ADDR. OF TCB                                              06140000
*   REG 14 =  RETURN REGISTER                                           06160000
         SPACE  2                                                       06180000
*  INTERNAL REGISTERS                                                   06200000
         SPACE  2                                                       06220000
*   XR  =  INTERNAL RETURN REGISTER                                     06240000
*   XL  =  LOW BOUND   FORBIDDEN REGION                                 06260000
*   XB  =  BASE REG.                                                    06280000
*   XH  =  HIGH BOUND  FORBIDDEN REGION                                 06300000
*   XC  =  LOOP COUNT                                                   06320000
*   XA  =  BEGINING OF PARTITION, AND SCRATCH                           06340000
*   XZ  =  END OF PARTITION, AND SCRATCH                                06360000
*   XX  =  TEMPORARY                                                    06380000
*   XW  =  ADDRESS OF XP.                                               06400000
*   XP  =  ADDRESS OF NEXT CONTROL BLOCK                                06420000
*   XF  =  LINK ADDRESS TERMINAL VALUE                                  06440000
*   XT  =  ADDRESS OF TCB                                               06460000
         SPACE 2                                                        06480000
*   REGISTER ABSOLUTES                                                  06500000
*                                                                       06520000
XR       EQU   1                                                        06540000
XL       EQU   2                                                        06560000
XB       EQU   3                                                        06580000
XH       EQU   4                                                        06600000
XC       EQU   5                                                        06620000
XA       EQU   6                                                        06640000
XZ       EQU   7                                                        06660000
XX       EQU   8                                                        06680000
XW       EQU   9                                                        06700000
XP       EQU   10                                                       06720000
XF       EQU  11                                                        06740000
XT       EQU  12                                                        06760000
*                                                                       06780000
**************************************                                  06800000
         EJECT                                                          06820000
        SPACE 2                                                         06840000
AUDITQS  EQU   *          *** ENTRY TO CONTROL BLOCK QUEUE VALIDITY     06860000
         LR    13,XH          SAVE LENGTH/F.R.                 ROUTINE. 06880000
         AR    XH,XL          SET HIGH FOR FORBIDDEN REGION             06900000
         L     XW,QMAX             DUMMY ADDR TO PASS TEST 2,2A (MSS)   06920000
         L     XP,TCBMSS(XT)  START MSS Q                               06940000
         TM    0(XP),X'01'             LCS IN THE SYSTEM           LOOB 06945017
         BZ    NOLCS                   NO, PROCEED NORMAL          LOOB 06950017
         NC    4(8,XP),4(XP)           H0 BEING USED               LOOB 06955017
         BNZ   NOLCS                   YES, PROCEED AS NORMAL      LOOB 06960017
         LA    XP,12(XP)               NO, OBT SECOND BB ADDR      LOOB 06965017
NOLCS    AR    XW,XP                   START MSSQ FROM BB          LOOB 06970017
         L     XP,0(XW)                                                 06980000
         SR    XF,XF          ZERO IS TERMINAL ADDRESS                  07000000
         BAL   XR,VALCMN      CHECK MSS QUEUE                           07020000
         DC    XL1'07'        BOUBLE WORD ALIGN.                        07040000
****   SEE LABEL 'FINALQ'  THAT MASK    MUST AGREE ERROR FLAG (FOR FQE) 07060000
         DC    XL1'01'        ERROR FLAG IN B-B                         07080000
         DC    FL2'08'        FREE-Q ELEMENT SIZE                       07100000
         DC    FL2'00'        LINK FIELD DISPLACEMENT                   07120000
*RETURN                                                                 07140000
         LA    XW,TCBDEB(XT)  START DEB CHAIN                           07160000
         L     XP,0(XW)       TERM. VALUE STILL ZERO                    07180000
         BAL   XR,VALCMN      CHECK DEB CHAIN                           07200000
         DC    XL1'03'        SINGLE WORD ALIGN.                        07220000
         DC    XL1'04'        ERROR FLAG IN B-B                         07240000
         DC    FL2'36'        MIN. DEB SIZE                             07260000
         DC    FL2'04'        LINK FIELD DISPL.                         07280000
*RETURN                                                                 07300000
         LA    XW,TCBLLS(XT)  START LOAD LIST FORWARD                   07320000
         L     XP,0(XW)                                                 07340000
         CR    XP,XF               IF NO LOAD LIST, SKIP                07360000
         BE    NOBACK                   BACK CHAIN                      07380000
         BAL   XR,VALCMN      CHECK LRB/LPRB,FORWARD                    07400000
         DC    XL1'07'        DOUBLE WORD                               07420000
         DC    XL1'08'        ERROR FLAG                                07440000
         DC    FL2'24'                 LOADED RB MIN. SIZE              07460000
         DC    FL2'00'                                                  07480000
*RETURN                                                                 07500000
         LA    XW,4(XW)       START LOAD LIST BACKWARD                  07520000
         L     XP,0(XW)                                                 07540000
        LA    XF,TCBLLS(XT)           ENDS AT TCB POINTER               07560000
         BAL   XR,VALCMN      CHECK LRB/LPRB,BACKWARD                   07580000
         DC    XL1'07'        DOUBLE WORD ALIGN.                        07600000
         DC    XL1'08'        ERROR FLAG IN B-B                         07620000
         DC    FL2'24'                 LOADED RB MIN. SIZE              07640000
         DC    FL2'04'        LINK FIELD DISPL.                         07660000
*RETURN                                                                 07680000
NOBACK   EQU   *                                                        07700000
         LA    XW,TCBRBP(XT)  START  ACTIVE RB CHAIN                    07720000
         L     XP,0(XW)       TERMINAL VALUE STILL  ZERO                07740000
        LR    XF,XW                   ENDS AT TCB POINTER               07760000
         BAL   XR,VALCMN       CHECK ACTIVE RB QUEUE                    07780000
         DC    XL1'03'                 FULL WORD ALLIGN.                07800000
         DC    XL1'02'        ERROR FLAG                                07820000
         DC    FL2'32'        RB  SIZE                                  07840000
        DC    FL2'28'            RB LIK FIELD OFFSET                    07860000
*RETURN                                                                 07880000
*                                                                       07880516
*                                                                       07881016
*  CHECK IF ENOUGH CORE TO BRING IN THE NEXT LOAD OF ABEND         RFOB 07883016
         GETMAIN R,LV=96                                           RFOB 07883516
         LTR   R15,R15                                             RFOB 07884016
         BC    7,WSTEAL                                            RFOB 07884516
         FREEMAIN R,LV=(0),A=(1)       IF ENOUGH CORE, FREE IT     RFOB 07885016
         BC    15,XCTL                                             RFOB 07885516
WSTEAL   EQU   *                                                   RFOB 07886016
*  MUST PROVIDE 96 BYTES FOR SVRB USED BY XCTL                     RFOB 07886516
         L     RM,TCBMSS(RT)           GET BB ADDRESS              RFOB 07887016
         TM    0(RM),X'01'             LCS IN THE SYSTEM           LOOB 07887117
         BZ    ANOLCS                  NO, PROCEED NORMAL          LOOB 07887217
         NC    4(8,RM),4(RM)           YES, IS H0 BEING USED       LOOB 07887317
         BZ    ANOLCS                  YES, PROCEED AS NORMAL      LOOB 07887417
         LA    RM,12(RM)               NO, ADVANCE TO H1           LOOB 07887517
ANOLCS   L     RL,4(RM)                LOAD LOW BND ADDR           LOOB 07887617
         LA    RL,PRBXT(RL)            ESTABLISH FIRST STEAL AREA  RFOB 07888016
         TM    TCBFLGS+1(RT),X'02'     IS CORE ALREADY STOLEN      RFOB 07888516
         BC    8,STEAL2                IF NO, BRANCH               RFOB 07888618
         TM    TCBCMP(RT),X'20'        IS SECOND STEAL BIT ON      4183 07888718
         BNO   OKSTEAL                 NO,ITS SAFE TO STEAL        4183 07888818
         L     RA,0(RT)                GET ADDR OF ABEND'S SVRB    4183 07888918
         ST    RT,XRBLNK(RA)           DEQUEUE ALL RB'S FROM CHAIN 4183 07889018
         OI    XSTAB+1(RA),X'80'       EXCEPT ABEND'S              4183 07889118
OKSTEAL  EQU   *                                                   4183 07889218
         OI    TCBCMP(RT),X'20'        SET SECOND STEAL BIT        RFOB 07889516
         LA    RL,SVRBXT(RL)           INCREMENT OVER ABEND SVRB   RFOB 07890016
STEAL2   ST    RL,0(RL)                SET UP MOVE TO BB           LOOB 07890317
         MVC   1(3,RM),1(RL)           MOVE NEW FQE ADDR IN BB     LOOB 07890617
         XC    0(4,RL),0(RL)           ZERO FQE LINK POINTER       RFOB 07891016
         LA    RS,SVBESA               ESTABLISH SIZE OF FQE       RFOB 07891516
         ST    RS,4(RL)                STORE IN THE MSS ELEMENT    RFOB 07892016
         OI    TCBFLGS+1(RT),X'02'     SET FIRST STEAL BIT         RFOB 07892516
XCTL     EQU   *                                                   RFOB 07893016
         LR    XH,13                   RESTORE LENGTH OF FORBI REG RFOB 07893516
         LA    15,WSIRB                ADDRESS OF EXITER           RFOB 07894016
         DS    0H                                                  RFOB 07894516
         L     RA,0(RT)                ADDRESS OF ABEND SVRB       RFOB 07895016
         LA    RA,TRNCNTL(RA)          ADDRESS THE LAST TWO DOUBLE RFOB 07895516
*                                      WORDS OF THE ABEND SVRB     RFOB 07896016
*                                      EXTENDED SAVE AREA          RFOB 07896516
         ST    15,0(RA)                ADDR OF NAME IN LIST        RFOB 07897016
         LR    15,RA                   PASS ADDR OF LIST TO XCTL   RFOB 07897516
         XCTL  SF=(E,(15))                                              07898016
         SPACE 3                                                        07900000
*        ***                                                            07960000
         DS    0F                                                       07980000
QMAX     DC    XL4'10000000'       MAKES ADDRESS FROM B-B SEEM LARGE    08000000
*                                                                       08000517
*  THE FOLLOWING TESTS INSPECT THE CB SIZE AND LOCATION REFERENCE  LOOB 08001017
*  THE UPPER AND LOWER BOUNDS OF THE APRTITION SEGMENTS IF LCS     LOOB 08001517
*  IS IN THE SYSTEM.                                               LOOB 08002017
*                                                                       08002517
BOUNTSTA L     XX,TCBMSS(XT)           LOAD ADDR OF BB             LOOB 08003017
         L     XX,8(XX)                OBT UPR BND OF SEG1         LOOB 08003517
SEGINUSE CR    XX,XF                   IS SEG BEING USED           LOOB 08004017
         BE    BADCB                   NO, CB OUT OF PARTITION     LOOB 08004517
         SH    XX,SZE(XR)              REDUCE HIGH BY CB SIZE      LOOB 08005017
         CR    XZ,XX                   UPR = 1ST SEG UPR BND       LOOB 08005517
         BNE   MAYBEBAD                NO, ONE MORE TEST           LOOB 08006017
         L     XX,TCBMSS(XT)           LOAD ADDR OF BB             LOOB 08006517
         L     XX,20(XX)               OBT UPR BND OF SEG2         LOOB 08007017
         B     SEGINUSE                TEST IF THIS SEG BEING USED LOOB 08007517
*                                                                       08008017
MAYBEBAD CR    XP,XX                   IS CB OUT OF SEGMENT        LOOB 08008517
         BH    BADCB                   NOT WITHIN SEGMENT          LOOB 08009017
         B     TRBCHAIN                BRANCH TO TEST RB CHAIN     LOOB 08009517
*                                                                       08010017
*                                                                       08010517
BOUNTSTB L     XX,TCBMSS(XT)           LOAD ADDR OF BB             LOOB 08011017
         L     XX,4(XX)                OBTAIN LOWER BND OF SEG     LOOB 08011517
SGINUSE2 CR    XX,XF                   IS THE SEGMENT IN USE       LOOB 08012017
         BE    BADCB                   NO,CB OUT OF  PARTITION     LOOB 08012517
         CR    XX,XA                   LOWER = 1ST SEG LB          LOOB 08013017
         BNE   MABEBAD2                NO, ONE MORE TEST           LOOB 08013517
         L     XX,TCBMSS(XT)           LOAD ADDR OF BB             LOOB 08014017
         L     XX,16(XX)               OBTAIN LOWER BOUND          LOOB 08014517
         B     SGINUSE2                TEST IF THIS SEGMENT IS USEDLOOB 08015017
*                                                                       08015517
MABEBAD2 CR    XP,XX                   IS CB OUT OF SEGMENT        LOOB 08016017
         BL    BADCB                   NOT WITHIN EITHER SEGMENT   LOOB 08016517
         B     NUCRB                   CB WITHIN PARTITION         LOOB 08017017
        EJECT                                                           08020000
**************************************                                  08040000
* COMMON ROUTINE,VALIDITY CHECK                                         08060000
*                                                                       08080000
*  XR =  RETURN AND CALLING PARAMETER LIST.                             08100000
*        PARAM. DISPLACEMENTS:                                          08120000
*                                                                       08140000
WRD      EQU   0  BOUNDARY ALIGNMENT MASK (SINGLE,DOUBLE)               08160000
ERR      EQU   1  MASK FOR CB ERROR FLAG IN BOUNDARY BOX                08180000
SZE      EQU   2  CONTROL BLOCK SIZE                                    08200000
LNK      EQU   4  DISPLACEMENT TO LINK FIELD FOR THIS CB.               08220000
OUT      EQU   6                                                        08240000
*                                                                       08260000
FQCNT    EQU   4                                                        08280000
        SPACE 2                                                         08300000
*        BASIC VALIDITY CHECK OF MSS,DEB,LRB, AND ARB                   08320000
*              -FOR LOOPS (MAX. NO.=300, EXCEPT FOR MSS)                08340000
*              -IF CONTROL BLOCK WITHIN P/P PARTITION.                  08360000
*              -FOR PROPER BOUNDARY ALIGNMENT.                          08380000
**************************************                                  08400000
           SPACE  3                                                     08420000
VALCMN   EQU   *           ** COMMON VERIFY SUBROUTINE...ENTRY          08440000
         LA    XC,300         INITIALIZE LOOP COUNT.                    08460000
         SPACE 2                                                        08480000
VALTOP   EQU   *            * INTERNAL QUEUE LOOP, ENTRY                08500000
         L     XA,TCBMSS(XT)  GET BOUNDARY BOX                          08520000
         TM    0(XA),X'01'             IS LCS IN THE SYSTEM        LOOB 08528017
         BZ    ZNOLCS                  NO, PROCEED AS NORMAL       LOOB 08536017
         NC    4(8,XA),4(XA)           IS H0 BEING USED            LOOB 08544017
         BNZ   ZNOLCS                  YES, PROCEED AS NORMAL      LOOB 08552017
         LA    XA,12(XA)               ADVANCE PTR TO H1           LOOB 08560017
ZNOLCS   LM    XA,XZ,4(XA)             LOAD UPR AND LWR BND        LOOB 08568017
         LA    XA,0(XA)       CLEAR TOP OF REG.                         08580000
         LA    XZ,0(XZ)       CLEAR HIGH-ORDER NOISE.                   08600000
         SH    XZ,SZE(XR)     REDUCE HIGH BY CB SIZE.                   08620000
        SPACE 2                                                         08640000
         LA    XP,0(XP)       CLEAR TOP OF REG.                         08660000
         CR    XP,XF          TEST IF LAST CB                           08680000
         BE    OUT(XR)             EXIT  COMMON                         08700000
         CR    XP,XZ                    TEST NCB, UPPER PARTITION.      08720000
         BH    BOUNTSTA                BRANCH TO TEST UPR BND      LOOB 08740017
TRBCHAIN TM    ERR(XR),X'02'           TEST FOR RB CHAIN           LOOB 08760017
         BZ    NOTRB                      ANS.= NO, BR.                 08780000
         TM    XSTAB(XP),X'C0'          TEST FOR SIRB OR IRB.           08800000
         BM    NUCRB                      ANS= YES, BR. OVER LOWER      08820000
NOTRB    EQU   *                                                        08840000
         CR    XP,XA                    TEST IF LOWER THAN PART.        08860000
         BL    BOUNTSTB                BRANCH TO TEST LOW BOUND    LOOB 08880017
NUCRB    EQU   *                                                        08900000
*                         YES,WITHIN PARTITION                          08920000
         IC    XX,WRD(XR)     LOAD BOUNDARY ALIGNMENT MASK              08940000
         EX    XX,TMI         TEST ALIGNMENT                            08960000
         BC    7,BADCB            BRANCH, IF ANY ONES                   08980000
         LA    XX,0(XL)       OK                                        09000000
         SH    XX,SZE(XR)     COMPUTE LOW FORBIDDEN - CBSIZE            09020000
         CR    XP,XX          TEST CB                                   09040000
         BNH   FINALQ             EQUAL OR LOW, OK TO BRANCH            09060000
         CR    XP,XH                                                    09080000
         BL    RELINKS            IF WITHIN , REMOVE FROM CHAIN         09100000
FINALQ   EQU   *                                                        09120000
        TM    ERR(XR),X'01'           TEST FOR MSS CHAIN                09140000
         BO    VALMSS              GO TO MORE TESTS                     09160000
***********************************                                     09180000
*                                 CROSS CHECK DEB AND RB CONTROL        09200000
*                                      BLOCKS TO ELIMINATE ANY FREE QUE 09220000
         L     RP,0(XT)                ADDR OF ABEND SVRB IN R 14  RFOB 09240016
         LA    RP,SVBESA(RP)           ADDR OF EXTENDED SAVE AREA  RFOB 09260016
         STM   XR,XH,0(RP)             SAVE REGISTERS AND REENTER  RFOB 09280016
         STM   XW,XF,16(RP)            CODE                        RFOB 09300016
         LR    XL,XP              SET UP A FORBIDDEN REGION             09320000
         LH    XH,SZE(XR)         EQUAL TO NEXT DEB OR RB.              09340000
         AR    XH,XL                                                    09360000
         L     XW,QMAX            START MSS CHAIN                       09380000
         L     XP,TCBMSS(XT)      MAKE B-B VALUE HIGHER IN              09400000
         AR    XW,XP                   CORE THAN FIRST FQE,FOR          09420000
         L     XP,0(XW)                MSS TEST(2)                      09440000
         SR    XF,XF              END-OF-LIST VALUE = ZERO              09460000
         BAL   XR,VALTOP          PRESERVE LOOP COUNT                   09480000
         DC    XL1'07'            DOUBLE ALIGNMENT                      09500000
         DC    XL1'01'            ERROR                                 09520000
         DC    FL2'08'            FQE SIZE                              09540000
         DC    FL2'00'            LINK FIELD DISPLACEMENT               09560000
         LM    XR,XH,0(RP)             RESTORE REGISTERS           RFOB 09590016
         LM    XW,XF,16(RP)                                        RFOB 09620016
**********************************                                      09660000
         BCT   XC,GETNCB      TEST FOR LOOP.                            09680000
        SPACE 2                                                         09700000
        SPACE 2                                                         09720000
BADCB    EQU   *                                                        09740000
        IC    XX,0(XW)                PRESERVE 1ST BYTE                 09760000
         ST    XF,0(XW)       CUT CHAIN  (STORE TERM. VALUE)            09780000
        STC   XX,0(XW)                RESTORE 1ST BYTE OF LINK POINTR   09800000
         L     XA,TCBMSS(XT)  SET REG.S FOR EXECUTE ERR MASK            09820000
         IC    XX,ERR(XR)          PICK UP ERROR MASK                   09840000
         BCTR  XA,0                    DECREMENT BB ADDR BY ONE    LOOB 09850017
         EX    XX,OII         SET FLAG IN B-B  FOR THIS CB.             09860000
         BAL   XX,CKRB                  CHECK IF RB CHAIN          3734 09870018
         B     OUT(XR)        EXIT   COMMON      SUBROUTINE             09880000
*        ***                                                            09900000
        SPACE 2                                                         09920000
RELINKS  EQU   *                THIS ENTRY SETS STOLEN ONLY BITS(B-B)   09940000
         IC    XX,ERR(XR)     FOR THIS TYPE CB                          09960000
         SLA   XX,4(0)        STOLEN-ONLY BIT                           09980000
         B     QERR                      BRANCH AROUND OTHER ENTRY PT.  10000000
RELINK   EQU   *                                                        10020000
         IC    XX,ERR(XR)          ERR FLAG FOR THIS TYPE CB.           10040000
QERR     EQU   *                                                        10060000
         L     XA,TCBMSS(XT)  SET FLAG IN B-B                           10080000
         BCTR  XA,0                    DECREMENT BB ADDR BY ONE    LOOB 10090017
         EX    XX,OII                                                   10100000
         AH    XP,LNK(XR)     ADDR OF LINK FIELD                        10120000
         L     XP,0(XP)       GET LINK ADDRESS                          10140000
        IC    XX,0(XW)                PRESERVE 1ST BYTE                 10160000
         ST    XP,0(XW)       STORE IN OLD CB                           10180000
        STC   XX,0(XW)                RESTORE 1ST BYTE OF LINK POINTR   10200000
         BAL   XX,CKRB                  CHECK IF RB CHAIN          3734 10210018
         BCT   XC,VALTOP      RESET SOME REG.S AND CONTINUE             10220000
         B     BADCB                     EXCEED LOOP COUNT              10240000
*        ***                                                            10260000
CKRB     EQU   *                                                   3734 10261018
         TM    ERR(XR),X'02'            Q. IS THIS RB QUEUE        3734 10262018
         BCR   8,XX                     NO-RETURN TO CALLER        3734 10263018
         L     XA,0(XW)                 GET ADDR STORED            3734 10264018
         LA    XA,0(XA)                 CLEAR NOISE                3734 10265018
         CLR   XA,RT                    Q. IS THIS LAST RB ON QUEUE3734 10266018
         BCR   7,XX                     NO-RETURN                  3734 10267018
         LR    XA,XW                    GET LINK ADDR OF RB        3734 10268018
         SH    XA,LNK(XR)               GET PTR TO START OF RB     3734 10269018
         OI    XSTAB+1(XA),X'80'        SET LAST INDICATOR         3734 10270018
         BR    XX                       RETURN TO CALLER           3734 10271018
**************************************                                  10280000
*        MSS FREE QUEUE ELEMENT ONLY.                                   10300000
*              -IF SIZE FIELD A MULTIPLE OF 8 BYTES.                    10320000
*              -IF QUEUES ARE IN DESCENDING ORDER.                      10340000
*              -FOR OVERLAPPING FREE ARES.                              10360000
*              -IF ENTIRE FREE BLOCK IN P/P PARTION.                    10380000
        SPACE 2                                                         10400000
**************************************                                  10420000
VALMSS   EQU   *          **  MSS ONLY TESTS FOLLOW                     10440000
         TM    FQCNT(XP),X'07'  1. IS COUNT MULT./DBLE WRDS.            10480000
         BC    7,RELINK                 ANS.= NO, BRANCH                10500000
         CR    XP,XW        2.IS QUEUE IN ASCENDING ORDER               10520000
         BNL   RELINK           ANS.= NO, BRANCH                        10540000
         L     XX,FQCNT(XP)   ADD POINTER + COUNT                       10560000
         AR    XX,XP              TO GET LAST FREE BYTE OF THIS BLOCK   10580000
        CR    XX,XW          2A.DO FREE AREAS OVERLAP NEXT FQE          10600000
        BNL   RELINK                ANS.= LAST-FREE-BYTE >  NEXT FQE    10620000
         AH    XZ,SZE(XR)              RESTORE TRUE PARTITION LIMIT     10640000
         CR    XX,XZ        3.COMPARE LAST-FREE-BYTE TO CORE LIMIT      10660000
         BH    RELINK           ANS.= EXCEEDS PARTITION, BRANCH         10680000
         CR    XP,XL        4. IS L-F-B IN OR DOES FREE  AREA CROSS     10700000
         BH    GETNCB              THE FORBIDDEN REGION.                10720000
         CR    XX,XL                                                    10740000
         BH    RELINKS              = YES, RELINK CHAIN.                10760000
*        B     GETNCB         LOOP COUNT NOT NEEDED WITH TEST 2.(ABOVE) 10780000
        SPACE 2                                                         10800000
GETNCB   EQU   *                                                        10820000
         LA    XW,0(XP)            GET POINTER TO NEXT CB               10840000
         AH    XW,LNK(XR)     ADDR OF LINK FIELD                        10860000
         L     XP,0(XW)       PICK UP LINK ADDRESS (IT'S SAFE NOW)      10880000
         B     VALTOP                  CONTINUE CHECKING                10900000
*                                                                       10920000
        SPACE 2                                                         10940000
*                                                                       10960000
OII      OI    0(XA),X'00'             SET FLAG IN BB              LOOB 10980017
TMI      TM     3(XW),X'00'   TEST BOUNDARY ALIGNMENT                   11000000
*                                                                       11020000
WSIRB    DC    C'IGC0A01C'              MAIN STOR LOAD             I250 12020019
         END                                                            13940000
