IGC0A01C CSECT                                                     I250 00100019
*2501440000,480000-482000,486000,490000,534000,562000              LOOB 00240017
*2501514000-520000,544000-552000,564000-578000,588000-596000       CCCC 00280017
*2501710000                                                        WSTC 00320017
*2501720000                                                        8056 00360017
*481000-486000                                                     I250 00380019
 TITLE   'IEAATM0A / ABEND LOAD 2A / IGC0A01C'                     I250 00480019
* ABEND LOAD 2A                                                         00600016
*                                                                       00800016
* ROUTINE NAME ... ABEND2A                                              01000016
*                                                                       01200016
* MODULE NAME ... IEAATM0A                                              01400016
*                                                                       01600016
*        DETERMINE HOW MUCH CORE IS NEEDED BY ABEND BASED ON            01800016
*        WHETHER A DUMP HAS BEEN REQUESTED OR CLOSE IS NECESSARY, AND   02000016
*        TRANSFER CONTROL TO THE NEXT APPROPRIATE LOAD OF ABEND.        02200016
         SPACE 2                                                        02400016
*   ENTRY ...                                                           02600016
*       ABEND2A IS ENTERED IN SUPERVISOR STATE, WITH SUPERVISOR         02800016
*       PROTECT KEY, AND WITH I/O AND EXTERNAL INTERRUPTS DISABLED.     03000016
*       ABEND2A IS ENTERED AT ENTRY POINT IGC0111C FROM ABEND2.         03200016
         SPACE 2                                                        03400016
*   INPUT ...                                                           03600016
*        GEN. REG. 12=ADDRESS OF CURRENT TCB                            03800016
*        BYTE 19 OF BOUNDARY BOX, INITIALIZED TO BINARY ZEROS.          04000016
         SPACE 2                                                        04200016
*  OUTPUT ... NONE                                                      04400016
         SPACE 2                                                        04600016
*   EXTERNAL REFERENCES ...                                             04800016
*       ABEND2A REFERENCES ENTRIES IN THE TCB AND THE VARIOUS CONTROL   05000016
*        BLOCKS.(SYMBOLIC OFFSET NOTED)                                 05200016
*        A.  TCB                                                        05400016
*        TCBRBP - ADDRESS OF ACTIVE RB                                  05600016
*        TCBDEB - POINTER TO QUEUE OF DEBS                              05800016
*        TCBTIO - POINTER TO TIOT                                       06000016
*        TCBCMP - TASK COMPLETION CODE                                  06200016
*        TCBMSS - ADDRESS OF MAIN STORAGE SUPERVISOR BOUNDARY BOX       06400016
*        TCBFLGS - TCB FLAG BITS                                        06600016
*        TCBLLS - POINTER TO LOAD LIST                                  06800016
*        B.  RB                                                         07000016
*        XSTAB - FLAG BITS                                              07200016
*        XRBPSW - SAVE AREA FOR RESUME PSW                              07400016
*        XRBWT - WAIT COUNT                                             07600016
*        XRBLNK - RB CHAIN ADDRESS                                      07800016
*        C.  LLS                                                        08000016
*        BYTE OFFSET +0 FORWARD CHAIN                                   08200016
*                    +4 BACKWARD CHAIN                                  08400016
*        (24 MINIMUM SIZE OF RB IN LOAD LIST)                           08600016
*        D.  DEB                                                        08800016
*        BYTE OFFSET +4 FORWARD CHAIN                                   09000016
*        (36 MINIMUM SIZE OF DEB)                                       09200016
*        E.  MSS                                                        09400016
*        BYTE OFFSET +0 FORWARD CHAIN                                   09600016
*                    +4 FREE AREA COUNT                                 09800016
*        (8 MINIMUM SIZE OF FQE)                                        10000016
         SPACE  2                                                       10200016
*        ABEND STATUS BITS ... (IF BIT IS 1 FOLLOWING INFO IS TRUE)     10400016
         SPACE  1                                                       10600016
*        TCBFLGS+1                                                      10800016
         SPACE  1                                                       11000016
