         TITLE 'LOG BUFFER MANAGER AND DUMP ROUTER'                     00300018
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 00600018
*                                                                     * 00900018
*NAME    LOG BUFFER MANAGER AND WRITER                                  01200018
*                                                                     * 01500018
* FUNCTION     PLACES USER RECORD IN THE LOG BUFFER, SCHEDULE THE       01800018
*        LOG WRITER WHICH INTURN SCHEDULES THE LOG DUMP FUNCTION        02100018
*                                                                     * 02400018
* INPUT  POINTER TO THE USER INPUT VARIABLE LENGTH RECORD             * 02700018
*                                                                     * 03000018
* OUTPUT       NONE                                                   * 03300018
*                                                                     * 03600018
* EXTERNAL REFERENCES  1. COMMUNICATIONS VECTOR TABLE (CVT)           * 03900018
*                                      2.LOG CONTROL AREA (IEELCA)      04200018
*                                                                     * 04500018
* EXITS  VIA BR R14 TO CALLER                                         * 04800018
*                                                                     * 05100018
* OPERATION    UPON ENTRANCE, THE MACHINE IN ENABLED, THE USERS       * 05400018
*        PROTECT IS CHECKED FOR ZERO AND THE SYS1.MAN DATA SET        * 05700018
*        PRESENCE IS DETERMINED. IF EITHER THE PROTECT IS ZERO OR     * 06000018
*        THE DATA SET IS ABSENT, RETURN TO THE CALLER IS MADE.        * 06300018
*        NEXT IT IS DETERMINED IF THIS RECORD IS TO BE WRITTEN BY     * 06600018
*        CHECKING THE USER RECORD ID WITH THE INDICATORS IN LCA.        06900018
*        THE LOF BUFFER IS ENQUEUED UPON AND THE CURRENT LOG BUFFER     07200018
*        POINTER AND SIZE IS GOTTEN. A CHECK IS MADE TO DETERMINE     * 07500018
*        IF THE USER RECORD WOULD EXCEED THE MAXIMUM BUFFER SIZE.     * 07800018
*        IF SO, THE USER RECORD MUST BE SEGMENTED. IF IT WILL NOT     * 08100018
*        EXCEED THE MAXIMUM LENGTH, A CHECK IS MADE TO DETERMINE      * 08400018
*        IF IT WILL FIT IN THE EMPTY PORTION OF THE BUFFER. IF IT     * 08700018
*        WILL NOT FIT, THE BUFFER IS WRITTEN TO SYS1.MAN. UPON        * 09000018
*        RETURN FROM THE WRITE OR THE USER RECORD WILL FIT, IT IS     * 09300018
*        MOVED INTO THE BUFFER. NEXT A CHECK IS MADE TO DETERMINE     * 09600018
*        IF THE BUFFER IS TO BE WRITTEN. IF SO, IT IS WRITTEN. EITHER * 09900018
*        CASE, THE BUFFER IS DEQUEUED AND THE ROUTINE EXITS TO THE    * 10200018
*        CALLER.    IF THE RECORD IS TO BE SEGMENTED AND THE BUFFER   * 10500018
*        IS NOT EMPTY, THE BUFFER IS WRITTEN. NEXT THE HEADER         * 10800018
*        (RECORD TYPE,TIME,DATE,SYSTEM ID) IS SAVED, THE CONTINUATION * 11100018
*        COUNT IS SET TO 01 AND THE FIRST SEGMENT IS PUT INTO THE     * 11400018
*        BUFFER AND WRITTEN. UPON RETURN, THE CONTINUATION COUNT      * 11700018
*        IS UPDATED BY ONE, THE NEXT SEGMENT IS PLACED IN THE BUFFER  * 12000018
*        AND WRITTEN. WHEN THE LAST SEGMENT IS PLACED IN THE BUFFER,  * 12300018
*        THE HIGH ORDER BIT IS SET IN THE CONTINUATION COUNT AND IS   * 12600018
*        HANDLED AS ANY NON-SEGMENTED RECORD AND EXIT IS MADE         * 12900018
*                                                                     * 13200018
*********************************************************************** 13500018
         EJECT                                                          13800018
