 TITLE    'IEANTM0J - IGC0J01C - ABEND LOAD J (MFT ATTACH)'             00100000
IGC0J01C CSECT                                                          00200000
* MOST RECENT CHANGES WERE MADE IN RELEASE 21.6               AC A48298 00250021
* ABEND J WAS SPLIT FROM ABEND 3 FOR MFT STEAL CORE PROBLEM   CE A35198 00300000
*        ROUTINE NAME - ABEND LOAD J                                  * 00400000
         SPACE 3                                                        00500000
*        MODULE  NAME - IEANTM0J                                      * 00600000
         SPACE 3                                                        00700000
*        SVCLIB  NAME - IGC0J01C                                      * 00800000
         SPACE 3                                                        00900000
*        THE FOLLOWING TABLE IS A LIST OF THE ABEND MODULES FOR       * 01000000
*        AN MFT,MFT-ATTACH SYSTEM                                     * 01100000
         SPACE 3                                                        01200000
*        ROUTINE NAME         MODULE NAME         SVCLIB NAME         * 01300000
         SPACE 1                                                        01400000
*        LOAD  0              IEANTM00            IGC0001C            * 01500000
*        LOAD  G              IEANTM0G            IGC0G01C            * 01600000
*        LOAD  M              IEANTM0M            IGC0M01C            * 01700000
*        LOAD  1              IEANTM01            IGC0101C            * 01800000
*        LOAD  2              IEANTM02            IGC0201C            * 01900000
*        LOAD  3              IEANTM03            IGC0301C            * 02000000
*        LOAD  J              IEANTM0J ***        IGC0J01C            * 02100000
*        LOAD  4              IEANTM04            IGC0401C            * 02200000
*        LOAD  5              IEANTM05 **         IGC0501C            * 02300000
*        LOAD  6              IEANTM06            IGC0601C            * 02400000
*        LOAD  7              IEANTM07            IGC0701C            * 02500000
*        LOAD  8              IEANTM08            IGC0801C            * 02600000
*        LOAD  9              IEANTM09            IGC0901C            * 02700000
*        LOAD  H              IEANTM0H            IGC0H01C            * 02800000
*        LOAD  10             IEANTM0A            IGC0A01C            * 02900000
*        LOAD  11             IEANTM0B *          IGC0B01C            * 03000000
*        LOAD  12             IEANTM0C ***        IGC0C01C            * 03100000
*        LOAD  13             IEANTM0D ***        IGC0D01C            * 03200000
*        LOAD  14             IEANTM0E ***        IGC0E01C            * 03300000
*        LOAD  15             IEANTM0F ***        IGC0F01C            * 03400000
        SPACE 2                                                         03500000
*      * NOTE  THAT IN A SYSTEM WITH THE MCS OPTION THE MODULE        * 03600000
*        NAME FOR LOAD 11 IS IEACTM0B.                                * 03700000
         SPACE 2                                                        03800000
         SPACE 2                                                        03900000
*     ** NOTE THAT IN AN MFT SYSTEM WITHOUT ATTACH, THE MODULE        * 04000000
*        NAME FOR LOAD 5 IS IEAMTM05.                                 * 04100000
         SPACE 2                                                        04200000
*    *** NOTE THAT IN A SYSTEM WITHOUT ATTACH,                        * 04300000
*        LOADS 12,13,14,15 AND J DO NOT EXIST                         * 04400000
         SPACE 4                                                        04500000
*        BELOW IS A LIST OF THE STAE MODULES USED IN ALL MFT SYSTEMS  * 04600000
         SPACE 2                                                        04700000
*        ROUTINE NAME         MODULE NAME         SVCLIB NAME         * 04800000
         SPACE 1                                                        04900000
*        LOAD  1              IEASTM11            IGC0111C            * 05000000
*        LOAD  2              IEASTM12            IGC0211C            * 05100000
*        LOAD  3              IEASTM13            IGC0311C            * 05200000
*        LOAD  4              IEASTM14            IGC0411C            * 05300000
         SPACE 4                                                        05400000
*        BELOW IS A LIST OF THE DAR MODULES USED IN ALL MFT SYSTEMS   * 05500000
         SPACE 2                                                        05600000
*        ROUTINE NAME         MODULE NAME         SVCLIB NAME         * 05700000
         SPACE 1                                                        05800000
*        LOAD  1              IEADTM22            IGC0221C            * 05900000
*        LOAD  2              IEADTM23            IGC0321C            * 06000000
*        LOAD  3              IEADTM24            IGC0421C            * 06100000
*        LOAD  4              IEADTM25            IGC0521C            * 06200000
         EJECT                                                          06300000
