         TITLE 'IEANTM0M / IGC0M01C / PROBLEM DETERMINATION'            00050021
IGC0M01C START                                                          00350021
***************************************************************         00650021
*                        PROLOGUE                             *         00950021
***************************************************************         01250021
*   STATUS-                                                   *         01550021
*      VERSION = 0                                            *         01850021
*   FUNCTION-                                                 *         02150021
*      A CONDITIONAL GETMAIN IS ISSUED TO GET CORE FROM       *         02450021
*      WHICH TO WRITE MESSAGES.  IF THE GETMAIN FAILS, NO     *         02750021
*      FURTHER PROCESSING IS DONE AND RETURN IS MADE VIA      *         03050021
*      XCTL TO IEANTM0G.                                      *         03350021
*      THE INFORMATION LIST MODULE, IEAQMSGS, IS SCANNED      *         03650021
*      FOR ENTRIES WHOSE TCB ADDRESS MATCHES THE ADDRESS      *         03950021
*      OF THE CURRENTLY ABENDING TCB.  FOR EACH SUCH ENTRY    *         04250021
*      FOUND, THE INFORMATION IS FORMATTED INTO AN IEA7XXI    *         04550021
*      MESSAGE AND OUTPUT VIA WTP. WHEN ALL ENTRIES HAVE      *         04850021
*      BEEN OUTPUT, RETURN IS MADE VIA XCTL TO IEANTM0G.      *         05150021
*   ENTRY POINTS-                                             *         05450021
*      IGC0M01C:                                              *         05750021
*         ENTERED VIA XCTL FROM IEANTM0G IF THERE ARE         *         06050021
*         ANY ENTRIES IN THE INFORMATION LIST (IEAQMSGS)      *         06350021
*         FOR THE CURRENTLY ABENDING TCB.                     *         06650021
*   INPUT-                                                    *         06950021
*      REGISTER CONTENT:                                      *         07250021
*         R3 = ADDRESS CVT                                    *         07550021
*         R4 = ADDRESS TCB                                    *         07850021
*         R5 = ADDRESS CURRENT RB                             *         08150021
*                                                             *         08450021
*      THE FORMAT OF THE INFORMATION LIST ENTRY IS SHOWN      *         08750021
*      BY THE INFORMATION LIST DSECT, INFOLIST, INCLUDED      *         09050021
*      AT THE END OF THIS MODULE.                             *         09350021
*   OUTPUT-                                                   *         09650021
*      REGISTER CONTENT:                                      *         09950021
*         R3 = ADDRESS CVT                                    *         10250021
*         R4 = ADDRESS TCB                                    *         10550021
*         R5 = ADDRESS CURRENT RB                             *         10850021
*      TCBRECDE IS SET TO (TCBREC+TCBTYP1R) TO INDICATE       *         11150021
*      A RETURN FROM THIS MODULE.                             *         11450021
*      A WTP IS ISSUED FOR EACH ENTRY IN THE INFORMATION      *         11750021
*      LIST WHICH WAS ENTERED FOR THIS TCB, I.E. INFTCB       *         12050021
*      CONTAINS THE ADDRESS OF THE CURRENTLY ABENDING TCB.    *         12350021
*   EXTERNAL REFERENCES-                                      *         12650021
*      THE ADDRESS OF THE INFORMATION LIST MODULE IS          *         12950021
*      OBTAINED FROM A POINTER, CVTQMSGS.                     *         13250021
*   EXITS, NORMAL-                                            *         13550021
*      XCTL TO IEANTM01 WITH TCBTYP1R FLAG BIT SET ALONG      *         13850021
*      WITH THE ABEND VALID RECURSION BIT, TCBREC.            *         14150021
*   EXITS, ERRORS-                                            *         14450021
*      TO IEANTM00 WITH TCBTYP1W FLAG BIT SET ALONG           *         14750021
*      WITH THE ABEND VALID RECURSION BIT, TCBREC.            *         15050021
*   TABLE/WORK AREAS-                                         *         15350021
*      THE MSG OUTPUT BUFFER, OBTAINED VIA A                  *         15650021
*      GETMAIN, CONTAINS ONE WORD FOR PARAMETERS FOR          *         15950021
*      THE WTO FOLLOWED BY 72 BYTES IN WHICH TO BUILD         *         16250021
*      THE MESSAGE, FOLLOWED BY 4 MORE BYTES FOR PARMS.       *         16550021
*   ATTRIBUTES-                                               *         16850021
*      TYPE 4 SVC, PRIVILEGED, DISABLED EXCEPT TO ISSUE       *         17150021
*      WTP.                                                   *         17450021
*   NOTES-                                                    *         17750021
*      NOT CHARACTER CODE DEPENDENT.                          *         18050021
***************************************************************         18350021
***************************************************************         18650021
         EJECT                                                          18950021
