IGC0L05A CSECT                                                          00100020
*0241054200,055020-055100,060800                                   RF0B 00200020
*02410770000-077800                                                4029 00300020
*2500047000                                                        7786 00400020
*038200,041800,047000-047600,054700,066400-066600,067400,          I250 00500020
*067800-081200,082400-093200,113400,114000,115400-121600,123400,   I250 00600020
*130800                                                            I250 00700020
*133500,191500-191600,462500-463652                               21014 00750000
         TITLE  'IEAMAD00 / ABDUMP LOAD 1 / IGC0L05A'                   00800020
*STATUS  CHANGE LEVEL  001                                              00900020
*        IEAMAD00 / ABDUMP LOAD 1 / IGC0L05A                            01000020
*         GENERAL ABDUMP INFORMATION                                    01100020
*        THE ABDUMP SVC ROUTINE (SVC 51) PRODUCES A VARIABLE DISPLAY OF 01200020
*        SYSTEM AND PROBLEM PROGRAM INFORMATION.  IT IS A TYPE 4 SVC    01300020
*        AND CONSISTS OF TWELVE TRANSIENT LOADS. IT IS CALLED BY ABEND  01400020
*        OR BY THE USER (VIA THE SNAP MACRO).                           01500020
*        THE FIRST LOAD OF ABDUMP IS REFERRED TO AS ABDUMP1, THE SECOND 01600020
*        AS ABDUMP2, ETC.  TO FACILITATE EASIER UNDERSTANDING OF THE    01700020
*        DESCRIPTIONS OF THE MODULES.                                   01800020
*        THE MODULE AND SVC LIBRARY NAMES ARE AS FOLLOWS:               01900020
*        ABDUMP NAME          MODULE NAME          SVC LIBRARY NAME     02000020
*          ABDUMP1             IEAMAD00                IGC0L05A         02100020
*          ABDUMP2             IEAAAD0D                IGC0D05A         02200020
*          ABDUMP3             IEAAAD0A                IGC0A05A         02300020
*          ABDUMP4             IEAAAD01                IGC0105A         02400020
*          ABDUMP5             IEAAAD02                IGC0205A         02500020
*          ABDUMP6             IEAAAD03                IGC0305A         02600020
*          ABDUMP7             IEAAAD0B                IGC0B05A         02700020
*          ABDUMP8             IEAAAD04                IGC0405A         02800020
*          ABDUMP9             IEAAAD05                IGC0505A         02900020
*          ABDUMP10            IEAAAD0E                IGC0E05A         03000020
*          ABDUMP11            IEAAAD0C                IGC0C05A         03100020
*          ABDUMP12            IEAAAD0F                IGC0F05A         03200020
         SPACE 2                                                        03300020
*FUNCTION-                                                            * 03400020
*        ABDUMP1 IS THE FIRST TRANSIENT LOAD OF ABDUMP WHICH IS A     * 03500020
*        TYPE IV SVC ROUTINE.  ABDUMP1 INSURES THAT ABDUMP            * 03600020
*        REQUIREMENTS HAVE BEEN MET (E.G.,BSAM DCB HAS BEEN           * 03700020
*        OPENED AND CONTAINS THE REQUIRED ATTRIBUTES) AND OBTAINS AND * 03800020
*        INITIALIZES A WORK AREA USED BY EACH TRANSIENT LOAD OF ABDUMP* 03900020
         SPACE 2                                                        04000020
*ENTRY-                                                               * 04100020
*        ABDUMP1 IS ENTERED AT ENTRY POINT NAME IGC0L05A FROM           04200020
*        IGC0005A.  ABDUMP1 IS                                          04300020
*        ENTERED IN SUPERVISOR STATE, WITH SUPERVISOR PROTECTION KEY, * 04400020
*        AND WITH INPUT/OUTPUT AND EXTERNAL INTERRUPTS DISABLED.      * 04500020
         SPACE 2                                                        04600020
*INPUT-                                                               * 04700020
*        ABDUMP1 IS PASSED A POINTER TO THE PARAMETER LIST IN REG 2     04800020
*        THE PARAM.LIST FORMAT IS DESCRIBED BY THE DSECT CALLED         04900020
*        'PARDSECT'. ABDUMP1 IS ALSO PASSED A POINTER TO THE TCB OF   * 05000020
*        THE CURRENT TASK IN REG 4 AND A POINTER TO ABDUMP'S SVRB IN    05100020
*        REG 5.                                                         05200020
         SPACE 2                                                        05300020
*OUTPUT-                                                              * 05400020
*        NONE                                                           05500020
         SPACE 2                                                        05600020
*EXTERNAL REFERENCES-                                                 * 05700020
*        ABDUMP1 REFERENCES ENTRIES IN THE COMMUNICATIONS VECTOR      * 05800020
*        TABLE (CVT), THE TCB OF THE CURRENT TASK, THE TCB OF THE TASK* 05900020
*        BEING DUMPED, AND THE DCB ASSOCIATED WITH THE DUMP DATA SET. * 06000020
*        A)  CVT                                                      * 06100020
*        SYMBOLIC OFFSET - CVTDCB, FROM WHICH IT IS DETERMINED WHETHER* 06200020
*                                  SYSTEM BEING USED IS PCP OR MFT    * 06300020
*        B)  TCB                                                      * 06400020
*        SYMBOLIC OFFSET - TCBMSS, PTR TO BOUNDARY BOX                * 06500020
*                        - TCBPKF, STORAGE PROTECTION KEY             * 06600020
*                        - TCBFLGS, FLAG BYTES                        * 06700020
*                        - TCBFLGS2, FLAG BYTES                       * 06800020
*                        - TCBJSTCB, PTR TO JOBSTEP TCB               * 06900020
*                        - TCBNTC, PTR TO PREVIOUS TCB ON SUBTASK Q   * 07000020
*                        - TCBOTC, PTR TO TCB OF ORIGINATING TASK     * 07100020
*                        - TCBLTC, PTR TO LAST TCB ON SUBTASK Q       * 07200020
*        C) DCB                                                       * 07300020
*        SYMBOLIC OFFSET - DCBOFLGS, FROM WHICH IT IS DETERMINED      * 07400020
*                                    WHETHER OR NOT THE DATA SET IS   * 07500020
*                                    OPEN                             * 07600020
*                        - DCBDSORG, DATA SET ORGANIZATION            * 07700020
*                        - DCBRECFM, RECORD FORMAT                    * 07800020
*                        - DCBLRECL, LOGICAL RECORD LENGTH            * 07900020
*                        - DCBMACRF, MACRO INSTRUCTION REFERENCE      * 08000020
*                        - DCBBLKSI, MAXIMUM BLOCKSIZE                * 08100020
         SPACE 2                                                        08200020