*        BELOW IS AN ENTRY-EXIT MATRIX TABLE DESCRIBING THE POSSIBLE  * 06400000
*        ENTRIES AND EXITS TAKEN BY THE ABEND MODULES VIA XCTL. THIS  * 06500000
*        TABLE DOES NOT DESCRIBE SVC OR BRANCH ENTRIES AND EXITS      * 06600000
*        NOR DOES IT DESCRIBE THE STAE,GRAPHICS OR DAR INTERFACES.    * 06700000
*        REFER TO EACH MODULE FOR A LIST OF POSSIBLE ENTRIES AND EXITS* 06800000
         SPACE 5                                                        06900000
*        LOAD 0  EXITS   TO LOADS   G,11,12                           * 07000000
*        LOAD 0  ENTERED BY LOADS   11                                * 07100000
*        LOAD G  EXITS   TO LOADS   1,2,M                               07200000
*        LOAD G  ENTERED BY LOADS   0,M                                 07300000
*        LOAD M  EXITS   TO LOAD    G                                   07400000
*        LOAD M  ENTERED BY LOAD    G                                   07500000
*        LOAD 1  EXITS   TO LOADS   11                                * 07600000
*        LOAD 1  ENTERED BY LOADS   0                                 * 07700000
*        LOAD 2  EXITS   TO LOADS   3,9                               * 07800000
*        LOAD 2  ENTERED BY LOADS   0,11                              * 07900000
*        LOAD 3  EXITS   TO LOADS   4,J                               * 08000000
*        LOAD 3  ENTERED BY LOADS   2                                 * 08100000
*        LOAD J  EXITS   TO LOADS   4                                 * 08200000
*        LOAD J  ENTERED BY LOADS   3                                 * 08300000
*        LOAD 4  EXITS   TO LOADS   5,7,8,10,12,13,14                 * 08400000
*        LOAD 4  ENTERED BY LOADS   3,9,10,H,J                        * 08500000
*        LOAD 5  EXITS   TO LOADS   6,9                               * 08600000
*        LOAD 5  ENTERED BY LOADS   4                                 * 08700000
*        LOAD 6  EXITS   TO LOADS   7,9,12,13,14                      * 08800000
*        LOAD 6  ENTERED BY LOADS   5                                 * 08900000
*        LOAD 7  EXITS   TO LOADS                                     * 09000000
*        LOAD 7  ENTERED BY LOADS   4,6,8,14                          * 09100000
*        LOAD 8  EXITS   TO LOADS   7,13,14                           * 09200000
*        LOAD 8  ENTERED BY LOADS   4                                 * 09300000
*        LOAD 9  EXITS   TO LOADS   4,H                               * 09400000
*        LOAD 9  ENTERED BY LOADS   2,5,6                             * 09500000
*        LOAD H  EXITS   TO LOADS   4                                 * 09600000
*        LOAD H  ENTERED BY LOADS   9                                 * 09700000
*        LOAD 10 EXITS   TO LOADS   4                                 * 09800000
*        LOAD 10 ENTERED BY LOADS   4                                 * 09900000
*        LOAD 11 EXITS   TO LOADS   0,2,14                            * 10000000
*        LOAD 11 ENTERED BY LOADS   0,1                               * 10100000
*        LOAD 12 EXITS   TO LOADS   13                                * 10200000
*        LOAD 12 ENTERED BY LOADS   0,4,6                             * 10300000
*        LOAD 13 EXITS   TO LOADS   14                                * 10400000
*        LOAD 13 ENTERED BY LOADS   4,6,8,12                          * 10500000
*        LOAD 14 EXITS   TO LOADS   7                                 * 10600000
*        LOAD 14 ENTERED BY LOADS   0,4,6,8,11,13                     * 10700000
         EJECT                                                          10800000
*        FUNCTION - ABEND LOAD J VALIDITY CHECKS ATTACH SYSTEM CONTROL* 10900000
*                   BLOCKS ASSOCIATED WITH THE ABENDING TASK AND      * 11000000
*                   SYSTEM CONTROL BLOCKS ASSOCIATED WITH             * 11100000
*                   ITS ABENDING DAUGHTERS. VALIDITY CHECKING MUST    * 11200000
*                   BE DONE ON THOSE CONTROL BLOCKS RESIDING IN THE   * 11300000
*                   PROBLEM PROGRAM PARTITION TO INSURE SYSTEM        * 11400000
*                   INTEGRITY AND TO PREVENT ABEND AND ABDUMP FROM    * 11500000
*                   ABENDING.                                         * 11600000
         SPACE                                                          11700000
*                   BELOW IS A LIST OF THE CONTROL BLOCKS WHICH       * 11800000
*                   ARE CHECKED AND THE CRITERIA AGAINST WHICH THEY   * 11900000
*                   ARE TESTED. IF A CONTROL BLOCK IS FOUND TO BE     * 12000000
*                   INVALID, THAT CONTROL BLOCK QUEUE IS TERMINATED   * 12100000
*                   EXCEPT FOR CERTAIN FQE TESTS. AN FQE CAN BE SIMPLY* 12200000
*                   DEQUED IF THE CORE IT DESCRIBES OVERLAPS ANOTHER  * 12300000
*                   FQE OR IF THE FQE IS NOT IN DESCENDING ORDER OR   * 12400000
*                   IF THE FQE SIZE IS NOT A MULTIPLE OF EIGHT.       * 12500000
         SPACE                                                          12600000