***************************************************************         19250021
*    REGISTER EQUATES                                         *         19550021
***************************************************************         19850021
R0       EQU   0                                                        20150021
PARREG0  EQU   0                                                        20450021
PARREG1  EQU   1                                                        20750021
MSGBASE  EQU   1                                                        21050021
BASEREG  EQU   2                                                        21100021
CVTREG   EQU   3                                                        21350021
TCBREG   EQU   4                                                        21650021
RBREG    EQU   5                                                        21950021
LISTREG  EQU   6                                                        22250021
ENDREG   EQU   7                                                        22550021
WORK     EQU   8                                                        22850021
WORK2    EQU   9                                                        23150021
EXITPARM EQU   10                                                       23450021
RETREG   EQU   14                                                       24050021
RTNREG   EQU   15                                                       24350021
R15      EQU   15                                                       24650021
*                                                                       24950021
GETLEN   EQU   80                                                       25250021
*                                                                       25550021
         EJECT                                                          25850021
IGC0M01C CSECT                                                          26150021
         BALR  BASEREG,0          ESTABLISH ADDRESSIBILITY              26450021
         USING *,BASEREG                                                26750021
         USING CVTDSECT,CVTREG                                          27050021
         USING TCBSECT,TCBREG                                           27350021
         USING RBSECT,RBREG                                             27650021
*                                                                       27950021
         B     BEGIN                                                    28250021
NAME     DC    C'IGC0M01C'                                              28550021
BEGIN    EQU   *                                                        28850021
         MVI   TCBRECDE,TCBTYP1W+TCBREC SET MSG RECUR CONFIG            29150021
*                                                                       29450021
         L     LISTREG,CVTQMSG    ADDR INFO LIST               CB 21016 29750021
         SPACE 1                                                        30050021
         L     ENDREG,0(LISTREG)  END OF INFORMATION LIST               30350021
         LA    LISTREG,4(LISTREG) 1ST ENTRY IN INFORMATION LIST         30650021
         SPACE 1                                                        30950021
         USING INFOLIST,LISTREG                                         31250021
         SR    MSGBASE,MSGBASE    INDICATE GETMAIN NOT DONE             31550021
SCAN     CR    ENDREG,LISTREG     ALL ENTRIES PROCESSED?                31850021
         BE    EXIT                                                     32150021
         C     TCBREG,INFTCB      MATCH?                                32450021
         BE    FORMAT             YES. GO TO FORMAT = ISSUE MSG         32750021
NEXT     LA    LISTREG,INFLEN(LISTREG)                                  33050021
         B     SCAN               NEXT ENTRY.                           33350021
FORMAT   LTR   MSGBASE,MSGBASE    HAS GETMAIN BEEN DONE YET?            33650021
         BNE   FORMAT1            IF YES, BYPASS                        33950021
*                                                                       34250021
         SPACE 1                                                        34550021
*   GETMAIN                                                             34850021
         ST    MSGBASE,XRBESA+12                                        35150021
         L     WORK,SP254         SVRB FOR WTO + ENQ (FROM SUBPOOL 254) 35450021
         SPACE 1                                                        35750021
         GETMAIN R,LV=(WORK)                                            36050021
         SPACE 1                                                        36350021
         LTR   R15,R15            SUCCESSFUL?                           36650021
         BNZ   EXIT               NO. EXIT                              36950021
         SPACE 1                                                        37250021
         FREEMAIN R,LV=(WORK),A=(1)                                     37550021
         SPACE 1                                                        37850021
         LA    WORK,GETLEN        NUMBER OF BYTES REQUESTED             38150021
         O     WORK,SP255          (FROM SUBPOOL 255)         CB  21016 38450021
         GETMAIN R,LV=(WORK)                                            38750021
         SPACE 1                                                        39050021
         LTR   15,15              GETMAIN SUCCESSFUL?                   39350021
         BNE   EXIT               NO. EXIT                              39650021
         SPACE 1                                                        39950021