*EXITS-                                                               * 08300020
*        A)  IF ABDUMP REQUIREMENTS HAVE BEEN MET, ABDUMP1 TRANSFERS  * 08400020
*            CONTROL (XCTL'S) TO THE SECOND TRANSIENT LOAD OF ABDUMP. * 08500020
*        B)  IF ABDUMP REQUIREMENTS HAVE NOT BEEN MET, ABDUMP1 EXITS  * 08600020
*            (SVC 3) WITH A RETURN CODE IN THE RETURN CODE REGISTER   * 08700020
*            (REGISTER 15).                                           * 08800020
*            RETURN CODE = 4 INDICATES BSAM DCB HAS NOT BEEN OPENED   * 08900020
*            RETURN CODE = 12 INDICATES DCB DOES NOT HAVE THE         * 09000020
*                             REQUIRED ATTRIBUTES.                    * 09100020
*            RETURN CODE = 8 INDICATES THAT THE TCB FOR THE TASK TO   * 09200020
*                            BE DUMPED IS NOT IN THE CURRENT JOBSTEP  * 09300020
         SPACE 2                                                        09400020
*TABLES/WORK AREAS-                                                   * 09500020
*        A)  TABLES                                                   * 09600020
*            SEE EXTERNAL REFERENCES ABOVE                            * 09700020
*        B)  WORK AREAS                                               * 09800020
*            ABDUMP1 OBTAINS A WORK AREA OF 672 BYTES VIA GETMAIN     * 09900020
*            AND MAINTAINS A PTR TO THE AREA IN REGISTER 13.  THE     * 10000020
*            AREA IS USED BY EACH TRANSIENT LOAD OF ABDUMP, AND IS    * 10100020
*            DESCRIBED BY THE DSECT NAMED 'ABDAREA'                   * 10200020
         SPACE 2                                                        10300020
*OPERATION-                                                           * 10400020
*        ABDUMP1 PERFORMS THE FOLLOWING FUNCTIONS -                   * 10500020
*        - CHECKS FOR OPEN DCB. IF NOT OPEN, ERROR EXIT.              * 10600020
*        - CHECKS DCB FOR REQUIRED ATTRIBUTES. IF REQUIRED ATTRIBUTES * 10700020
*          ARE NOT PRESENT, ERROR EXIT.                               * 10800020
*        - CHECKS TCB ADDRESS, IF DUMP IS FOR OTHER THAN CURRENT TASK,* 10900020
*          TO INSURE THAT IT IS IN THE CURRENT JOBSTEP. IF NOT, ERROR * 11000020
*          EXIT. (APPLIES ONLY TO MFT ATTACH SYSTEMS)                   11100020
*        - OBTAINS A WORK AREA.                                       * 11200000
*        - INITIALIZES PORTIONS OF WORK AREA.                         * 11300020
*        - ISSUES CONDITIONAL GETMAIN FOR BUFFER TO ALLOW FOR         * 11400020
*          BLOCKING.                                                  * 11500020
*        - SETS JOBSTEP NON-DISPATCHABLE, EXCEPT CURRENT TASK, IF     * 11600020
*          DUMP OF OTHER THAN CURRENT TASK IS SPECIFIED. (APPLIES     * 11700020
*          ONLY TO MFT ATTACH SYSTEMS)                                * 11800020
*        - ENQ'S ON DUMP DATA SET IF NOT ENTERED FROM ABEND. (APPLIES * 11900020
*          ONLY TO MFT ATTACH SYSTEMS)                                * 12000020
*        - ENABLES I/O AND EXTERNAL INTERRUPTS.                       * 12100020
*        - TURNS OFF TRACE IF NOT ENTERED FROM ABEND AND TRACE TABLE  * 12200020
*          IS REQUESTED.                                              * 12300020
*        - XCTL'S TO ABDUMP2.                                         * 12400020
         SPACE 2                                                        12500020
*REMARKS-                                                             * 12600020
*        ABDUMP IS AN ABNORMAL END DUMP, CALLED BY ABEND TO PROVIDE   * 12700020
*        A POST MORTEM DUMP.  HOWEVER, ABDUMP MAY ALSO BE USED BY THE * 12800020
*        PROBLEM PROGRAMMER VIA SNAP MACRO(SEE OPTION FLAGS).           12900020
        EJECT                                                           13000020