*                   1) LRB'S FROM JOB PACK AREA QUEUE                 * 12700000
*                        A) MAY NOT BE MORE THAN 300 LRB'S ON THE QUE.* 12800000
*                        B) MUST RESIDE WITHIN THE PARTITION.         * 12900000
*                        C) MUST RESIDE ON A DOUBLEWORD BOUNDARY.     * 13000000
*                        D) MUST NOT RESIDE IN FREE CORE.             * 13100000
*                        E) MUST HAVE VALID FORWARD AND BACKWARD PTRS.* 13200000
         SPACE                                                          13300000
*                   2) LPRB'S FROM THE TCB LOAD LIST.                 * 13400000
*                        SAME CRITERIA AS 1.                          * 13500000
*                   3) DEB                                            * 13600000
*                        A) MAY NOT BE MORE THAN 300 ON THE DEB QUE.  * 13700000
*                        B) MUST RESIDE WITHIN THE PARITION.          * 13800000
*                        C) MUST RESIDE ON A WORD BOUNDARY.           * 13900000
*                        D) MUST NOT RESIDE IN FREE CORE.             * 14000000
         SPACE                                                          14100000
*                   4) ACTIVE RB QUEUE                                * 14200000
*                        A) MAY NOT BE MORE THAN 300 ON THE RB QUE.   * 14300000
*                        B) MUST RESIDE WITHIN THE PARTITION (OT      * 14400000
*                           APPLICABLE FOR IRB'S).                    * 14500000
*                        C) MUST RESIDE ON A DOUBLEWORD BOUNDARY.     * 14600000
         SPACE                                                          14700000
*                   5) GQE                                            * 14800000
*                        A) MAY NOT BE MORE THAN 300 ON THE GQE QUE.  * 14900000
*                        B) MUST RESIDE WITHIN THE PARTITION.         * 15000000
*                        C) MUST RESIDE ON A DOUBLEWORD BOUNDARY.     * 15100000
*                        D) MUST NOT RESIDE IN FREE CORE.             * 15200000
*                        E) THE GQE SIZE MUST BE A DOUBLEWORD FACTOR. * 15300000
*                        F) THE GQE SIZE MUST NOT EXTEND ITSELF       * 15400000
*                           OUTSIDE OF THE PARTITION.                 * 15500000
*                        G) THE GQE SIZE MUST NOT DESCRIBE ANY STORAGE* 15600000
         SPACE 2                                                        15700000
*        APPLICABILITY - OPTION 2 (MFT) SYSTEM WITH THE               * 15800000
*                        ATTACH OPTION.                               * 15900000
         SPACE 3                                                        16000000
*        ATTRIBUTES - REENTRANT,REFRESHABLE                           * 16100000
         SPACE 3                                                        16200000
*        ENTRY POINT - IGC0J01C                                       * 16300000
         SPACE 3                                                        16400000
*        INPUT - NONE                                                 * 16500000
         SPACE 3                                                        16600000
*        OUTPUT - THE SETTING OF ERROR FLAGS IN THE ABEND             * 16700000
*                 APPENDAGE (TCBMSS-8) IF A CONTROL BLOCK IS INVALID. * 16800000
*                 ABEND APPENDAGE (BYTE 7) AND ARE USED BY ABEND      * 16900000
*                 LOAD 6 (IEANTM06) TO FORMAT THE ERROR MESSAGE.      * 17000000
*                 X'01' - INVALID FQE AND/OR GQE.                     * 17100000
*                 X'02' - INVALID ACTIVE RB.                          * 17200000
*                 X'04' - INVALID DEB.                                * 17300000
*                 X'08' - INVALID LPRB AND/OR LRB.                    * 17400000
         SPACE 3                                                        17500000
*        ENTERED BY - LOAD 3 - IEANTM03 FOR MFT ATTACH SYSTEMS        * 17600000
         SPACE 3                                                        17700000
*        EXITS - LOAD 4 - IEANTM04 (IGC0401C).                        * 17800000
*        WORK AREAS - THE TWELVE WORDS OF ABENDS EXTENDED SAVE AREA.  * 17900000
         SPACE 3                                                        18000000
*        NOTES - IF ALL THE ACTIVE RB'S OF A SUBTASK ARE DEQUED OR IF * 18100000
*                NONE EXIST, THE ACTIVE RB QUEUE WILL BE FOUND IN     * 18200000
*                ERROR AND THE TCBRBP FIELD WILL BE INITIALIZED TO    * 18300000
*                ZERO.                                                * 18400000
         SPACE 3                                                        18500000
