IEAIPL   START 0                                                        00020000
*0236020860                                                        INSS 00030018
*0236022000-025500                                                 1985 00040018
*0236149400-150000,153800,157200                                   0542 00050018
         ORG IEAIPL                                                     00060000
*                                                                     * 00080000
*TITLE IEAIPL  - IPL (INITIAL PROGRAM LOAD)                           * 00100000
*                                                                     * 00120000
*FUNCTION/OPERATION-   THE IPL PROGRAM INITIALIZES THE REGISTERS AND  * 00140000
*    CORE STORAGE AND LOADS THE RESIDENT NUCLEUS OF THE OPERATING     * 00160000
*    SYSTEM INTO CORE STORAGE.                                        * 00180000
*                                                                     * 00200000
*ENTRY POINTS-   IPL IS ENTERED ONLY THROUGH THE PSW WHICH IS LOADED  * 00220000
*    INTO LOCATION ZERO FROM THE SYSTEM RESIDENCE DEVICE BY THE IPL   * 00240000
*    HARDWARE CIRCUITRY WHICH INCLUDES THE EXECUTION OF THE IPL CCW'S * 00260000
*    AND THE IPL BOOTSTRAP.                                           * 00280000
*                                                                     * 00300000
*INPUT-     DIRECT ACCESS DEVICE CONTAINING IPL AND THE OPERATING     * 00320000
*    SYSTEM DATA SET.                                                 * 00340000
*           OPERATOR MAY STOP IPL PROGRAM ON AN ADDRESS COMPARE AND   * 00360000
*    THEN KEY IN A HEX CHARACTER TO CREATE A NON-STANDARD NUCLEUS NAME* 00380000
*           OPERATOR MAY STOP IPL PROGRAM ON AN ADDRESS COMPARE AND000B 00386014
*    THEN KEY IN A HEX CHARACTER TO LIMIT THE APPARENT MACHINE SIZE000B 00392014
*                                                                     * 00400000
*OUTPUT-  N/A    (NUCLEUS LOADED FROM DASD)                           * 00420000
*                                                                     * 00440000
*EXTERNAL ROUTINES-   N/A                                             * 00460000
*                                                                     * 00480000
*EXITS-NORMAL-    IPL BRANCHES TO THE NUCLEUS INITIALIZATION PROGRAM  * 00500000
*    (NIP) WHICH HAS BEEN LOADED BY IPL ALONG WITH THE REST OF THE    * 00520000
*    NUCLEUS CONTROL SECTIONS.  THE FINAL INITIALIZATION OF THE       * 00540000
*    SPECIFIC NUCLEUS LOADED IS DONE BY THE NIP PROGRAM.              * 00560000
*                                                                     * 00580000
*EXITS  -ERROR-    ERROR CONDITIONS RESULT IN A WAIT PSW BEING LOADED * 00600000
*    WITH THE FOLLOWING ERROR CODES STORED IN THE ADDRESS FIELD OF THE* 00620000
*    PSW FOR DISPLAY IN THE CONSOLE LIGHTS-                           * 00640000
*  ERROR CODE-  1  (0001)    I/O IS NOT OPERATIONAL.                  * 00660000
*               2  (0010)    I/O OPERATION IS NOT INITIATED. CSW IS   * 00680000
*                            STORED BUT UNIT IS NOT BUSY.             * 00700000
*               3  (0011)    I/O OPERATION IS NOT INITIATED. CSW IS   * 00720000
*                            NOT STORED AND THE CHANNEL IS NOT BUSY.  * 00740000
*               4  (0100)    CHANNEL IS NOT BUSY AND CSW IS NOT STORED* 00760000
*               5  (0101)    UNIT CHECK CONDITION IS INDICATED.       * 00780000
*               6  (0110)    ANY OF THE FOLLOWING CONDITIONS -        * 00800000
*                              PROGRAM CHECK                          * 00820000
*                              CHANNEL DATA CHECK                     * 00840000
*                              CHANNEL CONTROL CHECK                  * 00860000
*                              CHANNEL CHAINING CHECK                 * 00880000
*                              INTERFACE CONTROL CHECK                * 00900000
*              18  (00011000) AVAILABLE SPACE FOR RLD RCDS HAS BEEN000B 00920014
*                            EXCEEDED.                                * 00940000
*              19  (00011001) UNEXPECTED PGM CHK INTERRUPT, IPL    000B 00960014
*                            CONTAMINATED.                            * 00980000
*                                                                     * 01000000
*TABLES/WORK AREA-   IPL READS THE TRANSLATION TABLE AND THE SCATTER  * 01020000
*    LIST DIRECTLY BEHIND THE END OF THE IPL PROGRAM.                 * 01040000
*          IPL THEN BUILDS 3 TABLES EACH EQUAL IN SIZE TO THE SIZE OF * 01060000
*    THE SCATTER LIST. THESE TABLES FOLLOW DIRECTLY AFTER THE SCATTER * 01080000
*    LIST AND ARE RESPECTIVELY THE SIZE TABLE, ADDRESS TABLE, AND THE * 01100000
*    RELOCATION FACTOR TABLE (RLF).  THESE TABLES ARE NECESSARY TO    * 01120000
*    RELOCATE THE ADDRESS CONSTANTS IN THE NUCLEUS IPL LOADS.         * 01140000
*          A 256 BYTE BUFFER (IEABUFER) IS INCLUDED WITHIN THE IPL    * 01160000
*    PROGRAM INTO WHICH THE CONTROL RECORDS ARE READ FROM THE SYSTEM  * 01180000
*    RESIDENCE DEVICE.                                                * 01200000
*                                                                     * 01220000
*ATTRIBUTES-   PRIVILEGED, DISABLED, READ ONLY.                       * 01240000
*                                                                     * 01260000
*********************************************************************** 01260320
         EJECT                                                          01260620
**                                                            ***       01260920
*   THE FOLLOWING ARE REG EQUATES USED BY THIS ROUTINE          *       01261220
**                                                            ***       01261520
R0       EQU   0                                                        01261820
R1       EQU   1                                                        01262120
R2       EQU   2                                                        01262420
R3       EQU   3                                                        01262720
R4       EQU   4                                                        01263020
R5       EQU   5                                                        01263320
R6       EQU   6                                                        01263620
R7       EQU   7                                                        01263920
R8       EQU   8                                                        01264220
R9       EQU   9                                                        01264520
RA       EQU   10                                                       01264820
RB       EQU   11                                                       01265120
RC       EQU   12                                                       01265420
RD       EQU   13                                                       01265720
RE       EQU   14                                                       01266020
RF       EQU   15                                                       01266320
***                                                           ***       01266620
*   THE FOLLOWING ARE LO CORE ABSOLUTE ADDRESS EQUATES          *       01266920
***                                                           ***       01267220
CAW      EQU   72                                                       01267520
CSW      EQU   64                                                       01267820
***                                                           ***       01268120
*   THE FOLLOWING ARE MISCELLANOUS EQUATES                      *       01268420
***                                                           ***       01268720
Q0       EQU   0                                                        01269020
Q1       EQU   1                                                        01269320
Q2       EQU   2                                                        01269620
Q3       EQU   3                                                        01269920
Q4       EQU   4                                                        01270220
Q5       EQU   5                                                        01270520
Q6       EQU   6                                                        01270820
Q7       EQU   7                                                        01271120
Q8       EQU   8                                                        01271420
Q12      EQU   12                                                       01271720
Q13      EQU   13                                                       01272020
Q16      EQU   16                                                       01272320
Q17      EQU   17                                                       01272620
Q18      EQU   18                                                       01272920
Q20      EQU   20                                                       01273220
Q24      EQU   24                                                       01273520
X40      EQU   X'40'                                                    01273820
ECFCNTOP EQU   X'10'               MASK FOR CCW COUNT OP CODE           01274120
ECFDTACK EQU   X'08'               MASKS DATA CHK BIT IN SENSE          01274420
ECFTIC   EQU   X'08'               RESETS TIC CCW COMMAND               01274720
CCWSKIP  EQU   X'10'               MASKS CCW SKIP BIT                   01275020
CCWDATCN EQU   X'80'               MASKS DATA CHN BIT IN CCW            01275320
SNSZEUSA EQU   X'35'               ZEUS-A SENSE BYTE ID                 01275620
SNSZEUSC EQU   X'34'               ZEUS-C SENSE BYTE ID                 01282621
INCR     EQU   256                                            BI A44954 01302621
ZERO     EQU   16                                             BI A44954 01304621
         EJECT                                                          01310621
*                                                                       01320000
*   LOW CORE IS CLEARED EXCEPT FOR IPL INITIAL PSW AND PC HANDLER.      01340000
*                                                                       01360000
         DC    X'00000000'             IPL PSW DISABLED,SUPV MODE       01380000
         DC    AL4(START)              LOC OF 1ST EXECUTABLE INSTRUCT   01400000
         DC 12X'0000000000000000'    ZERO LOWER CORE                    01420000
         DC X'00000000'    PC NEW PSW ONLY ONE USED BY IPL              01440000
         DC AL4(IEAINT)     PCI HANDLER FOR IPL PRELUDE                 01460000
         DC 2X'0000000000000000'   ZERO REST OF LOWER CORE              01480000
*   *********   IPL PRELUDE   *********                                 01500000
*                                                                     * 01520000
*  IPL PRELUDE CLEARS REGISTERS AND MAIN STORAGE, DETERMINES MACHINE    01540000
*  SIZE, SETS STORAGE KEYS TO SUPERVISOR'S KEY, AND DETERMINES NUCLEUS  01560000
*  LOADED.  ALL PC INTERRUPTS GO TO IEAINT TO THEN BRANCH RELATIVE TO   01580000
*  REGISTER 10 WHICH IS PRESET TO HANDLE THE NEXT EXPECTED PC INTERRUPT 01600000
*                                                                       01620000
START    BALR  15,0  FIRST EXEC INSTR IPL, WHERE MACH SHOULD BE STOPPED 01640000
         USING *,15                                                     01660000
IEASTAR1 LM    R0,RE,ZERO          CLEAR GP REGS              BI A44954 01680021
         LA 10,IEAPCRET               RETURN AFTER FIRST PC             01700000
************** NUCLEUS SELECTION, LIMITATION OF CORE SIZE *********000B 01720014
*                                                                       01740000
*   OPERATOR CAN SELECT AN ALTERNATE NUCLEUS TO BE LOADED BY IPL        01760000
*   1.  SET ADDR COMP SW TO STOP AT LOC 80 HEX WHICH IS FIRST           01780000
*  EXECUTABLE INSTRUCTION IN IPL PROGRAM, THEN START IPL.               01800000
*   2. WHEN MACHINE STOPS, OPERATOR STORES INTO LOC 8 A HEX CHARACTER   01820000
*  THAT WILL BE APPENDED TO THE STANDARD ROOT OF THE NUCLEUS NAME WHICH 01840000
*  IS ASSEMBLED IN IPL AT IEANUCY.                                      01860000
*   3.  ADDRESS COMPARE SWITCHES ARE RESET AND IPL PROGRAM STARTED .    01880000
*   4.  AFTER STOP THE CONTENTS OF LOC 8 ARE  MOVED TO IEANUC AND THEN  01900000
*  A COMPARE IS MADE TO SEE IF IEANUC IS STILL ZERO.  IF SO, THE        01920000
*  PREASSEMBLED NUCLEUS NAME IS USED, OTHERWISE , THE KEYED IN SUFFIX   01940000
*  IS ADDED TO IEANUCY AND THE IPL PROGRAM SEARCHES FOR A NUCLEUS WITH  01960000
*  THE NEW NAME.                                                        01980000
*                                                                  000B 01981014
*******************************************************************000B 01982014
*                                                                  000B 01983014
*   OPERATOR CAN LIMIT APPARENT MACHINE SIZE BY THE FOLLOWING      000B 01984014
*  PROCEDURE:                                                      000B 01985014
*   1.  SET ADDRESS COMP SW TO STOP AT LOC 80 HEX WHICH IS FIRST   000B 01986014
*  EXECUTABLE INSTRUCTION IN IPL PROGRAM. LOAD IPL PROGRAM.        000B 01987014
*   2.  WHEN MACHINE STOPS, OPERATOR STORES INTO LOC 9 A HEX CHAR- 000B 01988014
*  ACTER. THE ACCEPTABLE HEX CHARACTERS AND THE CORRESPONDING      9715 01989017
*  MACHINE SIZES ARE LISTED BELOW.                                 9715 01990017
*    X'A7' - 192K,X'A8' - 384K,                                    INSS 01990518
*    X'C6' - 64K, X'C7' - 128K, X'C8' - 256K, X'C9' - 512K,        000B 01991014
*    X'D0' - 768K, X'D1' - 1024K                                   9715 01992017
*   3.  ADDRESS COMPARE SWITCHES ARE RESET AND IPL PROGRAM         000B 01993014
*  RESTARTED.                                                      000B 01994014
*   4.  IPL WILL ZERO CORE ONLY UP TO THE SPECIFIED LIMIT. STORAGE 000B 01995014
*  ADDRESSES ABOVE THIS LIMIT ARE NOT RECOGNIZED BY THE OPERATING  000B 01996014
*  SYSTEM.                                                         000B 01997014
*                                                                       02000000
*******************************************************************000B 02010014
         MVC IEANUC(1),8                PICKUP CHAR IF ANY OPER KEYED   02020000
         CL 2,IEANUC    TEST IF STILL ZERO MEANING USE STANDR NUCLEUS   02040000
         BE IEAMAIN                   STANDARD NUCLEUS SELECTED         02060000
         MVC IEANUCY+7(1),IEANUC        CHANGE DATA MEMBER NAME NUCLEUS 02080000