FORMAT0  ST    MSGBASE,XRBESA+8   ADDR OF CORE OBTAINED                 40250021
         ST    WORK,XRBESA+12     SUBPOOL AND LENGTH OF CORE            40550021
         USING MSGFORM,MSGBASE                                          40850021
FORMAT1  EQU   *            R1 CONTAINS ADDR OF GETMAINED AREA          41150021
         UNPK  MSGCC-1(5),INFCC(3)    SET COMPLETION CODE               41450021
         MVI   MSGCC-1,C' '                                             41750021
         TR    MSGCC(3),TRANTAB-X'EF'      INTO MSG AREA.               42050021
         MVC   MSGPARM+2(9),WTO+2     SET SKELETAL MSG ID AND PARMS     42350021
         CLI   INFCC+1,X'05'      CORRECT                               42650021
         BL    FORMAT2               MSG                                42950021
         MVI   MSGID+5,C'1'             ID                              43250021
         BE    FORMAT2                     FOR DIFFERENT                43550021
         MVI   MSGID+5,C'2'                  SVC CODES                  43850021
FORMAT2  MVC   MSGRC(3),BLANKS                                          44150021
         SR    WORK,WORK                                                44450021
         IC    WORK,INFRCL        GET POSSIBLE                          44750021
         SRL   WORK,5                REASON CODE IN REG                 45050021
         LTR   WORK,WORK          WAS REASON CODE GIVEN?                45350021
         BE    FORMAT3            NO. DON'T PUT IN MSG                  45650021
         STC   WORK,MSGRC+1       SET REASON                            45950021
         OI    MSGRC+1,X'F0'         CODE IN MSG.                       46250021
         MVI   MSGRC,C'-'                                               46550021
FORMAT3  L     WORK,TCBTIO        GET TIOT ADDR                         46850021
         MVC   MSGJOB(8),0(WORK)  SET JOBNAME IN MESSAGE                47150021
         TM    INFFLG,INFFLG0     WAS THIS BRANCH ENTRY?                47450021
         BZ    FORMAT4            NO. CONTINUE                          47750021
         UNPK  MSGJOB(9),INFBADDR(5)  IF YES, SET BRANCH ADDRESS        48050021
         TR    MSGJOB(8),TRANTAB-X'EF'   IN JOBNAME FIELD OF MSG        48350021
FORMAT4  MVI   MSGJOB+8,C' '          SET BLANK AFTER JOBNAME           48650021
         MVC   MSGSTEP(8),8(WORK)     SET STEPNAME IN MESSAGE           48950021
         MVI   MSGSTEP+8,C' '         SET BLANK AGTER STEPNAME          49250021
*                                                                       49550021
         UNPK  MSGFLG(3),INFFLG(2)    SET FLAG CHARACTERS               49850021
         TR    MSGFLG(2),TRANTAB-X'EF'     IN MESSAGE                   50150021
         MVI   MSGFLG+2,C' '          SET BLANK AFTER FLAG FIELD        50450021
*                                                                       50750021
         UNPK  MSGVAR1(9),INFVAR1(5)  UNPACK                            51050021
         UNPK  MSGVAR2(9),INFVAR2(5)     VARIABLE DATA                  51350021
         UNPK  MSGVAR3(9),INFVAR3(5)        IN FORMATTED                51650021
         UNPK  MSGVAR4(9),INFVAR4(5)           MESSAGE                  51950021
         MVI   MSGVAR1+8,X'EF'        SET PRE-TRANSLATE BLANKS          52250021
         MVI   MSGVAR2+8,X'EF'           BETWEEN VARIABLE DATA WORDS    52550021
         MVI   MSGVAR3+8,X'EF'              TO BE OUTPUT                52850021
         TR    MSGVAR(35),TRANTAB-X'EF' TRANSLATE ALL TO EBCDIC         53150021
         SPACE 1                                                        53450021