*        EXTERNAL REFERENCES - IEATCBP (DISPATCHERS NEW-OLD).         * 18600000
*                            - IEA0AB00 - ENTRY POINT OF ABTERM.      * 18700000
         SPACE 3                                                        18800000
*        TABLES AND CONTROL BLOCKS REFERENCED                         * 18900000
*              CVT,TCB,RB,LRB,LPRB,DEB,FQE,GQE.                       * 19000000
         SPACE 3                                                        19100000
*        SVC'S USED - XCTL - SVC 7.                                   * 19200000
*                     GETMAIN AND FREEMAIN - SVC 10                   * 19300000
         EJECT                                                          19400000
         BALR  BASE,R0                  ESTABLISH                       19500000
         USING *,BASE                   ADDRESSABILITY                  19600000
         B     BEGIN                    BRANCH AROUND IDENTIFIER        19700000
         DC    C'IGC0J01C'                                              19800000
BEGIN    EQU   *                                                        19900000
         USING CVTDSECT,CVTREG          DSECT FOR CVT                   20000000
         USING TCBSECT,TCBREG           DSECT FOR TCB                   20100000
         USING RBSECT,RBREG             DSECT FOR RB                    20200000
         USING TCBSECTP,TEMPTCB         DSECT FOR ALTERNATE TCB         20300000
         L     CVTREG,CVTPTR            GET CVT ADDR                    20400000
         L     TCBREG,CVTTCBP           GET NEW-OLD PTR                 20500000
         L     TCBREG,OLD(TCBREG)       GET CURRENT TCB                 20600000
         L     RBREG,TCBRBP             GET RB ADDR                     20700000
         L     TEMPTCB,TCBFTJST         GET JS TCB                      20800000
         XC    XESAWD4(FOUR),XESAWD4    INDICATE ONE HIARCHY            20900000
         LA    BADCBREG,BADCB           INITIALIZE BRANCHING REG        21000000
         L     MSS,TCBMSSP              GET MSS PTR                     21100000
         XC    XESAWD1(FOUR),XESAWD1    ZERO LCS SWITCH                 21200000
         TM    ZERO(MSS),HEX01          Q. LCS IN SYSTEM                21300000
         BZ    NOLCS                    NO-BRANCH                       21400000
         NC    FOUR(EIGHT,MSS),FOUR(MSS) Q. ONLY H1 USED                21500000
         BNZ   SETSW                    NO-BRANCH                       21600000
         LA    MSS,TWELVE(MSS)          GET PTR TO H1                   21700000
         B     NOLCS                    GO TO REG CODE                  21800000
SETSW    EQU   *                                                        21900000
         NC    N16(EIGHT,MSS),N16(MSS)  Q. TWO HIARCHYS                 22000000
         BZ    NOLCS                    NO-BRANCH                       22100000
         LA    WKREG,TWELVE(MSS)        GET H1 PTR                      22200000
         ST    WKREG,XESAWD1            SAVE IT                         22300000
         ST    WKREG,XESAWD4            INDICATE HIARCHYS               22400000
NOLCS    EQU   *                                                        22500000
         SR    ENDREG,ENDREG            ZERO TERMINAL ADDRESS           22600000
         SPACE                                                          22700000
*************      JPAQ VALIDITY CHECK      ****************            22800000
         SPACE                                                          22900000
         L     BLOCKREG,TCBPIBP         GET PTR TO PIB                  23000000
         LA    LASTREG,JPQ(BLOCKREG)    GET PTR TO PTR OF JPAQ          23100000
         L     BLOCKREG,ZERO(LASTREG)   GET PTR TO FIRST RB             23200000
         LA    BLOCKREG,ZERO(BLOCKREG)  CLEAR NOISE                     23300000
         LTR   BLOCKREG,BLOCKREG        Q. ANY JPAQ                     23400000
         BZ    NOJPAQ                   NO-BRANCH                       23500000
         BAL   RETURN,VALIDITY          VALIDITY CHECK JPAQ FWD         23600000
         DC    X'07'                    DBLWD ALLIGN                    23700000
         DC    X'08'                    ERR FLAG                        23800000
         DC    X'0018'                  RB SIZE                         23900000
         DC    X'0000'                  LINK DSP                        24000000
         L     BLOCKREG,FOUR(LASTREG)   LASTREG POINTS TO LAST RB       24100000
         L     ENDREG,TCBPIBP           GET PIB PTR                     24200000
         LA    ENDREG,JPQ(ENDREG)       GET TERMINAL ADDR               24300000
         L     WKREG,0(ENDREG)          GET RB POINTER        AB A49298 24350021
         LTR   WKREG,WKREG              Q. HAS CHAIN BEEN CUT AB A49298 24360021
         BZ    NOJPAQ                   YES, BYPASS VALID CK  AB A49298 24370021
         BAL   RETURN,VALIDITY          CHECK JPAQ BACKWARD             24400000
         DC    X'07'                    DBLWD BND                       24500000
         DC    X'08'                    ERR FLAG                        24600000
         DC    X'0018'                  RB SIZE                         24700000
         DC    X'0004'                  LINK DSP                        24800000
