  TITLE 'DELETE SERVICE ROUTINE FOR MFT WITH ASYNCHRONOUS ATTACH'       00300019
*********************************************************************** 00600019
*********************************************************************** 00900019
*  THIS MODULE WAS CREATED FOR RELEASE 19 TO SUPPORT ATTACH IN MFT      01200019
*********************************************************************** 01500019
*********************************************************************** 01800019
IGC009   START 0                                                        02100019
*                                                                       02400019
* ROUTINE. DELETE                                                       02700019
*                                                                       03000019
* ROUTINE NAME.  IEAIDL00                                               03300019
*                                                                       03600019
* CONTAINED IN MODULE.  IEAIDL00                                        03900019
*                                                                       04200019
* APPLICABILITY.  OPTION 2 (MFT) WITH ASYNCHRONOUS ATTACH               04500019
*                                                                       04800019
* FUNCTION.  DECREMENT THE USE COUNT OF A PROGRAM ON THE LOAD LIST,     05100019
*            AND, WHEN THE USE COUNT BECOMES ZERO, REMOVE THE PROGRAM   05400019
*            AND ITS MINORS, IF ANY, FROM THE LOAD LIST AND FREE THE    05700019
*            CORE OCCUPIED BY THE PROGRAM AND ITS MINORS.               06000019
*                                                                       06300019
* ENTRY POINTS AND                                                      06600019
*  CONDITIONS-      ENTRY AT LOCATION IEA0DL00 FROM THE SVC HANDLER     06900019
*                   IN RESPONSE TO AN SVC 9 INSTRUCTION IN THE          07200019
*                   PROBLEM PROGRAM.                                    07500019
*                                                                       07800019
* INPUT-     REGISTER ZERO ADDRESSES AN EIGHT CHARACTER NAME WHICH      08100019
*            SPECIFIES A PROGRAM ON THE LOAD LIST.                      08400019
*                                                                       08700019
* OUTPUT-    NONE                                                       09000019
*                                                                       09300019
* EXTERNAL REFERENCES-   SVCXT - THE RETURN ADDRESS FOR TYPE I SVC      09600019
*                                ROUTINES                               09900019
*                        SVCOPSW(LOCATION 32) - THE ADDRESS OF THE SVC  10200019
*                                OLD PSW.                               10500019
*                        SVF - TYPE 1 SVC SWITCH IN IEAAIH00.           10800019
*                                                                       11100019
* EXITS AND CONDITIONS-  RETURN TO THE SVC HANDLER WITH ZERO IN         11400019
*                        REGISTER 15 IF NO ERROR IS ENCOUNTERED.        11700019
*                                                                       12000019
* ERROR EXIT-       RETURN WITH FOUR IN BITS 24-31 OF REGISTER 15 IF    12300019
*                   THE SPECIFIED PROGRAM IS NOT FOUND ON THE LOAD      12600019
*                   LIST.                                               12900019
*                                                                       13200019
* NOTES-       THIS ROUTINE, RATHER THAN IEAADL00, IS USED WITH         13500019
*              THE SYSGEN ASYNCHRONOUS ATTACH OPTION.                   13800019
*                                                                       14100019
* OPERATION-   IF THE SPECIFIED PROGRAM IS NOT FOUND ON THE LOAD        14400019
*              LIST, SET THE VALUE FOUR INTO REGISTER 15 AND EXIT.      14700019
*              OTHERWISE SET ZERO IN BITS 24-31 OF REGISTER 15.         15000019
*              EXIT IF THE PROGRAM IS A MINOR. DECREMENT THE USE        15300019
*              COUNT, IF NOT ALREADY ZERO, AND EXIT IF THIS RESULTS     15600019
*              IN A NON-ZERO USE COUNT. EXIT IF THE PROGRAM IS          15900019
*              ACTIVE. OTHERWISE, DEQUEUE THE PROGRAM FROM THE LOAD     16200019
*              LIST, SAVE SVC OLD PSW, MOVE REGS FROM SVC SAVE          16500019
*              AREA TO IN LINE SAVE AREA, SAVE SVC OLD PSW.             16800019
*              THEN ISSUE AN SVC 10 (FREEMAIN) FOR                      17100019
*              THE PROGRAM, ITS RB, AND ITS LOAD LIST QUEUE ELEMENT.    17400019
*              RESTORE SVC OLD PSW AND SVC SAVE AREA, RESET             17700019
*              TYPE 1 SVC SWITCH IN IEAAIH00. REPEAT FOR ANY            18000019
*              MINORS BELONGING TO THE PROGRAM, AND THEN EXIT.          18300019
*              FOR SYSTEMS WITH LCS OPTION, IF PROGRAM WAS BLOCK        18600019
*              LOADED INTO H0/H1, I.E. TWO NON-CONTIGUOUS BLOCKS OF     18900019
*              MAIN STORAGE, THE LRB OR LPRB HAS A SIXTEEN BYTE         19200019
*              EXTENT LIST CONTAINING H0/H1 BLOCK ADDR AND LENGTHS.     19500019
*              MUST DO 3 FREEMAINS.                                     19800019
*                                                                       20100019
* REMARKS-     NONE                                                     20400019
*                                                                       20700019
         EJECT                                                          21000019
