IGC0501C CSECT                                                          00020000
*4406085600,086000,270000,290000,354000                            9836 00030016
*20240477,0578,0584                                                     00040000
*2500058400,061400-062000,075000                                   LOOB 00050017
         TITLE 'IEAATM05 / ABEND LOAD 6 / IGC0501C'                     00060000
* STATUS- CHANGE LEVEL 000                                              00080000
* IEAATM05, ABEND LOAD 6, CLEAN-UP LOAD                                 00100000
         SPACE 2                                                        00120000
         SPACE  2                                                       00140000
*   ROUTINE NAME ... ABEND6                                             00160000
         SPACE  2                                                       00180000
*   MODULE NAME ... IEAATM05                                            00200000
         SPACE  2                                                       00220000
*   CHART ID ... PP                                                     00240000
         SPACE  2                                                       00260000
*   FUNCTION ...                                                        00280000
         SPACE 2                                                        00300000
*        CLOSE ALL DATA SETS,PURGE TIMER QUEUE,RESET TCB FIELDS,        00320000
*        FREE STORAGE FOR NEXT TASK,AND TRANSFER CONTROL TO             00340000
*        THE JOB SCHEDULER.                                             00360000
         SPACE 2                                                        00380000
*   ENTRY ...                                                           00400000
         SPACE 1                                                        00420000
*        ABEND6 IS ENTERED IN SUPERVISOR STATE,WITH SUPERVISOR PROTECT  00440000
*        KEY AND WITH I/O AND EXTERNAL INTERRUPTS DISABLED. ABEND6 IS   00460000
*        ENTERED AT ENTRY POINT IGC0501C.ABEND6 CAN BE ENTERED FROM     00480000
*        ANY OF THE PREVIOUS LOADS OF ABEND. ON NORMAL END IT IS        00500000
*        ENTERED FROM ABEND1. ON AN ABNORMAL END IT COULD HAVE BEEN     00520000
*        ENTERED FROM ABEND2...IF NO DUMP WAS REQUESTED...FROM ABEND3   00540000
*        IF NO DUMP WAS REQUESTED AND CORE HAD TO BE OBTAINED FOR       00560000
*        CLOSE...FROM ABEND 4 IF AN INDICATIVE DUMP WAS TAKEN...        00580000
*        AND FROM ABEND5 IF THE ABNORMAL TERMINATION DUMP WAS           00600000
*        SUPPLIED.                                                      00620000
         SPACE 2                                                        00640000
*   INPUT ...                                                           00660000
*        TCBFLGS SET BY PREVIOUS LOADS OF ABEND TO PROVIDE ABEND6 WITH  00680000
*        INFORMATION AS TO WHETHER IT IS A NORMAL END, ABNORMAL END     00700000
*        WITH OR WITHOUT AN INDICATIVE DUMP,(ETC.).                     00720000
         SPACE   2                                                      00740000
*   OUTPUT ...                                                          00760000
*        THE OUTPUT OF ABEND6 IS ESSENTIALLY A RE-INITIALIZED SYSTEM    00780000
*        READY FOR THE NEXT TASK.                                       00800000
         SPACE   1                                                      00820000
*        THE STATUS OF THE TCB FIELDS UPON COMPLETION OF ABEND6 ARE...  00840000
         SPACE   1                                                      00860000
*        TCBRBP-ACTIVE RB-POINTS TO THE DUMMY PRB                       00880000
*        TCBPIE-PIE POINTER-CLEARED(SET TO ZEROES)                      00900000
*        TCBDEB-DEB QUEUE-CLEARED                                       00920000
*        TCBTIO-POINTER TO TIOT-THIS FIELD IS CLEARED ON A NORMAL OR    00940000
*                               ABNORMAL END WITH NO INDICATIVE DUMP.   00960000
*                               IF AN INDICATIVE DUMP IS PROVIDED ON    00980000
*                               ABNORMAL END,THIS FIELD CONTAINS THE    01000000
*                               UPPER BOUND OF TAE PARTITION.           01020000
*                               (INDICATIVE DUMP MATERIAL STARTS ONE    01040000
*                                BYTE BELOW THIS ADDRESS.)              01060000
*        TCBCMP-TASK COMPLETION CODE-UNCHANGED                          01080000
*        TCBTRN-TESTRAN FIELD-CLEARED                                   01100000
*        TCBMSS-MAIN STORAGE SUPERVISOR BOUNDARY BOX-UNCHANGED          01120000
*        TCBPKF-PROTECT KEY FIELD-UNCHANGED                             01140000
*        TCBFLGS-GROUP1-CLEARED EXCEPT FOR ABNORMAL TERMINATION BIT     01160000
*                       AND THE NORMAL END BIT,TCBFA AND TCBFB          01180000
*                       RESPECTIVELY.                                   01200000
*                GROUP2-HIGH PRIORITY BIT TCBFTCTC UNCHANGED.ALL OTHER  01220000
*                       GROUP2 BITS ARE ZEROED.                         01240000
*                GROUP3-ALL CLEARED.                                    01260000
*        TCBLMP-LIMIT PRIORITY-UNCHANGED                                01280000
*        TCBDSP-DISPATCHING PRIORITY-UNCHANGED                          01300000
*        TCBLLS-POINTER TO LOAD LIST-CLEARED                            01320000
*        TCBJLB-DCB OF JOB LIBRARY-CLEARED                              01340000
*        TCBJSE-LIST OF INACTIVE PROGRAMS-CLEARED                       01360000
*        TCBGRS-GENERAL REGISTER SAVE AREA-UNCHANGED                    01380000
*        TCBIDF-TCB IDENTIFIER-UNCHANGED                                01400000
*        TCBFSA-POINTER TO FIRST SAVE AREA-CLEARED                      01420000
*        RCBTCB-NEXT TCB ON THE READY QUEUE-UNCHANGED                   01440000
*        TCBTME-POINTER TO TIMER ELEMENT-UNCHANGED                      01460000
*        TCBNSTAE-ADDR OF STAE CONTROL BLOCK-CLEARED               STAE 01470017
         SPACE   2                                                      01480000