*          BIT0-ABNORMAL TERMINATION IN PROCESS        (ABEND BIT)      11200016
*          BIT1-NORMAL TERMINATION IN PROCESS          (NORMAL END BIT) 11400016
*          BIT2-ABEND WAS INITATED BY ABTERM                            11600016
*          BIT3-SECOND ENTRY INTO ABEND IS PERMISSIBLE                  11800016
*          BIT4-RESERVED                                                12000016
*          BIT5-CLOSE HAS BEEN INITIATED BY ABEND                       12200016
*          BIT6-STORAGE HAS BEEN OVERLAID TO PROCESS ABEND              12400016
*          BIT7-PROHIBIT QUEUING OF ASYNCHRONOUS EXITS FOR THIS TCB     12600016
         SPACE  1                                                       12800016
         SPACE  1                                                       13000016
*        TCBFLGS+2                                                      13200016
*          BIT0-THIS TASK CANNOT BE TERMINATED                          13400016
*          BIT5-ABEND HAS INITIATED ABDUMP FOR THIS TASK                13600016
        SPACE  1                                                        13800016
*        TCBCMP FIELD                                                   14000016
         SPACE  1                                                       14200016
*          BIT0-A DUMP IS REQUESTED FOR THIS TASK                       14400016
*          BIT1-RESERVED                                                14600016
*          BIT2-STORAGE WAS OVERLAID TO REACH SECOND ABEND LOAD         14800016
*          BIT3-ABEND HAS INITIATED A WTO AND WILL LOAD A WAIT STATE    15000016
*                  PSW WHEN RETURNED                                    15200016
*          BIT4-ABEND HAS BEEN ENTERED A SECOND TIME                    15400016
*          BIT5-A DUMP MESSAGE IS REQUIRED                              15600016
*          BIT6-AN INDICTIVE DUMP IS PROVIDED                           15800016
         SPACE 2                                                        16000016
*   EXITS ...                                                           16200016
*       ABEND2A CAN TRANSFER CONTROL TO ANY OF THE REMAINING LOADS      16400016
*        OF ABEND.  THE CONDITIONS FOR TRANSFERRING TO EACH SPECIFIC    16600016
*        LOAD ARE AS FOLLOWS...                                         16800016
         SPACE 1                                                        17000016
*        TRANSFER CONTROL TO ABEND3 (IEAATM02), THE CORE ACQUISITION    17200016
*        MODULE, IF CORE MUST BE "STOLEN" TO SATISFY ABEND/ABDUMPS      17400016
*        STORAGE REQUIREMENTS.                                          17600016
         SPACE 1                                                        17800016
*        TRANSFERS CONTROL TO ABEND4 (IEAATM03), THE INDICATIVE DUMP    18000016
*        MODULE,IF CORE IS AVAILABLE,A DUMP IS REQUESTED AND            18200016
*        A SYSABEND DD STATEMENT IS NOT FOUND IN THE TIOT.              18400016
         SPACE 1                                                        18600016
*        TRANSFERS CONTROL TO ABEND5 (IEAATM04), THE ABDUMP LINKAGE     18800016
*        MODULE, IF CORE IS AVAILABLE, A DUMP IS REQUESTED AND          19000016
*        A SYSABEND DD STATEMENT IS FOUND IN THE TIOT.                  19200016
         SPACE 1                                                        19400016
*        TRANSFERS CONTROL TO ABEND6 (IEAATM05), THE CLEAN-UP MODULE,   19600016
*        IF CORE IS AVAILABLE AND NO DUMP IS REQUESTED                  19800016
         SPACE 1                                                        20000016
         SPACE 2                                                        20600016
*   ERROR MESSAGES...                                                   20800016
*              NONE                                                DAR  21400018
         SPACE 2                                                        22000016
*   NOTES ...                                                           22200016
*        IF ENTERED A SECOND TIME FOR THE SAME TASK, WITH THE SECOND    22400016
*        ENTRY BIT SET, ABEND PROCEEDS TO TERMINATE THE TASK. HOWEVER,  22600016
*        IT WILL NOT PERFORM FOR A SECOND TIME THE FUNCTION WHICH       22800016
*        CAUSED THE RE-ENTRY (I.E., THE FUNCTION WHOSE FUNCTION BIT IS  23000016
*        SET).                                                          23200016
*        IF THE SECOND ENTRY BIT IS NOT SET, THERE IS NO VALID REASON   23400016
*        FOR RE-ENTRY AND, THEREFORE, ABEND DOES NOT ATTEMPT TO         23600016
*        CONTINUE, BUT LOADS A WAIT STATE PSW INDICATING AN             23800016
*        UNANTICIPATED PROBLEM WHICH COULD CAUSE INFINITE RECURSION.    24000016
         SPACE 2                                                        24200016
