IEE2903D CSECT                                                          00400019
* A 440500,444500,446500-447500                                  A53046 00400421
* C 425000-434000,440000,444000,446000,510000                    A53046 00400821
* A 160500,246500,303500-303800                                   M2196 00402021
*2909410000                                                      A22909 00410019
* 692000                                                          20030 00500020
* C698100-698150,C698400-698800,D698900-699400,D699500-699650,    M2047 00530020
* A193200                                                         M2047 00560020
*                                                                A39479 00570020
* C256000,C662500                                                A45338 00580021
*  A 255000,303510-303580,663500,721000                          A58369 00585021
*  C 256000,396000,460000,490000,554000,662500,691200            A58369 00590021
*  D 699700                                                      A58369 00595021
*******************************************************************     00600020
*NAME  IEE2903D - DISPLAY REQUESTS ROUTINE                         TMCS 00800018
*      (FORMERLY IEEVDOR1)                                         TMCS 01000018
*                                                                     * 01200018
*FUNCTION: TO DISPLAY ON THE OPERATOR'S CONSOLE THE ID OF EACH WTOR   * 01400018
*          TYPE MESSAGE THAT HE HAS NOT REPLIED TO AND THE UNIT NUMBER* 01600018
*          OF EACH DEVICE FOR WHICH A MOUNT INSTRUCTION HAS BEEN      * 01800018
*          ISSUED BUT NOT COMPLIED WITH, AND AN INDICATION IF AN AVR  * 02000018
*          MOUNT MESSAGE IS PENDING.                                  * 02200018
*                                                                     * 02400018
*OPERATION: A TEST IS MADE TO DETERMINE WHETHER THERE ARE ANY         * 02600018
*          OUTSTANDING REPLY QUEUE ELEMENTS (RPQE).  IF THERE ARE,    * 02800018
*          THE ID ASSOCIATED WITH EACH OUTSTANDING RPQE IS MOVED TO   * 03000018
*          A MESSAGE AREA.                                              03200018
*                AFTER ALL OF THE RPQES HAVE BEEN PROCESSED, THE UCBS * 03400018
*           FOR EACH TAPE AND DIRECT ACCESS DEVICE ON THE SYSTEM ARE  * 03600018
*           EXAMINED. THE HIGH ORDER BIT OF THE SRTEDMCT FIELD OF THE * 03800018
*           UCB IS TESTED. IF THIS BIT IS ON AND THE DEVICE IS A      * 04000018
*           DIRECT ACCESS DEVICE, THE EXTERNAL ACTION ROUTINE         * 04200018
*           (IEFWD000) IS WAITING TO VERIFY A MOUNT COMMAND THAT IT   * 04400018
*           HAS ISSUED, AND THE UNIT NUMBER FOR THIS UCB IS THEREFORE * 04600018
*           MOVED TO THE MESSAGE AREA TO ADVISE THE OPERATOR OF THIS  * 04800018
*           CONDITION.                                                * 05000018
*                IF THE HIGH ORDER BIT IN THE SRTEDMCT FIELD IS ON AND* 05200018
*           THE DEVICE IS A TAPE DRIVE, A MOUNT MESSAGE HAS BEEN      * 05400018
*           ISSUED WHICH, SINCE THE OPEN ROUTINE, AND NOT THE         * 05600018
*           EXTERNAL ACTION ROUTINE, VERIFIES THE MOUNT, MAY OR MAY   * 05800018
*           NOT HAVE BEEN COMPLIED WITH.  THE UCBFLG1 FIELD OF THE UCB* 06000018
*           IS THEREFORE TESTED AND IF THE DEVICE IS FOUND TO BE NOT  * 06200018
*           READY (BIT ONE IS ON) THE UNIT NUMBER IS MOVED TO THE     * 06400018
*           MESSAGE AREA.                                             * 06600018
*               IF THE HIGH ORDER BIT OF THE SRTEDMCT FIELD IS NOT ON * 06800018
*          AND THE DEVICE IS TAPE OR DIRECT ACCESS, THE UCBAT1 FIELD  * 07000018
*          IS TESTED. IF THIS FIELD IS NON-ZERO, AN AVR MOUNT MESSAGE * 07200018
*          IS PENDING, AND A SWITCH IS SET TO HAVE THIS CONDITION     * 07400018
*          INDICATED IN THE FINAL LINE OF MESSAGE.                    * 07600018
*               THIS ROUTINE KEEPS TRACK OF THE NUMBER OF BYTES MOVED * 07800018
*          TO THE MESSAGE AREA. EACH TIME BYTES ARE MOVED TO THE      * 08000018
*          MESSAGE AREA, A TEST IS MADE TO SEE IF MOVING ADDITIONAL   * 08200018
*          BYTES WOULD MAKE THE MESSAGE LONGER THAN 72 BYTES. IF THIS * 08400018
*          IS THE CASE, THE MESSAGE IS WRITTEN OUT, AND ADDITIONAL    * 08600018
*          BYTES ARE AGAIN MOVED IN TO THE BEGINNING OF THE AREA.     * 08800018
*                                                                     * 09000018
*ENTRY POINT- IEE2903D (FORMERLY IEEVDOR1)                         TMCS 09200018
*                                                                     * 09400018
*INPUT   POINTER TO XSA IN REGISTER TWO                            XMCS 09600018
*                                                                     * 09800018
*OUTPUT: IF THERE ARE NO OUTSTANDING RPQES AND NO UNATTENDED DEVICES  * 10000018
*        THIS MESSAGE WILL BE ISSUED TO THE REQUESTING CONSOLE -      * 10200018
*               'IEE111I   NO OUTSTANDING REUQESTS'                   * 10400018
*        IF THERE ARE OUTSTANDING RPQES AND/OR UNATTENDED DEVICES THIS* 10600018
*        MESSAGE WILL BE WRITTEN                                      * 10800018
*           'IEE110I  REPLY IDS:    READY UNITS:    AVR MOUNT PENDING'* 11000018
*        WHERE THE IDS AND UNIT NUMBERS ARE PLACED IN THE APPROPRIATE * 11200018
*        PLACES. EACH MESSAGE OF THIS TYPE IS A MAXIMUM OF 72 BYTES IN* 11400018
*        LENGTH WITH MORE THAN ONE MESSAGE BEING ISSUED IF NECESSARY. * 11600018
*        IF ONLY ONE CONDITION EXISTS, INDICATIONS OF THE OTHER WILL  * 11800018
*        BE OMITTED FROM THE MESSAGE.                                 * 12000018
*                                                                     * 12200018
*EXITS-NORMAL: RETURN VIA BR 14                                       * 12400018
*      ERROR: NONE                                                    * 12600018
*                                                                     * 12800018
*EXTERNAL REFERENCES- GETMAIN                                         * 13000018
*                     FREEMAIN                                        * 13200018
*                     WTO (SVC 35)                                    * 13400018
*                     XSA (EXTENDED SAVE AREA)                     XMCS 13600018
*                                                                     * 13800018
*TABLES/WORK AREAS: IF NECESSARY, A 110A MESSAGE IS CONSTRUCTED IN AN * 14000018
*                   80 BYTE AREA OBTAINED BY A GETMAIN                * 14200018
*                                                                     * 14400018
*ATTRIBUTES: ENABLED,REENTRANT,REFRESHABLE                              14600018
*NOTES   OPERATES IN SVC TRANSIENT AREA.                           XMCS 14800018
*        DOES NOT SAVE REGISTERS.                                  XMCS 15000018
*                                                                  XMCS 15200018
*********************************************************************** 15400018
         EJECT                                                          15600018
