         TITLE 'IEE23110  UNIT STATUS FOUR, PART OF SVC 110'            00100021
IEE23110 CSECT                                                          00200021
*C5790                                                        MC A63123 00201821
*D5794,69500,262700-262800                                    MC A63123 00203821
*A332500,69500-69580,385500-386000                            MC A63123 00205821
*D44000-45000                                                 MC A55717 00207721
*A69500-69600,262500-262800                                   MC A55717 00209521
*D78500-78600                                                 MC A55356 00211321
*A78700-78800,212500-212600,214500                            MC A55356 00213121
*C036000,043000                                               MH A57061 00214921
*D049000-052000                                               MH A57061 00216721
*D107000                                                      MH A52720 00218521
*D041000-043000                                               MH A52720 00220321
*A005690,005790,005794,041000-042500                          MH A52720 00222121
*C003199,003606,006000,040500                                 MH A52720 00223921
*A078500-078600,D085000-086000,D108000-109000                 MG  M2075 00225721
*C207000                                                      MG  M2074 00227521
*        THIS MODULE CREATED FOR RELEASE 21 OF OS/360            S21002 00229321
*********************************************************************** 00231121
*                                                                     * 00232921
* STATUS                                                              * 00234721
*    CHANGE LEVEL=0                                                   * 00236521
*                                                                     * 00238321
* FUNCTION                                                            * 00240121
*    FIND VALID UCB'S TO SCAN                                         * 00241921
*    WRITE COMPLETED DISPLAY LINES                                    * 00243721
*                                                                     * 00245521
* ENTRY POINTS                                                        * 00247321
*         IEE23110                                                    * 00249121
*                                                                     * 00250921
* INPUT                                                               * 00252721
*    REG 11 CONTAINS THE CSCB ADDRESS WHICH CONTAINS ALL OTHER PTRS   * 00254521
*    REG 9  CONTAINS THE UCB ADDRESS FOUND BY IEE20110                X 00256321
*                                                                     * 00258121
* OUTPUT                                                              * 00259921
*    DISPLAY LINES ISSUED TO CONSOLE SUPPORT                          * 00261721
*                                                                     * 00263521
* EXTERNAL REFERENCES                                                 * 00265321
*         SVC 11   (TIME)                                               00267121
*         SVC 35   (WTO)                                              * 00268921
*                                                                     * 00270721
* EXITS,NORMAL                                                        * 00272521
*         IEE21110 TO BUILD DEVICE ENTRIES IN DISPLAY LINE            * 00274321
*         IEE22110 TO BUILD DATA CELL BIN ENTRIES IN DISPLAY LINE     * 00276121
*         IEE22110 TO RETURN WHEN DISPLAY COMPLETE                    * 00277921
*                                                                     * 00279721
* EXITS,ERROR                                                         * 00281521
*         IEE22110 TO ISSUE ERROR MESSAGES                            * 00283321
*                                                                     * 00285121
* TABLES/WORKAREAS                                                    * 00286921
*    CSCB                                                             * 00288721
*    XSA                                                              * 00290521
*    UCB                                                              * 00292321
*    WORKAREA                                                         * 00294121
*    CVT                                                              * 00295921
*                                                                     * 00297721
* ATTRIBUTES                                                          * 00299521
*    TYPE IV SVC, PRIVILEGED, RE-ENTRANT                         A36790 00301321
*                                                                     * 00303121
* CHARACTER CODE DEPENDENCY                                           * 00304921
*    NONE                                                             * 00306721
*                                                                     * 00308521
* NOTES                                                               * 00310321
*    NONE                                                             * 00312121
*                                                                     * 00313921
*********************************************************************** 00315721
         EJECT                                                          00317521
