*    'EXTRACT SERVICE ROUTINE FOR MFT WITH ASYNCHRONOUS ATTACH'         00200021
*********************************************************************** 00400019
*********************************************************************** 00600019
* ROUTINE NAME-               IGC040- EXTRACT SVC ROUTINE               00800019
*                                                                       01000019
* FUNCTIONS-                  TO EXTRACT ONE OR ALL OF SEVEN FIELDS     01200019
*                             WITHIN A TASK CONTROL BLOCK. THE TCB      01400019
*                             FROM WHICH INFORMATION MAY BE EXTRACTED   01600019
*                             MAY BE FROM EITHER THE ISSUER'S OR        01800019
*                             ONE OF IT'S SUBTASKS.                     02000019
*                                                                       02200019
* ENTRY POINT NAMES-          IGC040- EXTRACT SVC ENTRY POINT           02400019
*                                                                       02600019
* CONTAINED IN MODULE-        IEABXR00                                  02800019
*                                                                       03000019
* ATTRIBUTES-                                                           03200019
*                                                                       03400019
* APPLICABILITY-              OPTION 2 ONLY (WITH ASYNCHRONOUS ATTACH)  03600019
*                                                                       03800019
* EXTERNAL REFERENCES-        IEATCBP- LOCATION 'NEW' AND 'OLD'         04000019
*                             IEABTERM- ABTERM                          04200019
*                                                                       04400019
* SVC'S USED-                 NONE                                      04600019
*                                                                       04800019
* INPUT-                      ADDRESS OF PARAMETER LIST IN REG 1        05000019
*                                                                       05200019
* MACRO EXPANSION EXAMPLES-                                             05400019
*                                                                       05600019
DUMMY1   DSECT                                                          05800019
         USING *,1                                                      06000019
         SPACE 1                                                        06200019
* EXAMPLE 1.........ALL SEVEN FIELDS WILL BE EXTRACTED FROM THE TCB     06400019
*                   OF THE TASK ISSUING THE EXTRACT MACRO INSTRUCTION.  06600019
*                   'P255' SPECIFIES THE ADDRESS OF A VARIABLE LENGTH   06800019
*                   LIST OF CONSECUTIVE FULL-WORDS OF MAIN STORAGE.     07000019
         SPACE 1                                                        07200019
         EXTRACT P255,'S',FIELDS=(ALL)                                  07400019
         SPACE 1                                                        07600019
* EXAMPLE 2.........THREE FIELDS WILL BE EXTRACTED FROM THE TCB         07800019
*                   INDICATED BY TCBLOC. THE ADDRESS OF THE GENERAL     08000019
*                   REGISTER SAVE AREA IS STORED INTO THE FIRST WORD    08200019
*                   OF THE FULL WORD AT LOCATION 'P255'.                08400019
         SPACE 1                                                        08600019
         EXTRACT P255,TCBOK,FIELDS=(GRS)                                08800019
         SPACE 1                                                        09000019
* EXAMPLE 3.........A PARAMETER LIST WILL BE CREATED AT A LOCATION      09200019
*                   'EXLIST'. PARAMETER ROUND IS THE ADDRESS OF         09400019
*                   THE LIST WHERE THE EXTRACTED FIELDS WILL BE         09600019
*                   PLACED. THE ISSUER'S TCB WILL BE EXTRACTED FROM.    09800019
         SPACE 1                                                        09840019
P255     DS    0F                                                       09880019
         SPACE 1                                                        09920019
EXLIST   EXTRACT ROUND,'S',FIELDS=(ALL)                                 09960019
         SPACE 1                                                        10000019
* EXAMPLE 4.........SPECIFIES AN EXISTING PARAMETER LIST AT LOCATION    10200019
*                   'EXLIST'. ONLY THE TCB TO BE EXTRACTED FROM         10400019
*                   IS ALTERED IN 'EXLIST' DYNAMICALLY.                 10600019
         SPACE 1                                                        10800019
         EXTRACT ,P255,MF=(E,EXLIST)                                    11000019
         SPACE 1                                                        11200019
* EXAMPLE 5.........WILL CREATE ONLY A PARAMETER LIST AT LOCATION       11400019
*                   ABLE. ANOTHER MACRO-INSTRUCTION, OF THE 'E'         11600019
*                   FORM COULD LOAD THE LIST.                           11800019
         SPACE 1                                                        12000019
         EXTRACT ,,MF=L                                                 12200019
         SPACE 1                                                        12400019
*  THE ABOVE MACRO EXPANSIONS ARE NOT TO BE MISCONSTRUED                12600019
* AS BEING AN EXECUTABLE PORTION OF THIS EXTRACT SVC SERVICE ROUTINE    12800019
* THESE MACRO EXPANSIONS SERVE ONLY TO ILLUSTRATE WHAT SOME OF          13000019
* THE VARIOUS FORMS OF THE EXPANSION LOOK LIKE.                         13200019
         SPACE 1                                                        13400019