*                                                                       21300019
* REGISTER EQUATES                                                      21600019
*                                                                       21900019
         EXTRN SVF                                                      22200019
         EXTRN SVCSAV                                                   22500019
OLD      EQU   1                                                        22800019
TCB      EQU   4                                                        23100019
JRET     EQU   8                                                        23400019
RAM      EQU   9                                                        23700019
RAM2     EQU   10                                                       24000019
WORK     EQU   11                       WORK REG                        24300019
EXIT     EQU   14                       RETURN REG                      24600019
FFFF     EQU   13                       DECREMENT REG - MINUS 1         24900019
XLISTPTR EQU   10                       LCS - INDEX PTR                 25200019
LCSRBADR EQU   11                       LCS - RB ADDRESS                25500019
LCSWORK  EQU   11                       LCS WORK REG                    25800019
BASE     EQU   6                        BASE REG                        26100019
R0       EQU   0                        REG 0                           26400019
R1       EQU   1                        REG 1                           26700019
R2       EQU   2                        REG 2                           27000019
R3       EQU   3                        REG 3                           27300019
R4       EQU   4                        REG 4                           27600019
R5       EQU   5                        REG 5                           27900019
R6       EQU   6                        REG 6                           28200019
R7       EQU   7                        REG 7                           28500019
R8       EQU   8                        REG 8                           28800019
R9       EQU   9                        REG 9                           29100019
R10      EQU   10                       REG 10                          29400019
R11      EQU   11                       REG 11                          29700019
R12      EQU   12                       REG 12                          30000019
R13      EQU   13                       REG 13                          30300019
R14      EQU   14                       REG 14                          30600019
R15      EQU   15                       REG 15                          30900019
* GENERAL EQUATES                                                       31200019
*                                                                       31500019
TCBLLS   EQU   36                       OFFSET IN TCB OF LD LIST        31800019
XRBNM    EQU   0                        OFFSET IN PRB OF PROG NAME      32100019
XRBSIZE  EQU   8                        OFFSET IN PRB OF RB SIZE        32400019
XSTAB    EQU   10                       OFFSET OF STATUS FLGS IN RB     32700019
XACTIV   EQU   X'40'                    MASK FOR ACTIVE PROGRAM         33000019
XRBQ     EQU   24                       ADDR OF SIZE OF PROG            33300019
XRBUSE   EQU   12                       RB USE COUNT                    33600019
REGMAIN  EQU   10                       SVC NUMBER FOR REGMAIN          33900019
*                                                                       34200019
* N-EQUATES ARE USED AS MASKS, OFFSETS, OR COUNTS                       34500019
*                                                                       34800019
N0       EQU   0                        ZERO                            35100019
N3       EQU   3                        THREE- X'03' - B'0011'          35400019
N4       EQU   4                        FOUR - X'04' - B'0100'          35700019
N6       EQU   6                        SIX  - X'06' - B'0110'          36000019
N8       EQU   8                        EIGHT- X'08' - B'1000'          36300019
N12      EQU   12                       TWELVE X'0C' - B'1100'          36600019
N16      EQU   16                       SIXTEEN                         36900019
N24      EQU   24                       TWENTYFOUR                      37200019
N40      EQU   40                       FORTY                           37500019
XSTABPN8 EQU   XSTAB+N8                 SELF-EXPLANATORY                37800019
XRBSZPN8 EQU   XRBSIZE+N8           DITTO                               38100019
TCBPIB   EQU   124                 OFFSET OF PIB PTR IN TCB             38400019
JPQ      EQU   X'2C'               OFFSET OF JPQ PTR IN PIB             38700019
CZERO    EQU   8                   CONDITION CODE ZERO EQUIVALENT       39000019
*                                   TO BZ OR BE                         39300019
C7       EQU   7                   CONDITION CODE EQUIVALENT TO         39600019
*                                    BNZ OR BNE                         39900019
XE0      EQU   X'E0'                                                    40200019
N9       EQU   9                   NINE                                 40500019
C1       EQU   1                   CC 1 = BO                            40800019
X02      EQU   X'02'               FLG INDICATING PROG WAS HIERARCHY    41100019
*                                   BLOCK LOADED                        41400019
XD0      EQU   X'D0'               MASK FOR MINOR LPRB STAB FIELD       41700019
SVCOPSW  EQU   32                  LOCATION OF SVC OLD PSW              42000019
XF0      EQU   X'F0'               STAB FIELD MASK FOR LRB              42300019
X50      EQU   X'50'               STAB FIELD MASK FOR FRB              42600019
* THE FIRST SEARCH CONDUCTED IS THAT OF THE RAM AREA. IF THE MODULE     42900019
* IS FOUND IN THE RAM AREA, A NORMAL RETURN IS INDICATED BUT ACTUAL     43200019
* DELETION OF THE MODULE DOES NOT OCCUR.                                43500019
         SPACE 1                                                        43800019
         SPACE 1                                                        44100019
         SPACE 1                                                        44400019
         SPACE 1                                                        44700019
         USING *,BASE                                                   45000019
         B     IEAYDL                                                   45300019
