         TITLE 'IEE22110  UNIT STATUS THREE,  PART OF SVC 110'          00100021
IEE22110 CSECT                                                          00200021
*A5862-5906,389500-390000                                     MC A63123 00201021
*D224000                                                      MG  M2074 00204021
*D028000,169000-171000,366000,367000,368000                   MH A57061 00205021
*A123600,D126400                                              MG A47864 00206021
*C355000                                                      MH A57484 00207021
*        THIS MODULE CREATED FOR RELEASE 21 OF OS/360            S21002 00208021
*********************************************************************** 00209021
*                                                                     * 00210021
* STATUS                                                              * 00211021
*    CHANGE LEVEL=0                                                   * 00212021
*                                                                     * 00213021
* FUNCTION                                                            * 00214021
*    CREATE DISPLAY LINE ENTRIES FOR DATA CELL BINS                   * 00215021
*    ISSUE ERROR MESSAGES                                             * 00216021
*    FREE REGION, IF GOTTEN (MVT ONLY)                                * 00217021
*    FREE WORKAREA                                                    * 00218021
*    RETURN TO FIRST LOAD SVC 110 (IEE00110)                          * 00219021
*                                                                     * 00220021
* ENTRY POINTS                                                        * 00221021
*         IEE22110                                                    * 00222021
*                                                                     * 00223021
* INPUT                                                               * 00224021
*    REG 11 CONTAINS THE CSCB ADDRESS WHICH CONTAINS ALL OTHER PTRS   * 00225021
*                                                                     * 00226021
* OUTPUT                                                              * 00227021
*    DISPLAY LINE ENTRIES FOR DATA CELL BINS                          * 00228021
*    ERROR MESSAGES                                                   * 00229021
*                                                                     * 00230021
* EXTERNAL REFERENCES                                                 * 00231021
*         SVC 35   (WTO)                                              * 00232021
*         SVC 10   (FREEMAIN)                                         * 00233021
*         SVC 9    (DELETE)                                           * 00234021
*                                                                     * 00235021
* EXITS,NORMAL                                                        * 00236021
*         IEE23110 TO ISSUE DISPLAY LINE BUILT                        * 00237021
*         IEE21110 TO COMPLETE DISPLAY LINE                           * 00238021
*         IEE00110 TO RETURN                                          * 00239021
*                                                                     * 00240021
* EXITS,ERROR                                                         * 00241021
*         IEE00110 TO RETURN                                          * 00242021
*                                                                     * 00243021
* TABLES/WORKAREAS                                                    * 00244021
*    CSCB                                                             * 00245021
*    XSA                                                              * 00246021
*    WORKAREA                                                         * 00247021
*    UCB                                                              * 00248021
*                                                                     * 00249021
* ATTRIBUTES                                                          * 00250021
*    TYPE IV SVC, PRIVILEGED, RE-ENTRANT                         A36790 00251021
*                                                                     * 00252021
* CHARACTER CODE DEPENDENCY                                           * 00253021
*    NONE                                                             * 00254021
*                                                                     * 00255021
* NOTES                                                               * 00256021
*    NONE                                                             * 00257021
*                                                                     * 00258021
*********************************************************************** 00259021
         EJECT                                                          00260021