*   WORK AREAS...                                                       24400016
         SPACE 2                                                        24600016
*   OPERATION ...                                                       24800016
*       ABEND2A (IEAATM0A) PERFORMS THE FOLLOWING FUNCTION...           25000016
         SPACE 1                                                        25200016
*        RESETS THE SIRB ACTIVE BIT AND DEQUEUES IF FROM THE ACTIVE RB  25400016
*        LIST IF THE SIRB IS ON THE ACTIVE CHAIN.                       25600016
         SPACE 1                                                        25800016
*        TESTS THE DISASTER BIT, AND IF SET, LOADS A WAIT STATE PSW.    26000016
*        SETS A DISASTER BIT, WRITES TO OPERATOR AND LOADS WAIT STATE   26200016
*        PSW IF THERE IS AN UNEXPLAINED RECURSION THROUGH ABEND.        26400016
         SPACE 1                                                        26600016
*        TURNS OFF RECURSION SWITCHES IF RECURSION IS EXPLAINED BY A    26800016
*        BIT SETTING.                                                   27000016
         SPACE 1                                                        27200016
*        RESTORES THE PSW AND WAIT COUNT TO THE RB WHICH CALLED ABEND   27400016
*        IF ABTERM HAS BEEN ENTERED TO INITIATE THE TERMINATION.        27600016
         SPACE 1                                                        27800016
*        TURNS OFF THE ABTERM BIT.                                      28000016
         SPACE 1                                                        28200016
*        DETERMINES THE AMOUNT OF CORE NEEDED BY ABEND FUNCTIONS SUCH   28400016
*        AS ABDUMP, INDICATIVE DUMP, CLOSE, AND XCTL.                   28600016
         SPACE 1                                                        28800016
*        ISSUES A GETMAIN FOR THE AMOUNT OF CORE NEEDED.                29000016
         SPACE 1                                                        29200016
*        TRANSFERS CONTROL TO NEXT APPROPRIATE LOAD OF ABEND.           29400016
         SPACE 2                                                        29600016
         EJECT                                                          29800016
         BALR  BASEREG,0                                                30000016
         USING *,BASEREG                                                30200016
BND     EQU   12                                                        30400016
BASEREG  EQU   3                                                        30600016
R0       EQU   0                                                        30800016
CVTDCB   EQU   X'74'                                                    31100017
RT       EQU   12                      TCB REG                          31400016
TCBRBP   EQU   0                                                        31600016
TCBPIE   EQU   4                                                        31800016
TCBDEB   EQU   8                                                        32000016
TCBTIO   EQU   12                                                       32200016
TCBCMP   EQU   16                                                       32400016
TCBTRN   EQU   20                                                       32600016
TCBMSS   EQU   24                                                       32800016
TCBPKF   EQU   28                                                       33000016
TCBFLGS  EQU   28                                                       33200016
TCBLMP   EQU   34                                                       33400016
TCBDSP   EQU   35                                                       33600016
TCBLLS   EQU   36                                                       33800016
TCBJLB   EQU   40                                                       34000016
TCBJSE   EQU   44                                                       34200016
TCBGRS   EQU   48                                                       34400016
TCBIDF   EQU   112                                                      34600016
TCBFSA   EQU   113                                                      34800016
TCBTCB   EQU   116                                                      35000016
TCBTME   EQU   120                                                      35200016
TCBITB   EQU   124                                                      35400016
TCBDAR   EQU   172                                                 DAR  35500018
XRBNM    EQU   0                                                        35600016
XRBSZ    EQU   8                                                        35800016
XSTAB    EQU   10                                                       36000016
XRBUSE   EQU   12                                                       36200016
XRBEP    EQU   12                                                       36400016
XRBPSW   EQU   16                                                       36600016
XRBQ     EQU   24                                                       36800016
XRBWT    EQU   28                                                       37000016
XRBLNK   EQU   28                                                       37200016
XRBREG   EQU   32                                                       37400016
RM       EQU   7                                                        37600016
RA       EQU   13                                                       37800016
RP       EQU   14                                                       38000016
R1       EQU   1              DUMP AREA                                 38200016
RC       EQU   2                                                        38400016
RV       EQU   4              WORK                                      38600016
RL       EQU   5              LOWER BND                                 38800016
RB       EQU   6              RB                                        39000016
RW       EQU   7              WORK                                      39200016
RD       EQU   8              DUMP                                      39400016
RS       EQU   9              WORK                                      39600016
RU       EQU   10             UPPER                                     39800016
RSAV     EQU   11             SAVE                                      40000016
R15     EQU   15                                                        40200016
SVCDCB   EQU   84                       DSPLMT OF SVC DCB IN CVT        40400016
XX       EQU   8                                                   LOOB 40500017
********************************************************************    40600016
**************************************                                  40800016
        L     RB,TCBRBP(RT)            LOAD POINTER TO ABEND SVRB       41200016
