         TITLE 'IEE40110  IGC40110   DISPLAY PFK'                       00062021
IEE40110 CSECT                                                          00064021
* /* START OF SPECIFICATIONS ****                                       00064421
*02*  PROCESSOR = ASSEMBLER;                                            00064821
**** END OF SPECIFICATIONS ***/                                         00065221
*/*IEE40110: CHART */                                                   00065621
*/*HEADER                                                               00065721
*/*     CHART ??   IEE40110  IGC40110                   DISPLAY PFK     00065821
*/*                                           PAGE #                */  00065921
*/*  E  IEE40110 */                                                     00067021
         EJECT                                                          00068921
* STATUS                                                                00070021
*    CHANGE LEVEL 0                                                     00071121
*    CREATED FOR RELEASE 21, LINE ITEM S21003.                          00072221
*                                                                       00072621
* FUNCTION                                                              00073321
*    THIS ROUTINE PROVIDES A DISPLAY SHOWING THE CURRENT DEFINITIONS    00074421
*    OF ALL PFKS WHICH WERE ALLOCATED AT SYSGEN IN RESPONSE TO AN       00075521
*    OPERATOR COMMAND OF 'D PFK'                                        00076621
*                                                                       00077721
* ENTRY POINTS                                                          00078821
*         IEE40110 FOR ALL FUNCTIONS                                    00079921
*         ENTERED FROM IGC00110 (IEE00110).                             00089921
*                                                                       00091921
* OPERATION                                                             00093221
*    IF THE PFK AREA DOES NOT EXIST AN INFORMATION MESSAGE IS SENT      00095221
*    TO THE OPERATOR.  IF THE AREA DOES EXIST THE KEYS ARE              00095621
*    EXAMINED ONE AT A TIME, FORMATTED AND WRITTEN TO THE SCREEN        00096021
*    USING THE MULTIPLE LINE FACILITY OF WTO.                           00096421
*                                                                       00123121
* INPUT                                                                 00123221
*    A CSCB CONTAINING THE OPERATOR COMMAND (WHICH IS NOT SCANNED,      00123321
*    BUT IS OVERLAYED AND USED AS A WORKAREA) AND THE PFK AREA          00124421
*    POINTED TO BY THE RESIDENT DCM.                                    00126421
*                                                                       00129721
* OUTPUT                                                                00131721
*    MESSAGE IEE724I WHICH CONSISTS OF UP TO 26 LINES OF PFK            00131821
*    DEFINITIONS.                                                       00131921
*    MESSAGE IEE720I IF THE DEVICE HAS NO PFKS ALLOCATED.               00132021
*    MESSAGE IEE921I IF MCS IS NOT IN THE SYSTEM.                       00132121
*                                                                       00132321
* EXTERNAL REFERENCES                                                   00136621
*         MACROS USED: TIME, WTO, XCTL.                                 00136721
*                                                                       00138721
* EXITS, NORMAL                                                         00140721
*         IGC00110 VIA XCTL WHEN WORK IS COMPLETE.                      00141121
*                                                                       00144821
* EXITS, ERROR                                                          00145221
*         NONE.                                                         00145621
*                                                                       00147621
* TABLES/WORK AREAS                                                     00148021
*    THE CSCB POINTED TO BY REGISTER 2. (SEE DSECT AT END OF            00148421
*    LISTING).  THE PFK AREA POINTED TO BY THE RESIDENT DCM             00148521
*    FOR THE REQUESTING CONSOLE.                                        00148621
*                                                                       00148821
* ATTRIBUTES                                                            00149221
*    REFRESHABLE, PRIVILEGED, TYPE 4 SVC.                               00149621
*                                                                       00149721
* CHARACTER CODE DEPENDENCY                                             00149821
*    THE EQUATE 'ZONE' MUST REFLECT THE ZONE OF DECIMAL DIGITS.         00149921
*                                                                       00153621
* NOTES                                                                 00155621
*    THE FOLLOWING FLAG BITS ARE USED:                                  00156021
*       THE ACTION COLUMN INDICATES WHETHER THE BIT IS TURNED ON, OFF   00156121
*       OR JUST TESTED BY THIS MODULE.                                  00156221
*                                                                       00156321
*         NAME         ACTION                 FUNCTION                  00156721
*       UCMMODE                                                         00156821
*        UCMMCS      TEST          MCS IS IN SYSTEM                     00156921
*       PFK AREA                                                        00157021
*        DCMPFKCN    TEST          KEY IS CONVERSATIONAL MODE           00160621
*        DCMPFKDF    TEST          KEY IS DEFINED                       00162621
*        DCMPFKKY    TEST          KEY IS A LIST OF KEYS                00164621
*                                                                       00164821
*********************************************************************** 00168421
  EJECT                                                                 00172021