* OUTPUT-                     EXTRACT LIST- ADDRESS OF LIST IS          13600019
*                             PROVIDED BY THE USER. THIS LIST           13800019
*                             PROVIDES THE INTERMEDIARY BY WHICH        14000019
*                             EXTRACTED INFORMATION FROM THE TCB        14200019
*                             IS MADE KNOWN TO THE PROBLEM PROGRAM.     14400019
*                                                                       14600019
* ENTRY POINTS-              1. IGC040- EXTRACT SVC ENTRY POINT.        14800019
*                                                                       15000019
*                            2. THE PSW MUST BE                         15200019
*                             DISABLED FOR ALL MASKABLE INTERRUPTS      15400019
*                             EXCEPT MACHINE CHECK, IN SUPERVISOR       15600019
*                             MODE AND HAVE SUPERVISOR PROTECT KEY.     15800019
*                                                                       16000019
*                            3. THE REGISTERS CONTAIN.                  16200019
*                              REG 1 CONTAINS THE ADDRESS OF THE        16400019
*                                  INPUT PARAMETER LIST.                16600019
*                                                                       16800019
*                              REGS 0,2,6-12 AND 15 CONTAIN             17000019
*                                  THE CONTENTS AT THE TIME             17200019
*                                  SVC 40 WAS ISSUED.                   17400019
*                                                                       17600019
*                              REG 3 CONTAINS THE ADDRESS OF THE        17800019
*                                  CVT.                                 18000019
*                                                                       18200019
*                              REG 4 CONTAINS THE ADDRESS OF THE        18400019
*                                  CURRENT TCB.                         18600019
*                                                                       18800019
*                              REG 5 CONTAINS THE ADDRESS OF THE        19000019
*                                  RB AT THE TOP OF THE RB QUEUE.       19200019
*                                                                       19400019
*                              REG 14 CONTAINS THE RETURN ADDRESS.      19600019
* EXIT POINT-                1. TO THE CALLING ROUTINE VIA              19800019
*                                  A BRANCH REG 14.                     20000019
*                                                                       20200019
* ERROR EXIT POINTS-         1. TO ABTERM IN ORDER TO CAUSE THE ISSUING 20400019
*                                  TASK TO BE TERMINATED.               20600019
*                                                                       20800019
*                            2. REG 1 WILL CONTAIN THE ERROR CODE       21000019
*                              THE ERROR CODES ARE.                     21200019
*                                                                       21400019
*                             X'0128' - THE EXTRACT LIST IS INVALID     21600019
*                                                                       21800019
*                             X'0228' - INPUT PARAMETER LIST ADDRESS    22000019
*                                  IS INVALID                           22200019
*                                                                       22400019
*                             X'0328' - SPECIFIED SUBTASK INVALID       22600019
*                                                                       22800019
* TABLES AND CONTROL BLOCKS                                             23000019
* REFERENCED-                                                           23200019
*                           1. TCB- TASK CONTROL BLOCK                  23400019
*                                                                       23600019
*                             THE FOLLOWING FIELDS ARE EXTRACTABLE.     23800019
*                                                                       24000019
*              TCBGRS- ADDRESS OF GENERAL REGISTER SAVE AREA.           24200019
*              (GRS)   WORD 1 EXTRACT LIST                              24400019
*                                                                       24600019
*              TCBFRS- ADDRESS OF FLOATING POINT SAVE AREA.             24850020
*              (FRS)   WORD 2 EXTRACT LIST.                             25000019
*                                                                       25050020
*              RES- RESERVED, ZEROS IN                                  25100020
*                   WORD 3 EXTRACT LIST                                 25200020
*                                                                       25250020
*              TCBAETX- ADDRESS OF THE ENTRY POINT TO THE               26000019
*              (AETX)   ASYNCHRONOUS TERMINATION ROUTINE.               26200019
*                       WORD 4 EXTRACT LIST                             26400019
*                                                                       26600019
*              TCBLMP- LIMIT AND DISPATCHING PRIORTIES.                 26800019
*              (PRI)   WORD 5 EXTRACT LIST                              27000019
*                                                                       27200019
*              TCBCMP- TASK COMPLETION CODE                             27400019
*              (CMC)   WORD 6 EXTRACT LIST                              27600019
*                                                                       27800019
*              TCBTIO- ADDRESS OF TASK INPUT/OUTPUT TABLE.              28000019
*              (TIOT)  WORD 7 EXTRACT LIST                              28200020
*                                                                       28400019
*              COMM- ADDRESS OF COMMUNICATIONS AREA IN CSCB             28410020
*                    WORD 8 EXTRACT LIST                                28450020
*                                                                       28550020
*                           2. IRB INTERRUPT REQUEST BLOCK              28600019
*                             THE CONTROLLING BLOCK UNDER WHICH         28800019
*                             THE INTERRUPT ROUTINE OPERATES.           29000019
*                                                                       29200019
*                             RBEP- ADDRESS OF AETX ROUTINE.            29400019
*                                   EXTRACTED BY EXTRACT ROUTINE        29600019
*                                   AND PLACED INTO EXTRACT LIST.       29800019
*                                                                       30000019
* LIST ORGINS,TABLES                                                    30200019
* AND CONTROL BLOCKS-         NONE                                      30400019
*                                                                       30600019
* RESTRICTIONS ON                                                       30800019
* USE OF ROUTINE-             NONE                                      31000019
*                                                                       31200019
* NOTES-                      THE ASYNCHRONOUS EXIT ENTRY POINT         31400019
*                             SPECIFIED BY THE ETXR ROUTINE IN          31600019
*                             ATTACH IS IN REALITY STORED INTO AN       31800019
*                             IRB. IT IS ONLY THROUGH THE USE OF        32000019
*                             THE TCB'S IQE THAT THE IRB CAN BE         32200019
*                             REFERENCED TO OBTAIN THIS ADDRESS         32400019
*                             DURING EXTRACT.                           32600019
*                                                                       32800019
*                                                                       33000019
* REGISTER ASSIGNMENTS                                                  33200019
*                                                                       33400019
XRERCODE EQU   1                   ERROR CODE IN REG BEFORE GOING ABTRM 33600019
XERCODE  EQU   1                   COMPLETION CODE FOR INVALID X   I250 33700019
XRTESTWD EQU   1                   WORD TO BE TESTED FOR VALIDTY        33800019
XRPADR   EQU   1                   INPUT PARAMETER ADDRESS              34000019
XWORK    EQU   2                   MASK FOR FULL WORD BDRY TEST    I250 34100019
XERRDIF  EQU   2                   DIFF BETWEEN ERR CODES          I250 34200019
XMSSAVE  EQU   2                   PTR TO HIARCHY ONE BB           I250 34300019
XRCVT    EQU   3                   ADDR OF CVT                          34400019
XROTCB   EQU   4                   CONTENT OF 'OLD'                     34600019
XRORB    EQU   5                   ADDR OF TOP RB OF 'OLD'              34800019
XRCOUNT  EQU   5                   COUNTER FOR FIELDS TO BE EXTRACTED   35000019
XRSAVE   EQU   6                   SAVE REGISTER 1 CONTENT              35200019
XRLIST   EQU   7                   UPDATED LIST ADDR                    35400019
XRTSTFLD EQU   8                   TEST WHAT FIELDS TO EXTRACT          35600019
XRTSTADR EQU   8                   HI ADDR IN PARTITION            I250 35700019
XRINF    EQU   8                   CONTAIN ZERO OR EXTRACTED INFO       35800019
XRFIELD  EQU   9                   UPDATED CONTENT OF FIELD  EXTRACTED  36000019
XRETCB   EQU   10                  ADDR TCB FOR EXTRACTION              36200019
XRSHIFT  EQU   11                  WORK BIT TEST REG                    36400019
XRIND    EQU   11                  INTERNAL INDICATOR                   36600019
XRTCBTST EQU   11                  TCB TO BE TESTED                     36800019
XRLINK   EQU   12                  LINK REGISTER                        37000019
XRABTERM EQU   13                  ABTERM ROUTINE ADDR                  37200019
XRRETURN EQU   14                  RETURN ADDR                          37400019
XRBASE   EQU   15                  BASE REG                             37600019
XRTST1   EQU   12                  TEST REG 1                           37800019
* TASK CONTROL BLOCK DISPLACEMENT (TCB)                                 38000019
*                                                                       38200019
TCBRBP   EQU   0                   PTR TO TOP RB                        38400019
TCBPIE   EQU   4                   PTR TO PROGRAM INTERUPT ELEMENT      38600019
TCBDEB   EQU   8                   PTR TO DATE EXTENT BLOCK             38800019
TCBTIO   EQU   12                  PTR TO TASK I/O TABLE (TIOT)         39000019
TCBCMP   EQU   16                  TCB COMPLETION CODE                  39200019
TCBTRN   EQU   20                  TESTRAN FIELD                        39400019
TCBMSS   EQU   24                  PTR TO EITHER BOUNDARY               39600019
*                                   BOX(JOBSTEP TCB) OR GQE QUEUE       39800019
*                                   (SUBTASKS)                          40000019
TCBPKF   EQU   28                  TASK PROTECT KEY                     40200019
TCBFLG   EQU   29                  FLAGS                                40400019
TCBDSP   EQU   35                  TCB'S DISPATCHING PRIORITY           40600019
TCBLLS   EQU   36                  PTR TO LOADED PROGRAM LIST           40800019
TCBJLB   EQU   40                  PTR TO JOBLIB DCB                    41000019
TCBJSE   EQU   44                  PTR TO JOB STEP TCB                  41200019
TCBGRS   EQU   48                  GENERAL REGISTER SAVE AREA           41400019
TCBIDF   EQU   112                 TCB'S ID                             41600019
TCBFSA   EQU   113                 PTR TO FIRST PROBLEM PROG SAVE AREA  41800019
TCBTCB   EQU   116                 PTR TO NEXT TCB ON READY QUEUE       42000019
TCBTME   EQU   120                 PTR TO TIMER ELEMENT                 42200019
TCBPIB   EQU   124                 PTR TO PIB                           42400019
TCBSTC   EQU   128                 PTR TO SISTER TCB                    42600019
TCBMTC   EQU   132                 PTR TO MOTHER TCB                    42800019
TCBDTC   EQU   136                 PTR TO DAUGHTER TCB                  43000019
TCBIQE   EQU   140                 PTR TO IQE                           43200019
TCBECB   EQU   144                 PTR TO EVENT CONTROL BLOCK           43400019
TCBSET   EQU   148                 PTR TO SELF END OF TASK ROUTINE      43600019
TCBLMP   EQU   152                 TCB'S LIMIT PRIORITY                 43800019
TCBRES1  EQU   153                 RESERVED (ABEND USE)                 44000019
TCBSB    EQU   154                 STATUS BYTE                          44200019
*        BIT 0 = 1   TCBCMP FIELD CONTAINS ABEND MACRO OPERANDS         44400019
*        BIT 5 = 1   JOB STEP TCB: SYSABEND ALREADY OPEN                44600019
*        BIT 6 = 1   ETXR EXIT REQUESTED BY ATTACHING TASK              44800019
TCBRES2  EQU   155                 RESERVED (ABEND USE)                 45000019
TCBRES3  EQU   156                 RESERVED                             45200019
TCBNSTAE EQU   160                 STAE FIELD                           45400019
TCBTCT   EQU   164                                                      45600019
TCBUSER  EQU   168                 USER FIELD                           45800019
TCBDARF  EQU   172                 DAR FLAGS                            46000019
TCBDISF  EQU   173                 DISPATCHABILITY FLAGS                46200019
*        BIT 2 = 1   SET BY ABDUMP                                      46400019
*        BIT 3 = 1   ABEND ENTERED WHILE SYSABEND OPEN FOR OTHER TASK   46600019
*        BIT 4 = 1   TASK TERMINATED                                    46800019
*        BIT 5 = 1   TO BE TERMINATED BY ABEND                          47000019
TCBRES4  EQU   174                 RESERVED AS NON-DISPATCHABILITY FLGS 47200019
TCBJSCB  EQU   180                     PTR TO JOB STEP CONTROL BLOCK    47300019
* REQUEST BLOCK DISPLACEMENTS (RB)                                      47400019
*                                                                       47600019
RBNM     EQU   0                   PROGRAM NAME                         47800019
RBSIZE   EQU   8                   SIZE OF RB                           48000019
RBSTAB   EQU   10                  FLAG BYTES                           48200019
RBUSE    EQU   12                  USE COUNT                            48400019
RBEP     EQU   13                  ENTRY POINT ADDRESS                  48600019
RBOPSW   EQU   16                  SAVE AREA FOR PSW                    48800019
RBQ      EQU   24                  ADDR OF SIZE OF PROG                 49000019
RBWCF    EQU   28                  WAIT COUNT                           49200019
RBLINK   EQU   29                  ADDR PREVIOUS RB OR TCB              49400019
         SPACE 1                                                        49600019