*/*IEE22110: CHART */                                                   00261021
*/* E IEE22110 */                                                       00263021
*/* P SET BASES */                                                      00271021
*/*%RET: P SET RETURN TO UNIT 3 FLAG */                                 00281021
*/*%GETCODE: P GET BRANCH CODE */                                       00291021
*/* D (=0,PUTMSG0,=4,DATCELL,=8,PARTCELL,=12,EXIT,=16,PUTMSG1,=20,      00295421
*/*PUTMSG3,=24,PUTMSG4) BRANCH TABLE */                                 00295821
*/*PARTCELL: P (,NEXTCELA) GET SAVED PARAMETERS */                      00297021
*/*DATCELL: P (,FULLTST) GET PASSED PARMS FROM UNIT2 */                 00299021
*/*BINA: D (YES,,NO,BINA2) BIN ALLOCATED */                             00299421
*/*%ALLOC: P (,BINB) MOVE ALLOC TO LINE */                              00299821
*/*BINA2: P (,BINB) MOVE ONLINE INTO LINE */                            00299921
*/*BINB: D (YES,,NO,BINB2) MOUNT PENDING */                             00300021
*/*%MTP: P (,BINB2) MOVE MTP TO LINE */                                 00350021
*/*BINB2: D (YES,,NO,CELLAB) VOL SER EXIST */                           00360021
*/*%VOLSER: P MOVE VOL SER INTO LINE */                                 00370021
*/*CELLAB: D (YES,,NO,CELLA2) VOLUME PUBLIC */                          00380021
*/*%PUB: P MOVE PUBLIC TO LINE */                                       00390021
*/*CELLB: D (YES,,NO,CELLB2) RESERVED VOLUME */                         00392021
*/*%RESV: P (,FULLTST1) MOVE WORD RESERVED */                           00394021
*/*CELLA2: D (YES,,NO,CELLA3) PRIVATE VOLUME */                         00396021
*/*%PRIV: P (,CELLB) MOVE WORD PRIVATE */                               00398021
*/*CELLA3: D (YES,,NO,CELLB) STORAGE VOLUME */                          00398421
*/*%STRG: P (,CELLB) MOVE WORD STORAGE */                               00398821
*/*CELLB2: D (YES,,NO,CELLB3) PERMRES VOLUME */                         00399221
*/*%PERM: P (,FULLTST1) MOVE WORD PERM RESIDENT */                      00399621
*/*CELLB3: P (,FULLTST1) DEFAULT IS REMOVEABLE */                       00399721
*/*FULLTST: D (YES,EXUN4,NO,) IS LINE FULL */                           00399821
*/*%BIN0: P (,NEXTCELL) SET BIN ZERO */                                 00399921
*/*BINCHECK: P MOVE UCBNAME AND BIN NO. INTO LINE */                    00433221
*/*%BINOFF: D (YES,,NO,BINA) BIN OFFLINE */                             00443221
*/*%OFFLINE: P MOVE WORD OFFLINE */                                     00453221
*/*FULLTST1: P BUMP AND SAVE BIN NUMBER */                              00463221
*/*%A1: D (YES,EXUN4,NO,) LINE FULL */                                  00465221
*/*%LASTBIN: D (YES,UNIT2RET,NO,) LAST BIN DONE */                      00465621
*/*NEXTCELL: P POINT TO SECOND HALF OF LINE */                          00466021
*/*NEXTCELA: P (,BINCHECK) POINT TO FIRST SUB-UCB */                    00466421
*/*PUTMSG0: P (,WTO) SET UP INSUFFICIENT STORAGE MSG */                 00469221
*/*PUTMSG1: P (,WTO) SET UP NO DEV WITH REQ ATTRIBUTES MSG */           00472121
*/*PUTMSG3:  P (,WTO) SET UP INVALID OPERAND MSG */                     00474921
*/*PUTMSG4: P (,WTO) SET UP DEVICE DOES NOT EXIST MSG */                00477721
*/*WTO: S WTO: ISSUE SVC 35 ON ERROR MSG */                             00487721
*/*EXIT: S DELETE:DEVNAMET */                                           00488121
*/*%FREE: S FREEMAIN:WORKAREA */                                        00488521
*/* D (NO,OUT,YES,) WAS REGION GETMAINED ? */                           00496421
*/* S FREEMAIN SVC 10:FREE THE REGION */                                00498421
*/*OUT: R IEE00110 */                                                   00505221
*/*EXUN4: D (YES,,NO,EXUN4A) LAST BIN DONE */                           00513121
*/*%F1: P SET LAST BIN DONE FOR UNIT4 */                                00521021
*/*%F2: P SET OFF PDCELL FLAG */                                        00528921
*/*EXUN4A: P (,XCTL) SET EXIT TO IEE23110 */                            00536821
*/*UNIT2RET: P SET EXIT TO IEE21110 */                                  00544721
*/*XCTL: R TO PROPER LOAD */                                            00552621
*/*IEE23110: END */                                                     00560521
         EJECT                                                          00568421
         BALR  R12,0                                                    00576321
         USING *,R12                                                    00584221
         B     ICATCH              BRANCH AROUND PATCH AREA   MC A63123 00586221
         DC    C'   MODULE IGC22110, FICHE IEE22110  '        MC A63123 00588221
         DC    12C'ZAP'            MAINTENANCE AREA           MC A63123 00590221
ICATCH   EQU   *                   CONTINUE                   MC A63123 00590621
         USING CSCB,R11                                                 00592121
         L     R10,XAL             GET POINTER TO WORKAREA              00600021
         USING WORKAREA,R10        ESTABLISH BASE                       00700021
         OI    FLAG3,UNIT3RET      INDICATE RETURN TO IEEUNIT3          00800021
         SPACE 2                                                        00900021
*********************************************************************** 01000021
*                                                                     * 01100021
*                  TEST REASON FOR ENTRY                                01200021
*                                                                     * 01600021
********************************************************************    01700021
         USING UCB,R7              ESTABLISH UCB BASE                   01800021
         SR    R2,R2                CLEAR REGISTER AND                  01900021
         IC    R2,FLAG4            GET BRANCH CODE                      02000021
         B     *+4(R2)            INDEX INTO BRANCH TABLE               02100021
         B     PUTMSG0             PUT OUT MSG0A AND EXIT               02200021
         B     DATCELL             PROCESS COMPLETE DATA CELL           02300021
         B     PARTCELL            PROCESS PARTIAL DATA CELL            02400021
         B     EXIT                RETURN                               02500021
         B     PUTMSG1             PUT OUT MSG1A AND EXIT               02600021
         B     PUTMSG3             PUT OUT MSG3A AND EXIT               02700021
         SPACE 2                                                        02900021