*        REGISTERS                                                      13100020
R0       EQU   0         ACCUMULATOR                                    13200020
R1       EQU   1         PTR TO PARAMETER LIST                          13300020
CVTREG   EQU   1         USED TO COVER THE CVT                    21014 13350000
R2       EQU   2         PTR TO TCB                                     13400020
R3       EQU   3         RB PTR                                         13500020
R4       EQU   4         PTR TO PARAMETER LIST,RB PTR                   13600020
R5       EQU   5         INTERNAL LINKAGE REGISTER                      13700020
R6       EQU   6         PTR TO CONSTANTS,...                           13800020
R7       EQU   7         PTR TO OUTPUT LINE                             13900020
PARREG   EQU   7                                                        14000020
R8       EQU   8         PTR TO INFO TO BE FORMATTED                    14100020
R9       EQU   9         PTR TO BLOCKING BUFFER                         14200020
RA       EQU   10        WORK REGISTER                                  14300020
RB       EQU   11        WORK REGISTER                                  14400020
RC       EQU   12        BASE REGISTER                                  14500020
RD       EQU   13        POINTER TO AREA OBTAINED VIA GETMAIN           14600020
RE       EQU   14                                                       14700020
RF       EQU   15        RETURN CODE REGISTER                           14800020
*                                                                       14900020
* ERROR RETORN CODE                                                     15000020
BADDCB   EQU   4                       DCB NOT OPENED                   15100020
BADTCB   EQU   8                   INVALID TCB ADDRESS GIVEN       I250 15200020
WRONGDCB EQU   12                  INCORRECT DCB TYPE RETURN CODE       15300020
VBA      EQU   X'54'               PROPER DCB RECFM FIELD               15400020
NOTPS    EQU   X'BF'               NOT PS ORG MASK FOR DCB              15500020
CUR      EQU   4                                                        15600020
EXIT     EQU   3                                                        15700020
FLAGS    EQU   0         DISPLACEMENT FROM BEGIN OF PARA.LIST TO FLAGS  15800020
DVTYPE   EQU   17        DCB DISPLACEMENT TO DEVICE TYPE                15900020
OFLGS    EQU   48        DCB DISPLACEMENT TO OPEN FLAGS                 16000020
IOBSYNAD EQU   56        DCB DISPLACEMENT TO IOB LENGTH, SYNAD          16100020
OPEN     EQU   X'10'     MASK TO TEST OPEN FLAG                         16200020
TCBFX    EQU   X'01'     MASK USED TO PREVENT ASYNCHRONOUS EXITS   I250 16300020
MFTATTCH EQU   X'08'     MASK TO TEST FOR MFT ATTACH               I250 16400020
TCBNDUMP EQU   X'80'     MASK USED TO SET TASK NON-DISPATCHABLE    I250 16500020
TCBNDISP EQU   X'01'     MASK TO SET OTHER NON-DISP BIT            I250 16600020
TESTTASK EQU   X'80'     ON-DUMP IS FOR TASK OTHER THAN CURRENT    I250 16700020
TERMBIT  EQU   X'80'     ON-TASK HAS BEEN TERMINATED               I250 16800020
TESTRBS  EQU   X'40'     MASK TO TEST IF RB CHAIN EXISTS           I250 16900020
XFF      EQU   X'FF'                                               I250 17000020
NDBYTE   EQU   4                                                   I250 17100020
ZERO     EQU   0                                                   I250 17200020
ONE      EQU   1                                                   I250 17300020
TWO      EQU   2                                                   I250 17400020
THREE    EQU   3                                                   I250 17500020
FOUR     EQU   4                                                   I250 17600020
EIGHT    EQU   8                                                   I250 17700020
TWELVE EQU     12                                                  I250 17800020
EOVSIZE  EQU   1600                                           CI A41341 17850000
* DISPLACEMENTS FROM BEGINNING OF TIOT TO                               17900020
TIOTJOB  EQU   0         JOB NAME                                       18000020
TIOTSTEP EQU   8         STEP NAME                                      18100020
* DISPLACEMENTS FROM BEGINNING OF TCB TO                                18200020
TCBRBP   EQU   0         PTR TO ACTIVE RB CHAIN                         18300020
TCBPIE   EQU   4         PTR TO PROG INTERRUPT ELEMENT                  18400020
TCBTIOT  EQU   12        PTR TO TIOT                                    18500020
TCBCMP   EQU   16        TASK COMPLETION CODE                           18600020
TCBMSS   EQU   24        PTR TO BOUNDARY BOX                       I250 18700020
TCBPKF   EQU   28        STORAGE PROTECTION KEY                    I250 18800020
TCBFLGS  EQU   29        TCB FLAGS                                 I250 18900020
TCBFLGS2 EQU   174       TCB FLAGS                                 I250 19000020
TCBNDSP2 EQU   173       TCB NON-DISPATCHABILITY BYTES             I250 19100020
TCBDAR   EQU   172       GTF TRACE DISABLED BIT                   21014 19130000
TCBGTOFM EQU   X'10'     MASK FOR GTF TRACE DISABLED              21014 19160000
TCBLL    EQU   36        PTR TO LIST OF LOADED PROGRAMS                 19200020
TCBJSTCB EQU   44        PTR TO JOBSTEP TCB                        I250 19300020
TCBNTC   EQU   128       PTR TO PREVIOUS TCB ON SUBTASK Q          I250 19400020
TCBOTC   EQU   132       PTR TO TCB OF ORIGINATING TASK            I250 19500020
TCBLTC   EQU   136       PTR TO LAST TCB ON SUBTASK Q              I250 19600020
* DISPLACEMENTS FROM BEGINNING OF RB TO                                 19700020
RBSIZE   EQU   8         SIZE OF RB/PROG                                19800020
RBSTAB   EQU   10        RB STATUS AND ATTRIBUTE BITS                   19900020
RBOPSW   EQU   16        PSW SAVE AREA                                  20000020
RBLINK   EQU   28        RB CHAIN ADDR                                  20100020
RBREG    EQU   32                                                       20200020
* EXTENDED ASA CARRIAGE CONTROL CHARACTERS FOR                          20300020
HDCC     EQU   C'0'                     HEADING LINE                    20400020
COMPCC   EQU   C'0'                     COMPLETION CODE LINE            20500020
PSWCC    EQU   C'0'                     PSW LINE                        20600020
MSGCC    EQU   C'0'                     MESSAGE LINE                    20700020
*                                                                       20800020
* OPTION FLAGS                                                          20900020
*                                                                       21000020
* FIRST FLAG BYTE                                                       21100020
PFABEND  EQU   X'80'                   OFF-ABEND,ON-SNAP IS THE CALLER  21200020
PFTCB    EQU   X'40'                   ON-TCB ADDR IS FIVEN        I250 21300020
PFSUPDAT EQU   X'20'                   ON-ALL SUPRV DATA                21400020
PFTRACE  EQU   X'10'                   ON-PRINT TRACE TABLE             21500020
PFNUC    EQU   X'08'                   ON-PRINT NUCLEUS                 21600020
PFSNAP   EQU   X'04'                   ON-SNAPSHOT LIST GIVEN           21700020
PFID     EQU   X'02'                   ON-AN ID GIVEN                   21800020
PFQCB    EQU   X'01'                   NOT USED IN SSS SYSTEM           21900020
* SECOND FLAG BYTE                                                      22000020
PFSAVE   EQU   X'80'                   ON-SAVE AREA(SEE PFSAVE2)        22100020
PFSAVE2  EQU   X'40'                   OFF-ENTIRE SA,ON-HEADINGS ONLY   22200020
PFREGS   EQU   X'20'                   ON-REGS AT ENTRY TO(SEE PFABEND) 22300020
PFLPA    EQU   X'10'              NOT USED IN SSS                       22400020
PFJPA    EQU   X'08'              ON- PRINT P/P PARTITION               22500020
PFPSW    EQU   X'04'                   ON--PSW AT ENTRY TO(SEE PFABEND) 22600020
PFSPALL  EQU   X'02'                   ON-P/P PARTITION                 22700020
*        EQU   X'01'              NOT USED IN SSS                       22800020
         EJECT                                                          22900020
* INITIALIZATION                                                        23000020
*       1)  DETERMINE IF ABDUMP REQUIREMENTS HAVE BEEN MET (OPENED      23100020
*           DCB AND SUFFICIENT CORE AVAILABLE).                         23200020
*       2)  ENABLE FOR I/O AND EXTERNAL INTERRUPTS.                     23300020
*       3)  INITIALIZE OUTPUT AREA.                                     23400020
*                                                                       23500020
ENTRY   BALR  RC,0                     ESTABLISH ADDRESSABILITY         23600020
         USING *,RC                                                     23700020
         USING PARDSECT,PARREG                                          23800020
         L     R3,CVTPTR               GET CVT PTR                      23900020
         L     R4,0(R3)                GET NEW-OLD PTR                  24000020
         L     R4,4(R4)                GET PTR TO TCB                   24100020
         L     R5,0(R4)                GET RB PTR                       24200020
         LR    PARREG,R2               SET UP BASE FOR PARDSECT    I250 24300020
         LR    R2,R4                   R2 POINTS TO TCB OF CURR    I250 24400020
*                                        TASK IN THE EVENT THE     I250 24500020
*                                        CURR TASK IS THE ONE TO   I250 24600020
*                                        BE DUMPED                 I250 24700020
         FREEMAIN R,LV=8,A=(11)         FREE CORE USED FOR XCTL         24800020
         L     R6,PDCBPTR              GET PTR TO DCB              I250 24900020
        TM    OFLGS(R6),OPEN           TEST FOR OPENED DCB              25000020
         BC    1,DCBOK                 BRANCH,DCB OPENED                25100020
         LA    RF,BADDCB               GET ERROR CODE                   25200020
         EJECT                                                          25300020
