 TITLE 'IMMEDIATE COMMANDS ROUTINE - SET - PART I'                21774 00020021
IEE0603D CSECT                                                          00040000
*                                                                 21774 00042021
* A 009300,054700-054720,106900                                   M0777 00044021
* 036600-037000,073200-073400                                     M2081 00050020
*********************************************************************** 00060000
*                                                                 21774 00070021
* THE PROLOGUE COMMENTS BELOW, HAVING AN ID FIELD OF 21 AND       21774 00074021
* NOT FLAGGED, ARE THE CHANGES FOR THE 21774 PROJECT.             21774 00076021
*                                                                 21774 00080021
*TITLE:  IEE0603D   IMMEDIATE COMMANDS ROUTINE - SET - PART I         * 00100021
*                                                                     * 00120000
*FUNCTION: ACCEPTS THE PARAMETERS OF THE SET COMMAND: CLOCK AND DATE  * 00150021
*          AND PROCEEDS AS FOLLOWS: IF AT IPL TIME, DATE, OR DATE AND * 00152021
*          TIME ARE SPECIFIED, PASSES THEM TO THE NEXT MODULE,        * 00154021
*          IEE8603D.  DATA IS ALSO PASSED IF TIME AND/OR DATE IS(ARE) * 00156021
*          SPECIFIED AT NON-IPL TIME.  OTHERWISE, AN ERROR EXIT TO THE* 00158021
*          MESSAGE MODULE, IEE0503D, IS TAKEN.  IN ADDITION, POSITIVE * 00160021
*          SYNTAX CHECKING IS PERFORMED ON KEYWORDS AND PARAMETERS.   * 00240021
*                                                                     * 00260000
*ENTRY POINT: IEE0603D  FROM COMMAND ROUTER MODULE, IEE0403D.         * 00280000
*                                                                     * 00300000
*ATTRIBUTES: REENTRANT, TRANSIENT, READ ONLY AND SELF-RELOCATABLE.    * 00320000
*                                                                     * 00340000
*APPLICABILITY: VARIABLE MEMORY SYSTEM.                               * 00360000
*                                                                     * 00380000
*EXTERNAL REFERENCES: MASTER RESIDENT CORE, USING MACRO IEEBASEA      * 00400021
*                     EXTENDED SAVE AREA(XSA), USING MACRO IEEXSA     * 00420021
*                     COMMUNICATIONS VECTOR TABLE, USING MACRO CVT    * 00440021
*                                                                     * 00460000
*MACROS: XCTL, IEEXSA, CVT, AND IEEBASEA.                             * 00480021
*                                                                     * 00500000
*INPUT: REGISTER 2 POINTING TO THE EXTENDED SAVE AREA WHICH MUST      * 00520000
*        CONTAIN:                                                     * 00530021
*            IN XAR, A POINTER TO THE COMMAND BUFFER                  * 00540021
*            IN XAL, A POINTER TO THE PARAMETER LIST (FIRST KEYWORD)  * 00560000
*       REGISTER 10 POINTING TO MASTER RESIDENT CORE(IEEBASEA)    M2081 00570021
*                                                                     * 00580000
*OUTPUT: FOR A NORMAL EXIT (TO IEE8603D, THE SECOND MODULE OF THE     * 00590021
*         IMMEDIATE COMMANDS ROUTINE), THE CLOCK AND/OR DATE IS(ARE)  * 00690021
*         SET IN THE EXTENDED SAVE AREA (XSA) AT THE XAS AND XAV      * 00692021
*         LOCATION RESPECTIVELY.  ZEROES ARE PUT IN THESE AREAS IF    * 00696021
*         UNSPECIFIED.  CLOCK AND/OR DATE MASK BIT SETTINGS IS(ARE)   * 00696421
*         SAVED IN THE XSA AT THE XAE LOCATION.  THE COUNTER USED FOR * 00698421
*         INDICATING NUMBER OF KEYWORDS PROCESSED ARE SAVED IN THE XSA* 00698821
*         AT THE XAU+4 LOCATION.  THE INPUT CONTENTS AS SPECIFIED     * 00703021
*         ABOVE ARE ALSO USED AS OUTPUT.                              * 00711621
*        FOR AN ERROR EXIT (TO IEE0503D, THE MESSAGE ASSEMBLER),      * 00715821
*          REG 2 POINTS TO THE EXTENDED SAVE AREA (XSA) WHICH         * 00720021
*          CONTAINS:                                                  * 00730021
*           IN XAE, THE MESSAGE CODE (SEE ERROR MESSAGES BELOW)       * 00740000
*           IN XAV, THE VERB IN EBCDIC, LEFT ADJUSTED WITH BLANKS     * 00760000
         EJECT                                                          00780021
