         TITLE 'IEE20110  UNIT STATUS ONE, PART OF SVC 110'             00100000
IEE20110 CSECT                                                          00200000
*D157996,203500,405500-405600                                 MC A63123 00201921
*A5884-5924,203500-203580,157996-158123,394500,496500-497000  MC A63123 00203921
*D155000-156000,158000-160000,191000,219000-220660            MC A55717 00209821
*A157500-158332,189420,203500-203600,405500-405600            MC A55717 00211721
*D161000-164000,189000                                        MH A57061 00213621
*        THIS MODULE CREATED FOR RELEASE 21 OF OS/360            S21002 00215521
*********************************************************************** 00217421
*                                                                     * 00219321
* STATUS                                                              * 00221221
*    CHANGE LEVEL=0                                                   * 00223121
*                                                                     * 00225021
* FUNCTION                                                            * 00226921
*    GET CORE FOR WORKAREA                                            * 00228821
*    SYNTAX CHECK COMMAND                                             * 00230721
*    ESTABLISH COMMAND REQUIREMENTS                                   * 00232621
*    FIND STARTING UCB                                                * 00234521
*                                                                     * 00236421
* ENTRY POINTS                                                        * 00238321
*         IEE20110                                                    * 00240221
*                                                                     * 00242121
* INPUT                                                               * 00244021
*    REG 2 CONTAINS THE CSCB ADDRESS WHICH CONTAINS THE COMMAND       * 00245921
*                                                                     * 00247821
* OUTPUT                                                              * 00249721
*    NONE                                                             * 00251621
*                                                                     * 00253521
* EXTERNAL REFERENCES                                                 * 00255421
*         SVC 10   (GETMAIN)                                          * 00257321
*                                                                     * 00259221
* EXITS,NORMAL                                                        * 00261121
*         IEE21110 TO TRY GET REGION (MVT ONLY)                       * 00263021
*         IEE23110 TO FIND MORE UCB'S                                 * 00264921
*                                                                     * 00266821
* EXITS,ERROR                                                         * 00268721
*         IEE22110 TO ISSUE ERROR MESSAGES                            * 00270621
*                                                                     * 00272521
* TABLES/WORKAREAS                                                    * 00274421
*    CSCB                                                             * 00276321
*    XSA                                                              * 00278221
*    WORKAREA                                                         * 00280121
*    CVT                                                              * 00282021
*    UCB                                                              * 00283921
*                                                                     * 00285821
* ATTRIBUTES                                                          * 00287721
*    TYPE IV SVC, PRIVILEGED, RE-ENTRANT                         A36790 00289621
*                                                                     * 00291521
* CHARACTER CODE DEPENDENCY                                           * 00293421
*    NONE                                                             * 00295321
*                                                                     * 00297221
* NOTES                                                               * 00299121
*    NONE                                                             * 00301021
*                                                                     * 00302921
*********************************************************************** 00304821
         EJECT                                                          00306721