WORK1    EQU   0                                                        15800018
WORK2    EQU   1                                                        16000018
WQEREG   EQU   1                                                  M2196 16050021
XSAREG   EQU   2    REG 2 HAS PTR TO XSA WHEN 2903D GETS CONTROL        16200018
UCBLSREG EQU   3                                                        16400018
SW1REG   EQU   4                                                        16600018
SW2REG   EQU   5                                                        16800018
MSGREG   EQU   6    USED AS PTR TO NEXT AVAILABLE SPACE IN MSG AREA     17000018
WORK3    EQU   7                                                        17200018
RQEREG   EQU   8                                                        17400018
UCBREG   EQU   8                                                        17600018
BASEREG  EQU   9                                                        17800018
MSGAD    EQU   10   HOLDS PTR TO BEGINNING OF MESSAGE AREA              18000018
SW3REG   EQU   11                                                       18200018
WTOREG   EQU   12   USED FOR BAL TO WTO ROUTINE                         18400018
WORK4    EQU   12                                                       18600018
WORK5    EQU   13                                                       18800018
EXITREG  EQU   14                                                       19000018
WORK6    EQU   15                                                       19200018
         SPACE                                                          19240018
D0       EQU   0                        USED FOR OFFSETS,LENGTHS,ETC.   19280018
D4       EQU   4                        *                               19320018
HALFWORD EQU   16                   USED TO SHIFT TJID IN         M2047 19330020
*                                      TPUT PARAMETER REG         M2047 19340020
         SPACE                                                          19360018
