         TITLE 'TIMER  S E T   C O M M A N D  HANDLER'                  00020000
IEAQOT00 START 0                                                        00040000
         SPACE 2                                                        00060000
* ROUTINE NAME- .IEAQOT00,SET COMMAND HANDLER.                          00080000
         SPACE                                                          00100000
* FUNCTION-    .PLACES DATE ENTERED BY SET COMMAND INTO CVT.            00120000
*              .USES LOCAL TIME CLOCK VALUE ENTERED BY SET COMMAND TO   00140000
*               UPDATE LTPC SO THAT LOCAL TIME OF DAY (LTOD) CAN BE     00160000
*               CALCULATED BY THE FORMULA- LTOD=LTPC+T4PC+(SHPC-TIMER). 00180000
*               ALSO ADJUSTS MIDNIGHT INTVL TO REFLECT THE (NEW) TIME   00200000
*               UNTIL MIDNIGHT. SEARCH THROUGH TIMER QUEUE AND MAKES    00220000
*               ADJUSTMENT TO ALL INTERVALS CREATED USING THE TOD       00240000
*               OPTION IN THE STIMER MACRO.                             00260000
*              .IF OPTION 6A IS IN SYSTEM, I.E., NO TIMER QUEUE OTHER   00280000
*               THAN THE RUDIMENTARY QUEUE EXISTS, ONLY THE MIDNIGHT    00300000
*               INTERVAL IS ADJUSTED.                                   00320000
         SPACE                                                          00340000
* ENTRY POINT NAME- .IEAQOT00, SET COMMAND HANDLER.                     00360000
         SPACE                                                          00380000
* CONTAINED IN MODULE- .IEAQOT00, SET COMMAND HANDLER.                  00400000
         SPACE                                                          00420000
* ATTRIBUTES-  .REENTRANT, SUPERVISOR STATE, DISABLE FOR SYSTEM         00440000
*               INTERRUPTS, TRANSIENT.                                  00460000
         SPACE                                                          00480000
* EXTERNAL REFERENCES- .NONE                                            00500000
*                   CVTTPC(LOADED).                                     00520000
*                  .TIMER PSEUDO CLOCKS-SHPC(LOADED), T4PC(LOADED),     00540000
*                   LTPC(SET)                                           00560000
*                  .TIME QUEUE- ALL INTERVALS ESTABLISHED USING'TOD'    00580000
*                   OPTION ARE ADJUSTED.                                00600000
         SPACE                                                          00620000
* SVC USED-    .NONE                                                    00640000
         SPACE                                                          00660000
* INPUT-       .REG 6- DATE IN PACKED DECIMAL FORMAT,  '00YYDDDF'       00680000
*              .REG 7- TIME IN PACKED DECIMAL FORMAT,  '0HHMMSSF'       00700000
         SPACE                                                          00720000
* OUTPUT-      .UPDATE DATE IN CVT                                      00740000
*              .ADJUSTED LTPC AND TIMER QUEUE (WITH OPTION 6B) AND      00760000
*               ADJUSTED MIDNIGHT INTERVAL BASED ON CURRENT LOCAL TIME. 00780000
         SPACE                                                          00800000
* ENTRY POINTS- .IEAQOT00- SET COMMAND HANDLER.                         00820000
*                  .PSW MUST BE DISABLED FOR SYSTEM INTERRUPTS, SUPV.   00840000
*                   STATE WITH SUPV.PROTECT KEY.                        00860000
*                  .REG 6- DATE ENTERED WITH SET COMMAND.               00880000
*                  .REG 7- TIME ENTERED WITH SET COMMAND.               00900000
*                  .OTHER REGS IRRELEVANT.                              00920000
         SPACE                                                          00940000