*        STORAGE ALLOCATION AT END OF TASK TERMINATION                  01500000
         SPACE  1                                                       01520000
*        . THE FIRST 72 BYTES OF THE PROBLEM PROGRAM PARTITION ARE      01540000
*        ALLOCATED AND USED FOR A 32 BYTE DUMMY PRB AND A 40 BYTE       01560000
*        PARAMETER LIST FOR XCTL AND INSTRUCTIONS TO TRANSFER CONTROL.  01580000
*        THESE 72 BYTES WILL BE RELEASED IN THE PROCESS OF              01600000
*        TRANSFERRING CONTROL.                                          01620000
         SPACE   1                                                      01640000
*        . IF AN INDICATIVE DUMP HAS BEEN PROVIDED BY ABEND, AN         01660000
*        ADDITIONAL 504 BYTES AT THE TOP OF THE PARTITION WILL BE       01680000
*        ALLOCATED FOR THE INDICATIVE DUMP INFORMATION AND              01700000
*        MUST BE RELEASED BY THE SCHEDULERS AFTER PRINTING THE DUMP.    01720000
         SPACE   1                                                      01740000
*        . ALL OTHER PROBLEM PROGRAM WILL BE DESIGNATED                 01760000
*        AS FREE STORAGE.                                               01780000
         SPACE   2                                                      01800000
*   EXTERNAL REFERENCES ...                                             01820000
         SPACE 1                                                        01840000
*        ABEND6 REFERENCES THE CVT AND ALL FIELDS OF THE TCB,           01860000
*        ALSO THE MASTER SCHEDULER IRB.                                 01880000
         SPACE   1                                                      01900000
*        A. CVT                                                         01920000
*          SYMBOLIC OFFSET-CVTMSLT-MASTER RESIDENT SAVE AREA            01940000
*                                (USED TO LOCATE CONSOLE FLAG)          01960000
*                         CVTQDT00-TIMER DEQUEUE ROUTINE                01980000
*                         CVTTPC-ADDRESS OF PSEUDO CLOCK                02000000
*                                (USED TO DETERMINE IF TIMER IS AN      02020000
*                                 OPTION ON THIS SYSTEM)                02040000
*        B. TCB                                                         02060000
*                ALL FIELDS (SEE OUTPUT WRITE-UP FOR DETAILS)           02080000
         SPACE  2                                                       02100000
*        ABEND STATUS BITS ... (IF BIT IS 1 FOLLOWING INFO IS TRUE)     02120000
         SPACE  1                                                       02140000
*        TCBFLGS+1                                                      02160000
         SPACE  1                                                       02180000
*          BIT0-ABNORMAL TERMINATION IN PROCESS        (ABEND BIT)      02200000
*          BIT1-NORMAL TERMINATION IN PROCESS          (NORMAL END BIT) 02220000
*          BIT2-ABEND WAS INITATED BY ABTERM                            02240000
*          BIT3-SECOND ENTRY INTO ABEND IS PERMISSIBLE                  02260000
*          BIT4-RESERVED                                                02280000
*          BIT5-CLOSE HAS BEEN INITIATED BY ABEND                       02300000
*          BIT6-STORAGE HAS BEEN OVERLAID TO PROCESS ABEND              02320000
*          BIT7-PROHIBIT QUEUING OF ASYNCHRONOUS EXITS FOR THIS TCB     02340000
         SPACE  1                                                       02360000
         SPACE  1                                                       02380000
*        TCBFLGS+2                                                      02400000
*          BIT0-THIS TASK CANNOT BE TERMINATED                          02420000
*          BIT5-ABEND HAS INITIATED ABDUMP FOR THIS TASK                02440000
        SPACE  1                                                        02460000
*        TCBCMP FIELD                                                   02480000
         SPACE  1                                                       02500000
*          BIT0-A DUMP IS REQUESTED FOR THIS TASK                       02520000
*          BIT1-RESERVED                                                02540000
*          BIT2-STORAGE WAS OVERLAID TO REACH SECOND ABEND LOAD         02560000
*          BIT3-ABEND HAS INITIATED A WTO AND WILL LOAD A WAIT STATE    02580000
*                  PSW WHEN RETURNED                                    02600000
*          BIT4-ABEND HAS BEEN ENTERED A SECOND TIME                    02620000
*          BIT5-A DUMP MESSAGE IS REQUIRED                              02640000
*          BIT6-AN INDICTIVE DUMP IS PROVIDED                           02660000
         SPACE   2                                                      02680000
*   EXITS ...                                                           02700000
*        ABEND6 TRANSFERS CONTROL TO THE JOB SCHEDULER ROUTINES.        02720000
         SPACE   2                                                      02740000
*   ERROR MESSAGES ...                                                  02760000
         SPACE   1                                                      02780000
*        IEA002I  ABEND/ABDUMP ERROR. NO ABEND OUTPUT.                  02800000
         SPACE   1                                                      02820000
*        ABEND HAS ATTEMPTED TO PROVIDE AN ABNORMAL TERMINATION DUMP    02840000
*        (ABDUMP) FOR THIS TASK AND HAS BEEN REENTERED. NO DUMP(OR      02860000
*        POSSIBLE PORTION OF THE DUMP) BUT ABEND WILL INITIATE THE      02880000
*        SYSTEM FOR THE NEXT TASK.                                      02900000
         SPACE   2                                                      02920000
*   WORK AREA ...                                                       02940000
         SPACE   1                                                      02960000