IEE0303F CSECT                                                          14100018
* 363200,367600,516000                                            M2591 14150020
*                                                                A31526 14200020
*                                                                       14400018
* REGISTER EQUATE                                                       14700018
*                                                                       15000018
R0       EQU   0                                                        15300018
R1       EQU   1                       USER RECORD POINTER - INPUT      15600018
R2       EQU   2                       UNUSED                           15900018
WORK     EQU   2                       WORK                             16200018
R3       EQU   3                       CVT POINTER(INPUT) AND WORK      16500018
WORK1    EQU   4                       TCB POINTER(INPUT) AND WORK      16800018
R4       EQU   WORK1                                              20030 16900020
R5       EQU   5                       RB POINTER(INPUT)                17100018
COUNT    EQU   6                       WORK                             17400018
BUFPTR   EQU   7                       LOG BUFFER POINTER               17700018
R8       EQU   8                                                        18000018
BASEREG  EQU   9                       MODULE BASE                      18300018
RECORD   EQU   10                      USER RECORD POINTER              18600018
CONTINUE EQU   11                      CONTINUATION REG                 18900018
LOGTBASE EQU   12                      LOG TABLE POINTER                19200018
WORKBASE EQU   13                      WORK AREA POINTER                19500018
LINK     EQU   14                      LINKAGE REGISTER                 19800018
R14      EQU   14                      EXIT POINTER                     20100018
R15      EQU   15                      XCTL REGISTER                    20400018
*                                                                       20420018
* EQUATES                                                               20440018
*                                                                       20460018
N0       EQU   0                                                        20480018
N1       EQU   1                                                        20500018
N2       EQU   2                                                        20520018
N3       EQU   3                                                        20540018
N4       EQU   4                                                        20560018
N8       EQU   8                                                        20580018
N12      EQU   12                                                       20600018
N20      EQU   20                                                       20620018
N256     EQU   256                                                      20640018
X40      EQU   X'40'                                                    20660018
MAXWTL   EQU   130                                                      20680018
         EJECT                                                          20700018
*                                                                       21000018
* INITIALIZE                                                            21300018
*                                                                       21600018
         BALR  BASEREG,R0              SET BASE                         21900018
         USING *,BASEREG                                                22200018
         USING WORKAREA,WORKBASE                                        22500018
         USING LOGBUFFR,BUFPTR                                          22800018
         USING USEREC,RECORD                                            23100018
         SSM   *+N1                    ENABLE                           23400018
         ORG   *-3                SET LOC CTR TO BEGINNING OF CSECT     23700018
         DC    X'FF'                   *                                24000018
         ORG                                                            24300018
         L     R3,CVTPTR                                                24600018
         USING LOGCVT,R3                                                24900018
         L     R5,CVTMSER                                               25200018
         USING BASE,R5                                                  25500018
         L     LOGTBASE,BALOG                                           25800018
         TM    BALOG,X'80'             IS LOG INITIALIZED???     A31256 25900020
         BZ    PRECHECK                BRANCH NO-NOT YET         A31256 26000020
         USING LCABASE,LOGTBASE                                         26100018
         N     LOGTBASE,TURNOFF        TRRN OFF HIGH ORDER BIT          26200018
         LPR   R8,R1                                                    26400018
*                                                                       26700018
*        IF R1 CONTAINS A NEGATIVE POINTER TO THE LCA, THEN             26800018
*        ENTRY IS DURING INITIALIZATION AND CONTROL IS IMMEDIATELY      26900018
*        TRANSFERRED TO IEE0403F.                                       27000018
*                                                                       27300018
         CLR   R8,LOGTBASE                                              27600018
         BNE   CHECK                   GO SAVE USER RECORD POINTER      27900018
         LA    R15,LCAXCTL                                              28200018
         MVC   LCAXNAM(N8),DUMPNAME                                     28500018
        XCTL   SF=(E,(15))                                              28800018