SAVEREG  DS    13F                                                      45600019
IEAYDL   SR    R15,R15             CLEAR REG                            45900019
         LR    FFFF,R15                                                 46200019
         BCTR  FFFF,N0             GENERATE MINUS ONE                   46500019
         LR    WORK,R0                                                  46800019
         CLC   N0(N6,WORK),IGGNAME DOES NAME START 'IGG019'             47100019
         BNE   SEARCH2             NO, GO TO NEXT SEARCH                47400019
         L     RAM,RAMCONS         GET PTR TO BEGINNING RAM LIST        47700019
         L     OLD,N0(RAM)         LD PTR SYSLL 1 - ACCESS METHODS      48000019
         BAL   JRET,XL21           SEARCH SYSLL 1                       48300019
         BR    EXIT                FOUND, RETURN WITHOUT DECREMENTING   48600019
*                                  MOD ON RAM LIST                      48900019
         NOPR  N0                    FILL OUT TO FOUR BYTES             49200019
         SPACE 1                                                        49500019
* THE SECOND SEARCH IS OF THE JPQ (JOB PACK QUEUE). THIS QUEUE          49800019
* CONTAINS ALL THE REENTRANT MODULES BROUGHT INTO THE PARTITION         50100019
* BY EITHER THE JOB STEP TASK OR A SUB-TASK VIA A LOAD. A PTR TO        50400019
* THIS QUEUE IS CONTAINED IN THE PIB AT OFFSET X'24'. THIS QUEUE        50700019
* MAY CONTAIN FRB'S WHICH REPRESENT PARTIALLY LOADED PROGRAMS AND       51000019
* THEREFORE SHOULD BE IGNORED DURING THE SEARCH.                        51300019
         SPACE 1                                                        51600019
SEARCH2  EQU   *                                                        51900019
         L     R2,TCBPIB(TCB)      GET PTR TO PIB                       52200019
         LA    R2,N0(R2)           CLEAR HI BYTE               BD M4932 52210021
         LTR   R2,R2              PIB PTR = ZERO                        52500021
         BZ    SEARCH3            YES - CHECK LLS OF TCB                52800019
         L     OLD,JPQ(R2)         GET JPQ PTR IN PIB                   53100019
         LA    OLD,N0(OLD)         ZERO HIGH ORDER BYTE                 53400019
         BAL   JRET,XL21           SEARCH JPQ                           53700019
         B     DECHE               FOUND, SET UP FOR DECREMENTING       54000019
         SPACE 1                                                        54300019
* NOT FOUND ON JPQ. NEXT SEARCH IS OF TCB LOAD LIST                     54600019
         SPACE 1                                                        54900019
SEARCH3  BAL   JRET,XL2           SEARCH TCB LOAD LIST                  55200019
         B     DECHE               FOUND SET UP FOR DECREMENTING        55500019
         LA    R15,N4              SET NOT FOUND CONDITION              55800019
         BR    EXIT                RETURN                               56100019
         SPACE 1                                                        56400019