* EXIT POINTS-  .SVC 3 AT COMPLETION                                    00960000
*                  .PSW HAS SAME STATUS AS AT ENTRY.                    00980000
*                  .REG SETTING IRRELEVANT.                             01000000
*               .BALR TO TIMER ENQUEUING RTN IF INTERVALS ARE TO BE RE- 01020000
*                QUEUED AFTER ADJUSTMENT                                01040000
*                 .REG 1- ADDRESS OF TQE TO BE ENQUEUED                 01060000
*                 .REG 2- RETURN ADDRESS IN SET COMMAND HANDLER.        01080000
*                 .REG 5- BASE REG. ASSUMED TRANSPARENT OVER      M0234 01100020
*                          ENQUEUING RTN.                               01120000
*                .PSW- DISABLED FOR SYSTEM INTERRUPTS, SUPV STATE,      01140000
*                      SUPV KEY.                                        01160000
         SPACE                                                          01180000
* ERROR EXIT POINTS- .NONE                                              01200000
         SPACE                                                          01220000
* TABLES AND CONTROL BLOCKS REFERENCED- .CVT- CVTDATE(SET),             01240000
         SPACE                                                          01260000
* LIST ORIGINS, TABLES,  - .NONE                                        01280000
* CONTROL BLOCKS INCLUDED                                               01300000
         SPACE                                                          01320000
* RESTRICTIONS- .NONE                                                   01340000
         SPACE                                                          01360000
* NOTES-       .THIS ROUTINE WILL RUN CORRECTLY IN SYSTEMS WITHOUT      01380000
*               TIMER QUEUES (NO OPTION 6B). FOR PCP SYSTEMS THERE WILL 01400000
*               BE NO RESOLVED ADDRESS IN THE CVT FOR THE PSEUDO CLOCK. 01420000
*               IN OPTION 6A SYSTEMS X'FF' IS ASSEMBLED FOLLOWING THE   01440000
*               LTPC WHICH IS TESTED BY THIS CODE.                      01460000
         EJECT                                                          01480000
CVTSECT  DSECT                                                          01500000
         CVT                                                            01520000
         EJECT                                                          01540000
IEAQOT00 CSECT                                                          01560000
* A 044620,044920,047984                                         A39718 01560421
* 023200-023400                                                   20030 01560620
* 001100,019600,023100-023200,040500,040700-040800                M0234 01561220
* 040600-040800                                                   M3217 01562019
* 040600-041200                                                  A27037 01565019
*1112039400                                                       15294 01570016
* 046200,046400,046600                                           A24887 01571019
*...REGISTER EQUATES...                                                 01580000
R0       EQU   0                   .PARM REG FOR TSEVENT            TSO 01590020
         SPACE                                                          01600000
XQPTR    EQU   1             .POINTER TO TIMER QUEUE                    01620000
R1       EQU   1                   .PARM REG FOR TSEVENT            TSO 01630020
XLINK    EQU   2             .LINKAGE REG.                              01640000
XCVT     EQU   3             .PTR TO CVT                                01660000
XDATE    EQU   6             .INPUT REG. FOR DATE                       01680000
XDIG     EQU   6                                                        01700000
XA       EQU   6                                                        01720000
XTIME    EQU   7             .INPUT REG. FOR TIME                       01740000
XPSEUDO  EQU   9             .PTR TO PSEUDO CLOCKS                      01760000
XSEC     EQU   10                                                       01780000
XLT      EQU   10                                                       01800000
XVAR     EQU   10            .INCREMENTING REG.                         01820000
XACCUM   EQU   11            .ACCUMULATES TIME                          01840000
XC       EQU   12                                                       01860000
XINC     EQU   12            .CONTAINS INCREMENTAL VALUE                01880000
XD       EQU   XC+1                                                     01900000
XCMP     EQU   XINC+1        .USED IN BXH COMPARISON                    01920000
XRET     EQU   14            .RETURN REGISTER                           01940000
XBASE    EQU   5                                                  M0234 01950020
R15      EQU   15                                                 M0234 01960020
K0       EQU   0                                                  M0234 01970020
         SPACE 2                                                        01980000
*...DISPLACEMENTS...                                                    02000000
* FOR TIMER SLIH CODE                                                   02020000
VSHPC    EQU   0             .6 HR CLOCK                                02040000
VT4PC    EQU   VSHPC+4       .24 HR CLOCK                               02060000
VLTPC    EQU   VSHPC+8       .LOCAL TIME CLOCK                          02080000
VQPTR    EQU   VSHPC+12      .OFFSET OF QPTR FROM PSEUDO CLOCKS         02100000
VMIDVAL  EQU   52            .OFFSET OF MIDNIGHT INTVL VALUE            02120000
         SPACE                                                          02140000