*/*IEE23110: CHART */                                                   00319321
*/*IEE23110: E IEE23110 */                                              00321121
*/* P ESTABLISH ADDRESSABILITY */                                       00322921
*/* D (NO,,YES,WTORTN) PUT OUT DATA CELL WTO ? */                       00324721
*/* D (NO,WTORTN,YES,) INITIAL ENTRY ? */                               00326521
*/* P TURN OFF INITIAL ENTRY FLAG */                                    00328321
*/* P CLEAR ADDRESS TABLE */                                            00330121
*/*NEWLINE: P POINT TO EBCDIC ADDRESS */                                00331921
*/* S COMPSET:GO CONVERT ADDRESS */                                     00341921
*/* P POINT TO UCB ADDRESS TABLE */                                     00343921
*/*DUMBHI: P DUMMY UP HIGH VALUE */                                     00345921
*/*VALIDCHK: D (NO,GETNEXT,YES,) CORRECT UCB TYPE ? */                  00347921
*/* D (NO,,YES,STORADDR) ALL STATUS WANTED ? */                         00356621
*/* D (NO,,YES,ONLINE) ONLINE REQUEST ? */                              00358621
*/* D (NO,STORADDR,YES,GETNEXT) IS DEVICE ONLINE OR ALLOC ? */   A52720 00360621
*/*ONLINE: D (NO,,YES,STORADDR) IS DEVICE ONLINE ? */                   00362621
*/*GETNEXT: D (NO,BUMP,YES,EXMSG1) SINGLE DEVICE REQUEST ? */           00364621
*/*STORADDR: P INDICATE UCB FOUND */                                    00365021
*/* P HOLD POINTER TO CURRENT HIGH UCB */                               00365121
*/* P (,BUMP) HOLD CONVERTED ADDRESS */                                 00365221
*/*LOOP: P GET UCB ADDR FROM LOOK UP TABLE */                           00365321
*/* D (NO,UCB,YES,EOL) END OF TABLE ? */                                00367321
*/*BUMP: P (,LOOP) POINT TO NEXT UCB ADDRESS */                         00369321
*/*UCB: P LOCATE EBCDIC ADDR VALUE */                                   00371321
*/* S COMPSET:GO CONVERT ADDR */                                        00373321
*/* D (NO,,YES,BUMP) NEW LOWER THAN OLD LOW ? */                        00373721
*/* D (NO,VALIDCHK,YES,BUMP) HIGHER THAN OLD HIGH ? */                  00373821
*/*EOL: D (NO,NOADDR,YES,) ANY NEW HIGH STORED? */                      00373921
*/* P PUT HIGH VALUE INTO LOW */                                        00374021
*/* P RESET UCB FOUND BIT */                                            00376021
*/* D (NO,,YES,ENDSCN) NUM UCBS FOUND = NUM WANTED */                   00378021
*/*GETONE: P POINT TO UCB LOOK UP TABLE */                              00380021
*/* D (NO,LOOP,YES,) ENOUGH TO FILL ONE LINE ? */                       00382021
*/*EXIT: P SET EXIT TO IGC22110 */                                      00382421
*/* D (NO,XCTL,YES,) FINISH DATA CELL ? */                              00382521
*/* P (,EXUN3) POINT TO FIRST UCB ADDRESS */                            00406021
*/*NOADDR: D (NO,EXMSG1,YES,) ANY DISPLAY OUTPUT ? */                   00416021
*/* D (NO,SETND,YES,) LINE DEFAULT NOT TAKEN ? */                       00426021
*/* P (,SETND) TELL UNIT 3 TO PUT OUT MESSAGE */                        00428021
*/*ENDSCN: D (NO,,YES,EXIT) ENOUGH UNITS TO FILL LINE ? */              00428121
*/*SETND: P (,EXIT) TURN ON DISPLAY ENDED FLAG */                       00428221
*/*COMPSET: E COMPSET */                                                00428621
*/* P PREPARE TO LOOP THRU NUMBER */                                    00429021
*/*COMPSET2: D (NO,,YES,COMPSET5) IS THIS DIGIT NUMERIC ? */            00429421
*/* P ADD NINE (9) TO DIGIT */                                          00437221
*/*COMPSET3: P HOLD RESULTING DIGIT OF ZONE/DIGIT */                    00439221
*/* D (NO,COMPSET2,YES,) DONE THREE DIGITS ? */                         00441221
*/*COMPSET4: R BR 14 */                                                 00443221
*/*COMPSET5: P (,COMPSET3) HOLD DIGIT */                                00443621
*/*WTORTN: P PREPARE WTO PARM LIST */                                   00444021
*/* D (NO,,YES,SKIPHEAD) HAVE HEADINGS BEEN WRITTEN  ? */               00444421
*/* P INDICATE HEADINGS WRITTEN */                                      00444821
*/* P SAVE DEVICE OUTPUT AND BUILD HEADING */                           00444921
*/* S TIME SVC 11: GET TIME OF DAY */                                   00445021
*/*TIME: P CONVERT TIME FOR PRINT AND PUT IN MSG */                     00445121
*/* S WTO RTN:GO ISSUE HEADING LINE */                                  00452921
*/* P PICK UP NUMBER OF DEVICES PER LINE */                             00453021
*/* D (NO,CONT,YES,) OFFLINE DISPLAY ? */                               00455021
*/* P USE OFFLINE LABELS IN LABEL LINE */                               00457021
*/*CONT: P DECREMENT LABEL LENGTH */                                    00457421
*/*LABLOOP: P PICK UP FIRST ENTRY IN LINE */                            00459021
*/* D (NO,LABEND,YES,) ANY MORE ENTRIES ? */                            00459421
*/* P PUT CORRECT LABEL IN LINE */                                      00459821
*/* D (NO,LABLOOP,YES,) ALL REQUIRED LABELS IN LINE ? */                00460221
*/*LABEND: D (NO,LABENDMV,YES,) REQUEST FOR SINGLE DEVICE ? */          00460621
*/* D (NO,LABENDMV,YES,) 2321 DATA CELL ? */                            00460721
*/* P MOVE IN SECOND HALF LABEL LINE */                                 00460821
*/*LABENDMV: S WTORTN:GO ISSUE LABEL LINE */                            00468621
*/* P (,WTORTN) RESTORE DEVICE TEXT OUTPUT */                           00468721
*/*SKIPHEAD: P SET LINE TYPE TO DATA */                                 00470721
*/* D (NO,,YES,MSGOUT) DATA CELL IN PROCESS */                          00472721
*/* D (NO,,YES,SKIPFR) IS THIS END OF DISPLAY ? */                      00474721
*/* S WTO RTN: GO ISSUE DATA LINE */                                    00475121
*/* D (NO,NEWLINE,YES,) IS DATA CELL COMPLETE? */                       00475521
*/* P (,NEWLINE) UP DEVICE DONE COUNT BY 2 */                           00475921
*/*SKIPFR: D (NO,OSU,YES,) WAS LAST LINE AN END LINE ? */               00497021
*/* S WTO RTN:GO WRITE MESSAGE */                                       00499021
*/* P MOVE MSG TEXT INTO WTO PARM LIST */                               00499421
*/*OSU: P SET LINETYPE = DATA END */                                    00499821
*/* S WTO RTN:GO OUTPUT MESSAGE */                                      00499921
*/*EXIT3: P (,EXUN3A) SET EXIT TO IGC22110 */                           00500021
*/*MSGOUT: S WTO RTN: GO OUTPUT MESSAGE */                              00510021
*/*EXUN3: P INDICATE FINISH DATA CELL */                                00512021
*/*EXUN3A: P PUT EXIT NAME (IGC22110) IN XCTL LIST */                   00514021
*/*XCTL: R IGC22110 */                                                  00516021
*/*WTO: E WTO RTN */                                                    00516421
*/*WTOLOOP: P FIND END OF MESSAGE TEXT */                               00516821
*/*HITEXT: P TAG DESCRIPTOR CODES ON END OF MESSAGE */                  00517221
*/* P COMPUTE AND PUT LENGTH INTO WTO LIST */                           00517621
*/* S WTO SVC 35:OUTPUT MESSAGE TO OPERATOR */                          00517721
*/* P SAVE CONSOLE ID AND MESSAGE NUMBER */                             00517821
*/* P CLEAR TEXT LINE */                                                00517921
*/* R BR 14 */                                                          00524721
*/*EXMSG1: P (,EXUN3A) INDICATE MESSAGE FOR UNIT 3 TO WRITE */          00526721
*/*IEE23110: END */                                                     00528721
         EJECT                                                          00531721
         BALR  PBASE,R0            ESTABLISH BASE REGISTER              00538521
         USING *,PBASE             DECLARE PROGRAM BASE                 00559021
         B     ICATCH              BRANCH AROUND EYECATCHER   MH A52720 00569021
         DC    C'   MODULE IGC23110, FICHE IEE23110 '         MC A63123 00579021
         USING XSASET,XSABASE      DECLARE XSA BASE                     00579521
