 TITLE   'IEANTM05 - IGC0501C - ABEND LOAD 5 (MFT ATTACH ONLY)'         00100019
IGC0501C CSECT                                                          00200019
*        ROUTINE NAME - ABEND LOAD 5 (MFT ATTACH ONLY)                * 00300019
         SPACE 4                                                        00400019
*        MODULE  NAME - IEANTM05                                      * 00500019
         SPACE 4                                                        00600019
*        SVCLIB  NAME - IGC0501C                                      * 00700019
         SPACE 4                                                        00800019
*        THE FOLLOWING TABLE IS A LIST OF THE ABEND MODULES FOR       * 00900019
*        AN MFT-ATTACH SYSTEM                                         * 01000019
         SPACE 3                                                        01100019
*        ROUTINE NAME         MODULE NAME         SVCLIB NAME         * 01200019
         SPACE 1                                                        01300019
*        LOAD  0              IEANTM00            IGC0001C            * 01400019
*        LOAD  1              IEANTM01            IGC0101C            * 01500019
*        LOAD  2              IEANTM02            IGC0201C            * 01600019
*        LOAD  3              IEANTM03            IGC0301C            * 01700019
*        LOAD  4              IEANTM04            IGC0401C            * 01800019
*        LOAD  5              IEANTM05            IGC0501C            * 01900019
*        LOAD  6              IEANTM06            IGC0601C            * 02000019
*        LOAD  7              IEANTM07            IGC0701C            * 02100019
*        LOAD  8              IEANTM08            IGC0801C            * 02200019
*        LOAD  9              IEANTM09            IGC0901C            * 02300019
*        LOAD  10             IEANTM0A            IGC0A01C            * 02400019
*        LOAD  11             IEANTM0B *          IGC0B01C            * 02500019
*        LOAD  12             IEANTM0C            IGC0C01C            * 02600019
*        LOAD  13             IEANTM0D            IGC0D01C            * 02700019
*        LOAD  14             IEANTM0E            IGC0E01C            * 02800019
        SPACE 2                                                         02900019
*      * NOTE  THAT IN A SYSTEM WITH THE MCS OPTION THE MODULE        * 03000019
*        NAME FOR LOAD 11 IS IEACTM0B.                                * 03100019
         SPACE 4                                                        03200019
*        BELOW IS A LIST OF THE STAE MODULES USED IN ALL MFT SYSTEMS  * 03300019
         SPACE 2                                                        03400019
*        ROUTINE NAME         MODULE NAME         SVCLIB NAME         * 03500019
         SPACE 1                                                        03600019
*        LOAD  1              IEASTM11            IGC0111C            * 03700019
*        LOAD  2              IEASTM12            IGC0211C            * 03800019
*        LOAD  3              IEASTM13            IGC0311C            * 03900019
*        LOAD  4              IEASTM14            IGC0411C            * 04000019
         SPACE 4                                                        04100019
*        BELOW IS A LIST OF THE DAR MODULES USED IN ALL MFT SYSTEMS   * 04200019
         SPACE 2                                                        04300019
*        ROUTINE NAME         MODULE NAME         SVCLIB NAME         * 04400019
         SPACE 1                                                        04500019
*        LOAD  1              IEADTM22            IGC0221C            * 04600019
*        LOAD  2              IEADTM23            IGC0321C            * 04700019
         EJECT                                                          04800019
*        BELOW IS AN ENTRY-EXIT MATRIX TABLE DESCRIBING THE POSSIBLE  * 04900019
*        ENTRIES AND EXITS TAKEN BY THE ABEND MODULES VIA XCTL. THIS  * 05000019
*        TABLE DOES NOT DESCRIBE SVC OR BRANCH ENTRIES AND EXITS      * 05100019
*        NOR DOES IT DESCRIBE THE STAE,GRAPHICS OR DAR INTERFACES.    * 05200019
*        REFER TO EACH MODULE FOR A LIST OF POSSIBLE ENTRIES AND EXITS* 05300019
         SPACE 5                                                        05400019
