         TITLE 'COMMAND HANDLER  VARY AND UNLOAD'                       00020013
         TITLE 'IEE1103D - COMMAND HANDLER - VARY AND UNLOAD'           00040018
*                                                                     * 00060000
*TITLE   IEE1103D   IMMEDIATE COMMANDS ROUTINE SECOND MODULE -        * 00080000
*                       VARY AND UNLOAD                               * 00100013
*                        A NON-MCS ONLY MODULE                   19784* 00110019
*                                                                     * 00120000
*FUNCTION - PROCESSES THE FOLLOWING COMMANDS -                        * 00140018
*              VARY      (UNITNAME),ONLINE OR OFFLINE                 * 00160000
*              VARY      (UNITNAME,UNITNAME,...),ONLINE OR OFFLINE    * 00162017
*              VARY      CPU(CPU ID),ONLINE OR OFFLINE             MP65 00164017
*              VARY      CH(CHANNEL ID),ONLINE OR OFFLINE          MP65 00166017
*              VARY      STOR(STORAGE ID),ONLINE OR OFFLINE        MP65 00168017
*              VARY      STOR(START ADR,END ADR),ONLINE OR OFFLINE MP65 00170017
*              UNLOAD    (UNITNAME)                                   * 00180000
*                                                                     * 00220000
*ENTRY POINT - IEE1103D - FROM COMMAND ROUTER, MODULE IEE0403D        * 00240018
*                                                                     * 00260000
*ATTRIBUTES - REENTRANT,TRANSIENT,READ-ONLY AND SELF-RELOCATING       * 00280018
*                                                                     * 00300000
*APPLICABILITY - VARIABLE MEMORY SYSTEMS                              * 00320018
*                                                                     * 00340000
*EXTERNAL REFERENCES - MASTER RESIDENT CORE, USING MACRO IEEBASEA     * 00360018
*   EXTENDED SAVE AREA(XSA), USING MACRO IEEXSA.                      * 00380000
*   COMMUNICATIONS VECTOR TABLE, USING MACRO CVT.                     * 00400000
*   UNIT CONTROL BLOCK, USING MACRO IEFUCBOB.                         * 00420000
*                                                                   MCS 00440018
*MARCOS   XCTL, IEEXSA, CVT, IEEBASEA, IEFUCBOB                     MCS 00450018
*                                                                     * 00500000
* INPUT - REGISTER 2 POINTS TO THE EXTENDED SAVE AREA                 * 00520018
*         XAR POINTS TO THE COMMAND BUFFER                            * 00540000
*         XAN (IN XSA) CONTAINS THE VERB CODE.                        * 00560000
*         XAL POINTS TO THE COMMAND PARAMETER LIST                    * 00580000
*         XAV (IN XSA) CONTAINS THE VERB.                             * 00600000
*                                                                     * 00620000
*OUTPUT - UNIT FIELD IS CHECKED FOR CORRECT SYNTAX.                 MCS 00640018
*   UNLOAD - UNITNAME IS VERIFIED                                   MCS 00720018
*                                                                   MCS 00740018
*EXITS -  NORMAL - UNLOAD - XCTL TO IGC3103D                        MCS 00760018
*             VARY --- IF SYSTEM MGT FACILITIES (SMF) IS PRESENT IN MCS 00780018
*                      THE SYSTEM, CONTROL IS PASSED TO IGC2303D FOR  * 00800019
*                      ONLINE KEYWORD.                           19784* 00820019
*                                                                   MCS 00840018
*             VARY --- IF NO SYSTEM MFT FACILITIES IS PRESENT THEN  MCS 00860018
*                      XCTL TO IGC3103D                             MCS 00880018
*             VARY --- IF 'CPU', 'CH' OR 'STOR' IS SPECIFIED,EXIT ISMCS 00900018
*                      IGC2203D FOR MULTIPROCESSING ROUTINES        MCS 00920018
*         ERROR  - TO THE MESSAGE MODULE (IGC0503D)                 MCS 00940018
* MESSAGES-NORMAL- NONE                                             MCS 00960018
*                                                                   MCS 00980018
*          ERROR -                                                  MCS 01000018
*                 'IEE307I VARY   DELIMITER ERROR.'                 MCS 01020018
*                     WHEN NO BLANK OR END OF BUFFER AFTER PARAMETERMCS 01040018
*                                                                   MCS 01060018
*                 'IEE308I VARY   TERM LENGTH ERROR.'               MCS 01080018
*                     WHEN PARAMETER IS TOO SHORT.                  MCS 01100018
*                                                                   MCS 01120018
*                 'IEE311I CCCC   PARAMETER MISSING.'               MCS 01200018
*                           (CCCC IS COMMAND)                       MCS 01220018
*                     WHEN XAL IS ZEROES,= NO PARAMETERS            MCS 01240018
*                                                                   MCS 01260018
*                                                                     * 01480000
*OPERATION= A SCAN IS MADE OF ALL THE UNITNAMES TO ENSURE THEY ARE    * 01490017
*           VALID LENGTH (EACH BETWEEN 3 AND 5 CHARACTERS). IT IS   MCS 01520018
*           THEN DETERMINED WHICH OF THE COMMANDS IS SPECIFIED AND  MCS 01550018
*           BITS IN THE XAS ARE SET AS FOLLOWS -                    MCS 01580018
*                                                                   MCS 01610018
*                                                                   MCS 01640018
*                   ONLINE       XAS-XOPCODE IS  X'20'              MCS 01700018
*                   OFFLINE      XAS-XOP3OD5 IS  X'10'              MCS 01730018
*                                                                     * 01860000
*TABLES/WORKAREAS - THE EXTENDED SAVE AREA IS USED INTERNALLY IN      * 01880018
*   IEE1103D AND IS MAPPED AS FOLLOWS -                               * 01900018
*        XAP - HOLDS ADDRESS OF COMMAND BUFFER END                    * 01920000
*        XAX - HOLDS UNITNAME AND DELIMITER (FOR VARY AND UNLOAD)     * 01940000
*        XAV - HOLDS VERB OR UNITNAME                                 * 01960000
*       XAS - TO SET KEYWORD BITS                                   MCS 01980018
*                                                                     * 02000000
*CHARACTER SET  THE OPERATION OF THIS MODULE DEPENDS UPON AN INTERNAL * 02020000
*   REPRESENTATION OF THE EXTERNAL CHARACTER SET WHICH IS EQUIVALENT  * 02040000
*   TO THE ONE USED AT ASSEMBLY TIME. THE CODING HAS BEEN ARRANGED SO * 02060000
*   THAT REDEFINITION OF 'CHARACTER' CONSTANTS, BY REASSEMBLY, WILL   * 02080000
*   RESULT IN A CORRECT MODULE FOR THE NEW DEFINITIONS.               * 02100000
*                                                                     * 02120000
*********************************************************************** 02140000
*2787                                                             19726 02150017
         EJECT                                                          02155019