* FOR TIMER ELEMENT                                                     02160000
VFLG     EQU   0             .FLAG BYTE                                 02180000
VCHAIN   EQU   4             .CHAIN FIELD                               02200000
VVAL     EQU   12            .TIME VALUE                                02220000
CHGTOD   EQU   26            .ENTRY CODE TO TIME-SHARING DRIVER   20030 02225020
ONE      EQU   1         .VALUE USED TO CONVERT FROM 52 TO 26 TU'S20030 02230020
*                                     DRIVER - CHANGE TIME OF DAY 20030 02235020
         SPACE                                                          02240000
*                                                                       02260000
TIMER    EQU   80            .HARDWARE TIMER LOCATION                   02280000
MP65FLAG EQU   X'04'         .CVTDCB FOR MP65 MULTIPROCESSOR       MP65 02286017
PREFTMRA EQU   X'2C8'        .DISPLACEMENT OF MP65 TIMER POINTERS  MP65 02292017
         SPACE 3                                                        02300000
         BALR  XBASE,K0                                           M0234 02310020
         USING *,XBASE                                            M0234 02320020
         SSM   TDISABLE      DISABLE FOR TIMER Q MANIPULATION     15294 02350016
         USING CVTSECT,XCVT                                             02360000
         L     XCVT,CVTPTR        .GET PTR. TO CVT.                     02380000
         LTR   XDATE,XDATE        .IS DATE GIVEN.                       02400000
         BZ    TSTIME             .BR IF NOT.                           02420000
         ST    XDATE,CVTDATE      .STORE DATE INTO CVT.                 02440000
         SR    XDATE,XDATE        .ZERO REG FOR REUSE.                  02460000
TSTIME   LTR   XTIME,XTIME        .IS CLOCK GIVEN.                      02480000
         BZ    TEXIT              .BR TO RETURN IF NOT.                 02500000
         SR    XACCUM,XACCUM                                            02520000
         C     XACCUM,CVTTPC      .IS PSEUDO CLOCK ADDR RESOLVED.       02540000
         BE    TEXIT              .BR IF NOT RESOLVED (=0) TO RETURN.   02560000
         SPACE                                                          02580000
*...CONVERT PACKED DECIMAL TIME TO SECONDS...                           02600000
         SLL   XTIME,4            .SHIFT TIME SO THAT 1ST PACKED HEX.   02620000
*                                  DIGIT OF HRS IS IN HI ORDER BYTE.    02640000
         LA    XVAR,2             .INITIALIZE VARIABLE REG TO -2.       02660000
         LCR   XVAR,XVAR                                                02680000
         LA    XINC,3             .INITIALIZE INC OF +3.                02700000
         LA    XCMP,11            .SET CMPR LIMIT FOR 6 LOOPS.          02720000
TLP      BXH   XVAR,XINC,TLPEND   .BR. 6 TIMES. FALL THRU ON 7TH.       02740000
         SLDL  XDIG,4             .SHIFT ONE HEX DIGIT TO LOW BYTE.     02760000
*...THE FOLLOWING INSTRUCTION HAS AN EXPECTED FLAG. IT IS O.K.          02780000
         MH    XDIG,TABLE-1(XVAR) .DEV SECONDS IN XDIG.                 02800000
         BCT   XVAR,*+6           .FALL THRU 1ST TIME TO DBL VALUE FOR  02820000
*                                  10'S POSITION OF HOURS. NECESSARY TO 02840000
*                                  IMPLEMENT HALF WD MULTIPLIERS.       02860000
         ALR   XDIG,XDIG          .DOUBLE VALUE.                        02880000
         ALR   XACCUM,XDIG        .ACCUM SECONDS.                       02900000
         SR    XDIG,XDIG          .RESTORE REG FOR MULT.                02920000
         B     TLP                                                      02940000
         SPACE                                                          02960000