DECHE    EQU   *                                                        56700019
         SR    WORK,WORK           DECHE USE COUNT                      57000019
         IC    WORK,XRBUSE+N8(OLD) GET RB USE COUNT                     57300019
         BXLE  WORK,FFFF,CHECK  Q. USE COUNT ALREADY ZERO               57600019
         STC   WORK,XRBUSE+N8(OLD) ST DECREMENTED USE COUNT             57900019
         LTR   WORK,WORK        Q. UPDATED USE COUNT EQUAL TO ZERO      58200019
         BCR   C7,EXIT             NO - EXIT                            58500019
CHECK    CLI   XSTAB+N8(OLD),XE0 Q. IS THIS A MINOR LPRB                58800019
         BCR   CZERO,EXIT          YES - EXIT                           59100019
         TM    XSTAB+N9(OLD),XACTIV  IS PROG ACTIVE                     59400019
         BCR   C1,EXIT             YES - EXIT                           59700019
         SLL   EXIT,N8             SHIFT RET ADDR TO HIGH BYTES         60000019
         L     R10,TCBPIB(TCB)     GET PIB PTR                          60300019
         IC    EXIT,JPQ(R10)        SAVE SUBTASK CNT                    60600019
IEAXDL   LM    R10,R11,N0(OLD)    GET FORWARD & BACKWARD PTRS           60900019
         ST    R10,N0(R11)         RELINK RB ON QUEUE                   61200019
         ST    R11,N4(R10)          DEQ'ING THE SUBJECT RB              61500019
         L     R0,XRBSIZE+N8(OLD)  GET PGM SIZE FOR FREEMAIN            61800019
         SRL   R0,N16              SHIFT OUT FLAG BYTES                 62100019
         SR    XLISTPTR,XLISTPTR   CLEAR REG 10                         62400019
         TM    XSTAB+N8(OLD),X02   HIERARCHY BLOCK LOAD USED            62700019
         LA    LCSRBADR,0(OLD)                                   A64914 62700221
         BZ    NOTLCS                                                   63000019
         LA    LCSWORK,N4          4 D WRDS FOR LRB WITH XLIST          63300019
         CR    R0,LCSWORK        Q. IS THIS AN LRB WITH EXTENT LIST     63600019
         BE    LCS01               MAYBE - BRANCH                       63900019
         LA    LCSWORK,N6          6 D WORDS FOR LPRB WITH XLIST        64200019
         CR    R0,LCSWORK        Q. IS THIS AN LPRB WITH EXTENT LIST    64500019
         BNE   NOTLCS              NO, BRANCH                           64800019
         LA    XLISTPTR,N40        INDEX TO EXTENT LIST                 65100019
         B     LCS02               BRANCH TO SET UP FREEMAIN            65400019
LCS01    TM    XSTABPN8(R1),XF0    IS LRB WITH XLIST REALLY AN LPRB     65700019
*                                   FOR MINOR ENTRY VIA IDENTIFY        66000019
         BNO   NOTLCS              YES, BRANCH                          66300019
         LA    XLISTPTR,N24        INDEX TO XLIST                       66600019
LCS02    LA    LCSRBADR,N0(R1)     SAVE RB ADDR & CLEAR HI BYTE         66900019
*                                  SET UP FREEMAIN H0 BLOCK             67200019
         L     R0,N0(LCSRBADR,XLISTPTR)  H0 LENGTH                      67500019
         L     R1,N8(LCSRBADR,XLISTPTR) H0 ADDR                         67800019
         B     FMIFACE             GO TO FREEMAIN                       68100019
NOTLCS   EQU   *                                                        68400019
         SLR   R0,FFFF             INCREMENT BY 1 FOR LOAD LIST PTRS    68700019
         SLL   R0,3                CHANGE FROM D WRDS TO BYTES          69000019
FMIFACE  EQU   *                                                        69300019
         LM    R8,R9,SVCOPSW       SAVE SVCOPSW                         69600019
         SPACE                                                          69900019
**       MVC   SAVEREG(52),SVCSAV+8     SAVE REGS IN LINE OVER SVC      70200019
         DC    X'D233'             MVC OP CODE & LENGTH                 70500019
         DC    AL4(SVCSAV+8)       ADDR SVC SAVE                        70800019
         ORG   *-4                                                      71100019
         DC    X'6004'        DISPLACEMENT AND BASE REG                 71400019
         ORG   *+2                                                      71700019
         SPACE                                                          72000019
FREE1    EQU   *                                                        72300019
         SR    R7,R7               CLEAR COMPRND REG                    72600019
         TM    XSTABPN8(LCSRBADR),XF0  IS THIS AN LRB             64914 72900021
         BO    FREE                YES - BRANCH                         73200019
         L     R7,XRBQ+8(LCSRBADR)     GET POINTER TO MINOR       64914 73500021
         TM    XSTABPN8(R7),XE0        MINOR                     A69380 73500221
         BO    FREE2                   YES                       A69380 73500421
         SR    R7,R7                   RESET POINTER             A69380 73500621