NOJPAQ   EQU   *                                                        24900000
         LR    TEMPTCB,TCBREG                                           25000000
         B     SKIPRB   LRB,DEB,AND RB TESTED FOR CURRENT TCB BY ABEND3 25100000
SUBLOOP  EQU   *                                                        25200000
         SPACE                                                          25300000
*************    LOAD LIST VALIDITY CHECK    ***************            25400000
         L     BLOCKREG,TCBLLSP         GET FIRST CB                    25500000
         LA    LASTREG,TCBLLSP          GET ADDR FOR BADCB              25600000
         LTR   BLOCKREG,BLOCKREG        Q. ANY LOAD LIST                25700000
         BZ    NOLLE                    NO-BRANCH                       25800000
         BAL   RETURN,VALIDITY          CHECK LRBS FWD                  25900000
         DC    X'07'                    DBLWD BND                       26000000
         DC    X'08'                    ERR FLAG                        26100000
         DC    X'0018'                  RB SIZE                         26200000
         DC    X'0000'                  LINK DSP                        26300000
         L     BLOCKREG,FOUR(LASTREG)   LASTREG POINTS TO LAST RB       26400000
         LA    ENDREG,TCBLLSP           GET TERMINAL ADDRESS            26500000
         L     WKREG,0(ENDREG)          GET RB POINTER        AB A49298 26550021
         LTR   WKREG,WKREG              Q. HAS CHAIN BEEN CUT AB A49298 26560021
         BZ    NOLLE                    YES, BYPASS VALID CK  AB A49298 26570021
         BAL   RETURN,VALIDITY          CHECK LRBS BACKWARD             26600000
         DC    X'07'                    DBLWD BND                       26700000
         DC    X'08'                    ERR FLAG                        26800000
         DC    X'0018'                  RB SIZE                         26900000
         DC    X'0004'                  LINK DSP                        27000000
NOLLE    EQU   *                                                        27100000
         SPACE                                                          27200000
*************    DEB VALIDITY CHECK        *****************            27300000
         SPACE                                                          27400000
         L     BLOCKREG,TCBDEBP         GET DEB                         27500000
         SR    ENDREG,ENDREG            SET TERMINAL VALUE              27600000
         LA    LASTREG,TCBDEBP          GET DEB PTR                     27700000
         SH    LASTREG,DEBDSP           ADJUST FOR LINK FIELD           27800000
         BAL   RETURN,VALIDITY          CHECK DEBS                      27900000
         DC    X'03'                    SINGLE WD ALLIGN                28000000
         DC    X'04'                    ERR FLAG                        28100000
         DC    X'0024'                  MIN DEB SIZE                    28200000
DEBDSP   DC    X'0004'                  LINK DSP                        28300000
         SPACE                                                          28400000
***********   ACTIVE RB VALIDITY CHECK     ******************           28500000
         L     BLOCKREG,TCBRBPP         GET RB                          28600000
         LA    LASTREG,TCBRBPP          GET PTR TO RB FIELD             28700000
         LTR   BLOCKREG,BLOCKREG        Q. RB CHAIN                     28800000
         BZ    SKIPRB                   NO-BRANCH                       28900000
         LR    ENDREG,LASTREG           INITIALIZE END REG              29000000
         SH    LASTREG,RBDSP            ADJUST FOR LINK DISP            29100000
         BAL   RETURN,VALIDITY          GO CHECK RB QUEUE               29200000
         DC    X'03'                    SINGLE WD BOUND                 29300000
         DC    X'02'                    FLAG FOR ERR                    29400000
         DC    X'0020'                  MIN RB SIZE                     29500000
RBDSP    DC    X'001C'                  LINK DSP                        29600000
SKIPRB   EQU   *                                                        29700000
         SR    ENDREG,ENDREG            RESET ENDREG TO ZERO            29800000
         CL    TEMPTCB,TCBFTJST         Q. JOB STEP TASK                29900000
         BE    SKIPGQE                  YES-SKIP GQE TESTING            30000000
         SPACE                                                          30100000
**************      GQE VALIDITY CHECK       ****************           30200000
         SPACE                                                          30300000
         L     LASTREG,TCBMSSP          GET PTR TO GQE                  30400000
         L     BLOCKREG,ZERO(LASTREG)   GET FIRST GQE                   30500000
         BAL   RETURN,VALIDITY          CHECK GQES                      30600000
         DC    X'07'                    DBLWD BOUND                     30700000
         DC    X'01'                    ERR  FLAG                       30800000
         DC    X'0008'                  GQE SIZE                        30900000
         DC    X'0000'                  LINK DSP                  M3232 31000000