*/*IEE20110: CHART */                                                   00308621
*/* E IEE20110 */                                                       00310521
*/* P ESTABLISH ADDRESSABILITY */                                       00312421
*/* S GETMAIN SVC 10:GET WORKAREA SP=255, LENGTH=136 */                 00314321
*/* P PREPARE WORK AREA */                                              00316221
*/*START: D (NO,,YES,UCOM) COMMAND = 'U,' ? */                          00318121
*/* D (NO,,YES,ALLDEFLT) COMMAND = 'UBLANK' ? */                        00320021
*/*ERROR1: P (,ERRWRITE) INDICATE INVALID OPERAND */                    00321900
*/*ALLDEFLT: P INDICATE DISPLAY ALL DEVICE TYPES */                     00331900
*/* P (,SCANSET) INDICATE DISPLAY ALL DEVICE STATUS */                  00341900
*/*UCOM: P POINT TO FIRST OPERAND (DEVICE TYPE) */                      00343900
*/* D (NO,,YES,DEFALL1) IS IT DEFAULTED (=',') */                       00345900
*/* P POINT TO DEVICE TYPE TABLE */                                     00347900
*/* S SCAN RTN:BAL TO FIND DEVICE TYPE */                               00356600
*/* D (NO,,YES,UCOM1) ANY MORE OPERANDS ? */                            00358600
*/* D (NO,ERROR1,YES,) BLANK DELIMITING COMMAND ? */                    00360600
*/* P INDICATE USE THE DEFAULT STATUS */                                00362600
*/* P (,ENDCOMM) SET NUMBER OF DEVICES TO 100 */                        00364600
*/*DEFALL1: P INDICATE ALL DEVICE TYPES TO BE DISPLAYED */              00365000
*/*UCOM1: D (NO,,YES,STATDEF) DEVICE STATUS DEFAULTED ? */              00365100
*/* P POINT TO STATUS TABLE */                                          00365200
*/* S SCAN RTN:GO FIND STATUS WANTED */                                 00373900
*/* D (NO,,YES,UCOM2) ANY MORE OPERANDS */                              00374000
*/* D (NO,ERROR1,YES,) BLANK DELIMIT COMMAND ? */                       00376000
*/* P (,ENDCOMM) SET NUMBER OF DEVICES TO 100 */                        00378000
*/*STATDEF: P INDICATE STATUS DEFAULT TO ALL */                         00380000
*/*UCOM2: D (NO,UCOM2A,YES,) DEVICE ADDRESS DEFAULTED */                00382000
*/* P (,UCOM3) REMEMBER THAT FACT */                                    00382400
*/*UCOM2A: D (NO,ERROR1,YES,) ADDRESS A HEX NUMBER ? */                 00382500
*/* D (NO,,YES,UCOM3) ANY MORE OPERANDS ? */                            00406000
*/* D (NO,ERROR1,YES,) COMMAND TERMINATED BY BLANK */                   00416000
*/* P (,ENDCOMM) SET NUMBER OF DEVICES TO 100 */                        00426000
*/*UCOM3: D (NO,,YES,ERROR1) IS NEXT OPERAND A BLANK */                 00428000
*/* P PREPARE TO CHECK FOR VALID NUMBER */                              00428400
*/* P POINT TO FIRST CHARACTER IN NUMBER */                             00428800
*/*LOOPER: D (NO,CHKBLANK,YES,) IS CHARACTER A NUMBER ? */              00429200
*/* D (NO,CHKBLANK,YES,LOOPER) MORE CHARACTERS TO CHECK ? */            00429300
*/*CHKBLANK: D (NO,ERROR1,YES,) IS CHARACTER A BLANK ? */               00429400
*/* P CONVERT NUMBER TO BINARY */                                       00437200
*/* D (NO,,YES,ERROR1) IS NUMBER = 0 ? */                               00439200
*/* P INDICATE LINE DEFAULT NOT TAKEN */                                00441200
*/*ENDCOMM: D (NO,SCANSET,YES,) REQUEST FOR ONE DEVICE ? */             00443200
*/* P INDICATE THAT FACT */                                             00443600
*/* P SET UP FOR SEVEN UNITS PER LINE */                                00443700
*/*SCANSET: D (NO,,YES,SCANSET0) OFFLINE DISPLAY ? */                   00444000
*/* P SET UP FOR 2 UNITS PER LINE */                                    00444400
*/*SCANSET0: P GET DEVICE ADDRESS FROM COMMAND */                       00444800
*/*SCANSET1: P POINT TO LOOK UP TABLE */                                00444900
*/* S SCAN1 RTN:GO FIND DEVICE IN TABLE */                              00445000
*/* D (NO,,YES,SCANEXIT) DEVICE FOUND ? */                              00445100
*/* D (NO,SCAN3,YES,) SINGLE DEVICE REQUEST */                          00452900
*/* D (NO,,YES,SCAN3) NUMBER DEFAULTED TO 100 */                        00453000
*/* P (,ERRWRIT1) INDICATE ERROR */                                     00455000
*/*SCAN3: P POINT TO UCB ADDRESS TABLE */                               00457000
*/*SCAN3A: P GET A UCB ADDRESS */                                       00459000
*/* D (NO,SCAN3C,YES,SCANEXI2) END OF TABLE ? */                        00459500
*/*SCAN3B: P (,SCAN3A) GO TO NEXT UCB ADDRESS */                        00459800
*/*SCAN3C: S COMPSET:CHANGE ADDRESS TO BINARY */                        00460200
*/* D (NO,SCAN3B,YES,) NEW ADDR OVER LAST ADDR ? */                     00460600
*/* D (NO,,YES,SCAN3E) ANY PREVIOUS LOW ? */                            00460700
*/*SCAN3D: P (,SCAN3B) SET NEW LOW */                                   00460800
*/*SCAN3E: S COMPSET:CHANGE ADDRESSES FOR COMPARE */                    00468600
*/* D (NO,SCAN3B,YES,SCAN3D) NEW ADDR LESS THAN OLD LOW ? */            00468700
*/* E SCAN1 */                                                          00497000
*/*SCAN1: P GET A UCB ADDRESS */                                        00499000
*/* D (NO,SCAN1B,YES,SCAN1C) END OF TABLE ? */                          00499500
*/*SCAN1A: P (,SCAN1) BUMP TO NEXT ADDRESS */                           00499800
*/*SCAN1B: D (NO,SCAN1A,YES,SCAN1D) THIS THE UCB SEARCHED FOR ? */      00499900
*/*SCAN1C: P INDICATE UCB NOT FOUND */                                  00500000
*/*SCAN1D: R BR 14 */                                                   00510000
*/*COMPSET: E COMPSET */                                                00512000
*/*COMPSET1: P PREPARE FOR LOOP */                                      00514000
*/*COMPSET2: D (NO,,YES,COMPSET5) NUMBER 0 TO 9 ? */                    00516000
*/* D (NO,ERROR1,YES,) LETTER A TO F ? */                               00516400
*/* D (NO,,YES,ERROR1) DIGIT GREATER THAN 'F' ? */                      00516800
*/* P ADD NINE (9) TO DIGIT AND SAVE ?*/                                00517200
*/*COMPSET3: P POINT TO NEXT DIGIT */                                   00517600
*/* D (NO,COMPSET2,YES,) LAST DIGIT DONE? */                            00517700
*/* D (NO,COMPSET4,YES,) FIRST TIME THRU ? */                           00517800
*/* D (NO,,YES,SCANEXI4) THIS ADDR OUT OF SYSTEM ? */                   00517900
*/* P INDICATE NOT FIRST TIME THRU */                                   00524700
*/* P (,COMPSET1) POINT TO ADDRESS IN UCB */                            00526700
*/*COMPSET4: P SAVE CONVERTED ADDRESSES */                              00528700
*/* R BR 14 */                                                          00530700
*/*COMPSET5: P (,COMPSET3) GET THE DIGIT */                             00531100
*/* E SCAN */                                                           00531500
*/*SCAN: P GET PARAMETER LENGTH */                                      00531600
*/* D (NO,,YES,ERROR1) END OF TABLE ? */                                00538400
*/* D (NO,,YES,HIT) THIS THE OPERAND ? */                               00538500
*/* P (,SCAN) GO TO NEXT ENTRY IN TABLE */                              00540500
*/*HIT: P GO TO NEXT OPERAND IN COMMAND */                              00542500
*/* R BR 14 */                                                          00544500
*/*SCANEXI2: D (NO,,YES,SCANEXI3) ADDR IN COMMAND HIGHER THAN SYSTEM ?  00544900
*/**/                                                                   00545300
*/*SCANEXI4: P (,ERRWRIT1) INDICATE ERROR MSG TO BE WRITTEN */          00552100
*/*ERRWRITE:  P HOLD 'FROM' CONSOLE ID */                               00552200
*/*ERRWRIT1: P (,XCTL) PREPARE FOR XCTL TO IGC22110 */                  00554200
*/*SCANEXI3: P HOLD UCB POINTER */                                      00565800
*/*SCANEXIT: P SET FIRST ENTRY FLAG FOR UNIT 2 */                       00565900
*/* P SET XCTL TO IGC23110 */                                           00567900
*/* D (NO,,YES,XCTL) MFT SYSTEM ? */                                    00569900
*/* P SET EXIT TO IGC21110 */                                           00571900
*/*XCTL: P SET UP XCTL PARM LIST */                                     00572300
*/* R NEXT LOAD */                                                      00574700
*/*IEE20110: END */                                                     00574900
         EJECT                                                          00579500
         BALR  R10,R0                                                   00579600
         USING *,R10                                                    00586400
         B     ICATCH              BRANCH AROUND PATCH AREA   MC A63123 00588421
         DC    C'   MODULE IGC20110, IEE20110  ' PATCH AREA   MC A63123 00590421
ICATCH   EQU   *                   CONTINUE                   MC A63123 00592421
         LR    R11,R2                                                   00593200
         USING CSCB,R11                                                 00600000
         SPACE 2                                                        00700000
*********************************************************************** 00800000
*                                                                     * 00900000
*     OBTAIN WORKAREA AND INITIALIZE                                  * 01000000
*                                                                     * 01100000
*********************************************************************** 01200000
         LA    R1,SPN              SUBPOOL NUMBER                       01300000
         SLL   R1,HIGH             SET IN HIGH ORDER BYTE               01400000
         LA    R0,WAL              WORKAREA LENGTH                      01500000
         OR    R0,R1               COMBINE IN REG 0                     01600000
         GETMAIN R,LV=(0)          OBTAIN WORKAREA CORE                 01700000
         LR    R12,R1              SAVE CORE POINTER                    01800000
         USING WORKAREA,R12                                             01900000
         XC    WORKAREA(WAL),WORKAREA   ZERO OUT WORKAREA               02000000
         MVI   UNIT1,NUMERIC       SET DEFAULT ADDRESS (UNIT2) AND      02100000
         MVC   UNIT1+ONE(L11),UNIT1     INITIALIZE OTHERS               02200000
         LA    R15,ADCVT           POINT TO CVT ADDRESS                 02300000
         L     R15,ZERO(R15)       GET CVT ADDRESS                      02400000
         USING CVT,R15                                                  02500000
         STM   R13,R14,SWORD      SAVE REGS FOR MFT RETURN              02600000
         MVC   HOLD2+L2(L1),CHUCMP  SAVE ROUTINE FROM ID                02700000
         MVC   HOLD2+L3(L1),CHCNID   SAVE ROUTE TO ID                   02800000
         MVC   IDFLD(L1),CHARID    SAVE CONSOLE AREA ID                 02900000
         MVI   PACKWORD,NUMERIC    SET TO C'0' FOR                      02960000
         MVC   PACKWORD+L1(L3),PACKWORD   PACKING OPERATIONS            03020000
         MVI   TEXT,BLANK          BLANK TEXT AREA                      03100000
         MVC   TEXT+L1(L71),TEXT   PROPAGATE BLANKS                     03200000
         SPACE 2                                                        03300000