FREE2    EQU   *                                                 A69380 73500821
         TM    XSTABPN8(LCSRBADR),XE0  IS THIS A MINOR            64914 73800021
         BNO   FREE                    NO BYPASS                        74100019
         S     OLD,EIGHT               BACK INDEX BY EIGHT              74400019
         A     R0,EIGHT                INCR LENGTH BY 8                 74700019
FREE     SVC   REGMAIN             FREE DELETEE                         75000019
         SPACE                                                          75300019
**       OI    SVF+1,X'F0'    RESET SVC TYPE 1 SWITCH IN IEAAIH         75600019
         DC    AL4(SVF+1)                                               75900019
         ORG   *-4                                                      76200019
         DC    X'96F0'                                                  76500019
         ORG   *+2                                                      76800019
         SPACE                                                          77100019
         LTR   XLISTPTR,XLISTPTR   MORE CORE TO FREE                    77400019
         BP    LCS03               YES  H1=1                            77700019
         BM    LCS04               YES RB                               78000019
         STM   R8,R9,SVCOPSW       RESTORE SVC OLD PSW                  78300019
**       MVC   SVCSAV+8(52),SAVEREG                                     78600019
         DC    AL4(SVCSAV+8)       ADDR FLIH SVAREA                     78900019
         ORG   *-4                                                      79200019
         DC    X'D233'             MVC OP CODE & LENGTH                 79500019
         ORG   *+2                                                      79800019
         DC    X'6004'                                                  80100019
         SPACE                                                          80400019
         SR    R15,R15             INDICATE SUCCESSFUL DELETE           80700019
         LTR   R1,R7             Q.ANY MINORS REMAINING                 81000019
         BNZ   IEAXDL              YES - CONTINUE                       81300019
         L     R10,TCBPIB(TCB)     GET PIB PTR                          81600019
         STC   EXIT,JPQ(R10)       RESTORE SUBTASK CNT                  81900019
         SRL   EXIT,N8             RESTORE RET ADDRESS                  82200019
         BR    EXIT                                                     82500019
XL2      L     OLD,TCBLLS(TCB)     LD PTR TO TCB LOAD LIST              82800019
XL21     LTR   OLD,OLD             IS PTR=0                             83100019
         BZ    N4(JRET)            YES,NOT FOUND  RETURN+4              83400019
         CLI   XSTABPN8(OLD),X50   IS THIS AN FRB                       83700019
         BE    GETNEXT             YES  GET NEXT                        84000019
         CLC   N0(N8,WORK),XRBNM+8(OLD)  ARE NAMES EQUAL                84300019
         BCR   CZERO,JRET          YES  FOUND  RETURN                   84600019
GETNEXT  L     OLD,N0(OLD)         NO, GET NEXT L(P)RB                  84900019
         LA    OLD,N0(OLD)         CLEAR HI ORDER BYTE            M4845 85000019
         B     XL21                BACK FOR ANOTHER TRY                 85200019
LCS03    L     R0,N4(LCSRBADR,XLISTPTR) H1 LENGTH                       85500019
         L     R1,N12(LCSRBADR,XLISTPTR)  H1 ADDR                       85800019
         LNR   XLISTPTR,XLISTPTR   SET RB SWITCH                        86100019
         B     FREE                BRANCH TO FREE DELETEE               86400019
LCS04    SR    XLISTPTR,XLISTPTR  CLEAR SWITCH                          86700019
         LR    R1,LCSRBADR         RB ADDR                              87000019
         L     R0,XRBSZPN8(LCSRBADR) RB SIZE                            87300019
         SRL   R0,N16              DUMP FLAGS                           87600019
         SLR   R0,FFFF             INCREMENT BY 1                       87900019
         SLL   R0,N3               CHANGE FROM D WRDS TO BYTES          88200019
         B     FREE1               BRANCH TO FREE DELETEE               88500019
         SPACE 2                                                        88800019
*                                                                       89100019
* CONSTANTS                                                             89400019
*                                                                       89700019
EIGHT    DC    F'8'                    DECIMAL EIGHT                    90000019
RAMCONS  DC    V(IEAARAM4)         ADDRESS OF LIST OF RESIDENT          90300019
*                                   ACCESS METHOD MODULES               90600019
IGGNAME  DC    C'IGG019'                                                90900019
         END                                                            91200019