ICATCH   L     WBASE,XAL           POINT TO WORK AREA         MH A52720 00600021
         USING WORKAREA,WBASE      DECLARE WORK AREA BASE               00700021
         LH    R13,DEVSPRE         GET NUMBER ALREADY PUT OUT           00800021
         TM    FLAG3,UNIT3RET      ENTRY TO PUT OUT DATA CELL WTO       00900021
         BO    WTORTN              YES ISSUE WTO AND RETURN TO UNIT3    01000021
         TM    FLAG5,INITENT       INITIAL ENTRY TO SET UP UCB TABLE    01100021
         BNO   WTORTN              NO ISSUE NORMAL WTO AND UPDATE TABLE 01200021
         SPACE 2                                                        01210021
*********************************************************************** 01220021
*                                                                     * 01230021
*  BUILD LIST OF VALID UCB ADDRESSES                                  * 01240021
*                                                                     * 01250021
*********************************************************************** 01260021
         NI    FLAG5,N255-INITENT   TURNOFF INITIAL ENTRY FLAG          01300021
         XC    UCBADDRA+N2(N12),UCBADDRA+N2 CLEAR TABLE                 01400021
         LR    R7,R9               GET STARTING UCB ADDRESS             01500021
NEWLINE  EQU   *                                                        01600021
         STH   R7,CURRENT         PUT VALUE INTO CURRENT WORD           01700021
         LA    R15,N13(R7)        GET PTR TO EBCICIC ADDRESS            01800021
         BAL   RETURN,COMPSET     GO CONVERT IT                         01900021
         ST    R8,LOW             SAVE CONVERTED VALUE                  02000021
         LH    ADDRPT,DEVNOLN      GET NUMBER OF DEVICES FOR LINE       02100021
         LA    ADDRPT,N1(ADDRPT)   KICK UP ADDRESS BY ONE               02200021
         LA    ADDR,UCBADDRA       POINT TO UCB ADDRESS TABLE           02300021
         LA    R3,CVT              POINT TO CVT ADDRESS                 02400021
         L     R3,ZERO(R3)         GET CVT ADDRESS                      02500021
         USING CVTDSECT,R3                                              02600021
         L     R3,CVTILK2         GET LOOK-UP TABLE ADDRESS             02700021
DUMBHI   EQU   *                                                        02800021
         MVI   HIGH+N2,N255       DUMMY UP HIGH VALUE                   02900021
VALIDCHK EQU   *                                                        03000021
         USING UCBDSECT,UCBADDR    DECLARE UCB ADDRESS                  03100021
         SR    WORK,WORK           CLEAR REGISTER                       03200021
         IC    WORK,UCBTBYT3       GET UCB TYPE                         03300021
         LA    POINT,FLAG1         POINT TO RIGHT FLAG BYTE             03400021
         EX    WORK,TESTMASK       CHECK TYPE                           03500021
         BNO   BUMP                NO MATCH GET NEXT UCB      MH A57061 03600021
         TM    FLAG2,ALLS          ALL STATUS WANTED                    03700021
         BO    STORADDR            YES SAVE THIS ADDRESS                03800021
         TM    FLAG2,ONLINS        ONLINE REQUEST                       03900021
         BO    ONLINE              YES TEST UCB ONLINE                  04000021
*                                  NO, ASSUME OFFLINE REQUEST MH A52720 04050021
         TM    SRTESTAT,SRTEONLI+SRTEALOC        IS DEVICE    MH A52720 04100021
*                                  ONLINE OR ALLOCATED        MH A52720 04150021
         BZ    STORADDR            NEITHER, MUST BE OFFLINE   MH A52720 04200021
         B     BUMP                GET NEXT DEVICE            MH A57061 04250021
ONLINE   EQU   *                                                        04600021
         TM    SRTESTAT,ONLINS     IS DEVICE ONLINE                     04700021
         BO    STORADDR            YES STORE ADDRESS                    04800021
         B     BUMP                NOT ONLINE, BRANCH                   04850021
STORADDR EQU   *                                                        05400021
         OI    FLAG5,DISPBIT       TURN ON UCB FOUND BIT                05500021
         STH   R7,CURRENT          STORE POINTER TO CURRENT HIGH UCB    05600021
         ST    R8,HIGH             STORE CONVERTED DEVICE ADDRESS       05700021
         B     BUMP                GO GET ANOTHER                       05800021
LOOP     EQU   *                                                        05900021
         LH    R7,NO(R3)          GET UCB POINTER FROM LOOK-UP TABLE    06000021
         LTR   R7,R7               TEST SIGN OF ADDRESS                 06100021
         BP    UCB                 BRANCH IF ADDRESS POSITIVE           06200021
         BM    EOL                 BRANCH IF ADDRESS NEGATIVE           06300021
BUMP     EQU   *                   FALL THROUGH ON ZERO                 06400021
         LA    R3,N2(R3)          BUMP POINTER TO THE NEXT ADDRESS      06500021
         B     LOOP                  BY TWO AND GO TO GET NEXT          06600021
UCB      EQU   *                                                        06700021
         LA    R15,N13(R7)        POINT TO EBCIDIC ADDRESS VALUE        06800021
         BAL   RETURN,COMPSET      CONVERT ADDRESS FOUND BY 'LOOP'      06900021
         STC   R8,UNITADDA         STORE CONVERTED ADDRESS    MC A63123 06950021
         NI    UNITADDA,ZEROFOX    ZERO SUBCHANNEL PORTION    MC A63123 06952021
         MVC   UNITADDB(L1),UCBUA  STORE HEX ADDRESS          MC A63123 06954021
         NI    UNITADDB,ZEROFOX    ZERO SUBCHANNEL PORTION    MC A63123 06956021
         CLC   UNITADDA(L1),UNITADDB    COMP DEVICE ADDRS     MC A63123 06958021
         BNE   BUMP                NOT EQUAL, NOT BASE DCM    MC A55717 06960021
         CL    R8,LOW              COMPARE AGAINST LOW VALUE            07000021
         BNH   BUMP                IF NEW VALUE LOW BRANCH              07100021
         CL    R8,HIGH             COMPARE AGAINST HIGH VALUE           07200021
         BH    BUMP                NEW VALUE HIGHER THAN OLD HIGH       07300021
         B     VALIDCHK           GO TO VALIDITY CHECK ROUTINE          07400021