*...NEW LOCAL TIME IN XACCUM IN SECONDS...                              02980000
TLPEND   CL    XACCUM,TMAX        .DOES VALUE EXCEED 23.59.59.          03000000
         BNH   *+8                .BR IF NOT.                           03020000
         L     XACCUM,TMAX        .USE MAX VALUE.                       03040000
         SPACE                                                          03060000
*...CONVERT TO TU'S...                                                  03080000
         M     XSEC,TCNVRT        .CONVERT SECONDS TO TU'S.             03100000
         D     XSEC,T10E5          DEV 52 MICRO-SECOND UNITS.           03120000
         ALR   XACCUM,XACCUM      .DEV NEW L.T. IN 26 USEC. UNITS.      03140000
         SPACE                                                          03160000
*...COMPUTE ADJUSTMENTS...                                              03180000
         L     XPSEUDO,CVTTPC     .GET ADDR OF PSEUDO CLOCKS.           03200000
         L     XLT,VLTPC(XPSEUDO) .GET CURRENT LTPC VALUE.              03220000
         L     XA,T24HRS          .LOAD 24 HR TU VALUE INTO REG.        03240000
         SLR   XA,XACCUM          .CALC TIME UNTIL MIDNIGHT.            03260000
*                                   = (24 HRS - NEW L.T.)               03280000
         L     XC,VSHPC(XPSEUDO)  .CALC CURRENT LTOD                    03300000
         AL    XC,VT4PC(XPSEUDO)   = SHPC + T4PC                        03320000
         SR    XD,XD              .SET TIMER INDEX FOR NON-MP65    MP65 03325017
         TM    CVTDCB,MP65FLAG    .TASK IN MULTIPROCESSOR MODE     MP65 03330017
         BZ    LODTIME1           .NO, USE INTERVAL TIMER          MP65 03335017
         L     XD,PREFTMRA        .SET INDEX FOR MP65 TIMER        MP65 03340017
LODTIME1 EQU   *                                                   MP65 03345017
         L     XD,TIMER(XD)       .GET PROPER TIMER VALUE          MP65 03350017
         SRA   XD,1                                                     03360000
         SLR   XC,XD                 - TIMER                            03380000
         ALR   XC,XLT                + OLD LTPC                         03400000
         BC    12,*+8             .CHECK FOR OVERFLOW. BR IF NONE       03420000
         B     *+12               .OVERFLOW                             03440000
         CL    XC,T24HRS          .IS VALUE LESS THAN 24 HRS.           03460000
         BL    *+8                .BR IF YES                            03480000
         AL    XC,TADJ            .ADD ADJUSTMENT FACTOR                03500000
*...XC CONTAINS CURRENT LTOD BASED ON OLD LTPC VALUE...                 03520000
*...THE TIME-SHARING DRIVER MUST BE NOTIFIED WHEN THE TIME OF DAY 20030 03522020
*   IS ALTERED BY THE OPERATOR SO THAT HE CAN ADJUST TOD TARGETS. 20030 03524020
*                                                                 20030 03526020
*...PREPARE REGISTERS 1 AND 0 FOR TSEVENT MACRO                   20030 03528020
         SR    R0,R0              .INITIALIZE R0 TO INDICATE      20030 03530020
*                                 .POSITIVE TIME DIFFERENCE       20030 03532020
         SLR   XACCUM,XC          .DEV. CORR. = NEW LTOD - CURR. LTOD.  03540000
         LR    R1,XACCUM          .SAVE TIME DIFFERENCE           20030 03550020
         BC    3,BRCH1            .CHECK FOR UNDERFLOW, BR IF NONE20030 03560020
         AL    XACCUM,T24HRS      .ADD ADJUSTMENT.                      03580000
         L     R0,NEGDIF          .INITIALIZE R0 WITH HIGH ORDER  20030 03580120