IEAMAIN  CLI   9,X'00'          TEST FOR STORAGE LIMIT SET         000B 02082014
         BE    IEAMAINR                                            000B 02084014
         TM    9,X'A0'             TEST FOR INTERMEDIATE SIZE      INSS 02084818
         BNO   IEANHSZ1            NO, BRANCH W/ R9,= 0            INSS 02085618
         LA    9,512               YES, R9 = X'200' INCREMENT      INSS 02086418
IEANHSZ1 LA    9,1024(9)           R9 = X'400' + POSS. INCREMENT   INSS 02087218
         CLI   9,C'I'           TEST FOR CHARACTER ABOVE 'I'       000B 02088014
         BC    13,IEAFRST       NO USE NUMBER AS IS                000B 02090014
         LA    2,9              R 2 = INCREMENT 9                  000B 02092014
IEAFRST  NI    9,X'0F'                                             000B 02094014
         BC    7,IEANHSZ2          BRANCH IF LOC 9 IS NOT ZERO     9715 02095017
         LA    9,512(9)            R9 = X'600' (INTERMEDIATE SIZE) 9715 02096017
IEANHSZ2 IC 1,9                    R1 = CHARACTER FROM LOC 9       9715 02097017
         AR    1,2              ADD INCREMENT IF ANY               000B 02098014
         STC   1,IEASHIFT+3                                        000B 02100014
IEASHIFT SLL   9,0                                                 000B 02102014
         ST    9,IEAMAXC        SAVE LIMITED CORE SIZE             000B 02104014
         MVI   IEALCSMX+1,X'F0'    SET NO-OP TO BRANCH        BI A44954 02106021
IEAMAINR LD    R0,ZERO             CLEAR FP REGS              CI A44954 02108021
         LDR 2,0                        PCI IF MACHINE HAS NO FP REGS   02120000
         LDR 4,0                                                        02140000
         LDR 6,0                                                        02160000
IEAPCRET EQU   *                                              BI A44954 02210021
         LA    R8,INCR             INCREMENT FOR LOOP         BI A44954 02260021
         LA    RA,IEAMXLOC         RESET PC RETURN            BI A44954 02310021
         SR    R9,R8               BXLE COMPARAND             BI A44954 02360021
IEALCSMX NOP   IEAZRLP2            BRANCH IF CORE LIMIT SET   BI A44954 02410021
         L     R9,IEAMAXC          16 MEG                      @SM0016K 02460021
         BCTR  R9,0                LOOP MAXIMUM                @SM0016K 02510021
IEAZRLP2 MVC   IPLEND(INCR),0      VALIDATE                   BI A44954 02560021
         XC    IPLEND(INCR),IPLEND CLEAR                      BI A44954 02570021
         LA    R4,IPLEND+INCR      NEXT SEGMENT OF CORE       BI A44954 02572021
IEAZRLP3 MVC   0(INCR,R4),IPLEND   VALIDATE AND CLEAR         BI A44954 02574021
         BCR   8,0                 FORCE EXECUTION ON MOD 91  BI A44954 02576021
         BXLE  R4,R8,IEAZRLP3      UPDATE TO ADDRESS          BI A44954 02578021