* GENERAL EQUATES                                                       49800019
*                                                                       50000019
FLDSIZE  EQU   10                  NO. OF FLDS TO BE EXTD-1   AC A47074 50200021
NOFLDS   EQU   11                        MAXIMUM NO. OF FIELDS    M0811 50300020
HEADADR  EQU   160                 DISPLACEMENT IN CVT OF 'HEAD' TCB    50400019
VALID    EQU   4                   DISP FOR NORMAL RETURN          I250 50450019
NXTBB    EQU   12                  DISPLACEMENT OF LCS BB          I250 50500019
LCSBIT   EQU   1                   BIT SETTING FOR LCS INCICATOR   I250 50550019
Q0       EQU   0                   DEC 0                                50600019
XF1      EQU   X'F1'               MASK FOR PROTECT KEY & MODE CHECK    50800019
SVCOPSW  EQU   32                  ADDR OF SUPERVISOR CALL OLD PSW      51000019
ABEND    EQU   13                    ABEND SVC NUMBER                   51200019
Q3       EQU   3                   DEC 3                                51400019
Q4       EQU   4                   DEC 4                                51600019
Q8       EQU   8                   DEC 8                                51800019
Q1       EQU   1                   DEC 1                                52000019
Q2       EQU   2                        DEC 1                           52200019
* Q-EQUATES ARE USED FOR DISPLACEMENTS, MASKS, OR AS COUNTS.            52400019
Q12      EQU   12                                                       52600019
X08      EQU   X'08'                    F PT REG MASK                   52800019
IRBPTR   EQU   8                        OFFSET TO IRB PTR IN IQE        53000019
TCBFPS   EQU   32                       F PT REG TCB DISPLACEMENT       53200019
ERRXRACT EQU   X'428'              ERROR CODE FOR ERROR5 ENTRY TO  I250 53250019
*                                  ERROR TABLE; EXTRACT LIST ADD   I250 53300019
*                                  INVALID                         I250 53350019
ERRCODE  EQU   X'228'              ERR CODE FOR ERROR1 & ERROR3    I250 53400019
*                                  ENTRIES TO ERROR TABLE          I250 53450019
EDECRMNT EQU   X'100'              DIFF BETWEEN ERROR CODES        I250 53500019
         SPACE 2                                                        53550019