*********************************************************************** 03000021
*                                                                     * 03100021
* ENTRY IS FROM UNIT4 AT PARTCELL, FIND CORRECT SUB-UCB FOR BIN       * 03200021
* NUMBER PASSED IN 'LASTUCB'.                                         * 03300021
* ENTRY IS FROM UNIT2 AT DATCELL, COMPLETE WHOLE DEVICE ENTRY THEN    * 03400021
* BUILD ENTRIES FOR BINS.                                             * 03500021
*                                                                     * 03600021
*********************************************************************** 03700021
PARTCELL EQU   *                                                        03800021
         L     R7,SAVE+L4          OBTAIN POINTER TO UCB ADDRESS        03900021
         LH    R7,ZERO(R7)         OBTAIN POINTER TO UCB DATA CELL      04000021
         LA    R8,TEXT             WHERE TO START LINE                  04300021
         USING TEXT,R8             ESTABLISH BASE                       04400021
         B     NEXTCELA            SET UP FOR CELL BUILD                04700021
         SPACE 2                                                        04800021
DATCELL  EQU   *                                                        04900021
         L     R7,SAVE+L4          OBTAIN POINTER TO UCB ADDRESS        05000021
         LH    R7,ZERO(R7)         OBTAIN POINTER TO UCB DATA CELL      05100021
         L     R8,SAVE             OBTAIN TEXT LINE BASE                05400021
         B     FULLTST             IS LINE COMPLETE                     05500021
         USING DATACELL,R9                                              05600021
*********************************************************************** 05700021
*                                                                     * 05800021
*     BUILD LINE SEGMENT FOR EACH BIN (ZERO THROUGH NINE)             * 05900021
*                                                                     * 06000021
*********************************************************************** 06100021
BINA     EQU   *                                                        06200021
         TM    DCELSTAT,USALLOC    BIN ALLOCATED                        06300021
         BNO   BINA2               NO                                   06400021
         LA    R1,ALLOC            YES                                  06500021
         B     BINA1               WORD                                 06600021
BINA2    EQU   *                                                        06700021
         LA    R1,ONLINE           MOVE                                 06800021
BINA1    EQU   *                                                        06900021
         MVC   USTAT1(L1),ZERO(R1)      MOVE WORD                       07000021
BINB     EQU   *                                                        07200021
         TM    DCELDMCT,USMOUNT    MOUNT PENDING                        07300021
         BNO   BINB2               NO                                   07400021
         LA    R1,MOUNT            ADDRESS OF WORD                      07500021
BINB1    EQU   *                                                        07600021
         MVC   USTAT2(L4),ZERO(R1)      MOVE WORD                       07700021
BINB2    EQU   *                                                        07800021
*                                  BUSY STATUS AND NOT READY STATUS     07900021
*                                  DO NOT APPLY TO INDIVIDUAL BINS.     08000021
BINC     EQU   *                                                        08100021
*                                  RESERVED UNIT STATUS DOES NOT APPLY  08200021
*                                  TO INDIVIDUAL BINS.                  08300021
CELLA    EQU   *                                                        08400021
         NC    DCELVOLI(L6),DCELVOLI    VOLUME SERIAL EQUAL ZERO        08500021
         BZ    CELLAB              YES   SKIP IT                        08600021
         MVC   VOLID1(L6),DCELVOLI      MOVE SERIAL NUMBER              08700021
CELLAB   EQU   *                                                        08900021
         TM    DCELSTAB,CELLPUB    VOLUME PUBLIC                        09000021
         BNO   CELLA2              NO                                   09100021
         LA    R1,PUB              YES                                  09200021
CELLA1   EQU   *                                                        09300021
         MVC   VOST1A(L4),ZERO(R1)      MOVE WORD                       09400021
CELLB    EQU   *                                                        09500021
         TM    DCELSTAT,CELLRESV   RESERVED VOLUME                      09600021
         BNO   CELLB2              NO                                   09700021
         LA    R1,RESERV           YES                                  09800021
CELLB1   EQU   *                                                        09900021
         MVC   VOST1B(L6),ZERO(R1)      MOVE WORD                       10000021
         B     FULLTST1            CHECK FOR END OF LINE                10100021
CELLA2   EQU   *                                                        10200021
         TM    DCELSTAB,CELLPRIV   PRIVATE VOLUME                       10300021
         BNO   CELLA3              NO                                   10400021
         LA    R1,PRIV             MOVE                                 10500021
         B     CELLA1              WORD                                 10600021
CELLA3   EQU   *                                                        10700021
         TM    DCELSTAB,CELLSTRG   STORAGE VOLUME                       10800021
         BNO   CELLB               NO, LEAVE BLANK                      10900021
         LA    R1,STRG             MOVE                                 11000021
         B     CELLA1              WORD                                 11100021
CELLB2   EQU   *                                                        11300021
         TM    DCELSTAT,CELLPERM   PERMRES VOLUME                       11400021
         BNO   CELLB3              NO                                   11500021
         LA    R1,RESDNT           MOVE                                 11600021
         B     CELLB1              WORD                                 11700021
CELLB3   EQU   *                                                        11800021
         LA    R1,REMOVE           HAS TO BE                            11900021
         B     CELLB1              REMOVABLE                            12000021