*          REGISTER EQUATES                                             00175621
CLOCK    EQU   0                   VALUE RETURNED BY TIME MACRO         00179221
WTOPT    EQU   0                   POINTER TO WTO TEXT                  00182821
WTOIDOUT EQU   1                   MLWTO ID FROM SVC 34                 00186421
CSCB     EQU   2                   POINTER TO CSCB                      00190021
PARM3    EQU   3                   XSA POINTER ON ENTRY                 00190121
UCMBASE  EQU   3                   UCM BASE REGISTER (TEMPORARY)        00190221
DCMBASE  EQU   3                   DCM BASE REGISTER                    00190321
RET      EQU   3                   SUBROUTINE RETURN REGISTER           00190421
POINT    EQU   4                   CHAINING POINTER (VARIABLE)          00196021
BACKSCAN EQU   4                   USED TO FIND LAST TEXT CHAR          00198021
WORK5    EQU   5                   WORK REGISTER                        00198421
APFK     EQU   6                   POINTER TO PFK AREA                  00198821
INSCAN   EQU   7                   SCANS LIST OF KEYS IN AREA           00199221
ID       EQU   8                   CONSOLE ID                           00199621
COUNT    EQU   9                   LOOP CONTROL                         00199721
OUTSCAN  EQU   10                  OUTPUT PTR FOR LIST OF KEYS          00199821
XSAREG   EQU   11                  XSA BASE REGISTER                    00215921
PROGBASE EQU   12                  PROGRAM BASE REGISTER                00216621
SAVEAREA EQU   13                  PTR TO MAINLINE SAVE AREA            00226621
RETURN   EQU   14                  RETURN REGISTER                      00228621
ENTRY    EQU   15                  ENTRY POINT REGISTER                 00230621
COMPARE  EQU   15                  COMPARE REG FOR LINE LENGTH          00231021
         EJECT                                                          00232621
         BALR  PROGBASE,N0         SET BASE ADDRESS                     00233321
         USING *,PROGBASE          AND TELL ASSEMBLER                   00250021
         USING CSCBSECT,CSCB                                            00260021
* NOTE  CSCB ADDRESS WAS PASSED IN REG 2                                00270021
         B     ICATCH              BRANCH AROUND EYECATCHER             00300021
         DC    C'   MODULE IGC40110, FICHE IEE40110  '   EYECATCHER AND 00350021
ZAPAREA  DC    12C'ZAP'               RESERVED FOR FIELD MODIFICATIONS  00350421
ICATCH   LR    XSAREG,PARM3        SAVE XSA POINTER                     00352021
         USING PSXA,XSAREG                                              00354021
* NOTE  XSA ADDRESS WAS PASSED IN REG 3                                 00356021
         STM   SAVEAREA,WTOIDOUT,CSCBSAVE    SAVE REGS                  00360021
         NI    FLAGS,N0            ZERO FLAG BYTE                       00370021
         SR    WORK5,WORK5         CLEAR WORK                           00410021
         SR    ID,ID                  REGISTERS                         00420021
         SPACE 5                                                        00422021
*/*%START: P           SET UP BASE REGISTERS */                         00430021
*****************************************************************       00440021
         L     POINT,CVTADDR       GET CVT POINTER                      00450021
         USING CVTDSECT,POINT                                           00460021
         L     POINT,CVTCUCB       GET UCM POINTER                      00500021
         DROP  POINT                                                    00550021
         IC    ID,CHUCMP           GET CONSOLE ID                       00650021
         LR    WORK5,ID                                                 00700021
         LR    WTOPT,ID            POINT WTO TO CONSOLE                 00710021
         BCTR  WORK5,N0            SUBTRACT ONE FOR LATER MULTIPLY      00750021
         USING PMUCM,POINT                                              00800021
         MVC   PREFIX,HEADER       MOVE PREFIX INTO WORKAREA            00802021
         MVI   LINTYPE,NONE        SET UP FOR STANDARD WTO              00804021
         SPACE 5                                                        00804421
