         TITLE 'DETACH FOR MFT'                                         00300019
*********************************************************************** 00600019
*********************************************************************** 00900019
** THIS ROUTINE WAS CREATED FOR RELEASE  19 TO SUPPORT ATTACH IN MFT ** 01200019
*********************************************************************** 01500019
*********************************************************************** 01800019
*-ROUTINE NAME- DETACH                                                  02100019
         SPACE                                                          02400019
*-FUNCTION-                                                             02700019
*      THIS SVC ROUTINE IS INVOKED BY THE ORIGINATOR (ATTACHOR) OF A    03000019
*  TASK TO REMOVE IT FROM THE SYSTEM. THE TASK BEING DETACHED SHOULD BE 03300019
*  COMPLETE AND BE A SUB-TASK OF THE DETACHOR. IF THE TASK BEING        03600019
*  DETACHED CANNOT BE FOUND ON THE DETACHOR'S SUB-TASK QUEUE, THE       03900019
*  DETACHOR IS ABENDED. IF THE SUB-TASK BEING DETACHED IS NOT COMPLETE, 04200019
*  IT IS ABTERMED (UNLESS IT IS IN THE PROCESS OF BEING TERMINETED      04500019
*  ALREADY). IN THIS EVENT, AN ECB IS CREATED, THE ADDRESS OF WHICH IS  04800019
*  PLACED IN THE TCBECB FIELD OF THE TASK BEING ABTERMED. THE OLD ECB   05100019
*  ADDRESS IS SAVED IN THE 1ST WORD OF THE DETACH SVRB'S EXTENDED SAVE  05400019
*  AREA. UPON COMPLETION OF THE ABEND OF THE SUB-TASK, EOT PROCESSING   05700019
*  WILL POST THE ECB ALLOWING THE DETACHOR TO CONTINUE. THE SAVED ECB   06000019
*  WILL THEN BE POSTED AND DETACH PROCESSING CONTINUED.                 06300019
*  DETACH CODE REMOVES THE DETACHEE'S TCB FROM THE SUB-TASK (SISTER)    06600019
*  QUEUE AND FREES THE TCB'S CORE. NOTE THAT DETACH DOES NOT REMOVE THE 06900019
*  TCB FROM THE READY QUEUE. THIS FUNCTION WAS PERFORMED EARLIER IN EOT 07200019
*  PROCESSING.                                                          07500019
         SPACE                                                          07800019
*-ENTRY POINT NAMES- IGC062 (DETACH)                                    08100019
         SPACE                                                          08400019
*-CONTAINED IN MODULE- IEAGED00                                         08700019
         SPACE                                                          09000019
*-ATTRIBUTES-                                                           09300019
*  1.TYPE 3 SVC (TRANSIENT, SUPERVISOR STATE)                           09600019
*  2.REENTERABLE                                                        09900019
         SPACE                                                          10200019
*-APPLICABILITY- OPTION 2 SYSTEMS.                                      10500019
         SPACE                                                          10800019
*-EXTERNAL REFERENCES- NONE.                                            11100019
         SPACE                                                          11400019
*-SVC USAGE-                                                            11700019
*  1. ABEND    (SVC 13)                                                 12000019
*  2. GETMAIN  (SVC 10)                                                 12300019
*  3. FREEMAIN (SVC 10) SUBPOOL 240                                     12600019
*  4. EXIT     (SVC 3)                                                  12900019
         SPACE                                                          13200019
*-INPUT-                                                                13500019
*  1. REGISTER 1 CONTAINS THE ADDRESS OF THE TCB OF THE TASK BEING      13800019
*     DETACHED.                                                         14100019
         SPACE                                                          14400019
*-OUTPUT- NONE                                                          14700019
         SPACE                                                          15000019
*-ENTRY POINTS-                                                         15300019
*  1. IGC062                                                            15600019
*     A. THE PSW IS THE STD SVC PSW, DISABLED FOR SYSTEM INTERRUPTS,    15900019
*        SUPERVISOR STATE, AND SUPERVISOR PROTECTION KEY.               16200019
*     B. REGISTERS-                                                     16500019
*        0,2,6-13,15     IRRELEVANT.                                    16800019
*        1               TCB ADDRESS OF TASK BEING DETACHED.            17100019
*        3               CVT ADDRESS.                                   17400019
*        4               CURRENT TCB ADDRESS (DETACHOR).                17700019
*        5               CURRENT RB ADDRESS.                            18000019
*        14              RETURN ADDRESS.                                18300019
         SPACE                                                          18600019
*-EXIT POINTS-                                                          18900019
*  1. RETURN TO CALLER VIA BRANCH REGISTER 14                           19200019
         SPACE                                                          19500019