*        LOAD 0  EXITS   TO LOADS   1,2,11,14                         * 05500019
*        LOAD 0  ENTERED BY LOADS   11                                * 05600019
*        LOAD 1  EXITS   TO LOADS   11                                * 05700019
*        LOAD 1  ENTERED BY LOADS   0                                 * 05800019
*        LOAD 2  EXITS   TO LOADS   3,9                               * 05900019
*        LOAD 2  ENTERED BY LOADS   0,11                              * 06000019
*        LOAD 3  EXITS   TO LOADS   4                                 * 06100019
*        LOAD 3  ENTERED BY LOADS   2                                 * 06200019
*        LOAD 4  EXITS   TO LOADS   5,7,8,10,12,13,14                 * 06300019
*        LOAD 4  ENTERED BY LOADS   3,9,10                            * 06400019
*        LOAD 5  EXITS   TO LOADS   6,9                               * 06500019
*        LOAD 5  ENTERED BY LOADS   4                                 * 06600019
*        LOAD 6  EXITS   TO LOADS   7,9,12,13,14                      * 06700019
*        LOAD 6  ENTERED BY LOADS   5                                 * 06800019
*        LOAD 7  EXITS   TO LOADS                                     * 06900019
*        LOAD 7  ENTERED BY LOADS   4,6,8,14                          * 07000019
*        LOAD 8  EXITS   TO LOADS   7,13,14                           * 07100019
*        LOAD 8  ENTERED BY LOADS   4                                 * 07200019
*        LOAD 9  EXITS   TO LOADS   4                                 * 07300019
*        LOAD 9  ENTERED BY LOADS   2,5,6                             * 07400019
*        LOAD 10 EXITS   TO LOADS   4                                 * 07500019
*        LOAD 10 ENTERED BY LOADS   4                                 * 07600019
*        LOAD 11 EXITS   TO LOADS   0,2,14                            * 07700019
*        LOAD 11 ENTERED BY LOADS   0,1                               * 07800019
*        LOAD 12 EXITS   TO LOADS   13                                * 07900019
*        LOAD 12 ENTERED BY LOADS   4,6                               * 08000019
*        LOAD 13 EXITS   TO LOADS   14                                * 08100019
*        LOAD 13 ENTERED BY LOADS   4,6,8,12                          * 08200019
*        LOAD 14 EXITS   TO LOADS   7                                 * 08300019
*        LOAD 14 ENTERED BY LOADS   0,4,6,8,11,13                     * 08400019
         EJECT                                                          08500019
*        FUNCTION - ABEND LOAD 5 OPENS THE DUMP DATA SET IF IT IS     * 08600019
*                   NOT ALREADY OPEN AND ENQUES ON THE DATA SET TO    * 08700019
*                   PREVENT ANOTHER TASK FROM WRITING ON IT UNTIL     * 08800019
*                   THE DUMP IS FINSIHED. BELOW IS A DETAILED         * 08900019
*                   NARRATIVE OF LOAD 5 FUNCTIONS.                    * 09000019
         SPACE                                                          09100019
*                        1)  THE DEVICE TO WHICH THE DUMP DATA SET    * 09200019
*                            IS TO BE WRITTEN (UCB ACCESSED BY TIOT)  * 09300019
*                            IS CHECKED TO SEE IF IT IS A TAPE DEVICE * 09400019
*                            TO WHICH A DIRECT SYSOUT WRITER HAS      * 09500019
*                            BEEN STARTED. IF SO, THE ABDUMP FUNCTION * 09600019
*                            WILL BE BYPASSED IF THE ABENDING TASK    * 09700019
*                            IS A SUBTASK. IF THE ABENDING TASK IS    * 09800019
*                            A JOB STEP TASK, THE OPEN DATA SET WILL  * 09900019
*                            BE CLOSED.                               * 10000019
         SPACE                                                          10100019
*                        2)  THE JOB STEP TASK IS CHECKED TO          * 10200019
*                            DETERMINE IF THE DUMP DATA SET IS        * 10300019
*                            ALREADY OPENED. (THE DUMP DATA SET IS    * 10400019
*                            LEFT OPEN ON THE JOB STEP TASK).         * 10500019
         SPACE                                                          10600019
*                        3)  IF THE DUMP DATA SET IS NOT OPEN, THE    * 10700019
*                            ENTIRE TASK TREE IS SEARCHED TO DETERMINE* 10800019
*                            IF ANY TASK IS OPENING THE DUMP DATA SET.* 10900019
*                            IF SO, THE CURRENT TASK IS SET NON-      * 11000019
*                            DISPATCHABLE AND ITS RESUME PSW FIELD    * 11100019
*                            INITIALIZED TO REENTER ABEND LOAD 5.     * 11200019
*                            THE TASK WILL BE SET DISPATCHABLE BY     * 11300019
*                            THE TASK THAT IS OPENING THE DUMP DATA   * 11400019
*                            SET.  EXIT TO THE DISPATCHER IS TAKEN.   * 11500019
         SPACE                                                          11600019
*                        4)  IF NO OTHER TASK IN THIS PARTITION IS    * 11700021
*                            OPENING THE DUMP DATA SET, A GETMAIN     * 11800019
*                            FOR SUBPOOL 240 IS MADE FOR DCB. THE     * 11900019
*                            DCB IS INITIALIZED FOR EITHER 'SYSABEND' * 12000019
*                            OR 'SYSUDUMP'.                           * 12100019
         SPACE                                                          12200019
*                        5)  IF THE CURRENT TASK IS A SUBTASK, ITS    * 12300019
*                            GQE CHAIN IS SAVED OVER OPEN AND ITS     * 12400019
*                            GQE POINTER CLEARED IN ORDER THAT ABEND  * 12500019
*                            CAN RESET THOSE GQES THAT WOULD BE BUILT * 12600019
*                            FOR THE DEB AND THE IOB.                 * 12700019
         SPACE                                                          12800019
*                        6)  THE JPAQ POINTER IN THE PIB IS SAVED     * 12900019
*                            OVER OPEN IN ZEROED IN ORDER TO FORCE    * 13000019
*                            THE LOADING OF NEW ACCESS METHOD ROUTINES* 13100019
         SPACE                                                          13200019