* THIS ROUTINE USES THREE REGISTERS AS SWITCHES: THE REGISTERS AND THE  19400018
* MEANING OF THEIR VALUES ARE AS FOLLOWS:                               19600018
*                                                                       19800018
* SW1REG  0 - NO OUTSTANDING RPQE'S                                     20000018
*         1 - AN ID HAS BEEN MOVED INTO THE MESSAGE AREA, BUT THE       20200018
*                MESSAGE HAS NOT YET BEEN ISSUED.                       20400018
*        -1 - A WTO HAS JUST BEEN ISSUED                              * 20600018
*                                                                       20800018
* SW2REG  0 - NO OUTSTANDING MOUNT MESSAGES FOR SPECIFIC UNITS          21000018
*         1 - A UNIT NUMBER HAS BEEN MOVED INTO THE MESSAGE AREA, BUT   21200018
*                THE MESSAGE HAS NOT YET BEEN ISSUED.                   21400018
*        -1 - A WTO HAS JUST BEEN ISSUED                              * 21600018
*                                                                       21800018
* SW3REG: 0 - NO AVR MOUNT MESSAGE PENDING                              22000018
*         1 - AN AVR MOUNT MESSAGE IS PENDING                           22200018
MIDMSG   EQU   1                                                        23200018
MOUNT    EQU   X'80'                                                    23800018
NOTTAPDA EQU   X'5F'                                                    24000018
DA       EQU   X'20'                                                    24200018
NOTREADY EQU   X'40'                                                    24400018
SLASH    EQU   C'/'                                                     24600018
WQEXB    EQU   X'8C'                                              M2196 24650021
         EJECT                                                          24800018
         BALR  BASEREG,0                                                25000018
         USING *,BASEREG           ESTABLISH ADDRESSABILITY             25200018
         USING XSA,XSAREG          BASE FOR XSA                    XMCS 25400018
         L     WORK1,SIZE1         GET S.P. AND SIZE             A58369 25500021
         GETMAIN R,LV=(0)          GET CORE FOR MSG AREA         A58369 25600021
         LR    MSGAD,WORK2         POINT MSGAD TO START OF MSG AREA     25800018
         LR    MSGREG,WORK2                                             26000018
         MVC   D0(D4,MSGAD),DUMYWTO     GET 1ST WORD OF WTO LIST    MCS 26200018
         SPACE 2                                                        26400018
*********************************************************************** 26600018
*    MSGAD  -  CONTAINS THE ADDRESS OF THE BEGINNING OF THE MESSAGE     26800018
*                    AREA                                               27000018
*                                                                       27200018
*    MSGREG  -  CONTAINS THE ADDRESS OF THE NEXT AVAILABLE SPACE IN     27400018
*                    THE MESSAGE AREA                                   27600018
*                                                                       27800018
*********************************************************************** 28000018
         SPACE 2                                                        28200018
         SR    SW1REG,SW1REG       SWITCH ONE IS 0: NO MSG.AT THIS PT.  28400018
         SR    SW3REG,SW3REG                                            28600018
         SPACE                                                          28800018
* A TEST IS MADE FOR OUTSTANDING RPQES. IF THERE ARE ANY, THE ID FIELD  29000018
* IS MOVED TO A MESSAGE AREA.                                           29200018
         SPACE                                                          29400018
         L     WORK4,CVTPTR             GET PTR TO CVT                  29500018
         USING CVT,WORK4                ADDRESS CVT                     29600018
         L     WORK4,CVTCUCB            GET PTR TO UCM                  29700018
         DROP  WORK4                    SET NEW BASE                    29800018
         USING DRUCM,WORK4              ADDRESSING UCM                  29900018
         L     RQEREG,UCMRPYQ           GET RQE PTR                     30000018
RQETEST  LTR   RQEREG,RQEREG            ANY REPLY QUEUE ELEMENTS        30100018
         BZ    ENDWTOR                  NO. GO SEARCH UCBS FOR AVRS     30200018
         USING DRRQE,RQEREG             ADDRESS RQE                     30300018
         L     WQEREG,RQEWQE      OBTAIN THE ASSOCIATED WQE       M2196 30350021
         LA    WQEREG,0(WQEREG)   CLEAR HIGH ORDER BYTE                 30350421
         TM    UCMMODE,UCMMCS      TEST FOR MCS                  A58369 30351021
         BO    MCS                 BRANCH YES                    A58369 30352021
         LTR   WQEREG,WQEREG       IS THERE AN ADDRESS           A58369 30353021
         BZ    TESTPRG             NO,REPLY IS OUTSTANDING       A58369 30354021
         B     NEXTRQE             YES,REPLY IS ANSWERED         A58369 30355021
MCS      EQU   *                                                 A58369 30356021
         LTR   WQEREG,WQEREG       IS THERE AN ADDRESS           A58369 30357021
         BZ    NEXTRQE             NO,NO REPLY OUTSTANDING       A58369 30358021
         L     WQEREG,WQEXB(WQEREG) OBTAIN THE WQEXB              M2196 30360021
         LTR   WQEREG,WQEREG      AN ADDRESS IN WQEXB?            M2196 30370021
         BNZ   NEXTRQE            YES, PICK UP NEXT RQE           M2196 30380021