IEAMXLOC ST    R4,IEAMAXC          SAVE MACHINE SIZE          BI A44954 02578421
         XR    R2,R2                                          BI A44954 02578821
         LA 10,IEAPCKEY               LOAD FOR PC ON STORAGE KEY        02580000
         LA 3,0                       SUPERVISOR KEY OF ZERO            02600000
         LA 4,2048                    STORAGE BLOCK NUMBER (1 IN BIT 20 02620000
IEAKYLP  SSK 3,2                      SET STORAGE KEY                   02640000
         AR 2,4                                                         02660000
         CL    R2,IEA16MEG         16 MEG MAXIMUM              @SM0016K 02680021
         BL    IEAKYLP             NO,BRANCH                   @SM0016K 02690021
IEAINT   BR 10                        RETURN FROM PC INTERRUPT          02700000
******************* NUCLEUS LOCATION ROUTINE ************************** 02720000
*                                                                     * 02740000
*  LOCATES THE NUCLEUS ON THE SYSTEM RESIDENCE DEVICE BY READING THE    02760000
* STANDARD VOLUME LABEL TO FIND THE VTOC AND THEN SEARCHING THRU THE    02780000
* VTOC DSCB'S UNTIL IT FINDS THE ONE REFERING TO THE NAME OF THE        02800000
* NUCLEUS. THE PODS DIRECTORY IS THEN READ AND THE NUCLEUS WITH THE     02820000
* DESIRED NAME IS SEARCHED FOR. WHEN FOUND, THE FIRST RECORD IS THE     02840000
* TRANSLATION TABLE AND SCATTER LIST AND THIS IS READ BEHIND THE IPL    02860000
* PROGRAM.  THE SIZE OF THE RECORD MAY EXCEED 1020 BYTES IN WHICH CASE, 02880000
* MORE THAN ONE READ MUST BE ISSUED.                                    02900000
*                                                                     * 02920000
IEAPCKEY MVC 108(4),IEAPCFP       UNEXPECTED PC INTERRUPT SIMPLY FIXED  02940000
         LH 10,2               SYS RES ADDR STORED BY IPL HARDWARE      02960000
*CLEAR PENDING IO CONDITIONS                                            02980000
IEAIOTST TIO   0(10)                    TEST IO                         03000000
         BC    1,IEAERR1                IO NOT OPERATIONAL,ERROR1       03020000
         BC    2,IEAIOTST               CHANNEL BUSY, TEST IO           03040000
*READ STD VOLUME LABEL                                                  03060000
         MVC   IEASKADR(6),IEAOTRCK     SEEK ADDR=ZERO CYL,ZERO TRACK   03080000
         MVC   IEASRADR(5),IEAREC3      SRCH ADDR=RECORD3 OF ZERO TRACK 03100000
         MVC   72(4),IEALBLST           MOVE CHNL PROG ADDR INTO CAW    03120000
         BAL   5,IEASTRIO               READ STD VOL LABEL INTO BUFFER  03140000
*READ VTOC DSCB DATA                                                    03160000
         MVC   IEASKADR+2(4),IEABUFER+11  CCHH OF VTOC  INTO SEEK ADDR  03180000
         MVC   IEASRADR(5),IEABUFER+11    CCHHR OF VTOC INTO SRCH ADDR  03200000
         MVC   72(4),IEAVTLST           MOVE CHNL PROG ADDR INTO CAW    03220000
         BAL   5,IEASTRIO               READ VTOC DSCB DATA INTO BUFFER 03240000
         TM    IEABUFER+27,X'04'        TEST FOR 2301 DEV TYPE          03260000
         BC    8,IETRAKER               NOT 2301 - GET TRPCYL           03280000
         MVI   IEADRUM,X'FF'            INDICATE 2301                   03300000
IETRAKER MVC   IEATRPCL(2),IEABUFER+20  SAVE TRKS PER CYL               03320000
         MVI   IEASRADR+4,X'01'         SEARCH FOR REC ONE OF VTOC      03340000
*READ NUCLEUS POD SET DSCB DATA                                         03360000
         MVC   72(4),IEADSLST           MOVE CHNL PROG ADDR INTO CAW    03380000
         BAL   5,IEASTRIO               READ NUCL POD SET DSCB DATA     03400000
*READ NUCLEUS PO DIRECTORY                                              03420000
         MVC   IEANUCDS(4),IEABUFER+63  SAVE CCHH OF NUCL POD SET       03440000
         MVC   IEASKADR+2(4),IEABUFER+63  CCHH OF NUCL POD INTO SEEKADR 03460000
         MVC   IEASRADR(4),IEABUFER+63  CCHH OF NUC INTO SEEKADR        03480000
         MVI   IEASRADR+4,X'01'         RECORD ONE                      03500000
         MVC   72(4),IEAPDLST           MOVE CHNL PROG ADDR INTO CAW    03520000
         BAL   5,IEASTRIO               READ NUCL POD REC INTO BUFFER   03540000
*SEARCH NUCLEUS ADDRESS WITHIN PO DIRECTORY                             03560000
         LA    13,IEABUFER+2            COUNT REG 13=ADDR OF BUFFER+2   03580000
IEACOMPR CLC   0(8,13),IEANUCY          NAM FLD IN BUFFER=IEANUCY       03600000
         BC    8,IEAPROCD               YES,PROCEED                     03620000
         LA    13,11(13)                SET COUNT REG13=COUNT+11        03640000
         IC    8,0(13)                  REG8=HALFWORD COUNT             03660000
         LA    9,X'1F'                  REG9= MASK BITS                 03680000
         NR    9,8                      MASK OFF FIRST 3 BITS IN REG8   03700000
         AR    9,9                      REG 9=SIZE OF VAR FLD IN BYTES  03720000
         LA    13,1(13)                 COUNT REG13=COUNT+1             03740000
         AR    13,9                     COUNT REG=COUNT+V=NEXT NAM FLD  03760000
         B     IEACOMPR                 CONTINUE COMPARING NAM FLD      03780000
*READ TRANSLATION TABLE AND SCATTER LIST BEHIND IPL PROGRAM             03800000
IEAPROCD LH    7,16(13)                 REG7=TT OF TRANSL TABLE RECORD  03820000
*CONVERT TT ADDRESS INTO CCHH ADDRESS                                   03840000
         LA 11,IEARET1                                                  03860000
IEACOMLP TM    IEADRUM,X'FF'            TEST FOR 2301 DEVICE            03880000
         BC    1,IEADRMR                YES DO NOT CONVERT TRPCYL       03900000
         LH    6,IEATRPCL               NO GET TRKS PER CYL             03920000
         LH    9,IEANUCDS+2                                             03940000
         AR    9,7                      REG9=HH OF POD SET+TT OF TRTAB  03960000
         SR    8,8                      CLEAR REG 8                     03980000
         DR    8,6                      REG8=HH OF TRTAB, REG9=CC       04000000
         LH    7,IEANUCDS               REG7=CC OF POD SET              04020000
         AR    7,9                      REG7=CC OF TRTAB                04040000
*CONSTRUCT CCW FOR READING TRANSLATION TABLE AND SCATTER LIST           04060000
         STH   7,IEASKADR+2             STORE CC OF TRTAB INTO SEEKADDR 04080000
         STH   8,IEASKADR+4             STORE HH OF TRTAB INTO SEEKADDR 04100000
         B     IEAIEARD                 BRANCH AROUND DRUM CODE         04120000
IEADRMR  LH    9,IEANUCDS+2             GET TTR OF NUCLEUS              04140000
         AR    9,7                      ADD REL TTR TO ABSL TTR         04160000
         SR    8,8                      CLEAR REG 8                     04180000
         STH   8,IEASKADR+2             SET CC TO ZERO                  04200000
         STH   9,IEASKADR+4             SET SEEK HH                     04220000
         MVC   IEATRPCL(2),IEADRMLM     SET TRPCYL TO 200               04240000
IEAIEARD MVC   IEASRADR(4),IEASKADR+2   SET SEARCH CC HH                04260000
         BR 11                   RETURN FROM COMMON ROUTINE             04280000
IEADRUM  DC    X'00'                                                    04300000
IEADRMLM DC    X'00C8'                                                  04320000
IEARET1  MVC   IEASRADR+4(1),18(13)                                     04340000
         MVC   IEATRTSZ(2),35(13)       STORE TRTAB SIZE AT IEATRTSZ    04360000
         LH 7,IEATRTSZ                  SIZE OF TRANSLATION TABLE       04380000
         MVC IEASCLSZ(2),33(13)         SCATTER LIST SIZE               04400000
         LH 8,IEASCLSZ                  LOAD REG 8 WITH SC LIST SIZE    04420000
         TM    21(13),X'40'             USE TEXT ORIGIN       BI A43037 04426021
         BO    IEANOR                   NO, BRANCH            BI A43037 04432021
         MVC IEATXTOR+1(3),30(13)       ORIGIN OF FIRST TXT REC         04440000
IEANOR   EQU   *                                              BI A43037 04450021
         MVC IEAESDID(2),37(13)         ESDID OF FIRST TXT REC          04460000
         MVC IEARLD1+1(3),22(13)        NUMBER OF CONTIG BYTES IN NUC   04480000
         LR 2,7                                                         04500000
         AR 2,8                         TT + SC LIST SIZE               04520000
         SLL 8,2                        FOUR TIMES SC LIST SIZE         04540000
         AR 7,8                         TT + SC LIST+ 3 TABLES          04560000
         ST 7,IEATSLSZ                  SAVE TT + 4 X SC LIST SIZE      04580000
         LA 5,1020                      MAX RECORD SIZE                 04620000
         CR 2,5                                                         04640000
         BH IEAUGH                      TT + SC GREATER THAN 1 REC 1020 04660000
         LA 2,4(2)                      INCLUDE 4 BYTE HEADER REC       04680000
         STH 2,IEATRTRD+6               STORE COUNT TO READ IN CW       04700000
         B IEATXT1                      GO TO READ TT IN ONE REC        04720000
IEAUGH   LA 6,IEAIPLND                  TOP OF IPL                      04740000
         LR 7,2                         ACTUAL COUNT TT + SC            04760000
         AR 2,6                         IPL + TT+ SC ADDRESS            04780000
         SR 6,6                                                         04800000
         DR 6,5                         7 HAS 1020 COUNT, 6 HAS REMAIND 04820000
         LA 8,1024                                                      04840000
         MVI IEATRTRD+4,X'60'           SILI AND CHAIN ON               04860000
IEARDAGN SR 2,8                         LOC FOR NEXT REC READ           04880000
         STH   2,R2COUNT           SAVE COUNT                           04890019
         STH 2,IEATRTRD+2               TARGET ADDRESS IN CW            04900000
         MVC   72(4),IEATRLST      RESET CAW AFTR POSSIB SENSE          04902019
*                                                                  0542 04904018
***  THE FOLLOWING THREE INSTRUCTIONS MUST REMAIN CONTIGUOUS       0542 04908018
*                                                                  0542 04912018
         OI    IEARREC1,X'02'    INDICATE MULTI-TRACKING REQ            04916018
         BAL 5,IEASTRIO                                                 04920000
         MVC IEASRADR(5),IEAST          NEW RECORD ID                   04940000
         SPACE 2                                                        04950018
         LH    2,R2COUNT           REST COUNT AFTR POS SENSE            04955019
         LA 8,1020                                                      04960000
         BCT  7,IEARDAGN                MORE BLOCKS OF 1020             04980000
         CR 7,6                         CHECK IF ANY RESIDUE            05000000
         BE IEATXTR1                    ALL RECORDS READ                05020000
         LA 3,IEATRTBH                                                  05040000
         STH 3,IEATRTRD+2               READ LAST RECORD                05060000
         LA 6,4(6)                                                      05080000
         STH 6,IEATRTRD+6               STORE REMAINDER AS CCW COUNT    05100000
         MVI IEATRTRD+4,X'20'           TURN OFF CHAIN BIT              05110000
IEATXT1  MVC 72(4),IEATRLST             SET CHAN PROG ADDR     PTM731   05120020
         BAL 5,IEASTRIO                 READ TRTAB BEHIND IPL  PTM731   05140020
IEATXTR1 LH 7,12(13)                    TT OF FIRST TXT REC             05160000
*CONVERT TT ADDRESS INTO CCHH ADDRESS                                   05180000
         BAL 11,IEACOMLP         ENTER COMMON ROUTINE FOR CCHH TEXT RC  05200000
*CONSTRUCT CCW FOR READING FIRST TEXT RECORD                            05220000
         MVC   IEASRADR+4(1),14(13)     STORE R  OF TXTRC INTO SRCHADDR 05240000
         MVC IEATXTRD+6(2),25(13)       MOVE TXT REC SIZE INTO CCW      05260000
         SPACE 1                                                        05280000
*************** CONTROL SECTION DATA ORGANISATION ROUTINE ************* 05300000
*                                                                     * 05320000
* ARRANGES THE OUT OF ORDER CONTROL SECTIONS BY RELATING THE REFERENCES 05340000
* IN THE TRANSLATION TABLE (ESDID) TO THE ENTRIES IN THE SCATTER LIST   05360000
* (ASSEMBLED ORIGIN).  THREE CONTROL TABLES ARE BUILT TO AIDE IN        05380000
* OBTAINING THE PROPER RELOCATION CONSTANTS AND LOAD ADDRESS.           05400000
*   CONTROL SECTION WITH ESDID OF 1 IS ASSUMED TO BE NIP AND THE FIRST  05420000
*  NUCLEUS CONTROL SECTION IS LOADED AT 0.                              05440000
*          1. SIZE OF EACH CONTROL SECTION                   -SIZTABLE* 05460000
*          2. ADDRESS AT WHICH EACH CONTROL SECTION IS LOADED-ADRTABLE* 05480000
*          3. RELOCATION FACTOR FOR EACH CONTROL SECTION     -RLFTABLE* 05500000
*                                                                     * 05520000
         L 12,IEATRTAB                  TRANSLATION TABLE ADDRESS       05540000
         LR 1,12                                                        05560000
         LH 13,IEATRTSZ                 SIZE OF TRANSLATION TABLE       05580000
         AR 12,13                       TT ADR + SIZE GIVES SC LIST ADR 05600000
         ST 12,IEASCATL                 SCATTER LIST ADDRESS            05620000
         LR 2,12                        REG 2 HAS START OF SCATTR LIST  05640000
         LH 13,IEASCLSZ                 SCATTER LIST SIZE               05660000
         AR 12,13                                                       05680000
         ST 12,IEASIZTB                 SIZE TABLE ADDR                 05700000
         AR 12,13                                                       05720000
         ST 12,IEAADRTB                 ADDRESS TABLE LOC.              05740000
         AR 12,13                                                       05760000
         ST 12,IEARLFTB                 RELOCATION CONSTANT TABLE ADDR. 05780000
         AR 12,13                                                       05800000
         ST 12,IEAIPLTP                 TOP OF IPL TABLES (RLF LAST 1)  05820000
         L 4,IEASIZTB                   REG 4 HAS START OF SIZE TABLE   05840000
         SRL 13,2                       DIVIDE SC LST BY 4 FOR CS COUNT 05860000
         BCTR 13,0                      FIRST SC LST ENTRY DUMMY OF 0   05880000
         ST 13,IEACSCNT                 STORE TOTAL NUMBER OF CS        05900000
IEAHOOP  LA 2,4(2)                      SCATTER LIST POINTER            05920000
         LA 4,4(4)                      SIZE TABLE POINTER              05940000
         L 11,0(2)                      OBTAIN CS ADDRESS FROM SCATTER  05960000
         L 12,4(2)                      ADDRESS ABOVE IN SCATTER LIST   05980000
         SR 12,11                       SUBTRACT ORIGIN OF PREVIOUS ONE 06000000
         ST 12,0(4)                     STORE CS SIZE IN SIZE TABLE     06020000
         BCT 13,IEAHOOP                 TEST IF ALL CS PROCESSED        06040000
         L     12,IEARLD1                                               06060000
         LA    13,7                                                     06080000
         AR    12,13                                                    06100000
         OR    12,13                                                    06120000
         XR    12,13                                                    06140000
         SR    12,11                                                    06160000
           ST    12,0(4)                                                06180000
         L 1,IEAADRTB                                                   06200000
         L 13,IEACSCNT                  CONTROL SECTION COUNT           06220000
         SLL 13,1                       DOUBLE SIZE FOR RLF TABLE TOO   06240000
         LA 13,1(13)                    ALLOW FOR DUMMY RLF ENTRY       06260000
IEAAGN   LA 1,4(1)                      SKIP FIRST ENTRY IN SC LIST     06280000
         MVI 0(1),X'70'                 FLAG AS ADDR NOT STORED SLOT    06300000
         BCT 13,IEAAGN                  SET REST OF TABLE AS NOT STORED 06320000
         L  1,IEATRTAB                  TRANSLATION TABLE ADDRESS       06340000
         L  4,IEASIZTB                                                  06360000
         L  5,IEAADRTB                  YES- BUILD ADDRESS TABLE        06380000
         L 7,IEARLD1                    TOP OF NUCLEUS                  06400000
         LH 13,IEATRTSZ                 TRANSLATION TABLE SIZE          06420000
         SRL 13,1                       DIVIDE BY 2                     06440000
         BCTR 13,0                      SKIP DUMMY FIRST ENTRY          06460000
         LA 1,2(1)                      POINT TO NEXT TT ENTRY          06480000
         LH 9,0(1)                      GET NEXT TT ENTRY               06500000
         SLL 9,2                        MULT BY 4 TO REFERENCE TABLE    06520000
         L 3,0(9,4)                     GET SIZE OF ENTRY               06540000
         SR    7,3                      SIZE NUC MINUS SIZE NIP         06560000
         LA    6,7                      R6 = 7                          06580000
         AR    7,6                      ROUND LOWEST ADDR NOT IN        06600000
         OR    7,6                      THE NUCLEUS TO A DOUBLE         06620000
         XR    7,6                      WORD BOUNDARY                   06640000
         ST    7,0(4)                   SAVE THIS ADDR IN THE TABLE     06660000
         ST    7,IEANUCND               SAVE THIS ADDR FOR NIP          06680000
         ST    7,IEARLD1                SAVE THIS ADDR FOR RLD WORK     06700000
         LA    6,IEARELSZ               R6 = SIZE OF IPL'S LISTS        06720000
         A     6,IEATSLSZ          ADD THE SIZE OF LISTS                06740000
         L     8,IEAMAXC           R 8 HAS SIZE OF CORE                 06760000
         C     8,IEA256K               TEST FOR CORE LESS THAN 256KMP65 06768017
         BL    IEATOPCR                YES, USE CORE SIZE FOR RELOCMP65 06776017
         BH    IEAC512K            GREATER THAN 256K-CHECK 512K  A26272 06778021
         L     R8,IEA252K          EQ. TO 256K LOAD NIP AT 252K  A26272 06780021
         B     IEATOPCR            GO TO CONTINUE LOADING        A26272 06782021
IEAC512K C     R8,IEA512K          IS CORE 512K OR MORE          A26272 06784021
         BL    IEATOPCR            NO,GO USE THE MAX CORE SIZE   A26272 06786021
         L     R8,IEA508K          YES, USE 508K AS THE MAX CORE A26272 06788021
IEATOPCR SR    8,6                     R 8 HAS DESTINATION OF IPL  MP65 06792017
         SRL   8,3                 ROUND THE ADDR DOWN TO A DBL WORD    06800000
         SLL   8,3                 THIS ADDR WILL BE USED TO MOVE IPL   06820000
         ST    8,IEAIPLOC          SAVE THIS ADDR FOR LATER             06840000
         SR    8,3                 DECREASE ADDR BY THE SIZE OF NIP     06860000
         SRL   8,3                 ROUND THIS ADDR DOWN                 06880000
         SLL   8,3                 TO A DBL WORD BOUNDARY ALSO          06900000
         ST    8,0(9,5)            SET THIS ADDR OF NIP IN THE TABLE    06920000
         SR    8,7                 R 8 HAS SIZE OF FREE CORE            06940000
         ST    8,IEASZRL1          SAVE ADDR FOR LATER                  06960000
         BCTR 13,0                      ALREADY PROCESSED 1 CS (NIP)    06980000
         SR 7,7                         SECOND CS LOADED AT 0           07000000
         LA 1,2(1)                                                      07020000
         LH 9,0(1)                                                      07040000
         SLL 9,2                        MULT BY 4 TO REFERENCE TABLE    07060000
         ST 7,0(9,5)                    STORE ZERO ENTRY FOR CS1        07080000
         LA 8,2                         PROCESSED 2 CSECTS NIP AND CS1  07100000
IEASTOL1 L 3,0(9,4)                     SIZE LAST ENTRY PROCESSED       07120000
         AR 7,3                         PLACE FOR NEXT ENTRY            07140000
         C 8,IEACSCNT                                                   07160000
         BE IEAGOON                     ALL CSECTS PROCESSED            07180000
IEADEC   BCT 13,IEAUP1                                                  07200000
         B IEAGOON                                                      07220000
IEAUP1   LA 1,2(1)                      NEXT TT ENTRY                   07240000
         LH 9,0(1)                                                      07260000
         SLL 9,2                        MULT BY 4 TO REFERENCE TABLE    07280000
         LH 2,0(9,5)                    PICK UP FLAG FROM ADDRESS TABLE 07300000
         SRL 2,8                        CLEAR ANY ADDRESS BITS          07320000
         SLL 2,8                                                        07340000
         CH 2,IEAFLAG                   TEST IF ADDRESS STORED          07360000
         BC 4,IEADEC                    YES SKIP THIS TT ENTRY          07380000
         ST 7,0(9,5)                    NO STORE ADDRESS FOR THIS ENTRY 07400000
         LA 8,1(8)                      ADD 1 TO TOTAL CSECTS PROCESSED 07420000
         B IEASTOL1                                                     07440000
*                                                                       07460000
*   ADDRESS TABLE COMPLETELY BUILT, NOW BUILD RLF TABLE                 07480000
*                                                                       07500000
IEAGOON  ST 7,IEATPNUC                  TOP OF LAST CS LOADED           07520000
         L  1,IEATRTAB                  TRANSLATION TABLE ADDRESS       07540000
         L 3,IEARLFTB                                                   07560000
         MVI 0(3),X'00'                 DO NOT FLAG FIRST RLF ENTRY     07580000
         L 4,IEASCATL                   ADDRESS OF SCATTER LIST         07600000
         L 5,IEAADRTB                   YES- BUILD RELOC FACTOR TABLE   07620000
         SR 8,8                                                         07640000
         LH 13,IEATRTSZ                 NUMBER OF ENTRIES IN TT         07660000
         SRL 13,1                       DIVIDE BY 2                     07680000
         BCTR 13,0                      SKIP DUMMY FIRST ENTRY          07700000
IEACOOP  LA 1,2(1)                                                      07720000
         LH 9,0(1)                      FIRST ENTRY                     07740000
         SLL 9,2                        MULT BY 4 TO REFERENCE TABLE    07760000
         LH 2,0(9,3)                    PICK UP RLF TABLE FLAG          07780000
         SRL 2,8                                                        07800000
         SLL 2,8                        CLEAR ANY ADDRESS BITS          07820000
         CH 2,IEAFLAG                   TEST IF RLF STORED FOR THIS CS  07840000
         BC 4,IEADOWN                   YES                             07860000
         L 7,0(9,5)                     PICK CORRESP ADDR FROM ADDR TAB 07880000
         L     11,0(9,4)           ORIGIN FROM SCATTER LIST       P4082 07900019
         SR    7,11                RELOC FACTOR LOAD-ASSEM ADDR   P4082 07920019
         ST 7,0(9,3)                    STORE IN RLF TABLE              07940000
         LA 8,1(8)                      UP CSECT COUNT                  07960000
         C 8,IEACSCNT                   ALL CSECTS PROCESSED            07980000
         BE IEAADDRS                    YES ADDRESS AND RLF TABLES DONE 08000000
IEADOWN  BCT 13,IEACOOP                 GO ON TO NEXT TT ENTRY          08020000
         B IEAADDRS                     GO TO RELOCATE IPL              08040000
*                                                                       08060000
*CONSTANTS- NUCLEUS LOCATION ROUTINE                                    08080000
IEALBLST DC    A(IEALBLSK)            LOCATE-READ STANDARD VOLUME LABEL 08100000
IEAVTLST DC    A(IEAVTCSK)            LOCATE-READ VTOC CCW CHAIN        08120000
IEADSLST DC    A(IEADSTSK)            LOCATE-READ DATA SET DSCB CCW CHN 08140000
IEAPDLST DC    A(IEAPODSK)            LOCATE-READ PODS CCW CHAIN        08160000
         DS    0D                                                       08180000
IEALBLSK DC    X'07'                    CONTROL SEEK REC 3, CYL 0, TR 0 08200000
         DC    AL3(IEASKADR)            DATA ADDRESS                    08220000
         DC    X'4000'                  CC ON,SILI OFF                  08240000
         DC    X'0006'                  6 BYTE COUNT                    08260000
IEALBLSR DC    X'31'                    SEARCH EQUAL ID STNDR VOL LABEL 08280000
         DC    AL3(IEASRADR)            D A                             08300000
         DC    X'4000'                  CC ON,SILI OFF                  08320000
         DC    X'0005'                  5 BYTE COUNT                    08340000
         DC    X'08'                    TIC                             08360000
         DC    AL3(IEALBLSR)            DATA ADDR                       08380000
         DC    X'00000000'              NO FLAG OR COUNT FOR TIC        08400000
         DC    X'06'                    READ DATA STANDARD VOLUME LABEL 08420000
         DC    AL3(IEABUFER)            INTO BUFER                      08440000
         DC    X'2000'                  CC OFF,SILI ON                  08460000
         DC    XL2'50'                  80 BYTE COUNT                   08480000
IEAVTCSK DC    X'07'                    CONTROL SEEK                    08500000
         DC    AL3(IEASKADR)            D A                             08520000
         DC    X'4000'                  CC ON, SILI OFF                 08540000
         DC    X'0006'                  6 BYTE COUNT                    08560000
IEAVTCSR DC    X'31'                    SEARCH EQUAL ID  VTOC           08580000
         DC    AL3(IEASRADR)            D A                             08600000
         DC    X'4000'                  CC ON, SILI OFF                 08620000
         DC    X'0005'                  5 BYTE COUNT                    08640000
         DC    X'08'                    TIC                             08660000
         DC    AL3(IEAVTCSR)            D A                             08680000
         DC    X'00000000'              NO FLAG OR COUNT FOR TIC        08700000
         DC    X'06'                    READ DATA  VTOC                 08720000
         DC    AL3(IEABUFER)            INTO BUFER                      08740000
         DC    X'2000'                  CC OFF. SILI ON                 08760000
         DC    XL2'60'                  96 BYTE COUNT                   08780000
IEADSTSK DC    X'07'                    CONTROL SEEK                    08800000
         DC    AL3(IEASKADR)            D A                             08820000
         DC    X'4000'                  CC ON,SILI OFF                  08840000
         DC    X'0006'                  6 BYTE COUNT                    08860000
IEASYNC  DC  X'31'                 *SEARCH FOR RECORD ONE               08880000
         DC    AL3(IEASRADR)                                            08900000
         DC    X'4000'                                                  08920000
         DC    X'0005'                                                  08940000
         DC    X'08'                                                    08960000
         DC    AL3(IEASYNC)                                             08980000
         DC    X'00000000'                                              09000000
IEADSTSR DC    X'A9'                                                    09020000
         DC    AL3(IEADSNAM)            D A                             09040000
         DC    X'6000'                  CC ON. SILI ON                  09060000
         DC    X'002C'                  44 BYTE KEY                     09080000
         DC    X'08'                    TIC                             09100000
         DC    AL3(IEADSTSR)            D A                             09120000
         DC    X'00000000'              NO FLAG OR COUNT FOR TIC        09140000
         DC    X'06'                    READ DATA  DATA SET DSCB        09160000
         DC    AL3(IEABUFER)            INTO BUFER                      09180000
         DC    X'2000'                  CC OFF, SILI ON                 09200000
         DC    XL2'60'                  96 BYTE COUNT                   09220000
IEAPODSK DC    X'07'                    CONTROL SEEK                    09240000
         DC    AL3(IEASKADR)            D A                             09260000
         DC    X'4000'                  CC ON, SILI OFF                 09280000
         DC    X'0006'                  6 BYTE COUNT                    09300000
IEAPODSR DC    X'31'                    SEARCH EQUAL ID. PODS DIRECTORY 09320000
         DC    AL3(IEASRADR)                                            09340000
         DC    X'4000'                  CC ON,SILI OFF                  09360000
         DC    X'0005'                  5 BYTE COUNT                    09380000
         DC    X'08'                    TIC                             09400000
         DC    AL3(IEAPODSR)            D A                             09420000
         DC    X'00000000'              NO FLAG OR COUNT FOR TIC        09440000
IEARECSR DC    X'69'                    SEARCH HI EQUAL KEY PODS        09460000
         DC    AL3(IEANUCY)             D A                             09480000
         DC    X'6000'                  CC ON SILI OON                  09500000
         DC    X'0008'                  8 BYTE KEY                      09520000
         DC    X'08'                    TIC                             09540000
         DC    AL3(IEARECSR)            D A                             09560000
         DC    X'00000000'              NO FLAG OR COUNT FOR TIC        09580000
         DC    X'06'                    READ DATA PODS                  09600000
         DC    AL3(IEABUFER)            INTO BUFER                      09620000
         DC    X'2000'                  CC OFF SILI ON                  09640000
         DC    X'0100'                  256 BYTE COUNT                  09660000
         DS 0D                                                          09680000
IEADSNAM DC CL22'SYS1.NUCLEUS'          DATA SET NAME VTOC DSCB KEY     09700000
         DC CL22' '                                                     09720000
         DS 0D                                                          09740000
IEAOTRCK DC    X'000000000000'          ZERO CYL, ZERO TRACK            09760000
         DS 0D                                                          09780000
IEAREC3  DC    X'0000000003'            REC3 ON ZERO CYL,ZERO TRACK     09800000
         DS    0D                                                       09806019
R2COUNT  DS    1F                                                       09812019
         DS 0D                                                          09820000
IEANUCDS DS    F                        4 BYTE AREA TO STORE CCHH OF DS 09860000
*  ******  IPL INITIALIZATION PROGRAM RELOCATION ROUTINE  ******        09880000
*    MOVES PART OF THE IPL PROGRAM TO UPPER CORE AND ADDS A RELOCATION  09900000
*    CONSTANT TO ADDRESS CONSTANTS. AFTER RELOCATION, THE IPL      MP65 09910017
*    PROGRAM WILL END AT 252K OR AT THE ACTUAL TOP OF CORE IF THE  MP65 09920017
*    MACHINE SIZE IS LESS THAN 256K.                               MP65 09930017
*                                                                       09940000
IEAADDRS LA 11,4                 ADDRESS CONSTANTS OF 4 BYTES EACH      09960000
         LA 3,IEACNTSZ                SIZE OF CONSTANT TABLE            09980000
         LA 5,IEALOAD            START OF RELOCATABLE IPL CODE          10000000
         LA 6,IEACONST                RETURN FROM GENERAL ROUTINE       10020000
         LA 7,IEARELSZ                SIZE OF IPL TO BE RELOCATED       10040000
         A 7,IEATSLSZ             ADD SIZE OF TT AND SCATTER LIST       10060000
         L     9,IEAIPLOC          R 9 HAS ADDR  OF HI CORE FOR IPL     10100000
         LA 14,IEASNCAW               START OF CONSTANT TABLE           10120000
IEARLOC  L 4,0(14)                    CONSTANT TO BE RELOCATED          10140000
         SR 4,5                  RELOC RELATIVE TO START OF RELOC       10160000
         AR 4,9                                                         10180000
         ST 4,0(14)              STORE BACK UPDATED ADDRESS CONSTANT    10200000
         AR 14,11                     INCREMENT THRU TABLE BY 4 OR 8    10220000
         SR 3,11                      DECREMENT COUNT                   10240000
         CL 3,IEAZERO                                                   10260000
         BC 2,IEARLOC                                                   10280000
         BR 6                         END OF RELOCATE CONST. ROUTINE    10300000
IEACONST LA 3,IEACCWSZ                SIZE OF CCW TABLE                 10320000
         LA 11,8                                                        10340000
         LA 14,IEACCWST               START OF CCW RELOC. TABLE         10360000
         BAL 6,IEARLOC                                                  10380000
         LR    4,9              R 4 = PNTR TO RELOCATED IPL CODE   000B 10390014
         LR    2,9              R 2 = PNTR TO RELOCATED IPL CODE   000B 10400014
         LA    3,256            R 3 = X'100'                       000B 10410014
         LA    6,255            R 6 = X'FF' FOR 256 MOVE           000B 10420014
IEAINTST CR    7,3              TEST FOR LESS THAN 256 BYTES       000B 10430014
         BC    11,IEAMVBLD      EQUAL OR MORE THAN 256             000B 10440014
         LTR   7,7              TEST FOR ALL MOVED                 000B 10450014
         BC    8,IEAEVEN        YES STOP MOVE                      000B 10460014
         BCTR  7,0              DECREMENT PARTIAL BLOCK FOR MOVE   000B 10470014
         LR    6,7              R 6 = LAST PORTION TO MOVE         000B 10480014
         MVI   IEAEVENR+1,X'F0' SET NOP TO BRANCH NEXT TIME        000B 10490014
IEAMVBLD EX    6,FRMTOIEA       MOVE IPL CODE                      000B 10500014
IEAEVENR BC    0,IEAEVEN        NOP UNTIL LAST PORTION             000B 10510014
         AR    5,3              INCREMENT FROM PNTR BY 256         000B 10520014
         AR    2,3              INCREMENT TO PNTR BY 256           000B 10530014
         SR    7,3              DECREMENT LEFT TO MOVE COUNT BY 256000B 10540014
         B     IEAINTST         MOVE IPL CODE                      000B 10550014
FRMTOIEA MVC   0(0,2),0(5)                                         000B 10560014
IEAEVEN  EQU   *                                                   000B 10570014
         LA 5,IEASTARL           AREA BELOW RELOC. IPL CODE             10620000
         SR 9,5                  RELOCATION CONSTANT FOR IPL            10640000
         LR 15,9                 LOAD BASE REG FOR NEW IPL LOC          10660000
         BR 4                    ENTER RELOCATED IPL (IEALOAD RELOCTD)  10680000
********************** NUCLEUS LOAD ROUTINE *************************** 10700000
*                                                                     * 10720000
*SCATTER LOADS THE NUCLEUS INTO MAIN STORAGE. BUILDS A TABLE OF RLD   * 10740000
*ITEMS IN MAIN STORAGE AT THE TOP OF THE NUCLEUS.                     * 10760000
*   CODE FROM HERE TO TOP OF IPL + TRANSLATION TABLE AND SCATTER LIST * 10780000
*  SIZE TABLE, ADDRESS TABLE AND RLF TABLE IS RELOCATED TO THE TOP OF * 10800000
*  CORE TO PREVENT IPL BEING OVERLAID BY THE NUCLEUS.                 * 10820000
*                                                                     * 10840000
         DS 0D                                                          10860000
IEALOAD  L     3,IEARLFTB               REG3= RLFTABLE ADDR             10880000
         SR 6,6                                                         10900000
         L 7,IEAIPLTP                   TOP OF IPL TABLES BEFORE RELOC  10920000
         LA 9,128                                                       10940000
         SR 7,9                                                         10960000
         LA 5,256                                                       10980000
         DR 6,5                         BLOCKS OF 256 TO CLEAR          11000000
         LA 7,1(7)                      CLEAR 256 FOR REMAINDER         11020000
         MVI 0(9),X'00'                 CLEAR FIRST BYTE AT 128         11040000
IEACLEAR MVC 1(256,9),0(9)              CLEAR TO TOP OF EXECUTED PART   11060000
         LA 9,256(9)                                                    11080000
         BCT 7,IEACLEAR                                                 11100000
         L 12,IEASIZTB                  SIZE TABLE ADDRESS              11120000
         L 6,IEATRTAB                                                   11140000
         L 8,IEAADRTB                                                   11160000
         L  14,IEASCATL                 SCATTER LIST START              11180000
         SR 13,13                                                       11220000
         LH 4,IEAESDID                  ESD OF FIRST TXT REC            11240000
         SLL 4,1                        REFERENCE TT                    11280000
         LH 4,0(4,6)                                                    11300000
         SLL 4,2                        GET INDEX FOR TABLE             11320000
         L 9,0(4,3)                     LOAD RELOCATION FACTOR          11340000
         A 9,IEATXTOR                   ORIGIN OF FIRST TXT REC         11360000
         MVI IEABUFER,X'00'             BE SURE FLAGS ARE CLEARED       11380000
         B IEARD1                       ENTER MAIN ROUTINE              11400000
IEACMESD L     3,IEARLFTB               RLFTABLE ADDRESS        PTM6273 11430020
         LH    7,IEABUFER+14                                            11460000
         STH   7,IEATRTRD+6                                             11480000
         LH    4,IEABUFER+6             REG4=RLD INFO BYTES IN RLD REC  11500000
         LH    4,IEABUFER+16(4)         REG4=ESDID                      11520000
         L 6,IEATRTAB                                                   11540000
         LR 7,4                                                         11560000
         SLL 4,1                                                        11580000
         LH 4,0(4,6)                    GET TT POINTER                  11600000
         SLL   4,2                      MULTIPLY(ESDID-1) BY 4          11620000
IEAREPLC L 4,0(4,3)                     RELOCATION FACTOR FOR CS        11640000
         L 9,IEABUFER+8                 ASSEMBLED ORG OF REC            11660000
         AR 9,4                         ADD RELOCATION CONSTANT         11680000
IEARD1   ST 9,IEATXTRD                  STORE ADDRESS CONSTANT IN CW    11700000
         MVI IEATXTRD,X'06'             RESTORE READ COMD               11720000
         MVI IEATXTRD+4,X'60'           INSURE CHAIN AND SILI BITS ON   11740000
         MVC   72(4),IEATXLST           MOVE CHNL PROG ADDRESS TO CAW   11760000
*                                                                  0542 11764018
***  THE FOLLOWING THREE INSTRUCTIONS MUST REMAIN CONTIGUOUS       0542 11768018
*                                                                  0542 11772018
         OI    IEARREC1,X'02'    INDICATE MULTI-TRACKING REQ       0542 11776018
         BAL 5,IEASTRIO                 READ A TXT RECORD               11780000
         MVC IEASRADR(5),IEAST          ID OF NEXT RECORD IN SRCH COMD  11800000
         SPACE 2                                                        11810018
         TM IEABUFER,X'0C'              LAST REC BIT ON IN CCW REC      11820000
         BC    1,IEARELOC               YES,STORE SIZE OF RLD TABLES    11840000
IEARDRC2 MVC   72(4),IEABFLST           MOVE CHNL PROG ADDR IN CCW      11860000
*                                                                  0542 11864018
***  THE FOLLOWING THREE INSTRUCTIONS MUST REMAIN CONTIGUOUS       0542 11868018
*                                                                  0542 11872018
         OI    IEARREC1,X'02'    INDICATE MULTI-TRACKING REQ       0542 11876018
         BAL   5,IEASTRIO               READ REC INTO BUFFER            11880000
         MVC IEASRADR(5),IEAST          ID OF NEXT RECORD IN SRCH COMD  11900000
         SPACE 2                                                        11910018
         TM    IEABUFER,X'03'           RLD WITH CCW PRESENT IN REC     11920000
         BC    1,IEATYP1                YES,SET TYPE 1                  11940000
         TM    IEABUFER,X'02'           RLD PRESENT IN REC              11960000
         BC    1,IEATYP0                YES,SET TYPE=0                  11980000
         B     IEACMESD                 BRANCH TO COMPARE ESDID         12000000
IEATYP0  MVI   IEATYP,X'00'             SET TYPE=0                      12020000
         B     IEABLDRL                 BRANCH TO BUILD RLD TABLE       12040000
IEATYP1  MVI   IEATYP,X'01'             SET TYPE=1                      12060000
IEABLDRL LH    13,IEABUFER+6            REG13=NO OF RLD INFO BYTES R    12080000
         LA    14,IEABUFER+16           REG14=ADDR OF RLD INFO BYTES    12100000
         L 1,IEASZRL1                   RLD SPACE                       12120000
         SR 1,13                        SPACE USED BY THIS RLD          12140000
         C 1,IEAZERO                    TEST IF ROOM IN RLD AREA        12160000
         BC 4,IEAERR8                   RLD AREA EXCEEDED               12180000
         ST 1,IEASZRL1                  REMAINING ROOM FOR RLD          12200000
         L 6,IEARLD1                    PLACE FOR RLDS                  12220000
         EX    13,IEAMVRL1              MOVE RLD BYTES FROM BUFFER      12240000
IEAMVRL1 MVC   0(0,6),0(14)             INTO RLD TABLE 1                12260000
         AR 6,13                        PART OF AREA USED               12280000
         ST 6,IEARLD1                   REMAINING RLD AREA              12300000
         TM    IEATYP,X'01'             TYPE=1{                         12320000
         BC    1,IEACMESD               YES BRANCH TO COMPARE ESDID     12340000
         TM IEABUFER,X'0C'              LAST REC BIT ON IN CCW REC      12360000
         BC    1,IEARELOC               YES,STORE SIZE OF RLD TABLES    12380000
         B     IEARDRC2                 NO,READ ANOTHER RECORDIN BUFFER 12400000
******************* SCATTER LOAD RELOCATION ROUTINE ******************* 12420000
*                                                                     * 12440000
*PROCESSES THE RLD ITEMS IN THE RLD TABLE AND RELOCATES THE LOAD      * 12460000
*CONSTANTS WITHIN THE NUCLEUS TEXT READ INTO MAIN STORAGE.            * 12480000
*                                                                     * 12500000
IEATYPE  C     13,IEAZERO               TEST IF ALL THROUGH             12520000
         BL    IEAOUTCD                 YES LEAVE ROUTINE               12540000
         TM    RLDFLAG,X'01'            TEST NEXT RLD ENTRY             12560000
         BC    1,IEATTRLD               R,P OMITTED IN NEXT RLD         12580000
         B     IEATRLRP                 R,P PRESENT IN NXT RLD          12600000
IEARELOC L 13,IEARLD1                   TOP OF RLD AREA                 12620000
         L 1,IEATRTAB                                                   12640000
         L     4,IEARLFTB               REG4= ADDR OF RLFTABLE ADDR     12660000
         L 3,IEASIZTB                   START OF RLD AREA TOP NUCLEUS   12680000
         L 3,0(3)                                                       12700000
         SR 13,3                        SIZE OF RLD AREA USED           12720000
         SRL   13,2                     REG13=ITEM COUNT1               12740000
IEATRLRP SR 5,5                                                         12760000
         LH 5,0(3)                      R POINTER ESD                   12780000
         SLL 5,1                        REFERENCE TT                    12800000
         LH 5,0(5,1)                    GET TT POINTER                  12820000
         SLL   5,2                      FOR RLFTABLE                    12840000
         L     2,0(5,4)                 REG 2=RELOCATION FACTOR R       12860000
         LH    5,2(3)                   REG5=CONTENTS OF P POINTER      12880000
         SLL 5,1                        REFERENCE TT                    12900000
         LH 5,0(5,1)                    GET TT POINTER                  12920000
         SLL   5,2                      FOR RLFTABLE                    12940000
         L     14,0(5,4)                REG14=RELOCATION FACTOR P       12960000
         LA    3,4(3)                   SET C=C+4                       12980000
         BCTR  13,0                     REDUCE ITEM COUNT               13000000
IEATTRLD CLI 0(3),X'20'                 RELOCATION REQUIRED             13020000
         BNL IEANEXT                    NO GO ON TO NEXT ITEM           13040000
         L     5,0(3)                   REG5=FLAG+RLD ADDR              13060000
         LA    5,0(5)                   REG5=RLD ADDR                   13080000
         AR    5,14                     ADD P RELOC FACTOR TO RLD ADDR  13100000
         NI    0(3),X'0F'               CLEAR UNWANTED FLAGS            13120000
         SR      6,6                                                    13140000
         IC    6,0(3)                   REG6=FLAG BYTE                  13160000
         SRL   6,2                      REG6=LENGTH OF LOAD CONSTANT    13180000
         MVC   IEAFULWD(4),IEAZERO      CLEAR FULL WORD                 13200000
         LA    7,IEAFULWD+3             REG7=ADDR OF IEAFULWD+3         13220000
         SR    7,6                      REG7=BYTE ALIGNMENT IN FULWD    13240000
         EX    6,IEAMOVE                MOVE LOAD CONSTANT              13260000
IEAMOVE  MVC   0(1,7),0(5)              FROM LOAD ADDRESS TO FULL WORD  13280000
         L     8,IEAFULWD               REG 8=LOAD CONSTANT             13300000
         TM    0(3),X'02'              TEST FOR NEG. RELOCATION    8468 13308017
         BNO   POSRELOC                NOT NEGATIVE                8468 13316017
         SR    8,2                 NEGATIVE,SUBTRACT RELOC FACTOR  8468 13324017
         B     BYPOSRLC            BYPASS POSITIVE RELOCATION      8468 13332017
POSRELOC AR    8,2                 ADD RELOC FAC TO LOAD CONSTANT  8468 13340017
BYPOSRLC ST    8,IEAFULWD          IEAFULWD = MODIFIED LOAD CONSTNT8468 13348017
         EX    6,IEARPLCE               REPLACE LOAD CONSTANT           13360000
IEARPLCE MVC   0(1,5),0(7)              IN TEXT                         13380000
IEANEXT  MVC   RLDFLAG(1),0(3)          SAVE FLAG BYTE                  13400000
         LA    3,4(3)                  RLD COUNT C=C+4                  13420000
         BCT   13,IEATYPE               ON ITEM COUNT,BRANCH TO IEATYPE 13440000
*****************  LAST STEP IN IPL PROGRAM  ************************** 13460000
*                                                                       13480000
* ***  TRANSFER OF CONTROL FROM IPL TO NIP VIA A BRANCH TO CONSTANT     13500000
**  ADDRESS IN LOWER CORE WHERE A PSW IS LOADED GIVING CONTROL TO NIP.  13520000
*                                                                       13540000
IEAOUTCD L     6,IEAMAXC                R6 = SIZE OF CORE               13560000
         L     7,IEANUCND          PASS LOW CORE BOUNDARY IN REG 7      13580000
         L     4,IEASIZTB               R4 = ADDR OF SIZE TABLE    000C 13583015
         L     8,IEAADRTB               R8 = ADDR OF ADDRESS TABLE 000C 13586015
         LA    4,4(4)                   SET ADDR, SIZE TABLE PTRS  000C 13589015
         LA    8,4(8)                   PAST DUMMY FIRST ENTRY     000C 13592015
         L     9,IEACSCNT               R9 = NO. ENTRIES PER TABLE 000C 13595015
         LA 5,X'16C'                    LOCATION WHERE NIP PSW LOADED   13600000
         BR 5                           IPL IS ALL DONE                 13620000
***************************** IO ROUTINE ****************************** 13640000
*                                                                     * 13660000
* THIS IS A COMMON I/O ROUTINE USED BY THE ROUTINES WHICH LOCATE AND  * 13680000
*   LOAD THE NUCLEUS. IT CONTAINS SUBROUTINES TO HANDLE CYLINDER AND  * 13700000
*   HEAD SWITCHING, AND DEFECTIVE AND ALTERNATE TRACKS.               * 13720000
*                                                                       13740000
*********************************************************************** 13760000
*                                                                       13780000
* THE FOLLOWING INITIATES THE I/O REQUEST, AND IF THE CSW IS STORED,    13800000
*   ANALYZES THE STATUS BYTES. IF THE OPERATION IS SUCCESSFUL, CONTROL  13820000
*   RETURNS TO THE MAIN LINE; ON UNIT CHECK, THE SENSE SUBROUTINE IS    13840000
*   BRANCHED TO; AND ON ANY OTHER CHECK, THE MACHINE IS PUT IN WAIT     13860000
*   STATE.                                                              13880000
*                                                                       13900000
IEASTRIO SIO   0(10)                    START IO                        13920000
         BC    8,IEATSTIO               IO OP INITIATED,TEST IO         13940000
         BC    4,ERRSIO2           I/O OP NOT INITIATED;CSW STORED      13960000
         BC    2,IEASTRIO               CHANNEL BUSY,START IO           13980000
         B     ERRSIO3             CHN NOT BUSY,CSW NOT STORED          14000000
IEATSTIO TIO   0(10)                    TEST IO                         14020000
         BC    2,IEATSTIO               CHANNEL BUSY,TEST IO            14040000
         BC    4,CSWTEST           CSW STORED; TEST STATUS              14060000
         B     ERRTIO              NEITHER OF ABOVE                     14080000
CSWTEST  TM    68,X'02'            TEST FOR UNIT CHECK                  14100000
         BC    1,SENSE                                                  14120000
         TM    69,X'2F'                 TEST FOR OTHER CHECKS           14140000
         BC    7,ERRCSW            UNRECOVERABLE ERROR                  14160000
         TM    68,X'04'                 TEST FOR DEVICE END             14180000
         BCR   1,5                 RETURN TO CALLER                     14200000
         B     IEATSTIO                 NONE OF ABOVE CONDITIONS,TESTIO 14220000
*                                                                       14240000
* SENSE SUBROUTINE-ISSUES SENSE COMMAND TO SYSRES. TESTS FOR THE VALID  14260000
*   CONDITIONS OF TRACK CONDITION CHECK, FILE MASK VIOLATION, OR END    14280000
*   OF CYLINDER. IF NONE OF THESE, AN ERROR CONDITION EXISTS.           14300000
*                                                                       14320000
SENSE    EQU   *                                                        14340000
         BC    0,ERRSNS            ERROR IF UNIT CHK ON SENSE      3800 14360016
         MVI   SENSE+1,X'F0'       MAKE THE BC AN UNCONDITIONAL BRANCH  14380000
         ST    13,IEAFULWD             PROTECT REGISTER 13         4841 14390016
         MVC   CSWCAW(Q12),CSW     SAVE CSW AND CAW                     14395020
         L     2,64                GET ADDR OF LAST CCW                 14400000
         LA    1,8                   BY SUBTRACTING 8 FROM THE CSW      14420000
         SLR   2,1                   TO POINT TO THE COMMAND            14440000
         LR    1,5                 SAVE REG5 (RETURN REG) OVER BAL      14460000
         XC    SENSESAV(Q24),SENSESAV ZERO SENSE DATA AREA              14470020
         MVC   72(4),IEASNCAW      PLACE PTR TO SENSE CMD IN CAW        14480000
         BAL   5,IEASTRIO          ISSUE SENSE                          14500000
         MVI   SENSE+1,X'00'       RESET BC FOR NO BRANCH               14520000
* THE FOLLOWING STATEMENTS TEST THE SENSE BITS                          14540000
         TM    SENSESAV,X'02'      TRK CONDITION CHECK                  14560000
         BC    1,TRKCCK                                                 14580000
         LA    8,INITRTRY     LOAD BR ADDR FOR RETURN FROM EOTRACK 0542 14590018
         TM    SENSESAV+1,X'04'    FILE MASK VIOLATION-EOTRK            14600000
         BC    1,EOTRACK                                                14620000
         TM    SENSESAV+1,X'20'    END OF CYLINDER                      14640000
         BC    1,UPCYL                                                  14660000
         TM    SENSESAV,ECFDTACK   TEST FOR DATA CHECK                  14660720
         BZ    ERRUCK              IF NO-LOAD WAIT                      14661420
***                                                           ***       14662120
*     THIS ROUTINE CORRECTS DATA CHECKS ON MERLIN/ZEUS DEV      *       14662820
*     SEVERAL ASSUMPTIONS HAVE BEEN MADE IN ECF CODING.                 14663520
*     THEY ARE:                                                         14664220
*            1.  NO CCWS ARE DATA CHAINED.                              14664920
*            2.  NO READ CCW IS FOLLOWED BY A 'TIC'.                    14665620
***                                                           ***       14666320
         OC    SENSESAV+Q7(Q17),SENSESAV+Q7 IS IT MER/ZEUS DEV          14667020
         BE    ERRUCK              NO-LOAD WAIT                         14667720
         XC    SENSDISP(Q5),SENSDISP CLEAR SEC SENSE AREA               14668420
         OC    SENSDISP(Q5),SENSESAV+Q16 IS THERE DATA TO CONVT         14669120
         BE    ECFRESIO            NO-REALGN READ HEAD AND EXIT         14669820
         LA    R5,Q8               GET LGN OF CCW                       14670520
         TM    Q4(R2),CCWSKIP      IS SKIP BIT ON IN CCW                14671220
         BO    ECFRESIO            YES-REALGN READ HEAD AND SIO         14671920
         CLI   SENSESAV+Q7,SNSZEUSA IS IT ZEUS-A                        14672620
         BE    ECFNOMER            YES-USE CCW INFO FOR ERR LOC         14673320
         CLI   SENSESAV+Q7,SNSZEUSC IS IT ZEUS-C                        14674020
         BE    ECFNOMER            YES-USE CCW INFO FOR ERR LOC         14674720
         L     RD,SENSESAV+Q20     GET MUMB BYTES CLOCKED               14675420
         LA    RD,Q0(RD)           CLEAR HI ORDER BYTE                  14676120
         B     ECFMERFX            BR TO CONTINUE ERROR LOCATE          14676820
ECFNOMER LH    R5,CSWCAW+Q6        GET RESID COUNT (ZEUS)               14677520
         LH    RD,Q6(R2)           GET LGN OF READ FROM FAIL CCW        14678220
         SLR   RD,R5               ADJUST ACTUAL READ LGN               14678920
ECFMERFX L     R3,Q0(R2)           GET DATA ADDRESS                     14679620
         LA    R3,Q0(R3)            CLEAR HI BYTE                       14680320
         ALR   RD,R3               ADD READ CT TO START OF DATA         14681020
         LH    R5,SENSDISP         GET DISP TO ERROR AREA               14681720
         SLR   RD,R5               FIND BAD AREA                        14682420
         CLR   RD,R3               IS ERROR IN THIS DATA AREA           14683120
         BL    ERRUCK              NO- CANT RECOVER                     14683820
         CLI   SENSESAV+Q7,SNSZEUSA  IS THIS A ZEUS-A                   14684520
         BNE   ECFNOZA            NO FIX 3 CONTIG BYTES                 14685220
         XC    Q0(Q1,RD),SENSOVLY    FIX BYTE ONE   *                   14685920
         XC    Q2(Q1,RD),SENSOVLY+Q1 FIX BYTE TWO   * ON ZEUS-A         14686620
         XC    Q4(Q1,RD),SENSOVLY+Q2 FIX BYTE THREE *                   14687320
         B     ECFIXMER            BR AROUND MERLIN FIX                 14688020
ECFNOZA  XC    Q0(Q3,RD),SENSOVLY  FIX BAD AREA FOR MERLIN OR ZEUS-C    14688720
ECFIXMER EQU   *                                                        14689420
ECFRESIO EQU   *                                                        14690120
         TM    Q4(R2),X40          IS CHAIN ON IN FAILING CCW           14690820
         BZ    NOMTRET             NO TAKE NO I/O EXIT                  14691520
         MVC   ECFTICCW+Q1(Q3),CSWCAW+Q1  PUT TIC ADDR IN CCW           14692220
         MVI   ECFTICCW,ECFTIC     RESTOR TIC CMD                       14692920
         MVC   TIC(Q8),ECFSRC      CHNG RETRY TIC TO SRCH W/CHAIN       14693620
         MVC   CAW(Q4),ECFRESTR    SET RESTART CAW                      14694320
         TM    Q8(R2),ECFCNTOP     IS USER CCW AT RESTRT A COUNT        14695020
         BO    ECFNOCNT            YES--DONT USE DUMMY COUNT CCW        14695720
         MVC   ECFTICRD(Q4),ECFDMYRD SET DMY RD COUNT IN CHAIN          14696420
         B     ECFRSEXT            LEAVE RESTART RTN                    14697120
ECFNOCNT MVC   ECFTICRD(Q4),ECFTICCW TIC TO USER,NO RD COUNT            14697820
ECFRSEXT EQU   *                                                        14698520
         B     INITRY25            REST REGS 1 AND 13 AND SIO           14699220
*                                                                       14700000
* ON A TRACK CONDITION CHECK, THE HOME ADDRESS AND RECORD 0 ARE READ.   14720000
*   THE ID OF RECORD 0 IS USED AS THE NEXT SEEK ARGUMENT, AND THE FLAG  14740000
*   BYTE OF HOME ADDRESS IS USED TO ROUTE CONTROL.                      14760000
*                                                                       14780000
TRKCCK   EQU   *                                                        14800000
         MVI   SENSE+1,X'F0'       ANY UNIT CHK IN TCC CHAIN IS ERROR;  14820000
*                                    IF SENSE REENTERED,BRANCH TO ERRTN 14840000
         MVC   72(4),TRKCKCAW      MOVE TO CAW A PTR TO TCC CMD CHAIN   14860000
         BAL   5,IEASTRIO          READ HA INTO BUF,R0 INTO IEASKADR+2  14880000
         MVI   SENSE+1,X'00'       TURN OFF BRANCH TO ERROR ROUTINE     14900000
         TM    HABUFER,X'02'       TEST IF ON DEFECTIVE TRACK           14920000
         BC    1,INITRYDT     YES-TEST FURTHER                          14940018
         LA    8,INITRTRY     LOAD BR ADDR FOR RETURN FROM EOTRACK 0542 14960018
*                              ROUTINE                             0542 14980018
*                                                                       15020000
* END OF TRACK ROUTINE UPDATES THE HH PORTION OF THE SEEK AND SEARCH    15040000
*   ARGUMENTS BY 1.                                                     15060000
*                                                                       15080000
EOTRACK  EQU   *                                                        15100000
         LH    13,IEASKADR+4       GET HH PORTION OF SEEK ARGUMENT      15120000
         LA    13,1(13)            UPDATE BY 1                          15140000
         CH    13,IEATRPCL         COMPARE TO MAX NO. OF TRKS PER CYL   15160000
         BE    UPCYL                                                    15180000
         STH   13,IEASKADR+4       STORE NEW HH IN SEEK ARGUMENT        15200000
         STH   13,IEASRADR+2         AND SEARCH ARGUMENT                15220000
        BR    8                                                         15230018
*                                                                       15240000
* THE FOLLOWING IS A COMMON SUBROUTINE USED TO SET UP THE COMMAND CHAIN 15260000
*   TO SEEK TO THE NEW TRACK AND TIC TO THE COMMAND WHICH CAUSED THE    15280000
*   UNIT CHECK.                                                         15300000
*                                                                       15320000
INITRTRY EQU   *                                                        15340000
         MVI   IEASRADR+4,X'01'    INSURE SEARCH FOR REC 1 ON NEW TRK   15360000
INITRY2  ST    2,TIC                                               0542 15380018
         MVI   TIC,X'08'           TIC COMMAND                          15400000
         MVC   72(4),RETRYCAW      MOVE TO CAW PTR TO RETRY CCW CHAIN   15406020
INITRY25 EQU   *                   ENTRY PT FROM ECF TO RESTART         15412020
         LR    5,1                 RESET REG FOR RETURN FROM I/O RTN    15420000
         L     13,IEAFULWD             RESTORE REGISTER 13         4841 15430016
         B     IEASTRIO                                                 15460000
INITRYDT TM    IEARREC1,X'02' *  IS THERE M-T?                     0542 15461018
         BNO   INITRY2           NO--TAKE NORM RETURN              0542 15462018
         ST    2,TIC             RESTORE TIC COMMAND AND           0542 15463018
         MVI   TIC,X'08'         CCW ADDR                          0542 15464018
         MVC   72(4),RETRYCAW    RE-ENTER CCW CHAIN CAUSING U-CHK  0542 15465018
         BAL   5,IEASTRIO        START I/O                         0542 15466018
         CLC   IEASRADR(4),IEAST   IS NEXT COUNT ON SAME TRK       0542 15467018
         BE    NOMTRET       YES-RETURN TO CALLER                  0542 15468018
         MVC   IEASKADR+2(4),IEASRADR RESTORE DEF TRK ADDR         0542 15469018
         BAL   8,EOTRACK      UPDATE TRK ADDR BY ONE               0542 15469618
         MVI   IEASRADR+4,X'01' INSURE READ OF REC ONE ON NXT TRK  0542 15470218
         LA    1,6(1)              SET RET ADR TO BYPAS INLIN TRK  0542 15470819
*                              UPDATE INSTRUCTION                  0542 15471418
NOMTRET  LR    5,1               RESTORE ORIG CALLERS RET ADDR     0542 15472018
         L     13,IEAFULWD                                         0542 15473018
         NI    IEARREC1,X'FD'    TURN OFF M-T SWIT IF ON           0542 15474018
         BR    R5                  RETURN TO CALLER OR IF M-T CI A51251 15475021
*                        RETURN IS PAST INLINE RESTORE OF SRADDR   0542 15476018
*                                                                       15480000
* END OF CYLINDER ROUTINE UPDATES THE CYLINDER PORTION BY 1, AND        15500000
*   ZEROS THE TRACK PORTION OF THE SEEK AND SEARCH ARGUMENTS.           15520000
*                                                                       15540000
UPCYL    EQU   *                                                        15560000
         SR    13,13                                                    15580000
         STH   13,IEASKADR+4       STORE 0 IN HH PART OF SEEK ARG       15600000
         STH   13,IEASRADR+2       STORE 0 IN HH PART OF SEARCH ARG     15620000
         LH    13,IEASKADR+2       GET CURRENT CC ARGUMENT              15640000
         LA    13,1(13)            UPDATE BY 1                          15660000
         STH   13,IEASKADR+2       STORE NEW CC IN SEEK ARG             15680000
         STH   13,IEASRADR         STORE NEW CC IN SEARCH ARG           15700000
         BR    8                                                   0542 15720018
*                                                                       15740000
* FOLLOWING ARE THE VARIOUS ERROR ROUTINES WHICH CAUSE A WAIT STATE     15760000
*   WITH AN ERROR CODE.                                                 15780000
*                                                                       15800000
IEAERR1  MVI   IEAERR,X'01'        I/O NOT OPERATIONAL                  15820000
         LPSW  IEAWAIT                                                  15840000
         SPACE                                                          15860000
ERRSIO2  TM    68,X'30'            TEST FOR CU BUSY OR CU END      3800 15865016
         BC    7,IEASTRIO          IF EITHER, RESTART I/O          3800 15870016
*    IF THE I/O OPERATION WAS NOT INITIATED DUE TO SOME CAUSE      3800 15875016
*    OTHER THAN CONTROL UNIT BUSY OR CONTROL UNIT END, THE CSW     3800 15880016
*    WAS STORED IN ERROR                                           3800 15885016
         MVI   IEAERR,X'02'        CSW STORED IN ERROR             3800 15890016
         LPSW  IEAWAIT                                                  15900000
         SPACE                                                          15920000
ERRSIO3  MVI   IEAERR,X'03'        I/O NOT INITIATED                    15940000
         LPSW  IEAWAIT                                                  15960000
         SPACE                                                          15980000
ERRTIO   MVI   IEAERR,X'04'        ERROR ON TIO                         16000000
         LPSW  IEAWAIT                                                  16020000
         SPACE                                                          16040000
IEAERR8  MVI   IEAERR,X'18'             EXCEEDED CORE AVAIL FOR RLD000B 16060014
         LPSW IEAWAIT                                                   16080000
         SPACE                                                          16100000
PGMCHK   MVI   IEAERR,X'19'             UNEXPECTED PGM CHECK       000B 16120014
         LPSW  IEAWAIT                                                  16140000
         SPACE                                                          16160000
ERRCSW   EQU   *                   PGM CHECK OR CATASTROPHIC ERROR      16180000
         MVI   IEAERR,X'06'        INDICATE UNDEFINED CHECK             16200000
         LPSW  IEAWAIT                                                  16220000
         SPACE                                                          16240000
ERRUCK   EQU   *                   UNIT CHK OTHER THAN TCC,EOT,EOCYL    16260000
         ST    2,76                SAVE PTR TO CCW CAUSING UNIT CHK     16280000
         MVC   84(4),SENSESAV      MOVE 4 SNSE BYTES TO AREA IN S/A DMP 16300000
         MVI   IEAERR,X'05'        INDICATE UNIT CHECK                  16320000
         LPSW  IEAWAIT                                                  16340000
         SPACE                                                          16360000
ERRSNS   EQU   *                   UNIT CHECK ON SENSE COMMAND     3800 16364016
         MVI   IEAERR,X'17'        INDICATE WAIT CODE              3800 16368016
         LPSW  IEAWAIT                                             3800 16372016
         SPACE 1                                                   3800 16376016
         DS 0D                                                          16380000
IEAWAIT  DC X'00020000'          DISABLED WITH WAIT FLAG ON             16400000
IEAERRX  DC X'00000000'          I/O ERROR STOP                         16420000
         SPACE 1                                                        16440000
*  ******************************************************************** 16460000
*  **  THE ORDER OF THE FOLLOWING ADDRESS CONSTANTS FROM IEASNCAW TO    16480000
*   IEACCWND MUST NOT BE ALTERED WITHOUT THE CONSENT OF THE IPL         16500000
*  MAINTAINER AS IT WILL IMPACT THE SELF RELOCATION OF IPL.             16520000
*  ******************************************************************** 16540000
         SPACE 1                                                        16560000
*CONSTANTS- IO ROUTINE                                                  16580000
IEASNCAW DC A(IEASNCCW)                                                 16600000
TRKCKCAW DC    A(TRKCKCCW)                                              16620000
RETRYCAW DC    A(RETRYCCW)                                              16640000
ECFRESTR EQU   RETRYCAW            ECF RESTART CCW CHAIN ADDR           16650020
IEAPCFP  DC    A(PGMCHK)                                                16660000
*CONSTANTS- NUCLEUS LOAD ROUTINE                                        16680000
IEABFLST DC    A(IEABUFSR)                                              16700000
IEATRLST DC A(IEATRTSK)                 SEEK COMD                       16720000
*CONSTANTS- CONTROL SECTION DATA ORGANIZATION ROUTINE                   16740000
IEATRTAB DC A(IEAIPLND)                 START OF TRANSLATION TABLE      16760000
IEASCATL DS F                           START OF SCATTER LIST           16780000
IEASIZTB DS    F                        AREA TO STORE SIZTABLE ADDRESS  16800000
IEAADRTB DS    F                        AREA TO STORE ADRTABLE ADDRESS  16820000
IEARLFTB DS    F                        AREA TO STORE RLFTABLE ADDRESS  16840000
IEACNTND DS    F                        END   OF 4 BYTE LOAD CONT TABLE 16860000
IEANUCND DS    F                        PNTR TO END OF NUCLEUS          16880000
IEAIPLOC DS    F                        PNTR TO IPL RELOC ADDR          16900000
*CONSTANTS- IPL RELOCATION PROGRAM                                 MP65 16904017
         DS    0F                                                       16908017
IEA256K  DC    X'00040000'  HIGH SPEED CORE MULTIPLE (1 BOX) = 256KMP65 16912017
IEA252K  DC    X'0003F000' 256-4K = 1 BOX LESS POSSIBLE MP65 PREFIXMP65 16916017
IEA512K  DC    X'00080000'         CORE SIZE OF 512K             A26272 16917021
IEA508K  DC    X'0007F000'         512K-4K FOR POSSIBLE MP PREFIXA26272 16918021
         SPACE 1                                                        16920000
IEACCWST DS    0D                       START OF CCW TABLE              16940000
IEABUFSR DC X'07'                       SEEK                            16960000
         DC AL3(IEASKADR)                                               16980000
         DC X'4000'                                                     17000000
         DC H'6'                                                        17020000
         DC X'1F'                       SET FILE MASK                   17040000
         DC AL3(IEAMASK)                INHIBIT WRITES AND SEEKS        17060000
         DC X'4000'                                                     17080000
         DC H'1'                                                        17100000
IEASRID  DC X'31'                       SEARCH EQUAL ID                 17120000
         DC    AL3(IEASRADR)            DA                              17140000
         DC    X'4000'                  CC ON,SILI OFF                  17160000
         DC    X'0005'                  5 BYTE COUNT                    17180000
         DC    X'08'                    TIC                             17200000
         DC AL3(IEASRID)                                                17220000
         DC X'00000000'                 NO FLAGS OR COUNT ON TIC        17240000
         DC    X'06'                    READ DATA                       17260000
         DC    AL3(IEABUFER)            INTO BUFFER                     17280000
         DC X'6000'                     SILI AND CHAIN ON               17300000
         DC    H'260'                  MAX COUNT 260                    17320000
         DC X'92'                       READ COUNT MULTI TRACK          17340000
         DC AL3(IEAST)                                                  17360000
         DC X'2000'                                                     17380000
         DC H'8'                                                        17400000
         SPACE 1                                                        17420000
IEASNCCW DC X'04'                SENSE COMD                             17440000
         DC    AL3(SENSESAV)                                            17460000
         DC X'2000'                                                     17480000
         DC    H'24'                                                    17500020
         SPACE 1                                                        17520000
IEATRTSK DC X'07'                       SEEK FIRST TR TBL THEN TXT RECS 17540000
         DC AL3(IEASKADR)                                               17560000
         DC X'4000'                                                     17580000
         DC H'6'                                                        17600000
         DC X'1F'                       SET FILE MASK                   17620000
         DC AL3(IEAMASK)                INHIBIT WRITES AND SEEKS        17640000
         DC X'4000'                                                     17660000
         DC H'1'                                                        17680000
IEATRTSR DC X'31'                       SEARCH EQUAL ID                 17700000
         DC AL3(IEASRADR)                                               17720000
         DC X'4000'                                                     17740000
         DC H'5'                                                        17760000
         DC X'08'                       TIC                             17780000
         DC AL3(IEATRTSR)                                               17800000
         DC X'00000000'                 NO FLAGS OR COUNT ON TIC        17820000
IEATRTRD DC X'06'                       READ DATA                       17840000
         DC AL3(IEATRTBH)               TT/SC LIST FIRST READ           17860000
         DC X'2000'                                                     17880000
         DC H'1024'                                                     17900000
IEARDCNT DC X'92'                       READ COUNT MULTI TRACK          17920000
         DC AL3(IEAST)                                                  17940000
         DC X'2000'                                                     17960000
         DC H'8'                                                        17980000
         SPACE 1                                                        18000000
TRKCKCCW DC    X'07'               SEEK                                 18020000
         DC    AL3(IEASKADR)                                            18040000
         DC    X'40000006'                                              18060000
         DC    X'1A'               READ HOME ADDRESS                    18080000
         DC    AL3(HABUFER)                                             18100000
         DC    X'40000005'                                              18120000
         DC    X'16'               READ RECORD 0                        18140000
         DC    AL3(IEASKADR+2)       INTO THE SEEK ARGUMENT             18160000
         DC    X'00000004'                                              18180000
         SPACE                                                          18200000
RETRYCCW DC    X'07'               SEEK                                 18220000
         DC    AL3(IEASKADR)                                            18240000
         DC    X'40000006'                                              18260000
         DC    X'1F'               SET FILE MASK                        18280000
         DC    AL3(IEAMASK)                                             18300000
         DC    X'40000001'                                              18320000
         DC    X'1A'               READ HOME ADDRESS                    18340000
         DC    AL3(IEASKADR+1)                                          18360000
         DC    X'50000005'         SUPPRESS DATA TRANSFER               18380000
TIC      DC    2F'0'                                                    18400000
         DC    X'08'          TIC BACK TO ECFSRC                        18401020
         DC    AL3(TIC)        TILL RECORD FOUND                        18402020
         DC    F'0'                                                     18403020
ECFTICRD DC    2F'0'               HOLDS 'ECFTICCW' IF RESTART          18404020
*                                   ON COUNT OR 'ECFTICRD' IF           18405020
*                                     FOR NON-COUNT RESTART             18406020
ECFTICCW DC    2F'0'          TIC FILLED BY ECF RTN TO USERS CHAN       18407020
ECFDMYRD DC    X'12'          DUMMY READ COUNT TO ALIGN HEAD TO         18408020
         DC    AL3(IEABUFER)   COUNT FIELD FOLLOWING RECORD             18409020
         DC    X'7000'         WITH BAD DATA-CMD CHAIN,SKIP,SILI        18410020
         DC    H'1'            BITS ARE ON                              18411020
ECFSRC   DC    X'31'          THIS SEEK CCW WILL OVERLAY CCW            18412020
         DC    AL3(IEASRADR)   LABELED 'TIC' TO FINISH ECF CCW          18413020
         DC    X'4000'         CHAIN 'TIC' IS DYNMACLY RESTORED         18414020
         DC    H'5'                                                     18415020
IEACCWND DS    0D                       END OF CCW TABLE                18420000
         SPACE 1                                                        18440000
*CONSTANTS- SCATTER LOAD RELOCATION ROUTINE                             18460000
IEANUCY  DC C'IEANUC01'                 MEMBER NAME STANDARD NUCLEUS    18480000
IEAMASK  DC X'58'                       INHIBIT WRITES AND SEEKS        18500000
HABUFER  DS    5X'00'                                                   18520000
RLDFLAG  DC    X'00'                                                    18540000
         DS 0D                                                          18560000
IEASKADR DS    3H            SEEK ADDRESS  BBCCHH                       18580000
         DC    X'0100'                                                  18600000
         DS 0D                                                          18620000
IEASRADR DC    5X'00'        SEARCH ADDRESS   CCHHR                     18640000
         DS 0D                                                          18660000
IEAST    DS 2F                          STORE RECORD ID                 18680000
IEAFULWD DS    F                                                        18720000
IEAZERO  DC X'00000000'                                                 18740000
IEARREC1 DC    X'00'             SWITCH USED TO TEST MULTITRK OPT  0542 18750018
         SPACE 1                                                        18760000
*CONSTANTS- COMMON TO IPL LOADER ROUTINES                               18780000
IEATSLSZ DS    F                        4 BYTE AREA TO STOR TRL+5XSCLST 18800000
IEATXTOR DC X'00000000'                 ORIGIN OF FIRST TXT REC         18820000
IEACSCNT DS F                           NUMBER OF CS IN NUCLEUS         18840000
IEAIPLTP DS F                           TOP OF IPL TABLES BEFORE RELOC  18860000
IEATPNUC DS F                           LOCATION ABOVE ORDERED CS       18880000
IEASZLST DS F                           ESDID OF LAST ORDERED CS        18900000
IEARLD1  DC X'00000000'          STARTING ADDR. OF LARGEST AREA FOR RLD 18920000
IEASZRL1 DS F                    SIZE LARGEST RLD AREA                  18940000
*CONSTANTS- IPL PRELUDE                                                 18960000
IEANUC   DC X'00000000'               WHERE OP KEYS IN NUCLEUS SUFFIX   18980000
IEAMAXC DC    X'01000000'               MAXIMUM MACHINE SIZE       000B 19000014
IEA16MEG DC    X'01000000'         16 MEG                      @SM0016K 19001021
CSWCAW   DS    3F                  SAVE AREA FOR CSW + CAW USED         19003020
*                                   IN SENSE RTN                        19006020
SENSESAV DS    12H                 AREA TO HOLD SENSE DATA              19009020
SENSDISP DS    H                   ECF DISPLACEMENT DATA                19012020
SENSOVLY DS    2H                  ECF CORRECTION DATA                  19015020
         DC C'V006'                     IPL ID                          19020000
IEATYP   DC    X'00'                                                    19040000
         DS    0H                                                       19060000
IEAFLAG  DC X'7000'                    FLAG BYTE                        19080000
IEAESDID DS H                           ESDID OF FIRST TXT REC          19100000
IEATRTSZ DS    H                        2BYTE AREA TO STOR TRL TABLE SZ 19120000
IEASCLSZ DS    H                        2 BYTE AREA TO STOR SCLST SIZE  19140000
IEATRPCL DS    H                      2 BYTE AREA TO STOR TRACKS/CYL    19160000
IEACTLSC DS    H                                                        19180000
         DS 0D                                                          19200000
IEABUFER EQU   *                                              BI A44954 19210021
*   THE NEXT TWO INSTRUCTIONS ROUND IPL TEXT UP TO A          BI A44954 19220021
*   256 BYTE BOUNDARY.  ''IPLEND'' MUST NOT HAVE A VALUE      BI A44954 19230021
*   GREATER THAN X'E00' DUE TO 2311 RESTRICTIONS.             BI A44954 19232021
L        EQU   (IEABUFER-IEAIPL+255)/256*256-(IEABUFER-IEAIPL)   A44954 19234021
         DC    XL(L)'00'                                      BI A44954 19236021
IPLEND   EQU   *                   ROUNDED END OF IPL TEXT    BI A44954 19238021
IEATRTBH EQU IEABUFER+264               ALLOW FOR TT HEADER             19240000
IEAIPLND EQU IEABUFER+268               ASSUME TOP OF IPL               19260000
IEAERR   EQU IEAERRX+3                  ERROR STOP SIGNAL               19280000
IEASTARL EQU IEALOAD-IEASTAR1    AREA BELOW RELOCATABLE SECTION OF IPL  19300000
IEARELSZ EQU   IEAIPLND-IEALOAD         SIZE OF IPL TO BE RELOCATED     19320000
IEACNTSZ EQU IEACNTND-IEASNCAW       SIZE OF 4 BYTE CON TABLE           19340000
IEACCWSZ EQU   IEACCWND-IEACCWST        SIZE OF CCW TABLE               19360000
IEATXTRD EQU IEATRTRD                   TEXT READ AND TT READ SAME CCWS 19380000
IEATXLST EQU IEATRLST                                                   19400000
         END START                                                      19420000