*********************************************************************** 12210021
*                                                                     * 12220021
*  DETERMINE IF THERE IS MORE TO DO OR IF A LINE IS FINISHED OR       * 12230021
*  CREATE AN OFFLINE ENTRY                                            * 12240021
*                                                                     * 12250021
*********************************************************************** 12260021
FULLTST  EQU   *                                                        12300021
         DROP  R8                                                       12350021
         MVI   LASTUCB,ZERO        ESTABLISH BIN ZERO         MG A47864 12360021
         LA    R3,TEXT             POINT TO START OF LINE               12400021
         CLR   R8,R3               FULL LINE                            12500021
         BNE   EXUN4               YES, EXIT TO IEE23110                12570021
         B     NEXTCELL            SET UP FOR CELL BUILD                12710021
BINCHECK EQU   *                                                        12800021
         USING TEXT,R8                                                  12850021
         MVC   UCBN1(L3),UCBNAME   MOVE UNIT ADDRESS TO LINE            12900021
         LA    R1,BIN0             FIRST BIN NUMBER                     13000021
         AH    R1,DCELBBNR         ADD REAL NUMBER EQUALS               13100021
         MVC   MODL1+ONE(L1),ZERO(R1)     THE RIGHT PRINTABLE           13200021
         TM    DCELSTAT,USONL      BIN OFFLINE                          13300021
         BO    BINA                NOT OFFLINE, CHECK ALLOCATE          13400021
         MVC   USTAT1(L7),OFFLIN   MOVE WORD                            13500021
FULLTST1 EQU   *                                                        13600021
         DROP  R8                                                       13650021
         LH    R2,DCELBBNR         LOAD PRESENT BIN NUMBER              13700021
         LA    R2,ONE(R2)          BUMP TO NEXT NUMBER                  13800021
         STC   R2,LASTUCB          SAVE BIN NUMBER                      13900021
         LA    R3,TEXT             POINT TO START OF LINE               14000021
         CLR   R8,R3               FULL LINE                            14100021
         BNE   EXUN4               YES, TEST EXIT TO IEEUNIT4           14200021
         LA    R3,L6(R3)           POINT TO BIN NUMBER IN LINE          14300021
         CLI   ZERO(R3),BINLAST    LAST BIN DONE                        14400021
         BE    UNIT2RET            YES                                  14500021
         DROP  R9                                                       14600021
NEXTCELL EQU   *                                                        14700021
         LA    R8,DISP(R8)         POINT TO SECOND HALF OF LINE         14730021
NEXTCELA EQU   *                                                        14760021
         SR    R2,R2               CLEAR REGISTER                       14800021
         IC    R2,LASTUCB          GET BIN NUMBER                       14900021
         LA    R9,DATACELL         FIRST SUBUCB ADDRESS                 15000021
         SLL   R2,L4               BIN NUMBER TIMES LENGTH (L16)        15100021
         AR    R9,R2               POINT TO CORRECT SUBCELL             15200021
         B     BINCHECK            BUILD CELL ENTRY                     15400021
*********************************************************************** 15500021
*                                                                     * 15600021
*     EXIT EFFECTING MODULES                                          * 15700021
*                                                                     * 15800021
*********************************************************************** 15900021
PUTMSG0  EQU   *                                                        16100021
         MVC   TEXT(MSG0LN),MSG0A      PUT TEXT INTO WTO                16200021
         B     WTO                 WRITE LINE                           16300021
PUTMSG1  EQU   *                                                        16400021
         MVC   TEXT(MSG1ALGN),MSG1A     PUT MSG1A INTO WTO LIST         16500021
         B     WTO                 WRITE LINE                           16600021
PUTMSG3  EQU   *                                                        16700021
         MVC   TEXT(MSG3ALGN),MSG3A     PUT MSG3A INTO WTO TEXT         16800021
WTO      EQU   *                                                        17300021
         LA    R1,TEXT+L71         BEGIN SEARCH AT END OF TEXT FIELD    17400021
WTOLOOP  EQU   *         SEARCH BACK FOR LAST TEXT CHARACTER            17600021
         CLI   ZERO(R1),BLANK      Q.   IS THIS CHARACTER A BLANK       17700021
         BNE   HITEXT              NO   FOUND END - FINISH WTO          17800021
         BCT   R1,WTOLOOP          CHECK PREVIOUS ENTRY                 18000021
HITEXT   EQU   *                                                        18300021
         MVC   ONE(L4,R1),DCODE    MOVE WTO TAIL AFTER TEXT             18400021
         LA    R1,L5(R1)           INCREMENT 5 TO COMPUT LENGTH         18500021
         LA    R0,TEXT             POINT TO TEXT BEGINNING              18600021
         SR    R1,R0               COMPUTE WTO LENGTH                   18700021
         STH   R1,WTOSET           STORE LENGTH IN LIST                 18800021
         MVI   MCSONE,SETONE       SET MCS FLAG FIELD                   18900021
         MVI   MCSTWO,ZERO         ZERO OUT SECOND MCS BYTE             18950021
         SR    R0,R0               CLEAR REG FOR UCM ENTRY ID           19000021
         IC    R0,FROMID           PUT IN REQUESTOR'S ID                19100021
         LA    R1,WTOSET           POINT TO WTO LIST IN WORKAREA        19200021
         WTO   MF=(E,(1))          EXECUTE WTO LIST                     19300021