TESTPRG  TM    RQEXA,PURGE              PURGE BIT ON IN THIS RQE        30400018
         SPACE                                                          30500018
PURGE    EQU   X'80'                                                    30600018
         SPACE                                                          30700018
         BO    NEXTRQE                  YES. SKIP IT. GET NEXT ONE.     30800018
         LTR   SW1REG,SW1REG            INITIAL PART OF MSG IN          30900018
         BNE   SETSWICH                 YES. SKIP MOVE OF MSG HDR       31000018
MOVEINIT MVC   4(21,MSGAD),MSG1CODE     MOVE IN HEADER PART OF MSG      31400018
         LA    MSGREG,25(MSGAD)    ADJUST FREE SPACE PTR                31600018
SETSWICH LA    SW1REG,MIDMSG       SW1 INDICATES MSG BEING PROCESSED    31800018
         MVC   0(2,MSGREG),RQEID        PUT REPLY ID IN MSG             32000018
         LA    MSGREG,2(MSGREG)    INCREMENT FREE SPACE PTR.            32200018
         SR    MSGREG,MSGAD        NUMBER OF BYTES USED IN MSG.         32400018
         CH    MSGREG,NOROOMID     IS THERE ROOM FOR ANOTHER ID?        32600018
         BL    ROOMLEFT                 YES. GO LOOK FOR MORE RQES      32800018
         BAL   WTOREG,WTO          GO WRITE OUT MSG                     33000018
         LNR   SW1REG,SW1REG       MAKE NEG. TO SHOW WTO JUST ISSUED    33200018
         LA    MSGREG,25(MSGAD)    POINT TO NEXT FREE SPACE IN AREA     33400018
         B     NEXTRQE             GO TO GET NEXT RPQE                  33600018
ROOMLEFT AR    MSGREG,MSGAD        RESTORE FREE SPACE POINTER           33800018
         MVC   0(2,MSGREG),BLANKS  FOLLOW ID BY BLANKS                  34000018
         LA    MSGREG,2(MSGREG)    POINT TO NEXT FREE SPACE             34200018
NEXTRQE  L     RQEREG,RQELKP            GET PTR TO NEXT RQE             34400018
         B     RQETEST                  GO SEE IF THERE ARE ANY MORE    34600018
ENDWTOR  LTR   SW1REG,SW1REG       ANY MSGS ISSUED OR BEING PROCESSED?  35000018
         BZ    UCBSRCH             BRANCH DIRECTLY TO UCB SEARCH IF NO  35200018
         BP    TESTROOM            MSG BEING PROCESSED; GO CHECK SPACE  35400018
         LA    MSGREG,13(MSGAD)    POINT TO NEXT FREE SPACE             35600018
         B     UCBSRCH             START UCB SEARCH                     35800018
TESTROOM SR    MSGREG,MSGAD        NUMBER OF BYTES USED IN MESSAGE      36000018
         CH    MSGREG,NOROOMA      ENOUGH ROOM FOR POSSIBLE UNIT MSG.?  36200018
         BC    12,ADJMSGRG       YES,ADJUST PTR. START UCB SCAN A34862  36400020
         BAL   WTOREG,WTO          GO WRITE OUT MESSAGE                 36600018
         LNR   SW1REG,SW1REG       MAKE NEG. TO SHOW WTO JUST ISSUED    36800018
         LA    MSGREG,13(MSGAD)    POINT AT NEXT FREE SPACE             37000018
         B     UCBSRCH             START UCB SEARCH                     37200018
ADJMSGRG AR    MSGREG,MSGAD        RESTORE POINTER TO NEXT FREE SPACE   37400018
UCBSRCH  SR    SW2REG,SW2REG       SWITCH 2 IS 0:NO UNIT MSGS YET       37600018
         L     WORK4,CVTPTR             GET CVT ADDRESS                 37700018
         DROP  WORK4                    WAS ADDRESSING UCM              37800018
         USING CVT,WORK4                ADDRESS CVT                     37900018
         L     UCBLSREG,CVTILK2         ADDR OF 2-BYTE UCB PTRS         38000018