*                        7)  AFTER A SUCCESSFUL OPEN, THE DEB IS      * 13300019
*                            FLAGGED AS THE DUMP DEB. IF THE CURRENT  * 13400019
*                            TASK IS A SUBTASK, THE GQES BUILT OVER   * 13500019
*                            THE OPEN ARE RESET TO SIZE 8, AND THE    * 13600019
*                            DUMP DEB IS DEQUED FROM THE CURRENT TASK * 13700019
*                            AND ENQUED ON THE JOB STEP TASK. THE JOB * 13800019
*                            STEP TASK IS THEN APPROPRIATLY FLAGGED.  * 13900019
*                            THE ENTIRE JOB STEP TASK TREE IS THEN    * 14000019
*                            SEARCHED TO SEE IF ANY TASK HAS SET      * 14100019
*                            ITSELF NON DISPATCHABLE WAITING FOR THE  * 14200019
*                            DUMP DATA SET TO BE OPENED. IF ANY TASK  * 14300019
*                            IS FOUND THEY ARE RESET DISPATCHABLE.    * 14400019
         SPACE                                                          14500019
*                        8)  ALL OF THE CURRENT TASKS SUBTASKS ARE    * 14600019
*                            CHECKED TO DETERMINE IF THEY ARE         * 14700019
*                            CURRENTLY ENQUED ON THE DUMP DATA SET.   * 14800019
*                            BECAUSE THESE SUBTASKS ARE NON-          * 14900019
*                            DISPATCHABLE, THEY MUST BE DEQUED PRIOR  * 15000019
*                            TO THE ISSUANCE OF AN ENQ BY THE         * 15100019
*                            CURRENT TASK. THE DEQUE OF ITS DAUGHTER  * 15200019
*                            TASKS IS ACCOMPLISHED BY A BRANCH        * 15300019
*                            ENTRY TO DEQUE.                          * 15400019
         SPACE                                                          15500019
*                        9)  AN ENQ IS THEN ISSUED ON THE DUMP DATA   * 15600019
*                            SET AND EXIT TO LOAD 6 IS MADE TO        * 15700019
*                            CALL ABDUMP                              * 15800019
         EJECT                                                          15900019
*        APPLICABILITY - OPTION 2 (MFT) SYSTEM WITH THE ATTACH OPTION * 16000019
         SPACE 4                                                        16100019
*        ATTRIBUTES - REENTRANT,REFRESHABLE                           * 16200019
         SPACE 4                                                        16300019
*        ENTRY POINT - IGC0501C                                       * 16400019
         SPACE 4                                                        16500019
*        INPUT - SETTING THE SYSABEND OR SYSUDUMP BIT IN THE TCB      * 16600019
         SPACE 4                                                        16700019
*        OUTPUT -  AN OPEN DCB FOR THE DUMP DATA SET.                 * 16800019
*               -  THE FLAGGING OF THE DUMP DEB.                      * 16900019
*               -  THE SETTING OF THE DUMP DATA SET OPEN BIT IN THE   * 17000019
*                  JOB STEP TCB.                                      * 17100019
         SPACE 4                                                        17200019
*        ENTERED BY - ABEND LOAD 4 WHEN AN ABDUMP IS REQUESTED AND    * 17300019
*                     A SYSABEND OR SYSUDUMP DD CARD IS INCLUDED.     * 17400019
         SPACE 4                                                        17500019
*        EXITS TO - ABEND LOAD 6 IF THE DUMP DATA SET IS OPEN         * 17600019
*                 - ABEND LOAD 9 IF THE DUMP DATA SET COULD NOT       * 17700019
*                   BE OPENED.                                        * 17800019
         SPACE 4                                                        17900019
*        WORK AREAS - THE TWELVE WORDS OF ABENDS EXTENDED SAVE AREA.  * 18000019
         SPACE 4                                                        18100019
*        NOTES - IF FOR ANY REASON THE OPEN OF THE DUMP DATA SET      * 18200019
*                 CANNOT BE MADE, THE OPEN IN PROCESS BIT MUST BE     * 18300019
*                 ON WHEN PASSING CONTROL TO ABEND LOAD 9 SO THAT     * 18400019
*                 HE CAN IDENTIFY THE FAILURE AS OPEN.                * 18500019
         SPACE 4                                                        18600019
*        EXTERNAL REFERENCES - IEATCBP (DISPATCHERS NEW-OLD).         * 18700019
*                            - IEA0AB00 - ENTRY POINT OF ABTERM       * 18800019
*                            - IEA0DS   - ENTRY POINT OF DISPATCHER   * 18900019
         SPACE 4                                                        19000019
*        TABLES AND CONTROL BLOCKS REFERENCED                         * 19100019
*              CVT,TCB,RB,TIOT,DEB,GQE,PIB,UCB                        * 19200019
         SPACE 4                                                        19300019
*        SVC'S USED - XCTL    -7                                      * 19400019
*                     GETMAIN -10                                     * 19500019
*                     OPEN    -19                                     * 19600019
*                     CLOSE   -20                                     * 19700019
*                     ENQ     -56                                     * 19800019
         EJECT                                                          19900019
         BALR  BASE,R0                  ESTABLISH                       20000019
         USING *,BASE                   ADDRESSABILITY                  20100019
