IGC0601C CSECT                                                          00300017
*                                                                       00600017
*0457000200-000330,000400,000500,008000                            CMTB 00900017
*0457054400,054800-055000,059200,060000,060400,061800-062000,      RFOB 01200017
*     0628000-063200,063800                                        RFOB 01500017
* STATUS- CHANGE LEVEL 000                                              01800017
* THIS MODULE HAS BEEN REASSEMBLED WITH MACRO IECIPR (AS REVISED)       02100017
* FOR RELEASE # 17.                                                DAR  02300018
*PRIOR TO RELEASE 17 THIS MODULE WAS LABELED IEAATM00.                  02500017
         TITLE 'IEAATM06 / ABEND LOAD 1 / IGC0601C'                     02700017
         SPACE 2                                                        03000017
*        THE ABEND SVC SERVICE ROUTINE(SVC 13)TERMINATES THE TASK UNDER 03300017
*        WHICH IT IS RUNNING AND RESETS THE PARTITION SO THAT A NEW JOB 03600017
*        STEP CAN BE INITIATED USING THIS TASK CONTROL BLOCK.  ABEND IS 03900017
*        TYPE 4 SVC AND CONSISTS OF SIX TRANSIENT LOADS.  IT CAN BE     04200017
*        CALLED BY ABTERM OR DIRECTLY BY USE OF THE ABEND MACRO-        04500017
*        INSTRUCTION.                                                   04800017
         SPACE 2                                                        05100017
*        THE FIRST LOAD OF ABEND IS REFERRED TO AS ABEND1, THE SECOND   05400017
*        AS ABEND2,ETC. TO FACILITATE AN EASIER UNDERSTANDING OF THE    05700017
*        DESCRIPTIONS OF THE SIX MODULES.  THE MODULE AND SVC LIBRARY   06000017
*        NAMES ARE AS FOLLOWS:                                          06300017
         SPACE 2                                                        06600017
*              ABEND NAME     MODULE NAME     SVC LIBRARY NAME          06900017
*        ABEND1               IEAATM06        IGC0601C                  07200017
*        ABEND2               IEAATM01        IGC0101C                  07500017
*        ABEND3               IEAATM02        IGC0201C                  07800017
*        ABEND4               IEAATM03        IGC0301C                  08100017
*        ABEND5               IEAATM04        IGC0401C                  08400017
*        ABEND6               IEAATM05        IGC0501C                  08700017
         SPACE 2                                                        09000017
*   ROUTINE NAME ... ABEND1                                             09300017
         SPACE 1                                                        09600017
*   MODULE NAME ... IEAATM06                                            09900017
         SPACE 1                                                        10200017
*   CHART ID ... PH                                                     10500017
         SPACE 1                                                        10800017
*   FUNCTION ...                                                        11100017
         SPACE 1                                                        11400017
*        SAVE THE COMPLETION CODE AND ABEND STATUS INFORMATION,PURGE    11700017
*        I/O,AND TRANSFER CONTROL TO THE NEXT LOAD.                     12000017
         SPACE 1                                                        12300017
*   ENTRY ...                                                           12600017
         SPACE 1                                                        12900017
*        ABEND1 IS ENTERED IN SUPERVISOR STATE, WITH SUPERVISOR         13200017
*        PROTECTION KEY, AND WITH INPUT/OUTPUT AND EXTERNAL INTERRUPTS  13500017
*       DISABLED. ABEND1 IS ENTERED AT ENTRY POINT NAME IGC0001C WHEN   13800017
*        THE ABEND SVC INSTRUCTION (SVC 13) IS EXECUTED.                14100017
         SPACE 1                                                        14400017
*   INPUT ...                                                           14700017
         SPACE 1                                                        15000017
*        NORMAL END                                                     15300017
         SPACE   1                                                      15600017
*        THE RESIDENT EXIT ROUTINE SETS THE NORMAL TERMINATION BIT TO   15900017
*        ONE IN THE TCB.  NORMAL END REQUIRES THAT REGISTER 15 CONTAINS 16200017
*        THE COMPLETION CODE. REGISTER 1 MUST CONTAIN ALL ONES.         16500017
         SPACE   1                                                      16800017