*-ERROR EXIT POINTS-                                                    19800019
*  1. ABTERM (ERROR CODE X'8013E000') INCOMPLETE TASK                   20100019
*  2. ABEND (ERROR CODE X'8023E000') INVALID DETACH PARAMETER.          20400019
         SPACE                                                          20700019
*-TABLES AND CONTROL BLOCKS REFERENCED-                                 21000019
*  CVT- CVT0VL01 (UNALTERED)                                            21300019
*     - CVTBTERM (UNALTERED)                                            21600019
*  TCB- TCBLTC   (ALTERED)                                              21900019
*     - TCBNTC   (ALTERED)                                              22200019
*     - TCBFA    (UNALTERED)                                            22500019
         SPACE                                                          22800019
*-LIST ORIGINS TABLES, AND CONTROL BLOCKS INCLUDED-                     23100019
*  NONE                                                                 23400019
         SPACE                                                          23700019
*-RESTRICTIONS ON USE OF ROUTINE-                                       24000019
*  NONE                                                                 24300019
         SPACE                                                          24600019
*-NOTES-                                                                24900019
*  1. REGISTER 1 UPON ENTERING DETACH CODE CONTAINS THE ADDRESS OF A    25200019
*     FULL WORD IN WHICH IS CONTAINED (IN THE 3 LOW ORDER BYTES) THE    25500019
*     ADDRESS OF THE TCB TO BE DETACHED.                                25800019
         EJECT                                                          26100019
TCBLTC   EQU   136            MOST RECENT SUB TASK                      26400019
TCBNTC   EQU   128            OLDER SISTER TASK                         26700019
TCBIDF   EQU   112            NUM VALUE OF TABLE SLOT                   27000019
TCBFSA   EQU   113            FIRST SAVE AREA                           27300019
TCBFPR   EQU   8              FL PT REGS EXIST                          27600019
TCBFLGS3 EQU   31                 OFFSET OF DISPATCHABILITY FLAGS       27900019
TCBTME   EQU   120            TIMER Q ELEM ADDR                         28200019
TCBFLGS4 EQU   X'AF'               TASK TERMINATION BIT                 28500019
TCBDONE  EQU   X'80'               ID FO TERMINATED TASK                28800019
TCBPIB   EQU   124                TCB OFFEST OF PIB PTR                 29100019
PIBJPQ   EQU   44  PIB OFFSET TO NUMBER OF ACTIVE SUBTASKS              29400019
TCBFLGS1 EQU   29                                                       29700019
TCBABND  EQU   X'80'          TASK IS BEING TERMINATED                  30000019
TCBECB   EQU   144            ECB TO BE POSTED ON COMPLETION            30300019
TCBIQE   EQU   140            IQE FOR ETXR RTN                          30600019
CVTIXAVL EQU   124   ADDR OF IOS DATA AREA                              30900019
CVTABTRM EQU   52             ENTRY TO ABTERM                           31200019
IQEIRB   EQU   8              IQE PTR TO IRB                            31500019
IRBUSE   EQU   12             IRB USE COUNT                             31800019
OFFETXR  EQU   X'FD'              ETXR EXISTS NO MORE                   32100019
TCBFLGS5 EQU   154                                                      32400019
DTBSE    EQU   6                                                        32700019
WORK     EQU   7         ADDR OF DETACHEE                               33000019
PARM     EQU   1                                                        33300019
TCBADDR  EQU   2                                                        33600019
REQTCB   EQU   4         REQUESTORS TCB                                 33900019
FIRST    EQU   8                                                        34200019
ZERO     EQU   0                                                        34500019
TABLEADR EQU   9                                                        34800019
XCVT     EQU   3         ADDR OF CVT                                    35100019
SAVERET  EQU   11                                                       35400019
RETREG   EQU   14                                                       35700019
REGF     EQU   15        REG - 15                                       36000019
REQRB    EQU   5         SVRB FOR DETACH                                36300019
IQERG    EQU   9         ADDR OF IQE                                    36600019
IRBRG    EQU   10        ADDR OF IRB                                    36900019
HOLD     EQU   12                                                       37200019
TCBLENTH EQU   212                 LENGTH OF TCB & APPENDAGES BD A58667 37500021
Q0       EQU   0                                                        37800019
ESA      EQU   96                  OFFSET OF ESA IN SVRB                38100019
         EJECT                                                          38400019
IGC062   CSECT                                                          38700019
         DS    0D                                                       39000019
         BALR  DTBSE,Q0            SET UP BASE                          39300019
         USING *,DTBSE                                                  39600019