START    SSM   DISABLE                  DISABLE PSW           AC A44100 20200021
         B     BEGIN                    BR AROUND IDENTIFIER  AC A44100 20300021
         DC    C'IGC0501C'                                              20400019
BEGIN    EQU   *                                                        20500019
         L     CVTREG,CVTPTR            GET CVT ADDR                    20600019
         USING CVTDSECT,CVTREG          CVT DSECT                       20700019
         USING TCBSECT,TCBREG           TCB DSECT                       20800019
         USING RBSECT,RBREG             RB  DSECT                       20900019
         USING TCBSECTP,TEMPTCB         ALT TCB DSECT                   21000019
         L     TCBREG,CVTTCBP           GET NEW-OLD PTR                 21100019
         L     TCBREG,FOUR(TCBREG)      GET TCB ADDR                    21200019
         L     RBREG,TCBRBP             GET RB ADDR                     21300019
         L     TIOTREG,TCBTIO           GET TIOT                        21400019
         LA    TIOTREG,N24(TIOTREG)     BYPASS INITIAL PART             21500019
         L     TEMPTCB,TCBFTJST         GET JOB STEP                    21600019
         L     MSS,TCBMSSP              GET JS BB                       21700019
         NC    FOUR(EIGHT,MSS),FOUR(MSS) Q. ONLY H1                     21800019
         BNZ   SKIPLCS                  NO-BRANCH                       21900019
         LA    MSS,TWELVE(MSS)          GET PTR TO LCS BB               22000019
SKIPLCS  EQU   *                                                        22100019
         L     MSS,EIGHT(MSS)           GET TOP OF PART                 22200019
TIOLOOP  EQU   *                                              AB A65738 22300021
         L     TIOTREG,124(RBREG)       @ DD CARD FROM 401C   AB A65738 22500021
         LTR   TIOTREG,TIOTREG          DD EXIST              AB A65738 22700021
         BE    TORECLD                  NO, NO SYSABEND CARD  AB A65738 22900021
         SPACE 2                                                        23300019
*        THE FOLLOWING CODE CHECKS IF A DIRECT SYSOUT                   23400019
*        WRITER HAS BEEN STARTED TO TAPE.                               23500019
         SPACE 2                                                        23600019
FOUND    EQU   *                                                        23700019
         L     TIOTREG,N16(TIOTREG)     GET UCB ADDR                    23800019
         LA    TIOTREG,ZERO(TIOTREG)    CLEAR HI BYTE                   23900019
         LTR   TIOTREG,TIOTREG          Q. IS THI DD DUMMY    AH A49243 23950021
         BZ    TORECLD                  YES. BYPASS DUMP      AH A49243 23960021
         TM    N18(TIOTREG),TAPE        Q. TAPE DEVICE                  24000019
         BZ    MCKMSE                   NO-BRANCH                       24100019
         TM    DSPSYBIT(TIOTREG),SWTR   Q. DIRECT SYSOUT WTR STARTED    24200019
         BZ    MCKMSE                   NO-BRANCH                       24300019
         CL    TCBREG,TCBFTJST          Q. JOB STEP                     24400019
         BNE   TORECLD                  NO-BYPASS DUMP                  24500019
         LR    TEMPTCB,TCBREG                                           24600019
         B     FIRSTDEB                 CHECK CURRENT                   24700019
DSDEB    BAL   RETURN,GETTCB            GET LOWER TASK                  24800019
         B     MCKMSE                   RETURN HERE IF TREE SEARCHED    24900019
         SPACE 4                                                        25000019
FIRSTDEB EQU   *                                                        25100019
         L     DEBREG,TCBDEBP           RETURN HERE IF TASK FOUND       25200019
         LA    SAVE,TCBDEBP             GET ADDR FOR RELINK             25300019
         SH    SAVE,HALF8               ADJUST DISP                     25400019
         USING DEBSECT,DEBREG                                           25500019
DEBLOOP  EQU   *                                                        25600019
         LA    DEBREG,ZERO(DEBREG)      CLEAR HI BYTE                   25700019
         LTR   DEBREG,DEBREG            Q. ANY DEB                      25800019
         BZ    DSDEB                    NO-BRANCH                       25900019
         L     WKREG,N32(DEBREG)        GET UCB                         26000019
         LA    WKREG,ZERO(WKREG)        CLEAR HI BYTE                   26100019
         CLR   WKREG,TIOTREG            DEB ON THIS DEVICE              26200019
         BE    FOUNDDS                  YES-BRANCH                      26300019
         LR    SAVE,DEBREG              SAVE LAST DEB                   26400019
         L     DEBREG,DEBDEBAD          GET NEXT DEB                    26500019
         B     DEBLOOP                  TO NEXT DEB                     26600019