*   CALCULATE LENGTH OF MESSAGE AND SET IN PARM FIELD                   53750021
         NI    INFRCL,X'1F'       TURN OFF REASON CODE IF EXISTS        54050021
         CLI   INFRCL,X'10'       COMPARE TO MAXIMUM LENGTH             54350021
         BNH   FORMAT5            IF NOT TOO GREAT, CONTINUE.           54650021
         MVI   INFRCL,X'10'       OTHERWISE, SET TO MAX OF 16.          54950021
FORMAT5  SR    WORK,WORK          CLEAR REGISTER                        55250021
         IC    WORK,INFRCL        NO. OF VARIABLE BYTES TO OUTPUT       55550021
         SRDL  WORK,2             NO. OF FULL WORDS OF VAR DATA         55850021
         MH    WORK,H9            9 BYTES INCLUDING LEADING BLANK      *56150021
                                  TO OUTPUT 4 BYTES OF VARIABLE DATA    56450021
         SRL   WORK2,30           REMAINDER IN WORK2                    56750021
         SLL   WORK2,1            REMAINDER X 2 FOR OUTPUT              57050021
         LTR   WORK2,WORK2        IF NO REMAINDER                       57350021
         BE    FORMAT6               DON'T INCREMENT                    57650021
         LA    WORK2,1(WORK2)     ELSE, ADD 1 FOR LEADING BLANK         57950021
         AR    WORK,WORK2         ( LENGTH OF VARIABLE PORTION )        58250021
FORMAT6  LA    WORK,FIXEDLNG+4(WORK)  + ( LENGTH OF FIXED PORTION ) +4  58550021
         STH   WORK,MSGPARM            = MESSAGE LENGTH + 4 BYTES PARMS 58850021
         LA    WORK,MSGPARM(WORK)  END OF MSG                           59150021
         MVC   0(4,WORK),WTPPARM2  SET DESC CODE + ROUT                 59450021
*                                     CODE AFTER MESSAGE.               59750021
         SPACE 1                                                        60050021
         WTO   MF=(E,(1))         WRITE MESSAGE                         60350021
         SPACE 1                                                        60650021
         L     MSGBASE,XRBESA+8   RESTORE MSG AREA ADDR       AC  M0604 60700021
         XC    0(INFLEN,LISTREG),0(LISTREG) ZERO OUT ENTRY              60950021
         B     NEXT               PROCESS ALL ENTRIES                   61250021
EXIT     EQU   *                                                        61260021
         CLI   XRBESA+15,X'00'    Q. ANY CORE GOTTEN          AB A62284 61300021
         BE    OUT                NO. SKIP FREEMAIN           AB A62284 61350021
         L     WORK,XRBESA+12     YES. GET LEN AND SUBPOOL    AB A62284 61400021
         L     1,XRBESA+8         GET ADDRESS OF CORE TO FREE AB A62284 61450021
         FREEMAIN   R,LV=(WORK),A=(1)      FREE BUFFER CORE   AB A62284 61500021
OUT      EQU   *                                              AB A62284 61510021
         LA    R0,C'M'                                                  61550021
         LA    R15,NMLOADG        ADDR OF NEXT LOAD                     61850021
         ST    R15,XESAXCTL         IN ESA                              62150021
         LA    R15,XESAXCTL       ADDR OF PARAM TO XCTL                 62450021
         MVI   TCBRECDE,TCBTYP1R+TCBREC SET MSG RETURN CONFIG CB  21016 62500021
         XCTL  SF=(E,(15))        GO TO ABENDG                          63050021
         SPACE 1                                                        63350021
***************************************************************         63650021
*      CONSTANTS                                              *         63950021
***************************************************************         64250021
WTO      WTO   'IEA700I',MF=L,ROUTCDE=11,DESC=6                         64550021
WTPPARM2 EQU   *-4                                                      64850021
IEA700I  EQU   WTO+4                                                    65150021
         SPACE 1                                                        65450021
BLANKS   DC    C'   '                                                   65750021
TRANTAB  DC    C' 0123456789ABCDEF'                                     66050021
         DS    0F                                                       66350021
NMLOADG  DC    C'IGC0G01C'                                              66650021
THISMOD  DC    C'M01C'                                                  66950021
H9       DC    H'9'                                                     67250021
         DS    0F                                                       67550021