* MAPPING MACRO FOR JSCB                                                53600019
         IEZJSCB                                                        53650019
         SPACE 2                                                        53700019
* MAPPING MACRO FOR CSCB                                                53750019
CSCB     DSECT                                                          53800019
         IEECHAIN                                                       53850019
         SPACE 2                                                        53900019
IGC040   CSECT                                                          54000019
* EXTRACT (SVC 40)                                                      54200019
         SPACE 1                                                        54400019
* INPUT PARAMETER                                                       54600019
********************                                                    54800019
*     *  LIST ADR  *                                                    55000019
********************                                                    55200019
*    * TCB LOC ADR *                                                    55400019
********************                                                    55600019
* EXTRACT FIELD    *                                                    55800019
********************                                                    56000019
         SPACE 1                                                        56200019
* BIT MEANING IN FIELD. ON (1) MEANS EXTRACT INFORMATION                56400019
* 0 BIT (GRS)  ADDRESS OF TCB GENERAL REGISTER LOCATION                 56600019
* 1 BIT (FRS)  ADDRESS OF TCB FLOATING REGISTER LOCATION                56800019
* 2 BIT (RES)  RESERVED                                                 57000020
* 3 BIT (AETX) ADDRESS OF TCB ASYNCHRONUS TERMINATE ROUTINE             57200019
* 4 BIT (PRI)  TCB LIMIT AND DISPATCHING PRIORTIES                      57400019
* 5 BIT (CMC)  TCB COMPLETION CODE                                      57600019
* 6 BIT (TIOT) ADDRESS OF TASK I/O TABLE                                57800019
* 7 BIT (COMM) ADDRESS OF COMMUNICATION AREA IN CSCB                    57900020
         SPACE 1                                                        58000019