*********************************************************************** 03400000
*                                                                     * 03500000
*     OBTAIN COMMAND INPUT FROM CSCB AND CHECK SYNTAX                 * 03600000
*                                                                     * 03700000
*********************************************************************** 03800000
START    EQU   *                                                        03900000
         LA    R3,CHBUF+ONE        ADDRESS OF SECOND CHARACTER. IT IS   04000000
*                                  ASSUMED THAT THE FIRST IS A 'U'      04100000
         CLI   ZERO(R3),COMMA      U,                                   04200000
         BE    UCOM                YES                                  04300000
         CLI   ZERO(R3),BLANK      U BLANK                              04400000
         BE    ALLDEFLT            YES SET ON DEFAULT SWITCHES          04500000
ERROR1   EQU   *                                                        04700000
         MVI   FLAG4,MSG3          INVALID OPERAND                      04800000
         B     ERRWRITE            ISSUE MESSAGE                        04900000
ALLDEFLT EQU   *                                                        05100000
         OI    FLAG1,ALLTYPE       INDICATE DISPLAY ALL TYPES           05200000
         OI    FLAG2,ALLS          INDICATE DISPLAY ANL STATUS          05300000
         MVI   NODEVICS+ONE,NODEVDEF MOVE IN DEFAULT VALUE              05400000
         B     SCANSET             SET UP FOR UCB SCAN                  05500000
UCOM     EQU   *                                                        05600000
         LA    R3,ONE(R3)          BUMP PAST POINTER                    05700000
         CLI   ZERO(R3),COMMA      FIRST VALUE DEFAULTED                05800000
         BE    DEFALL1             YES HANDLE ALL                       05900000
         LA    R2,TYPELIST         POINT TO CORRECT LIST                06000000
         LA    R6,FLAG1            POINT TO CORRECT FLAG BYTE           06100000
         BAL   R14,SCAN            FIND PARAMETER                       06200000
         CLI   ZERO(R3),COMMA      MORE PARAMETERS                      06300000
         BE    UCOM1               YES HANDLE                           06400000
         CLI   ZERO(R3),BLANK      BLANK DELIMIT COMMAND                06500000
         BNE   ERROR1              NO ERROR                             06600000
         OI    FLAG2,ALLS          INDICATE STATUS DEFAULT              06700000
         MVI   NODEVICS+ONE,NODEVDEF SET NUMBER DEFAULT                 06800000
         B     ENDCOMM             CHECK DIDOCS                         06900000
DEFALL1  EQU   *                                                        07000000
         OI    FLAG1,ALLTYPE       INDICATE ALL TYPES TO BE DISPLAYED   07100000
UCOM1    EQU   *                                                        07200000
         LA    R3,ONE(R3)          BUMP PAST COMMA                      07300000
         CLI   ZERO(R3),COMMA      STATUS DEFAULT                       07400000
         BE    STATDEF             YES HANDLE                           07500000
         LA    R2,STATPARM         POINT TO CORRECT LIST                07600000
         LA    R6,FLAG2            POINT TO CORRECT FLAG BYTE           07700000
         BAL   R14,SCAN            FIND OPERAND                         07800000
         CLI   ZERO(R3),COMMA      MORE OF COMMAND                      07900000
         BE    UCOM2               YES HANDLE                           08000000
         CLI   ZERO(R3),BLANK      BLANK DELINEATE COMMAND              08100000
         BNE   ERROR1              NO ERROR                             08200000
         MVI   NODEVICS+ONE,NODEVDEF INDICATE DEFAULT VALUE             08300000
         B     ENDCOMM             CHECK FOR DIDOCS                     08400000
STATDEF  EQU   *                                                        08500000
         OI    FLAG2,ALLS          INDICATE STATUS DEFAULT TO ALL       08600000
UCOM2    EQU   *                                                        08700000
         LA    R3,ONE(R3)          KICK PAST COMMA                      08800000
         CLI   ZERO(R3),COMMA      DEVICE ADDRESS DEFAULTED             08900000
         BNE   UCOM2A              NO, CHECK ADDRESS                    08940000
         OI    FLAG3,DEVDEF        YES, REMEMBER                        08980000
         B     UCOM3               CHECK NEXT OPERAND                   09020000
UCOM2A   EQU   *                                                        09060000
         CLI   ZERO(R3),BLANK      SHOULD BE A HEX NUMBER               09100000
         BE    ERROR1              IS NOT, ERROR CONDITION              09200000
         MVC   UNIT2+ONE(L3),ZERO(R3) MOVE ADDRESS INTO WORK AREA       09300000
         LA    R3,L3(R3)           POINT PAST ADDRESS                   09400000
         CLI   ZERO(R3),COMMA      MORE OPERANDS                        09500000
         BE    UCOM3               YES HANDLE                           09600000
         CLI   ZERO(R3),BLANK      IS COMMAND STOPPED BY A BLANK        09700000
         BNE   ERROR1              NO ERROR MSG                         09800000
         MVI   NODEVICS+1,NODEVDEF      SET NO. DEVICES TO 100          09900000
         B     ENDCOMM             YES END OF COMMAND                   10000000
UCOM3    EQU   *                                                        10100000
         LA    R3,ONE(R3)          BUMP PAST COMMA                      10200000
         CLI   ZERO(R3),BLANK      IS THIS CHARACTER A BLANK            10300000
         BE    ERROR1              YES THIS MUST BE A NUMBER-ERROR MSG  10400000
         LR    R2,R3               SAVE CHAR POINTER IN COMMAND         10500000
         SR    R6,R6               CLEAR REG                            10600000
         LH    R5,THREE            GET BYTE STOP                        10700000
LOOPER   EQU   *                                                        10800000
         TM    ZERO(R2),NUMERIC     IS THIS CHARACTER A NUMBER          10900000
         BNO   CHKBLANK            NO SEE IF BLANK DELIMITS COMMAND     11000000
         LA    R2,ONE(R2)          POINT TO NEXT CHARACTER              11100000
         LA    R6,ONE(R6)          UP COUNT                             11200000
         BCT   R5,LOOPER           CHECK THREE NUMBERS                  11300000
CHKBLANK EQU   *                                                        11400000
         CLI   ZERO(R2),BLANK      BLANK CHARACTER                      11500000
         BNE   ERROR1              NO ERROR MSG                         11600000