IEE1103D CSECT                                                          02160000
* C 035620,A 030900                                              A39894 02162021
* 038560,038900                                                   M3258 02170019
* VARY REGISTER ASSIGNMENTS        FUNCTION(S)                          02180000
R1       EQU   1                       LINKAGE REGISTER                 02200017
R2       EQU   2                       XSA BASE                         02220000
R3       EQU   3                       CVT BASE                         02240000
R4       EQU   4                                                    MCS 02250018
R5       EQU   5                                                    MCS 02260018
R6       EQU   6                                                    MCS 02270018
R7       EQU   7                                                    MCS 02280018
R8       EQU   8                                                    MCS 02290018
R9       EQU   9                                                    MCS 02300018
R10      EQU   10                                                   MCS 02310018
R11      EQU   11                                                   MCS 02320018
VBASE    EQU   12                      PROGRAM BASE                     02413017
R13      EQU   13             USED AS PTR TO FIRST UCM              MCS 02416018
R14      EQU   14                      RETURN REGISTER                  02420000
R15      EQU   15                      XCTL REGISTER                    02440017
*                                                                     * 02460000
* ERROR CODES FOR MESSAGE MODULE                                      * 02480000
ERR8     EQU   8                                                        02560000
ERR11    EQU   11                                                       02600000
MULTPROC EQU   X'04'                   MULTIPROCESSING CODE        MP65 02650017
*                                                                     * 02700000
VRYCOD   EQU   X'28'                         VERB = VARY                02720000
*                                                                     * 02780000
ZERO     EQU   0                                                    MCS 02783018
ONE      EQU   1                                                    MCS 02786018
TWO      EQU   2                                                    MCS 02789018
TRI      EQU   3                                                    MCS 02792018
FOR      EQU   4                                                    MCS 02795018
SVN      EQU   7                                                    MCS 02804018
EIT      EQU   8                                                    MCS 02807018
FIFTN    EQU   15                                                   MCS 02810018
THIRTY2  EQU   32                                                 19084 02813019
LPAREN   EQU   C'('                                                 MCS 02816018
RPAREN   EQU   C')'                                                 MCS 02819018
SLASH    EQU   C'/'                                                 MCS 02822018
COMMA    EQU   C','                                                 MCS 02828018
BLANK    EQU   C' '                                                 MCS 02831018
         EJECT                                                          02840000