SKIPGQE  EQU   *                                                        31100000
         LR    WKREG,TEMPTCB            SAVE REG                        31200000
         L     TEMPTCB,TCBLTCP          GET DAUGHTER              M4827 31300000
SUBSRCH  EQU   *                                                        31400000
         LTR   TEMPTCB,TEMPTCB          Q. NEW TASK FOUND               31500000
         BNZ   SUBLOOP                  YES-BRANCH                      31600000
         CLR   WKREG,TCBREG             Q. TREE FINISHED                31700000
         BE    ALLDONE                  YES-BRANCH                      31800000
         L     TEMPTCB,NTC(WKREG)       GET SISTER                      31900000
         L     WKREG,OTC(WKREG)         INITIALIZE WITH MOTHER          32000000
         B     SUBSRCH                  INTERROGATE                     32100000
ALLDONE  EQU   *                                                        32200000
         LA    R0,J                                                     32300000
         LA    R15,LOAD4                SET UP XCTL TO NEXT LOAD        32400000
         ST    R15,XESAXCTL             STORE ADDR INTO LIST            32500000
         LA    R15,XESAXCTL             GET PTR TO LIST                 32600000
         XCTL  SF=(E,(15))              TO NEXT LOAD                    32700000
         EJECT                                                          32800000
*        THE FOLLOWING CODE IS THE VALIDITY ROUTINE. IF AN INVALID      32900000
*        CONTROL BLOCK IS FOUND-THE BLOCK IS DEQUED AND THE ABEND       33000000
*        APPENDAGE IS APPROPRIATLY FLAGGED. REGISTER INPUT IS -         33100000
*              BLOCKREG-ADDR OF FIRST CB                                33200000
*              LASTREG -ADDR OF ADDR OF FIRST CB                        33300000
*              ENDREG  -TERMINAL ADDR OF CB QUEUE                       33400000
*              RETURN  -ADDRESS PLUS 6 TO RETURN CONTROL                33500000
         SPACE 5                                                        33600000
VALIDITY EQU   *                                                        33700000
         LA    CNT,N300                 COUNT IN CASE OF LOOP           33800000
LCSENTRY LM    LOW,HIGH,FOUR(MSS)       GET PARTITION BOUNDS            33900000
         SH    HIGH,SZE(RETURN)         ADJUST HIGH FOR CB SIZE         34000000
         CLR   BLOCKREG,ENDREG          Q. LAST CB                      34100000
         BNE   MORECB                   NO-BRANCH                       34200000
         BAL   WKREG,MSSFIX             FIX MSS REG                     34300000
         B     OUT(RETURN)              RETURN TO CALLER                34400000
MORECB   EQU   *                                                        34500000
         CR    BLOCKREG,HIGH            Q. CB HIGHER THAN HI AB  A40875 34600000
         BH    LCSTEST                  CHECK FOR LCS        AB  A40875 34700000
         TM    ERR(RETURN),HEX02        Q. RB CHECK                     34800000
         BZ    NOTRB                    NO-BRANCH                       34900000
         TM    TEN(BLOCKREG),HEX30      Q. NOT IRB OR SIRB        M4826 35000000
         BNZ   NOTRB                    YES-BRANCH                M4826 35100000
         TM    TEN(BLOCKREG),HEXC0      Q. IRB OR SIRB                  35200000
         BM    SKPART                   YES-SKIP PARTITION TEST         35300000
NOTRB    EQU   *                                                        35400000
         CR   BLOCKREG,LOW           CB HIGHER THAN LOW       AB A40875 35500000
         BCR  L,BADCBREG             NO-BAD CB FOUND          AB A40875 35600000
SKPART   EQU   *                                                        35700000
         AH    LASTREG,DSP(RETURN)      GET PTR TO BLOCKREG             35800000
         IC    WKREG,ALIGN(RETURN)      GET BND ALLIGN                  35900000
         EX    WKREG,BOUNTEST           TEST ALLIGNMENT                 36000000
         BNZ   FIXBAD                   BRANCH IF BAD                   36100000
         SH    LASTREG,DSP(RETURN)      ADJUST LASTREG                  36200000
         SPACE 5                                                        36300000
*        THE FOLLOWING ROUTINE IS ENTERED FOR ALL BUT FQE CHECKS TO     36400000
*        BE CERTAIN THAT THE CB DOES NOT RESIDE IN FREE CORE            36500000
         SPACE 2                                                        36600000
         L     TOP,ZERO(MSS)            GET PTR TO FIRST FQE            36700000
         LA    TOP,ZERO(TOP)            CLEAR HI BYTE                   36800000
CKIT     EQU   *                                                        36900000
         LTR   TOP,TOP                  Q. LAST FQE                     37000000
         BZ    WHERE                    YES-CB OK                       37100000
         CR    TOP,BLOCKREG             Q. CB RESIDE HIGHER THAN FQE    37200000
         BL    CKFQE                    YES-BRANCH                      37300000
         L     TOP,ZERO(TOP)            GET NEXT FQE                    37400000
         B     CKIT                     CHECK NEXT FQE                  37500000