*        ABEND6 SETS UP A PRB,XCTL PARAMETER LIST AND SEVERAL           02980000
*        INSTRUCTIONS IN A 72-BYTE AREA OF PROBLEM PROGRAM STORAGE.     03000000
*        THIS IS THE MECHANISM BY WHICH CONTROL IS PASSED TO THE        03020000
*        JOB MANAGEMENT ROUTINES.                                       03040000
         SPACE   1                                                      03060000
*        THE JOB MANAGEMENT ROUTINES MUST BE ENTERED ENABLED AND THE    03080000
*        XCTL INSTRUCTION MUST BE IN PROBLEM PROGRAM STORAGE INSTEAD    03100000
*        OF THE TRANSIENT AREA. THE REASON FOR THIS IS BECAUSE ABENDS   03120000
*        SVRB NO LONGER IS ON THE ACTIVE RB QUEUE WHEN IT IS NECESSARY  03140000
*        TO ENABLE. IF AN INTERRUPT OCCURS AT THIS POINT IN TIME,AND    03160000
*        THE TRANSIENT AREA HAS BEEN OVERLAID, THE TRANSIENT ABEND      03180000
*        ROUTINE WOULD NOT BE REFRESHED IN THE TRANSIENT AREA.THEREFORE 03200000
*        ABEND MOVES THE ENABLING AND XCTL INSTRUCTIONS TO PROBLEM      03220000
*        PROGRAM STORAGE AND BRANCHES TO THESE INSTRUCTIONS.            03240000
         SPACE   2                                                      03260000
*   OPERATION ...                                                       03280000
         SPACE   1                                                      03300000
*        ABEND6 PERFORMS THE FOLLOWING FUNCTIONS...                     03320000
         SPACE   1                                                      03340000
*        . WRITES A MESSAGE TO THE OPERATOR IF ABDUMP HAS BEEN          03360000
*        ATTEMPTED BUT FAILED TO COMPLETE.                              03380000
*        . ISSUES A CLOSE FOR ANY OPEN DATA SETS                        03400000
*        . PURGES THE TIMER QUEUE.                                      03420000
*        . RESETS THE CONSOLE FLAG AND THE MASTER SCHEDULER IRB.        03440000
*        . MOVES THE INDICATIVE DUMP,IF ONE IS PROVIDED,TO THE          03460000
*        UPPER BOUND OF THE PARTITION.                                  03480000
*        . RESETS FIELDS IN THE TCB SO A NEW TASK CAN BE INITIATED.     03500000
*        . RESETS THE MAIN STORAGE SUPERVISOR QUEUE.                    03520000
*        . TRANSFERS CONTROL TO THE CSHEDULERS BY SETTING UP A DUMMY    03540000
*        PRB AT THE BEGINNING OF THE PARTITION AND THEN ISSUING         03560000
*        A TRANSFER CONTROL.                                            03580000
         EJECT                                                          03600000
         BALR  BASEREG,0                                                03620000
         USING *,BASEREG                                                03640000
BND      EQU   24        DISPL OF BND ADDR IN ABTERM                    03660000
BASEREG  EQU   3                                                        03680000
CVTQTD00 EQU   X'6C'                                                    03700000
CVTQTE00 EQU   X'68'                                                    03720013
TCBRBP   EQU   0                                                        03740000
TCBPIE   EQU   4                                                        03760000
TCBDEB   EQU   8                                                        03780000
TCBTIO   EQU   12                                                       03800000
TCBCMP   EQU   16                                                       03820000
TCBTRN   EQU   20                                                       03840000
TCBMSS   EQU   24                                                       03860000
TCBPKF   EQU   28                                                       03880000
TCBFLGS  EQU   28                                                       03900000
TCBLMP   EQU   34                                                       03920000
TCBDSP   EQU   35                                                       03940000
TCBLLS   EQU   36                                                       03960000
TCBJLB   EQU   40                                                       03980000
TCBJSE   EQU   44                                                       04000000
TCBGRS   EQU   48                                                       04020000
TCBIDF   EQU   112                                                      04040000
TCBFSA   EQU   113                                                      04060000
TCBTCB   EQU   116                                                      04080000
TCBTME   EQU   120                                                      04100000
TCBITB   EQU   124                                                      04120000
TCBNSTAE EQU   160                     STAE FIELD IN TCB           STAE 04130017
TCBDAR   EQU   172                                                 DAR  04135018
XRBNM    EQU   0                                                        04140000
XRBSZ    EQU   8                                                        04160000
XSTAB    EQU   10                                                       04180000
XRBUSE   EQU   12                                                       04200000
XRBEP    EQU   12                                                       04220000
XRBPSW   EQU   16                                                       04240000
XRBQ     EQU   24                                                       04260000
XRBWT    EQU   28                                                       04280000
XRBLNK   EQU   28                                                       04300000
XRBREG   EQU   32                                                       04320000
DCBDISP  EQU   40                       POSITION OF DDNAME IN DCB       04340000
DEBREG   EQU   6                                                        04360000
INPREG   EQU   1                                                        04380000
MACDISP  EQU   50                       DISP OF MACR FLGS FOR OPEN      04400000
BEGFREE  EQU   72                       SIZE OF XCTL PRB AND PARAMETERS 04420000
COMPCON  EQU   16                                                       04440000
XCTLST   EQU   32                                                       04460000
CVTXAPG  EQU   20                      ADDR OF IOS APPEND TABLE    SDOB 04462016
CVTQCBO  EQU   148                     QCB ORIGIN IN CVT           SDOB 04464016
CVTILK2  EQU   40                      PTR TO UCB LOOK-UP TABLE    SDOB 04466016
UCBTYP   EQU   16                      DEVICE TYPE IN UCB          SDOB 04468016
UCBRESV  EQU   40                      UCB RESERVE COUNT           SDOB 04470016
UCBSKA   EQU   48                      BIN NUMBER                  SDOB 04472016
TCBRESV  EQU   34                      TCB RESERVE COUNT           SDOB 04474016
R0      EQU   0                                                         04480000
R1      EQU   1                                                         04500000
RC      EQU   2                                                         04520000
RBASE   EQU   3                                                         04540000
RV      EQU   4                                                         04560000
RL      EQU   5                                                         04580000
RU      EQU   6                                                         04600000
RW      EQU   7                                                         04620000
RD      EQU   8                                                         04640000
RS      EQU   9                                                         04660000
RB      EQU   10                                                        04680000
RM      EQU   11                                                        04700000
RT      EQU   12                                                        04720000
RA      EQU   13                                                        04740000
RN      EQU   14                                                        04760000
R15     EQU   15                                                        04780000
         MVI   20,X'00'                 CLEAR STOP TRACE INDIC.  A27771 04781019
         TM    TCBDAR(RT),X'10'        HAS CLOSE BEEN TRIED AFTER DAR?  04786018
         BO    DEBDEQ                   YES-DEQ FAILING DEB       19272 04793019
         TM    TCBFLGS+1(RT),X'40'      IS THIS NORMAL END       A35704 04843000
         BO    NOM                      YES. SKIP MSG            A35704 04893000