* INITIALIZATION - SETS UP MODULE ADDRESSABILITY, AND ESTABLISHES     * 02870017
*   THE END OF BUFFER AND PARAMETER POINTERS.                         * 02900017
*                                                                     * 02940000
         BALR  VBASE,ZERO                       ESTABLISH PROGRAM       02960018
         USING *,VBASE                       ADDRESSABILITY             02980000
         USING XSA,R2                        BASE FOR EXTENDED SAVE A   03000000
         L     R3,CVTPTR           ..                               MCS 03084018
         USING SETCVT,R3                     CVT ADDRESSABILITY     MCS 03088018
         L     R10,XAR                 SAVE ORIGINAL XAR         A39894 03090021
         L     R7,XAR                                             19084 03098019
         LA    R7,ZERO(R7)         CLEAR HIGH ORDER BYTE            MCS 03108018
         L     R9,XAL                                             19084 03114019
         LA    R9,ZERO(R9)                      TO PARAMETER KEYWORD    03120018
         LTR   R9,R9                         IS PARAMETER POINTER ZERO  03140017
         LA    R5,ERR11            PRESET ERR CODE 11,FOR ERR-COND  MCS 03150018
         LA    R15,VULERR          PRESET EXIT RTN ADDRESS          MCS 03160018
         BCR   EIT,R15               YES - PARAMETER MISSING - ERR  MCS 03170018
         AH    R7,ZERO(R7)            COMPUTE END OF BUFFER         MCS 03200018
         LA    R5,ERR8                                              MCS 03210018
         EJECT                                                          03260018
         EJECT                                                          03270017
* UNITNAME SCAN - THE UNITNAMES OF THE INPUT BUFFER ARE CHECKED TO    * 03280017
*   ENSURE THEY ARE BETWEEN THREE AND FIVE CHARACTERS IN LENGTH. IF   * 03290017
*   AN UNITNAME IS GREATER THAN 5 CHARACTERS AND MULTIPROCESSING IS   * 03300017
*   NOT IN THE SYSTEM OR IT IS LESS THEN 3 CHARACTERS, AN ERROR       * 03310017
*   MESSAGE IS PRINTED AND THE COMMAND IGNORED                        * 03320017
*                                                                     * 03330017
PRESCAN0 EQU   *                                                    MCS 03336018
         LR    R13,R9              SAVE START OF BUFFER             MCS 03342018
         CLI   ZERO(R9),LPAREN     IS FIRST CHARACTER A LEFT RAREN  MCS 03351018
         BE    PRESCAN3                YES, SET UP FOR MULTI-DEVICES    03360017
*                                                                       03370017
*  SINGLE UNITNAME CHECK SET UP                                         03380017
*                                                                       03390017
         BAL   R11,UNTCHK              CHECK UNIT NAME                  03400017
         B     MP65CK                  INVALID DEVICE - CHECK MP        03410017
         B     PRESCAN1                END OF DEVICE CHECK              03420017
         BCTR  R5,ZERO                 ERROR CODE IS 7              MCS 03426018
         BCR   FIFTN,R15               DELIMITER ERROR              MCS 03432018
PRESCAN1 EQU   *                                                        03440017
         CH    R6,CON5                 WAS IT FIVE CHARACTERS           03450017
         BNE   PRESCAN7                NO, 3 CHARACTER UNITNAME         03460017
         CLI   TRI(R13),SLASH      DATA CELL INDICATED              MCS 03466018
         BE    PRESCAN7                YES                          MCS 03472018