*CHECK IF PARAM IS VALID                                                39900019
         LR    WORK,PARM           TO SAVE ADDR                         40200019
         SLL   WORK,30             CK IF MULT OF 4                      40500019
         LTR   WORK,WORK           IF NOT THEN                          40800019
         BNE   ABEND               ABEND REQUESTOR                      41100019
         L     WORK,0(PARM)        GET TCB ADDR                         41400019
         LTR   TCBADDR,WORK        IS ADDR 0                            41700019
         BZ    ABEND               YES-INVALID                          42000019
         SLL   WORK,30             TCB ON FW BNDRY                      42300019
         LTR   WORK,WORK           IF NOT                               42600019
         BNE   ABEND               IT IS INVALID                        42900019
*TCB TO BE DETACHED MUST BE DIRECT SUBTASK OF REQUESTOR                 43200019
         SR    FIRST,FIRST              INIT                            43500019
         L     WORK,TCBLTC(REQTCB)  ADDR MOST RECENT SUB-TASK           43800019
LOOP     EQU   *                                                        44100019
         LTR   WORK,WORK            NO MORE                             44400019
         BZ    ABEND                YES-INVALID                         44700019
         CR    WORK,TCBADDR         IS THIS TASK BEING DETACHED         45000019
         BE    OK                  YES                                  45300019
         LR    FIRST,WORK               SAVE BACK POINTER               45600019
         L     WORK,TCBNTC(WORK)   NEXT TASK                            45900019
         B     LOOP                                                     46200019
*THE INPUT PARM IS VALID AND THE TASK BEING DETACHED HAS                46500019
*BEEN FOUND                                                             46800019
OK       EQU   *                                                        47400019
         TM    TCBFLGS4(WORK),TCBDONE  IS TASK DONE                     47700019
         BZ    STILLON             BR IF NO                             47800019
ADJUST   EQU   *                                                        48000019
         LTR   FIRST,FIRST         IF DONE,ADJUST                       48300019
         BZ    DETMRCNT            RELATIONSHIP                         48600019
         MVC   TCBNTC(4,FIRST),TCBNTC(WORK)  TREE                       48900019
         B     FREECORE                                                 49200019
DETMRCNT EQU   *                                                        49500019
         MVC   TCBLTC(4,REQTCB),TCBNTC(WORK)  ADJUST TREE FOR           49800019
*                                  DETACHEE AS MOST RECENT SUBTSK       50100019
FREECORE EQU   *                                                        50400019
         L      PARM,TCBIDF(WORK)  SAVE AREA OF DETACHEE                50700019
         LA    PARM,0(PARM)        CLEAR HI ORDER BYTE                  51000019
         LTR   PARM,PARM           ANY SAVE                             51300019
         BZ    FREETBLE            NO                                   51600019
      FREEMAIN R,LV=72,A=(1)       FREE SAVE AREA                A37993 51900020
FREETBLE EQU   *                                                        52200019
         SR    PARM,PARM           GET ZERO                             52500019
         IC    PARM,TCBIDF(WORK)   GET TBLE CNTR                        52800019
         SLL   PARM,2             CALC TBL INDEX                        53100019
         L     TABLEADR,CVTIXAVL(XCVT)  ADDR OF IOS DATA AREA           53400019
         L     TABLEADR,4(TABLEADR)   ADDR OF TCB ADDR TABLE            53700019
         SR    ZERO,ZERO                                                54000019
         ST    ZERO,0(TABLEADR,PARM)    ZERO TABLE SLOT                 54300019
         L     PARM,TCBPIB(WORK)  GET PIB ADDR                          54600019
         IC    ZERO,PIBJPQ(PARM)   GET NUMBER  ACTIVE TASKS IN PART     54900019
         BCTR  ZERO,ZERO          DECREMENT BY ONE                      55200019
         STC   ZERO,PIBJPQ(PARM)   STORE UPDATE NUMBER TASKS            55500019
         LR    PARM,WORK                SET ADDR FOR FM                 55800019
         LA    REGF,TCBLENTH       GET LENGTH BASE TCB                  56100019
         TM    TCBFLGS3(WORK),TCBFPR    ARE THERE FLOATING REGS         56400019
         BNO   CKTME               NO - DON'T INCR FOR SAVE             56700019
         LA    REGF,32(REGF)       INCR SIZE FOR FP REGS                57000019
         SH    PARM,TRTYTWO        GET ADDR WITH FPREGS                 57300019
CKTME    EQU   *                                                        57600019
         L     FIRST,TCBTME(WORK)  GET TQE ADDR                         57900019
         LTR   FIRST,FIRST         ANY TQE                              58200019
         BZ    FRTCB               NO                                   58500019
         LA    REGF,112(REGF)      ADD TO LNG FOR TQE                   58800019