WSIRBCK DS    0C                                                        41400016
         LA    RS,XRBLNK(RB)            LOAD ADDR OF LINK FIELD         41600016
         L     RB,XRBLNK(RB)            LOAD LINK FIELD                 41800016
        LA    RB,0(RB)                 ELIMINATE HIGH ORDER BYTE        42000016
        CR    RB,RT                    LAST RB                          42200016
        BC    8,WSIRBXT                IF SO  GET OUT                   42400016
         TM    XSTAB(RB),X'80'         POSSIBLY IN SIRB.           L00A 42600016
         BZ    WSIRBCK                 IF NOT, BRANCH.             L00A 42800016
         TM    XSTAB(RB),X'70'         INSURE THAT IT IS AN SIRB.  L00A 43000016
         BNZ   WSIRBCK                 IF NOT, BRANCH              LOOA 43200016
        NI    XSTAB+1(RB),X'BF'        TURN OFF ACTIVE BIT              43600016
         L     RM,TCBMSS(RT)                                            43800016
         BCTR  RM,0                    DECREMENT THE BB ADDR BY    LOOB 43900017
         BCTR  RM,0                    TWO TO ADDR BB FLAGS        LOOB 44000017
         OI    0(RM),X'01'             SET SIRB REMOVE BIT         LOOB 44100017
        MVC   1(3,RS),XRBLNK+1(RB)     RELINK RB QUEUE                  44200016
WSIRBXT DS    0C                                                        44400016
         TM    TCBCMP(RT),X'08'         IS SECOND ENTRY BIT ON          45400016
        BC    8,XABT                   IF NOT, CHECK ABTERM             45600016
        NI    TCBFLGS+1(RT),X'EF'       RESET SECOND ENTRY SW           46200016
        NI    TCBCMP(RT),X'F7'         RESET SECOND ENRTY BIT           46400016
        BC    15,AGO                                                    46600016
XABT    DS    0C                                                        46800016
        TM    TCBFLGS+1(RT),X'20'      IS ABTERM BIT ON                 47000016
         BC    8,AGO                    IF NOT, BRANCH                  47200016
         L     RB,0(RT)                LOAD ADDR OF RB                  47400016
         L     RB,XRBLNK(RB)           LOAD ADDR OF CALLING RB          47600016
         L     RW,TCBMSS(RT)           LOAD ADDR OF BOUNDARY BOX        47800016
         SH    RW,DECREM               TO POINT TO ABEND APPEN     LOOB 47900017
         MVC   XRBPSW+4(4,RB),0(RW)    RESTORE SAVE PSW            LOOB 48000017
         XC    0(5,RW),0(RW)           ZERO OUT THE SAVE AREA      LOOB 49000017
AGO      DS    0C                                                       49200016
DISPTT   EQU   4                                                        49400016
INDSIZE  EQU   728                                                 3446 49600016
CLOSSIZE EQU   856                                                 M00A 49800016
         NI    TCBCMP(RT),X'FD'        TURN OFF INDICATIVE DUMP BIT     50000016
        LA    RC,0                                                      50200016
        TM    TCBFLGS+1(RT),X'04'      HAS CLOSE BEEN TRIED             50400016
         BC    7,LAST                                                   50600016
         TM    TCBCMP(RT),X'80'         IS A DUMP REQUESTED             50800016
         BC    8,TESTMAIN               IF NOT, SKIP                    51000016
        TM    TCBFLGS+2(RT),X'04'      HAS DUMP BEEN TRIED              51200016
         BO    TESTMAIN                PREP TO GO TO NEXT LOAD     DAR  51600018