*********************************************************************** 25400020
*                                                                     * 25500020
*        THE FOLLOWING CODE IS ADDED TO ALLOW ABDUMP1 TO VALIDITY     * 25600020
*        CHECK THE DCB THAT IS PASSED BY THE USER FOR 'SNAP'.         * 25700020
*        THE ROUTINE CHECKS FOR THE FOLLOWING ATTRIBUTES-             * 25800020
*                  DSORG = PS                                         * 25900020
*                  MACRF = W                                          * 26000020
*                  RECFM = VBA                                        * 26100020
*                  LRECL = 125                                        * 26200020
*        MFT2 BLKSIZE = 882                                           * 26300020
*        IF ANY OF THESE ATTRIBUTES FAIL TO APPEAR IN THE DCB,        * 26400020
*        A CONDITION CODE = 12 IS RETURNED IN REGISTER 15.            * 26500020
*                                                                     * 26600020
*********************************************************************** 26700020
         SPACE 2                                                        26800020
ERREXIT  EQU   *                   EXIT TO CALLER                       26900020
         SVC   EXIT                                                     27000020
         USING IHADCB,R6                                                27100020
DCBOK    TM    DCBDSORG,NOTPS          SEE IF DSORG IS CORRECT          27200020
         BM    SICKDCB             IF NOT, RETURN CONDITION CODE=8.     27300020
         CLI   DCBRECFM,VBA        SEE IF RECFM IS CORRECT              27400020
         BNE   SICKDCB             IF NOT, GO EXIT                      27500020
         CLC   DCBLRECL,PHYLOG+4   SEE IF LOGICAL RECORD LENGTH IS 125. 27600020
         BNE   SICKDCB             IF NOT, BRANCH                       27700020
         CLC   DCBMACRF,=H'32'     SEE IF CORRECT MACRO FORM            27800020
         BNE   SICKDCB             GO RETURN ERROR CODE IF NOT          27900020
         L     R1,CVTPTR                POINT TO CVT               M00A 28000020
         USING CVTDSECT,R1                                         M00A 28100020
MFT2RUN  LA    RB,MINMAX2          GET ADDR OF BLOCK LIMITS        BLKZ 28200020
         CLC   DCBBLKSI,MINMAX2+6  IS BLOCK SIZE 882 - MFT2        BLKZ 28300020
         BE    TSTATTCH            YES,DCB IS GOOD                 I250 28400020
SICKDCB  LA    RF,WRONGDCB         ERROR CODE = 12 FOR WRONG DCB   BLKZ 28500020
         B     ERREXIT             RETURN TO USER                  BLKZ 28600020
         LTORG                                                          28700020
         DROP  R6                                                       28800020
TSTATTCH EQU   *                                                   I250 28900020
         L     R1,CVTPTR           GET PTR TO CVT                  I250 29000020
         TM    CVTOPTA,MFTATTCH    IS THIS AN MFT ATTACH SYSTEM    I250 29100020
         BNO   GETCORE             NO,BRANCH                       I250 29200020
         TM    PFLAGS,PFTCB        IS TCB ADDR IN PARAMETER LIST   I250 29300020
         BZ    CURRTCB             NO,DUMP IS FOR CURRENT TASK     I250 29400020
*                                                                  I250 29500020
* VALIDITY CHECK TCB ADDRESS IN PARAMETER LIST                     I250 29600020
*                                                                  I250 29700020
         L     R3,PTCBPTR          GET TCB ADDR FROM PARAM LIST    I250 29800020
         LA    R3,ZERO(R3)         CLEAR TOP BYTE                  I250 29900020
         LTR   R3,R3               IS TCB ADDR ZERO                I250 30000020
         BZ    CURRTCB             YES,DUMP IS FOR CURRENT TASK    I250 30100020
         LR    R2,R3               NO,MAKE R2 POINT TO TCB OF      I250 30200020
*                                  TASK TO BE DUMPED               I250 30300020
         CLI   TCBPKF(R4),ZERO     WAS ABDUMP CALLED BY SPVR RTN   I250 30400020
         BNE   PPRTN               NO,BRANCH                       I250 30500020
         OI    TCBFLGS2(R2),TCBNDUMP  SET TASK NON-DISPATCHABLE    I250 30600020
         OI    TCBFLGS+NDBYTE(R2),TCBNDISP                         I250 30700020
         B     GETCORE                                             I250 30800020
PPRTN    CLC   TCBJSTCB(FOUR,R2),TCBJSTCB(R4)  IS PASSED TCB IN    I250 30900020
*                                              CURRENT JOBSTEP     I250 31000020
         BE    GETCORE             YES,BRANCH                      I250 31100020
         LA    RF,BADTCB           NO,GET ERROR RETURN CODE        I250 31200020
         SVC   EXIT                RETURN TO CALLER                I250 31300020
CURRTCB  OI    TCBFLGS(R4),TCBFX   PREVENT ASYNCHRONOUS EXITS      I250 31400020
*                                    FOR CURRENT TASK              I250 31500020
         EJECT                                                          31600020
GETCORE  EQU   *                                                        31700020
*                                                             CI A41341 31709000
* IF INVOKED BY ABEND, THE ADDRESS OF THE ABDUMP WORK AREA IS CI A41341 31718000
* PASSED IN THE 5TH WORD OF THE PARAMETER LIST.               CI A41341 31727000
*                                                             CI A41341 31736000
         TM    PFLAGS,PFABEND      Q. INVOKED BY ABEND        CI A41341 31745000
         BO    GETMAIN             NO, BRANCH                 CI A41341 31754000
         L     RD,PWORKPTR         GET ADDR OF WORK AREA      CI A41341 31763000
         B     SKIPGET             BRANCH AROUND GETMAIN      CI A41341 31772000
GETMAIN  EQU   *                                              CI A41341 31781000
*                                                             CI A41341 31790000
* GETMAIN FOR OUTPUT AREA, SAVE AREA, DECB, WORK AREA, SPACE FOR        31800020
* OUTPUT ROUTINE, PRINT LINE                                            31900020
         LA    R0,672         TOTAL CORE REQUIRED ABDAREA DSECT PTM 893 32000020
         GETMAIN   R,LV=(0)                                             32100020
* POINTER TO AREA ALLOCATED IS RETURNED IN REGISTER 1.                  32200020
         LR    RD,R1                                                    32300020
         USING ABDAREA,RD                                               32400020
SKIPGET  EQU   *                                              CI A41341 32450000
         ST    PARREG,ABDPARA      SAVE PTR TO PARAM LIST          I250 32500020
*                                                                  I250 32600020
* IN PCP SYSTEMS AND MFT SYSTEMS WITHOUT THE ATTACH OPTION, THE    I250 32700020
* BOUNDARY BOX ADDRESS IS GOTTEN FROM THE TCBMSS FIELD OF THE      I250 32800020
* CURRENT TCB. IN MFT ATTACH SYSTEMS, IT IS GOTTEN FROM THE        I250 32900020
* TCBMSS FIELD OF THE JOBSTEP TCB.                                 I250 33000020
*                                                                  I250 33100020
         L     R1,CVTPTR           GET PTR TO CVT                  I250 33200020
         TM    CVTOPTA,MFTATTCH    IS THIS AN MFT ATTACH SYSTEM    I250 33300020
         LR    R1,R2                                               I250 33400020
         BNO   GETBBPTR            NO,BRANCH                       I250 33500020
         L     R1,TCBJSTCB(R2)     GET ADDR OF JOBSTEP TCB         I250 33600020