EOL      EQU   *                                                        07600021
         CH    R13,NODEVICS        REQUEST SATISFIED          MG  M2075 07850021
         BNL   SETND               YES, END OF DISPLAY        MG  M2075 07860021
         TM    FLAG5,DISPBIT       ANY NEW HIGH STORED        MC A55356 07870021
         BNO   NOADDR              NO-ALL UCB'S FOUND THAT SF MC A55356 07880021
         MVC   LOW+N2(L2),HIGH+N2     PUT HIGH VALUE INTO LOW           07900021
         MVC   NO(L2,ADDR),CURRENT MOVE UCB POINTER INTO SAVE LIST      08000021
         MVC   UCBADDRB(L2),CURRENT     SAVE LAST VALUE FOUND           08100021
         LA    ADDR,N2(ADDR)      BUMP POINTER                          08200021
         LA    R13,N1(R13)         BUMP NUMBER FOUND BY 1               08300021
         NI    FLAG5,N255-DISPBIT      TURN OFF UCB FOUND BIT           08400021
GETONE   EQU   *                                                        08700021
         LA    R3,CVT              POINT TO CVT ADDRESS                 08800021
         L     R3,ZERO(R3)         GET CVT ADDRESS                      08900021
         L     R3,CVTILK2         GET LOOKUP POINTER                    09000021
         MVI   HIGH+N2,N255       DUMMY UP HIGH UCB                     09100021
         BCT   ADDRPT,LOOP        COUNT NUMBER IN LINE                  09200021
EXIT     EQU   *                                                        09300021
         MVI   XAX+L4,F1           SECOND LOAD NAME                     09400021
         TM    FLAG4,PDCELL        FINISH DATA CELL                     09500021
         BNO   XCTL                NO, GO TO SECOND LOAD                09600021
         LA    WORK,UCBADDRA       POINT TO FIRST UCB ADDRESS           09700021
         ST    WORK,SAVE+N4        STORE UCB ADDRESS                    09800021
         B     EXUN3A              EXIT TO IEEUNIT3                     09900021
NOADDR   EQU   *                                                        10100021
         LTR   R13,R13             ANY DISPLAY                          10200021
         BZ    EXMSG1              ISSUE MESSAGE                        10300021
         TM    FLAG5,NODEF        TEST FOR DEFAULT                      10400021
         BNO   SETND              BRANCH TO SET END FLAG                10500021
         OI    FLAG5,CRTMSG2      TURN ON MESSAGE BIT FOR U3            10600021
SETND    EQU   *                                                        11100021
         OI    FLAG5,DISPEND      TURN ON DISPLAY FINISHED              11200021
         B     EXIT               BUILD LINE                            11300021
         SPACE 2                                                        11400021
*********************************************************************** 11410021
*                                                                     * 11420021
*  THIS ROUTINE CHANGES EBCDIC DEVICES TO BINARY.                     * 11430021
*  REG 15 POINTS TO THE NUMBER TO BE CONVERTED.                       * 11440021
*  THE CONVERTED NUMBER IS RETURNED IN REG 8.                         * 11450021
*  RETURN IS VIA BR 14.                                               * 11460021
*  REGS 8,9,4 AND 15 ARE DESTROYED                                    * 11470021
*                                                                     * 11480021
*********************************************************************** 11490021
COMPSET  EQU   *                                                        11500021
         SR    WORK,WORK          ZERO REGISTER                         11700021
         LA    WORK,L3(WORK)      INITIALIZE COUNTER                    11800021
         SR    TEXTPTR,TEXTPTR     CLEAR WORK REF                       11900021
COMPSET2 EQU   *                                                        12000021
         SR    R9,R9               CLEAR WORK REG                       12100021
         TM    N0(R15),F0          THIS DIGIT NUMERIC                   12200021
         BO    COMPSET5            YES HANDLE                           12300021
         IC    R9,N0(R15)          ISOLATE DIGIT                        12400021
         LA    R9,N9(R9)           UP BY NINE                           12500021
COMPSET3 EQU   *                                                        12600021
         SLL   R9,N28              SHIFT DIGIT TO                       12700021
         SLDL  TEXTPTR,N4          LOW ORDER NIBBLE OF REG 8            12800021
         LA    R15,N1(R15)         POINT TO NEXT DIGIT                  12900021
         BCT   WORK,COMPSET2           DO ALL DIGITS                    13000021
COMPSET4 EQU   *                                                        13100021
         BR    RETURN              RETURN TO CALLER                     13200021
COMPSET5 EQU   *                                                        13300021
         IC    R9,N0(R15)          ISOLATE CHARACTER                    13400021
         B     COMPSET3            CONVERT IT                           13500021
         SPACE 2                                                        13600021
*********************************************************************** 13610021
*                                                                     * 13620021
*  ISSUE WTO ON THE COMPLETED DISPLAY LINES                           * 13630021
*                                                                     * 13640021
*********************************************************************** 13650021
WTORTN   EQU   *                                                        13700021
         MVC   DESCODE(L4),DCODE   MOVE WTO TAIL                        13800021
         MVC   AID(L1),IDFLD      MOVE IN AREA ID                       13900021
         MVI   MCSONE,SETONE      SET FIRST BIT OF MCS FIELD            14000021
         MVI   MCSTWO,SETTWO      SET SECOND BIT OF MCS FLAGS           14100021
         MVI   LNUM,L1             RE/SET LINES IN LIST                 14200021
         MVI   TYPEFLAG+N1,ZERO    ZERO OUT LINE TYPE BYTE 2            14250021
         TM    FLAG3,HEADOUTF      Q.  HAVE HEADING LINE BEEN WRITTEN   14300021
         BO    SKIPHEAD            A. YES SKIP THEM                     14400021
         OI    FLAG3,HEADOUTF      INDICATE HEADING LINES OUT           14500021
         MVC   SAVE+N12(N72),TEXT  SAVE LINE BUILT BY IEEUNIT2/IEEUNIT3 14600021
         MVI   TEXT,BLANK          BLANK TEXT                           14630021
         MVC   TEXT+N1(L71),TEXT   LINE OUT                             14660021
         MVC   TEXT(HEADLGN),HEAD       MOVE HEADING INTO TEXT          14700021
         TIME  DEC                                                      14800021