LOOK     EQU   *                                                   CCCC 52000017
         L     RP,TCBTIO(RT)            LOAD ADDR OF TIOT               52200016
         LA    RP,0(RP)                CLEAR HIGH BYTE             1545 52400016
         LTR   RP,RP                   IS TIOT PRESENT             545 52600016
         BZ    SCHED                   NO, CHECK FOR SCHEDULER     1545 52800016
         LA    RP,24(RP)                PT RP TO BEG OF DD ENTRIES      53000016
         L     RU,TCBMSS(RT)           LOAD ADDR OF BOUNDARY BOX        53200016
         TM    0(RU),X'01'             LCS IN THE SYSTEM           LOOB 53250017
         BZ    XNOLCS                  NO, PROCEED NORMAL          LOOB 53300017
         NC    4(8,RU),4(RU)           YES, H0 BEING USED          LOOB 53350017
         BNZ   XNOLCS                  NO, PROCEED NORMAL          LOOB 53400017
         LA    RU,12(RU)               NO, LOAD ADDR OF 2D BB      LOOB 53450017
XNOLCS   L     RU,8(RU)                LOAD UPPER BOUND            LOOB 53500017
         SR    RA,RA                    CLEAR RA                        53600016
SAGAIN   EQU   *                                                        53800017
         TM    0(RP),X'FF'              TEST FOR LAST DD ENTRY          54000017
         BE    SCHED                    LAST ENTRY IN TABLE             54200017
         CLC   DISPTT(8,RP),DSSYS       TEST IF SYSTEM DATA SET IN TIOT 54400017
         BE    PRESENT                  EQUAL COMPARE              CCCC 54500017
         CLC   DISPTT(8,RP),DSDUMP      IS ALTERNATE DDNAME IN TIOT     54600017
         BNE   ABSENT                                              CCCC 54700017
PRESENT  EQU   *                  IF YES,GETMAIN FOR FULL DUMP     CCCC 54800017
         LH    RC,ABDSIZE               LOAD SIZE FOR FULL ABDUMP  CCCC 54900017
         B     GET                      BRANCH TO TRY TO GET CORE  CCCC 55000017
ABSENT   EQU  *                                                    CCCC 55100017
         IC    RA,0(RP)                 INSERT LENGTH OF THIS ENTRY     55400016
         AR    RP,RA                    POINT TO NEXT ENTRY IN TIOT     55600016
         LA    RM,8(RP)                 INCREMENT FOR VALID CHECK       55800016
         CR    RM,RU                    COMPARE TIOT POSIT TO UPPER     56000016
         BNH   SAGAIN                  NOT HIGH, ALRIGHT           LOOB 56020017
         L     XX,TCBMSS(RT)           LOAD RB ADDRESS             LOOB 56040017
         TM    0(XX),X'01'             LCS IN THE SYSTEM           LOOB 56060017
         BZ    SCHED                   NO, PROCEED NORMAL          LOOB 56080017
         NC    4(8,XX),4(XX)           YES, IS H0 BEING USED       LOOB 56100017
         BZ    SCHED                    NO, BRANCH TO NORMAL       LOOB 56120017
         L     RU,TCBMSS(RT)            YES,LOAD BB ADDR FOR TEST  LOOB 56140017
         LM    RU,XX,16(RU)            LOAD SEG2 LOW BND           LOOB 56180017
         CR    RM,RU                   TEST IF BELOW LOW BND       LOOB 56200017
         BL    SCHED                   SKIP ABEND DUMP             LOOB 56220017
         CR    RM,XX                   TEST IF ABOVE UPR BND       LOOB 56240017
         BNH   SAGAIN                                              CCCC 56640017
SCHED    EQU   *                                                   CCCC 57040017
         L     R1,16                    POINT TO CVT               CCCC 57440017
         TM    TCBPIB(RT),X'01'         SCDEULER  ABEND            I250 57740019
TCBPIB   EQU   124                                                 DAR  58040018
         BO    DODAR                 SYSTEM ERROR - GO TO DAR      I250 58340019
INDICDMP EQU   *                                                   CCCC 58800017
         LA    RC,INDSIZE             LOAD AMT NEEDED FOR IND DMP  CCCC 59000017
         OI    TCBCMP(RT),X'02'         SET INDICATIVE DUMP BIT         59200017
TESTMAIN EQU   *                                                   CCCC 59400017
        L     RB,TCBDEB(RT)            LOAD DEB POINTER                 59800016
        LTR   RB,RB                    ANY DEBS TO CLOSE                60000016
        BC    8,GET                                                     60200016
         LA    RC,CLOSSIZE(RC)         ADD CORE FOR CLOSE               60400016