*/*%MCSTST: D (NO,NOMCS,YES,)          IS MCS IN THE SYSTEM? */         00806021
*****************************************************************       00808021
         TM    UCMMODE,UCMMCS      IS MCS IN SYSTEM                     00810021
         BNO   NOMCS                NO, WRITE ERROR MESSAGE             00820021
         EJECT                                                          00822021
*/*  P                             LOCATE REQUESTING CONSOLE */         00830021
*****************************************************************       00840021
         LM    UCMBASE,POINT,UCMVEA YES, GET ENTRY AND LENGTH POINTERS  00850021
         DROP  POINT                                                    00860021
         MR    POINT,POINT         INDEX TO CORRECT CONSOLE             00900021
* NOTE  THIS MULTIPLIES POINT (LENGTH) BY WORK5 (ID) TO                 00950021
*       OBTAIN INDEX IN WORK5.                                          00960021
         AR    UCMBASE,WORK5       PLUS ENTRY EQUAL UCM ENTRY           01000021
         USING UCMLIST,UCMBASE                                          01010021
         SPACE 5                                                        01012021
*/*  D (NO,MSG1,YES,)              IS IT A GRAPHICS CONSOLE? */         01014021
*****************************************************************       01016021
         NC    UCMXB,UCMXB         IS THIS A GRAPHICS CONSOLE           01020021
         BZ    MSG1                 NO, ISSUE MESSAGE                   01030021
         SPACE 5                                                        01032021