*                                 .BIT = 1 TO INIDCATE NEGATIVE   20030 03580220
*                                 .TIME DIFFERENCE                      03580320
BRCH1    EQU   *                                                  20030 03580420
         TM    CVTTSFLG,CVTTSRDY  .IS TIME SHARING DRIVER ACTIVE  20030 03580920
         BZ    NOTSO              .NO - SKIP CODE                 20030 03581820
         LPR   R1,R1              .SET TIME DIFFERENCE TO POSITIVE20030 03585420
NTYTSDRV EQU   *                                                  20030 03587220
         SRL   R1,ONE             .CONVERT TIME DIFFERENCE TO OLD 20030 03588120
*                                     AND NEW LTPC TO 52.08 TU'S. 20030 03589020
         OR    R1,R0              .TO INDICATE SIGN OF TIME       20030 03590020
*                                 .DIFFERENCE                     20030 03591020
*                                    ORDER BIT INDICATING POSITIVE20030 03594420
*                                     OR NEGATIVE CHANGE.         20030 03595320
         LA    R0,CHGTOD          .ENTRY CODE = 26 = CHANGE TOD   20030 03596320
         SVC   95                                                       03598020
NOTSO    EQU   *                                                        03598920
         ALR   XLT,XACCUM         .ADD CORR TO OLD LTPC TO DEV. NEW     03600000
         BC    12,*+8             .CHECK FOR OVERFLOW. BR IF NONE.      03620000
         B     *+12               .OVERFLOW                             03640000
         CL    XLT,T24HRS         .IS VALUE LESS THAN 24 HRS.           03660000
         BL    *+8                .BR IF YES.                           03680000
         AL    XLT,TADJ           .ADD ADJUSTMENT.                      03700000
         ST    XLT,VLTPC(XPSEUDO)  LTPC VALUE. STORE IN LTPC.           03720000
         SPACE                                                          03740000
*...MAKE ADJUSTMENTS TO TIMER QUEUE ELEMENTS...                         03760000
         TM    VQPTR(XPSEUDO),X'FF' .DOES QUEUE EXIST.                  03780000
         BO    TEXIT              .RETURN IF NO QUEUE.                  03800000
         ST    XA,VMIDVAL(XPSEUDO) .STORE NEW MIDNIGHT VALUE.           03820000
         LA    XQPTR,8(XPSEUDO)   .INITIALIZE XQPTR.                    03840000
TQLP     L     XQPTR,VCHAIN(XQPTR) .GET ELM ADDRESS.                    03860000
         CLC   VVAL(4,XQPTR),TQMAX .TEST FOR END OF QUEUE               03880000
         BNE   TLTEST             .BR IF NOT END OF QUEUE               03900000
         SPACE                                                          03920000
TEXIT    SSM   TENABLE       ENABLE MACHINE                       15294 03930016
         SVC   3             RETURN TO CALLER                     15294 03940016
         SPACE                                                          03960000
*...NOTE THAT ALL LOCAL INTERVALS WILL BE ENQUEUED SINCE THE LOCAL      03980000
*   (TOD) OPTION IMPLIES EITHER A REAL OR WAIT INTERVAL.                04000000
TLTEST   TM    VFLG(XQPTR),X'40'  .TEST FOR LOCAL TYPE INTVL.           04020000
         BC    12,TQLP            .CONTINUE SEARCH IF NOT LOCAL INTVL.  04040000
         LR    XC,XBASE            SAVE BASE REG                  M0234 04050020
         L     XVAR,CVTTPC         ADDRESS OF TIMER CORE          M3217 04060019
         L     R15,CVTQTD00        TIMER DEQ RTN ADDR             M0234 04070020
         BALR  XLINK,R15           GO TO TIMER DEQ RTN            M0234 04080020
         LR    XBASE,XC            RESTORE BASE REG               M3217 04090019
         CLI   CVTDCB,X'20'        IS THIS AN MFT SYSTEM?               04122015
         BNE   MVTSYS              BR NO IT'S AN MVT SYSTEM             04124015
         CLI   VFLG(XQPTR),X'C5'   IS THIS A MIDNIGHT INTERVAL?         04126015
         BE    TSTRINT+4                                                04128015
         B     ADJST                                                    04130015