FOUNDDS  EQU   *                                                        26700019
         CLR   TCBREG,TEMPTCB           Q. CURRENT TCB                  26800019
         BE    SKDEBDEQ                 YES-BRANCH                      26900019
         MVC   NINE(THREE,SAVE),DEBDEBAD+ONE DEQUE DEB                  27000019
         IC    WKREG,DEBTCBAD           SAVE HI BYTE                    27100019
         ST    TCBREG,DEBTCBAD          CHANGE TCB ADDRESS              27200019
         STC   WKREG,DEBTCBAD           STORE HI BYTE                   27300019
         MVC   DEBDEBAD+ONE(THREE),TCBDEB+ONE PUT DEB ON                27400019
         ST    DEBREG,TCBDEB            CURRENT TCB                     27500019
SKDEBDEQ EQU   *                                                        27600019
         MVC   XESAXCTL(FOUR),DEBDCBAD  MOVE IN DCB                     27700019
         MVI   XESAXCTL,HEX80           INDICATE END OF LIST            27800019
         MVI   TCBRECDE,TCBREC+TCBOPEN  SET REC BITS FOR OPEN     21372 27900021
         LA    R1,XESAXCTL              GET ADDR OF  CLOSE LIST         28100019
         CLOSE MF=(E,(1))               CLOSE DS                        28200019
         EJECT                                                          28300019
MCKMSE   EQU   *                                                        28400019
         L     TEMPTCB,TCBFTJST         GET JS TCB                      28500019
         TM    TCBFL2P+ONE,TCBFDSOP     Q. DUMP DS ALREADY OPENED       28600019
         BO    CKENQ                    YES-BRANCH                      28700019
         ST    TCBREG,XESAWD1           SAVE TCB REG                    28800019
         LR    TCBREG,TEMPTCB                                           28900019
         SPACE 2                                                        29000019
*        CHECK IF OPEN OF DUMP DATA SET ALREADY IN PROGRESS             29100019
         SPACE 2                                                        29200019
PRECK    BAL   RETURN,GETTCB            GET LOWER TASK                  29300019
         B     TCBFIX                   RETURN HERE IF TASK NOT FOUND   29400019
         CLI   TCBRECDP,TCBREC+TCBOPEN  RETURN HERE IF TASK FOUND 21372 29500021
*                                       Q.IS DS OPEN ON THIS TASK 21372 29550021
         BNE   PRECK                    BRANCH-OPEN NOT IN PROC   21372 29600021
         L     TCBREG,XESAWD1           RELOAD TCB REG                  29700019
         MVC   XRBPSW+FIVE(THREE),XRBEP+ONE INITIALIZE PSW              29800019
         OI    TCBNDFL+ONE,TCBONDSP     SET MYSELF                      30000019
         OI    TCBFLGS+FOUR,PRIMNDFL    NON-DISP.                       30100019
GODISP   EQU   *                                                        30200019
         MVI   XRBPSW,ALL               ENABLE RESUME PSW               30250019
         MVI   TCBRECDE,OFF             TURN OFF PRIMARY REC.     21372 30300021
*                                        TURN OFF OPEN IND.       21372 30400021
         BAL   WKREG,TOTASKX            GO CHECK FOR TASK SWITCH        30500019
         L     WKREG,CVTTCBP            GET NEW-OLD                     30600019
         CLC   ZERO(FOUR,WKREG),FOUR(WKREG) TASK SWITCH                 30700019
         BNE   SKNWCHG                  YES-BRANCH                      30800019
         XC    ZERO(FOUR,WKREG),ZERO(WKREG) ZERO NEW                    30900019
SKNWCHG  EQU   *                                                        31000019
         L     WKREG,CVT0DS             GET DISP EPA                    31100019
         BR    WKREG                    TO DISPATCHER                   31200019
         EJECT                                                          31300019
TCBFIX   EQU   *                                                        31400019
         L     TCBREG,XESAWD1           RESTORE TCB REG                 31500019
         LA    R0,ENDDCB-SNAPDCB        GET SIZE OF DCB                 31600019
         O     R0,SP240                 INSURE DCB NOT GQED             31700019
         GETMAIN  R,LV=(0)              GET CORE FOR DCB                31800019
         LTR   R15,R15                  Q. CORE OBTAINED                31900019
         BNZ   TORECLD                  NO-GO TO RECURSIVE LOAD         32000019
         MVC   ZERO(DCBSZE,R1),SNAPDCB  MOVE IN DCB                     32100019
         ST    R1,XESAWD2               MOVE ADDR FOR OPEN              32200019
         L     TEMPTCB,TCBFTJST         GET JOB STEP TASK               32300019
         TM    TCBFL2P+ONE,TCBSYSAB     Q. SYSABEND DATA SET            32400019
         BO    NOCHANGE                 YES-BRANCH                      32500019
         MVC   N40(EIGHT,R1),SYSUD      MOVE IN SYSUDUMP                32600019
         SPACE 4                                                        32700019