*   EXTRACT ROUTINE                                                     58200019
*      THIS ROUTINE EXTRACTS INFORMATION FROM REQUESTING TCB OR FROM    58400019
* IT'S DAUGHTER TCB, THE TCB ADDRESS WILL BE IN THE SECOND WORD OF      58600019
* INPUT LIST SPECIFIED BY INPUT REGISTER (1). NO TCB VALIDITY CHECK IS  58800019
* MADE.                                                                 59000019
*      THE LIST ADDRESS (LOCATION WHERE EXTRACTED INFORMATION           59200019
* IS TO BE STORED) IS CHECKED FOR PROPER PARTITION.                     59400019
*      THE INFORMATION TO BE EXTRACTED IS FLAGGED IN THE FIELD BYTE     59600019
* OF THE INPUT PARAMETER.                                               59800019
         SPACE 2                                                        60000019
         BALR  XRBASE,Q0                SET UP BASE REG                 60200019
         USING *,XRBASE                                                 60400019
* TEST INPUT LIST TO FIND IF REQUESTING TCB OR DAUGHTER TCB             60600019
* INFORMATION SHOULD BE EXTRACTED.                                      60800019
         SPACE 1                                                        61000019
         L     XRABTERM,RBWCF(XRORB)   GET PREVIOUS RB                  61200019
         TM    RBOPSW+1(XRABTERM),XF1  ENTRY VIA SUPERVISOR TASK        61400019
         BZ    SVCENTRY                YES - BYPASS VALIDITY CHECK      62500019
         BAL   XRLINK,VALIDCK      GO TO VALIDITY CHECK RTN        I250 63000019
         B     ERROR3              ERROR RETURN FROM VALIDCK RTN   I250 63500019
SVCENTRY L     XRLIST,Q0(XRPADR)        LOAD LIST ADDR                  64200019
         L     XRFIELD,Q8(XRPADR)       LOAD FIELD CONTENT              64400019
         L     XRETCB,4(XRPADR)         LOAD TCB FIELD                  64600019
         LTR   XRETCB,XRETCB            SUB-TASK OR OWN                 64800019
         BP    LOADLIST                 SUB-TASK - BRANCH               65000019
         LR    XRETCB,XROTCB            LOAD OWN TCB                    65200019
         B     TCBOK                    BRANCH                          65800019
LOADLIST N     XRETCB,ROUND             FORCE TO FULL-WORD BNDRY        66000019
         LA    XRETCB,Q0(XRETCB)        GET OBJECT TCB        AB A66120 66200021
         CLR   XRETCB,XROTCB            EXTRACTING FROM A SUB-TASK      66400019
         BE    TCBOK                    NO - BRANCH                     66600019
         SPACE 1                                                        66800019
* SEARCH THE IMMEDIATE FAMILY FOR THE SUB-TASK. IF NOT PRESENT          67000019
* ABTERM THE REQUESTOR.                                                 67200019
         SPACE 1                                                        67400019
         L     XRTCBTST,TCBDTC(XROTCB)  GET NEXT TCB IN FAMILY          67600019
TRYAGAIN LTR   XRTCBTST,XRTCBTST        IS SUB-TASK PRESENT             67800019
         BZ    ERROR5                   NO SUB-TASK                     68000019