*                                  NUMBER IS VALID. THE FOLLOWING CODE  11700000
*                                  CONVERTS IT TO BINARY.               11800000
         LA    R5,ONE(R5)          KICK UP BY ONE                       11900000
         LA    R4,PACKWORD         POINT TO MOVE PLACE                  12000000
         BCTR  R6,R0               DECREMENT LENGTH BY ONE              12100000
         AR    R5,R4               POINT TO CORRECT MOVE POINT          12200000
         EX    R6,MOVE             MOVE NUMBER                          12300000
         PACK  CVBWORD(L4),PACKWORD(L4)   PACK EBCDIC TO HEX            12400000
         XC    PACKWORD(L4),PACKWORD    ZERO OUT FIRST WORD             12500000
         LR    R5,R6               SAVE LENGTH                          12600000
         CVB   R6,PACKWORD         CONVERT TO HEX WITHOUT SIGN          12700000
         LTR   R6,R6               IS NUMBER ZERO                       12800000
         BZ    ERROR1              YES ERROR                            12900000
         OI    FLAG5,NODEF         LINE DEFAULT NOT TAKEN               13000000
         STH   R6,NODEVICS         SAVE IN WORKAREA                     13300000
ENDCOMM  EQU   *                                                        13400000
         CLI   NODEVICS+L1,L1      SINGLE REQUEST                       13500000
         BNE   SCANSET             NO                                   13600000
         OI    FLAG2,SINGLE        YES, INDICATE SINGLE SEARCH          13700000
         SPACE 2                                                        13800000
*********************************************************************** 13900000
*                                                                     * 14000000
*     SET UP FOR SCAN TO PRODUCE DISPLAY LINES                        * 14100000
*                                                                     * 14200000
*********************************************************************** 14300000
SCANSET  EQU   *                                                        14400000
         XC    WORKING(L104),WORKING    ZERO OUT CSCB WORK AREA         14500000
         MVC   FROMID(L1),HOLD2+L2   SAVE FROM ID                       14600000
         XC    HOLD2(L3),HOLD2     ZERO OUT MLWTO NUMBER                14700000
         MVI   DEVNOLN+ONE,LONGLINE    SEVEN UNITS PER LINE             14800000
         TM    FLAG2,OFFLNS        OFFLINE DISPLAY                      14900000
         BO    SCANSET0            YES                                  15000000
         MVI   DEVNOLN+ONE,REGLINE    TWO UNITS PER LINE                15100000
SCANSET0 EQU   *                                                        15200000
         USING UCB,R9                                                   15300000
         MVC   LASTUCB+L1(L3),UNIT2+L1  GET COMMAND DEVICE ADDRESS      15350021
         L     R8,CVTILK2          POINT TO LOOK UP TABLE               15700000
SCAN1    EQU   *                                              MC A55717 15750021
         LH    R9,ZERO(R8)         GET ADDRESS                MC A55717 15760021
         LTR   R9,R9               VALID ADDRESS              MC A55717 15770021
         BP    SCAN1B              YES                        MC A55717 15780021
         BM    SCAN3               END OF TABLE               MC A55717 15790021
SCAN1A   EQU   *                                              MC A55717 15792021
         LA    R8,L2(R8)           BUMP TO NEXT ADDRESS       MC A55717 15794021
         B     SCAN1               LOOK AT IT                 MC A55717 15796021
SCAN1B   EQU   *                                              MC A55717 15798021
         N     R9,FOXAND           CLEAR TOP HALF OF REG      MC A55717 15798421
         LA    R13,UNIT2+ONE       POINT TO DEV ADDR          MC A55717 15798821
         BAL   R14,COMPSET         CONVERT EBCDIC TO HEX      MC A55717 15799221
         STC   R5,UNITADDA         STORE CONVERTED ADDRESS    MC A63123 15799621
         NI    UNITADDA,ZEROFOX    ZERO SUBCHANNEL PORTION    MC A63123 15806321
         MVC   UNITADDB(L1),UCBUA  STORE HEX ADDRESS          MC A63123 15808321
         NI    UNITADDB,ZEROFOX    ZERO SUBCHANNEL PORTION    MC A63123 15810321
         CLC   UNITADDA(L1),UNITADDB    COMP DEVICE ADDRS     MC A63123 15812321
         BNE   SCAN1A              NOT EQUAL, NOT BASE UCB    MC A55717 15813121
         CLC   UNIT2+L1(L3),UCBNAME   RIGHT UCB               MC A55717 15819821
         BE    SCANEXIT            YES                        MC A55717 15826521
         B     SCAN1A              NO, FIND ANOTHER           MC A55717 15833221
**********************************************************************  18870000
*         THIS CODE IS USED AS A SUBROUTINE TO FIND THE NEXT            18880000
*         HIGHEST DEVICE ADDRESS THAT EXISTS IN THE SYSTEM              18890000
*********************************************************************** 18892000
SCAN3    EQU   *                                              MC A55717 18942021
         L     R8,CVTILK2          UCB ADDR LIST                        19000000
         MVC   UNIT2+L1(L3),LASTUCB+L1  MOVE UCB ADDRESS FOR SORT       19050021
SCAN3A   EQU   *                                                        19200000
         LH    R9,ZERO(R8)         GET UCB ADDR                         19300000
         LTR   R9,R9               VALID ADDR                           19400000
         BP    SCAN3C              YES                                  19500000
         BM    SCANEXI2            END OF LIST                          19600000
SCAN3B   EQU   *                                                        19700000
         LA    R8,L2(R8)           BUMP TO NEXT ADDR                    19800000
         B     SCAN3A              TRY NEXT                             19900000
SCAN3C   EQU   *                                                        20000000
         N     R9,FOXAND           CLEAR TOP HALF OF REGISTER           20100000
         LA    R13,UNIT2+ONE       WHICH ADDRESS TO COMPARE             20200000
         BAL   R14,COMPSET         CHANGE ADDRESSES FOR COMPARE         20300000
         STC   R5,UNITADDA         STORE CONVERTED ADDRESS    MC A63123 20350021
         NI    UNITADDA,ZEROFOX    ZERO SUBCHANNEL PORTION    MC A63123 20352021
         MVC   UNITADDB(L1),UCBUA  STORE HEX ADDRESS          MC A63123 20354021
         NI    UNITADDB,ZEROFOX    ZERO SUBCHANNEL PORTION    MC A63123 20356021
         CLC   UNITADDA(L1),UNITADDB    COMP DEVICE ADDRS     MC A63123 20358021
         BNE   SCAN3B              NOT EQUAL, NOT BASE UCB    MC A55717 20360021
         CLR   R4,R5               NEW ADDRESS GREATER                  20400000
         BH    SCAN3B              NO                                   20500000
         CLI   UNIT3,NUMERIC       ANY PREVIOUS LOW                     20600000
         BNE   SCAN3E              YES                                  20700000
         MVI   UNIT3,ZERO          CLEAR FLAG FROM FIRST BYTE           20800000