NOCHANGE EQU   *                                                        32800019
         MVI   XESAWD2,HEX8F            FLAG FOR OPEN                   32900019
         MVI   TCBRECDE,TCBREC+TCBOPEN  SET OPEN RECURSION BITS   21372 33000021
         CL    TCBREG,TCBFTJST          Q. JOB STEP TASK                33200019
         BE    TOOPEN                   YES-BRANCH                      33300019
         L     WKREG,TCBMSS             GET MSS PTR                     33400019
         MVC   XESAWD1(FOUR),ZERO(WKREG) SAVE GQE CHAIN                 33500019
         XC    ZERO(FOUR,WKREG),ZERO(WKREG)  ZERO GQE PTR               33600019
TOOPEN   EQU   *                                                        33700019
         L     RETURN,TCBPIB            GET PIB PTR                     33800019
         MVC   XESAWD7+ONE(THREE),JPQ+ONE(RETURN)  SAVE JPAQ PTR        33900019
         XC    JPQ+ONE(THREE,RETURN),JPQ+ONE(RETURN)  ZERO JPAQ         34000019
*                                       TO FORCE NEW ACCESS             34100019
         LR    SAVE,R1                  SAVE DCB ADDR                   34200019
         LA    R1,XESAWD2               GET ADDR OF OPENS LIST          34300019
         OPEN  MF=(E,(1))               OPEN DUMP DS                    34400019
         SPACE 4                                                        34500019
         MVC   JPQ+ONE(THREE,RETURN),XESAWD7+ONE  RESTORE JPAQ          34600019
         TM    N48(SAVE),HEX10          Q. DCB OPENED                   34700019
         BZ    TORECLD                  NO DUMP D.S. NOT OPENED         34800021
         L     DEBREG,TCBDEB            GET DEB                         34900019
         OI    TWELVE(DEBREG),DEBABND   FLAG AS ABEND DEB               35000019
         CL    TCBREG,TCBFTJST          Q. JOB STEP TASK                35100019
         BE    CKENQ                    YES-BRANCH                      35200019
         LA    WKREG,EIGHT              INITIALIZE REG                  35300019
         L     MSS,TCBMSS               GET MSS PTR                     35400019
GQELOOP  EQU   *                                                        35500019
         LR    SAVE,MSS                 SAVE LAST GQE                   35600019
         L     MSS,ZERO(MSS)            GET NEXT GQE                    35700019
         LTR   MSS,MSS                  Q. GQE EXIST                    35800019
         BZ    FIXDEB                   NO-BRANCH                       35900019
         ST    WKREG,FOUR(MSS)          INITIALIZE GQE                  36000019
         B     GQELOOP                  DO ALL GQES AFTER OPEN          36100019
         EJECT                                                          36200019
FIXDEB   EQU   *                                                        36300019
         MVC   ZERO(FOUR,SAVE),XESAWD1  REHOOK GQE CHAIN                36400019
         L     TEMPTCB,TCBFTJST         GET JOB STEP                    36500019
         MVC   TCBDEB+ONE(THREE),FIVE(DEBREG) DEQUE DEB FROM CURR TASK  36600019
         MVC   FIVE(THREE,DEBREG),TCBDEBP+ONE PUT DEB ON JS TASK        36700019
         IC    WKREG,DEBTCBAD           SAVE HI BYTE                    36800019
         ST    TEMPTCB,DEBTCBAD         STORE NEW TCB ADDR              36900019
         STC   WKREG,DEBTCBAD           RESTORE HI BYTE                 37000019
         ST    DEBREG,TCBDEBP           FIX JS DEB FIELD                37100019
         OI    TCBFL2P+ONE,TCBFDSOP     FLAG DUMP DS OPEN ON JS         37200019
         ST    TCBREG,XESAWD4           SAVE TCB REG                    37300019
         LR    TCBREG,TEMPTCB           FORCE FULL TREE SEARCH          37400019
         B     SETDISP                  SET JOB STEP DISP        A39431 37450020
         SPACE 3                                                        37500019
GETMORE  BAL   RETURN,GETTCB            GET TASK                        37600019
         B     CKTOP                    RETURN HERE IF TASK NOT FOUND   37700019
SETDISP  EQU   *                                                 A39431 37750020
         NI    TCBNDFLP+ONE,ALL-TCBONDSP    RETURN HERE IF TASK FOUND   37800019
         NC    TCBDAR(FOUR),TCBDAR      Q. SHOULD PRIMARY BE SHUT OFF   37900019
         BNZ   GETMORE                  NO-BRANCH                       38000019
         NI    TCBFLGSP+FOUR,ALL-PRIMNDFL TURN OFF PRIMARY              38100019
         B     GETMORE                  GET MORE TCBS                   38200019
CKTOP    EQU   *                                                        38300019
         L     TCBREG,XESAWD4           RELOAD TCB REG                  38400019
         LR    TEMPTCB,TCBREG                                           38500019
TCBLOOP  EQU   *                                                        38600019
         L     TEMPTCB,TCBOTCP          GET MOTHER                      38700019
         LTR   TEMPTCB,TEMPTCB          MOTHER EXIST                    38800019
         BZ    CKENQ                    NO-BRANCH                       38900019
         TM    TCBFL2P,TCBFT            Q. HIGHER TASK ABENDING         39000019
         BZ    TCBLOOP                  NO-BRANCH                       39100019
         OI    TCBNDFL+TWO,TCBAWF       SET MYSELF                      39200019
         OI    TCBFLGS+FOUR,PRIMNDFL    NON-DISP                        39300019
         B     GODISP                   GIVE UP CONTROL                 39400019