TRY      CR    XRTCBTST,XRETCB          TCB FOUND                       68200019
         BE    TCBOK                    YES - BRANCH                    68400019
         L     XRTCBTST,TCBSTC(XRTCBTST) GET SISTER TCB                 68600019
         LTR   XRTCBTST,XRTCBTST        IS SISTER PRESENT               68800019
         BZ    ERROR5                   NO SUBTASK - BRANCH             69000019
         B     TRY                      GO TO TEST TCB                  69200019
         SPACE 1                                                        69400019
* TEST IF ENTRY BY SUPERVISOR. YES, SKIP THIS SECTION. NO, TEST IF      69600019
* LIST ADDRESS WHERE EXTRACTED INFORMATION IS TO BE STORED IS IN THE    69800019
* CORRECT PARTITION. WRONG PARTITION, ABTERM.                           70000019
         SPACE 1                                                        70200019
TCBOK    EQU   *                                                  M0811 70209020
         L     XRABTERM,RBWCF(XRORB)     LOAD ADDR OF PREV RB           70308020
         TM    RBOPSW+1(XRABTERM),XF1                                   70320019
         BZ    GOFIRST                 YES - BYPASS VALIDITY CHECK      70380019
         LR    XRTESTWD,XRLIST         LOAD ADDR OF LIST                70500019
         LA    XROTCB,0(XROTCB)    CLEAR HI ORDER BYTE             I250 70800019
CHECKL   DS    0H                                                  I250 71100019
         BAL   XRLINK,VALIDCK      GO TO VALIDITY CHECK RTN        I250 71400019
         B     ERROR1              ERROR RETURN FROM VALIDCK RTN   I250 71700019
         LTR   XROTCB,XROTCB            1ST OR 2ND LIST CHECK           72200019
         BNH   GOFIRST             BR IF 2ND TIME THRU LOOP        I250 72400019
         LA    XRCOUNT,FLDSIZE          LOAD FIELD SIZE MINUS ONE       72600019
         LA    XRSHIFT,Q1(XRCOUNT)      LD FIELD SIZE                   72800019
         LR    XRTSTFLD,XRFIELD         LD FIELD CONTENT                73000019
LOOP2    ALR   XRTSTFLD,XRTSTFLD        FIELD TO BE EXTRACTED           73200019
*                                        (INDICATED BY CARRY)           73400019
         BC    Q3,SHIFTCTR              YES - BRANCH                    73600019
         BCT   XRCOUNT,SHIFTCTR         DECREMENT FIELD COUNTER         73800019
SHIFTCTR BCT   XRSHIFT,LOOP2            DECREMENT SHIFT COUNTER         74000019
*                                       (NOT ZERO BRANCH)               74200019
         SLL   XRCOUNT,Q2               ADJUST FROM BYTES TO WORDS      74400019
         LA    XRTESTWD,Q0(XRCOUNT,XRLIST) LOAD LAST LIST ADR           74600019
         O     XROTCB,TESTBIT      INDICATE NEG VALUE FOR 2ND      I250 74700019
*                                  VALID. CHK LOOP                 I250 74800019
         B     CHECKL                   GO CHECK LAST ADDRESS           75000019
GOFIRST  EQU   *                                                        75010020
         LA    XRSAVE,NOFLDS            MAXIMUM NO. FIELDS        M6074 75050020
         LR    XRTESTWD,XRLIST          LIST ADDRESS              M0811 75100020
         LR    XWORK,XRFIELD            EXTRACT FIELD BITS        M2922 75160020
LOOP1    EQU   *                                                        75170020
         ALR   XWORK,XWORK              Q.FIELD TO BE EXTRACTED   M0811 75180020
         BC    Q12,FLDCTR                NO, BYPASS ZEROING FLD   M2922 75190020
         XC    0(4,XRTESTWD),0(XRTESTWD) ZERO FIELD               M3850 75192020
         LA    XRTESTWD,4(XRTESTWD)     INCR TO NEXT LIST FIELD   M0811 75194020
FLDCTR   BCT   XRSAVE,LOOP1             Q. ALL FIELDS ZEROED      M0811 75196020
*                                        NO, BRANCH TO TEST NXT   M6074 75198020
         LA    XRLINK,BITS              LD ADDR OF FIRST TEST           75200020
         B     SHIFT                    GO                              75400019
         SPACE 1                                                        75600019
* TEST REG. Q INDICATE SOMETHING TO STORE IN LIST. IF YES STORE         75800019
* REG CONTENTS AND UPDATE LIST ADDRESS, NOTHING TO STORE GO TO          76000019
* NEXT SECTION.                                                         76200019
         SPACE 1                                                        76400019
QSTORE   BC    Q12,SHIFT           Q.   EXTRACT INFORMATION (NO BRANCH) 76600019
         ST    XRINF,Q0(XRLIST)         ST EXTRACTED INFO IN LIST       76800019
         LA    XRLIST,Q4(XRLIST)        UPDATE LIST ADDR                77000019
         SPACE 1                                                        77200019
