 TITLE   'IEADTM25 - IGC05D1C - DAR LOAD 4 MFT-MFT ATTACH'              00700021
IGC05D1C CSECT                                                          01400021
*  DAR LOAD4 WAS SPLIT FROM DAR 3 FOR MFT STEAL CORE PROBLEM  CE A35198 02100000
*********************************************************************** 02800000
*                                                                     * 03500000
*              MFT DAMAGE ASSESSMENT ROUTINE (LOAD 4)                 * 04200000
*                                                                     * 04900000
*   MODULE NAME ... IEADTM25                                          * 05600000
*                                                                     * 06300000
*   ENTRY POINT ... IGC05D1C                                          * 07000021
*                                                                     * 07700000
*   FUNCTION ...                                                      * 08400000
*        1. SET THE FAILING TASK PERMANENTLY NONDISPATCHABLE.         * 09100000
*                                                                     * 09800000
*   ATTRIBUTES ...                                                    * 10500000
*        REENTRANT, REFRESHABLE, DISABLED, PRIVILEGED, NON-RESIDENT   * 11200000
*                                                                     * 11900000
*   EXITS ...                                                         * 12600000
*        TO THE DISPATCHER                                            * 13300000
*                                                                     * 14000000
*   OUTPUT ... NONE                                                   * 14700000
*                                                                     * 15400000
*   EXTERNAL REFERENCES ...                                           * 16100000
*        1. COMMUNICATIONS VECTOR TABLE (CVT)                         * 16800000
*              A. CVTHEAD-ADDRESS OF HIGHEST PRIORITY TCB             * 17500000
*              B. CVTTCBP-ADDRESS OF A DOUBLE WORD-FIRST CONTAINING   * 18200000
*                 THE NEXT TO BE DISPATCHED TCB ADDRESS, THE SECOND   * 18900000
*                 CONTAINING THE LAST (CURRENT) TCB ADDRESS           * 19600000
*              C. CVTBTERM-ENTRY POINT ADDRESS OF ABTERM              * 20300000
*              D. CVT0DS-ENTRY POINT ADDRESS OF THE DISPATCHER        * 21000000
*        2. TASK CONTROL BLOCK (TCB)                                  * 21700000
*              A. TCBRBP-POINTER TO TOP RB ON RB QUEUE FOR ADDRESS OF * 22400000
*                 PRESENT RB                                          * 23100000
*              B. TCBTCB-ADDRESS OF NEXT TCB ON READY QUEUE           * 23800000
*              C. TCBDAR-CONTAINS DAR STATUS BITS AND SECONDARY       * 24500000
*                 DISPATCHABILITY FLAGS                               * 25200000
*                 TCBDAR+1 (SECONDARY DISPATCHABILITY FLAGS)          * 25900000
*                    X'40' PNONDISP DAR PERMANENT NONDISPATCHABILITY  * 26600000
*                                                                     * 27300000
*        3. REQUEST BLOCK (RB)                                        * 28000000
*              A. RBWCF-WAIT COUNT                                    * 28700000
*                                                                     * 29400000
*********************************************************************** 30100000
         EJECT                                                          30800000
         BALR  BASEREG,ZERO             ESTABLISH                       31500000
         USING *,BASEREG                     ADDRESSIBILITY             32200000
         L     CVTREG,SIXTEEN           CVT ADDRESS                     32900000
         L     TCBREG,ZERO(CVTREG)      OBTAIN TCB                      33600000
         L     TCBREG,FOUR(TCBREG)           ADDRESS                    34300000
         USING TCBSECT,TCBREG                                           35000000
         USING CVTDSECT,CVTREG          ADDRESSABILITY FOR CVT    20373 35700000
         L     RBADR,TCBRBP             PRESENT RB ADDRESS              36400000
         USING RBSECT,RBADR                                             37100000
         L     R15,CVTPURG              GET ADDR SUBSYSTEM PURGE  21014 37800000
         LR    R1,TCBREG                INPUT = CURRENT TCB       21014 38500000
         BALR  RETREG,R15               LINK WITH SS PURGE        21014 39200000
         SPACE 3                                                        39900000
         OI    TCBFLGS+4,NONDISPA       SET THIS TASK NON-DISPATCHABLE  40600000
         OI    TCBDAR+1,PNONDISP        SET THIS TASK PERMANENTLY       41300000
*                                       NON-DISPATCHABLE                42000000
*  THE FOLLOWING BLOCK OF CODE WAS ADDED IN SUPPORT OF PROJECT    21014 42700000
*   (GTF).  IT CHECKS TO SEE IF THE FAILING TASK HAS SUSPENDED    21014 43400000
*   GTF TRACING. IF IT HAS, WE WILL EXECUTE A HOOK TO SIGNAL THAT 21014 44100000
*   TRACING IS TO RESUME. IF THIS TASK HAS NOT REQUESTED TRACE    21014 44800000
*   SUSPENSION, THE HOOK WILL BE BYPASSED. THIS PROCESS ENSURES   21014 45500000
*   THAT A FAILING TASK WILL NOT PERMANENTLY KEEP THE TRACE       21014 46200000
*   SUSPENDED.                                                    21014 46900000
*                                                                 21014 47600000
         TM    TCBFLGS,TCBGTOFM         IS A SUSPEND GTF TRCE AC  21014 48300000