WCLOSE  DS    0C                                                        04960000
        TM    TCBCMP(RT),X'04'        NEED DUMP MESSAGE                 04980000
* IF ENTRY TO THIS MODULE IS FROM DAR, THE TEST OF THE MESSAGE BIT      04985018
* WILL ALWAYS PROVE NEGATIVE SINCE DAR WILL CLEAR THE BIT TO PREVENT    04990018
* THE PRINTING OF THE MESSAGE.                                          04995018
        BC    8,NOM                                                     05000000
         L     R1,0(RT)                GET SVRB ADDR               DAR  05020018
         LA    R1,96(R1)               GET ESA ADDR                DAR  05040018
         MVC   0(MSGLEN,R1),DUMPMESS   PUT MSG IN ESA              DAR  05060018
        WTO   MF=(E,(1))              REG 1 CONTAINS MESSAGE ADDR       05100000
NOM     DS    0H                                                        05120000
         NI    TCBFLGS+1(RT),X'BF'      TURN OFF NORM END BIT    A35704 05130000
        TM    TCBFLGS+1(RT),X'04'      HAS CLOSE BEEN INITIATED         05140000
         BO    DEBDEQ                   YES-DEQ FAILING DEB       19272 05160019
         TM    TCBFLGS+1(RT),X'80'                                      05180000
         BC    8,QQQQA                                                  05200000
         TM    TCBDAR(RT),X'80'        ENTRY FROM DAR?             DAR  05204018
         BZ    QQQQW1                  NO, BRANCH                  DAR  05208018
         OI    TCBDAR(RT),X'10'        INDICATE CLOSE AFTER DAR    DAR  05212018
QQQQW1   EQU   *                                                   DAR  05216018
         OI    TCBFLGS+1(RT),X'04'                                      05220000
QQQQA    OI    TCBFLGS+1(RT),X'10'                                      05240000
         SR    R1,R1                   ZERO INPUT REGISTER              05260017
        LA    RW,1                    FORCE UNEQUAL FIRST TIME          05280000
CAG     L     RD,TCBDEB(RT)           ADDRESS OF FIRST DEB              05300000
        CR    RW,RD                   SEE IF DEQUEUED BY CLOSE          05320000
        BNE   SKIP                                                      05340000
        L     RD,4(RD)                LOAD NEXT DEB                     05360000
        LA    RD,0(RD)                ZERO HIGH ORDER BYTE              05380000
        ST    RD,TCBDEB(RT)           DEQUEUE DEB                       05400000
SKIP    DS    0H                                                        05420000
        LTR   RD,RD                   DEB POINTER ZERO                  05440000
        BC    8,DEBOUT                IF ZERO,LAST DEB                  05460000
        LTR   R1,R1                   HAS CORE BEEN ACQUIRED            05480000
        BC    7,CGET                  IF SO, SKIP GETMAIN               05500000
        GETMAIN R,LV=8                GET 8 BYTES FOR PARAMETER         05520000
CGET    MVC   0(4,R1),24(RD)          MOVE DCBADDR TO LIST              05540000
        MVI   0(R1),X'80'             SPEC LAST ITEM IN LIST            05560000
        LR    RS,R1                   SAVE ADDRESS OF ACQUIRED CORE     05580000
        CLOSE MF=(E,(1))                                                05600000
        LR    R1,RS                   RESTORE INPUT REGISTER            05620000
         LR    RW,RD                   SAVE DEB ADDR WE TRY TO CLOSE    05640000
        BC    15,CAG                  CHECK FOR MORE DEBS               05660000
DEBDEQ   EQU   *                                                  19272 05664019
         L     RD,TCBDEB(RT)            GET DEB                   19272 05668019
         MVC   TCBDEB+1(3,RT),5(RD)     DEQ DEB                   19272 05672019
         B     QQQQW1                                             19272 05676019
DEBOUT  DS    0C                                                        05680000
        LTR   R1,R1                   HAS CORE BEEN ACQUIRED            05700000
        BC    8,CLOSOUT               IF NO, SKIP FREEING               05720000
        FREEMAIN R,LV=8,A=(1)         FREE CORE FOR INPUT PARAMETERS    05740000
CLOSOUT DS    0C                                                        05760000
        NI    TCBFLGS+1(RT),X'EF'      TURN OFF SECOND ENTRY            05780000
         SR    R0,R0                                                    05800017
         L     RW,TCBMSS(RT)            LOAD ADDR OF BOUNDARY BOX       05820000
         TM    0(RW),X'01'             IS LCS IN THE SYSTEM        LOOB 05825017
         BZ    XNOLCS                  NO,PROCEED AS NORMAL        LOOB 05830017
         NC    4(8,RW),4(RW)           YES, IS SEG 1 BEING USED    LOOB 05835017
         BNZ   XNOLCS                  YES, PROCEED AS NORMAL      LOOB 05840017
         LA    RW,12(RW)               NO,LOAD ADDR OF SEGMENT 2   LOOB 05845017