SCAN3D   EQU   *                                                        20900000
         MVC   UNIT3+ONE(L3),UCBNAME    NEW LOW ABOVE ORIGINAL ADDRESS  21000000
         LR    R0,R9              SHIFT UCB POINTER                     21100000
         B     SCAN3B              GET ANOTHER                          21200000
SCAN3E   EQU   *                                                        21300000
         LA    R13,UNIT3+ONE       WHICH ADDRESS TO COMPARE             21400000
         BAL   R14,COMPSET         CHANGE ADDRESSES FOR COMPARE         21500000
         CLR   R4,R5               NEW ADDR LESS THAN OLD LOW           21600000
         BNH   SCAN3B              NO                                   21700000
         B     SCAN3D              YES, SAVE IT                         21800000
         SPACE 3                                                        22066400
*********************************************************************** 22066700
* THE FOLLOWING CODE CONVERTS EBCDIC REPRESENTATION OF HEX UNIT       * 22100000
* ADDRESSES INTO BINARY NUMBERS THAT CAN BE USED IN A COMPARE LOGICAL * 22200000
* REGISTER STATEMENT FOLLOWED BY A BRANCH HIGH, LOW OR EQUAL.         * 22300000
* ON ENTRY R13 POINTS TO EITHER UNIT1, UNIT2 OR UNIT3. THE CONVERTED  * 22400000
* ADDRESS FROM THIS LOCATION IS PLACED IN R4.                         * 22500000
* THE OTHER ADDRESS ALWAYS COMES FROM THE UCBNAME FIELD OF THE UCB    * 22600000
* POINTED TO BY R9. THIS CONVERTED ADDRESS IS PLACED IN R5.           * 22700000
* THE CONTENTS OF R1 THROUGH R5 ARE DESTROYED.                        * 22800000
* RETURN IS VIA A BR R14.                                             * 22900000
* IF ANY ADDRESS IS FOUND WHICH IS NOT A VALID HEX NUMBER (0-9,A-F),  * 23000000
* AN ERROR CONDITION EXISTS AND CONTROL IS PASSED TO ERROR1.          * 23100000
*********************************************************************** 23200000
COMPSET  EQU   *                                                        23300000
         SR    R3,R3               CLEAR REGISTER                       23400000
COMPSET1 EQU   *                                                        23500000
         SR    R1,R1               CLEAR REGISTER                       23600000
         LA    R1,L3(R1)           BCT LOOP CONTROL                     23700000
         SR    R2,R2               CLEAR WORK REGISTER                  23800000
COMPSET2 EQU   *                                                        23900000
         TM    ZERO(R13),NUMERIC   HEX NUMERAL (0-9)                    24000000
         BO    COMPSET5            YES                                  24100000
         TM    ZERO(R13),CMASK     HEX DIGIT (A-F)                      24200000
         BNO   ERROR1              NEITHER, ERROR CONDITION             24300000
         CLI   ZERO(R13),C6        DIGIT CANNOT BE GREATER THAN HEX F   24400000
         BH    ERROR1              IT IS, THEREFORE ERROR CONDITION     24500000
         IC    R3,ZERO(R13)        OBTAIN DIGIT                         24600000
         LA    R3,L9(R3)           ADD NINE                             24700000
COMPSET3 EQU   *                                                        24800000
         SLL   R3,L28              SHIFT TO                             24900000
         SLDL  R2,L4               LOW ORDER OF R2                      25000000
         SR    R3,R3               CLEAR REG                            25100000
         LA    R13,ONE(R13)        POINT TO NEXT DIGIT                  25200000
         BCT   R1,COMPSET2         CONVERT NEXT DIGIT                   25300000
         TM    FLAG2,R13UCBNM      FIRST PASS                           25400000
         BO    COMPSET4            NO                                   25500000
         CH    R2,HIADDR           THE HIGHEST SYSTEM ADDRESS IS BFF,   25600000
*                                  AS OF RELEASE 19                     25700000
         BH    SCANEXI4            ADDRESS IS HIGHER, ERROR             25800000
         OI    FLAG2,R13UCBNM      TURN ON FLAG                         25900000
         LR    R4,R2               SAVE CONVERTED ADDRESS               26000000
         LA    R13,UCBNAME         POINT TO ADDRESS IN UCB              26100000
         B     COMPSET1                 CONVERT IT                      26200000
COMPSET4 EQU   *                                                        26300000
         LR    R5,R2                    SAVE CONVERTED ADDRESS          26400000
         NI    FLAG2,L255-R13UCBNM      TURN OFF BIT                    26500000
         BR    R14                      RETURN TO CALLER                26600000
COMPSET5 EQU   *                                                        26700000
         IC    R3,ZERO(R13)        OBTAIN DIGIT                         26800000
         B     COMPSET3            ISOLATE NUMBER                       26900000
         SPACE 2                                                        27000000
*********************************************************************** 27100000
*  THE FOLLOWING CODE COMPARES A PARAMETER TO A LIST OF VALID         * 27200000
*  PARAMETERS.  IF NOT FOUND EXIT IS TO LABEL 'ERROR1'.  IF FOUND,    * 27300000
*  THE MASK IN THE TABLE ENTRY IS USED TO SET BIT(S) IN THE           * 27400000
*  APPROPRIATE FLAG FIELD  AND THE PARAMETER POINTER IS UPDATED TO    * 27500000
*  POINT TO THE ADDRESS OF THE CHARACTER FOLLOWING THE PARAMETER.     * 27600000
*                                                                     * 27700000
*  UPON ENTRY REGS MUST BE PRIMED AS FOLLOWS:                         * 27800000
*  R3= POINTER TO PARAM TO BE VALIDITY CHECKED                        * 27900000
*  R2= POINTER TO CORRECT TABLE OF VALID PARAMETERS                   * 28000000
*  R6= POINTER TO FLAG FIELD TO BE OR'ED                              * 28100000
*  R4= RETURN ADDRESS                                                 * 28200000
*  R2 AND R5 ARE DESTROYED, R3 IS UPDATED AS ABOVE                    * 28300000
*********************************************************************** 28400000
SCAN     EQU   *                                                        28500000
         SR    R5,R5               CLEAR REG FOR PARAMETER LENGTH       28600000
         IC    R5,ZERO(R2)         GET PARAMETER LENGTH                 28700000
         LTR   R5,R5               TEST FOR END OF TABLE (LENGTH=0)     28800000
         BZ    ERROR1              END OF TABLE - PARAM NOT VALID       28900000
         EX    R5,COMPR            EXECUTE COMPARE OF PARM              29000000
         BE    HIT                 FOUND GOOD PARAMETER - SET FLAG      29100000
         LA    R5,L3(R5)           GO TO NEXT                           29200000
         AR    R2,R5               ENTRY IN PARAMETER TABLE             29300000
         B     SCAN                LOOP TO TEST NEXT ENTRY              29400000
HIT      EQU   *                                                        29500000
         OC    ZERO(L1,R6),L1(R2)  OR MASK INTO CORRECT FLAGS (R6)      29600000
         LA    R5,L1(R5)           CORRECT LENGTH OF PARAMETER          29700000
         AR    R3,R5               BUMP COMMAND PTR PAST FOUND PARAM    29800000
         BR    R14                 RETURN TO CALLER                     29900000
         SPACE 1                                                        30000021