* SHIFT FIELD CONTENT LEFT 1 TO SET CONDITION CODE. IF INFORMATION TO   77400019
* BE EXTRACTED, CONDITION CODE WILL BE CARRY.                           77600019
         SPACE 1                                                        77800019
SHIFT    ALR   XRFIELD,XRFIELD     SHIFT FIELD LEFT 1                   78000019
         BR    XRLINK                                                   78200019
         SPACE 1                                                        78400019
* (GRS) LOAD  EXTRACT TCB'S GENERAL REGISTER SAVE AREA ADDRESS.         78600019
         SPACE 1                                                        78800019
BITS     LA    XRINF,TCBGRS(XRETCB)     LD ADR OF GENERAL REG SAVE      79000019
         BAL   XRLINK,QSTORE                                            79200019
         SPACE 1                                                        79400019
* (FRS) LOAD EXTRACT TCB'S FLOATING PT REG SAVE AREA ADDRESS.           79600019
         SPACE 1                                                        79800019
         BC    Q12,EX1             Q.   FRS BIT ON (NO BRANCH)          80000019
         LA    XRINF,TCBFPS             LD FLOATING PT DISPLACMENT      80200019
         LNR   XRINF,XRINF              MAKE NEGATIVE DISPLACEMENT      80400019
         AR    XRINF,XRETCB             ADD EXTRACT TCB'S ADDR          80600019
         TM    TCBFLG+Q2(XRETCB),X08    SET CONDITION WHETHER FLOATING  80800019
*                                        PT REGS EXIST OR NOT           81000019
EX1      BAL   XRLINK,QSTORE            CHECK EXTRACTION                81200019
         SPACE 1                                                        81400019
* (RES) THIRD WORD OF LIST RESERVED                                     81600020
         SPACE 1                                                        81800019
         LA    XRINF,0                  LOAD ZEROS                M2973 82000020
         BAL   XRLINK,QSTORE            CHECK EXTRACTION                82200019
         SPACE 1                                                        82400019
* (AETX) LOAD ASYNCHRONOUS TERMINATE ROUTINE ADDRESS                    82600019
         SPACE 1                                                        82800019
         BC    Q12,EX2             Q.   ETXR BIT ON                     83000019
         L     XRINF,TCBIQE(XRETCB)     GET IQE ADDRESS                 83200019
         LTR   XRINF,XRINF         Q.   ETXR ADDR PRESENT               83400019
         BZ    EX3                      NO - BRANCH                     83600019
         L     XRINF,IRBPTR(XRINF)      GET IRB ADDRESS                 83800019
         L     XRINF,RBUSE(XRINF)      LD ASYN TERM ADDR                84000019
         LA    XRINF,Q0(XRINF)                                          84010019
EX3      LTR   XRETCB,XRETCB            RE-SET CONDITION CODE           84200019
EX2      BAL   XRLINK,QSTORE            CHECK EXTRACTION                84400019
         SPACE 1                                                        84600019
* (PRI) LOAD LIMIT AND DISP PRIORITIES                                  84800019
         LA    XRINF,Q0                ZERO REG                   M4416 84810019
         IC    XRINF,TCBLMP(XRETCB)     GET LIMIT PRIORITY              85000019
         SLL   XRINF,Q8                SHIFT ONE                        85010019
         IC    XRINF,TCBDSP(XRETCB)     GET DISPATCHING PRIORITY        85200019
         BAL   XRLINK,QSTORE            CHECK EXTRACTION                85400019
         SPACE 1                                                        85600019
* (CMC) LOAD COMPLETION CODE OF TCB.                                    85800019
         SPACE 1                                                        86000019
         L     XRINF,TCBCMP(XRETCB)     LD COMPLETION CODE              86200019
         BAL   XRLINK,QSTORE            CHECK EXTRACTION                86400019
         SPACE 1                                                        86600019
* (TIOT) LOAD TASK INPUT OUTPUT TABLE ADDRESS.                          86800019
         SPACE 1                                                        87000019
         L     XRINF,TCBTIO(XRETCB)     LD ADDR TIOT                    87200019
         BAL   XRLINK,QSTORE           CZECH EXTRACTION                 87210019
         SPACE                                                          87220019
* (COMM) LOAD COMMUNICATION AREA ADDRESS.                               87230019
         SPACE                                                          87240019
         L     XRINF,TCBJSCB(XRETCB)   LOAD JSCB ADDR                   87250019
         USING IEZJSCB,XRINF           JSCB ADDRESSABILITY              87260019
         L     XRINF,JSCBCSCB          LOAD CSCB ADDR                   87270019
         USING CSCB,XRINF              CSCB ADDRESSABILITY              87280019
         LA    XRINF,CHECBP            LOAD ECB/CIB PTR LIST ADDRESS    87290019
         DROP  XRINF                   REGISTER CONTAINS ANSWER         87300019
         BAL   XRLINK,QSTORE           CHECK EXTRACTION       AC A47074 87350021
         SPACE                                                          87400021