XNOLCS   LM    RL,RU,4(RW)             OBTAIN LOW AND UPER BOUND   LOOB 05850017
        LA    RS,BEGFREE(RL)          DETERMINE LOWER BOUND OF FREE     05860000
         ST    R0,TCBTIO(RT)            STORE ZERO IN TIOT TCB          05880000
        TM    TCBCMP(RT),X'02'         IS INDIC DUMP BIT SET            05900000
* IF ENTRY TO THIS MODULE IS FROM DAR, THE TEST OF THE INDICATIVE       05905018
* DUMP BIT WILL ALWAYS PROVE NEGATIVE SINCE DAR CLEARS THE BIT TO       05910018
* PREVENT THE PRINTING OF AN INDICATIVE DUMP BY THE SCHEDULER.          05915018
         BC    8,NOIND                 IF NOT, SKIP MOVING              05920000
         ST    RU,TCBTIO(RT)           STORE UPPER IN TIOT              05940000
*                                                                       05960000
         LA    RM,632                        LOAD DUMP SIZE ***632***   05980000
         SR    RU,RM                    SUBT SIZE FROM UPPER            06000000
         MVC   0(256,RU),0(RV)         MOVE DUMP                        06020000
         MVC   256(256,RU),256(RV)           MOVE SECOND PART           06040000
         MVC   512(120,RU),512(RV)           MOVE THIRD PART            06060000
NOIND    EQU   *                                                        06080017
         SR    RU,RS                    UPPER BOUND - LOWER BOUND  LOOB 06100017
         ST    RU,4(RS)                STORE SIXE IN QUEUE ELEMENT LOOB 06130017
         ST    RS,0(RS)                STORE LOWER ADDRESS.        LOOB 06135017
         MVC   1(3,RW),1(RS)           MOVE 3-BYTE ADDR TO BB      LOOB 06140017
         TM    0(RW),X'01'             TEST FOR DBL-BOUND-BOX.     LOOB 06145017
         BZ    NOALLOC1                NO, BRANCH OUT.             LOOB 06150017
         LTR   R0,R0                   YES, IS THIS FIRST TIME THRU DAR 06155018
         BNE   NOALLOC1                NO BRANCH OUT.              LOOB 06160017
         ST    R0,0(RS)                ZERO OUT THE LINK FIELD     LOOB 06165017
         LA    RW,12(RW)               ADVANCE TO SEGMENT 2        LOOB 06170017
         LA    R0,1                    RESTORE R0.                 LOOB 06175017
         L     RS,4(RW)                LOAD LOWER BOUND            LOOB 06180017
         L     RU,8(RW)                LOAD UPPER BOUND            LOOB 06185017
         B     NOIND                    LOOP BACK FOR LCS          LOOB 06205017
NOALLOC1 EQU   *                                                   LOOB 06225017
         SR    R0,R0                    RESTORE R0                 LOOB 06245017
         ST    R0,0(RS)                 CLEAR LINK FIELD           LOOB 06265017
*                                                                       06285017
*   TIMER PURGE                                                         06305017
*                                                                       06325017
         L     R1,TCBTME(RT)            GET TIMER ELEMENT ADDRESS 20483 06345017
         LA    R1,0(R1)                 CLEAN POSSIBLE NOISE      20483 06365017
         LTR   R1,R1                    IS AN ADDRESS PRESENT     20483 06385017
         BNP   TIMXT                    IF NOT, BRANCH AROUND     20483 06405017
*******  RESET IQE SAVE AREA POINTER TO ZERO TO INDICATE TO STIMER      06480000
*******  THAT IQE HAS NO SAVE AREA                                      06500000
         ST    0,100(R1)      SET IQE SAVE AREA PTR TO ZERO             06540000
VFLG     EQU   0                                                        06550017
         TM    VFLG(R1),X'83'           IS ELEMENT NOT IN USE           06560000
         BO    PINACTV                                                  06580000
         TM    VFLG(R1),X'80'           IS ELEMENT ON QUEUE             06600000
        BO    TIMXT                                                     06620000
         TTIMER CANCEL                                            20483 06650017
         B     TIMXT                                                    06680017
PINACTV  NI    XSTAB+1(R1),X'BF'       SET IRB INACTIVE                 06720000
TIMXT    DS    0C                                                       06740000
* RESET TCB FIELDS IN ORDER TO INITIATE A NEW TASK                      06760000
         SR 0,0   CLEAR REGISTER 0 (R0)                                 06780000
         XC    TCBPIE(8,RT),TCBPIE(RT)  ZERO OUT TCB PIE AND DEB   DEVL 06810017
         ST    R0,TCBTRN(RT)            ZERO OUT TESTRAN                06840000
         NC    TCBFLGS+1(5,RT),RESET    RESET FLAG BITS IN TCB          06860000
         XC    TCBLLS(12,RT),TCBLLS(RT) ZERO LOAD LIST,JOB LIB DCB,DEVL 06880017
*                                       AND INACTIVE PROG LIST.    DEVL 06900017
         XC    TCBFSA(3,RT),TCBFSA(RT) ZERO SAVE AREA FOR TRACE    DAR  06910018
         NI    TCBDAR(RT),X'03'        CLEAR DAR FLAGS             DAR  06920018
         ST    R0,TCBNSTAE(RT)         ZERO STAE FIE               STAE 06940117