*        ABNORMAL END                                                   17100017
         SPACE   1                                                      17400017
*        IF ABTERM (IEAAAB00, IEAGAB00, OR IEAHAB00) WAS ENTERED TO     17700017
*        INITIATE THIS ABNORMAL TASK TERMINATION, ABTERM HAS STORED THE 18000017
*        FOLLOWING INFORMATION IN THE TCB COMPLETION CODE FIELD         18300017
*        (TCBCMP).  OTHERWISE THIS INFORMATION MUST BE CONTAINED IN     18600017
*        REGISTER 1 ON ENTRY TO ABEND.                                  18900017
*        BIT 0 - IS A DUMP INDICATOR. A DUMP IS REQUESTED IF THIS BIT   19200017
*        IS SET TO ONE.                                                 19500017
*        BIT 1 - IS IGNORED.                                            19800017
*        BITS 2 THROUGH 6 - MUST BE ZERO                                20100017
*        BIT 7 - IS USED TO INDICATE PRESENCE OF ABEND                  20400017
*        MESSAGE TO BE PRINTED(SET BY CALLER OF ABEND).                 20700017
*        BITS 8 THROUGH 31 - COMPRISE THE COMPLETION CODE FIELD.        21000017
*        IF A SYSTEM ROUTINE INITIATED THIS TASK TERMINATION, BITS 8    21300017
*        THROUGH 19 CONTAIN THE SYSTEM COMPLETION CODE.  BITS 20        21600017
*        THROUGH 31 MUST BE ZERO.                                       21900017
*        IF A PROBLEM PROGRAM ROUTINE INITIATED THIS TASK TERMINATION,  22200017
*        BITS 20 THROUGH 31 CONTAIN THE PROBLEM PROGRAM COMPLETION      22500017
*        CODE.  BITS 8 THROUGH 19 MUST BE ZERO.                         22800017
         SPACE 1                                                        23100017
*   OUTPUT ...                                                          23400017
         SPACE 1                                                        23700017
*        NONE                                                           24000017
         SPACE 1                                                        24300017
*   EXTERNAL REFERENCES ...                                             24600017
         SPACE 1                                                        24900017
*        ABEND1 REFERENCES ENTRIES IN THE COMMUNICATIONS VECTOR TABLE   25200017
*        (CVT), IN THE TCB, AND THE 12* TABLE.                          25500017
*        A.  CVT                                                        25800017
*        SYMBOLIC OFFSET - CVTTCBP, BY WHICH THE ADDRESS OF THE         26100017
*        CURRENTLY DISPATCHED TASK IS OBTAINED.                         26400017
*        SYMBOLIC OFFSET - CVTITSAR, THE ADDRESS OF THE 12* TABLE.      26700017
*        SYMBOLIC OFFSET - CVTIXAVL, THE ADDRESS OF THE NEXT AVAILABLE  27000017
*        12*.                                                           27300017
*        B.  TCB                                                        27600017
*        SYMBOLIC OFFSET - TCBRBP, ADDRESS OF THE ACTIVE RB.            27900017
*        TCBCMP, TASK COMPLETION CODE                                   28200017
*        TCBMSS, ADDRESS OF MAIN STORAGE SUPERVISOR BOUNDARY BOX        28500017
*        TCBFLGS, TCB FLAG BITS.                                        28800017
*        C.  12*                                                        29100017
*        THE UCB, IOB, AND DEBS POINTED TO BY A 12* ENTRY ARE           29400017
*        REFERENCED IN THE PURGE PORTION OF ABEND1.                     29700017
         SPACE  2                                                       30000017
*        ABEND STATUS BITS ... (IF BIT IS 1 FOLLOWING INFO IS TRUE)     30300017
         SPACE  1                                                       30600017
*        TCBFLGS+1                                                      30900017
         SPACE  1                                                       31200017