DUMYTEST CLC   0(2,UCBLSREG),ZERO  IS THIS A DUMMY UCB?                 38200018
         BE    NEXTUCB             IF YES,SKIP AND GET NEXT ONE         38400018
         LH    UCBREG,0(UCBLSREG)  GET UCB ADDRESS                      38600018
         N     UCBREG,ZEROFOX     ZERO OUT PROPAGATED BITS              38800018
         C     UCBREG,ZEROFOX     END OF LIST                           39000018
         BE    AVRTEST             GO CHECK FOR AVR MSGS IF YES         39200018
         USING UCB,UCBREG                                               39400018
         EX    R0,MOVENAME         IS THIS A DATA CELL           A58369 39600021
         BE    DEV2321             BRANCH IF YES                        39800018
         TM    UCBTBYT3,NOTTAPDA      DEVICE TAPE OR DIRECT ACCESS?     40000018
         BNE   NEXTUCB                  NO. SKIP IT. GET NEXT ONE.      40200018
         TM    SRTEDMCT,MOUNT      MOUNT MSG. PENDING?                  40400018
         BZ    TESTATTN            NO, TEST ATTENTION BYTE              40600018
         CLI   UCBTBYT3,DA         IS DEVICE DA                         40800018
         BE    TSTSWICH            BRANCH TO SET UP MESSAGE IF IT IS    41000018
         TM    SRTESTAT,SRTEALOC  IS UNIT CURRENTLY ALLOCATED    22909  41060019
         BZ    TESTATTN           NO, TEST ATT. TABLE INDEX      22909  41120019
         TM    UCBFL2,NOTREADY     IS DEVICE READY?                     41200018
         BZ    NEXTUCB             GET NEXT UCB IF IT ISN'T             41400018
TSTSWICH LTR   SW2REG,SW2REG       IS SWITCH TWO 0                      41600018
         BZ    SETUPUM             SET UP UNIT MESSAGE IF ZERO          41800018
SETSWIH2 LA    SW2REG,MIDMSG       SW2 INDICATES MSG BEING PROCESSED    42000018
* THE FOLLOWING RTN CHECKS FOR DUPLICATE UNIT NAMES IN CASE OF A TWO    42200018
* CHANNEL SWITCH.                                                       42400018
DUPNAMRT L     WORK2,CVTPTR       GET CVT ADDRESS                A53046 42450021
         DROP  WORK4                                             A53046 42500021
         USING CVT,WORK2          ADDRESS CVT                    A53046 42550021
         L     WORK2,CVTILK2      GET UCB LIST ADDRESS           A53046 42600021
CHKZERO  CLC   0(2,WORK2),ZERO    IS IT A DUMMY UCB              A53046 42650021
         BE    GETNEXT            IF SO, SKIP IT                 A53046 42700021
         LH    WORK1,0(WORK2)     GET UCB ADDRESS                A53046 42750021
         N     WORK1,ZEROFOX      ZERO OUT PROPAGATED BITS              43500018
         CR    WORK1,UCBREG        DO UCB ADDRESSES MATCH               43600018
         BE    MATCH               IF SO, GO CHECK LIST ADDRESSES       43800018
         C     WORK1,ZEROFOX      END OF LIST                           43860018
         BE    MOVENAME           NO DUPE NAMES...MOVE IN UCB NUMBER    43920018
GETNEXT  EQU   *                                                 A53046 44000021
         LA    WORK2,2(WORK2)     POINT TO NEXT LIST ENTRY       A53046 44050021
         B     CHKZERO             AND GO CHECK FOR DUMMY UCB           44200018
MATCH    EQU   *                                                 A53046 44400021
         CR    WORK2,UCBLSREG     COMPARE LIST ADDRESSES         A53046 44450021
         BNE   NEXTUCB                                                  44500018
MOVENAME EQU   *                                                 A53046 44600021
         CLC   UCBTBYT3(2),DTACEL IS THIS A DATA CELL?           A53046 44650021
         BE    DCELPEND           BRANCH IF YES                  A53046 44700021
         MVC   0(3,MSGREG),UCBNAME MOVE IN UNIT NUMBER           A53046 44750021
         LA    MSGREG,3(MSGREG)    INCREMENT FREE SPACE PTR.            44800018
         SR    MSGREG,MSGAD        NUMBER OF BYTES USE IN MSG.          45000018
         CH    MSGREG,NOROOMUN     ENOUGH ROOM FOR ANOTHER UNIT?        45200018
         BL    MOREROOM                 YES.                            45400018
         BAL   WTOREG,WTO          GO WRITE OUT MSG                     45600018
         SR    SW2REG,SW2REG       NOTE - WTO RTN CLOBBERS THIS REG     45700018
         BCTR  SW2REG,0            MAKE NEG TO SHOW WTO JUST ISSUED     45800018
         EX    R0,MOVERDY          MOVE IN 'READY UNITS: '       A58369 46000021
         LA    MSGREG,27(MSGAD)    POINT TO NEXT FREE SPACE             46200018
         B     NEXTUCB             GO GET NEXT UCB'S ADDRESS            46400018
MOREROOM AR    MSGREG,MSGAD        RESTORE FREE SPACE POINTER           46600018
         EX    R0,EXCODE1          FOLLOW UNIT # BY BLANKS              46800021
         LA    MSGREG,2(MSGREG)    POINT TO NEXT FREE SPACE             47000018
         B     NEXTUCB             GO GET NEXT UCB'S ADDRESS            47200018