PRECHECK SR    LOGTBASE,LOGTBASE                                 A31526 28900020
         SPACE 2                                                        29100018
CHECK    EQU   *                                                        29400018
         LR    RECORD,R1               SAVE POINTER TO USER RECORD      29700018
*   VALIDITY CHECK THE LENGTH PASSED IN THE USERS PARAMETERS.  IT       29740018
*   MUST BE GREATER THAN FOUR AND LESS THAN 131.                        29780018
         CLC   USERSIZE,FOUR       IS LENGTH GREATER THAN FOUR          29820018
         BNH   EXIT                BRANCH IF NO                         29860018
         CLC   USERSIZE,K131       IS LENGTH LESS THAN 131              29900018
         BNL   EXIT                BRANCH IF NO                         29940018
*                                                                       30000018
GETWORK  EQU   *                                                        30300018
         GETMAIN   R,LV=WORKSIZE,SP=255          GET WORK AREA          30600018
         XC    N0(WORKSIZE,R1),N0(R1)  CLEAR IT                         30900018
         LR    WORKBASE,R1             SET WORKAREA BASE                31200018
*ENQ ON LOG BUFFER                                                      33900018
*                                                                       34200018
         SR    R0,R0               INDICATE ENQ                         34600018
         BAL   LINK,CONSTENQ           CONSTRUCT ENQ LIST               35100018
         TM    MSLOGST,MSLOGTHD    IS LOG SUPPORTED                     35200018
         BO    WTOLOOP             BRANCH IF NO                         35300018
         LTR   LOGTBASE,LOGTBASE                                        35330018
         BZ    WTOLOOP                                                  35360018
WAITBUF  EQU   *                                                        35400018
         USING TCB,R4                                             20030 35405020
         TM    TCBTSFLG,TCBTSTSK   CHECK FOR TIME SHARED TASK     20030 35410020
         BNO   NOTSO               SAVE TJID ONLY IN TSO          20030 35415020
         L     R4,TCBJSCB          GET JSCB POINTER               20030 35420020
         USING IEZJSCB,R4                                         20030 35425020
         MVC   LCATJID(N2),JSCBTJID  SAVE TJID                    20030 35430020
NOTSO    EQU   *                                                  20030 35435020
         WAIT  ECB=LCABECB             WAIT FOR BUFFER AVAILABILITY     35440018
         XC    LCATJID(N2),LCATJID  CLEAR TJID TO AVOID CONFUSION 20030 35460020
         TM    MSLOGST,MSLOGTHD        IS LOG SUPPORTED                 35480018
         BZ    WRECFIT                 BRANCH IF YES                    35520018
WTOLOOP  EQU   *                                                        35560018
         LA    R0,4          INDICATE DEQ OFF RESOURCE SINCE      M2591 35570020
*                            LOG IS INACTIVE                      M2591 35580020
         BAL   LINK,CONSTENQ BRANCH TO PERFORM THE DEQUEUE        M2591 35590020
*        THIS SECTION IS EXECUTED WHEN NO LOG DATA SET IS A AILABLE     35600018
         MVC   INRECSAV(2),USERSIZE    MOVE LNTH TO WORKAREA            35640018
         LH    WORK1,INRECSAV          LOAD LENTH                       35680018
         SH    WORK1,FOUR              ADJUST FOR 4 BYTE PARM AREA      35720018
         MVC   WTOMID,WLOGMID     MOVE WTL NOW WTO MSG ID TO WORK AREA  35760018
         LA    R11,USERCONT           POINT TO FIRST BYTE OF MSG        35800018
WTOLOOPA EQU   *                                                        35840018
         CH    WORK1,MAXWLNTH       CAN REMAINING BYTES IN MSG FIR IN   35880018