*          BIT0-ABNORMAL TERMINATION IN PROCESS        (ABEND BIT)      31500017
*          BIT1-NORMAL TERMINATION IN PROCESS          (NORMAL END BIT) 31800017
*          BIT2-ABEND WAS INITATED BY ABTERM                            32100017
*          BIT3-SECOND ENTRY INTO ABEND IS PERMISSIBLE                  32400017
*          BIT4-RESERVED                                                32700017
*          BIT5-CLOSE HAS BEEN INITIATED BY ABEND                       33000017
*          BIT6-STORAGE HAS BEEN OVERLAID TO PROCESS ABEND              33300017
*          BIT7-PROHIBIT QUEUING OF ASYNCHRONOUS EXITS FOR THIS TCB     33600017
         SPACE  1                                                       33900017
         SPACE  1                                                       34200017
*        TCBFLGS+2                                                      34500017
*          BIT0-THIS TASK CANNOT BE TERMINATED                          34800017
*          BIT5-ABEND HAS INITIATED ABDUMP FOR THIS TASK                35100017
        SPACE  1                                                        35400017
*        TCBCMP FIELD                                                   35700017
         SPACE  1                                                       36000017
*          BIT0-A DUMP IS REQUESTED FOR THIS TASK                       36300017
*          BIT1-RESERVED                                                36600017
*          BIT2-STORAGE WAS OVERLAID TO REACH SECOND ABEND LOAD         36900017
*          BIT3-ABEND HAS INITIATED A WTO AND WILL LOAD A WAIT STATE    37200017
*                  PSW WHEN RETURNED                                    37500017
*          BIT4-ABEND HAS BEEN ENTERED A SECOND TIME                    37800017
*          BIT5-A DUMP MESSAGE IS REQUIRED                              38100017
*          BIT6-AN INDICTIVE DUMP IS PROVIDED                           38400017
*          BIT 7-AN ABEND MESSAGE IS PROVIDED                           38700017
         SPACE   1                                                      39000017
*   EXITS ...                                                           39300017
         SPACE   1                                                      39600017
*        IF NORMAL END, CONTROL IS TRANSFERRED TO ABEND6 (IEAATM05).    39900017
*        IF ABNORMAL END, CONTROL IS TRANSFERRED TO ABEND2 (IEAATM01).  40200017
         SPACE   1                                                      40500017
*   ERROR MESSAGES...                                                   40800017
*        NONE                                                           41100017
         SPACE 1                                                        41400017
         SPACE 1                                                        41700017
*   NOTES ...                                                           42000017
         SPACE 1                                                        42300017
*        ABEND/MAIN STORAGE SUPERVISOR INTERFACE...                     42600017
         SPACE 1                                                        42900017
*        THE ABEND AND ABTERM BITS IN THE TCB ARE TESTED BY THE         43200017
*        REGISTER FORM OF GETMAIN-FREEMAIN.  IF AN ERROR IS             43500017
*        ENCOUNTERED, AND EITHER OF THESE BITS ARE SET, GETMAIN-        43800017
*        FREEMAIN RETURNS CONTROL TO THE CALLER WITH AN ERROR CODE (4)  44100017
*        IN REGISTER 15 INSTEAD OF INITIATING ANOTHER ABEND.            44400017
         SPACE 1                                                        44700017
*        PURGE/ABEND INTERFACE ...                                      45000017
         SPACE 1                                                        45300017
*        ABEND ISSUES A SPECIAL PURGE SPECIFYING A TCB PURGE WITH HALT  45600017
*        I/O, NO CHAINING OF IOBS AND NO POSTING OF ECBS (EXCEPT FOR    45900017
*        THOSE ECBS POINTED TO BY A DEB CONTAINED WITHIN THE NUCLEUS).  46200017
*        THE REASON FOR THIS INTERFACE IS THAT THE ECB AND IOB          46500017
*        ADDRESSES IN THE 12* TABLE MAY BE INVALID OR MAY POINT TO AN   46800017
*        AREA OF CORE WHICH HAS BEEN OVERLAID BY ABEND'S SVRB.          47100017
*        PURGE IS CONTAINED WITHIN THE FIRST LOAD OF ABEND TO PREVENT   47400017
*        RECURSION THROUGH ABEND.  THIS RECURSION COULD OCCUR AS A      47700017
*        RESULT OF...                                                   48000017
*        A.  THE I/O INTERRUPT HANDLER, IN HANDLING AN I/O INTERRUPT    48300017
*        WHILE THE MACHINE IS ENABLED TO FETCH PURGE, CAUSING A PROGRAM 48600017
*        CHECK WHILE ACCESSING IOBS OR ECBS POINTED TO BY THE 12*       48900017
*        TABLE.                                                         49200017
*        B.  THE I/O INTERRUPT HANDLER POSTING AN ECB AS A RESULT OF AN 49500017
*        I/O INTERRUPT AND DESTROYING ONE OF THE SVRBS OVERLAYING       49800017
*        PROBLEM PROGRAM CORE.                                          50100017
         SPACE 1                                                        50400017