TIME     EQU   *                                                        15000021
         ST    R0,WORKING          HOLD TIME                            15100021
         UNPK  WORKING(N8),WORKING(N4)   UNPACK TIME FOR PRINT          15200021
         MVC   TITLEDGH(N2),WORKING+N1      HH                          15300021
         MVC   TITLEDGM(N2),WORKING+N3      HH.MM                       15400021
         MVC   TITLEDGS(N2),WORKING+N5      HH.MM.SS                    15500021
         MVI   TYPEFLAG,ATE        SET CONTROL LINE TYPE                15700021
         BAL   RETURN,WTO          ISSUE WTO FOR HEADIND                15900021
         LH    WORK,DEVNOLN        GET NO. OF DEVICES PER LINE          16000021
         LA    TEXTPTR,TEXT        POINT TO TEXT LINE                   16100021
         LA    R15,UCBADDRA        POINT TO UCB ADDRESS LIST            16200021
         SR    POINT,POINT         ZERO REGISTER                        16300021
         LA    SCRATCH,LABELA      POINT TO CORRECT LABEL               16400021
         LA    POINT,LABALGN(POINT)     LENGTH OF LABEL FOR MOVE        16500021
         MVC   WORKING(N2),ONLGN   TEXT INCREMENT                       16600021
         TM    FLAG2,OFFLNS       TEST FOR OFFLINE                      16700021
         BNO   CONT               BRANCH IF NOT                         16800021
         LA    R5,LABOLGN         SET UP FOR OFFLINE DISPLAY            16900021
         MVC   WORKING(N2),OFFLGN      SET FOR OFFLGN HEADDER SPACING   17000021
CONT     EQU   *                                                        17100021
         BCTR  POINT,R0            DECREMENT LENGTH OF LABEL BY ONE     17200021
LABLOOP  EQU   *                                                        17300021
         LH    ADDR,N0(R15)        PICK UP UCB ADDRESS                  17400021
         LTR   ADDR,ADDR           Q. ZERO POINTER                      17500021
         BZ    LABEND              YES ISSUE LABEL LINE                 17600021
         EX    POINT,LABMOVE       PUT CORRECT LABEL IN LINE            17700021
         AH    TEXTPTR,WORKING     NO INCREMENT  TEXT POINTER           17800021
         LA    R15,N2(R15)         UP TO NEXT ENTRY IN LIST             17900021
         BCT   WORK,LABLOOP        DO ALL LABELS REQUIRED               18000021
LABEND   EQU   *                                                        18100021
         TM    FLAG2,SINGLE        SINGLE REQUEST                A35057 18200021
         BNO   LABENDMV            NO SKIP REQUEST               A35057 18300021
         TM    FLAG3,UNIT3RET      IF UNIT3 THEN SINGLE 2321 WHICH      18400021
         BNO   LABENDMV            REQUIRES A FULL LABEL, ELSE HALF.    18500021
         EX    POINT,LABMOVE       MOVE SECOND HALF OF LABEL LINE       18600021
LABENDMV EQU   *                                                        18700021
         MVI   TYPEFLAG,FORE       SET LABEL LINE TYPE                  18800021
         BAL   RETURN,WTO          WRITE LABEL LINE                     18900021
         MVC   TEXT(N72),SAVE+N12       RESTORE TEXT LINE               19000021
         B     WTORTN              RE-INITIALIZE WTO TAIL               19100021
SKIPHEAD EQU   *                                                        19200021
         MVI   TYPEFLAG,TWO        SET DATA LINE TYPE                   19300021
         TM    FLAG3,UNIT3RET      DATA CELL IN PROGRESS                19400021
         BO    MSGOUT              YES                                  19500021
         TM    FLAG5,DISPEND       IS THIS END OF DISPLAY               19600021
         BO    SKIPFR              YES, ISSUE WTO AND EXIT              19700021
         BAL   RETURN,WTO          NO PUT OUT TEXT LINE                 19800021
         XC    UCBADDRA(N14),UCBADDRA  CLEAR TABLE                      19900021
         LH    UCBADDR,UCBADDRB    GET NEXT VALID UCB                   20000021
         TM    FLAG5,UN4BINLT      IS UNIT3 DONE WITH A DATA CELL       20100021
         BNO   NEWLINE             NO START NEW LINE                    20200021
         NI    FLAG5,N255-UN4BINLT TURN OFF INDICATOR BIT               20300021
         LH    ADDRPT,DEVNOLN      GET DEVICE COUNT/LINE                20400021
         LA    ADDRPT,N2(ADDRPT)       BUMP BY TWO                      20500021
         LA    ADDR,UCBADDRA       POINY TO START OF LIST               20600021
         B     NEWLINE            GO TO DO ANOTHER LINE       MG  M2074 20700021
SKIPFR   EQU   *                                                        21000021
         TM    FLAG5,CRTMSG2      SEE IF LAST STATUS LINE IS END LINE   21100021
         BNO   OSU                BRANCH IF NO ERROR MSG                21200021
         CLC   TEXT(N7),MSG2A      IS CRTMSG IN TEXT SLOT     MC A55356 21250021
         BE   OSU                  YES, SET END AND WRITE     MC A55356 21260021
         BAL   RETURN,WTO         GO WRITE                              21300021
         MVC   TEXT(MSG2ALGN),MSG2A    OTHERWISE MOVE TEXT IN FOR MSG2  21400021
         B     WTORTN              RE-INIT WTO PARA LIST      MC A55356 21450021
OSU      EQU   *                                                        21500021
         MVI   TYPEFLAG,THREE      SET DATA-END LINE TYPE               21600021
         BAL   RETURN,WTO         GO WRITE MSG2                         21700021
EXIT3    EQU   *                                                        21800021
         MVI   FLAG4,EXITBIT       GO TO THIRD LOAD AND EXIT            21900021
         B     EXUN3A              BRANCH AROUND OTHER FLAG SETTING     22000021
MSGOUT   EQU   *                                                        22100021
         BAL   RETURN,WTO              GO WRITE OUT                     22200021
EXUN3    EQU   *                                                        22300021
         MVI   FLAG4,PDCELL        FINISH DATA CELL                     22400021