*                                     ONE WTO                           35920018
         BNH   LASTWRTE                BRANCH IF YES                    35960018
         LA    R7,MAXEXLN              GET LENGTH FOR EXECUTE           36000018
         EX    R7,MOVEWTO              MOVE NEXT BYTEX TO MSG AREA      36040018
         LA    R7,MAXEXLN+DEC13        SET LENGTH OF WTO                36080018
         STH   R7,WTOLN                STORE IN PARMS                   36120018
         XC    WTOFLGS,WTOFLGS         CLEAR FLAGS                      36160018
         LA    R1,WTOLN                SET PARAMETER REG                36200018
         WTO   ,MF=(E,(1))             ISSUE WTO                        36240018
         SH    WORK1,MAXWLNTH         ADJUST NUMBER OF BYTES REMAINING  36280018
         BZ    RETURN2       BRANCH IF DONE                       M2591 36320020
         LA    R11,MAXEXLN+DEC1(R11)    POINT TO NEXT BYTE              36360018
         B     WTOLOOPA                PROCESS REMAINING BYTES          36400018
LASTWRTE EQU   *                                                        36440018
         BCTR  WORK1,0                 SET LENGTH FOR EXECUTE           36480018
         EX    WORK1,MOVEWTO          MOVR REMAINING BYTES TO MSG AREA  36520018
         LA    WORK1,DEC13(WORK1)      SET WTO LENGTH                   36560018
         STH   WORK1,WTOLN             STORE IN PARM AREA               36600018
         XC    WTOFLGS,WTOFLGS         CLEAR FLAGS                      36640018
         LA    R1,WTOLN               SET PARAMETER REG                 36680018
         WTO   ,MF=(E,(1))             ISSUE WTO                        36720018
         B     RETURN2       RETURN TO CALLER                     M2591 36760020
MOVEWTO  MVC   WTOLTXT(1),0(R11)       EXECUTEC INSTRUCTION             36800018
WRECFIT  EQU   *                                                        37200018
*                                                                       37500018
* MOVE USER RECORD INTO BUFFER                                          37800018
*                                                                       38100018
         BAL   LINK,GETBUF             GET CURRENT BUFFER PTR AND COUNT 38400018
         LA    CONTINUE,RETURN                                          38700018
         MVC   INRECSAV(N2),USERSIZE   ALIGN SIZE OF CALLERS RECORD     39000018
         L     WORK1,INRECSIZ          GET USER RECORD SIZE             39300018
         LTR   WORK1,WORK1             IS USER RECORD SIZE ZERO         39600018
         BZ    RETURN              BRANCH IF ZERO LENGTH                39900018
         AH    WORK1,LOGBLOCK          ADD NEW TO CURRENT BYTE COUNT    40200018
         EJECT                                                          41100018
         LR    COUNT,BUFPTR            SAVE BUFFER POINTER              42300018
         AH    BUFPTR,LOGBLOCK         POINT TO NEXT AVAILABLE BYTE     42600018