*                                                                       03490017
* CHECK FOR MULTIPROCESSING OPTION                                      03500017
*                                                                       03510017
MP65CK   EQU   *                                                   MP65 03520017
         CLI   XAN,VRYCOD              IS VERB VARY                MP65 03530018
         BCR   SVN,R15                  NO, TERM LENGTH ERROR      MP65 03540018
         TM    CVTDCB,MULTPROC         MULTIPROCESSING IN SYSTEM   MP65 03550018
         BCR   EIT,R15                  NO, TERM LENGTH ERROR      MP65 03560018
         ST    R10,XAR                  RESTORE XAR FOR MP65     A39894 03562021
         MVC   XAX(EIT),MPNAME           SET MP MODULE NAME        MP65 03570018
         B     VEXIT                   XCTL TO MULTIPROCESSING     MP65 03590017
         EJECT                                                          03600017
*                                                                     * 03610017
* UNITNAME CHECK SUBROUTINE - CHECK UNITNAME FOR VALIDITY             * 03620017
*  REG R6  IS A WORK REGISTER                                         * 03630017
*  REG R11 IS THE LINKAGE REGISTER                                    * 03640017
*    RETURN IS TO REG R11 FOR INVALID LENGTH                          * 03650017
*        TO REG R11 PLUS 4 IF VALID LENGTH AND BLANK/COMMA FOUND*       03660017
*              TO REG R11 PLUS 4 IF VALID LENGTH AND BLANK/COMMA FOUND* 03670017
*              TO REG R11 PLUS 8 IF VALID LENGTH AND RIGHT PAREN FOUND* 03680017
*                                                                     * 03690017
UNTCHK   EQU   *                                                        03700017
         SR    R6,R6                   CLEAR CHARACTER COUNTER          03710017
UNTCHK1  EQU   *                                                        03720017
         BAL   R1,DELIMCHK             IS THIS CHARACTER A DELIMITER    03730017
         B     UNTCHK2                 YES                              03740017
         B     UNTCHK1                 NO, CHECK NEXT CHARACTER         03750017
UNTCHK2  EQU   *                                                        03760017
         ST    R9,XAR              SAVE END OF WORKING BUFFER PTR   MCS 03770018
         CH    R6,CON5                 UNITNAME GREATER THAN FIVE       03780017
         BCR   TWO,R11                   YES, RETURN                    03790018
         BE    UNTCHK4                  EQUAL - CHECK DELIMITER         03800017
         CH    R6,CON3                 UNIT NAME EQUAL THREE            03810017
         BE    UNTCHK4                 YES, CHECK DELIMITER             03820017
         BCR   FOR,R15                   LOWER - TERM LENGTH ERROR  MCS 03830018
         BR    R11                     EQUALS FOUR - RETURN             03840017
UNTCHK4  EQU   *                                                        03850017
         CLI   ZERO(R9),BLANK      WAS DELIMITER A BLANK          19084 03853019
         BE    UNTCHK5                 ERROR IF IT IS VARY        M3258 03856019
         CLI   ZERO(R9),RPAREN          WAS DELIMITER A RIGHT PAREN MCS 03860018
         LA    R9,ONE(ZERO,R9)              POINT TO NEXT DEVICE        03870018
         BE    EIT(R11)                  NO, EXIT PLUS 8                03880018
         CLI   XAN,VRYCOD              IS IT VARY                 M3258 03882019
         BE    FOR(R11)                YES, COMMA IS OK           M3258 03884019
         B     EIT(R11)            COMMA FOR UNLOAD IS ERROR      M3258 03886019
UNTCHK5  EQU   *                                                  M3258 03888019
         CLI   XAN,VRYCOD              IS IT VARY                 M3258 03890019
         BE    EIT(R11)                VARY DELIMITER ERROR       M3258 03892019
         B     FOR(R11)                UNLOAD, BLANK IS EXPECTED  M3258 03894019
