         TITLE 'IEAATM08/IGC0801C - PCP DAMAGE ASSESMENT ROUTINE'       02000018
IGC0801C CSECT                                                          04000018
*********************************************************************** 04020018
*                                                                     * 04040018
*MODULE NAME:   IEAATM08 - PCP DAR                                    * 04060018
*                                                                     * 04080018
*CSECT NAME:    IGC0801C                                              * 04100018
*                                                                     * 04120018
*FUNCTION:      INVOKED AS FOLLOWS -                                  * 04140018
*                                                                       04160018
*               BY:                          IF:                      * 04180018
*                   ABEND1 (IGC0001C)            DAR RECURSION        * 04200018
*                                                     RECOGNIZED      * 04220018
*                   ABEND2 (IGC0601C)            INVALID ABEND        * 04240018
*                                                     RECURSION       * 04260018
*                                                     RECOGNIZED      * 04280018
*                   ABEND2 (IGC0601C)            FAILING TASK IS A    * 04300018
*                                                     SYSTEM TASK     * 04320018
*                                                    (TCBFLGS+1=X'80')* 04340018
*                                                                     * 04360018
*               RESPONSIBLE FOR WRITING A CORE IMAGE DUMP DEPICTING   * 04380018
*               STORAGE AT THE TIME THE FAILURE IS DETECTED TO THE    * 04400018
*               DATA SET SYS1.DUMP, IF PROVIDED, AND PREPARING THE    * 04420018
*               FAILING TASK FOR CONTINUED ABEND VIA  ABEND5          * 04440018
*               (IGC0501C) AND THE JOB SCHEDULER SO AS NOT TO         * 04460018
*               INTERRUPT SYSTEM OPERATION.                           * 04480018
*                                                                     * 04500018
* APPLICABILITY: PCP VERSION OF OS/360 ONLY.                          * 04520018
*                                                                     * 04540018
* ATTRIBUTES:    REENTRANT, PARTIALLY ENABLED, PRIVILEDGED,           * 04560018
*                TRANSIENT, TYPE 4 SVC ROUTINE.                       * 04580018
*                                                                     * 04600018
* ENTRY POINT:   IGC0801C                                             * 04620018
*                                                                     * 04640018
* EXITS:         NORMAL - TO LAST ABEND LOAD, IGC0501C, VIA XCTL.     * 04660018
*                ABNORMAL - NONE                                      * 04680018
*                                                                     * 04700018
* INPUT:         NONE                                                 * 04720018
*                                                                     * 04740018
* OUTPUT:        STATUS MESSAGES ISSUED VIA WTO ARE PROVIDED AS       * 04760018
*                FOLLOWS:                                             * 04780018
*                                                                     * 04800018
*                     IEA021I JOBNAME STEPNAME CORE IMAGE BYPASSED-1  * 04820018
*                                                                 -2  * 04840018
*                MSG IEA021I-1: DAR RECURSION RECOGNIZED - NO ATTEMPT * 04860018
*                               MADE TO WRITE ANOTHER CORE IMAGE DUMP.* 04880018
*                MSG IEA021I-2: NO SYS1.DUMP DATA SET - NO ATTEMPT    * 04900018
*                              MADE TO WRITE A CORE IMAGE DUMP.       * 04920018
*                                                                     * 04940018
* EXTERNAL REFERENCES:                                                * 04960018
*                                                                     * 04980018
*                1. CVT                                               * 05000018
*                2. TCB                                               * 05020018
*                3. SVRB                                              * 05040018
*                                                                     * 05060018
* SVC'S USED:                                                         * 05080018
*                1. XCTL  SVC  7                                      * 05100018
*                2. WTO   SVC 35                                      * 05120018
*                                                                     * 05140018
* EXTERNAL ROUTINES: NONE                                             * 05160018
*                                                                     * 05180018
* ASSEMBLY RESTRICTIONS   THIS MODULE ISSUES THE DUMPMAC MACRO INSTR- * 05200018
*                        UCTION TO OBTAIN A COPY OF DAR'S WRITE DUMP  * 05220018
*                        SUBROUTINE. DUMPMAC IS A PVTMAC.             * 05240018
*                                                                     * 05260018
* OPERATION:     THIS MODULE FIRST EXAMINES THE PRIMARY DAR RECURSION * 05280018
*                BIT IN THE FAILING TASKS TCB. SUCH A TEST IS TO      * 05300018
*                DETERMINE IF THIS IS A SECOND TIME ENTRY RESULTING   * 05320018
*                FROM A PRIEVIOUS FAILURE IN DAR. IN THIS CASE, A     * 05340018
*                BYPASS MSG IS WRITTEN TO THE CONSOLE AND THE TASK    * 05360018
*                IS PREPARED FOR CONTINUED PROCESSING VIA ABEND5      * 05380018
*                AND THE SCHEDULER.                                   * 05400018
*                                                                     * 05420018
*                NEXT THE CVTDAR FIELD IS TESTED TO DETERMINE IF      * 05440018
*                THE DATA SET SYS1.DUMP EXISTS. A NEGATIVE FINDING    * 05460018
*                RESULTS IN WRITING A BYPASS MESSAGE AND CONTINUED    * 05480018
*                PROCESSING AS ALREADY DESCRIBED.                     * 05500018
*                                                                     * 05520018
*                IF THE DATA SET IS PROVIDED, THE WRITE DUMP SUB-RTN  * 05540018
*                (EXPANSION OF DUMPMAC MACRO) IS BRANCHED TO TO       * 05560018
*                ATTEMPT WRITING OF A CORE IMAGE DUMP. SUBSEQUENTLY,  * 05580018
*                THE FAILING TASK IS PREPARED FOR CONTINUED           * 05600018
*                PROCESSING BY:                                       * 05620018
*                                                                     * 05640018
*                        1. CLEARING THE FLAGS IN THE TCBCMP FIELD    * 05660018
*                        2. XCTLING TO ABEND5, IGC0501C.              * 05680018
*                                                                     * 05700018
*********************************************************************** 05720018
 EJECT                                                                  05740018