*EXITS: NORMAL      TO IEE8603D                                       * 00800021
*       ERROR       TO THE MESSAGE ASSEMBLY MODULE (IEE0503D)         * 00820000
*                                                                     * 00840000
*ERROR MESSAGES: THE FOLLOWING CONDITIONS GENERATE THE INDICATED      * 00880000
*   MESSAGES                                                          * 00900000
*      1.NON-NUMERIC OR EXCESSIVE CHARACTERS IN TIME OR DATE          * 00920000
*        OR, DATE SPECIFIED WITH DDD = 000                        M0777 00930021
*        'IEE306I SET  INVALID NUMERICS.'           (CODE=6)          * 00940021
*      2.MISPLACED PERIODS IN CLOCK OR DATE PARAMETER, OR MISSING     * 00960021
*        RIGHT PARENTHESIS                                            * 00970021
*        'IEE307I SET  DELIMITER ERROR.'            (CODE=7)          * 00980021
*      3.FAILURE TO FIND BLANK, COMMA OR END OF BUFFER AFTER PARAMETER* 01000000
*        'IEE308I SET  TERM LENGTH ERROR.'          (CODE=8)          * 01020021
*      4.NO KEYWORD OR NO DATE SPECIFIED AT IPL TIME, OR AT NON-IPL   * 01080021
*        TIME, NO DATE AND/OR CLOCK KEYWORD SPECIFIED                 * 01090021
*        'IEE310I SET  KEYWORD MISSING.'            (CODE=10)         * 01100021
*      5.BLANK AFTER KEYWORD                                          * 01120021
*        'IEE311I SET  PARAMETER MISSING.'          (CODE=11)         * 01140021
*      6.REPEATED KEYWORD                                             * 01160021
*        'IEE312I SET  PARAMETERS CONFLICT.'        (CODE=12)         * 01180021
*                                                                     * 01256021
* NOTE- IF AN ERROR OCCURS IN A SYSTEM WITH THE TOD CLOCK, A CODE 20071 01256421
*       OF EIGHT IS PLACED IN BAIPL(IPL ECB) TO INDICATE TO IPL   20071 01256821
*       THAT AN ERROR OCCURRED ON THE SET COMMAND.                20071 01257221
*                                                                     * 01258021
*OPERATION:                                                           * 01260021
*   EACH INCOMING COMMAND HAS ITS LEADING KEYWORD COMPARED WITH A     * 01300000
*   TABLE(KEYTAB) CONTAINING EACH OF THE TWO POSSIBLE KEYWORDS, CLOCK * 01320021
*   AND DATE.  SUCCESSFUL COMPARISON RESULTS IN TRANSFER BEING MADE,  * 01340021
*   USING KEYTAB, TO THE APPROPRIATE KEYWORD SUBROUTINE.  SUCCESSFUL  * 01360021
*   RECOGNITION OF A KEYWORD CAUSES THE SETTING OF AN ID MASK FOR THAT* 01380021
*   KEYWORD IN THE XSA.  CHECKS FOR VALID NUMERICS THAT DO NOT EXCEED * 01420021
*   THE PRE-DETERMINED MAXIMUMS ARE MADE.  THEN THE VALID TIME AND/OR * 01440021
*   DATE, IF SPECIFIED, IS(ARE) PACKED AND HELD IN THE XSA.  THE      * 01490021
*   PROCESSED KEYWORD COUNTER IS INCREMENTED BY ONE.  RETURNING FROM  * 01492021
*   THE SUBROUTINES, A CHECK IS MADE FOR SUCCESSIVE KEYWORDS.  IF     * 01500021
*   THERE ARE MORE, THE KEYTAB SCAN IS REPEATED.  IF THE KEYWORD CAN  * 01520021
*   NOT BE FOUND IN THE KEYWORD TABLE, THE BUFFER IS SCANNED FOR THE  * 01530021
*   NEXT VALID KEYWORD.  WHEN THE BUFFER HAS BEEN SCANNED, A XCTL IS  * 01532021
*   MADE TO THE SECOND MODULE, IEE8603D, FOR FURTHER PROCESSING.      * 01540021
         EJECT                                                          01820000