EXIT     EQU   *                                                        19500021
         DELETE EP=DEVNAMET        REMOVE SUPPORT FROM DNT USE COUNT    19600021
         LA    R1,SPN              WORK AREA SUBPOOL                    19800021
         SLL   R1,HIGH             SHIFT TO HIGH ORDER                  19900021
         LA    R0,WAL              LENGTH                               20000021
         OR    R0,R1               COMBINE IN REGISTER ZERO             20100021
         LR    R1,R10              CORE POINTER                         20200021
         FREEMAIN   R,LV=(0),A=(1)     FREE WORKAREA CORE               20300021
         TM    FLAG2,COREGOT       WAS GETMAIN DONE FOR REGION          20400021
         BNO   OUT                 NO, DON'T FREEMAIN                   20500021
         LA    R1,SP              GET SUBPOOL NUMBER                    20700021
         SLL   R1,HIGH            SHIFT TO HIGH ORDER                   20800021
         LH    R0,H4000            REGION SIZE - 4K                     20900021
         OR    R0,R1              PUT TOGETHER IN REG 0                 21100021
         LA    R1,L4               SET REGISTER                         21200021
         FREEMAIN R,LV=(0),A=(1)       FREE UP                          21300021
OUT      EQU   *                                                        21400021
         LR    R2,R11             SHIFT CSCB POINTER                    21500021
         LM    R13,R14,SWORD1     RESTORE REGS                          21600021
         MVC   XAX(L8),RETRNAME    GO BACK TO IGC00110                  21700021
         B     XCTL               GO TO XCTL                            21800021
EXUN4    EQU   *                                                        21900021
         LA    R3,L42(R3)          POINT TO BIN NUMBER IN LINE          22000021
         CLI   ZERO(R3),BINLAST    LAST BIN                             22100021
         BNE   EXUN4A              NO   LEAVE RETURN BIT ON             22200021
         OI    FLAG5,UN4BINLT      TELL UNIT4 ABOUT SUFFIX WITH BIN 9   22300021
         NI    FLAG3,L255-UNIT3RET      YES  TURN OFF RETURN BIT        22500021
         MVI   FLAG4,ZERO          TURN OFF PDCELL FLAG                 22600021
EXUN4A   EQU   *                                                        22700021
         MVI   XAX+4,X'F3'        MOVE INTO NAME FOR XCTL TO UNIT4      22800021
         B     XCTL                GO TO EXIT                           22900021
UNIT2RET EQU   *                                                        23000021
         MVI   FLAG4,ZERO          ALL DONE, CLEAR FLAGS                23100021
         LA    R2,TEXT             POINT TO BEGINNING OF LINE           23200021
         MVI   XAX+4,X'F1'        MOVE INTO NAME FOR XCTL TO UNIT2      23300021
         ST    R2,SAVE             SAVE FOR UNIT2                       23400021
XCTL     EQU   *                                                        23500021
         LA    R15,XSA             POINT TO PARA LIST                   23550021
         XCTL  SF=(E,(R15))        TRANSFER CONTROL                     23600021
         EJECT                                                          23700021
*********************************************************************** 23800021
*                                                                     * 23900021
*        EQUATE STATEMENTS                                            * 24000021
*                                                                     * 24100021
*********************************************************************** 24200021
R0       EQU   0                   GENERAL REGISTER NOTATION            24300021
R1       EQU   1                   *                       *            24400021
R2       EQU   2                   *                       *            24500021
R3       EQU   3                   *                       *            24600021
R4       EQU   4                   *                       *            24700021
R5       EQU   5                   *                       *            24800021
R6       EQU   6                   *                       *            24900021
R7       EQU   7                   *                       *            25000021
R8       EQU   8                   *                       *            25100021
R9       EQU   9                   *                       *            25200021
R10      EQU   10                  *                       *            25300021
R11      EQU   11                  *                       *            25400021
R12      EQU   12                  *                       *            25500021
R13      EQU   13                  *                       *            25600021
R14      EQU   14                  *                       *            25700021
R15      EQU   15                  *                       *            25800021
         SPACE 2                                                        25850021