*                                                                       06940216
*  CHECK FOR OUTSTANDING RESERVES AND ISSUE A RELEASE FOR EAC      SDOB 06940416
*                                                                       06940616
         TM    TCBRESV(RT),X'FF'       ANY OUTSTANDING RESERVES    SDOB 06940816
         BC    8,NORESV                NO-GO TO CANCEL INTERFACE   SDOB 06941016
         SR    RB,RB                    INDICATE CORE NOT OBT.   A27492 06941119
         LA    RC,GETCORE              SET SWITCH TO OBTAIN CORE   SDOB 06941216
         L     RD,16                   GET CVT POINTER             SDOB 06941416
         L     RW,CVTILK2(RD)          POINTER TO UCB LOOK-UP TABLESDOB 06941616
GETNEXT  LH    RS,0(RW)                GET ADDRESS OF UCB          SDOB 06941816
         LTR   RS,RS                   IS THIS A ZERO ENTRY        SDOB 06942016
         BC    8,TESTNEXT              YES-TEST FOR NEXT ENTRY     SDOB 06942216
         TM    UCBTYP+2(RS),X'20'      IS THIS DIRECT ACCESS DEVICESDOB 06942416
         BZ    TESTNEXT                NO-GO GET NEXT UCB          SDOB 06942616
         TM    UCBRESV(RS),X'FF'       ANY RESERVES IN THIS DVC    SDOB 06942816
         BZ    TESTNEXT                NO-GET NEXT UCB             SDOB 06943016
         CLI   UCBRESV+1(RS),X'00'     IS HDWARE RESERVE IN EFFECT      06943216
         BCR   7,RC                    YES, RELEASE DEVICE              06943416
         MVI   UCBRESV(RS),X'00'       ZERO RESERVE CNT IN UCB          06943616
         B     TESTNEXT                                                 06943816
*                                                                       06944016
*  AT THIS POINT WE KNOW THAT THIS UCB HAS A RESERVE. THE FOLLOWINGSDOB 06944216
*  SECTION OF CODE WILL BE ENTERED ONLY FOR THE FIRST RELEASE. EACHSDOB 06944416
*  ONE AFTER WILL CAUSE THE CODE TO BE SKIPPED VIA THE BRANCH ON   SDOB 06944616
*  REGISTER RC WHICH IS INITIALIZED IN THE FOLLOWING SECTION.      SDOB 06944816
*                                                                  SDOB 06945016
GETCORE  GETMAIN R,LV=104                                               06945216
         LR    RU,R1                                                    06945416
         LR    RB,R1                    INDICATE CORE OBTAINED   A27492 06945519
         USING RLDCB,RU                                                 06945616
         LA    RC,PASS                 SET BRANCH TO SKIP COMMON   SDOB 06945816
         XC    0(104,R1),0(R1)         CODE AND CLEAR GOTTEN CORE  SDOB 06946016
         MVI   UCBRESV(RS),X'00'       ZERO UCB COUNT              SDOB 06946216
*                                                                  SDOB 06946416
*  INITIALIZE COMMON SECTION OF DEB                                SDOB 06946616
*                                                                  SDOB 06946816
         L     RL,CVTXAPG(RD)          GET ADDRESS OF AVT RET SLOT SDOB 06947016
         MVI   DENEXT,X'02'            NUMBER OF EXTENTS           SDOB 06947216
         ST    R1,DEDCBAD              POINT DEB TO DCB            SDOB 06947416
         MVI   DEPKID,X'0F'            SET DEB ID                  SDOB 06947616
         MVZ   DEPKID,TCBPKF(RT)       SET DEB PROTECT KEY         SDOB 06947816
         ST    RL,DEAPPAD              STORE IN TABLE POINTER SLOT SDOB 06948016
         MVI   DEEXTSCL,X'04'          GET SIZE OF EXTENT          SDOB 06948216
         MVI   DEFM,X'18'              GET FILE MASK               SDOB 06948416
         MVI   DEEND,X'FF'             INIT END 'C' TO FF          SDOB 06948616
         MVC   DEEND+1(3),DEEND        PROPAGATE FF TO REM CHH     SDOB 06948816
         LA    RL,X'01'                SET NR ALLOC TKS TO 1       SDOB 06949016
         STH   RL,DETRKS               STORE IN DEB                SDOB 06949216
*                                                                  SDOB 06949416
*  INITIALIZE COMMON SECTION OF IOB                                SDOB 06949616
*                                                                  SDOB 06949816
         MVI   IOBFL1,X'02'            GET IOB FLAGS               SDOB 06950016
         MVI   IOBFL2,X'00'            SET IOB FLAGS               SDOB 06950216
         ST    R1,IOBECBAD             SET ADDRESS OF ECB          SDOB 06950416
         LA    RL,RLCCW                GET ADDRESS OF CHN PGM      SDOB 06950616
         ST    RL,IOBSTART             POINT TO CHANNEL PGM        SDOB 06950816
         ST    R1,IOBDCBAD             POINT IOB TO DCB            SDOB 06951016
*                                                                  SDOB 06951216
*  INITIALIZE DCB                                                  SDOB 06951416
*                                                                  SDOB 06951616
         LA    RL,DEAPGV               GET ADDRESS OF DEB          SDOB 06951816
         ST    RL,DCBDEBAD             POINT DEB TO DCB            SDOB 06952016
*                                                                  SDOB 06952216
*  INITIALIZE CHANNEL PROGRAM                                      SDOB 06952416
*                                                                  SDOB 06952616
         MVI   RLCCW,X'03'             NOP COMMAND CODE            SDOB 06952816
         MVI   RLCCW+4,X'20'           SUPPRESS INCORRECT LEN IND  SDOB 06953016
         MVI   RLCCW+7,X'EE'           IDENTIFICATION NORMALLY CNT SDOB 06953216