GETBBPTR L     R1,TCBMSS(R1)       GET PTR TO BOUNDARY BOX         I250 33700020
         ST    R1,BBADDR           SAVE IT FOR LATER               I250 33800020
         SR    R8,R8               INITIALIZE SWITCH          CI A41341 33850000
* INITIALIZE BSAM DECB                                                  33900020
         LA    R6,0(R6)                 DCB PTR, CLEAR HI-ORDER BITS    34000020
         LA    R7,ABDCC-8               PTR TO OUTPUT LINE              34100020
         STM   R6,R7,ABDDCB             BSAM PARAMETERS TO DECB         34200020
         SR    R9,R9                    PTR TO BUFFER SET TO ZERO       34300020
         TM    DVTYPE(R6),X'48'         TEST, BR, IF OUTPUT DEVICE      34400020
         BC    14,ABD004                IS NOT A PRINTER                34500020
* DEVICE IS A PRINTER, ESTABLISH SYNAD.                                 34600020
         LA    R1,ABDOUT+210     *****                                  34700020
         ST    R1,ABDWORK1                                              34800020
         MVC   IOBSYNAD+1(3,R6),ABDWORK1+1   SYNAD TO DCB               34900020
         B     ABD005                                                   35000020
*                                                                       35100020
* A VARIABLE, CONDITIONAL REQUEST IS ISSUED TO OBTAIN A BUFFER FOR      35200020
* BLOCKING.                                                             35300020
*                                                             CI A41341 35310000
* NOTE- IF INVOKED BY ABEND, A BLOCKING BUFFER WILL NOT BE    CI A41341 35320000
*       GETMAINED UNLESS SUFFICIENT STORAGE IS ALSO AVAILABLE CI A41341 35330000
*       FOR END OF VOLUME PROCESSING AND ABEND RECURSION      CI A41341 35340000
*       SVRBS.                                                CI A41341 35350000
*                                                             CI A41341 35360000
ABD004   EQU   *                                                        35400020
         L     PARREG,ABDPARA      GET ADDR OF PARM LIST      CI A41341 35409000
         TM    PFLAGS,PFABEND      Q. INVOKED BY ABEND        CI A41341 35418000
         BO    GETBUFF             NO, BRANCH                 CI A41341 35427000
         LA    R1,ABDOUT+8         POINT TO GETMAIN PARM LIST CI A41341 35436000
         LA    R7,EOVSIZE          GET SIZE NEEDED            CI A41341 35445000
         GETMAIN EC,LV=(R7),A=ABDOUT,SP=0,MF=(E,(1))          AB A56025 35454021
         LTR   RF,RF               Q. GETMAIN SATISFIED       CI A41341 35463000
         BNZ   ABD005              NO, BRANCH                 CI A41341 35472000
         L     R8,ABDOUT           GET ADDR OF GETMAINED AREA CI A41341 35481000
GETBUFF  EQU   *                                              CI A41341 35490000
        LA    R1,ABDOUT+8                                               35500020
         GETMAIN  VC,LA=(RB),A=ABDOUT,SP=0,MF=(E,(1))              RF0B 35600020
         LTR   RF,RF                    TEST, BR, IF REQUEST FOR        35700020
         BC    7,ABD005-4(RF)           BUFFER NOT SATISFIED            35800020
         LM    R9,RA,ABDOUT             PTR TO BUFFER, SIZE             35900020
         ST    R9,ABDPTR                BUFFER ADDRESS TO DECB          36000020
         LA    RB,0(R9,RA)              END OF BUFFER                   36100020
         LA    RA,4(R9)                 PTR TO NEXT SLOT IN BUFFER      36200020
ABD005   STM   R9,RB,ABDPTRS                                            36300020
         LTR   R8,R8               Q. EOV CORE TO BE FREED    CI A41341 36320000
         BZ    SKIPFREE            NO, BRANCH                 CI A41341 36340000
         FREEMAIN R,LV=(R7),A=(R8)                            CI A41341 36360000
SKIPFREE EQU   *                                              CI A41341 36380000
         L     PARREG,ABDPARA      SET UP BASE FOR PARDSECT        I250 36400020
         L     R1,CVTPTR           GET PTR TO CVT                  I250 36500020
         TM    CVTOPTA,MFTATTCH    IS THIS AN MFT ATTACH SYSTEM    I250 36600020
         BNO   FLAGOFF             NO,BRANCH                       I250 36700020
         TM    PFLAGS,PFABEND      IS ABEND THE CALLER             I250 36800020
         BZ    DONTENQ             YES,BYPASS ENQ                  I250 36900020
*                                                                  I250 37000020
* ENQ ON DUMP DATA SET                                             I250 37100020
*                                                                  I250 37200020
         LA    R1,ABDWORK3         POINT TO ENQ PARAM LIST         I250 37300020
         MVI   TWO(R1),ZERO        ZERO FLAGS IN ENQ PARAM LIST    I250 37400020
         MVC   TWELVE(EIGHT,R1),QNAME  MOVE QNAME OUT OF           I250 37500020
*                                      TRANSIENT AREA              I250 37600020
         LA    RE,TWELVE(R1)       GET ADDR OF QNAME               I250 37700020
         LA    RF,PDCBPTR          GET ADDR OF RNAME (DCB ADDR)    I250 37800020
         LA    R3,FOUR             LENGTH OF RNAME = 4 BYTES       I250 37900020
         MVI   ZERO(R1),XFF        SET LAST ENTRY INDICATOR        I250 38000020
         ENQ   ((RE),(RF),E,(R3),),MF=(E,(1))                      I250 38100020
DONTENQ  EQU   *                                                   I250 38200020
         TM    PFLAGS,PFTCB        IS TCB ADDR IN PARAMETER LIST   I250 38300020
         BZ    FLAGOFF             NO,DUMP IS FOR CURRENT TASK     I250 38400020
         NC    PTCBPTR,PTCBPTR     IS GIVEN TCB ADDR ZERO          I250 38500020
         BZ    FLAGOFF             YES,BRANCH-DUMP FOR CURR TASK   I250 38600020
         OI    ABDFLAG,X'80'       SET FLAG TO INDICATE ATTACH     I250 38700020
*                                    FUNCTION IS BEING USED AND    I250 38800020
*                                    DUMP IS FOR TASK OTHER THAN   I250 38900020
*                                    CURRENT ONE                   I250 39000020
*                                                                  I250 39100020
* TO AVOID ANY DYNAMIC MODIFICATION OF THE SUPERVISOR'S Q'S, THE   I250 39200020
* CURRENT JOBSTEP WILL BE SET NON-DISPATCHABLE (EXCEPT CURRENT     I250 39300020
* TASK).                                                           I250 39400020
*                                                                  I250 39500020
         L     RE,TCBJSTCB(R4)     GET JOBSTEP TCB ADDR            I250 39600020