*********************************************************************** 30100000
*                                                                     * 30200000
*        EXITS TO UNIT2 FOR MVT UNIT4 FOR MFT OR UNIT3 FOR ERROR      * 30300000
*                                                                     * 30400000
*********************************************************************** 30500000
SCANEXI2 EQU   *                                                        30600000
         CLI   UNIT3,NUMERIC       IF UNIT3 HAS NEVER BEEN CHANGED THEN 30700000
         BNE   SCANEXI3            ADDRESS IN COMMAND IS HIGHER THAN    30800000
*                                  HIGHEST SYSTEM ADDRESS.              30900000
SCANEXI4 EQU   *                                                        31000000
         MVI   FLAG4,MSG1         ERROR MESSAGE                         31200000
         B     ERRWRIT1           ID ALREADY IN FROMID                  31250000
ERRWRITE EQU   *                                                        31300000
         MVC   FROMID(L1),HOLD2+L2   STORE FROM CONSOLE ID              31350000
ERRWRIT1 EQU   *                                                        31360000
         MVC   XAX(L8),XCTLNAME   PUT IN NAME FOR XCTL                  31400000
         MVI   XAX+L4,F2          NAME FOR ERROR XCTL                   31500000
         B     XCTL                EXIT TO IEEUNIT3                     31600000
SCANEXI3 EQU   *                                                        31700000
         LR    R9,R0              SHIFT UCB POINTER BACK                31800000
SCANEXIT EQU   *                                                        31900000
         OI    FLAG5,INITUNT2      FIRST ENTRY FOR UNIT2                32000000
         OI    FLAG5,INITENT       TELL IEEUNIT4 ABOUT IEEUNIT1 ENTRY   32100000
         MVC   XAX(L8),XCTLNAME   PUT IN NAME FOR XCTL                  32200000
         TM    CVTDCB,TWENT       TEST FOR MFT                          32300000
         BO    XCTL               BRANCH IF MFT                         32400000
         MVI   XAX+L4,F1          SET UP FOR EXIT TO UNIT2              32500000
         OI    FLAG3,U2           SET FOR EXIT TO UNIT2 AND SCAN ROUTN  32600000
XCTL     EQU   *                                                        32800000
         ST    R12,XAL             SAVE WORKAREA ADDRESS                32900000
         STH   R9,SWORD+L8                                              33000000
         SR    R4,R4               CREATE ZEROS                         33100000
         ST    R4,XAD              NO DCB PTR                           33200000
         LA    R4,XAX              POINTER TO XCTL NAME                 33300000
         ST    R4,XAP              POINTER TO XCTL NAME                 33400000
         LA    R15,XSA             POINT TO PARA LIST                   33450000
         XCTL  SF=(E,(R15))        TRANSFER CONTROL                     33500000
         EJECT                                                          33600000
*********************************************************************** 33700000
*                                                                     * 33800000
*     EQUATES                                                         * 33900000
*                                                                     * 34000000
*********************************************************************** 34100000
R0       EQU   0                   GENERAL REGISTER NOTATION            34200000
R1       EQU   1                   *                       *            34300000
R2       EQU   2                   *                       *            34400000
R3       EQU   3                   *                       *            34500000
R4       EQU   4                   *                       *            34600000
R5       EQU   5                   *                       *            34700000
R6       EQU   6                   *                       *            34800000
R7       EQU   7                   *                       *            34900000
R8       EQU   8                   *                       *            35000000
R9       EQU   9                   *                       *            35100000
R10      EQU   10                  *                       *            35200000
R11      EQU   11                  *                       *            35300000
R12      EQU   12                  *                       *            35400000
R13      EQU   13                  *                       *            35500000
R14      EQU   14                  *                       *            35600000
R15      EQU   15                  *                       *            35700000
*                                  THE FOLLOWING STATEMENTS DEFINE      35900000
*                                  LENGTHS AND NUMBERS USED IN THIS     36000000
*                                  SUPPORT.                             36100000
L1       EQU   1                   *             *         *            36200000
L2       EQU   2                   *             *         *            36300000
L3       EQU   3                   *             *         *            36400000
L4       EQU   4                   *             *         *            36500000
L5       EQU   5                   *             *         *            36600000
L7       EQU   7                   *             *         *            36700000
L8       EQU   8                   *             *         *            36800000
L9       EQU   9                   *             *         *            36900000
L24      EQU   24                  *             *         *     A36165 37000000
L11      EQU   11                  *             *         *            37100000
L12      EQU   12                  *             *         *            37200000
L28      EQU   28                  *             *         *            37300000
L32      EQU   32                  *             *         *            37350000
L71      EQU   71                  *             *         *            37400000
L104     EQU   104                 *             *         *            37600000
L255     EQU   255                 *             *         *            37700000
ZERO     EQU   0                   *             *         *            37800000
ONE      EQU   1                   *             *         *            37900000
ADCVT    EQU   16                  LOCATION OF CVT ADDRESS              38100000
HIGH     EQU   24                  USED FOR REGISTER SHIFTING           38200000
CMASK    EQU   X'C0'               CHARACTER ZONE                       38300000
SPN      EQU   X'FF'               SUBPOOL NUMBER 255                   38400000
TWENT    EQU   X'20'               MFT MASK                             38500000
F1       EQU   C'1'                UNIT STATUS TWO NAME, IGC21110       38600000
F2       EQU   C'2'                UNIT STATUS THREE NAME, IGC22110     38700000
BLANK    EQU   C' '                BLANK DELIMETER                      38800000
COMMA    EQU   C','                FOR SYNTAX CHECK                     38900000
NUMERIC  EQU   C'0'                FIRST EBCDIC NUMERAL                 39000000
REGLINE  EQU   X'02'               TWO UNITS PER LINE                   39200000
LONGLINE EQU   X'07'               SEVEN UNITS PER LINE                 39300000
C6       EQU   C'F'                HIGHEST ADDRESS DIGIT, HEX F         39400000
ZEROFOX  EQU   X'0F'               MASK TO ZERO SUBCHANNEL    MC A63123 39450021
         SPACE 3                                                        39500000
*********************************************************************** 39600000
*                                                                     * 39700000
*     EXECUTED STATEMENTS                                             * 39800000
*                                                                     * 39900000
*********************************************************************** 40000000
         DS    0H                  FORCE HALF WORD BOUNDRY              40100000
MOVE     EQU   *                                                        40200000
         MVC   ZERO(R0,R5),ZERO(R3)  EXECUTED MOVE FOR CVB              40300000
COMPR    EQU   *                                                        40400000
         CLC   ZERO(ZERO,R3),L2(R2)     USED BY SCAN ROUTINE            40500000
         EJECT                                                          40600000
*********************************************************************** 40700000
*                                                                     * 40800000
*     CONSTANTS                                                       * 40900000
*                                                                     * 41000000
*********************************************************************** 41100000
         DS    0F                                                       41200000