*TABLES/WORK AREAS: THE EXTENDED SAVE AREA AS USED INTERNALLY IN      * 01840000
*   IEE0603D IS MAPPED AS FOLLOWS:                                    * 01860000
*                                                                     * 01880021
*  ****************************************************************   * 01900021
*  *XAP                            *XAD                           *   * 01920021
*  *SAVE AREA FOR POINTER TO       *                              *   * 01940021
*  *END OF COMMAND BUFFER          *                              *   * 01960021
*  ****************************************************************   * 01980021
*  *XAX                                                           *   * 02000021
*  *                                                              *   * 02020021
*  *                                                              *   * 02040021
*  ****************************************************************   * 02050021
*  *XAE    *XAR                    *XAL                           *   * 02080021
*  *K.W. ID*POINTER TO THE         *SAVE AREA FOR CURRENT         *   * 02100021
*  *MASK   *COMMAND BUFFER         *PARAMETER POINTER             *   * 02120021
*  ****************************************************************   * 02150021
*  *XAV                            *XAV+4                         *   * 02160021
*  *                               *DATE IN PACKED                *   * 02180021
*  *                               *DECIMAL                       *   * 02200021
*  ****************************************************************   * 02230021
*  *XAS                            *XAS+4                         *   * 02240021
*  *                               *TIME IN PACKED                *   * 02260021
*  *                               *DECIMAL                       *   * 02280021
*  ****************************************************************   * 02310021
*  *XAU                            *XAU+4  *                      *   * 02330021
*  *                               *KEYWORD*                      *   * 02332021
*  *                               *COUNT  *                      *   * 02334021
*  ****************************************************************   * 02336021
*                                                                     * 02338021
*   A KEYWORD TABLE(KEYTAB), WHICH CONTROLS KEYWORD SCANNING AND      * 02340000
*   KEYWORD SUBROUTINE BRANCHING.                                     * 02360000
*                                                                     * 02380000
*CHARACTER SET: THE OPERATION OF THIS MODULE DEPENDS UPON AN INTERNAL * 02480021
*   REPRESENTATION OF THE EXTERNAL CHARACTER SET WHICH IS EQUIVALENT  * 02500000
*   TO THE ONE USED AT ASSEMBLY TIME. THE CODING HAS BEEN ARRANGED SO * 02520000
*   THAT REDEFINITION OF 'CHARACTER' CONSTANTS, BY REASSEMBLY, WILL   * 02540000
*   RESULT IN A CORRECT MODULE FOR THE NEW DEFINITIONS.               * 02560000
*                                                                     * 02580000
*********************************************************************** 02600000
         EJECT                                                          02620000
*      REGISTER ASSIGNMENTS        FUNCTION(S)                          02640000
R1       EQU   1                   BASE REGISTER FOR CVT          21774 02660021
R2       EQU   2                       BASE FOR XSA                     02680000
R3       EQU   3                       CURRENT PARAM PTR AND LINK REG   02700000
R4       EQU   4                       KEYTAB PTR AND WORK REGISTER     02720000
R5       EQU   5                       ERROR LINKER AND WORK REGISTER   02740000
R6       EQU   6                   WORK REGISTER                  21774 02760021
R7       EQU   7                   WORK REGISTER                  21774 02780021
R8       EQU   8                       WORK REGISTER                    02800000
R9       EQU   9                       PARAMETER POINTER AND WORK REG   02820000
R10      EQU   10                      BASE FOR MASTER RESIDENT CORE    02840000
R11      EQU   11                      WORK REGISTER                    02860000
SBASE    EQU   12                      BASE FOR PROGRAM                 02880000
R13      EQU   13                                                 20071 02890020
R14      EQU   14                            BRANCH REG           20071 02895020
R15      EQU   15                      XCTL                             02900000
*                                                                     * 02920000
* DISPLACEMENTS OF INFORMATION WITHIN KEYWORD TABLE ELEMENTS:     21774 02940021
*  KEYTBL - KEYWORD TABLE LENGTH (DEFINED AFTER THE TABLE BELOW)  21774 02972021
KEYELN   EQU   14                  KEYWORD TABLE ELEMENT LENGTH   21774 02980021
KEYLNG   EQU   0                   DISPLACEMENT OF KEYWORD LENGTH 21774 03000021
KEYDIS   EQU   1                   DISPLACEMENT OF DELIMITER      21774 03020021
KEYWRD   EQU   2                   DISPLACEMENT OF KEYWORD        21774 03040021
KEYBRN   EQU   8                   DISPLACEMENT OF BRANCH         21774 03060021
KEYIDM   EQU   12                  DISPLACEMENT OF ID MASK        21774 03080021
* ERROR CODES FOR MESSAGE MODULE                                        03100000
ERR6     EQU   6                                                        03120000
ERR7     EQU   7                                                        03140000
ERR8     EQU   8                                                        03160000
ERR10    EQU   10                                                       03200000
ERR11    EQU   11                                                       03220000
ERR12    EQU   12                                                       03240000
* PERIOD DISPLACEMENTS FOR DATE AND CLOCK                             * 03280000
PERD1    EQU   2                             DISPLACEMENT OF PERIOD     03300000
PERD2    EQU   5                             DISPLACEMENT OF PERIOD     03320000
D0       EQU   0                                                  21774 03320121
D1       EQU   1                                                  21774 03320421
D2       EQU   2                                                  20071 03322020
D3       EQU   3                                                  20071 03324020
D4       EQU   4                                                  21774 03326421
D8       EQU   8                                                  20071 03328020
* UPPER AND LOWER COMPARANDS FOR SCHECK                               * 03340000
SNUMHI   EQU   C'9'                          HIGH NUMERIC               03360000
SNAWT    EQU   C'0'                          CHARACTER ZERO             03380000
SEINS    EQU   X'01'                         BINARY ONE                 03400000
SNUMLO   EQU   SNAWT-SEINS                   LOW NUMERIC COMPARAND      03420000
ZERO     EQU   X'00'                                              21774 03430021
TWO      EQU   X'02'                                              21774 03432021
THREE    EQU   X'03'                                              21774 03434021
COMMA    EQU   C','                                               21774 03436021
LEFT     EQU   C'('                                               21774 03438021
RIGHT    EQU   C')'                                               21774 03438421
         EJECT                                                          03440000