TESTATTN CLI   UCBATI,X'0C'        IS ATTN TAB INDEX SET FOR AVR A39479 47400020
         BNE   DAVV                CHECK DAVV ISSUED             A39479 47600020
         LA    SW3REG,1            INDICATE AVR MOUNT PENDING           47800018
         B     NEXTUCB             GET NEXT UCB'S ADDR           A39479 47850020
DAVV     CLI   UCBTBYT3,DA         IS DEVICE DA                  A39479 47900020
         BNE   NEXTUCB             NO- GET NEXT UCB              A39479 47950020
         TM    UCBFL4,UCBMNT       DAVV ISSUED                   A39479 48000020
         BO    TSTSWICH            YES- PUT OUT READY UNIT MSG   A39479 48050020
NEXTUCB  LA    UCBLSREG,2(UCBLSREG) PT TO NEXT ENTRY IN UCB LIST A39479 48100020
         B     DUMYTEST            BRANCH TO HANDLE IT                  48200018
SETUPUM  LTR   SW1REG,SW1REG       INITIAL PART IN MESSAGE              48400018
         BC    7,INITIN            BRANCH IF YES                        48600018
         MVC   4(9,MSGAD),MSG1CODE     MOVE IN HEADER CODE              48800018
         EX    R0,MOVERDY          MOVE IN 'READY UNITS: '       A58369 49000021
         LA    MSGREG,27(MSGAD)    POINT TO NEXT FREE SPACE             49200018
         B     SETSWIH2            GO SET SW2 THAT MSG BEING PROCESSED  49400018
INITIN   MVC   0(14,MSGREG),RDYUNITS   MOVE IN READY UNITS:  '          49600018
         LA    MSGREG,14(MSGREG)   POINT TO NEXT FREE SPACE             49800018
         B     SETSWIH2            GO SET SW2 THAT MSG BEING PROCESSED  50000018
DEV2321  LA    WORK5,10            LOOP CONTROL                         50200018
         LA    WORK3,DATACELL      ESTABLISH SUB-UCB ADDRESSABILITY     50400018
         USING DATACELL,WORK3                                           50600018
DCELTEST TM    DCELDMCT,MOUNT      MOUNT MSG PENDING?                   50800018
         BC    7,DUPNAMRT          BRANCH IF YES TO CHECK FOR    A53046 51000021
*                                      DUPLICATE UNIT NAMES IN   A53046 51100021
*                                      CASE OF TWO CHANNEL       A53046 51150021
*                                      SWITCH ON DATA CELL       A53046 51160021
NEXTBIN  LA    WORK3,16(WORK3)     POINT TO NEXT BIN                    51200018
         BCT   WORK5,DCELTEST          BRANCH IF MORE BINS TO TEST      51400018
         B     NEXTUCB             IF NOT, GO GET NEXT UCB              51600018
DCELPEND LTR   SW2REG,SW2REG       FIRST TIME FOR UNIT MSG?             51800018
         BC    8,TESTONE           BRANCH IF YES                        52000018
         SR    MSGREG,MSGAD        GET NMBR BYTES USED IN MSG SO FAR    52200018
         CH    MSGREG,NORUMDCL     ROOM FOR DATA CELL ENTRY?            52400018
         BC    4,NUFROOMA          BRANCH IF YES                        52600018
NOTENUF  BAL   WTOREG,WTO          GO WRITE OUT MESSAGE                 52800018
MOVERDY  MVC   13(14,MSGAD),RDYUNITS    MOVE IN 'READY UNITS0  '        53000018
         LA    MSGREG,27           POINT TO NEXT FREE SPACE             53200018
NUFROOMA AR    MSGREG,MSGAD        POINT AT NEXT FREE SPACE             53400018
         MVC   0(3,MSGREG),UCBNAME    MOVE IN UNIT NUMBER               53600018
         MVI   3(MSGREG),SLASH                                          53800018
         MVC   4(1,MSGREG),DCELBBNR+1   MOVE IN BIN NUMBER              54000018
         OI    4(MSGREG),X'F0'     CONVERT IT TO EBCDIC                 54200018
         LA    MSGREG,5(MSGREG)    POINT AT NEXT FREE SPACE             54400018
         SR    MSGREG,MSGAD        # OF BYTES IN MSG AREA               54600018
         CH    MSGREG,NOROOMUN     ROOM LEFT FOR ANOTHER UNIT NUMBER?   54800018
         BC    4,NUFROOMB          BRANCH IF YES                        55000018
         BAL   WTOREG,WTO          GO WRITE MSG                         55200018
         EX    R0,MOVERDY          MOVE IN 'READY UNITS: '       A58369 55400021
         LA    MSGREG,27(MSGAD)    POINT TO NEXT FREE SPACE             55600018
         SR    SW2REG,SW2REG       NOTE - WTO RTN CLOBBERS THIS REG     55700018
         BCTR  SW2REG,0            MAKE NEG TO SHOW WTO JUST ISSUED     55800018
         B     NEXTBIN             GO CHECK NEXT BIN                    56000018