CKFQE    EQU   *                                                        37600000
         A     TOP,FOUR(TOP)            ADD FQE SIZE                    37700000
         CR    TOP,BLOCKREG             Q. CB RESIDE IN FREE CORE       37800000
         BCR   H,BADCBREG               YES-BRANCH                      37900000
WHERE    EQU   *                                                        38000000
         TM    ERR(RETURN),HEX01        Q. GQE CHECK                    38100000
         BNO   PRGETNCB                 NO-BRANCH                       38200000
         TM    SEVEN(BLOCKREG),HEX07    Q. COUNT IN DBLWDS              38300000
         BCR   NZ,BADCBREG              NO-BRANCH                       38400000
         L     WKREG,FOUR(BLOCKREG)     GET SIZE OF GQE                 38500000
         AR    WKREG,BLOCKREG           COMPUTE TOP OF GQE              38600000
         C     WKREG,EIGHT(MSS)         Q. GQE EXTEND PAST PARTITION    38700000
         BCR   H,BADCBREG               YES-BRANCH                      38800000
         L     TOP,ZERO(MSS)            GET FIRST FQE                   38900000
LOOPGQE  EQU   *                                                        39000000
         LTR   TOP,TOP                  Q. LAST FQE                     39100000
         BZ    PRGETNCB                 YES-BRANCH-GQE OK               39200000
         CR    TOP,WKREG                Q. FQE LOWER THAN TOP OF GQE    39300000
         BL    POSSIBL                  YES-BRANCH                      39400000
         L     TOP,ZERO(TOP)            GET NEXT FQE                    39500000
         B     LOOPGQE                  GO TO CHECK MORE                39600000
POSSIBL  EQU   *                                                        39700000
         CR    TOP,BLOCKREG             Q. DOES FQE RESIDE IN GQE       39800000
         BCR   NL,BADCBREG              YES-BRANCH                      39900000
PRGETNCB EQU   *                                                        40000000
         BCT   CNT,GETNCB               CHECK FOR LOOP                  40100000
BADCB    EQU   *                                                        40200000
         BAL   WKREG,MSSFIX             FIX MSS                         40300000
         CLR   BLOCKREG,RBREG           Q. IS MY RB BAD                 40400000
         BE    OUT(RETURN)              YES DONT DEQ IT                 40500000
         AH    LASTREG,DSP(RETURN)      GET PTR TO LINK FIELD           40600000
         SR    WKREG,WKREG              CLEAR REG                       40700000
         TM    ERR(RETURN),HEX01+HEX08  Q. DEB OR ACTIVE RB             40800000
         BZ    DOIC                     YES-BRANCH                      40900000
         C     LASTREG,FOUR(MSS)        Q. TERM VALUE INTO TCB          41000000
         BH    SKIPHI                   NO-BRANCH                       41100000
DOIC     EQU   *                                                        41200000
         IC    WKREG,ZERO(LASTREG)      SAVE HI BYTE                    41300000
SKIPHI   EQU   *                                                        41400000
         ST    ENDREG,ZERO(LASTREG)     CUT CHAIN STORE TERM VALUE      41500000
         STC   WKREG,ZERO(LASTREG)      RESTORE HI BYTE                 41600000
         IC    WKREG,ERR(RETURN)        GET ERROR FLAG                  41700000
         L     LOW,TCBMSSP              GET PTR TO BB                   41800000
         BCTR  LOW,R0                   GET PTR TO APPENDAGE            41900000
         EX    WKREG,FLAGIT             FLAG ABEND APPENDAGE            42000000
         TM    ERR(RETURN),HEX02        Q. IS THIS RB QUEUE             42100000
         BZ    OUT(RETURN)              NO-RETURN TO CALLER             42200000
         CL    LASTREG,TCBRBPP          Q. ALL RBS DEQUEUED             42300000
         BE    OUT(RETURN)              YES-BRANCH                      42400000
         SH    LASTREG,DSP(RETURN)      ADJUST PTR                      42500000
         OI    ELEVEN(LASTREG),HEX80    FLAG LAST RB                    42600000
         B     OUT(RETURN)              RETURN TO CALLER                42700000
FIXBAD   EQU   *                                                        42800000
         SH    LASTREG,DSP(RETURN)      ADJUST LASTREG                  42900000
         BR    BADCBREG                 GO DEQUE BAD CB                 43000000
         EJECT                                                          43100000
*        THE FOLLOWING ROUTINE ADJUSTS MSS REG TO CONTAIN H0 MSS PTR    43200000
*        IF TWO SEGMENTS ARE USED.                                      43300000
         SPACE 2                                                        43400000