* MAIN ROUTINE - ESTABLISHES ADDRESSABILITY FOR PROGRAM, XSA, AND     * 03460000
*    MASTER RESIDENT CORE. USES XSA POINTERS TO COMMAND BUFFER AND    * 03480000
*    LEADING KEYWORD TO IDENTIFY THE KEYWORD.  KEYWORD            21774 03500021
*    RECOGNITION LEADS TO BRANCHING TO THE KEYWORD'S SUBROUTINE.  21774 03540021
*    ALSO SETS UP THE BASIC XCTL NAME.                            21774 03550021
*                                                                     * 03580000
         BALR  SBASE,0                       ESTABLISH PROGRAM          03600000
         USING *,SBASE                       ADDRESSABILITY             03620000
         USING XSA,R2                        BASE FOR EXTENDED SAVE A   03640000
         USING BASE,R10                      TO ESTABLISH ADDRESSABLTY  03720000
         MVC   XAX(D8),XL8603D     SET UP BASIC XCTL              21774 03730021
         L     R9,XAL                        USE REGISTER 9 AS POINTER  03740000
         LA    R9,0(R9)                      TO PARAMETER KEYWORD       03760000
         LTR   R9,R9                         IS PARAMETER PTR 0   20071 03780020
         BZ    SERR10                        YES. KEYWORDS MISSING20071 03800020
         L     R7,XAR                        LOAD PTR TO BUFFER         03840000
         LA    R7,0(R7)                      CONTAINING COMMAND         03860000
         LH    R6,0(R7)                      LOAD BUFFER LENGTH         03880000
         N     R6,SFFFF-2                    CLEAR POSSIBLE GARBAGE     03900000
         AR    R7,R6                         COMPUTE END OF BUFFER      03920000
         ST    R7,XAP                        SAVE IN FIRST WORD OF XSA  03940000
         NI    XAE,ZERO            CLEAR ID MASK AREA             21774 03960021
         SR    R8,R8               CLEAR PROCESSED KEYWORD        21774 03970021
*                                       COUNTER                   21774 03972021
         SPACE                                                          03980000
SNEWKY   EQU   *                             EXAMINE KEYWORD            04000000
         LA    R6,KEYELN                     LOAD KEYTAB ELEMENT LENGTH 04020000
*                                            FOR INCREMENT IN BXLE      04040000
         LA    R4,KEYTAB                     ADCON OF KEYWORD TABLE     04060000
         LA    R7,KEYTBL(R4)                 LOAD KEYWORD TABLE LENGTH  04080000
*                                            FOR COMPARAND IN BXLE      04100000
         SR    R5,R5                         LOAD LENGTH OF A           04120000
SLOOP    EQU   *                                                  21774 04130021
         IC    R5,KEYLNG(R4)                 PARTICULAR KEYWORD         04140000
         EX    R5,SETCLC                     IS THIS THE KEYWORD        04160000
         BE    SBRANCH             YES, NOW GO CHECK PARAMETER    21774 04180021
         BXLE  R4,R6,SLOOP         RECHECK IF NOT END OF TABLE    21774 04200021
         B     SCOMMA              END OF TABLE, SCAN FOR NEXT    21774 04220021