*        SVC HANDLER/ABEND INTERFACE ...                                50700017
         SPACE 1                                                        51000017
*        WHEN AN ABEND SVC IS ISSUED, THE SVC HANDLER MAY BE UNABLE TO  51300017
*        ACQUIRE THE 96 BYTES OF CORE REQUIRED TO FETCH ABEND INTO THE  51600017
*        TRANSIENT AREA.  IF THIS IS THE CASE, THE SVC HANDLER WILL     51900017
*        OVERLAY 96 BYTES OF PROBLEM PROGRAM CORE AT LOWER BOUND PLUS   52200017
*        32 BYTES.  THIS ACTION WILL BE NOTED BY SETTING A BIT IN THE   52500017
*        TCB.                                                           52800017
         SPACE 1                                                        53100017
*   OPERATION ...                                                       53400017
         SPACE 1                                                        53700017
*        ABEND1 PERFORMS THE FOLLOWING FUNCTIONS FOR A NORMAL END...    54000017
         SPACE 1                                                        54300017
*        STORES COMPLETION CODE FROM REGISTER 15 TO THE COMPLETION CODE 54600017
*        FIELD OF THE TCB (TCBCMP).                                     54900017
*        TURNS OFF THE NORMAL END BIT IN THE TCB (SO THAT IF NORMAL END 55200017
*        CAUSES AN ABEND, THE ABEND WILL BE RECOGNIZED).                55500017
*        TRANSFERS CONTROL TO THE LAST LOAD OF ABEND.                   55800017
         SPACE 1                                                        56100017
*        ABEND1 PERFORMS THE FOLLOWING FUNCTIONS FOR AN ABNORMAL END... 56400017
         SPACE 1                                                        56700017
*        TESTS ABEND BIT, AND IF SET, SETS THE SECOND ENTRY BIT IN THE  57000017
*        TCB.                                                           57300017
*        SETS THE ABEND BIT AND THE BIT TO PROHIBIT ASYNCHRONOUS EXITS  57600017
*        FROM BEING SCHEDULED.                                          57900017
*        PURGES THE I/O INITIATED BY OR FOR THIS TASK BY USING A MACRO- 58200017
*        INSTRUCTION VERSION OF PURGE ASSEMBLED WITHIN ABEND1.          58500017
*        ACQUIRES CORE FOR 96 BYTES, USED BY XCTL, TO GET TO THE        58800017
*        NEXT LOAD.  THIS CORE IS ACQUIRED BY A GETMAIN, OR IF THAT     59100017
*        FAILS, BY SETTING UP A FREE QUEUE ELEMENT OF 96 BYTES WITHIN   59400017
*        PROBLEM PROGRAM CORE.                                          59700017
*        TRANSFERS CONTROL TO ABEND2 (IEAATM01).                        60000017
         EJECT                                                          60300017