EXUN3A   EQU   *                                                        22500021
         MVI   XAX+L4,F2           THIRD LOAD NAME                      22600021
XCTL     EQU   *                                                        22700021
         LA    R15,XSA             POINT TO  PARA  LIST                 22750021
         XCTL  SF=(E,(R15))                                             22800021
         SPACE 2                                                        22900021
*********************************************************************** 22910021
*                                                                       22920021
*  ROUTINE ISSUES SVC 35 ON COMPLETED DISPLAY LINES                     22930021
*                                                                       22940021
*********************************************************************** 22950021
WTO      EQU   *                                                        23000021
         LA    ADDRPT,TEXT+L71     POINT TO SEARCH BEGIN                23100021
WTOLOOP  EQU   *         SEARCH BACK FOR LAST TEXT CHARACTER            23300021
         CLI   ZERO(ADDRPT),BLANK   IS THIS CARACTER A BLANK            23400021
         BNE   HITEXT              NO   FOUND END - FINISH WTO          23500021
         BCT   ADDRPT,WTOLOOP      GO BACK ONE                          23800021
HITEXT   EQU   *                                                        24000021
         MVC   ONE(N8,ADDRPT),DESCODE       BACK UP TAIL TO TEXT        24100021
         LA    ADDRPT,N5(ADDRPT)   UP LENGTH FOR SEARCH AND CODES       24200021
         LA    R0,TEXT             POINT TO TEXT BEGINNING              24300021
         SR    ADDRPT,R0           FIND LENGTH OF WTO                   24400021
         STH   ADDRPT,WTOSET       STORE LENGTH IN LIST                 24500021
         L     R0,HOLD2           PUT IN AREA  CONSOLE ID AND MLWTO ID  24600021
         LA    ADDRPT,WTOSET       POINT TO WTO LIST                    24700021
         WTO   MF=(E,(1))          EXECUTE WTO LIST                     24800021
         SLL   R1,N8               SHIFT TO HIGH ORDER BYTES            24900021
         IC    R1,HOLD2+N3         GET CONSOLE ID                       25000021
         ST    R1,HOLD2           STORE THEM BACK                       25100021
         MVI   TEXT,BLANK          BLANK TEXT AREA                      25200021
         MVC   TEXT+L1(L71),TEXT   PROPAGATE BLANKS                     25300021
         BR    14                  EXIT TO CALLER                       25400021
         SPACE 2                                                        25500021
         SPACE 2                                                        25600021
EXMSG1   EQU   *                                                        25700021
         MVI   FLAG4,MSG1          IEEUNIT3 - WRITE MSG1A               25800021
         B     EXUN3A              GO TO IEEUNIT3                       25900021
         EJECT                                                          25920021
*********************************************************************** 25940021
*                                                                     * 25960021
*  EXECUTED INSTRUCTIONS                                              * 25980021
*                                                                     * 26000021
*********************************************************************** 26020021
LABMOVE  EQU   *                                                        26100021
         MVC   ZERO(ZERO,TEXTPTR),ZERO(SCRATCH)   LABEL MOVE            26200021
TESTMASK EQU   *                                              MC A55717 26250021
         TM    N0(POINT),N0        EXECUTED TEST UNDER MASK   MC A55717 26260021
         SPACE 2                                                        26300021
*********************************************************************** 26400021
*                                                                     * 26500021
*                             EQUATES                                 * 26600021
*                                                                     * 26700021
*********************************************************************** 26800021
R0       EQU   0                   GENERAL REGISTER NOTATION            26900021
ADDRPT   EQU   1                   *                       *            27000021
ADDR     EQU   2                   *                       *            27100021
SCRATCH  EQU   3                   *                       *            27200021
R1       EQU   1                   *                       *            27300021
R3       EQU   3                   *                       *            27400021
WORK     EQU   4                   *                       *            27500021
R5       EQU   5                   *                       *            27600021
POINT    EQU   5                   *                       *            27700021
LINEOUT  EQU   6                   *                       *            27800021
R7       EQU   7                   *                       *            27900021
UCBADDR  EQU   7                   *                       *            28000021
R8       EQU   8                   *                       *            28100021
TEXTPTR  EQU   8                   *                       *            28200021
OUTWTO   EQU   7                   *                       *            28300021
R9       EQU   9                   *                       *            28400021
WBASE    EQU   10                  *                       *            28500021
XSABASE  EQU   11                  *                       *            28600021
PBASE    EQU   12                  *                       *            28700021
R13      EQU   13                  *                       *            28800021
RETURN   EQU   14                  *                       *            28900021
R15      EQU   15                  *                       *            29000021
         SPACE 2                                                        29050021
NO       EQU   0                   LENGTHS AND DISPLACEMENTS            29200021
N0       EQU   0                   *          *            *            29300021
N1       EQU   1                   *          *            *            29400021
N2       EQU   2                   *          *            *            29500021
N3       EQU   3                   *          *            *            29600021
N4       EQU   4                   *          *            *            29700021
N5       EQU   5                   *          *            *            29800021
N6       EQU   6                   *          *            *            29900021
N7       EQU   7                   *          *            *            30000021
N8       EQU   8                   *          *            *            30100021
N9       EQU   9                   *          *            *            30200021
N12      EQU   12                  *          *            *            30300021
N13      EQU   13                  *          *            *            30400021
N14      EQU   14                  *          *            *            30500021
N28      EQU   28                  *          *            *            30600021
N72      EQU   72                  *          *            *            30700021
N255     EQU   255                 *          *            *            30800021
L1       EQU   1                   *          *            *            30900021
L3       EQU   3                   *          *            *            31000021
L4       EQU   4                   *          *            *            31100021
L2       EQU   2                   *          *            *            31300021
L8       EQU   8                   *          *            *            31400021
L12      EQU   12                  *          *            *            31600021
L24      EQU   24                  *          *            *     A36165 31700021
L32      EQU   32                  *          *            *            31750021
L71      EQU   71                  *          *            *            31800021
ATE      EQU   X'80'               CONTROL LINE                         32000021
FORE     EQU   X'40'               LABEL LINE                           32100021
THREE    EQU   X'30'               DATA END LINE                        32200021
TWO      EQU   X'20'               DATA LINE                            32300021
ZERO     EQU   0                   *          *            *            32400021
ONE      EQU   1                   *          *            *            32500021
CVT      EQU   16                  ADDRESS OF CVT POINTER               32700021
F0       EQU   C'0'                EBCDIC ZERO                          32800021
F1       EQU   C'1'                EBCDIC 1                             32900021
F2       EQU   C'2'                EBCDIC 2                             33000021
BLANK    EQU   C' '                BLANK                                33200021
ZEROFOX  EQU   X'0F'               MASK TO ZERO SUBCHANNEL    MC A63123 33250021
         EJECT                                                          33400021