*                                       KEYWORD                   21774 04230021
SBRANCH  EQU   *                                                  21774 04240021
         LA    R9,1(R9,R5)                   POINT REG TO PARAM         04260000
         CLI   0(R9),C' '                    IS PARAMETER BLANK         04280000
         BE    SERR11                        YES. ERROR                 04300000
         SPACE                                                          04320000
         SR    R3,R3                         POINT A REG TO THE END OF  04340000
         IC    R3,KEYDIS(R4)                 PARAMETER                  04360000
         LA    R3,0(R3,R9)                                              04380000
         C     R3,XAP                        IS BUFFER EXCEEDED         04400000
         BH    SERR08                        YES. ERROR                 04420000
         SPACE                                                          04440000
         SR    R5,R5                         NO. PREPARE TO             04460000
         IC    R5,KEYIDM(R4)                 LOAD KEYWORD'S ID MASK     04480000
         EX    R5,SETTMP                     IS THIS KEYWORD A REPEAT   04500000
         BO    SERR12                        YES. ERROR                 04520000
         SPACE                                                          04540000
         OC    XAE(D1),KEYIDM(R4)  SAVE KEYWORD'S ID IN XSA       21774 04560021
         EX    0,KEYBRN(R4)                  GO TO APPROPRIATE SUBRTN   04600000
         SPACE                                                          04610021
* THIS SUBROUTINE IS ENTERED WHEN A VALID KEYWORD IS NOT FOUND IN 21774 04610421
* THE TABLE.  IT CHECKS FOR THE NEXT COMMA, OUTSIDE THE           21774 04610821
* PARENTHESES, IF ANY.  IF FOUND, THE NEW KEYWORD IS FOUND AFTER  21774 04611221
* THE COMMA.                                                      21774 04611621
SCOMMA   EQU   *                                                  21774 04612021
         LA    R9,D1(R9)           INCREMENT TO NEXT BUFFER       21774 04614021
*                                       ELEMENT                   21774 04614421
         C     R9,XAP              IS IT END OF BUFFER?           21774 04616021
         BH    SETOUT              YES, BRANCH                    21774 04618021
         CLI   D0(R9),LEFT         NO, IS IT A LEFT PARENTHESIS?  21774 04618421
         BE    SRIGHT              YES, BRANCH                    21774 04618821
         CLI   D0(R9),COMMA        NO, IS IT A COMMA?             21774 04619221
         BNE   SCOMMA              NO, CHECK NEXT BUFFER ELEMENT  21774 04619621
         LA    R9,D1(R9)           YES, INCREMENT TO THE NEXT     21774 04619721
*                                       BUFFER ELEMENT            21774 04619821
         B     SNEWKY              BRANCH AND PROCESS THE NEW     21774 04619921
*                                       KEYWORD                   21774 04622221
         SPACE                                                          04625521
* THIS SUBROUTINE IS ENTERED WHEN A LEFT PARENTHESIS IS           21774 04627821
* ENCOUNTERED IN THE SUBROUTINE ABOVE.  IT LOOKS FOR A RIGHT      21774 04630121
* PARENTHESIS, AND THEN BRANCHES BACK TO THE SCOMMA SUBROUTINE.   21774 04632421
SRIGHT   EQU   *                                                  21774 04634721
         LA    R9,D1(R9)           INCREMENT TO NEXT BUFFER       21774 04637021
*                                       ELEMENT                   21774 04639321
         C     R9,XAP              IS IT END OF BUFFER?           21774 04641621
         BH    SERR07              YES, TAKE ERROR EXIT           21774 04643921
         CLI   D0(R9),RIGHT        NO, IS IT A RIGHT PARENTHESIS? 21774 04646221
         BNE   SRIGHT              NO, CHECK NEXT BUFFER ELEMENT  21774 04650821
         B     SCOMMA              YES, BRANCH BACK TO SCOMMA     21774 04653121
         EJECT                                                          04655421
* KEYWORD=CLOCK SUBROUTINE - SYNTAX CHECKS THE CLOCK PARAMETER FOR    * 04657721
*    PROPER POSITIONING OF PERIODS, NUMERIC CHARACTERS, AND THE EX-   * 04660000
*    CEEDING OF PROPER LIMITS FOR HOUR, MINUTE OR SECOND. A VALID     * 04680000
*    PARAMETER IS PACKED IN THE XSA TEMPORARILY, IN XAS.              * 04700000
*                                                                     * 04720000
SCLOCK   EQU   *                                                        04740000
         LA    R8,D1(R8)           INCREMENT PROCESSED KEYWORD    21774 04750021