PASS     DS    0C                                                  SDOB 06953416
*                                                                  SDOB 06953616
*  INITIALIZE REMAINDER OF DEB                                     SDOB 06953816
*                                                                  SDOB 06954016
         STH   RS,DEUCBAD              SET POINTER TO UCB          SDOB 06954216
         MVC   DEBB(2),UCBSKA+1(RS)    SET BIN = OF DEVICE         SDOB 06954416
*                                                                  SDOB 06954616
*  INITIALIZE REMAINDER OF IOB                                     SDOB 06954816
*                                                                  SDOB 06955016
         MVC   IOBSK(4),UCBSKA+1(RS)   MOVE IN SEEK ADDR FROM UCB  SDOB 06955216
         MVI   UCBRESV(RS),X'00'       ZERO UCB COUNT              SDOB 06955416
         XC    RLECB(4),RLECB          CLEAR ECB                   SDOB 06955616
         SSM   SCHPSW                  ALLOW INTERRUPTS            DAR  06955818
         EXCP  RLIOB                   ISSUE PSUEDO RELEASE        SDOB 06956016
         WAIT  ECB=RLECB               WAIT FOR I/O COMPLETION     SDOB 06956216
         SSM   SCHPSW+2                DISABLE ALL INTERRUPTS      DAR  06956418
TESTNEXT DS    0C                                                  SDOB 06956616
         LA    RW,2(RW)                INCREMENT TO NEXT UCB       SDOB 06956816
         CLC   0(2,RW),CHEK            LAST UCB                    SDOB 06957016
         BC    7,GETNEXT               NO-GO GET NEXT UCB          SDOB 06957216
         LTR   RB,RB                    Q. WAS GM DONE           A27492 06957319
         BZ    AWNOGM                   NO-BRANCH                A27492 06957419
         FREEMAIN R,LV=104,A=(RU)                                A26259 06957719
AWNOGM   SR    RL,RL                                             A27492 06957919
         STC   RL,TCBRESV(RT)          RESET RESERVE CNT IN TCB    SDOB 06958119
         ST    RL,CVTQCBO(RD)          RESET QCB ORIGIN            SDOB 06958319
         SR    R0,R0                   RESET TO ZERO               SDOB 06958519
         B     NORESV                                                   06958719
CHEK     DC    X'FFFF'                 END OF LOOK-UP TBL INDIC    SDOB 06958816
******** RESETTING OF TCBFLGS :    GROUP I EXCEPT:                      06960000
*                                       TCBFA-  ABNORMAL TERMINATION    06980000
*                                       TCBFB-  NORMAL TERMINATION      07000000
*                                  GROUP II EXCEPT:                     07020000
*                                       TCBFSTI - TIMER- UNDETERMINED   07040000
*                                       TCBFJSTI- TIMER- UNDETERMINED   07060000
*                                       TCBFTCTC- HIGH PRIORITY         07080000
*                                  GROUP III EXCEPT:                    07100000
*                                       TCBFC-    TERMINATION BIT       07120000
*********************************************************************** 07140000
*********************************************************************** 07160000
* *  * * *  CANCEL  INTERFACE-   TURN OFF  CANCEL FLAG   * * * *  * *   07180000
CVTBTERM EQU   52                                                       07200000
CVTMSLT  EQU   60                                                       07220000
MTSFLG   EQU   137                                                      07240000
BIT0     EQU   X'80'                                                    07260000
IRB      EQU   8                                                        07280000
         DS    0F                                                  SDOB 07286016
NORESV   DS    0C                                                  SDOB 07292016
         L     RW,COMPCON               GET CVT POINTER                 07300000
         L     RS,CVTMSLT(RW)           LOCATE MASTER RESID. AREA       07320000
        NI    MTSFLG(RS),X'FF'-BIT0   TURN OFF CONSOLE FLAG             07340000
         L     RS,CVTBTERM(RW)          LOAD ABTERM ADDR                07360000
         L     RS,IRB(RS)               ADDR OF MASTER IRB FROM ABTERM  07380000
         NI    XSTAB+1(RS),X'BF'        TURN OFF ACTIVE BIT             07400000
         XC    XRBQ(4,RS),XRBQ(RS)     ZERO OUT XRBQ FIELD IN IRB  DAR  07420018
*********************************************************************** 07440000
********             SET UP DUMMY  PRB     **********                   07460000
         L     RW,TCBMSS(RT)            LOAD BOUNDARY BOX               07480000
         TM    0(RW),X'01'             IS LCS IN THE SYSTEM        LOOB 07485017
         BZ    NOLCS                   NO,PROCEED AS NORMAL        LOOB 07490017
         NC    4(8,RW),4(RW)           YES, IS SEG 1 BEING UESD    LOOB 07495017
         BNZ   NOLCS                   YES, PROCEED AS NORMAL      LOOB 07500017
         LA    RW,12(RW)               NO,LOAD ADDR OF SEGMENT 2   LOOB 07505017
NOLCS    L     RL,4(RW)                OBTAIN UPPER BOUND          LOOB 07510017
         MVC   0(32,RL),CTLPRB          MOVE DUMMY PRB TO LOWER BOUND   07520000
         ST    RT,XRBLNK(RL)            STORE ADDR OF TCB IN PRB        07540000
         ST    RL,TCBRBP(RT)            STORE ADDR OF DUMMY PRB IN TCB  07560000
*********************************************************************** 07580000
*********      SET UP XCTL PARAMETERS                                   07600000
         LA    R15,XCTLST(RL)           LOAD BEG ADDR OF XCTL LIST      07620000
         ST    R0,XCTLST+4(RL)          STORE ZERO AS XCTL DCB          07640000
         MVC   XCTLST+8(8,RL),SCHEDNM   MOVE SCHED NAME TO LIST         07660000
         LA    RS,XCTLST+8(RL)          LOAD ADDR OF NAME               07680000
         ST    RS,XCTLST(RL)            STORE NAME IN XCTLST            07700000