FRTCB    EQU   *                                                        59100019
         LR    ZERO,REGF           INDICATE LENGTH OF FREE              59400019
         O     ZERO,SUB255         SQS CORE                             59700019
         FREEMAIN R,LV=(0),A=(1)  FREE TCB CORE                         60000019
         BR    14                  EXIT                                 60300019
ABEND    EQU   *                                                        60600019
         L     PARM,ERRCD1              SET ERROR                       60900019
         SVC   13                       ABEND REQUESTOR                 61200019
STILLON  EQU   *                                                        61500019
         LR    SAVERET,RETREG      SAVE SINCE RETREG WILL BE USED       61800019
         TM    TCBFLGS1(WORK),TCBABND   IS DETEE ABENDING               62100019
         BNE   NOABTRM             YES-ABTERM NOT NEEDED                62400019
         LR    ZERO,WORK           SET TCB ADDR TO ABTERM               62700019
         L     PARM,ERRCD2         SET CODE                             63000019
         L     RETREG,CVTABTRM(XCVT) GET ENTRY POINT                    63300019
         BALR  RETREG,RETREG       ABTERM DETACHEE                      63600019
NOABTRM  EQU   *                                                        63900019
         MVC   ESA(4,REQRB),TCBECB(WORK)  SAVE ECB IN ESA               64200019
         GETMAIN R,LV=8            CORE FOR NEW ECB                     64500019
         LR    HOLD,PARM           SAVE ECB ADDR                 A37432 64600020
         SR    ZERO,ZERO                                                64800019
         ST    ZERO,0(PARM)        SET NEW ECB TO ZIP                   65100019
         ST    PARM,TCBECB(WORK)   PUT ADDR IN TCB                      65400019
         L     IQERG,TCBIQE(WORK)  CK IF IQE SPEC FOR ETXR              65700019
         LTR   IQERG,IQERG                                              66000019
         BZ    WAIT                NO-NONE TO FREE                      66300019
         L     IRBRG,IQEIRB(IQERG) GET IRB ADDR                         66600019
         IC    ZERO,IRBUSE(IRBRG)  GET IRB USE CNT                      66900019
         BCTR  0,ZERO              DECR CNT BY 1                        67200019
         LTR   ZERO,ZERO           ANY MORE IQE'S                       67500019
         BNE   SAVEUSE             YES-MORE IQES                        68100019
         LR    PARM,IRBRG          NO MORE IQES                         68400019
         FREEMAIN R,LV=96,A=(1)    FREE IRB CORE                        68700019
COMMON   EQU   *                                                        69000019
         LR    PARM,IQERG                                               69300019
         FREEMAIN R,LV=16,A=(1)    FREE IQE CORE                        69600019
         NI    TCBFLGS5(WORK),OFFETXR  TURN OFF BIT                     69900019
         SR    ZERO,ZERO                                                70200019
         ST    ZERO,TCBIQE(WORK)   ZERO IQE FIELD                       70500019
         LR    PARM,HOLD           RESTORE ECB                          70800019
WAIT     EQU   *                                                        71100019
         WAIT  ECB=(1)  WAIT FOR SUBTASK TO TERMINATE                   71400019
         SSM   DISABLE             NON-INTER                            71700019
         LR    PARM,HOLD                                                72000019
         FREEMAIN R,LV=8,A=(1)     FREE ECB CORE                        72300019
         L     PARM,ESA(REQRB)     RESTORE ORIG ECB               21372 72600021
         LTR   PARM,PARM           WAS THERE AN ECB                     72900019
         BZ    NOECB               NO                                   73200019
         L     RETREG,16(WORK)     COMP CODE FROM TCB            A38669 73300020
         LA    ZERO,ZERO(RETREG)   CLEAR HI BYTE                 A38669 73400020
         POST  (1),(0)             POST ECB                      A38669 73500020
NOECB    EQU   *                                                        73800019
         LR    RETREG,SAVERET      RESTORE EXIT ADDR                    74100019
         B     ADJUST              TASK NOW COMPLETE                    74400019
SAVEUSE  EQU   *                                                        74700019
         STC   ZERO,IRBUSE(IRBRG)  IRB STILL IN USE-DO NOT FREE         75000019
         B     COMMON              TO FREE IEQ,ETC                      75300019
         EJECT                                                          75600019
*   THE FOLLOWING ARE THE CONSTANTS THAT ARE USED BY THIS RTN.          75900019
************************************************                        76200019
TRTYTWO  DC    H'32'                                                    76500019
         DS    0F                                                       76800019
ERRCD1   DC    X'8023E000'                                              77100019
ERRCD2   DC    X'0013E000'         ACTIVE SUBTASK                       77400019
SUB255   DC    X'FF000000'                                              77700019
DISABLE  DC    X'00'                                                    78000019
         END                                                            78300019