*                                       HOOK OUTSTANDING AGAINST  21014 49000000
*                                       THIS TCB ?                21014 49700000
         BNO   NOHOOK                   NO.. THEN SKIP HOOK       21014 50400000
         HOOK  EID=IHLMABON             RESUME TRACE              21014 51100000
         NI    TCBFLGS,FF-TCBGTOFM      RESET TRACE SUSP FLAG AC  21014 51800000
NOHOOK   EQU   *                        BYPASS RE-ENTRY           21014 52500000
         MVI   XRBPSW,ENABLE            ENABLE RESUME PSW IN RB   20373 53200000
         SR    WKREG5,WKREG5            SWITCH TO COMM TASK             53900000
         ST    WKREG5,TCBTME            ZERO OUT TIMER FIELD            54600000
*                                       THIS PREVENTS HARDWARE INTERR   55300000
         LR    WKREG,TCBREG             SAVE CURRENT TCB ADR     A33254 56000000
         L     TCBREG,CVTHEAD           GET TOP TCB ON QUEUE     A33254 56700000
TCBCOMP  CR    TCBREG,WKREG             CURRENT TASK             A33254 57400000
         BNE   CONT1                    NO-CONTINUE               M1523 58100000
         SR    TCBREG,TCBREG            SET TO ZERO 'NEW'         M1523 58800000
         B     SETSWTCH                 GO SET TASK SWITCH        M1523 59500000
CONT1    EQU   *                                                  M1523 60200000
         CLI   TCBFLGS+4,ZERO           IS THIS TCB DISPATCHABLE A33254 60900000
         BNE   SEARCHQ                  NO-CONTINUE TO NEXT TCB  A33254 61600000
         L     RBADR,ZERO(TCBREG)       TOP RB                   A33254 62300000
         CLI   XRBWT,ZERO               IS THE TOP RB WAITING    A33254 63000000
         BE    SETSWTCH                 NO-BRANCH                A33254 63700000
SEARCHQ  L     TCBREG,TCBTCB            NEXT LOWER PRTY TCB      A33254 64400000
         B     TCBCOMP                  TEST FOR DISPATCHABILITY A33254 65100000
SETSWTCH L     WKREG5,CVTTCBP            ADDR OF 'NEW'        CE A35198 65800000
         ST    TCBREG,ZERO(WKREG5)      SET TASK SWITCH       CE A35198 66500000
         L     R1,CVTBTERM              LOCATE ABTERM EP      CE A35198 67200000
         L     R1,SVRBPOOL(R1)         LOCATE ABEND SVRB POOL CE A35198 67900000
         CL    WKREG,USERTCB(R1)    DOES JOB HAVE ABEND POOL  CE A35198 68600000
         BNE   NOPOOL                   NO, DO NOT FREE POOL  CE A35198 69300000
         MVI   XRBSZE(R1),ZERO           FREE POOL SVRB1      CE A35198 70000000
         MVI   SVRB2+XRBSZE(R1),ZERO     FREE POOL SVRB2      CE A35198 70700000
         MVI   SVRB3+XRBSZE(R1),ZERO     FREE POOL SVRB3      CE A35198 71400000
         SR    R0,R0                                          CE A35198 72100000
         ST    R0,USERTCB(R1)           FREE ABEND SVRB POOL  CE A35198 72800000
NOPOOL   EQU   *                                              CE A35198 73500000
         L     RETREG,CVT0DS            ADDRESS OF DISPATCHER           74200000
         BR    RETREG                   RETURN TO DISPATCHER            74900000
         SPACE 3                                                        75600000
ENABLE   EQU   X'FF'                    TO ENABLE RBOPSW IN RB          76300000
FF       EQU   X'FF'                    TO FORM RESET MASK        21014 77000000
NONDISPA EQU   X'01'                    NON-DISPATCHABILITY FLAG        77700000
PNONDISP EQU   X'40'                    PERMANENT NON-DISPATCHABILITY   78400000
*                                       BIT INTERNAL TO DAR             79100000
R0       EQU   0                                                        79800000
R1       EQU   1                                                        80500000
BASEREG  EQU   2                        BASE REGISTER                   81200000
CVTREG   EQU   3                        CVT ADDRESS                     81900000
TCBREG   EQU   4                        TCB ADDRESS                     82600000
RBADR    EQU   5                        REQUEST BLOCK ADDRESS           83300000
WKREG5   EQU   5                                                        84000000
WKREG    EQU   6                        WORK REGISTER                   84700000
RETREG   EQU   14                       RETURN REGISTER                 85400000
R15      EQU   15                                                       86100000
SIXTEEN  EQU   16                                                       86800000
SVRBPOOL EQU   X'28'        DISP. TO ABEND POOL PTR.IN ABTERM CE A35198 87500000
SVRB2    EQU   144            DISP. TO 2ND SVRB IN POOL       CE A35198 88200000
SVRB3    EQU   288            DISP. TO 3RD SVRB IN POOL       CE A35198 88900000
USERTCB  EQU   432            DISP. TO CONTROL WORD OF POOL   CE A35198 89600000
XRBSZE   EQU   9              DISP. TO RB SIZE BYTE           CE A35198 90300000
         SPACE 2                                                        91000000
         IHBMFTAB                                                       91700000
         END                                                            92400000