*********************************************************************** 33500021
*                                                                     * 33600021
*     MESSAGES                                                        * 33700021
*                                                                     * 33800021
*********************************************************************** 33900021
MSG2A    DC    C'IEE452I UNIT STATUS NUMBER OF UNITS REQUESTED EXCEEDS X34000021
               NUMBER AVAILABLE'        ERROR MESSAGE 2                 34100021
MSG2AEND EQU   *                   END PF MSG2A                         34200021
MSG2ALGN EQU   MSG2AEND-MSG2A      LENGTH OF MSG2A                      34300021
HEAD     DC    C'IEE450I   .  .   UNIT STATUS'                          34400021
HEADEND  EQU   *                   END OF HEADING LINE                  34500021
HEADLGN  EQU   HEADEND-HEAD                                             34600021
*              THE FIRST NINE BYTES OF LABELA ARE ALSO USED FOR LABELO  34700021
LABELO   EQU   *                  MUST IMMEDIATELY PRECEED LABELA       34800021
LABELA   DC    C'UNIT TYPE STATUS  VOLSER VOLSTATE'                     34900021
LABAEND  EQU   *                   END OF LABELA                        35000021
LABALGN  EQU   LABAEND-LABELA      LENGTH OF LABELA                     35100021
LABOLGN  EQU   9                  LENGTH FOR OFFLINE LABEL              35200021
         EJECT                                                          35300021
*********************************************************************** 35400021
*                                                                     * 35500021
*                             CONSTANTS                               * 35600021
*                                                                     * 35700021
*********************************************************************** 35800021
ONLGN    DC    H'36'               FIRST HALF OF ONLINE LINE LENGTH     35900021
OFFLGN   DC    H'10'               LENGTH OF ONE OFFLINE ENTRY          36000021
DCODE    DC    XL4'09800000'       DESCRIPTOR CODES 5,8,9 AND           36100021
*                                  ROUTING CODES (0)                    36200021
         EJECT                                                          36300021
*********************************************************************   36400021
*                                                                     * 36500021
*        DSECTS                                                       * 36600021
*                                                                     * 36700021
*********************************************************************   36800021
CVTDSECT DSECT                                                          36900021
         CVT                                                            37000021
         EJECT                                                          37100021
UCBDSECT DSECT                                                          37200021
         IEFUCBOB                                                       37300021
         EJECT                                                          37400021
XSASET   DSECT                                                          37500021
         IEECHAIN                                                       37600021
         ORG   CHAIN+L32                                                37700021
         IEEXSA                                                         37800021
         ORG   XSA+L24                                           A36165 37900021
WORKING  DS    5F                  WORKING STORAGE                      38000021
DEVNOLN  EQU   WORKING+L8          NUMBER OF DEVICES PER LINE           38100021
DEVSPRE  EQU   DEVNOLN+L2          NUMBER OF DEVICES DISPLAYED          38200021
LASTUCB  EQU   DEVSPRE+L3          STARTING UCB ADDRESS/BIN NUMBER      38300021
FROMID   EQU   LASTUCB+L4          REQUESTING CONSOLE ID                38400021
SAVE     DS    21F                 SAVE AREA BETWEEN MODULES            38500021
UNITADDA DS    C                   DEVICE ADDRESS FROM EBCDIC MC A63123 38550021
UNITADDB DS    C                   DEVICE ADDRESS FROM HEX    MC A63123 38600021
         ORG   SAVE+L12                                                 39000021
PACKWORD DS    F                                                        39100021
CVBWORD   DS   F                                                        39200021
         EJECT                                                          39300021
WORKAREA DSECT                                                          39400021
         SPACE 2                                                        39500021
         DS    0D                                                       39600021
UCBADDRA DS    7H                  STORAGE FOR UCB ADDRESSES            39700021
UCBADDRB DS    H                   FOUND BY UNIT4                       39800021
SWORD    DC    3F'0'               SAVE AREA ACROSS MODULES             39900021
UNIT1    DS    F                   HOLD ADDRESS ONE                     40000021
UNIT2    DS    F                   HOLD ADDRESS TWO                     40100021
UNIT3    DS    F                   HOLD ADDRESS THREE                   40200021
         SPACE 4                                                        40300021
FLAG2    DC    X'00'               COMMUNICATIONS BYTE                  40400021
ONLINS   EQU   128                 DISPLAY ONLINE DEVICES               40500021
OFFLNS   EQU   64                  DISPLAY OFFLINE DEVICES              40600021
ALLS     EQU   32                  DISPLAY OFFLINE + ONLINE DEVICES     40700021
SUFEXIST EQU   16                  REQUESTING CONSOLE IS A CRT DEVICE   40800021
SINGLE   EQU   8                   SINGLE DEVICE REQUEST                40900021
COREGOT  EQU   4                   CORE GOTTEN FOR REGION               41000021
OPEN22   EQU   2                   OPEN FLAG                            41100021
R13UCBNM EQU   1                   FLAG FOR COMPSET ROUTINE             41200021
         SPACE 2                                                        41300021
FLAG3    DC    X'00'               COMMUNICATIONS FLAGS                 41400021
U2       EQU   128                 SCAN CDE'S FOR DEVNAMET              41500021
UNIT3RET EQU   64                  IEE22110 RETURNING TO IEE21110       41600021
OPEN332  EQU   32                  OPEN FLAG                            41700021
DEVDEF   EQU   16                  DEVICE ADDRESS DEFAULTED             41800021
HEADOUTF EQU   8                   HEADING AND LABELS ARE OUT           41900021
OPEN34   EQU   4                   OPEN FLAG                            42000021
OPEN32   EQU   2                   OPEN FLAG                            42100021
OPEN31   EQU   1                   OPEN FLAG                            42200021
         SPACE 2                                                        42300021