*/*  D (NO,MSG1,YES,)              ANY PFKS ALLOCATED? */               01034021
*****************************************************************       01036021
         L     DCMBASE,UCMXB        YES, LOAD RESIDENT DCM POINTER      01040021
         DROP  UCMBASE                                                  01042021
         USING RESDCM,DCMBASE                                           01042421
         L     APFK,DCMADPFK       POINT TO PFK AREA                    01100021
         LTR   APFK,APFK           ARE ANY KEYS ALLOCATED               01150021
         BZ    MSG1                 NO, ISSUE MESSAGE                   01200021
         DROP  DCMBASE                                                  01300021
         SH    APFK,PFKLGTH        BACK UP 1 PSEUDO AREA                01802021
         MVC   TEXT(L'MSGID),MSGID MOVE IN MESSAGE ID                   01804421
         EJECT                                                          01804821
*/*  S  TIME:     PACKED DECIMAL */                                     01805221
*****************************************************************       01805621
         TIME  DEC                 GET TIME                             01806021
* NOTE  TIME RETURNED IN REG 0 AS PACKED DECIMAL                        01808021
         SPACE 5                                                        01808121
*/*  P                             BUILD CONTROL LINE */                01830021
*****************************************************************       01840021
         ST    CLOCK,TEXT+N8       STORE PACKED DECIMAL TIME            01852121
         UNPK  TEXT+N10(N7),TEXT+N8(N4) UNPACK IT                       01874021
         MVI   TEXT+N16,BLANK      BLANK FRACTIONAL SECONDS             01884021
         MVC   TEXT+N9(N4),TEXT+N10     SHIFT HOURS LEFT                01938021
         MVC   TEXT+N8(N2),TEXT+N9 SHIFT MINUTES LEFT                   01970021
         MVI   TEXT+N10,PERIOD     ADD IN                               02002021
         MVI   TEXT+N13,PERIOD        PUNCTUATION                       02034021
         MVC   TEXT+N19(L'CONTROL),CONTROL    MOVE IN CONTROL LINE TEXT 02066021
         MVI   LINTYPE,CTRLINE     SET LINE TYPE FLAG                   02098021
         LR    WTOPT,ID            REFRESH ID POINTER                   02108021
         SPACE 5                                                        02118021
*/*  S   SUBROUT:                  WRITE CONTROL LINE */                02128021
*****************************************************************       02128421
         BAL   RET,SUBROUT         GO TO WRITE THE CONTROL LINE         02130021
         SPACE 5                                                        02140021
*/*  P                             BUILD TITLE LINE */                  02150021
*****************************************************************       02160021
         MVC   TEXT(L'TITLE),TITLE MOVE IN TITLE LINE                   02162021
         MVI   LINTYPE,TITLINE       SET LINE TYPE FLAG                 02194021
         SPACE 5                                                        02204021
*/*LOOP: D (YES,ENDFLAG,NO,)      IS THIS THE LAST LINE? */             02214021
*****************************************************************       02224021
LOOP     CLI   PFKLGN(APFK),STOPPER     IS NEXT KEY A STOPPER           02226021
* NOTE  IT CANNOT BE ON FIRST PASS                                      02258021
         BE    ENDFLAG              YES, GO TO MARK LAST LINE           02290021
         SPACE 5                                                        02300021
*/*  S   SUBROUT:                  WRITE NEXT LINE */                   02310021
*****************************************************************       02320021
         BAL   RET,SUBROUT         WRITE NEXT LINE                      02322021
         MVI   LINTYPE,DATA        SET LINE TYPE TO DATA LINE           02354021
         SPACE 5                                                        02364021
*/*  P                         POINT TO NEXT KEY AREA */                02374021
*****************************************************************       02384021
         LA    APFK,PFKLGN(APFK)   POINT TO NEXT KEY                    02386021
         SPACE 5                                                        02418021
*/*  P                 CONVERT KEY # AND MOVE TO LINE */                02420021
*****************************************************************       02422021
         SR    WORK5,WORK5         CLEAR REGISTER                       02428021
         IC    WORK5,N0(APFK)      GET KEY NUMBER                       02450021
         CVD   WORK5,PACK          CONVERT TO DECIMAL                   02500021
         UNPK  PACK,CVBIN          UNPACK IT                            02510021
         OI    PACK+N3,ZONE        INSERT EBCDIC ZONE                   02550021
         MVC   TEXT+N2(N2),PACK+N2 MOVE KEY NUMBER TO LINE              02600021
         SPACE 5                                                        02610021
*/*  D (NO, NOTDEF,YES,)            IS KEY DEFINED? */                  02620021
*****************************************************************       02630021
         TM    N1(APFK),DCMPFKDF   IS KEY DEFINED                       02650021
         BNO   NOTDEF               NO, MOVE IN MESSAGE                 02700021
         EJECT                                                          02710021
*/*  D (YES,CONVERS,NO,)         IS KEY CON- VERSATIONAL? */            02720021
*****************************************************************       02730021
         TM    N1(APFK),DCMPFKCN   IS KEY CONVERSATIONAL                02750021
         BO    CONVERS              YES, GO TO INDICATE SO              02800021
         SPACE 5                                                        02810021
*/*  P (,TESTYPE)                 MOVE IN 'NO' */                       02820021
*****************************************************************       02830021
         MVC   TEXT+N7(L'NO),NO     NO, INDICATE SO                     02850021
         B     TESTYPE             GO SEE IF KEY IS A LIST              02900021
         SPACE 5                                                        02910021
*/*CONVERS: P                     MOVE IN 'YES' */                      02920021
*****************************************************************       02930021
CONVERS  MVC   TEXT+N7(L'YES),YES  INDICATE CONV MODE                   02950021
         SPACE 5                                                        02960021
*/*TESTYPE: D (YES,KEYLIST,NO,)   IS THIS A LIST OF KEYS? */            02970021
*****************************************************************       02980021
TESTYPE  TM    N1(APFK),DCMPFKKY   IS THIS A LIST OF KEYS               03000021
         BO    KEYLIST              YES, GO TO FORMAT IT                03050021
         SPACE 5                                                        03060021
*/*TEXTCOM: P                 MOVE IN ONE LINE OF TEXT */               03070021
*****************************************************************       03080021
TEXTCOM  EQU   *                                                        03100021
         CLC   TEXT+N13(PFKLIN/2),PFKLIN/2+N2(APFK)                     03250021
*                                  IS SECOND HALF LINE BLANK            03260021
         MVC   TEXT+N13(PFKLIN/2),N2(APFK) MOVE FIRST 1/2 LINE ANYWAY   03270021
         EJECT                                                          03280021
*/*  D (YES,,NO,LOOP)     ANY MORE TEXT FOR THIS KEY? */                03290021
*****************************************************************       03292021
         BE    LOOP                 YES, GET NEXT KEY                   03300021
         SPACE 5                                                        03302021
*/*  S   SUBROUT:                    WRITE NEXT LINE */                 03304021
*****************************************************************       03306021
         BAL   RET,SUBROUT         GO TO WRITE LINE                     03310021
         SPACE 5                                                        03360021
*/*  P (,LOOP)          MOVE IN SECOND LINE OF TEXT */                  03370021
*****************************************************************       03380021
         MVC   TEXT+N13(PFKLIN/2),PFKLIN/2+N2(APFK)   MOVE IN 2ND LINE  03400021
         B     LOOP                GO TO NEXT TEST                      03410021
         SPACE 5                                                        03460021
*/*KEYLIST: P              POINT TO FIRST KEY IN LIST */                03510021
*****************************************************************       03560021
KEYLIST  EQU   *                                                        04220021
         LA    INSCAN,N2(APFK)     POINT TO FIRST KEY IN LIST           04230021
         SR    COUNT,COUNT         CLEAR LOOP CONTROL REG               04232021
         LA    COUNT,TEXT+PFKLIN/2+N10    SET COUNT FOR END OF LINE     04234021
         SPACE 5                                                        04236021
*/*SECLINE: P         POINT TO TEXT AREA OF LINE */                     04238021
*****************************************************************       04238421
SECLINE  LA    OUTSCAN,TEXT+N13    POINT TO TEXT AREA OF LINE           04240021
         EJECT                                                          04250021
*/*NEXTKEY: P     CONVERT KEY # AND MOVE TO LINE WITH COMMA */          04260021
*****************************************************************       04270021
NEXTKEY  SR    WORK5,WORK5         CLEAR REGISTER                       04290021
         IC    WORK5,N0(INSCAN)    GET KEY NUMBER                       04350021
         CVD   WORK5,PACK          CONVERT TO DECIMAL                   04400021
         UNPK  PACK,CVBIN          UNPACK IT                            04410021
         OI    PACK+N3,ZONE        ADD EBCDIC ZONE                      04450021
         CLI   PACK+N2,ZERO        IS FIRST DIGIT ZERO                  04500021
         BE    ONEDIG               YES, SKIP FIRST DIGIT               04550021
         MVC   N0(N1,OUTSCAN),PACK+N2   MOVE FIRST DIGIT                04600021
         LA    OUTSCAN,N1(OUTSCAN) BUMP OUTPUT POINTER                  04650021
ONEDIG   EQU   *                                                        04700021
         MVC   N0(N1,OUTSCAN),PACK+N3   MOVE SECOND DIGIT               04750021
         MVI   N1(OUTSCAN),COMMA   MOVE IN COMMA                        04800021
         LA    OUTSCAN,N2(OUTSCAN) BUMP OUTPUT POINTER                  04850021
         LA    INSCAN,N2(INSCAN)   BUMP INPUT POINTER                   04900021
         SPACE 5                                                        04902021
*/*ENDLIST: D (YES,CLEARCOM,NO,)   IS THIS END OF LIST? */              04904021
*****************************************************************       04906021
ENDLIST  CLI   N0(INSCAN),STOPLIST IS THIS END OF LIST                  04910021
         BE    CLEARCOM             YES, GO ON TO NEXT KEY              04920021
         SPACE 5                                                        04922021
*/*  D (NO,NEXTKEY,YES,)          IS THIS END OF LINE? */               04924021
*****************************************************************       04926021
         CR    COUNT,OUTSCAN       IS THIS END OF DISPLAY LINE          04930021
         BNL   NEXTKEY              NO, GET NEXT KEY                    04940021
         SPACE 5                                                        04940421
*/*  S  (,SECLINE)   SUBROUT:     WRITE NEXT LINE */                    04940821
*****************************************************************       04941221
         BAL   RET,SUBROUT          YES, WRITE THIS LINE OUT            04942021
         B     SECLINE             GO TO FORMAT SECOND LINE             04944021
         EJECT                                                          04994021
*/*CLEARCOM: P (,LOOP)       BLANK OUT LAST COMMA */                    04996021
*****************************************************************       04998021
CLEARCOM EQU   *                                                        05000021
         SH    OUTSCAN,H1          POINT TO LAST COMMA                  05050021
         MVI   N0(OUTSCAN),BLANK   BLANK IT OUT                         05100021
         B     LOOP                GO ON TO NEXT KEY                    05150021
         SPACE 5                                                        05160021
*/*NOTDEF: P (,LOOP)     MOVE IN 'NOT DEFINED' */                       05170021
*****************************************************************       05180021
NOTDEF   EQU   *                                                        05200021
         MVC   TEXT+N14(L'UNDEF),UNDEF   MOVE IN UNDEFINED MESSAGE      05250021
         B     LOOP                GO ON TO NEXT KEY                    05300021
         EJECT                                                          05302021
***********SUBROUTINE TO WRITE EACH LINE ************                   05304021
*/*SUBROUT: E       SUBROUTINE TO WRITE LINES */                        05304421
*/*  P          BACKSCAN TO LAST VISIBLE CHARACTER */                   05304521
*****************************************************************       05304821
SUBROUT  LA    BACKSCAN,SUFF       PT TO END OF TEXT                    05306021
         BCTR  BACKSCAN,N0         POINT TO LAST CHARACTER              05306421
X        CLI   N0(BACKSCAN),BLANK  IS IT BLANK                          05308021
         BNE   NONBLANK             NO, MARK LOCATION                   05308421
* NOTE  THE FOLLOWING INSTRUCTION DOES NOT PROVIDE LOOP CONTROL         05308521
         BCT   BACKSCAN,X           YES, POINT TO NEXT CHAR             05308821
         SPACE 5                                                        05308921
*/*NONBLANK: P       MOVE CONTROL BYTES AFTER TEXT */                   05309021
*****************************************************************       05309121
NONBLANK MVC   N1(L'SUFFIX,BACKSCAN),SUFFIX  MOVE IN SUFFIX FLAGS       05309221
         SPACE 5                                                        05309321
*/*  D (NO,MLWTO,YES,)           STANDARD WTO? */                       05309421
*****************************************************************       05309521
         TM    FLAGS,FLAGA         IS THIS A REGULAR WTO                05309621
         BNO   MLWTO                NO, DON'T CHANGE PREFIX             05309721
         SPACE 5                                                        05310121
*/*  P                    ALTER FLAGS IN SUFFIX */                      05310521
*****************************************************************       05310921
         MVC   PREFIX+N2(N2),ORDWTO      YES, ALTER PREFIX              05311121
         SPACE 5                                                        05313121
*/*MLWTO: P                   MARK LINE TYPE */                         05313521
*****************************************************************       05313921
MLWTO    MVC   N5(N1,BACKSCAN),LINTYPE  MARK LINE TYPE AS REQUIRED      05315021
         EJECT                                                          05315421
*/*  P     COMPUTE LENGTH AND STORE IN PREFIX */                        05315521
*****************************************************************       05315821
         LA    COMPARE,PREFIX      PT TO START OF PARAMETER LIST        05316421
         SR    BACKSCAN,COMPARE   DETERMINE TOTAL LENGTH MINUS ONE      05317821
         LA    BACKSCAN,N1(BACKSCAN)    ADD ONE FOR TRUE LENGTH         05319221
         STC   BACKSCAN,PREFIX+N1  STORE IN HEADER                      05320621
         SPACE 5                                                        05321021
*/*  S    WTO:    EXECUTE FORM */                                       05321421
*****************************************************************       05321821
         WTO   MF=(E,PREFIX)                                            05322021
* NOTE  WTO MESG ID IS RETURNED IN REG 1, BUT MUST BE PASSED            05323421
*          BACK WITH CONSOLE ID IN REG 0                                05324821
         SPACE 5                                                        05325221
*/*  P     SAVE MESG AND CONSOLE IDS FOR NEXT LINE */                   05325621
*****************************************************************       05326021
         LR    WTOPT,WTOIDOUT      MOVE WTO ID FOR NEXT LINE            05326221
         SLL   WTOPT,N8            ALIGN WTO ID IN REG                  05326621
         IC    WTOPT,CHUCMP        INSERT CONSOLE ID                    05327621
         SPACE 5                                                        05328021
*/*  P                      BLANK TEXT AREA */                          05328421
*****************************************************************       05328821
         MVI   TEXT,BLANK          BLANK THE                            05329021
         MVC   TEXT+N1(N70),TEXT      TEXT AREA                         05330421
         SPACE 5                                                        05330821
*/*  R     RETURN TO CALLER */                                          05331221
*****************************************************************       05331621
         BR    RET                 RETURN TO CALLER                     05331821
*************END OF SUBROUTINE*****************                         05332221
         EJECT                                                          05333221
*/*ENDFLAG: P     MARK LINE AS LAST ONE */                              05333621
*****************************************************************       05334021
ENDFLAG  EQU   *                                                        05334621
         MVI   LINTYPE,DTEND       SET LINE TYPE TO DATA-END            05336021
         SPACE 5                                                        05336421
*/*  S   SUBROUT:             WRITE LAST LINE */                        05336821
*****************************************************************       05337221
         BAL   RET,SUBROUT         GO TO WRITE LINE                     05337421
         SPACE 5                                                        05337821
*/*EXIT: R      RETURN TO IGC00110 */                                   05338221
*****************************************************************       05338621
EXIT     LM    SAVEAREA,WTOIDOUT,CSCBSAVE    RETORE SAVED REGS          05338821
         MVI   CSANAME+N3,ZERO     POINT TO FIRST LOAD OF SVC 110       05339221
         XCTL  SF=(E,(XSAREG))     RETURN TO IT TO FREE CSCB AND EXIT   05340221
         SPACE 5                                                        05340621
*/*NOMCS: P       MOVE IN IEE921I TEXT */                               05341021
*****************************************************************       05341421
NOMCS    EQU   *                                                        05341621
         MVC   TEXT(L'REJECT),REJECT    MOVE IN MESSAGE                 05343021
         SPACE 5                                                        05343121
*/*SETA: S (,EXIT)   SUBROUT:  WRITE ONE LINE MESSAGE */                05343221
*****************************************************************       05343321
SETA     OI    FLAGS,FLAGA         INDICATE NORMAL WTO                  05343421
         BAL   RET,SUBROUT         GO TO WRITE LINE                     05343821
         B     EXIT                RETURN TO CALLER                     05344421
         EJECT                                                          05344821
*/*MSG1: P (,SETA)    MOVE IN IEE720I TEXT */                           05345221
*****************************************************************       05345621
MSG1     EQU   *                                                        05345821
         MVC   TEXT(L'NALLOC),NALLOC    MOVE IN MESSAGE                 05347221
         B     SETA                SET NORMAL LINE FLAG                 05348621
         EJECT                                                          05350021
*************      CONSTANTS                                            05350421
CONTROL  DC    C'PFK DEFINITION'   CONTROL LINE TEXT                    05352021
HEADER   DC    X'0000E140'         LINE LENGTH AND MCS FLAGS            05360021
H1       DC    H'1'                ONE                                  05362021
MSGID    DC    C'IEE724I'          MESSAGE IDENTIFIER                   05370021
NALLOC   DC    C'IEE720I NO PFK ALLOCATION'                             05380021
NO       DC    C'NO'               KEY NOT CONVERSATIONAL MODE          05400021
ORDWTO   DC    X'6100'             FLAGS FOR STANDARD WTO               05400121
PFKLGTH  DC    H'110'              LENGTH OF PFK AREA                   05400421
REJECT   DC    C'IEE921I D PFK REJECTED, NO CRT CONSOLES'               05400821
SUFFIX   DC    X'098000000000E901' MLWTO CONTROL                        05402021
TITLE    DC    C' KEY#  CONv   DEFINITION...' TITLE TEXT                05410021
UNDEF    DC    C'NOT DEFINED'      KEY IS NOT DEFINED                   05420021
YES      DC    C'YES'              KEY IS CONVERSATIONAL MODE           05450021
         EJECT                                                          05560021
***********      EQUATES                                                05570021
BLANK    EQU   C' '                BLANK CHARACTER                      05600021
COMMA    EQU   C','                COMMA CHARACTER                      05650021
CTRLINE  EQU   X'80'               CONTROL LINE TYPE FLAG               05660021
CVTADDR  EQU   16                  CVT POINTER ADDRESS                  05670021
DATA     EQU   X'20'               DATA LINE TYPE FLAG                  05680021
DTEND    EQU   X'30'               DATA-END LINE TYPE FLAG              05690021
MVCLN    EQU   256                 LENGTH OF EACH MOVE TO COPY PFK AREA 05700021
NONE     EQU   X'00'               NULL LINE TYPE                       05702021
N0       EQU   0                   NUMBER                               05710021
N1       EQU   1                   NUMBER                               05720021
N2       EQU   2                   NUMBER                               05730021
N3       EQU   3                   NUMBER                               05730421
N4       EQU   4                   NUMBER                               05730821
N5       EQU   5                   NUMBER                               05732021
N6       EQU   6                   NUMBER                               05734021
N7       EQU   7                   NUMBER                               05740021
N8       EQU   8                   NUMBER                               05742021
N9       EQU   9                   NUMBER                               05744021
N10      EQU   10                  NUMBER                               05744121
N11      EQU   11                  NUMBER                               05744221
N12      EQU   12                  NUMBER                               05744321
N13      EQU   13                  NUMBER                               05744421
N14      EQU   14                  NUMBER                               05744521
N15      EQU   15                  NUMBER                               05744821
N16      EQU   16                  NUMBER                               05745221
N19      EQU   19                  NUMBER                               05746021
N70      EQU   70                  NUMBER                               05748021
ONEBYTE  EQU   8                   NUMBER OF BITS IN BYTE               05748121
PERIOD   EQU   C'.'                PERIOD CHARACTER                     05768421
PFKLGN   EQU   110                 LENGTH OF PFK AREA                   05778421
PFKLIN   EQU   PFKLGN-2            LENGTH OF PFK TEXT                   05789121
STOPLIST EQU   X'61'               STOPPER FOR LIST OF KEYS             05819421
STOPPER  EQU   X'64'               FLAG TO SHOW END OF LIST OF KEYS     05829721
TITLINE  EQU   X'40'               TITLE LINE TYPE FLAG                 05839721
ZERO     EQU   C'0'                CHARACTER ZERO                       05850021
ZONE     EQU   X'F0'               EBCDIC ZONE                          05900021
         TITLE 'IEE40110  IGC40110  DISPLAY PFK  CXSA'                  05910021
PSXA     DSECT                                                          05920021
         IEECVMUG   CXSA                                                05930021
         TITLE 'IEE40110  IGC40110   DISPLAY PFK   COMMUNICATIONS VECTO*05950021
               R TABLE'                                                 05960021
CVTDSECT DSECT                                                          06000021
         CVT                                                            06050021
         TITLE 'IEE40110  IGC40110   DISPLAY PFK   RESIDENT DISPLAY CON*06100021
               TROL MODULE'                                             06150021
RESDCM   DSECT                                                          06160021
         IEECRDCM                                                       06170021
         TITLE 'IEE40110  IGC40110   DISPLAY PFK   TRANSIENT DISPLAY CO*06172021
               NTROL MODULE'                                            06174021
DCMSECT  DSECT                                                          06176021
         IEECEJM                   CODE=DI                              06178021
         TITLE 'IEE40110  IGC40110   DISPLAY PFK   UNIT CONTROL MODULE' 06180021
PMUCM    DSECT                                                          06200021
         IEECUCM                                                        06250021
         TITLE 'IEE40110  IGC40110   DISPLAY PFK   CSCB (USED AS WORKSP*06260021
               ACE)'                                                    06270021
CSCBSECT DSECT                                                          06300021
         IEECHAIN                                                       06350021
* NOTE  THE FOLLOWING PORTION SHOWS HOW THIS MODULE MAKES USE           06360021
*       OF THE CSCB AS A WORK AREA.                                     06370021
         ORG   CHBUF               START MODULE WORKAREA ON D/W         06400021
FLAGS    DC    X'00'               NOT USED                             06450021
FLAGA    EQU   X'80'               USE REGULAR WTO                      06452021
LINTYPE  DC    X'00'               LINE TYPE                            06460021
OP       DS    14C                 INCOMING COMMAND OPERAND             06500021
PREFIX   DC    X'00000000'         WTO LINE LENGTH AND MCS FLAGS        06550021
TEXT     DC    71C' '              TEXT OF OUTPUT LINE                  06600021
SUFF     DC    X'000000000000'     MLWTO CONTROL AREA                   06650021
         DS    3C                  UNUSED                               06700021
CSCBSAVE DS    5F                  REGISTER SAVE AREA                   06750021
         ORG   CHPEND              ALIGN TO D/W PAST CONSOLE ID         06760021
PACK     DC    F'0'                AREA TO PLACE NUMBER FOR PACKING     06770021
CVBIN    DC    F'0'                AREA FOR CONVERSION TO BINARY        06780021
         END   IEE40110                                                 06800021