* PCP DAR - MAINLINE                                                    06000018
         BALR  BASEREG,ZERO            ESTABLISH BASE                   08000018
         USING *,BASEREG                    FOR CSECT                   10000018
         L     CVTREG,CVTPTR           GET CVT ADDR                     12000018
         L     TCBREG,ZERO(CVTREG)     GET TCB OLD/NEW PTRS             14000018
         L     TCBREG,INDEX4(TCBREG)   GET CURRENT TCB ADDR             16000018
         USING TCBSECT,TCBREG          BASE TO ADDRESS TCB DSECT        20000018
         L     SVRBREG,TCBRBP          GET ADDR OF THIS SVRB            22000018
         USING RBSECT,SVRBREG                                           23000018
         TM    TCBDAR,DARREC           SECOND ENTRY TO DAR              24000018
         BO    PHASE3A                 YES, SKIP WRITING OF DUMP        26000018
         OI    TCBDAR,DARREC           INDICATE DAR ENTERED             29000018
         LR    SRBAD,SVRBREG            INITIALIZE REG            M3240 29010019
SIRBLOOP EQU   *                                                  M3240 29020019
         LR    SVRBREG,SRBAD            SAVE LAST RB              M3240 29030019
         USING RBSECT2,SRBAD            ALT RB DSECT              M3240 29040019
         L     SRBAD,RBLINK2-1          GET NEXT RB               M3240 29050019
         LA    SRBAD,0(SRBAD)           CLEAR HI BYTE             M3240 29060019
         CR    SRBAD,TCBREG             Q. END OF RB CHAIN        M3240 29070019
         BE    SIRBOUT                  YES-BRANCH                M3240 29080019
         TM    RBSTAB2,X'80'            POSSIBLY SIRB             M3240 29090019
         BZ    SIRBLOOP                 NO-BRANCH                 M3240 29100019
         TM    RBSTAB2,X'70'            DEFINITELY SIRB           M3240 29110019
         BNZ   SIRBLOOP                 NO-BRABCH                 M3240 29120019
         MVC   RBLINK(3),RBLINK2        DEQ SIRB                  M3240 29130019
         NI    RBSTAB2+1,X'BF'          TURN OFF ACTIVE BIT       M3240 29140019
SIRBOUT  EQU   *                                                  M3240 29150019
         L     SVRBREG,TCBRBP           INIT REG                  M3240 29160019
         DROP  SRBAD                                              M3240 29170019
         USING CVTSECT,CVTREG          BASE TO ADDRESS CVT              32000018
         NC    CVTDAR,CVTDAR           DOES SYS1.DUMP EXIST             34000018
         MVI   CODENO,FOX2             SET MSG IDENTIFIER               36000018
         BZ    PHASE3A                 IF NO SYS1.DUMP, WRITE MSG       38000018
         LA    RETREG,PHASE3           SET RETURN POINT                 40000018
         B     PHASE2                  GO TO WRITE DUMP SUBROUTINE      42000018
PHASE3A  EQU   *                                                        44000018
         MVC   STATUSG(COUNT),STATUSA  SET UP BYPASS MSG                46000018
         BAL   RETREG,DUMPENT2         PUT OUT BYPASS MSG               48000018
*                                                                       50000018
*                        RETURN FROM WRITE DUMP SUBROUTINE              52000018
*                                                                       54000018
PHASE3   EQU   *                                                        56000018
         MVI   TCBCMP,XZERO            CLEAR FLAGS IN TCBCMP FIELD      58000018
         LA    WORK,NXTLOAD            GET ADDR OF 501C NAME            60000018
         LA    XREG,ESANDX(SVRBREG)    ADDRESS ESA OF SVRB              62000018
         ST    WORK,ZERO(XREG)         SET UP PARM LIST                 64000018
         XC    INDEX4(L4,XREG),INDEX4(XREG)          FOR XCTL           66000018
         SVC   XCTL                    XCTL TO NEXT LO AD               67000018
XCTL     EQU   7                       XCTL SVC NO.                     68000018
SRBAD    EQU   5                                                  M3240 68010019
NXTLOAD  DC    C'IGC0501C'             NAME OF NEXT LOAD                70000018
PHASE2   DUMPMAC                                                        72000018
 EJECT                                                                  74000018
         IHBABCTL                                                       76000018
 EJECT                                                                  78000018
         END                                                            84000018