L0       EQU   0                   THESE ARE LENGTHS AND DISPLACEMENTS  26000021
L1       EQU   1                   USED BY THIS MODULE               *  26100021
L2       EQU   2                   *                                 *  26200021
L3       EQU   3                   *                                 *  26300021
L4       EQU   4                   *                                 *  26400021
L5       EQU   5                   *                                 *  26500021
L6       EQU   6                   *                                 *  26600021
L7       EQU   7                   *                                 *  26700021
L8       EQU   8                   *                                 *  26800021
L9       EQU   9                   *                                 *  26900021
L10      EQU   10                  *                                 *  27000021
L11      EQU   11                  *                                 *  27100021
L12      EQU   12                  *                                 *  27200021
L13      EQU   13                  *                                 *  27300021
L14      EQU   14                  *                                 *  27400021
L15      EQU   15                  *                                 *  27500021
L16      EQU   16                  *                                 *  27600021
L24      EQU   24                  *                             A36165 27700021
L32      EQU   32                  *                                 *  27750021
L42      EQU   42                  *                                 *  27900021
L71      EQU   71                  *                                 *  28000021
SP       EQU   247                 SUBPOOL NUMBER FOR FREEMAIN          28100021
L255     EQU   255                 LENGTH OF 255                        28200021
ZERO     EQU   0                   *                                 *  28500021
ONE      EQU   1                   *                                 *  28600021
HIGH     EQU   24                  USED FOR SHIFTING IN REGISTERS       28900021
DISP     EQU   36                  TEXT+DISP=SECOND HALF OF LINE        29000021
SPN      EQU   255                 WORKAREA SUBPOOL                     29200021
USMOUNT  EQU   X'80'               MOUNT PENDING MASK                   29600021
USONL    EQU   X'80'               ONLINE STATUS MASK                   29700021
USALLOC  EQU   X'08'               ALLOCATED DEVICE MASK                29900021
CELLSTRG EQU   X'04'               STORAGE CELL MASK                    30000021
CELLPUB  EQU   X'08'               PUBLIC CELL MASK                     30100021
CELLPERM EQU   X'04'               PERMANENT CELL MASK                  30200021
CELLPRIV EQU   X'10'               PRIVATE CELL MASK                    30300021
CELLRESV EQU   X'20'               RESERVED CELL MASK                   30400021
BLANK    EQU   C' '                USED TO BLANK WORKAREAS              30900021
F0       EQU   C'0'                USED TO CLEAR EBCDIC ZONES           31000021
BINLAST  EQU   C'9'                LAST BIN NUMBER                      31100021
         EJECT                                                          31500021
*********************************************************************** 31600021
*                                                                     * 31700021
*     CONSTANTS                                                       * 31800021
*                                                                     * 31900021
*********************************************************************** 32000021
H4000    DC    H'4096'             REGION SIZE - 4K                     32100021
PUB      DC    C' PUB'             PUBLIC CELL                          32200021
PRIV     DC    C'PRIV'             PRIVATE CELL                         32300021
STRG     DC    C'STRG'             STORAGE CELL                         32400021
REMOVE   DC    C'/REMOV'           REMOVEABLE CELL                      32500021
RESDNT   DC    C'/RSDNT'           RESIDENT CELL                        32600021
RESERV   DC    C'/RSERV'           RESERVED CELL                        32700021
ONLINE   DC    C'O'                ONLINE DEVICE                        33100021
OFFLIN   DC    C'OFFLINE'          OFFLINE DEVICE                       33200021
ALLOC    DC    C'A'                ALLOCATED DEVICE                     33300021
MOUNT    DC    C'-MTP'             MOUNT REQUEST OUTSTANDING            33600021
*                                  THE FOLLOWING BIN NUMBERS ARE A      33630021
*                                  TABLE. DO NOT DISTURB THE ORDER.     33660021
BIN0     DC    C'0'                BIN NUMBER ZERO                      33700021
B1       DC    C'1'                BIN NUMBER ONE                       33800021
B2       DC    C'2'                BIN NUMBER TWO                       33900021
B3       DC    C'3'                BIN NUMBER THREE                     34000021
B4       DC    C'4'                BIN NUMBER FOUR                      34100021
B5       DC    C'5'                BIN NUMBER FIVE                      34200021
B6       DC    C'6'                BIN NUMBER SIX                       34300021
B7       DC    C'7'                BIN NUMBER SEVEN                     34400021
B8       DC    C'8'                BIN NUMBER EIGHT                     34500021
B9       DC    C'9'                BIN NUMBER NINE                      34600021
DCODE    DC    XL4'01000000'       DESCRIPTOR CODE 5                    34700021
RETRNAME DC    C'IGC00110'         FIRST LOAD SVC 110                   34800021
         EJECT                                                          34900021
*********************************************************************** 35000021
*                                                                     * 35100021
*     MESSAGES                                                        * 35200021
*                                                                     * 35300021
*********************************************************************** 35400021
MSG0A    DC    C'IEE931I INSUFFICIENT STORAGE FOR D U'        MH A57484 35500021
MSG0ND   EQU   *                                                        35600021
MSG0LN   EQU   MSG0ND-MSG0A       MESSAGE LENGTH                        35700021
MSG1A    DC    C'IEE455I UNIT STATUS NO DEVICES WITH REQUESTED ATTRIBUTX35800021
               ES'                ERROR MESSAGE 1                       35900021
MSG1AEND EQU   *                   END OF MSG1A                         36000021
MSG1ALGN EQU   MSG1AEND-MSG1A      LENGTH OF MSG1A                      36100021
MSG3A    DC    C'IEE453I UNIT STATUS INVALID OPERAND RE-ENTER'    ERROR 36300021
MSG3AEND EQU   *                   END OF MSG3A                         36400021
MSG3ALGN EQU   MSG3AEND-MSG3A      LENGTH OF MSG3A                      36500021
         EJECT                                                          36900021