FOXAND   DC    XL4'0000FFFF'       USED TO AND REGISTERS                41300000
HIADDR   DC    H'3071'             HIGHEST POSSIBLE ADDRESS, HEX BFF    41400000
THREE    DC    H'3'                LOOP COUNT NUMBER                    41500000
XCTLNAME DC    C'IGC23110'        STANDARD XCTL NAME                    41700000
         SPACE 1                                                        41800000
STATPARM EQU   *                   TABLE OF STATUS OPERANDS             41900000
         DC    AL1(ON2-ON1-ONE)    LENGTH OF ENTRY LESS ONE             42000000
         DC    AL1(ONLINS)         ONLINE DEVICES MASK                  42100000
ON1      EQU   *                                                        42200000
         DC    C'ONLINE'           OPERAND                              42300000
*                                                                       42400000
ON2      EQU   *                                                        42500000
         DC    AL1(OFF2-OFF1-ONE)      LENGTH OF WORD LESS ONE          42600000
         DC    AL1(OFFLNS)         OFFLINE DEVICES MASK                 42700000
OFF1     EQU   *                                                        42800000
         DC    C'OFFLINE'          OPERAND                              42900000
OFF2     EQU   *                                                        43000000
*                                                                       43100000
         DC    AL1(ALL4-ALL3-ONE)   LENGTH OF ENTRY LESS ONE            43200000
         DC    AL1(ALLS)           ALL STATUS MASK                      43300000
ALL3     EQU   *                                                        43400000
         DC    C'ALL'              OPERAND                              43500000
ALL4     EQU   *                                                        43600000
         DC    AL1(0)              END OF TABLE                         43700000
         SPACE 1                                                        43800000
TYPELIST EQU   *                   TABLE OF DEVICE TYPE OPERANDS        43900000
         DC    AL1(ALL2-ALL1-1)    LENGTH OF PARAMETER MINUS ONE        44100000
         DC    AL1(ALLTYPE)        ALLDEVICE TYPES MASK                 44200000
ALL1     EQU   *                                                        44300000
         DC    C'ALL'              PARAMETER                            44400000
ALL2     EQU   *                                                        44500000
*                                                                       44600000
         DC    AL1(TP2-TP1-ONE)    LENGTH OF ENTRY LESS ONE             44700000
         DC    AL1(TPTYPE)         TELEPROCESSING DEVICES MASK          44800000
TP1      EQU   *                                                        44900000
         DC    C'TP'               OPERAND                              45000000
TP2      EQU   *                                                        45100000
*                                                                       45200000
         DC    AL1(GRPH2-GRPH1-ONE)   LENGTH OF ENTRY LESS ONE          45300000
         DC    AL1(GRTYPE)         GRAPHIC DEVICES MASK                 45400000
GRPH1    EQU   *                                                        45500000
         DC    C'GRAPHIC'          OPERAND                              45600000
GRPH2    EQU   *                                                        45700000
*                                                                       45800000
         DC    AL1(DA2-DA1-ONE)    LENGTH OF ENTRY LESS ONE             45900000
         DC    AL1(DATYPE)         DIRECT ACCESS DEVICE TYPE MASK       46000000
DA1      EQU   *                                                        46100000
         DC    C'DASD'             OPERAND                              46200000
DA2      EQU   *                                                        46300000
*                                                                       46400000
         DC    AL1(TA2-TA1-ONE)    LENGTH OF ENTRY LESS ONE             46500000
         DC    AL1(TATYPE)         TAPE DEVICE TYPE MASK                46600000
TA1      EQU   *                                                        46700000
         DC    C'TAPE'             OPERAND                              46800000
TA2      EQU   *                                                        46900000
*                                                                       47000000
         DC    AL1(UR2-UR1-ONE)    LENGTH OF ENTRY LESS ONE             47100000
         DC    AL1(URTYPE)         UNIT RECORD DEVICE TYPE MASK         47200000
UR1      EQU   *                                                        47300000
         DC    C'UR'               OPERAND                              47400000
UR2      EQU   *                                                        47500000
         DC    AL1(0)              END OF TABLE                         47600000
*                                                                       47700000
*                                                                       47800000
         EJECT                                                          47900000
*********************************************************************** 48000000
*                                                                     * 48100000
*     DSECTS                                                          * 48200000
*                                                                     * 48300000
*********************************************************************** 48400000
CSCB     DSECT                                                          48500000
         IEECHAIN                                                       48600000
         ORG   CHAIN+L32                                                48700000
         IEEXSA                                                         48800000
         ORG   XSA+L24                                           A36165 48900000
         DS    0F                                                       49000000
WORKING  DS    5F                  WORKING STORAGE                      49100000
DEVNOLN  EQU   WORKING+L8          NUMBER OF DEVICES PER LINE           49200000
DEVSPRE  EQU   DEVNOLN+L2          NUMBER OF DEVICES DISPLAYED          49300000
LASTUCB  EQU   DEVSPRE+L3          STARTING UCB ADDRESS/BIN NUMBER      49400000
FROMID   EQU   LASTUCB+L4          REQUESTING CONSOLE ID                49500000
SAVE     DS    21F                 SAVE AREA BETWEEN MODULES            49600000
UNITADDA DS    C                   DEVICE ADDRESS FROM EBCDIC MC A63123 49650021
UNITADDB DS    C                   DEVICE ADDRESS FROM HEX    MC A63123 49700021
         ORG   SAVE+L12                                                 50000000
PACKWORD DS    F                   USED BY SYNTAX CHECKER               50100000
CVBWORD  DS    F                   FOR PACKING AND CONVERTING           50200000
         EJECT                                                          50300000
UCB      DSECT                                                          50400000
         IEFUCBOB                                                       50500000
         EJECT                                                          50600000
CVT      DSECT                                                          50700000
         CVT                                                            50800000
         EJECT                                                          50900000
WORKAREA DSECT                                                          51000000
         SPACE 2                                                        51100000
         DS    0D                                                       51200000
UCBADDRA DS    7H                  STORAGE FOR UCB ADDRESSES            51300000
UCBADDRB DS    H                   FOUND BY UNIT4                       51400000
SWORD    DS    3F                  SAVE AREA ACROSS MODULES             51500000
UNIT1    DS    F                   HOLD ADDRESS ONE                     51600000
UNIT2    DS    F                   HOLD ADDRESS TWO                     51700000
UNIT3    DS    F                   HOLD ADDRESS THREE                   51800000
         SPACE 4                                                        51900000
FLAG2    DC    X'00'               COMMUNICATIONS BYTE                  52000000
ONLINS   EQU   128                 DISPLAY ONLINE DEVICES               52100000
OFFLNS   EQU   64                  DISPLAY OFFLINE DEVICES              52200000
ALLS     EQU   32                  DISPLAY OFFLINE + ONLINE DEVICES     52300000
SUFEXIST EQU   16                  REQUESTING CONSOLE IS A CRT DEVICE   52400000
SINGLE   EQU   8                   SINGLE DEVICE REQUEST                52500000
COREGOT  EQU   4                   CORE GOTTEN FOR REGION               52600000
OPEN22   EQU   2                   OPEN FLAG                            52700000
R13UCBNM EQU   1                   FLAG FOR COMPSET ROUTINE             52800000
         SPACE 2                                                        52900000