SETNDISP OI    TCBFLGS2(RE),TCBNDUMP  SET TASK NON-DISPATCHABLE    I250 39700020
         OI    TCBFLGS+NDBYTE(RE),TCBNDISP                         I250 39800020
         LR    RF,RE               SAVE TCB ADDR                   I250 39900020
         L     RE,TCBLTC(RF)       GET ADDR DAUGHTER TASK'S TCB    I250 40000020
TESTDATR LTR   RE,RE               IS THERE A DAUGHTER TASK        I250 40100020
         BNZ   SETNDISP            YES,BRANCH                      I250 40200020
         L     RE,TCBNTC(RF)       NO,GET ADDR SISTER TASK'S TCB   I250 40300020
         C     RF,TCBJSTCB(RF)     IS SCAN OF SUBTASKS COMPLETED   I250 40400020
         BE    SETCURR             YES,BRANCH                      I250 40500020
         L     RF,TCBOTC(RF)       NO,GET ADDR MOTHER TASK'S TCB   I250 40600020
         B     TESTDATR            TEST DAUGHTER TASK              I250 40700020
SETCURR  NI    TCBFLGS2(R4),XFF-TCBNDUMP  SET CURRENT TASK DISP    I250 40800020
         CLC   TCBNDSP2(THREE,R4),ALLZERO  ANY NON-DISP BITS ON    I250 40900020
*                                          IN TCBNDSP2 FIELD       I250 41000020
         BNE   ENABLE                       YES,BRANCH             I250 41100020
         NI    TCBFLGS+NDBYTE(R4),XFF-TCBNDISP  TURN OFF OTHER     I250 41200020
*                                               N-DISP BIT         I250 41300020
         B     ENABLE                                              I250 41400020
FLAGOFF  NI    ABDFLAG,XFF-TESTTASK  SET FLAG TO INDICATE DUMP     I250 41500020
*                                    IS FOR CURRENT TASK           I250 41600020
*                                                                       41700020
ENABLE   EQU   *                                                   I250 41800020
         SSM   SYSMASK                 ENABLE                           41900020
*                                                                       42000020
* INITIALIZE OUTPUT AREA                                                42100020
*       1)  BSAM PARAMETERS IN DECB ( DCB PTR, AREA ADDRESS ) HAVE      42200020
*           BEEN ESTABLISHED.                                           42300020
*       2)  ESTABLISH RECORD COUNTS PRIOR TO OUTPUT LINE                42400020
*       3)  MOVE OUTPUT ROUTINE TO WORK AREA (AREA OBTAINED - GETMAIN)  42500020
*       4)  CLEAR OUTPUT LINE.                                          42600020
*       5)  SET LINE COUNT TO 6, PAGE COUNT TO 1.                       42700020
*       6)  STORE POINTER TO PARAMETER LIST IN WORK AREA.               42800020
*                                                                       42900020
* ESTABLISH BSAM RECORD LENGTH FIELDS                                   43000020
         MVC   ABDPHY(8),PHYLOG                                         43100020