*                                       COUNTER BY ONE            21774 04752021
         CLI   PERD1(R9),C'.'      CHECK FOR PROPER PLACEMENT     21774 04760021
         BNE   SERR07                        INCORRECT                  04780000
         CLI   PERD2(R9),C'.'                OF PERIODS                 04800000
         BNE   SERR07                        INCORRECT                  04820000
         MVC   XAS(2),0(R9)                  PLACE TIME IN EXTENDED     04840000
         MVC   XAS+2(2),3(R9)                SAVE AREA                  04860000
         MVC   XAS+4(2),6(R9)                SANS PERIODS.              04880000
         LA    R11,6                         LOAD LOOP CONTROL REGISTER 04900000
         LA    R9,XAS                        SET PTR TO TIME            04920000
         BAL R13,SCHECK                      VERIFY TIME DIGITS   20071 04950020
         CLC   XAS(2),SETCHR                 DOES HOUR EXCEED 23        04980000
         BH    SERR06                        YES. ERROR                 05000000
         CLC   XAS+2(2),SETCMS               DOES MINUTE EXCEED 59      05020000
         BH    SERR06                        YES. ERROR                 05040000
         CLC   XAS+4(2),SETCMS               DOES SECOND EXCEED 59      05060000
         BH    SERR06                        YES. ERROR                 05080000
         PACK  XAS+4(4),XAS(6)               PACK TIME FOR CONVERSION   05100000
         B     SETNXT                        GO CHECK NEXT KEYWORD      05120000
         EJECT                                                          05140000
* KEYWORD=DATE SUBROUTINE - SYNTAX CHECKS THE DATE PARAMETER FOR      * 05160000
*    PROPER POSITIONING OF PERIODS, NUMERIC CHARACTERS, AND THE EX-   * 05180000
*    CEEDING OF PROPER LIMITS FOR THE DAY. A VALID PARAMETER IS       * 05200000
*    PACKED IN THE XSA TEMPORARILY, IN XAV.                           * 05220000
*                                                                     * 05240000
SDATE    EQU   *                                                        05260000
         LA    R8,D1(R8)           INCREMENT PROCESSED KEYWORD    21774 05270021
*                                       COUNTER BY ONE            21774 05272021
         CLI   PERD1(R9),C'.'                IS PERIOD POSITIONED       05280000
         BNE   SERR07                        NO. ERROR                  05300000
         MVC   XAV(2),0(R9)                  CONSOLIDATE DATE WITHOUT   05320000
         MVC   XAV+2(3),3(R9)                PERIODS                    05340000
         LA    R11,5                         SET LOOP CONTROLLER TO 5   05360000
         LA    R9,XAV                        SET PTR TO DATE            05380000
         BAL   R13,SCHECK                    VERIFY DATE DIGITS   20071 05390020
         L     R1,CVTPTR                    GET PTR TO CVT        20071 05392020
         USING SETCVT,R1                    ESTAB CVT BASE        20071 05394020
         TM    CVTOPTB,CVTTOD               IS TOD SUPPORTED      20071 05396020
         BNO   CONTINU3                NO, DONT CHECK FOR 60      20071 05398020
         CLC   XAV(D2),SETCMS                IS YEAR LESS THAN 1960     05400020
         BNH   SERR06                        YES. INVALID NUMERIC 20071 05410020
CONTINU3 EQU   *                                                        05430020
         CLC   XAV+2(3),SETDDY               DOES DAY EXCEED LIMIT      05440000
         BH    SERR06                        YES. ERROR                 05460000
         CLC   XAV+D2(D3),SET000             IS DAY 000 (ERROR)   M0777 05470021
         BE    SERR06                        YES.INVALID NUMERICS M0777 05472021
         PACK  XAV+4(4),XAV(5)               PACK DATE FOR CONVERSION   05480000
         B     SETNXT                        GO CHECK NEXT KEYWORD      05500000
         EJECT                                                          05520000
* THE FOLLOWING CLOSED SUBROUTINE IS USED BY SCLOCK AND SDATE TO      * 05540000
*    CHECK THAT ALL PARAMETER CHARACTERS ARE NUMERIC. R11 IS LOOP     * 05560000
*    COUNTER, R13 IS RETURN REGISTER, R9 POINTS TO THE PARAMETER. 21774 05580021
*                                                                     * 05600000
SCHECK   EQU   *                                                        05620000
         SR    R4,R4                         SET INCREMENT REGS TO ZERO 05640000
         SR    R6,R6                                                    05660000
         LA    R5,SNUMLO                     SET LOWER LIMIT OF DIGIT   05680000
         LA    R7,SNUMHI                     SET UPPER LIMIT OF DIGIT   05700000