*********************************************************************** 37000021
*                                                                     * 37100021
*     DSECTS                                                          * 37200021
*                                                                     * 37300021
*********************************************************************** 37400021
CSCB     DSECT                                                          37800021
         IEECHAIN                                                       37900021
CSCBL    EQU   CHLAST-CHAIN        LENGTH OF CSCB                       38000021
         ORG   CHAIN+L32                                                38100021
         IEEXSA                                                         38200021
         ORG   XSA+L24                                           A36165 38300021
WORKING  DS    5F                  WORKING STORAGE                      38400021
DEVNOLN  EQU   WORKING+L8          NUMBER OF DEVICES PER LINE           38500021
DEVSPRE  EQU   DEVNOLN+L2          NUMBER OF DEVICES DISPLAYED          38600021
LASTUCB  EQU   DEVSPRE+L3          STARTING UCB ADDRESS/BIN NUMBER      38700021
FROMID   EQU   LASTUCB+L4          REQUESTING CONSOLE ID                38800021
SAVE     DS    21F                 SAVE AREA BETWEEN MODULES            38900021
UNITADDA DS    C                   DEVICE ADDRESS FROM EBCDIC MC A63123 38950021
UNITADDB DS    C                   DEVICE ADDRESS FROM HEX    MC A63123 39000021
         ORG   SAVE+L12                                                 39400021
PACKWORD DS    F                   WORD USED FOR PACKING                39500021
CVBWORD  DS    F                   WORD USED FOR CONVERSION TO BINARY   39600021
         EJECT                                                          39700021
UCB      DSECT                                                          39800021
         IEFUCBOB                                                       39900021
         EJECT                                                          40000021
         EJECT                                                          41000021
         SPACE 2                                                        41100021
WORKAREA DSECT                                                          41200021
         SPACE 2                                                        41300021
         DS    0D                                                       41400021
UCBADDRA DS    7H                  STORAGE FOR UCB ADDRESSES            41500021
UCBADDRB DS    H                   FOUND BY UNIT4                       41600021
SWORD    DS    0F                  SAVE AREA ACROSS MODULES             41700021
SWORD1   DS    F                   SAVE AREA POINTER (R13)              41800021
SWORD2   DS    F                   RETURN ADDRESS (R14)                 41900021
SWORD3   DS    F                   DEVICE NAME TABLE ADDRESS            42000021
UNIT1    DS    F                   HOLD ADDRESS ONE                     42100021
UNIT2    DS    F                   HOLD ADDRESS TWO                     42200021
UNIT3    DS    F                   HOLD ADDRESS THREE                   42300021
         SPACE 4                                                        42400021
FLAG2    DC    X'00'               COMMUNICATIONS BYTE                  42500021
ONLINS   EQU   128                 DISPLAY ONLINE DEVICES               42600021
OFFLNS   EQU   64                  DISPLAY OFFLINE DEVICES              42700021
ALLS     EQU   32                  DISPLAY OFFLINE + ONLINE DEVICES     42800021
SUFEXIST EQU   16                  REQUESTING CONSOLE IS A CRT DEVICE   42900021
SINGLE   EQU   8                   SINGLE DEVICE REQUEST                43000021
COREGOT  EQU   4                   CORE GOTTEN FOR DEVICE NAME TABLE    43100021
OPEN22   EQU   2                   OPEN FLAG                            43200021
R13UCBNM EQU   1                   FLAG FOR COMPSET ROUTINE             43300021
         SPACE 2                                                        43400021
FLAG3    DC    X'00'               COMMUNICATIONS FLAGS                 43500021
U2       EQU   128                TELL UNIT2 ENTRY FOR SCAN OF CDES     43600021
UNIT3RET EQU   64                  IEE22110 RETURNING TO IEE21110       43700021
OPEN332  EQU   32                  OPEN FLAG                            43800021
DEVDEF   EQU   16                  DEVICE ADDRESS DEFAULTED             43900021
HEADOUTF EQU   8                   HEADING AND LABELS ARE OUT           44000021
OPEN34   EQU   4                   OPEN FLAG                            44100021
OPEN32   EQU   2                   OPEN FLAG                            44200021
OPEN31   EQU   1                   OPEN FLAG                            44300021
         SPACE 2                                                        44400021
*  FLAG4 BYTE IS USED FOR COMMUNICATIONS BETWEEN IEEUNIT3 AND THE       44500021
*  OTHER  D UNIT  MODULES.                                              44600021
FLAG4    DC    X'00'               COMMUNICATIONS BYTE                  44900021
MSG0     EQU   X'00'               ISSUE MESSAGE MSG0A                  45000021
DCELL    EQU   X'04'               PROCESS DATA CELL ENTRY              45100021
PDCELL   EQU   X'08'               COMPLETE DATA CELL ENTRY             45200021
EXITBIT  EQU   X'0C'               RETURN TO CALLER                     45300021
MSG1     EQU   X'10'               ISSUE MESSAGE MSG1A                  45400021
MSG3     EQU   X'14'               ISSUE MESSAGE MSG3A                  45500021
MSG4     EQU   X'18'               ISSUE MESSAGE MSG4A                  45600021
         SPACE 2                                                        45700021