NUFROOMB AR    MSGREG,MSGAD                                             56200018
EXCODE1  MVC   0(2,MSGREG),BLANKS                                       56400021
         LA    MSGREG,2(MSGREG)    POINT TO NEXT FREE SPACE             56600018
         LA    SW2REG,MIDMSG       INDICATE MSG. BEING PROCESSED        56800018
         B     NEXTBIN             GO CHECK NEXT BIN                    57000018
TESTONE  LTR   SW1REG,SW1REG       IS HEADER PART OF MSG IN             57200018
         BC    7,INITINB           YES, GO MOVE IN 'READY UNITS0  '     57400018
         EX    R0,EXCODE2          NO, MOVE IN 'IEE110A  '              57600021
         B     MOVERDY                                                  57800018
INITINB  MVC   0(14,MSGREG),RDYUNITS   MOVE IN 'READY UNITS:  '         58000018
         LA    MSGREG,14(MSGREG)   POINT TO NEXT FREE SPACE             58200018
         SR    MSGREG,MSGAD        GET NUMBER OF MSG BYTES USED SO FAR  58400018
         CH    MSGREG,NORUMDCL         ENOUGH ROOM FOR DATA CELL ENTRY  58600018
         BC    12,NUFROOMA         BRANCH IF YES                        58800018
         SH    MSGREG,FOURTEEN       GET NUMBER OF BYTES IN MSG.        59000018
         B     NOTENUF             GO WRITE OUT MESSAGE                 59200018
AVRTEST  LTR   SW3REG,SW3REG       AVR MOUNT MSG PENDING?               59400018
         BC    8,TSTFORNO          BRANCH IF NO                         59600018
         LTR   SW2REG,SW2REG       ANY UNIT MESSAGES?                   59800018
         BC    8,TSTIDMSG          BRANCH IF NO                         60000018
         BP    SPACTEST            MSG BEING PROCESSED; GO CHECK SPACE  60200018
MOVEAVR  MVC   13(17,MSGAD),AVRMSG                                      60400018
         LA    MSGREG,30           LENGTH OF AVR MESSAGE                60600018
GOWRITE  BAL   WTOREG,WTO          GO WRITE OUT MESSAGE                 60800018
         B     RETURN                                                   61000018
TSTIDMSG LTR   SW1REG,SW1REG       ANY ID MESSAGES?                     61200018
         BM    MOVEAVR             WTO ISSUED; GO MOVE IN AVR MSG       61400018
         BP    SPACTEST            MSG BEING PROCESSED; GO CHECK SPACE  61600018
EXCODE2  MVC   4(9,MSGAD),MSG1CODE MOVE IN HEADER CODE                  61800021
         B     MOVEAVR                                                  62000018
SPACTEST SR    MSGREG,MSGAD        # OF BYTES IN MSG AREA               62200018
         CH    MSGREG,NORUMAVR     IS THERE ENOUGH ROOM FOR THE AVR MSG 62400018
         BC    4,SAMEMSG           BRANCH IF YES                        62600018
         BAL   WTOREG,WTO          GO WRITE OUT MSG                     62800018
         B     MOVEAVR                                                  63000018
SAMEMSG  AR    MSGREG,MSGAD        RESTORE FREE SPACE POINTER           63200018
         MVC   0(17,MSGREG),AVRMSG MOVE IN 'AVR MOUNT PENDING'          63400018
         LA    MSGREG,17(MSGREG)   POINT TO NEXT FREE SPACE             63600018
         SR    MSGREG,MSGAD        LENGTH OF MESSAGE AREA               63800018
         B     GOWRITE             GO WRITE OUT MSG                     64000018
TSTFORNO LTR   SW2REG,SW2REG       ANY UNIT MESSAGES                    64200018
         BZ    TSTSW1              IF NO, BRANCH TO CHECK FOR WTOR MSGS 64400018
         BM    RETURN              MSG WRITTEN; GO TO EXIT ROUTINE      64600018
         SR    MSGREG,MSGAD        GET NUMBER OF BYTES USED IN MSG AREA 64800018
         B     GOWRITE             GO WRITE OUT MESSAGE                 65000018
TSTSW1   LTR   SW1REG,SW1REG       ANY WTOR MESSAGES?                   65200018
         BZ    NONEMSG             BRANCH IF NO                         65400018
         BM    RETURN              MSG WRITTEN; GO TO EXIT ROUTINE      65600018
         SR    MSGREG,MSGAD        NUMBER OF BYTES IN MSG. AREA         65800018
         BAL   WTOREG,WTO          GO WRITE OUT MSG                     66000018