SDGTLP   EQU   *                                                  21774 05710021
         SR    R15,R15             CLEAR FOR LOADING              21774 05720021
         IC    R15,D0(R9)          TAKE ONE CHARACTER             21774 05740021
         BXLE  R15,R4,SERR06       TEST FOR LOW                   21774 05760021
         BXH   R15,R6,SERR06       TEST FOR HIGH                  21774 05780021
         LA    R9,1(R9)                      INCREMENT CHARACTER PTR    05800000
         BCT   R11,SDGTLP                    IS LOOP DONE               05820000
         BR    R13                           YES. RETURN          20071 05840020
         EJECT                                                          05860000
* RETURNED TO FROM A KEYWORD SUBROUTINE, THIS PORTION OF THE MAIN 21774 05870021
*    ROUTINE CHECKS IF THE SET COMMAND IS COMPLETE OR IF THERE    21774 07620021
*    ARE MORE KEYWORDS. A COMMA AS DELIMITER RESULTS IN THE       21774 07640021
*    RETURN TO THE KEYWORD TABLE SCAN FOR THE NEW KEYWORD.        21774 07660021
*    SUCCESSFUL COMPLETION LEADS TO 'SETOUT'.                     21774 07680021
*                                                                     * 07700000
SETNXT   EQU   *                                                        07720000
         C     R3,XAP                        IS IT VALID END OF BUFFER  07740000
         BE    SETOUT                        YES. END OF SET COMMAND    07760000
         CLI   0(R3),C' '                    IS NEXT CHARACTER A BLANK  07780000
         BE    SETOUT                        YES. END OF SET COMMAND    07800000
         CLI   0(R3),C','                    IS NEXT CHARACTER A COMMA  07820000
         BNE   SERR08                        NO. MUST BE ERROR          07840000
         LA    R9,1(R3)                      YES. BUMP CURRENT PARAM    07860000
         CLI   0(R9),C' '                    IS NEXT CHAR BLANK         07880000
         BE    SERR07                        YES. DELIMITER ERROR.      07900000
         B     SNEWKY                        GO CHECK NEXT KEYWORD.     07920000
         EJECT                                                          07940000
* AFTER THE COMMAND'S CONTENTS HAVE BEEN COMPLETELY VERIFIED, THIS    * 07960000
*    SECTION PERFORMS THE FOLLOWING FUNCTIONS: IF IT IS IPL TIME AND  * 07980000
*    THE DATE HAS BEEN SPECIFIED, CONTROL IS PASSED TO IEE8603D.  21774 08000021
*    IF NOT IPL TIME, ANY SPECIFIED TIME OR DATE IS SAVED IN THE  21774 08040021
*    XSA AND CONTROL IS ALSO GIVEN TO IEE8603D.                   21774 08060021
*                                                                     * 08080000
SETOUT   EQU   *                                                        08100000
         STC   R8,XAU+D4           SAVE PROCESSED KEYWORD COUNTER 21774 08110021
         TM    BASFL,BAIN                    IS IT IPL TIME             08120000
         BO    SNOIPL              NO                             21774 08140021
         TM    XAE,TWO             YES, IS DATE SET FOR IPL?      21774 08160021
         BZ    SERR10              NO, ERROR                      21774 08180021
SXCTL    EQU   *                                                  21774 08424021
         SR    R15,R15             SET DCB POINTER TO ZERO        21774 08460021
         ST    R15,XAD                                                  08480000
         LA    R15,XAX                       PUT PTR TO NAME IN LIST    08500000
         ST    R15,XAP                                                  08520000
         LR    R15,R2                        PUT PTR TO LIST IN REG 15  08540000
         XCTL  SF=(E,(15))                   PASS CONTROL               08560000
SNOIPL   EQU   *                                                  21774 08790021
         TM    XAE,THREE           IS DATE OR CLOCK SPECIFIED?    21774 08792021
         BNZ   SXCTL               YES, GO TO XCTL                21774 08794021
         B     SERR10              NO, ERROR EXIT                 21774 08796021
         EJECT                                                          08800000
* THE FOLLOWING INSTRUCTIONS PASS A DESIGNATED ERROR CODE TO THE      * 08820000
*    SET COMMAND ERROR SUBROUTINE, 'SETERR', IN REGISTER 5.           * 08840000
*                                                                     * 08860000
SERR06   BAL   R5,SETERR                     ERROR CODE = 6             08880000
         DC    AL1(ERR6)                                                08900000
*                                                                     * 08920000
SERR07   BAL   R5,SETERR                     ERROR CODE = 7             08940000
         DC    AL1(ERR7)                                                08960000
*                                                                     * 08980000
SERR08   BAL   R5,SETERR                     ERROR CODE = 8             09000000
         DC    AL1(ERR8)                                                09020000
*                                                                     * 09040000
SERR10   BAL   R5,SETERR                     ERROR CODE =10             09120000
         DC    AL1(ERR10)                                               09140000