MVTSYS   EQU   *                                                        04132015
         TM    VFLG(XQPTR),X'03'  .IS SUPV. INTERVAL REFERENCED.        04140000
         BC    9,*+12             .BR IF NOT.                           04160000
         TM    VFLG(XQPTR),X'06'  .IS MIDNIGHT SUPV INTVL. REFERENCED.  04180000
         BO    TSTRINT+4          .BR IF YES TO ENQUEUE.                04200000
ADJST    EQU   *                                                        04210015
         L     XC,VSHPC(XPSEUDO)  .CALC 6 HR TOD.                       04220000
         SR    XD,XD              .SET TIMER INDEX FOR NON-MP65    MP65 04225017
         TM    CVTDCB,MP65FLAG    .TASK IN MULTIPROCESSOR MODE     MP65 04230017
         BZ    LODTIME2           .NO, USE INTERVAL TIMER          MP65 04235017
         L     XD,PREFTMRA        .SET INDEX FOR MP65 TIMER        MP65 04240017
LODTIME2 EQU   *                                                   MP65 04245017
         L     XD,TIMER(XD)       .GET PROPER TIMER VALUE          MP65 04250017
         SRA   XD,1                                                     04260000
         SLR   XC,XD              .= SHPC - TIMER                       04280000
         SL    XC,VVAL(XQPTR)        -ELM TOX (WILL GO NEG. IF NOT DUE) 04300000
         BC    4,TNPD             .BR IF NOT PAST DUE.                  04320000
TSETZERO SR    XC,XC              .PAST DUE...SET INTVL TO ZERO.        04340000
         B     TSTRINT                                                  04360000
TNPD     LCR   XC,XC              .DEV POSITIVE INTVL.                  04380000
         SLR   XC,XACCUM          .SUBT CORRECTION FACTOR               04400000
         BC    4,TSETZERO         .IF UNDERFLOW, INTVL IS NOW PAST DUE  04420000
TSTRINT  ST    XC,VVAL(XQPTR)     .STORE ADJUSTED VALUE BACK INTO ELM.  04440000
         L     XLINK,CVTQTE00     .GET ADDR OF TIMER ENQUEUING RTN.     04460000
         ST    R1,R1SAVE           SAVE REG 1 BEFORE ENQUE       A39718 04462021
         LR    15,5                                                     04470020
         BALR  XLINK,XLINK        .TO ENQUEUING RTN.                    04480000
         LR    5,15                                                     04490020
         L     R1,R1SAVE           RESTORE REG 1 AFTER ENQUE     A39718 04492021
         B     TQLP                                                     04500000
         SPACE 2                                                        04520000
*...CONSTANTS...                                                        04540000
TMAX     DC    F'86399'      .23 HRS.59 MINS.59 SECS. IN SECONDS        04560000
TQMAX    DC    F'-1'         .LARGEST LOGICAL VALUE.                    04580000
T10E5    DC    F'100000'     .CONVERSION CONSTANT                       04600000
TCNVRT   DC    X'7270E000'    .CONVERSION CONSTANT               A24887 04620019
T24HRS   DC    X'C5C10000'    .24 HOURS IN TU'S                  A24887 04640019
TADJ     DC    X'3A3F0000'    .MODLUE ADJUSTMENT                 A24887 04660019
TABLE    DC    H'18000'      .CONVERSION TABLE-  .HRS TO SECS.          04680000
         DC    H'3600'                                                  04700000
         DC    H'600'                            .MINS TO SECS.         04720000
         DC    H'60'                                                    04740000
         DC    H'10'                             .SECS TO SECS.         04760000
         DC    H'1'                                                     04780000
TENABLE  DC    X'FF'         ENABLE  MASK                         15294 04786016
TDISABLE DC    X'00'         DISABLE MASK                         15294 04792016
         DS    0F                 BOUNDARY ALIGNMENT              20030 04794020
NEGDIF   DC    X'80000000'        CONSTANT USED TO SET HIGH-ORDER 20030 04796020
*                                   BIT IN REG. FOR TSO DRIVER    20030 04798020
R1SAVE   DC    F'0'               REGISTER 1 SAVE AREA           A39718 04798421
         END                                                            04800000