*  FLAG4 BYTE IS USED FOR COMMUNICATIONS BETWEEN IEEUNIT3 AND THE       42400021
*  OTHER  D UNIT  MODULES.                                              42500021
FLAG4    DC    X'00'               COMMUNICATIONS BYTE                  42800021
MSG0     EQU   X'00'               ISSUE MESSAGE MSG0A                  42900021
DCELL    EQU   X'04'               PROCESS DATA CELL ENTRY              43000021
PDCELL   EQU   X'08'               COMPLETE DATA CELL ENTRY             43100021
EXITBIT  EQU   X'0C'               RETURN TO CALLER                     43200021
MSG1     EQU   X'10'               ISSUE MESSAGE MSG1A                  43300021
MSG3     EQU   X'14'               ISSUE MESSAGE MSG3A                  43400021
MSG4     EQU   X'18'               ISSUE MESSAGE MSG4A                  43500021
         SPACE 2                                                        43600021
FLAG5    DS    XL1                                                      43700021
NODEF    EQU   X'80'               LINE DEFAULT NOT TAKEN               43800021
INITENT  EQU   X'40'               INITIAL ENTRY TO UNIT STATUS FOUR    43900021
INITUNT2 EQU   X'20'               INITIAL ENTRY TO UNIT STATUS TWO     44000021
CRTMSG2  EQU   X'10'               MSG2 WITH HEADINGS FOR DIDOCS        44100021
UN4BINLT EQU   X'08'               LASTBIN FLAG FOR UNIT4               44200021
DISPBIT  EQU   X'04'               VALID ADDRESS FOUND                  44300021
DISPEND  EQU   X'02'               END OF FRAME AND DISPLAY             44400021
OPEN51   EQU   X'01'               OPEN FLAG                            44430021
         SPACE 2                                                        44460021
         DS    0F                  FORCE FULL WORD FOR WTO              44500021
WTOSET   DS    XL1                 ZERO                                 44600021
TEXTLEN  DS    XL1                 OUTPUT LENGTH                        44700021
LENGTH   EQU   76                  FULL LINE                            44800021
MCSONE   DS    XL1                 MCS FLAGS PART ONE                   44900021
SETONE   EQU   X'E1'               QUEUE BY ID, ROUTING + DESCRIPTOR    45000021
*                                  CODES EXIST, COMMAND RESPONSE, QUEUE 45100021
*                                  BY ID ONLY.                          45200021
MCSTWO   DS    XL1                 MCS FLAGS PART TWO                   45300021
SETTWO   EQU   X'40'               MLWTO                                45400021
         SPACE 1                                                        45500021
MSGT     DS    0C                  BEGIN TEXT LINE                      45600021
TEXT     DS    XL72                TEXT FIELD                           45700021
         ORG   TEXT                                                     45800021
TITLEID  DS    XL8                 MESSAGE ID NUMBER                    45900021
TITLEDGH DS    XL3                 HOURS.                               46000021
TITLEDGM DS    XL3                 MINUTES.                             46100021
TITLEDGS DS    XL2                 SECONDS                              46200021
TITLENM  DS    XL11               NAME OF DISPLAY                       46300021
         ORG   TEXT                                                     46400021
UCBN1    DS    XL5                 UNIT ADDRESS                         46500021
MODL1    DS    XL5                 DEVICE TYPE                          46600021
USTAT1   DS    XL1                 STATUS (O,A,S,C,OFFLINE)             46700021
USTAT2   DS    XL4                 STATUS (-BSY,-MTP,-NRD)              46800021
USTAT3   DS    XL3                 STATUS (-R)                          46900021
VOLID1   DS    XL7                 VOLUME SERIAL NUMBER                 47000021
VOST1A   DS    XL4                 VOLUME STATE (PUB,PRIV,STRG)         47100021
VOST1B   DS    XL6                 VOLUME STATE (-REMOV,-RSDNT,-RSERV)  47200021
         SPACE 2                                                        47300021
         ORG   TEXT+72            ORG FOR WTO TAIL                      47400021
DESCODE  DS    XL2                 DESCRIPTOR CODES                     47500021
RTECODE  DS    XL2                 ROUTING CODES                        47600021
TYPEFLAG DS    XL2                 MESSAGE TYPES                        47700021
AID      DS    XL1                AREA ID FIELD                         47800021
LNUM     DS    XL1                NUMBER OF LINES                       47900021
         SPACE 2                                                        48000021
HOLD2    DS    F                   MLWTO ID/ CONSOLE ID FOR WTO         48100021
NODEVICS DS    H                   NUMBER OF UNITS REQUESTED            48200021
NODEVDEF EQU   100                 DEFAULT                              48300021
         SPACE 2                                                        48400021
         SPACE 4                                                        48500021
*  FLAG1 BYTE IS SET BY IEEUNIT1 TO REFLECT THE DEVICE TYPE(S)          48600021
*  REQUESTED BY THE D U  COMMAND.  THE BITS SET CORRESPOND TO THE BIT   48700021
*  SETTINGS IN BYTE 3 OF THE UCBTYP FIELD.                              48800021
         SPACE 2                                                        48900021
FLAG1    DC    X'00'               FLAG1 FIELD                          49000021
TATYPE   EQU   UCB3TAPE           TAPE DEVICES                          49100021
TPTYPE   EQU   UCB3COMM           TELECOMMUNICATIONS DEVICES            49200021
DATYPE   EQU   UCB3DACC           DIRECT ACCESS DEVICES                 49300021
GRTYPE   EQU   UCB3DISP            GRAPHIC DISPLAY DEVICES              49400021
URTYPE   EQU   UCB3UREC+UCB3CHAR        UNIT RECORD + CHAR RDR DEVICES  49500021
ALLTYPE  EQU   TATYPE+TPTYPE+DATYPE+GRTYPE+URTYPE     ALLDEVICE TYPES   49600021
         SPACE 2                                                        49700021
IDFLD    DS    XL1                AREA ID SAVE AREA                     49800021
WEND     EQU   *                   END OF WORK AREA                     49900021
WAL      EQU   WEND-WORKAREA       LENGTH OF WORK AREA                  50000021
LOW      EQU   UNIT1                                                    50100021
CURRENT  EQU   UNIT2                                                    50200021
HIGH     EQU   UNIT3                                                    50300021
         END                                                            50400021