* (TSO) LOAD ZEROS FOR TIME SHARING BYTE ADDRESS              AC A47074 87450021
         SPACE                                                          87500021
         LA    XRINF,0                  LOAD ZEROS            AC A47074 87550021
         BAL   XRLINK,QSTORE            CHECK EXTRACTION      AC A47074 87600021
         SPACE                                                          87602021
* (PSB) LOAD ZEROS FOR PROTECTED STORAGE CONTROL BLOCK ADDR   AC A47074 87604021
         SPACE                                                          87604421
         LA    XRINF,0                  LOAD ZEROS            AC A47074 87604821
         BAL   XRLINK,QSTORE            CHECK EXTRACTION      AC A47074 87605221
         SPACE                                                          87605621
* (TJID) LOAD ZEROS FOR TIME SHARING OPTION TERMINAL          AC A47074 87605721
         SPACE                                                          87605821
         LA    XRINF,0                  LOAD ZEROS            AC A47074 87605921
         BAL   XRLINK,QSTORE            CHECK EXTRACTION      AC A47074 87612321
         SPACE                                                          87614321
         SPACE                                                          87620021
         BR    XRRETURN                 RETURN TO CALLER      AC A47074 87620421
         SPACE                                                          87620521
         SPACE                                                          87620821
* THIS RTN PERFORM VALIDITY CHECKING FOR THE EXTRACT LIST &        I250 87627221
* PARAMETER LIST TO WHICH THE EXTRACTS ARE RETURNED                I250 87633621
         SPACE                                                          87640021
VALIDCK  DS    0H                                                  I250 87646421
         LA    XWORK,Q3            GENERATE FULL WORK MASK         I250 87652821
         NR    XWORK,XRTESTWD      Q. FULL WORD BOUNDARY           I250 87659221
         BNZ   ADDRERR             NO GENERATE ERROR CODE          I250 87665621
         L     XRSAVE,TCBJSE(XROTCB) GET JOBSTEP TCB               I250 87672021
         L     XRSAVE,TCBMSS(XRSAVE) ADDR BOUNDARY BOX (BB)        I250 87678421
         LR    XMSSAVE,XRSAVE      SAVE ADDR BOUNDARY BOX          I250 87684821
CKLCS    L     XRTSTADR,Q8(XRSAVE) GET HIGH ADDR OF PARTITION      I250 87691221
         L     XRSAVE,Q4(XRSAVE)   GET LOW  ADDR OF PARTITION      I250 87697621
         LA    XRPADR,Q0(XRPADR)   CLEAR HIGH ORDER BYTE           I250 87704021
         CR    XRSAVE,XRPADR       PLIST LOWER THAN P LOWLIM       I250 87710421
         BH    ADDRERR             YES PLIST NOT IN PARTITION      I250 87716821
         CR    XRTSTADR,XRPADR     PLIST HIGHER THAN P HI LIM      I250 87723221
         BH    VALID(XRLINK)       NO,PLIST IS IN PARTITION        I250 87729621
*                                  NORMAL RETURN TO CALLER         I250 87736021
         SPACE                                                          87742421
* NEXT INSTRUCTION ASSUMES 1ST BYTE LCS BB HAS BIT 7 EQUAL ZERO         87748821
         TM    Q0(XMSSAVE),LCSBIT  IS LCS BIT ON IN THIS BB        I250 87755221
         BNO   ADDRERR             NO  PLIST NOT IN PARTITION      I250 87761621
         LA    XRSAVE,NXTBB(XMSSAVE) UPDATE TO CHK LCS BB          I250 87768021
         B     CKLCS               CHECK FOR PLIST IN LCS          I250 87774421
ADDRERR  LA    XERCODE,ERRCODE     VALUE FOR ENTRY TO ERRTABLE     I250 87780821
         LA    XERRDIF,EDECRMNT    DECREMENT BETWEEN ERR CODES     I250 87787221
         BR    XRLINK              RETURN TO ERROR EXIT FOR CALL   I250 87793621
         SPACE 1                                                        87800019
* ERROR EXIT.                                                           88000019
ERROR5   LA    XERCODE,ERRXRACT    INVALID SUBTASK  CC 328         I250 88200019
         LA    XERRDIF,EDECRMNT    DECREMENT BETWEEN ERROR CODES   I250 88400019
ERROR1   SR    XERCODE,XERRDIF     LD ERRCODE   CC 128             I250 88600019
ERROR3   DS    0H                  INPUT PLIST ERRCODE  CC 228     I250 88800019
RDYABT   SLL   XRERCODE,12         POSITION COMP CODE                   89070019
         O     XRERCODE,TESTBIT    INDICATE DUMP                        89150019
         SVC   ABEND               ABEND REQUESTRO                      89250019
         SPACE 1                                                        89400019
* DEFINE CONSTANT                                                       89600019
         SPACE 1                                                        89800019
         DS    0F                                                       90000019
ROUND    DC    X'00FFFFFC'              MASK TO FORCE FULL-WORD BDRY    90200019
TESTBIT  DC    X'80000000'              TEST MASK                       90400019
         END                                                            90800019