CKENQ    EQU   *                                                        39500019
         MVI   TCBRECDE,TCBREC+TCBADUMP TURN ON DUMP REC          21372 39600021
*                                       OPEN REC FLAGS OFF        21372 39700021
         LR    TEMPTCB,TCBREG           INITIALIZE REG                  39800019
GETFENQ  BAL   RETURN,GETTCB            GET LOWER TASK                  39900019
         B     TOENQ                    RETURN HERE IF TREE DONE        40000019
         TM    TCBFL2P,TCBENQ           RETURN HERE IF TASK FOUND       40100019
         BZ    GETFENQ                  BRANCH IF NOT ENQUED            40200019
         BAL   RETURN,ENQDEQ            BUILD DEQ PARAM LIST            40300019
         EJECT                                                          40400019
*        BRANCH LINKAGE TO DEQ IS AS FOLLOWS                            40500019
*                   1. TCB TO BE DEQUED IN REG 4.                       40600019
*                   2. RETURN ADDRESS IN XESAWD7                        40700019
*                   3. PARAMETER LIST ADDR IN REG 1.                    40800019
         SPACE 5                                                        40900019
         ST    TEMPTCB,XESAWD6          SAVE LAST TCB                   41000019
         LA    RETURN,BACKDEQ           GET RETURN ADDR                 41100019
         ST    RETURN,XESAWD7           SAVE IT                         41200019
         L     WKREG,CVTBTERM           GET ABTERMS EPA                 41300019
         L     WKREG,EIGHT(WKREG)       GET DEQ BRANCH                  41400019
         LR    TCBREG,TEMPTCB           DEQ TASK FROM DUMP DS           41500019
         BR    WKREG                                                    41600019
BACKDEQ  BALR  BASE,R0                  REESTABLISH                     41700019
FINIS    LA    WKREG,FIXBASE            ADDRESSABILITY                  41800019
         SR    BASE,WKREG               FIX BASE                        41900019
         L     CVTREG,CVTPTR            GET CVT                         42000019
         L     TCBREG,CVTTCBP           GET NEW-OLD                     42100019
         L     TCBREG,FOUR(TCBREG)      GET TCB                         42200019
         L     RBREG,TCBRBP             GET RB                          42300019
         L     TEMPTCB,XESAWD6          GET LAST TCB DEQUED             42400019
         NI    TCBFL2P,ALL-TCBENQ       TURN OFF ENQ BIT                42500019
         B     GETFENQ                                                  42600019
         EJECT                                                          42650021
TOENQ    EQU   *                                                        42700019
         BAL   RETURN,ENQDEQ            BUILD ENQ PARAM LIST            42800019
         OI    TCBFL2,TCBENQ            SET ENQ BIT                     42900019
         ENQ   (,,E,,STEP),MF=(E,(1))   ENQ ON DUMP DS                  43000019
         LA    SAVE,LOAD6               TO ABDUMP                       43100019
         SPACE 4                                                        43200019
GOODBYE  BAL   WKREG,TOTASKX            CHECK FOR HIGHER READY TASK     43300019
         ST    SAVE,XESAXCTL            STORE ADDR OF NEXT LOAD NM      43400019
         LA    R0,FIVE                                                  43500019
         LA    R15,XESAXCTL             GET ADDR OF XCTL LIST           43600019
         XCTL  SF=(E,(15))              TO NEXT LOAD                    43700019
         EJECT                                                          43800019
GETTCB   EQU   *                                                        43900019
         LR    WKREG,TEMPTCB            SAVE LAST TCB                   44000019
         L     TEMPTCB,TCBLTCP          GET DAUGHTER                    44100019
SUBSRCH  EQU   *                                                        44200019
         LTR   TEMPTCB,TEMPTCB          Q. TASK FOUND                   44300019
         BNZ   FOUR(RETURN)             YES-RETURN                      44400019
         CLR   WKREG,TCBREG             Q. TREE SEARCHED                44500019
         BCR   E,RETURN                 YES-RETURN                      44600019
         L     TEMPTCB,NTC(WKREG)       GET SISTER                      44700019
         L     WKREG,OTC(WKREG)         INITIALIZE WITH MOTHER          44800019
         B     SUBSRCH                  CONTINUE SEARCH                 44900019
         SPACE 5                                                        45000019
*        THE FOLLOWING ROUTINE PREPARES AN ENQDEQ PARAMETER LIST        45100019
*        IN THE FIRST SIX WORDS OF THE EXTENDED SAVE AREA               45200019
         SPACE 2                                                        45300019
ENQDEQ   EQU   *                                                        45400019
         MVC   XESAXCTL(N16),MAJOR      MOVE IN MAJOR AND MINOR NAMES   45500019