BND     EQU   12                                                        60600017
BASEREG  EQU   3                                                        60900017
R0       EQU   0                                                        61200017
COMPCON  EQU   16                                                       61500017
COMREG   EQU   1                                                        61800017
RT       EQU   12                      TCB REG                          62100017
TCBRBP   EQU   0                                                        62400017
TCBPIE   EQU   4                                                        62700017
TCBDEB   EQU   8                                                        63000017
TCBTIO   EQU   12                                                       63300017
TCBCMP   EQU   16                                                       63600017
TCBTRN   EQU   20                                                       63900017
TCBMSS   EQU   24                                                       64200017
TCBPKF   EQU   28                                                       64500017
TCBFLGS  EQU   28                                                       64800017
TCBLMP   EQU   34                                                       65100017
TCBDSP   EQU   35                                                       65400017
TCBLLS   EQU   36                                                       65700017
TCBJLB   EQU   40                                                       66000017
TCBJSE   EQU   44                                                       66300017
TCBGRS   EQU   48                                                       66600017
TCBIDF   EQU   112                                                      66900017
TCBFSA   EQU   113                                                      67200017
TCBTCB   EQU   116                                                      67500017
TCBTME   EQU   120                                                      67800017
TCBITB   EQU   124                                                      68100017
XRBNM    EQU   0                                                        68400017
XRBSZ    EQU   8                                                        68700017
XSTAB    EQU   10                                                       69000017
XRBUSE   EQU   12                                                       69300017
XRBEP    EQU   12                                                       69600017
XRBPSW   EQU   16                                                       69900017
XRBQ     EQU   24                                                       70200017
XRBWT    EQU   28                                                       70500017
XRBLNK   EQU   28                                                       70800017
XRBREG   EQU   32                                                       71100017
R1       EQU   1              DUMP AREA                                 71400017
RC       EQU   2                                                        71700017
RV       EQU   4              WORK                                      72000017
RL       EQU   5              LOWER BND                                 72300017
RB       EQU   6              RB                                        72600017
RM      EQU   7                                                         72900017
RD       EQU   8              DUMP                                      73200017
RS       EQU   9              WORK                                      73500017
RU       EQU   10             UPPER                                     73800017
RSAV     EQU   11             SAVE                                      74100017
R15     EQU   15                                                        74400017
SVCDCB   EQU   84                       DSPLMT OF SVC DCB IN CVT        74700017
         BALR  BASEREG,0                                                75000017
         USING *,BASEREG                                                75300017
         L     RT,COMPCON                                               75600017
         L     RT,0(RT)                                                 75900017
         L     RT,4(RT)                LOAD ADDR OF ABENDING TCB        76200017
SKPNORM  DS    0H                                                       76500017
         TM    TCBFLGS+1(RT),X'20'      IS ABTERM BIT SET               77400017
         BC    7,SKIP                   IF SO, SKIP STORING COMP CODE   77700017
         ST    RSAV,TCBCMP(RT)          STORE COMPLETE CODE             78000017
SKIP     DS    0C                                                       79500017
         L     RM,TCBMSS(RT)           LOAD ADDR OF BOUNDARY BOX        79800017
         BCTR  RM,0                    DECREMENT THE ADDR IN RM BY LOOB 80100017
         BCTR  RM,0                    THREE TO POINT AT THE SIXTH LOOB 80400017
         BCTR  RM,0                    BYTE OF THE ABEND APPENDAGE LOOB 80700017
         XC    0(3,RM),0(RM)           ZERO BOUNDARY BOX FLAGS     LOOB 81000017
         L     RB,0(RT)                ADDR OF ABEND SVRB          RFOB 81600017
         LA    RB,TRNCNTL(RB)          ADDRESS LAST TWO DOUBLE WORDRFOB 81900017
*                                      OF THE ABEND SVRB SAVE AREA RFOB 82200017
         MVC   0(4,RB),PURGLIST        LOAD OPT FLD AND 0 DEB      RFOB 82500017
         ST    RT,4(RB)                STORE TCB ADDR IN PARA LIST RFOB 82800017
         XC    8(4,RB),8(RB)           ZERO 3D WORD OF LIST        RFOB 83100017
         LR    R1,RB                   LOAD PRG PARAM REGISTER     RFOB 83400017
         IECIPR 12,SPECIAL                                              83700017
PRG034   DS    0H                      PURGE EXIT ADDRESS               84000017
         L     15,16                   CVT PTR                          84300017
         L     15,0(15)                                                 84600017
         L     RT,4(15)                GET TCB ADDR                     84900017
         TM    TCBFLGS+2(RT),X'80'     SYSTEM TASK ABENDING?       DAR  84920018
         BZ    CKREC                   NO, BRANCH                  DAR  84940018