*                                                                       03900017
* MULTIPLE UNITNAME CHECK SET UP                                        03910017
*                                                                       03920017
PRESCAN3 EQU   *                                                        03930017
         CLI   XAN,VRYCOD              VARY COMMAND                     03940017
         BCR   SVN,R15                  NO, UNLOAD TERM LENGTH ERRORMCS 03950018
         LA    R9,ONE(ZERO,R9)              POINT TO FIRST UNITNAME MCS 03960018
         LR    R13,R9                   SAVE POINTER                MCS 03970018
PRESCAN4 EQU   *                                                        03980017
         BAL   R11,UNTCHK              CHECK UNIT NAME                  03990017
         B     ZERO(R15)                  TERM LENGTH ERROR         MCS 03997018
         B     PRESCAN4                VALID LENGTH UNITNAME,CHECK NMCS 04004018
*                                      NEXT                         MCS 04011018
         CLI   ZERO(R9),COMMA      IS THE NEXT CHARACTER A COMMA    MCS 04018018
         LA    R9,ONE(ZERO,R9)              POINT TO THE KEYWORD    MCS 04025018
         BCTR  R5,ZERO                ERROR = 7                     MCS 04032018
         BCR   SVN,R15                  NO, DELIMITER ERROR         MCS 04039018
*                                                                       04050017
* DETERMINE COMMAND VERB                                                04060017
*                                                                       04070017
PRESCAN7 EQU   *                                                        04080017
         CLI   XAN,VRYCOD              VARY OR UNLOAD                   04090017
         BNE   UNLDEXT2             UNLOAD                          MCS 04150018
         XC    XAS(TWO),XAS                                         MCS 04270018
         LA    R11,THIRTY2                                        19084 04470019
         SLL   R11,SVN             NO, ASSUME OFFLINE               MCS 04700018
         CLC   ZERO(TRI,R9),VARYOFF     OFFLINE                   19084 04750019
         BE    UNLDEXT             YES                              MCS 04810018
         AR    R11,R11             NO,ASSUME ONLINE                 MCS 04870018
SMFCK    EQU   *                                                    MCS 05110018
         STH   R11,XAS                                              MCS 05170018
         SR    R6,R6                                                MCS 05290018
         C     R6,CVTSMCA          SMF IN SYSTEM                    MCS 05350018
         BE    UNLDEXT2            GO TO XCTL RTN TO 3103D          MCS 05410018
         MVC   XAX(EIT),XSMF        SMF MODULE                      MCS 05430018
*                                                                   MCS 05440018
*************SET UP INDICATION FOR SMF TO RETURN TO 3103D******   19084 05442019
*                                                                 19084 05444019
         OI    XSWITCH,XSMF31          GO TO 3103D AFTER SMF      19084 05446019
VEXIT    EQU   *                                                        05450018
         SR    R15,R15                       SET DCB POINTER TO ZERO    05460018
         ST    R15,XAD                                                  05470018
         LA    R15,XAX                       PUT PTR TO NAME IN LIST    05480018
         ST    R15,XAP                                                  05490018
         LR    R15,R2                        PUT PTR TO LIST IN REG 15  05500018
         XCTL  SF=(E,(15))                   PASS CONTROL TO IEE0503D   05510018
*                                                                   MCS 05530018
*                                                                   MCS 05590018
*                                                                   MCS 05650018
         EJECT                                                          05710018
*                                                                     * 05770018
* DELIMITER CHECK SUBROUTINE - CHECKS FOR COMMA, BLANK, RIGHT PAREN   * 05830018
*  OR END OF BUFFER REACHED. IT CHECKS ONE CHARACTER PER ENTRY.       * 05890018
*    REG R9 POINTS TO THE CHARACTER TO BE CHECKED. IF A DELIMITER IS  * 05950018
*    FOUND, RETURN IS REG R1. IF IT IS NOT FOUND, R9 AND R6 ARE       * 06010018
*   ADVANCED BY ONE AND RETURN IS R1 PLUS FOUR,                       * 06070018
*                                                                     * 06130018
DELIMCHK EQU   *                                                    MCS 06190018
         CLI   ZERO(R9),COMMA      IS THIS CHARACTER A COMMA        MCS 06250018
         BCR   EIT,R1              YES - EXIT                       MCS 06310018
         CLI   ZERO(R9),BLANK      IS THIS CHARACTER A BLANK        MCS 06370018
         BCR   EIT,R1              YES - EXIT                       MCS 06430018
         CLI   ZERO(R9),RPAREN     IS THIS CHARACTER A RIGHT PARENS MCS 06490018
         BCR   EIT,R1              YES - EXIT                       MCS 06550018
         LA    R9,ONE(ZERO,R9)     POINT TO THE NEXT CHARACTER      MCS 06610018
         LA    R6,ONE(ZERO,R6)     BUMP CHARACTER COUNTER           MCS 06670018
         CR    R9,R7               END OF BUFFER REACHED            MCS 06730018
         BL    FOR(R1)             NO, DELIMITER NOT FOUND          MCS 06790018
         BR    R1                      YES, FAKE DELIMITER FOUND    MCS 06850018
         EJECT                                                          06910018