FLAG3    DC    X'00'               COMMUNICATIONS FLAGS                 53000000
U2       EQU   128                TELL UNIT2 ENTRY FOR SCAN OF CDES     53100000
UNIT3RET EQU   64                  IEE22110 RETURNING TO IEE21110       53200000
OPEN332  EQU   32                  OPEN FLAG                            53300000
DEVDEF   EQU   16                  DEVICE ADDRESS DEFAULTED             53400000
HEADOUTF EQU   8                   HEADING AND LABELS ARE OUT           53500000
OPEN34   EQU   4                   OPEN FLAG                            53600000
OPEN32   EQU   2                   OPEN FLAG                            53700000
OPEN31   EQU   1                   OPEN FLAG                            53800000
         SPACE 2                                                        53900000
*  FLAG4 BYTE IS USED FOR COMMUNICATIONS BETWEEN IEEUNIT3 AND THE       54000000
*  OTHER  D UNIT  MODULES.                                              54100000
FLAG4    DC    X'00'               COMMUNICATIONS BYTE                  54400000
MSG0     EQU   X'00'               ISSUE MESSAGE MSG0A                  54500000
DCELL    EQU   X'04'               PROCESS DATA CELL ENTRY              54600000
PDCELL   EQU   X'08'               COMPLETE DATA CELL ENTRY             54700000
EXITBIT  EQU   X'0C'               RETURN TO CALLER                     54800000
MSG1     EQU   X'10'               ISSUE MESSAGE MSG1A                  54900000
MSG3     EQU   X'14'               ISSUE MESSAGE MSG3A                  55000000
MSG4     EQU   X'18'               ISSUE MESSAGE MSG4A                  55100000
         SPACE 2                                                        55200000
FLAG5    DS    XL1                                                      55300000
NODEF    EQU   X'80'               LINE DEFAULT NOT TAKEN               55400000
INITENT  EQU   X'40'               INITIAL ENTRY TO UNIT STATUS FOUR    55500000
INITUNT2 EQU   X'20'               INITIAL ENTRY TO UNIT STATUS TWO     55600000
CRTMSG2  EQU   X'10'               MSG2 WITH HEADINGS FOR DIDOCS        55700000
UN4BINLT EQU   X'08'               LASTBIN FLAG FOR UNIT4               55800000
DISPBIT  EQU   X'04'               VALID ADDRESS FOUND                  55900000
DISPEND  EQU   X'02'               END OF FRAME AND DISPLAY             56000000
OPEN51   EQU   X'01'               OPEN FLAG                            56060000
         SPACE 2                                                        56120000
         DS    0F                  FORCE FULL WORD FOR WTO              56200000
WTOSET   DS    XL1                 ZERO                                 56300000
TEXTLEN  DS    XL1                 OUTPUT LENGTH                        56400000
LENGTH   EQU   76                  FULL LINE                            56500000
MCSONE   DS    XL1                 MCS FLAGS PART ONE                   56600000
SETONE   EQU   X'E1'                QUEUE BY ID, ROUTINE + DESCRIPTOR   56700000
*                                  CODES EXIST, COMMAND RESPONSE, QUEUE 56800000
*                                  BY ID ONLY.                          56900000
MCSTWO   DS    XL1                 MCS FLAGS PART TWO                   57000000
SETTWO   EQU   X'40'               MLWTO                                57100000
         SPACE 1                                                        57200000
MSGT     DS    0C                  BEGIN TEXT LINE                      57300000
TEXT     DS    XL72                TEXT FIELD                           57400000
         ORG   TEXT                                                     57500000
TITLEID  DS    XL8                 MESSAGE ID                           57700000
TITLEDGH DS    XL3                 HOURS.                               57900000
TITLEDGM DS    XL3                 MINUTES.                             58000000
TITLEDGS DS    XL2                 SECONDS                              58100000
TITLENM  DS    XL11                DISPLAY NAME                         58150000
         ORG   TEXT                                                     58200000
UCBN1    DS    XL5                 UNIT ADDRESS                         58300000
MODL1    DS    XL5                 DEVICE TYPE                          58400000
USTAT1   DS    XL1                 STATUS (O,A,S,C,OFFLINE)             58500000
USTAT2   DS    XL4                 STATUS (-BSY,-MTP,-NRD)              58600000
USTAT3   DS    XL3                 STATUS (-R)                          58700000
VOLID1   DS    XL7                 VOLUME SERIAL NUMBER                 58800000
VOST1A   DS    XL4                 VOLUME STATE (PUB,PRIV,STRG)         58900000
VOST1B   DS    XL6                 VOLUME STATE (-REMOV,-RSDNT,-RSERV)  59000000
         ORG   TEXT+72            ORG FOR WTO TAIL                      59100000
         SPACE 2                                                        59200000
DESCODE  DS    XL2                 DESCRIPTOR CODES                     59300000
RTECODE  DS    XL2                 ROUTING CODES                        59400000
TYPEFLAG DS    XL2                 MESSAGE TYPES                        59500000
AID      DS    XL1                AREA ID FIELD                         59600000
LNUM     DS    XL1                NUMBER OF LINES                       59700000
         SPACE 2                                                        59800000
HOLD2    DS    F                   MLWTO ID/CONSOLE ID FOR WTO          59900000
NODEVICS DS    H                   NUMBER OF UNITS REQUESTED            60000000
NODEVDEF EQU   100                 DEFAULT                              60100000
         SPACE 4                                                        60200000
*  FLAG1 BYTE IS SET BY IEEUNIT1 TO REFLECT THE DEVICE TYPE(S)          60300000
*  REQUESTED BY THE D U  COMMAND.  THE BITS SET CORRESPOND TO THE BIT   60400000
*  SETTINGS IN BYTE 3 OF THE UCBTYP FIELD.                              60500000
         SPACE 2                                                        60600000
FLAG1    DC    X'00'               FLAG1 FIELD                          60700000
TATYPE   EQU   UCB3TAPE           TAPE DEVICES                          60800000
TPTYPE   EQU   UCB3COMM           TELECOMMUNICATIONS DEVICES            60900000
DATYPE   EQU   UCB3DACC           DIRECT ACCESS DEVICES                 61000000
GRTYPE   EQU   UCB3DISP            GRAPHIC DISPLAY DEVICES              61100000
URTYPE   EQU   UCB3UREC+UCB3CHAR        UNIT RECORD + CHAR RDR DEVICES  61200000
ALLTYPE  EQU   TATYPE+TPTYPE+DATYPE+GRTYPE+URTYPE     ALLDEVICE TYPES   61300000
         SPACE 2                                                        61400000
IDFLD    DS    XL1                AREA ID SAVE AREA                     61500000
WEND     EQU   *                   END OF WORK AREA                     61600000
WAL      EQU   WEND-WORKAREA       LENGTH OF WORK AREA                  61700000
         END                                                            61800000