*                                       AND FLAGS                       45600019
         LA    R1,XESAXCTL              GET ADDR OF MAJOR NAME          45700019
         ST    R1,XESAWD4               STORE IT                        45800019
         LA    R1,XESAWD2               GET ADDR OF MINOR NAME          45900019
         ST    R1,XESAWD5               STORE IT                        46000019
         LA    R1,XESAWD3               GET ADDR OF PARAM LIST          46100019
         BR    RETURN                   RETURN TO CALLER                46200019
         SPACE 5                                                        46300019
TORECLD  EQU   *                                                        46400019
         NI    TCBRECDE,ALL-TCBREC      TURN OFF RECURSIVE BIT    21372 46500021
         NI    TCBCMP,ALL-TCBDUMP       TURN OFF DUMP BIT    AB  A49243 46550021
         LA    SAVE,LOAD9               TO RECURSION LOAD               46600019
         B     GOODBYE                  TO XCTL INTERFACE               46700019
         SPACE 5                                                        46800019
TOTASKX  EQU   *                                                        46900019
         L     RETURN,CVTTCBP           GET NEW OLD ADDR.               47000019
         L     RETURN,EIGHT(RETURN)     GET TASK SWITCH EPA             47100019
         SR    R0,R0                    NEGATIVE VALUE                  47200019
         BCTR  R0,R0                    INDICATES FULL SEARCH           47300019
         BALR  RETURN,RETURN            TO TASK SWITCH                  47400019
         BR    WKREG                    RETURN TO CALLER                47500019
         EJECT                                                          47600019
         IHBMFTAB                                                       47700019
         EJECT                                                          47800019
IGC0501C CSECT                                                          47900019
*                                  CONSTANTS                            48000019
         DS    0F                                                       48100019
SYSUD    DC    C'SYSUDUMP'                                              48200019
LOAD6    DC    C'IGC0601C'                                              48300019
LOAD9    DC    C'IGC0901C'                                              48400019
SYSAB    EQU   *                                                        48500019
MAJOR    DC    C'SYSABEND'                                              48600019
         DC    C'DUMP'                                                  48700019
         DC    X'FF040100'                                              48800019
HALF8    DC    H'8'                                                     48900019
         DS    0F                                                       49000019
SP240    DC    X'F0000000'                                              49100019
SNAPDCB  DCB   DSORG=PS,MACRF=W,DDNAME=SYSABEND,RECFM=VBA,             X49200019
               BLKSIZE=882,LRECL=125                                    49300019
ENDDCB   EQU   *                                                        49400019
DISABLE  DC    X'00'                                                    49500019
         SPACE 5                                                        49600019
*                                  REGISTERS                            49700019
R0       EQU   0                                                        49800019
R1       EQU   1                                                        49900019
BASE     EQU   2                                                        50000019
CVTREG   EQU   3                                                        50100019
TCBREG   EQU   4                                                        50200019
RBREG    EQU   5                                                        50300019
TEMPTCB  EQU   6                                                        50400019
WKREG    EQU   7                                                        50500019
SAVE     EQU   8                                                        50600019
DEBREG   EQU   9                                                        50700019
MSS      EQU   10                                                       50800019
TIOTREG  EQU   11                                                       50900019
RETURN   EQU   14                                                       51000019
R15      EQU   15                                                       51100019
         SPACE 5                                                        51200019
*                                  EQUATES                              51300019
NINE     EQU   9                                                        51400019
N16      EQU   16                                                       51500019
N18      EQU   18                                                       51600019
N24      EQU   24                                                       51700019
N32      EQU   32                                                       51800019
N40      EQU   40                                                       52000019
JPQ      EQU   44                                                       52010019
N48      EQU   48                                                       52100019
DSPSYBIT EQU   12                                                       52200019
NTC      EQU   128                                                      52300019
OTC      EQU   132                                                      52400019
FIXBASE  EQU   FINIS-START                                              52500019
DCBSZE   EQU   ENDDCB-SNAPDCB                                           52600019
PRIMNDFL EQU   X'01'                                                    52700019
HEX10    EQU   X'10'                                                    52800019
TAPE     EQU   X'80'                                                    52900019
SWTR     EQU   X'40'                                                    53000019
DEBABND  EQU   X'80'                                                    53100019
HEX80    EQU   X'80'                                                    53200019
HEX8F    EQU   X'8F'                                                    53300019
         EJECT                                                          53350021
*                                                                       53360021
* THE FOLLOWING SPACE IS RESERVED FOR MAINTENANCE                       53370021
         DC    H'0'                                           AC A37447 53380021
         DC    H'0'                                           AC A37447 53390021
         DC    H'0'                                           AC A37447 53392021
         DC    H'0'                                           AC A37447 53394021
         DC    H'0'                                           AC A37447 53396021
         DC    H'0'                                           AC A37447 53398021
         DC    H'0'                                           AC A37447 53398421
         DC    H'0'                                           AC A37447 53398821
         DC    H'0'                                           AC A37447 53399221
         DC    H'0'                                           AC A37447 53399621
         DC    H'0'                                           AC A37447 53399721
         DC    H'0'                                           AC A37447 53399821
         DC    H'0'                                           AC A37447 53449821
         DC    H'0'                                           AC A37447 53499821
         END                                                            53499921