* MOVE OUTPUT ROUTINE TO AREA OBTAINED VIA GETMAIN.                     43200020
         MVC   ABDOUT(LAST-OUTPUT),OUTPUT                               43300020
         MVI   ABDLINE,C' '                                             43400020
         MVC   ABDLINE+1(119),ABDLINE   CLEAR OUTPUT LINE TO BLANKS     43500020
         MVC   ABDCTR1(L'COUNTS),COUNTS     LINE, PAGE COUNTS           43600020
*                                                                  I250 43700020
* IN AN MFT ATTACH SYSTEM IN WHICH THE DUMP REQUEST IS FOR A       I250 43800020
* TASK OTHER THAN THE CURRENT ONE, IT IS POSSIBLE THAT THIS TASK   I250 43900020
* HAS NO RB'S CHAINED OFF OF ITS TCB.                              I250 44000020
*                                                                  I250 44100020
         TM    ABDFLAG,TESTTASK    IS CURRENT TASK BEING DUMPED    I250 44200020
         BZ    RBSOK               YES,RB CHAIN EXISTS             I250 44300020
         TM    TCBFLGS2+ONE(R2),TERMBIT  IS TASK ALREADY           I250 44400020
*                                        TERMINATED                I250 44500020
         BO    NORBS               YES,RB CHAIN DOESN'T EXIST      I250 44600020
         L     R1,TCBRBP(R2)       GET RB FIELD FROM TCB           I250 44700020
         LA    R1,ZERO(R1)         CLEAR TOP BYTE                  I250 44800020
         LTR   R1,R1               IS IT ZERO                      I250 44900020
         BZ    NORBS               YES,RB CHAIN DOESN'T EXIST      I250 45000020
         CR    R1,R2               DOES RB FIELD POINT TO TCB      I250 45100020
         BE    NORBS               YES,RB CHAIN DOESN'T EXIST      I250 45200020
RBSOK    NI    ABDFLAG,XFF-TESTRBS SET FLAG INDICATING RB CHAIN    I250 45300020
*                                    EXISTS                        I250 45400020
         B     AROUND                                              I250 45500020
NORBS    OI    ABDFLAG,TESTRBS     SET FLAG INDICATING RB CHAIN    I250 45600020
*                                    DOESN'T EXIST                 I250 45700020
AROUND   EQU   *                                                   I250 45800020
* IF SNAP AND TRACE ARE REQUESTED, TURN OFF TRACE FOR THIS TASK         45900020
* UNTIL TRACE INFO HAS BEEN PRINTED.                                    46000020
         TM    PFLAGS,PFABEND+PFTRACE                                   46100020
         BNO   NXTLOAD                                             I250 46200020
         SPACE 2                                                        46208000
*                                                                 21014 46216000
*   THIS CODE WILL SUSPEND GTF TRACE FOR AN MFT SYSTEM HAVING GTF 21014 46224000
*  ACTIVE AND HAVING RECIEVED A REQUEST FOR A FORMATTED GTF TRACE 21014 46232000
*                                                                 21014 46240000
         L     CVTREG,CVTPTR       ESTABLISH BASE FOR CVT DSECT   21014 46248000
         TM    CVTGTFST,CVTGTFS    IS GTF ACTIVE?                 21014 46256000
         BNO   OFFOLD              NO.. DO NOT EXECUTE GTF CODE.  21014 46264000
         TM    CVTGTFST,CVTFORM    IS GTF TRACE TABLE TO BE FORMAT21014 46272000
         BNO   NXTLOAD             NO.. NO NEED TO SUSPEND TRACE. 21014 46280000
         TM    TCBFLGS(R4),TCBGTOFM   GTF TRACE ALREADY SUSPENDED 21014 46288021
         BO    NXTLOAD             YES..NO NEED TO SUSPEND AGAIN  21014 46298000
         OI    TCBFLGS(R4),TCBGTOFM  NO-SET TRACE SUSPENDED BIT.  21014 46308021
         HOOK  EID=IHLMABOF        SUSPEND GTF TRACING FUNCTION.  21014 46318000
OFFOLD   EQU   *                                                  21014 46328000
*                                                                 21014 46338000
         SPACE 2                                                        46348000
NXTLOAD  EQU   *                                                   I250 46400020
         LA    RA,NMLOAD2              GET NAME OF LOAD 2               46500020
         LA   RF,ABDWORK3                                               46600021
        XCTL  EPLOC=(10),SF=(E,(15))                                    46700020
*                                                                       46800020
         EJECT                                                          46900020
* OUTPUT ROUTINE                                                        47000020
*      THIS ROUTINE IS USED BY EACH LOAD OF ABDUMP TO WRITE A           47100020
*      PRINTABLE RECORD.  IT IS ASSEMBLED WITH ABDUMP1, BUT IS MOVED    47200020
*      TO AN AREA WITHIN ABDUMP'S WORK AREA(POINTED TO BY REGISTER 13). 47300020
*      WHEN THE ROUTINE GETS CONTROL, A PRINTABLE RECORD IS IN THE AREA 47400020
*      RESERVED FOR AN OUTPUT LINE.                                     47500020
*      IF THE RECORDS ARE NOT TO BE BLOCKED ,I.E.  OUTPUT DEVICE IS A   47600020
*      PRINTER OR NO BUFFER IS AVAILABLE FOR BLOCKING, THE RECORD IN    47700020
*      THE OUTPUT LINE IS WRITTEN.                                      47800020
*      IF THE RECORDS ARE TO BE BLOCKED, THE RECORD IN THE OUTPUT LINE  47900020
*      IS MOVED TO THE BUFFER.  WHEN THERE REMAINS LESS THAN 125 BYTES  48000020
*      IN THE BUFFER, THE BLOCK IS WRITTEN.                             48100020
*      PAGINATION IS CONTROLLED BY THE ROUTINE, BASED UPON 56 LINES     48200020
*      PER PAGE.                                                        48300020
*      THE ROUTINE RETURNS CONTROL VIA 'BR R5'.                         48400020
         SPACE 2                                                        48500020
* DISPLACEMENTS FROM BEGINNING OF ABDUMP'S WORK AREA TO                 48600020
DECB     EQU   72                       DECB FOR BSAM                   48700020
LINECTR  EQU   92                       LINE COUNTER                    48800020
PAGECTR  EQU   94                       PAGE COUNTER                    48900020
DBLWORD  EQU   336                      DBL WORD USED TO CONVERT-DEC.   49000020
PTRBUF   EQU   348                PTR TO BUFFER FOR BLOCK RECORD        49100020
PTRNEXT  EQU   352                PTR TO NEXT SLOT W/IN BLOCK BUFFER    49200020
PTREOB   EQU   356                PTR TO END OF BLOCK BUFFER            49300020
PHYSICAL EQU   360                      PHYSICAL RECORD LENGTH          49400020
LOGICAL  EQU   364                      LOGICAL RECORD LENGTH           49500020
CCCHAR   EQU   368                      CARRIAGE CONTROL CHARACTER      49600020
         SPACE 2                                                        49700020
* REGISTER 13 IS THE BASE REG FOR THE OUTPUT ROUTINE                    49800020
         USING *-96,RD                                                  49900020
*                                                                       50000020
OUTPUT   LM    RE,R0,PTRBUF(RD)                                         50100020
* RE = PTR TO BUFFER                                                    50200020
* RF = PTR TO NEXT AVAILABLE SLOT IN BUFFER                             50300020
* R0 = END OF BUFFER (RE + SIZE)                                        50400020
         LTR   RE,RE                    TEST, BR, IF RECORDS ARE NOT    50500020
         BC    8,OUTPUT2                TO BE BLOCKED.                  50600020
         MVC   0(125,RF),LOGICAL(RD)    LOGICAL RECORD COUNT, CC CHAR,  50700020
*                                       AND RECORD TO BUFFER.           50800020
         LA    RF,125(RF)               INC PTR TO NEXT SLOT IN BUFFER  50900020
         ST    RF,PTRNEXT(RD)                                           51000020
         LA    R1,125(RF)               CHECK FOR END OF BUFFER         51100020
         CR    R1,R0                    BR IF THERE IS ROOM IN BUFFER   51200020
         BC    12,OUTPUT3               FOR ANOTHER LINE.               51300020
OUTPUT1  SR    RF,RE                    PHYSICAL RECORD LENGTH, AND     51400020
         STH   RF,PHYSICAL(RD)          SYSTEM RESERVED CHARACTERS TO   51500020
         MVC   0(4,RE),PHYSICAL(RD)     BUFFER.                         51600020
         LA    RF,4(RE)                 RESET PTR TO NEXT SLOT AVAIL.   51700020
         ST    RF,PTRNEXT(RD)           IN BUFFER.                      51800020
         SPACE 2                                                        51900020
OUTPUT2  LA    R1,DECB(RD)              ADDRESS OF DECB                 52000020
        WRITE  (1),SF,MF=E                                              52100020
         LA    R1,DECB(RD)              ADDRESS OF DECB                 52200020
        CHECK  (1)                                                      52300020
OUTPUT3  LA    R1,1                     DETERMINE AMOUNT BY WHICH THE   52400020
         LH    R0,LINECTR(RD)           LINE COUNTER IS TO BE BUMPED.   52500020
         CLI   CCCHAR(RD),C'-'                                          52600020
         BL    INCBYONE                 BR IF SPACE 1 , CCCHAR = X'40'  52700020
         BH    INCBYTWO                 BR IF SPACE2 OR EJECT,'F0'-'F1' 52800020
         AR    R0,R1                    SPACE 3, CC CHAR = X'60'        52900020
INCBYTWO AR    R0,R1           *** NOTE-IF EJECT,LINE CT = -1 +2 = 1    53000020
INCBYONE AR    R0,R1                                                    53100020
         MVI   CCCHAR(RD),X'40'         SET CC CHAR,OUTPUT LINE TO      53200020
         MVC   CCCHAR+1(120,RD),CCCHAR(RD)        BLANKS.               53300020
         LA    R1,56                                                    53400020
         CR    R0,R1                    TEST, BR, IF LINE COUNT IS GT   53500020
         BC    10,OUTPUT4               OR EQ TO 56.                    53600020
         STH   R0,LINECTR(RD)                                           53700020
         BR    R5                       EXIT FROM OUTPUT ROUTINE        53800020
         SPACE 2                                                        53900020
OUTPUT4  LH    R1,PAGECTR(RD)           NEW PAGE, BUMP PAGE COUNT BY 1  54000020
         LA    R1,1(R1)                 PUT OUT PAGE LINE.              54100020
         STH   R1,PAGECTR(RD)                                           54200020
         MVI   CCCHAR(RD),C'1'          CC CHAR FOR 'PAGE DDDD'         54300020
         MVC   CCCHAR+109(4,RD),PAGE                                    54400020
         CVD   R1,DBLWORD(RD)           CONVERT PAGE NO. TO DECIMAL     54500020
         UNPK  CCCHAR+114(4,RD),DBLWORD+4(4,RD)                         54600020
         OI    CCCHAR+117(RD),X'F0'     GET RID OF SIGN                 54700020
         MVC   LINECTR(2,RD),MINUSONE   RESET LINE COUNTER              54800020
         B     OUTPUT                                                   54900020
         SPACE 2                                                        55000020
* IF OUTPUT5 CHANGED FROM A DISPLACEMENT OF 280 FROM THE BEGINNING      55100020
* OF ABDUMP'S WORK AREA, A CHANGE IN LOAD 4 OF ABDUMP(IEAAAD03) WILL    55200020
* BE NECESSARY.  (LTOUTPUT  EQU  280)                                   55300020
OUTPUT5  LM    RE,R0,PTRBUF(RD)         LAST TIME ENTRY - CHECK IF      55400020
         LTR   RE,RE                    NECESSARY TO WRITE BUFFER.      55500020
         BCR   8,R5                     NO BUFFER USED, RETURN          55600020
         LA    R1,4(RE)                 BUFFER USED                     55700020
         CR    R1,RF                                                    55800020
         BCR   8,R5                     LAST WRITE EMPTIED BUFFER,EXIT. 55900020
         B     OUTPUT1                  INFO REMAINS TO BE WRITTEN.     56000020
*                                                                       56100020
PAGE     DC    C'PAGE'                                                  56200020
MINUSONE DC    X'FFFF'                                                  56300020
* SYNCHRONOUS EXIT ROUTINE - ENTERED ONLY IF DEVICE IS A PRINTER.       56400020
         RETURN                                                         56500020
*                                                                       56600020
LAST     EQU   *    THIS SYMBOL USED TO DETERMINE SIZE OF OUTPUT RTN.   56700020
         DROP  RD                                                       56800020
         EJECT                                                          56900020
MINMAX  DC    A(256)    MINIMUM BUFFER LENGTH FOR BLOCKING              57000020
         DC    A(1632)   MAXIMUM BUFFER LENGTH FOR BLOCKING (13 LINES)  57100020
*        THE ABOVE MINMAX VALUES ARE BLOCKING LENGTHS FOR PCP           57200020
MINMAX2  DC    A(256)              MFT2  MIN BLOCKING LENGTH       RF0B 57300020
         DC    A(882)              MFT2  MAX BLOCKING LENGTH       RF0B 57400020
NMLOAD2  DC    CL8'IGC0D05A'       NAME OF NEXT LOAD OF ABDUMP     ATCH 57500020
PHYLOG   DC    H'129'                   PHYSICAL RECORD LENGTH          57600020
         DC    C'  '                    SYSTEM-RESERVED CHARACTER       57700020
         DC    H'125'                                                   57800020
         DC    C'  '                    SYSTEM-RESERVED CHARACTER       57900020
         DC    X'0000'             SYSTEM RESERVED CHARACTER       6900 58000020
SYSMASK  DC    X'FF'                                                    58100020
COUNTS   DC    X'00060001'         LINE, PAGE COUNTS USED BY OUTPUT RTN 58200020
QNAME    DC    C'SYSIEA01'         QNAME FOR ENQ MACRO             I250 58300020
ALLZERO  DC    AL3(0)              ZEROES USED FOR COMPARING       I250 58400020
         EJECT                                                          58500020
         DCBD  DSORG=BS,DEVD=PR                                         58600020
         EJECT                                                          58700020
PARDSECT DSECT                                                          58800020
PID      DS    1C                      ID NUMBER LT 128                 58900020
         DS    1C                      RESERVED                         59000020
PFLAGS   DS    2C                      OPTION FLAGS                     59100020
PDCBPTR  DS    1F                      DCB ADDRESS                      59200020
PTCBPTR  DS    1F                      TCB ADDRESS                 I250 59300020
PSNAPPTR DS    1F                      ADDRESS OF SNAPSHOT LIST         59400020
PWORKPTR DS    1F                      ADDR OF WORK AREA      CI A41341 59450000
         EJECT                                                          59500020
ABDAREA  DSECT                                                          59600020
ABDSAVE  DS    18F       SAVE AREA                                      59700020
ABDECB   DS    1F        DECB-ECB                                       59800020
ABDTYPE  DS    1H              TYPE FIELD                               59900020
ABDLEN   DS    1H              LENGTH FIELD                             60000020
ABDDCB   DS    1F              PTR TO DCB                               60100020
ABDPTR   DS    1F              AREA ADDRESS                             60200020
ABDSTAT  DS    1F              PTR TO STATUS INDICATORS                 60300020
*                                                                       60400020
*                                                                       60500020
ABDCTR1  DS    1H        LINE CTR                                       60600020
ABDCTR2  DS    1H        PAGE CTR                                       60700020
*                        OUTPUT ROUTINE                                 60800020
ABDOUT  DS    55F       220 BYTES RESERVED FOR OUTPUT ROUTINE           60900020
*                                                                       61000020
ABDPARA  DS    1F        PTR TO PARAMETER LIST SAVED HERE               61100020
ABDENDLL DS    1F        COMPARAND TO END LOAD LIST TRACE               61200020
ABDWORK3 DS    1C        USED TO MAINTAIN RB SEQUENCE COUNT PREFIX      61300020
ABDWORK4 DS    11C       9 BYTES USED FOR UNPACK AREA                   61400020
ABDWORK1 DS    1D        CONVERT TO DECIMAL AREA,SAVE AREA              61500020
ABDWORK2 DS    1F                 SAVE AREA FOR LINK ADDRESS            61600020
ABDPTRS  DS    3F        BUFFER POINTERS USED BY OUTPUT ROUTINE         61700020
*                        OUTPUT LINE                                    61800020
ABDPHY   DS    2C        PHYSICAL RECORD LENGTH                         61900020
ABDSRC1  DS    2C        SYSTEM-RESERVED CHAR                           62000020
ABDLOG   DS    2C        LOGICAL RECORD LENGTH                          62100020
ABDSRC2  DS    2C        SYSTEM-RESERVED CHAR                           62200020
ABDCC    DS    1C        CARRIAGE-CONTROL CHAR                          62300020
ABDLINE  DS    CL32      120 CHAR PRINT LINE                            62400020
         DS    CL32                                                     62500020
         DS    CL32                                                     62600020
         DS    CL24                                                     62700020
         DS    1C        ONE BYTE FOLLOWING OUTPUT LINE TO BE USED AS   62800020
*                        'OVERFLOW' BYTE WHEN UNPACKING INTO LINE       62900020
         DS    2C                                                       63000020
ABDFLAG  DS    1C        BIT 0 = 1 MEANS DUMP IS FOR TASK OTHER    I250 63100020
*                                  THAN CURRENT ONE                I250 63200020
*                              = 0 MEANS DUMP IS FOR CURRENT TASK  I250 63300020
*                        BIT 1 = 1 MEANS RB CHAIN DOESN'T EXIST    I250 63400020
*                                  FOR TASK BEING DUMPED           I250 63500020
*                              = 0 MEANS RB CHAIN DOES EXIST       I250 63600020
         DS    171C                                                I250 63700020
BBADDR   DS    1F        SAVE BOUNDARY BOX ADDRESS                 I250 63800020
         EJECT                                                          63900020
CVTDSECT DSECT                                                          64000020
         CVT     SYS=INT                                                64100020
         END                                                            64200020