FLAG5    DS    XL1                                                      45800021
NODEF    EQU   X'80'               LINE DEFAULT NOT TAKEN               45900021
INITENT  EQU   X'40'               INITIAL ENTRY TO UNIT STATUS FOUR    46000021
INITUNT2 EQU   X'20'               INITIAL ENTRY TO UNIT STATUS TWO     46100021
CRTMSG2  EQU   X'10'               MSG2 WITH HEADINGS FOR DIDOCS        46200021
UN4BINLT EQU   X'08'               LASTBIN FLAG FOR UNIT4               46300021
DISPBIT  EQU   X'04'               VALID ADDRESS FOUND                  46400021
DISPEND  EQU   X'02'               END OF FRAME AND DISPLAY             46500021
OPEN51   EQU   X'01'               OPEN FLAG                            46600021
         DS    0F                  FORCE FULL WORD FOR WTO              46700021
WTOSET   DS    XL1                 ZERO                                 46800021
TEXTLEN  DS    XL1                 OUTPUT LENGTH                        46900021
LENGTH   EQU   76                  FULL LINE                            47000021
MCSONE   DS    XL1                 MCS FLAGS PART ONE                   47100021
SETONE   EQU   X'E1'                QUEUE BY ID, ROUTINE + DESCRIPTOR   47200021
*                                  CODES EXIST, COMMAND RESPONSE, QUEUE 47300021
*                                  BY ID ONLY.                          47400021
MCSTWO   DS    XL1                 MCS FLAGS PART TWO                   47500021
SETTWO   EQU   X'40'               MLWTO                                47600021
         SPACE 1                                                        47700021
MSGT     DS    0C                  BEGIN TEXT LINE                      47800021
TEXT     DS    XL72                TEXT FIELD                           47900021
         ORG   TEXT                                                     48000021
TITLEID  DS    XL8                 MESSAGE ID                           48200021
TITLEDGH DS    XL3                 HOURS.                               48400021
TITLEDGM DS    XL3                 MINUTES.                             48500021
TITLEDGS DS    XL2                 SECONDS                              48600021
TITLENM  DS    XL11                DISPLAY NAME                         48650021
         ORG   TEXT                                                     48700021
UCBN1    DS    XL5                 UNIT ADDRESS                         48800021
MODL1    DS    XL5                 DEVICE TYPE                          48900021
USTAT1   DS    XL1                 STATUS (O,A,S,C,OFFLINE)             49000021
USTAT2   DS    XL4                 STATUS (-BSY,-MTP,-NRD)              49100021
USTAT3   DS    XL3                 STATUS (-R)                          49200021
VOLID1   DS    XL7                 VOLUME SERIAL NUMBER                 49300021
VOST1A   DS    XL4                 VOLUME STATE (PUB,PRIV,STRG)         49400021
VOST1B   DS    XL6                 VOLUME STATE (-REMOV,-RSDNT,-RSERV)  49500021
         ORG   TEXT+72            ORG FOR WTO TAIL                      49600021
         SPACE 2                                                        49700021
DESCODE  DS    XL2                 DESCRIPTOR CODES                     49800021
RTECODE  DS    XL2                 ROUTING CODES                        49900021
TYPEFLAG DS    XL2                 MESSAGE TYPES                        50000021
AID      DS    XL1                AREA ID FIELD                         50100021
LNUM     DS    XL1                NUMBER OF LINES                       50200021
         SPACE 2                                                        50300021
HOLD2    DS    F                                                        50400021
NODEVICS DS    H                   NUMBER OF UNITS REQUESTED            50500021
NODEVDEF EQU   100                 DEFAULT                              50600021
         SPACE 4                                                        50700021
*  FLAG1 BYTE IS SET BY IEEUNIT1 TO REFLECT THE DEVICE TYPE(S)          50800021
*  REQUESTED BY THE D U  COMMAND.  THE BITS SET CORRESPOND TO THE BIT   50900021
*  SETTINGS IN BYTE 3 OF THE UCBTYP FIELD.                              51000021
         SPACE 2                                                        51100021
FLAG1    DC    X'00'               FLAG1 FIELD                          51200021
TATYPE   EQU   UCB3TAPE           TAPE DEVICES                          51300021
TPTYPE   EQU   UCB3COMM           TELECOMMUNICATIONS DEVICES            51400021
DATYPE   EQU   UCB3DACC           DIRECT ACCESS DEVICES                 51500021
GRTYPE   EQU   UCB3DISP            GRAPHIC DISPLAY DEVICES              51600021
URTYPE   EQU   UCB3UREC+UCB3CHAR        UNIT RECORD + CHAR RDR DEVICES  51700021
ALLTYPE  EQU   TATYPE+TPTYPE+DATYPE+GRTYPE+URTYPE     ALLDEVICE TYPES   51800021
         SPACE 2                                                        51900021
IDFLD    DS    XL1                AREA ID SAVE AREA                     52000021
WEND     EQU   *                   END OF WORK AREA                     52100021
WAL      EQU   WEND-WORKAREA       LENGTH OF WORK AREA                  52200021
      END                                                               52300021