DODAR    EQU   *                                                   DAR  84960018
         LA     RD,DARNAME             DAR MODULE NAME             DAR  84980018
         B     CKCORE                                              DAR  85000018
CKREC    EQU   *                                                   DAR  85020018
         TM    TCBCMP(RT),X'08'        SECOND ENTRY TO ABEND?      DAR  85040018
         BZ    NOREC                   NO, BRANCH                  DAR  85060018
         TM    TCBFLGS+1(RT),X'10'     VALID RECURSION?            DAR  85080018
         BZ    DODAR                   NO, BRANCH                  DAR  85100018
NOREC    EQU   *                                                   DAR  85120018
         LA     RD,CTLNM2              NAME OF NEXT ABEND LOAD     DAR  85140018
CKCORE   EQU   *                                                   DAR  85160018
* CHECK IF ENOUGH CORE TO GET TO NEXT ABEND LOAD                        85200017
         GETMAIN R,LV=96                                                85500017
         LTR   R15,R15                                                  85800017
         BC    7,WSTEAL                                                 86100017
         FREEMAIN R,LV=(0),A=(1)       IF ENOUGH CORE, FREE IT          86400017
         BC    15,XCTL                 BR TO XCTL TO NEXT LOAD          86700017
WSTEAL   DS    0C                                                       87000017
* MUST PROVIDE 96 BYTES FOR AN SVRB USED BY XCTL                        87300017
         L     RM,TCBMSS(RT)           LOAD MSS BOUND BOX ADDR          87600017
         TM    0(RM),X'01'             LCS IN THE SYSTEM           LOOB 87900017
         BZ    NOLCS                   NO,PROCEED AS NORMAL        LOOB 88200017
         NC    4(8,RM),4(RM)           H0 BEING USED               LOOB 88500017
         BNZ   NOLCS                   NO, PROCEED AS NORMAL       LOOB 88800017
         LA    RM,12(RM)               NO,RESET PTR TO SECOND BB   LOOB 89100017
NOLCS    L     RL,4(RM)                LOAD LOWER BOUND ADDRESS    LOOB 89400017
         LA    RL,PRBXT(RL)            ESTABLISH FIRST STEAL AREA  RFOB 89700017
         TM    TCBFLGS+1(RT),X'02'     HAS CORE ALREADY BEEN STOLEN     90000017
        BC    8,STEAL2                 IF NO, BRANVH                    90300017
         OI    TCBCMP(RT),X'20'         SET SECOND STEAL BIT            90600017
         LA    RL,SVRBXT(RL)           INCREMENT OVER ABEND SVRB   RFOB 90900017
STEAL2   ST    RL,0(RL)                                                 91200017
         MVC   1(3,RM),1(RL)                                            91500017
         XC    0(4,RL),0(RL)           ZERO MSS FREE QUEUE         RFOB 91800017
         LA    RS,96                   ESTABLISH SIZE OF FREE           92100017
         ST    RS,4(RL)                STORE SIZE IN MSS QUEUE          92400017
         OI    TCBFLGS+1(RT),X'02'      SET FIRST STEAL BIT             92700017
XCTL     DS    0C                                                       93000017
XOUT     DS    0H                                                       93600017
         ST    RD,0(RB)                ADDR OF NAME IN LIST        DAR  93900018
         LR    R15,RB                  PASS ADDR OF LIST TO XCTL   RFOB 94200017
         XCTL  SF=(E,(15))                                              94500017
PURGLIST DS   0F                                                        94800017
         DC    X'22000000'       OPTION FIELD AND 0 DEB                 95100017
CTLNM2   DC    C'IGC0101C'                                              95400017
DARNAME  DC    C'IGC0801C'             DAR MODULE NAME             DAR  95500018
PRBXT    EQU   32                      SIZE OF PRB                 RFOB 95700017
TRNCNTL  EQU   128                     OFFSET FOR SVRB ESA DBL WDS RFOB 96000017
SVRBXT   EQU   144                     SIZE OF ABEND SVRB          RFOB 96300017
EXITMASK DC    X'FFFFFFFF'                                              96600017
         END                                                            96900017