SP254    DC    X'FE000120'               SUBPOOL=254, LENGTH=X'120'     67850021
SP255    DC    X'FF000000'               SUBPOOL=255, LENGTH=NULL       68150021
         EJECT                                                          68450021
***************************************************************         68750021
*                                                             *         69050021
*      THE FOLLOWING CODE IS ZAP SPACE FOR MAINTENANCE USE    *         69350021
*                                                             *         69650021
***************************************************************         69950021
ZAP      DC    H'0'                                                     70250021
         DC    H'0'                                                     70550021
         DC    H'0'                                                     70850021
         DC    H'0'                                                     71150021
         DC    H'0'                                                     71450021
         DC    H'0'                                                     71750021
         DC    H'0'                                                     72050021
         DC    H'0'                                                     72350021
         DC    H'0'                                                     72650021
         DC    H'0'                                                     72950021
         DC    H'0'                                                     73250021
         DC    H'0'                                                     73550021
         DC    H'0'                                                     73850021
         DC    H'0'                                                     74150021
         DC    H'0'                                                     74450021
         DC    H'0'                                                     74750021
         DC    H'0'                                                     75050021
         DC    H'0'                                                     75350021
         DC    H'0'                                                     75650021
         DC    H'0'                                                     75950021
         DC    H'0'                                                     76250021
         DC    H'0'                                                     76550021
         EJECT                                                          76850021
***************************************************************         77150021
*        DSECT TO COVER INFORMATION LIST ENTRY                          77450021
***************************************************************         77750021
         SPACE 1                                                        78050021
INFOLIST DSECT                                                          78350021
INFTJID  DS    F     THIS FIELD USED FOR TJID ...MVT ONLY     AB A49808 78400021
INFTCB   DS    F                                                        78650021
INFBADDR DS    F                                                        78950021
INFRCL   DS    X     BITS 0-2 USED FOR REASON CODE(0=>NO RC)            79250021
*                    BITS 3-7 USED FOR COUNT OF VARIABLE DATA BYTES     79550021
INFFLG   DS    X     FLAG BYTE                                          79850021
INFFLG0  EQU   X'80' BIT 0 ON => BRANCH ENTRY                           80150021
INFCC    DS    H     COMPLETION CODE                                    80450021
INFVAR   DS    4F    VARIABLE INFORMATION                               80750021
         ORG   INFVAR                                                   81050021
INFVAR1  DS    F                                                        81350021
INFVAR2  DS    F                                                        81650021
INFVAR3  DS    F                                                        81950021
INFVAR4  DS    F                                                        82250021
INFEND   EQU   *                                                        82550021
INFLEN   EQU   (INFEND-INFTJID)  LENGTH OF ENTRY              AB A49808 82850021
         SPACE 2                                                        83150021
***************************************************************         83450021
*        DSECT TO COVER MESSAGE FORMAT                        *         83750021
***************************************************************         84050021
         SPACE 1                                                        84350021
MSGFORM  DSECT                                                          84650021
MSGPARM  DS    F                                                        84950021
MSG      DS    0X                                                       85250021
MSGID    DS    8C                                                       85550021
MSGCC    DS    3C                                                       85850021
MSGRC    DS    3C                                                       86150021
MSGJOB   DS    9C                                                       86450021
MSGSTEP  DS    9C                                                       86750021
MSGFLG   DS    3C                                                       87050021
MSGVAR   DS    35C                                                      87350021
         ORG   MSGVAR                                                   87650021
MSGVAR1  DS    8C                                                       87950021
         DS    C                                                        88250021
MSGVAR2  DS    8C                                                       88550021
         DS    C                                                        88850021
MSGVAR3  DS    8C                                                       89150021
         DS    C                                                        89450021
MSGVAR4  DS    8C                                                       89750021
         DS    C                                                        90050021
MSGEND   EQU   *                                                        90350021
MSGLEN   EQU   MSGEND-MSG                                               90650021
         SPACE 1                                                        90950021
FIXEDLNG EQU   (MSGVAR-1-MSG)                                           91250021
         EJECT                                                          91550021
         IHBMFTAB                                                       91850021
         END                                                            92500021