GET     DS    0C                                                        60600016
         LTR   RC,RC                   ZERO COUNT?                 DAR  60660018
         BZ    GOGO                    YES, SKIP CORE TEST         DAR  60720018
         LR    0,RC                     LOAD GETMAIN PARAMETER          60800016
         GETMAIN R,LV=(0)                                               61000016
         LTR   R15,R15                  IS MAIN AVAILABLE               61200016
*********************************************************************   61400016
         BC    7,WSTEAL                                                 61600016
         FREEMAIN R,LV=(0),A=(1)                                        61800016
GOGO     EQU   *                                                   DAR  61900018
         TM    TCBCMP(RT),X'80'         IS DUMP BIT ON                  62000016
         BC    8,LAST                                                   62200016
         TM    TCBFLGS+2(RT),X'04'      HAS DUMP BEEN TRIED             62400016
         BC    7,NODUMP                 IF SO, SKIP DUMP                62600016
        TM    TCBCMP(RT),X'02'        IS INDIC DUMP REQUESTED           62800016
         BZ    XABDUMP                 IF NOT, GO TO ABDUMP LOAD        63000017
         LA    R15,INDICATE            TO 301C FOR INDICATIVE DUMP CCCC 63200017
XCTL     EQU   *                                                        63400017
         L     RD,0(RT)                ADDR OF THE ABEND SVRB      RFOB 63800016
         LA    RD,128(RD)              ADDRESS THE LAST TWO DOUBLE RFOB 64000016
*                                      WORDS OF THE ABEND SVRB     RFOB 64200016
*                                      EXTENDED SAVE AREA          RFOB 64400016
         ST    15,0(RD)                STORE THE NAME IN LIST      RFOB 64600016
         LR    15,RD                   PASS ADDR OF NAME TO XCTL   RFOB 64800016
         XCTL  SF=(E,(15))                                              65000016
DODAR    EQU   *                                                   DAR  65020018
         LA    R15,DARMOD              POINT TO NAME OF NEXT LOAD  DAR  65060018
         B     XCTL                    GO TO IT                    DAR  65080018
*                                                                       65100017
XABDUMP  EQU   *                                                        65200017
         LA    R15,ABDUMP              TO 401C TO CALL ABDUMP      CCCC 65300017
         B     XCTL                                                     65400017
NODUMP   EQU   *                                                        65500017
         OI    TCBCMP(RT),X'04'        SET DUMP MESSAGE BIT             65600017
LAST     EQU   *                                                        65700017
         LA    R15,TERMINUS          TO 501C FOR ABEND TERMINATION CCCC 65800017
         B     XCTL                                                     65900017
WSTEAL   EQU   *                                                        66000017
         LA    R15,TAKECORE            TO 201C TO STEAL CORE       CCCC 66100017
         B     XCTL                                                     66200017
AB2      EQU   *                                                        66300017
DSSYS    DC    C'SYSABEND'                                              71200016
DSDUMP   DC    C'SYSUDUMP'         ALTERNATE DD NAME                    71400016
         DS    0F                                                       71600016
DARMOD   DC    C'IGC0801C'             DAR MODULE NAME             DAR  71610018
TAKECORE DC    C'IGC0201C'             STEAL REQUIRED MAIN         CCCC 71630017
*                                      STORAGE FROM LRB'S.         CCCC 71660017
INDICATE DC    C'IGC0301C'             MAIN STORAGE AVAILABLE AND  CCCC 71690017
*                                      INDICATIVE DUMP IS REQUESTED.    71720017
ABDUMP   DC    C'IGC0401C'             MAIN STORAGE IS AVAILABLE   CCCC 71750017
*                                      AND ABDUMP IS REQUESTED.    CCCC 71780017
TERMINUS DC    C'IGC0501C'             MAIN STORAGE IS AVAILABLE,  CCCC 71810017
*                                      NO DUMP REQUESTED, SO DO A  CCCC 71840017
*                                      NORMAL ABEND TERMINATION.   CCCC 71870017
ABDSIZE  DC    H'4800'                                             8056 71900017
DECREM   DC    H'8'                    CONST OF 8 TO REGREE PTR    LOOB 72100017
         END                                                            72200016