DUMMY    EQU   64            ADDR OF DUMMY RTN TO CHANGE FROM SPV TO    07720000
*                            P/P STATE AND TO ENTER SCHEDULER           07740000
         MVC   DUMMY-8(14,RL),SCHPSW   PLACE DUMMY PROGR IN P/P CORE    07760000
         LA    RS,DUMMY+4(RL)          GET ADDRESS OF SVC 7 INSTR       07780000
         ST    RS,DUMMY-4(RL)                                           07800000
*  SET UP TERMINATION FLAG                                              07820000
********************************************************************    07840000
********************************************************************    07860000
         OI    TCBFLGS+3(RT),X'04'                                      07880000
         TM    TCBFLGS+1(RT),X'80'      TEST FOR ABEND                  07900000
         BC    7,ABS                                                    07920000
         OI    TCBFLGS+1(RT),X'40'      SET NORMAL END BIT              07940000
ABS     DS    0C                                                        07960000
         LR    RW,R15                                                   07980000
*******************************************************************     08000000
*        SSM   ENABLE                  ENABLE FOR SCHED                 08020000
*********************************************************************   08040000
********************  TEMPORARY FOR SCHEDULERS    ******************    08060000
         BC    15,DUMMY(RL)            EXECUTE DUMMY PROGR TO ENTER     08080000
*                                      SCHEDULER                        08100000
*********************************************************************   08120000
         DS    0F                                                  SDOB 08130016
CTLST    DC    2F'0'                                                    08140000
CTLNM    DC    C'GO      '                                              08160000
********************   DUMMY  XCTL  PRB    **************************** 08180000
CTLPRB   DC    1D'0'                                                    08200000
         DC    H'9'                                                     08220000
         DC    X'00C0'                                                  08240000
         DC    4F'0'                                                    08260000
CTLTCB   DC    F'0'                     TCB ADDR OF PRB                 08280000
*********************************************************************** 08300000
SCHEDNM  DC    C'GO      '              NAME OF SCHED TO XCTL TO        08320000
RESET    DC    X'C060090000'                 RESET TCB FLAG FIELD       08340000
********************************************************************    08380000
***************    TEMPORARY FOR SCHEDULERS    *********************    08400000
         DS    0D                                                       08420000
SCHPSW   DC    X'FF050000'             TEMP                             08440000
         DC    1F'0'                                                    08460000
         LPSW  DUMMY-8(RL)                                              08480000
         SVC   7             XCTL    EP=GO                              08500000
********************************************************************    08520000
DUMPMESS WTO   'IEA002I ABEND/ABDUMP ERROR',MF=L,ROUTCDE=2,DESC=6  DAR  08560018
MSGEND   EQU   *                                                   DAR  08610018
MSGLEN   EQU   MSGEND-DUMPMESS                                     DAR  08630018
RLDCB    DSECT                                                     SDOB 08680516
RLECB    DS    F                       ECB TO WAIT ON              SDOB 08681016
RLIOB    DS    0F                      START OF IOB                SDOB 08681516
IOBFL1   DS    X                       IOB FLAGS                   SDOB 08682016
IOBFL2   DS    X                       IOB FLAGS                   SDOB 08682516
         DS    H                       FILLER                      SDOB 08683016
IOBECBAD DS    F                       ADDR OF ECB TO BE POSTED    SDOB 08683516
         DS    2F                      FILLER                      SDOB 08684016
IOBSTART DS    F                       ADDRESS OF CHANNEL PROGRAM  SDOB 08684516
IOBDCBAD DS    F                       ADDRESS OF ASSOCIATED DCB   SDOB 08685016
         DS    2F                      FILLER                      SDOB 08685516
IOBMOD   DS    X                       MODIFIER-DEBEXTENT NUMBER   SDOB 08686016
IOBSK    DS    CL4                     BBCC TO SEEK TO             SDOB 08686516
         DS    CL3                     FILLER                      SDOB 08687016
DCBDEBAD DS    F                       FLAGS AND ADDR OF ASSOC DEB SDOB 08687516
RLCCW    DS    X                       CCW OP CODE                 SDOB 08688016
         DS    CL3                     FILLER                           08688516
         DS    X                       CCW FLAGS                   SDOB 08689016
         DS    CL2                     FILLER                      SDOB 08689516
         DS    X                       BYTE CNT-END OF IOB INDIC   SDOB 08690016
DEAPGV   DS    4F                      APPENDAGE VECTOR TABLE      SDOB 08690516
DENEXT   DS    X                       NUMBER OF EXTENTS           SDOB 08691016
         DS    CL3                     REMAINDER OF AVT            SDOB 08691516
DEPRIOR  DS    X                       DEB PRIORITY                SDOB 08692016
         DS    X                       FILLER BYTE                 SDOB 08692516
DEVRET   DS    H                       AVT RETURN                  SDOB 08693016
DEPKID   DS    0X                      USER PTK KEY AND DEB ID     SDOB 08693516
DEDCBAD  DS    F                       ADDR OF ASSOC DCB           SDOB 08694016
DEEXTSCL DS    0F                      SIZE OF EXTENTS             SDOB 08694516
DEAPPAD  DS    F                       ADDRESS OF AVT              SDOB 08695016
DEFM     DS    X                       FILE MASK                   SDOB 08695516
         DS    X                       FILLER BYTE                 SDOB 08696016
DEUCBAD  DS    H                       ADDRESS OF UCB              SDOB 08696516
DEBB     DS    H                       BIN = 0F DEVICE             SDOB 08697016
DESTART  DS    2H                      START CCHH OF EXTENT        SDOB 08697516
DEEND    DS    2H                      END CCHH OF EXTENT          SDOB 08698016
DETRKS   DS    H                       = OF TRACKS ALLOCATED       SDOB 08698516
         END                                                            08700000