*                                                                     * 09160000
SERR11   BAL   R5,SETERR                     ERROR CODE =11             09180000
         DC    AL1(ERR11)                                               09200000
*                                                                     * 09220000
SERR12   BAL   R5,SETERR                     ERROR CODE =12             09240000
         DC    AL1(ERR12)                                               09260000
         EJECT                                                          09340000
* ERROR SUBROUTINE - RECEIVES IN REGISTER 5 AN ERROR MESSAGE CODE     * 09360000
*    WHICH IS PLACED IN THE XSA (IN XAE). CONTROL GOES TO THE MESSAGE * 09380000
*    ASSEMBLY MODULE, IEE0503D, BY XCTL.                              * 09400000
SETERR   DS    0H                                                       09420000
         MVC   XAV(8),SETSET                 MOVE VERB NAME TO XSA      09440000
         MVC   XAE(1),0(R5)                  INSERT ERROR CODE          09460000
         MVC   XAX+D3(2),C05       GO TO IEE0503D                 21774 09480421
         L     R1,CVTPTR               GET PTR TO CVT             M2081 09481020
         USING SETCVT,R1               ESTAB ADDRESSABILITY       M2081 09482020
         TM    CVTOPTB,CVTTOD          IS TOD SUPPORTED           M2081 09483020
         BZ    SXCTL                   NO. NO ERROR CODE          M2081 09484020
         LA    R15,D8                  SET UP BAD SET RETURN CODE 20071 09486020
         ST    R15,BAIPL               PUT RET CODE IN IPL ECB    20071 09492020
         B     SXCTL                         GO TO XCTL EXIT            09500000
         EJECT                                                          09520000
* THE FOLLOWING TABLE CONTROLS THE SCAN OF INCOMING KEYWORDS AND THE  * 09540000
*   BRANCHING TO SPECIFIC KEYWORD SUBROUTINES.                        * 09560000
*                                                                     * 09580000
         DS    0H                                                       09600000
KEYTAB   EQU   *                                                        09620000
         DC    X'5'                          KEYWORD LENGTH MINUS ONE   09640000
         DC    X'8'                          PARAMETER DELIMITER        09660000
         DC    C'CLOCK='                     KEYWORD                    09680000
         B     SCLOCK                        SPECIFIC CODING            09700000
         DC    X'01'                         KEYWORD ID MASK PATTERN    09720000
         DS    C                             FILLER                     09740000
*                                                                     * 09760000
         DC    X'4'                          KEYWORD LENGTH MINUS ONE   09780000
         DC    X'6'                          PARAMETER DELIMITER        09800000
         DC    C'DATE='                      KEYWORD                    09820000
         DC    C' '                          FILLER                     09840000
         B     SDATE                         SPECIFIC CODING            09860000
         DC    X'02'                         KEYWORD ID MASK PATTERN    09880000
ENDTAB   DS    C                   FILLER                         21774 09900021
KEYTBL   EQU   (ENDTAB-KEYTAB)     LENGTH OF TABLE                21774 10390021
         EJECT                                                          10400000
* CONSTANTS USED BY THE IMMEDIATE COMMANDS ROUTINE                    * 10420000
*                                                                     * 10440000
         DS    0F                                                       10500000
         DC    X'0000'                                                  10520000
SFFFF    DC    X'FFFF'                                                  10540000
*                                                                     * 10560000
XL8603D  DC    C'IGC8603D'         NAME OF IEE8603D MODULE        21774 10600021
C05      DC    C'05'               OVERLAY FOR ERROR MODULE       21774 10610021
*                                       XCTL'ING                  21774 10612021
*                                                                     * 10620000
SETCHR   DC    C'23'                         MAXIMUM HOUR               10640000
SETCMS   DC    C'59'                         MAXIMUM MINUTE OR SECOND   10660000
SETDDY   DC    C'366'                        MAXIMUM DAY                10680000
SET000   DC    C'000'              DAY 000 IS IN ERROR            M0777 10690021
*                                                                     * 10700000
SETSET   DC    C'SET     '         VERB FOR MESSAGE MODULE        21774 10702021
*                                                                 21774 10710021
SETCLC   CLC   0(1,R9),KEYWRD(R4)            COMPARE NEW KW WITH TAB KW 10780000
SETTMP   TM    XAE,ZERO            TEST ID MASK PATTERN           21774 10800021
         EJECT                                                          10920000
SETXSA   DSECT                                                          10940000
         IEEXSA                                                         10960000
         EJECT                                                          10980000
SETCVT   DSECT                                                          11000000
         CVT                                                            11020000
         EJECT                                                          11040000
         IEEBASEA                                                       11060000
         END                                                            11080000