*  ERROR SUBROUTINE - RECIEVES, IN REG5, A MESSAGE                  MCS 07210018
*   CODE WHICH IS PLACED IN THE XSA (IN XAE). CONTROL GOES TO THE     * 07640000
*   MESSAGE ASSEMBLY MODULE, IEE0503D, BY XCTL.                       * 07660000
*                                                                     * 07680000
VULERR   STC   R5,XAE                  INSERT ERROR CODE            MCS 07700018
         MVC   XAX(EIT),XLMESG                 MODULE NAME FOR XCTL     07710018
         B     VEXIT               GO TO EXIT RTN                       07712018
UNLDEXT  EQU  *                                                     MCS 07714018
         STH  R11,XAS             ..                                MCS 07716018
UNLDEXT2 EQU   *                                                    MCS 07718018
         MVC  XAX(EIT),XLUNLD       MODULE TO CONTINUE PROCESSING   MCS 07720018
         B     VEXIT    XCTL TO MODULE                              MCS 07722018
         EJECT                                                          07860000
* CONSTANTS USED BY IEE1103D.                                         * 07880000
*                                                                     * 07900000
         DS    0H                                                   MCS 07960018
CON5     DC    H'5'                    MCS CONSTATNT                MCS 08020018
         DS    0F                                                   MCS 08100018
XLMESG   DC    C'IGC0503D'         MESSAGE MODULE                   MCS 08300018
MPNAME   DC    C'IGC2203D'         NAME OF MP65 PROCESSING          MCS 08500018
XLUNLD   DC    C'IGC3103D'         VARY SECOND PROCESSOR            MCS 08700018
XSMF     DC    C'IGC2303D'         SYSTEM MGT FACILITIES MODULE     MCS 08900018
CON3     DC    H'3'                    MCS CONSTANT                 MCS 09000018
VARYOFF  DC    C'OFF'                  OFFLINE KEYWORD            19084 10000019
         EJECT                                                          11300018
         TITLE 'IEE1103D - PART II - MCS VARY COMMAND HANDLER'          11500018
         EJECT                                                          82900018
SETXSA   DSECT                                                          83100018
         IEEXSA                                                         83300018
*   RECONFIGURATION OF THE TEMPORARY SAVE AREA                      MCS 83500018
         ORG   XAS                 **                                   83700018
XOPCODE  DS    AL1                 CONTAINS OPERAND CODES               83900018
XSWITCH  DS    AL1                 SYNTAX INDICATORS                    84100018
*                                                                       84150019
XSMF31   EQU   X'08'               SMF TO GO TO 3103D BIT         19084 84200019
*                                                                 19084 84250019
XRESV    DS    AL1                 RESERVED WITHIN VARY PROCESSORS      84300018
XALTPTR  DS    AL1                 ALTS UCM ENTRY INDICATOR             84500018
*                                                                       84700018
XCMDATH  DS    AL2                 COMMAND AUTHORITY                    84900018
XRTCODE  DS    AL2                 ROUTING CODES                        85100018
         EJECT                                                          85300018
SETCVT   DSECT                                                          85500018
         CVT                                                            85700018
         EJECT                                                          86100018
         IEEBASEA                                                       86300018
         EJECT                                                          86500018
UCB      DSECT                                                          86700018
         IEFUCBOB                                                       86900018
         EJECT                                                          87100018
UUCM     DSECT                                                          87300018
         IEECUCM                                                        87500018
         EJECT                                                          87700018
         END                                                            87900018