*                                      IN BUFFER(FOR USER'S RECORD)     42900018
         STH   WORK1,N0(R0,COUNT)      UPDATE LOG BYTE COUNT            43200018
         L     COUNT,INRECSIZ          SET LENGTH OF DATA TO MOVE       43500018
         BAL   LINK,VARMOVE            MOVE USER RECORD TO LOG BUFFER   43800018
*                                                                       43810018
* WOULD NEXT WTL(MAXIMUM POSSIBLE SIZE)OVERFLOW BUFFER                  43820018
*                                                                       43830018
         BAL   LINK,GETBUF                                              43850018
         LA    R2,MAXWTL               MAXIMUM WTL SIZE                 43900018
         AH    R2,LOGBLOCK             ADD CUMULATIVE BUFFER COUNT      43950018
         C     R2,LCABSIZ              WOULD NEXT WTL OVERFLOW BUFFER   44000018
         BH    EMPTYBUF                BRANCH IF YES                    44050018
*                                                                       44100018
WRITCHCK EQU   *                                                        46500018
*                                                                       46800018
         TM    LCAPOSTT,POSTCLOZ       IS CLOSE IN PROCESS              47100018
         BO    FLUSHA                  YES, FLUSH BUFFER ANYWAY         47400018
*  USER RECORDS MUST BE WRITTEN FOR CLOSE OPERATION                     47700018
*                                                                       48000018
         B     RETURN                  GO SET UP FOR RETURN             48400018
FLUSHA   LA    CONTINUE,RETURN         POINT TO SVC EXIT AFTER WRITE    48900018
         B     EMPTYBUF                FLUSH BUFFER                     49200018
*                                                                       49500018
* RETURN TO CALLER                                                      49800018
*                                                                       50100018
RETURN   EQU   *                                                        50400018
         LA    R0,4                INDICATE DEQ                         50700018
         BAL   LINK,CONSTENQ                                            51000018
RETURN2  L     R14,RETSAVE   SET EXIT REGISTER                    M2591 51400020
         LR    R1,WORKBASE             SET FREEMAIN ADDRESS             51900018
         FREEMAIN  R,LV=WORKSIZE,A=(1),SP=255                           52200018
EXIT     EQU   *                                                        52500018
         SVC   LEAVE               RETURN TO CALLER                     52800018
*                                                                       53100018
*LOG BUFFER WRITER INTERFACE                                            53400018
*                                                                       53700018
EMPTYBUF EQU   *                                                        54000018
         OI    MSLOGST,X'20'           DO NOT ALLOW COMP TASK TO        54100018
*                                      ISSUE WTL                        54200018
         OI    LCAPOSTT,POSTCHAN       TURN ON  SVC BUFFER HANDLER POST 54300018
         XC    LCABECB(N4),LCABECB     CLEAR BUFFER ECB TO CLOSE BUFFER 54600018
         POST  BALOGECB                FOR WRITE REQUEST                54900018
         BR    CONTINUE                                                 56900018
         EJECT                                                          59100018
         EJECT                                                          60300018
* SET UP ENQ LIST AND ISSUE ENQ                                         60600018
*                                                                       60900018
*   R1 POINTS TO CORE INWHICH THE LIST IS TO BE CONSTRUCTION            61200018
*   R3 POINTS TO MINOR NAME                                             61500018
*                                                                       61800018
CONSTENQ EQU   *                                                        62100018
         LA    R1,BENQCORE         SET REG1                             62200018
         LA    R3,BENQLIST         SET R3                               62300018
         MVC   N0(N4,R1),ENQPARM       SET INDICATORS                   62500018
         MVC   N20(N3,R1),N0(R3)       SET MINOR NAME                   62700018
         MVC   N12(N8,R1),MAJOR        SET MAJOR NAME                   62900018
         LA    R3,N12(N0,R1)           POINT TO MAJOR NAME              63100018
         ST    R3,N4(N0,R1)            SET MAJOR NAME POINTER           63300018
         LA    R3,N20(N0,R1)           POINT TO MINOR NAME              63500018
         ST    R3,N8(N0,R1)            ISSUE ENQ                        63700018
         LTR   R0,R0               DEQ OR ENQ                           64300018
         BNZ   CDEQA               BRANCH IF DEB                        64400018
        ENQ    MF=(E,(1))              ISSUE ENQ                        64500018
         BR    LINK                    RETURN                           64800018
CDEQA    EQU   *                                                        64870018
         DEQ   MF=(E,(1))          ISSUE DEB                            64940018
         BR    LINK                                                     65010018
*                                                                       65100018
* VARIABLE LENGTH MOVE                                                  65400018
*                                                                       65700018
*  THIS SUB-ROUTINE MOVES DATA FROM THE USER'S AREA (REG 'RECORD') TO   66000018
*   THE LOG BUFFER (REG 'BUFFER') BY THE COUNT (REG 'COUNT'). RETURN    66300018
*   IS VIA REG 'LINK'. REG 'WORK' IS A WORK REGISTER.                   66600018
*                                                                       66900018
VARMOVE  EQU   *                                                        67200018
         LA    WORK,N256               SET MAX SINGLE MOVE              67500018
VARMOVE1 EQU   *                                                        67800018
         CR    COUNT,WORK              SINGLE MOVE REQUIRED             68100018
         BH    VARMOVE2                NO                               68400018
         BCTR  COUNT,R0                SET COUNT FOR EXECUTED MOVE      68700018
         EX    COUNT,MOVE              MOVE DATA                        69000018
         LA    COUNT,N1(R0,COUNT)      RESTORE LAST COUNT               69300018
         BR    LINK                    RETURN                           69600018
VARMOVE2 EQU   *                                                        69900018
         BCTR  WORK,R0                 SET COUNT FOR EXECUTED MOVE      70200018
         EX    WORK,MOVE               MOVE 256 BYTES                   70500018
         LA    WORK,N256               RESTORE MAX COUNT                70800018
         SR    COUNT,WORK              REDUCE COUNT BY 256              71100018
         AR    BUFPTR,WORK             BUMP LOG BUFFER POINTER          71400018
         AR    RECORD,WORK             BUMP USER DATA POINTER           71700018
         B     VARMOVE1                CHECK FOR NEXT MOVE              72000018
         SPACE 2                                                        72300018
MOVE     MVC   N0(N0,BUFPTR),N0(RECORD)  EXECUTED USER DATA MOVE        72600018
         EJECT                                                          72900018
*                                                                       73200018
* GET LOG BUFFER POINTER AND SIZE                                       73500018
*                                                                       73800018
GETBUF   EQU   *                                                        74100018
         L     COUNT,LCABSIZ           GET LOG BUFFER HALF              74400018
         L     BUFPTR,LCABUFP          GET LOG BUFFER POINTER           74700018
         TM    LCAMISC,LCABSW          WHICH HALF IS AVAILABLE          75000018
         BCR   N8,LINK                 FIRST HALF - RETURN              75300018
         AR    BUFPTR,COUNT            POINT TO SECOND HALF             75600018
         BR    LINK                    RETURN                           75900018
         EJECT                                                          76200018
*                                                                       76500018
* CONSTANTS                                                             76800018
*                                                                       77100018
ENQPARM  DC    X'FF034000'             ENQ INDICATORS                   77400018
BENQLIST DC    C'BUF'                  MINOR ENQ NAME                   77700018
MAJOR    DC    C'SYSLOG01'             MAJOR ENQ NAME                   78000018
DUMPNAME DC    C'IGC0403F'             DUMP INTERFACE AND OPENER NAME   78300018
CON08    DC    H'8'                     EIGHT                           78600018
FOUR     DC    H'4'                    CONSTANT OF FOUR                 78900018
MAXWLNTH DC    H'64'                                                    78930018
K131     DC    H'131'                                                   78940018
LEAVE    EQU   3                   EXIT SVC                             78950018
MAXEXLN  EQU   63                  MAXIMUM EX LENGTH                    78960018
DEC13    EQU   13                                                       78990018
DEC1     EQU   1                                                        79020018
R6       EQU   6                                                        79050018
R7       EQU   7                                                        79080018
R11      EQU   11                                                       79110018
WLOGMID  DC    C'IEE147I '         MSG ID THAT INDICATES LOG NOT SUPP   79150018
         DS    0F                                                       79160018
TURNOFF  DC    X'7FFFFFFF'                                              79170018
         EJECT                                                          79200018
         IEEBASEA                                                       79500018
         EJECT                                                          79800018
         IEELCA                                                         80100018
         EJECT                                                          80400018
LOGBUFFR DSECT                                                          80700018
*                                                                       81000018
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 81300018
*                                                                     * 81600018
* THIS IS THE LAYOUT OF THE FIELDS FOUND IN THE LOG BUFFER            * 81900018
*                                                                     * 82200018
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 82500018
*                                                                       82800018
LOGBLOCK DS    1H                      LOG PHYSICAL RECORD LENGTH       83100018
         DS    1H   ALWAYS ZERO          IT CONTAINS THE TOTAL COUNT    83400018
*                                        OCCUPIED BY DATA INCLUDING     83700018
*                                        ITSELF                         84000018
*                                                                       84300018
*  E A C H   L O G I C A L   R E C O R D   C O N T A I N S              84600018
*                                                                       84900018
*   T H E   F O L L O W I N G   F I E L D S                             85200018
*                                                                       85500018
LOGLOCNT DS    1H                      LOGICAL RECORD SIZE INCLUDING    85800018
         DS    1H   ALWAYS ZERO          ITSELF                         86100018
LOGDATA  DS    1C                      USER VARIABLE LENGTH DATA        86400018
         EJECT                                                          86700018
*                                                                       87000018
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 87300018
*                                                                       87600018
* U S E R   R E C O R D   L A Y O U T                                   87900018
*                                                                       88200018
*                                                                       88500018
USEREC   DSECT                                                          88800018
USERSIZE DS    1H                      SIZE OF USER RECORD              89100018
         DS    1H                      ALWAYS ZERO                      89400018
USERCONT DS    1C                       RESERVED - BEGINNING OF DATA    89700018
USERTYP  DS    1C                      RECORD TYPE                      90000018
USERTIME DS    4C                      TIME                             90300018
USERDATE DS    4C                      DATE                             90600018
USERSYID DS    4C                      ID                               90900018
USERDATA DS    1C                      VARIABLE LENGTH DATA             91200018
         EJECT                                                          91500018
*                                                                       91800018
* WORK AREA LAYOUT                                                      92100018
*                                                                       92400018
WORKAREA DSECT                                                          92700018
RETSAVE  DS    F                       MODULE EXIT POINTER              93000018
BENQCORE DC    C'FF034000'             BUFFER ENQ/DEQ INDICATORS        93300018
         DC    A(0)                    BUFFER MAJOR NAME POINTER-ENQ    93600018
         DC    A(0)                    BUFFER MINOR NAME POINTER-ENQ    93900018
         DC    C'SYSSMF01'             BUFFER MAJOR NAME                94200018
         DC    C'BUF'                  BUFFER MINOR NAME                94500018
         DS    0F                                                       94800018
INRECSIZ DC    X'0000'                 ALWAYS ZERO                      95100018
INRECSAV DC    X'0000'                 USER RECORD SIZE REMAING TO MOVE 95400018
*                                                                       95700018
* HEADER - TO BE REPEATED FOR CONTINUATION RECORDS                      96000018
*                                                                       96300018
INRECONT DS    1C                       RESERVED - BEGINNING OF DATA    96600018
INRECTYP DS    13C                     TYPE,TIME,DATE + SYS ID FIELDS   96900018
REPSIZE  EQU   *-INRECONT              SIZE OF HEADER                   97200018
ADDPUT   DS    8C                      TRACK CONVERSION AREA            97500018
         ORG   BENQCORE+4          RESET                                97550018
WTOLN    DS    CL2                 LENTH OF WTO                         97600018
WTOFLGS  DS    CL2                 *                                    97650018
WTOMID   DS    CL8                 MSGID FOR CONVERTED WTL MESSAGE      97700018
WTOLTXT  DS    CL64                POSSIBLE LENGTH OF MESSAGE           97750018
WORKSIZE EQU   *-WORKAREA              WORK AREA SIZE                   97800018
         EJECT                                                          98100018
LOGCVT   DSECT                                                          98400018
         CVT                                                            98700018
         IKJTCB                                                         98800020
         IEZJSCB                                                        98900020
         END                                                            99000018