RETURN   LR    WORK2,MSGAD                                              66200018
         L     WORK1,SIZE1         GET SIZE AND S.P.             A58369 66250021
         FREEMAIN R,LV=(0),A=(1)   FREE MSG AREA                 A58369 66350021
         BR    EXITREG             RETURN                               66600018
NONEMSG  EQU   *                        NO OUTSTANDING REQUESTS         66700018
         MVC   0(LN,MSGAD),NOREQMSG     MOVE MSG INTO GOTTEN CORE       66800018
         LH    MSGREG,0(MSGAD)          GET LENGTH OF MESSAGE     20030 66900020
         BAL   WTOREG,WTOWRITE     GO WRITE IEE111I MSG                 67000018
         B     RETURN                                                   67200018
*********************************************************************** 67400018
*                                                                       67600018
*              THIS ROUTINE WRITES OUT THE MESSAGE AREA                 67800018
*                                                                       68000018
**********************************************************************  68200018
WTO      STH   MSGREG,0(MSGAD)     PUT LENGTH IN MSG. AREA              68400018
         LA    SW2REG,0(MSGAD,MSGREG)    POINT TO END OF MSG            68800018
         MVC   0(4,SW2REG),DUMYWTO+8     MOVE IN DESC AND RTE FIELDS    69000018
WTOWRITE EQU   *                                                        69060020
         CLC   XAJ(D2),ZERO        IS IT A TERMINAL REQUEST      A58369 69120021
         BNZ   TPUTMSG             YES, GO TO PUT MSG TO TERMINAL 20030 69210020
         SR    WORK1,WORK1         CLEAR REG FOR INSERT CHARACTER 20030 69300020
         IC    WORK1,XAU           SET CONSOLE ID PTR                   69400018
         WTO   MF=(E,(MSGAD))           WRITE MESSAGE                   69600018
         BR    WTOREG              RETURN TO CALLER                     69800018
TPUTMSG  EQU   *                                                        69805020
         LA    R1,D4                DECREMENT LENGTH OF MSG BY    M2047 69810020
         SR    MSGREG,R1               FOUR FOR WTO HEADER        M2047 69815020
         LR    R0,MSGREG                                                69820020
TPUT2    EQU   *                                                  20030 69825020
         LA    R1,4(MSGAD)         GET ADDR O MSG TEXT            20030 69830020
         LH    MSGREG,XAJ          GET TJID                       20030 69835020
         SLL   MSGREG,HALFWORD      GET TJID INTO BYTES 0,1       M2047 69845020
         OR    R0,MSGREG               OF PARAMETER REGISTER            69855020
         TPUT  (1),(0),R            PUT MESSAGE TO TERMINAL             69865020
         BR    WTOREG              RETURN TO CALLER                     69885020
D2       EQU   2                                                        69945020
R0       EQU   0                                                        69975020
R1       EQU   1                                                        69980020
R2       EQU   2                                                        69985020
         SPACE 5                                                        70000018
NOROOMID DC    H'73'                                                    70600018
NOROOMA  DC    H'63'                                            A34862  70800020
NORUMDCL EQU   *                                                        71000018
NOROOMUN DC    H'72'                                                    71200018
NORUMAVR DC    H'59'                                                    71400018
FOURTEEN DC    H'14'                                                    71600018
         DS    0F                                                       71800018
ZERO     EQU   *                                                        71900018
ZEROFOX DC    X'0000FFFF'                                               72000018
SIZE1    DC    X'FF000058'         SIZE AND S.P. FOR GETMAIN     A58369 72100021
BLANKS   DC    2X'40'                                                   72200018
DUMYWTO  WTO   '    ',MF=L,DESC=(5),MCSFLAG=(REG0,RESP)            XMCS 72400018
DTACEL   DC    X'2005'                                                  72600018
MSG1CODE DC    C'IEE110I  '                                             72800018
         DC    C'REPLY IDS:  '                                          73000018
RDYUNITS DC    C'READY UNITS:  '                                        73200018
AVRMSG   DC    C'AVR MOUNT PENDING'                                     73400018
NOREQMSG WTO   'IEE111I NO OUTSTANDING REQUESTS',MF=L,DESC=(5),    XMCS*73600018
               MCSFLAG=(REG0,RESP)                                 XMCS 73800018
LN       EQU   *-NOREQMSG               TOTAL MSG BUFFER LENGTH         73900018
CVT      DSECT                                                          74000018
         CVT                                                            74200018
         IEEBASEA                                                       74400018
UCB      DSECT                                                          74600018
         IEFUCBOB                                                       74800018
         EJECT                                                          74820018
DRUCM    DSECT                                                          74840018
         IEECUCM                                                        74860018
         EJECT                                                          74880018
DRRQE    DSECT                                                          74900018
         IEECVMUG RQE                                                   74920018
         EJECT                                                          75000018
XSAMAP   DSECT                                                          75200018
         IEEXSA                                                         75400018
         END                                                            75600018