MSSFIX   EQU   *                                                        43500000
         L     R0,XESAWD1               GET OTHER MSS POINTER           43600000
         LTR   R0,R0                    Q. TWO SEGMENTS USED            43700000
         BCR   Z,WKREG                  NO-RETURN TO CALLER             43800000
         CR    R0,MSS                   Q. WAS MSS SWITCHED             43900000
         BCR   H,WKREG                  NO-RETURN TO CALLER             44000000
         ST    MSS,XESAWD1              STORE H1 BB PTR                 44100000
         LR    MSS,R0                   GET H0 BB PTR                   44200000
         BR    WKREG                    RETURN TO CALLER                44300000
         SPACE 5                                                        44400000
*        THE FOLLOWING ROUTINE IS ENTERED TO ALTER MSS IF TWO           44500000
*        SEGMENTS ARE USED                                              44600000
         SPACE 2                                                        44700000
LCSTEST  EQU   *                                                        44800000
         L     WKREG,XESAWD1            GET OTHER MSS PTR               44900000
         LTR   WKREG,WKREG              Q. OTHER ONE EXIST              45000000
         BCR   Z,BADCBREG               NO-CB IS INVALID                45100000
         CR    WKREG,MSS                Q. WAS TEST MADE ON LCS MSS     45200000
         BCR   L,BADCBREG               YES-INVALID CB                  45300000
         ST    MSS,XESAWD1              SAVE H0 MSS PTR                 45400000
         LR    MSS,WKREG                GET H1 MSS PTR                  45500000
         B     LCSENTRY                 GO CHECK CB                     45600000
         SPACE 5                                                        45700000
*        THE FOLLOWING ROUTINE GETS THE NEXT CONTROL BLOCK              45800000
         SPACE 2                                                        45900000
GETNCB   EQU   *                                                        46000000
         LR    LASTREG,BLOCKREG         SAVE LAST VALID CB              46100000
         AH    BLOCKREG,DSP(RETURN)     GET PTR TO LINK FIELD           46200000
         L     BLOCKREG,ZERO(BLOCKREG)  GET NEXT CB                     46300000
         LA    BLOCKREG,ZERO(BLOCKREG)  CLEAR HI BYTE                   46400000
         BAL   WKREG,MSSFIX             GET CORRECT MSS PTR             46500000
         B     LCSENTRY                 CHECK NEXT CB                   46600000
         SPACE 5                                                        46700000
*        TWO   INSTRUCTIONS  FOR  EXECUTE                               46800000
BOUNTEST TM    THREE(LASTREG),ZERO                                      46900000
FLAGIT   OI    ZERO(LOW),ZERO                                           47000000
*                             CONSTANTS                                 47100000
         SPACE 2                                                        47200000
         DS    0F                                                       47300000
LOAD4    DC    C'IGC0401C'                                              47400000
         SPACE 5                                                        47500000
*                             REGISTER EQUATES                          47600000
         SPACE                                                          47700000
R0       EQU   0                                                        47800000
MSS      EQU   1                                                        47900000
BASE     EQU   2                                                        48000000
CVTREG   EQU   3                                                        48100000
TCBREG   EQU   4                                                        48200000
RBREG    EQU   5                                                        48300000
TEMPTCB  EQU   6                                                        48400000
WKREG    EQU   7                                                        48500000
ENDREG   EQU   8                                                        48600000
BLOCKREG EQU   9                                                        48700000
LASTREG  EQU   10                                                       48800000
CNT      EQU   11                                                       48900000
LOW      EQU   12                                                       49000000
HIGH     EQU   13                                                       49100000
TOP      EQU   13                                                       49200000
RETURN   EQU   14                                                       49300000
R15      EQU   15                                                       49400000
BADCBREG EQU   15                                                       49500000
         SPACE 5                                                        49600000
*                             GENERAL EQUATES                           49700000
         SPACE                                                          49800000
ALIGN    EQU   0                                                        49900000
ERR      EQU   1                                                        50000000
SZE      EQU   2                                                        50100000
DSP      EQU   4                                                        50200000
OUT      EQU   6                                                        50300000
TEN      EQU   10                                                       50400000
ELEVEN   EQU   11                                                       50500000
N16      EQU   16                                                       50600000
JPQ      EQU   44                                                       50700000
NTC      EQU   128                                                      50800000
OTC      EQU   132                                                      50900000
N300     EQU   300                                                      51000000
HEX01    EQU   X'01'                                                    51100000
HEX02    EQU   X'02'                                                    51200000
HEX07    EQU   X'07'                                                    51300000
HEX08    EQU   X'08'                                                    51400000
HEX30    EQU   X'30'                                              M4826 51500000
HEX80    EQU   X'80'                                                    51600000
HEXC0    EQU   X'C0'                                                    51700000
J        EQU   X'D1'                                                    51800000
         EJECT                                                          51900000
         IHBMFTAB                                                       52000000
         END                                                            52100000
