         TITLE 'IGC5603D IEE5603D K AND MR MESSAGE MODULE LOAD ONE'     00100000
*********************************************************************** 00200021
*                                                                     * 00300021
*STATUS -- CHANGE LEVEL 0                                             * 00400021
*                                                                     * 00500021
*FUNCTION -- ISSUE MESSAGES RESULTING FROM MSGRT (MR) CDR ERRORS.THESE* 00600000
*    MESSAGES ARE ISSUED BY THE WRITE TO OPERATOR (WTO) MACRO. THIS   * 00700021
*    MODULE ALSO HANDLES CONTROL (K) COMMAND ERROR MESSAGES. IF THE   * 00800021
*    MESSAGE TO BE WRITTEN IS A RESPONSE TO A CONTROL COMMAND ISSUED  * 00900021
*    FROM A CRT CONSOLE, THE MESSAGE IS SET UP TO BE WRITTEN BY DIDOCS* 01000021
*    IN THE INSTRUCTION LINE OF THE DCM.                              * 01100021
*                                                                     * 01200021
*ENTRY POINT -- IEE5603D                                              * 01300021
*                                                                     * 01400021
*INPUT -- REGISTER TWO HAS THE ADDRESS OF THE XSA WHICH CONTAINS INFO * 01500021
*    ABOUT THE MESSAGE THAT IS TO BE WRITTEN.                         * 01600021
*         XAE - FIELD IN THE XSA CONTAINS A ONE BYTE MESSAGE CODE     * 01700021
*         XASTSAVE - FIELD IN THE XSA CONTAINS A ONE BYTE SECONDARY   * 01800021
*    MESSAGE CODE WHEN THE MESSAGE IS IN TWO PARTS.THE LAST THREE BYTE* 01900021
*    CONTAIN AN ADDRESS TO AN INVALID OPERAND IF IT IS TO BE INCLUDED * 02000021
*    IN THIS MESSAGE                                                    02100021
*                                                                     * 02200021
*OUTPUT -- ISSUES A MESSAGE USING THE WTO MACRO OR MOVES THE MESSAGE  * 02300021
*    INTO THE INSTRUCTION LINE OF THE DCM IF IT IS AN ERROR FROM THE  * 02400021
*    K COMMAND                                                        * 02500021
*                                                                     * 02600021
*EXTERNAL REFERENCE -- WTO (SVC 35) GETMAIN (SVC 4) FREEMAIN (SVC 5)  * 02700021
*                                                                     * 02800021
*EXITS,NORMAL -- RETURNS VIA REGISTER FOURTEEN                        * 02900021
*                XCTL TO IEE5903D MESSAGE MODULE'S SECOND LOAD        * 03000021
*                                                                     * 03100021
*EXITS,ERROR -- NONE                                                  * 03200021
*                                                                     * 03300021
*TABLES/WORK AREA -- UNIT CONTROL MODULE (UCM)                        * 03400021
*                    DISPLAY CONTROL MODULE (DCM)                     * 03500021
*                    EXTENDED SAVE AREA (XSA)                         * 03600021
*                                                                     * 03700021
*ATTRIBUTES -- REFRESHABLE,PRIVILEGED,TYPE 4 SVC                      * 03800021
*                                                                     * 03900021
*NOTE -- THIS MODULE WAS CREATED FOR RELEASE 21 TO ISSUE ERROR MESS-  * 04000021
*    AGES FROM ROUTING AND THE K COMMAND.                             * 04100021
*                                                                     * 04200021
*********************************************************************** 04300021
         EJECT                                                          04400021
IEE5603D CSECT                                                          04500021
*A 104500,164000-164720,164900 C 481000                         SA69717 04520021
* A 261300-261600                                               SA68512 04550021
********                                                              * 04600021
******** REGISTER EQUATES                                             * 04700021
********                                                              * 04800021
WRK0     EQU   0                   WORK REGISTER                        04900021
WRK1     EQU   1                   WORK REGISTER                        05000021
XSAR     EQU   2                   BASE REGISTER FOR THE XSA            05100021
WRK3     EQU   3                   WORK REGISTER                        05200021
WRK4     EQU   4                   WORK REGISTER                        05300021
BALR     EQU   5                   BRANCH AND LINK REGISTER             05400021
WRK6     EQU   6                   WORK REGISTER                        05500021
ENTR     EQU   7                   BASE REGISTER FOR THE UCM ENTRY      05600021
RCTR     EQU   8                   BASE REGISTER FOR THE RCT            05700021
UCMR     EQU   9                   BASE REGISTER FOR THE UCM            05800021
CVTR     EQU   10                  BASE REGISTER FOR THE CVT            05900021
LTSR     EQU   11                  CURSOR POINTER FROM XSA              06000021
BASR     EQU   12                  ROUTINE BASE REGISTER                06100021
SAVR     EQU   13                  SAVE REGISTER                        06200021
RETR     EQU   14                  RETURN REGISTER                      06300021
LNKR     EQU   15                  LINK REGISTER                        06400021
         EJECT                                                          06450000
********                                                              * 06500021
******** OTHER EQUATES                                                * 06600021
********                                                              * 06700021
N0       EQU   0                   NUMBER CONSTANT                      06800021
N1       EQU   1                   NUMBER CONSTANT                      06900021
N2       EQU   2                   NUMBER CONSTANT                      07000021
N3       EQU   3                   NUMBER CONSTANT                      07100021
N4       EQU   4                   NUMBER CONSTANT                      07200021
N5       EQU   5                   NUMBER CONSTANT                      07300021
N6       EQU   6                   NUMBER CONSTANT                      07400021
N7       EQU   7                   NUMBER CONSTANT                      07500021
N8       EQU   8                   NUMBER CONSTANT                      07600021
N9       EQU   9                   NUMBER CONSTANT                      07700021
N10      EQU   10                  NUMBER CONSTANT                      07800021
N11      EQU   11                  NUMBER CONSTANT                      07900021
N12      EQU   12                  NUMBER CONSTANT                      08000021
N15      EQU   15                  NUMBER CONSTANT                      08100021
N16      EQU   16                  NUMBER CONSTANT                      08200021
N25      EQU   25                  NUMBER CONSTANT                      08300021
N33      EQU   33                  NUMBER CONSTANT                      08400021
N59      EQU   59                  NUMBER CONSTANT                      08500021
N60      EQU   60                  NUMBER CONSTANT                      08600021
N64      EQU   64                  NUMBER CONSTANT                      08700021
BLK      EQU   X'40'               BLANK CONSTANT                       08800021
COMMA    EQU   C','                COMMA CHARACTER                      08900021
PARA2    EQU   C')'                PARENTHSIS CONSTANT                  09000021
CDRFG    EQU   X'80'               COMMAND FLAG IN MSG TABLE            09100021
OPDFG    EQU   X'40'               OPERAND FLAG IN MSG TABLE            09200021
VTXT     EQU   X'20'               VARIABLE TEXT FLAG IN TABLE          09300021
OP2FG    EQU   X'10'               OPERAND AT MSG END FLAG IN TABLE     09400021
WTOFG    EQU   X'80'               WTO FLAG                             09500021
CODHI    EQU   14                  HIGHEST MESSAGE CODE                 09600021
CODLOW   EQU   1                   LOWEST MESSAGE CODE                  09700021
TF       EQU   X'FF'               MASK TO TURN OFF FLAGS               09800021
KCDR     EQU   X'90'               CODE IN XSA FO K CDR                 09900021
RTCDR    EQU   X'94'               CODE IN XSA FOR ROUTE CDR            10000021
MCSFG    EQU   X'E0'               MCS FLAGS FOR WTO                    10100021
CHGOPT   EQU   2                   ERROR CODE FOR CHANGE OPTION MSG     10200021
ZERO     EQU   0                   NUMBER CONSTANT                      10300021
SUBP     EQU   255                 SUBPOOL NUMBER FOR GETMAIN           10400021
CHARK    EQU   X'D2'                                            SA69717 10450021
         EJECT                                                          10500021
*/* IEE5603D: CHART */                                                  10600021
*/* %START:   E (,%DD1)               IEE5603D */                       10700021
*****************************************************************       10800021
         BALR  BASR,N0             LOAD BASE REG                        10900021
         USING *,BASR                                                   11000021
         USING DXSA,XSAR           ADDRESSIBILITY OF XSA                11100021
         L     CVTR,CVTPTR         ADDRESS OF CVT                       11200021
         USING DCVT,CVTR           ADDRESSIBILITY OF CVT                11300021
         L     UCMR,CVTCUCB        ADDRESS OF UCM FROM CVT              11400021
         USING DUCM,UCMR           ADDRESSIBILITY OF UCM                11500021
         DROP  CVTR                                                     11600021
         USING UCMLIST,ENTR        ADDRESSIBILITY OF UCM ENTRY          11700021
***                                                                   * 11800021
***  CHECK FOR INCORRECT MESSAGE CODE                                 * 11900021
***                                                                   * 12000021
         SPACE 2                                                        12100021
*/* %DD1:   D (YES,%DD2,NO,%RET1)     IS ERROR CODE XAE VALID */        12200021
*/* %RET1:  R                         RETURN */                         12300021
*****************************************************************       12400021
         CLI   XAE,CODHI           IS MESSAGE CODE HIGHER THAN MAXIMUM  12500021
         BCR   N2,RETR             BRANCH YES TO RETURN                 12600021
         CLI   XAE,CODLOW          IS MESSAGE CODE LOWER THAN MINIMUM   12700021
         BCR   N4,RETR             BRANCH YES TO RETURN                 12800021
         SR    WRK1,WRK1           CLEAR REG                            12900021
         IC    WRK1,XAU            GET SOURCE CONSOLE ID                13000021
         TM    UCMMODE,UCMMCS      IS THIS A NON MCS SYSTEM  ME         13050021
         BNO   WRITE1              BRANCH YES FOR WTO        ME         13060021
***                                                                   * 13150021
***  TAKE THE CONSOLE ID IN REG 1 AND RETURN THE ADDRESS OF THE       * 13160021
***  UCM ENTRY FOR THAT CONSOLE IN ENTR REG                           * 13170021
***                                                                   * 13180021
         L     ENTR,UCMVEA         FIRST ENTRY FROM UCM                 13192021
         BCTR  WRK1,N0             SUBTRACT ONE FROM CONSOLE ID         13194021
         M     WRK0,UCMVEZ         MULTIPLY ENTRY SIZE BY REDUCED ID    13196021
         AR    ENTR,WRK1           ADDRESS OF DESIRED UCM ENTRY         13198021
         SR    WRK0,WRK0           CLEAR REG FOR CDR AND OPD LENGTH     13200021
         SPACE 2                                                        13300021
*/* %DD2:   D (YES,%DD3,NO,WRITE1)    IS THIS CONSOLE A CRT */          13400021
*****************************************************************       13500021
         TM    UCMDISP,UCMDISPC    IS THIS CONSOLE A CRT?               13600021
         BNO   WRITE1              BRANCH NO                            13700021
         L     CVTR,UCMXB          ADDRESS OF RESIDENT DCM              13800021
         L     CVTR,N0(CVTR)       ADDRESS OF TRANSIENT DCM             13900021
         USING DTDCM,CVTR          ADDRESSIBILITY OF TRANSIENT DCM      14000021
         EJECT                                                          14100021
*/* %DD3:   D (YES,MOVEDCM,NO,%DD4)   IS THIS A K CDR ERROR */          14200021
*****************************************************************       14300021
         CLI   XAN,KCDR            IS THIS A CONTROL(K) COMMAND?        14400021
         BE    MOVEDCM             BRANCH YES                           14500021
         SPACE 1                                                        14600021
*/* %DD4:   D (YES,MOVEDCM,NO,WRITE1) IS THIS A CHANGE OPT. MSG. */     14700021
*****************************************************************       14800021
         CLI   XAE,CHGOPT          IS THIS A CHANGE OPTIONS CODE        14900021
         BNE   WRITE1              BRANCH NO                            15000021
         SPACE 2                                                        15100000
*/* MOVEDCM: P (,BUILDL)              SET CURSOR TO ZERO. GET ADDR OF   15200021
*/*DCM INST. LINE */                                                    15300021
*****************************************************************       15400021
MOVEDCM  EQU   *                                                        15500021
         L     WRK4,XAR            ADDRESS OF PARM LIST                 15600021
         LA    WRK4,N4(WRK4)       INCREMENT OVER FOUR BYTE PARMS       15700021
         CLI   XAE,CHGOPT          IS THIS A CHANGE OPTIONS CODE        15800021
         BNE   MOVEOPT             BRANCH NO                            15900021
         L     WRK4,DCMAENTR       ADDRESS OF DCM ENTRY AREA            16000021
MOVEOPT  EQU   *                                                        16100021
         L     LTSR,XASTSAVE       SET CURSOR POSITION                  16200021
         LA    LTSR,N0(LTSR)       ZERO OUT SECOND MSG CODE             16300021
         LTR   LTSR,LTSR          IS THERE AN INVALID OPERAND   SA69717 16400021
         BNZ   COMPCUR            BRANCH NO                     SA69717 16409021
         CLI   N0(WRK4),CHARK     WAS COMMAND K                 SA69717 16418021
         BE    SETCUR2            BRANCH YES                    SA69717 16427021
         LA    LTSR,N6            COMMAND WAS CONTROL           SA69717 16436021
SETCUR2  EQU   *                                                SA69717 16445021
         LA    LTSR,N2(LTSR)      INCREMENT FOR CURSOR POSITION SA69717 16454021
         B     STORCUR                                          SA69717 16463021
COMPCUR  EQU   *                                                SA69717 16472021
         SR    LTSR,WRK4         BYTES INVALID OPERAND FROM CDR         16481021
STORCUR  EQU   *                                                SA69717 16490021
         STH   LTSR,DCMINLGN       SET UP FOR CURSOR POSITIONING        16500021
         OI    DCMSVC34,DCMINVLD   SET INVALID K BIT                    16600021
         L     WRK3,DCMAINS        ADDRESS OF INSTRUCTION LINE OF DCM   16700021
         LH    WRK4,DCMLGNTH       GET THE LENGTH OF A LINE FROM DCM    16800021
         SPACE 2                                                        16900000
*/* BUILDL: P (,%BUILD)               COMPUTE TABLE ENTRY FROM XAE CODE 17000021
*/* */                                                                  17100021
*****************************************************************       17200021
BUILDL   EQU   *                                                        17300021
***                                                                   * 17450021
***  BLANK OUT THE BUFFER AREA FOR THE MESSAGE                        * 17460021
***                                                                   * 17470021
         BCTR  WRK4,N0             DECREMENT THE LENGTH OF THE BUFFER   17490021
         BCTR  WRK4,N0             AREA BY TWO                          17492021
         MVI   N0(WRK3),BLK        BLANK FIRST CHARACTER                17494021
         EX    WRK4,BLI            PROPAGATE BLANKS                     17496021
         SR    WRK4,WRK4           CLEAR REG                            17500021
         IC    WRK4,XAE            ERROR CODE FROM XSA                  17600021
         AR    WRK4,WRK4           DOUBLE CODE FOR INDEX                17700021
         LA    WRK6,TAB1(WRK4)     PT TO APPROPRIATE TAB1 ENTRY         17800021
         LH    WRK6,N0(WRK6)       LOAD TABLE ELEMENT                   17900021
         EJECT                                                          17950021
***                                                                   * 18000021
***  BUILD MESSAGE IN DCM INSTRUCTION LINE OR WTO BUFFER                18100021
***                                                                   * 18200021
*/* %BUILD: P (,%DD5)                 MOVE MESSAGE ID INTO BUFFER */    18400021
*****************************************************************       18500021
         MVC   N0(N3,WRK3),FXID    MOVE IN IEE                          18600021
         LA    WRK1,TAB2(WRK6)     PT TO APPROPRIATE TAB2 ENTRY         18700021
         MVC   N3(N4,WRK3),N1(WRK1) FILL IN MSG ID                      18800021
         SPACE 2                                                        18900021
*/* %DD5:   D (YES,MOVECDR,NO,OPDTEST) DOES ERROR MSG. CONTAIN CDR */   19000021
*****************************************************************       19100021
         TM    N5(WRK1),CDRFG      DOES MSG CONTAIN COMMAND?            19200021
         BO    MOVECDR             BRANCH YES                           19300021
         SPACE 2                                                        19400021
*/* OPDTEST: D (YES,MOVEOPD,NO,MOVETXT) DOES ERROR MSG. CONTAIN         19500021
*/*OPERAND */                                                           19600021
*****************************************************************       19700021
OPDTEST  EQU   *                                                        19800021
         TM    N5(WRK1),OPDFG      DOES MSG CONTAIN OPERAND?            19900021
         BO    MOVEOPD             BRANCH YES                           20000021
***                                                                   * 20100021
***  MOVE FIXED TEXT FOR TABLE TWO INTO MESSAGE BUFFER                * 20200021
***                                                                   * 20300021
         SPACE 2                                                        20400021
*/* MOVETXT: P (,%DD6)               MOVE FIXED TEXT OF MSG FROM TABLE  20500021
*/* */                                                                  20600021
*****************************************************************       20700021
MOVETXT  EQU   *                                                        20800021
         SR    WRK6,WRK6           CLEAR REG                            20900021
         IC    WRK6,N0(WRK1)       GET FIXED MSG TEXT LENGTH            21000021
         EX    WRK6,FXTEXT         MOVE IN FIXED TEXT                   21100021
         LA    WRK6,N9(WRK6)       LENGTH OF ID,+ BLANK,+ 1             21200021
         AR    WRK3,WRK6           UPDATE BUFFER POINTER TO INCLUDE TXT 21300021
         AR    WRK6,WRK0           LENGTH OF VERB AND OPERAND OR ZERO   21400021
         SPACE 3                                                        21500021
*/* %DD6:   D (YES,VARTXT,NO,WTODCM)  DOES MSG HAVE SECONDARY CODE */   21600021
*****************************************************************       21700021
         TM    N5(WRK1),VTXT       DOES MSG HAVE MORE TEXT?             21800021
         BO    VARTXT              BRANCH YES                           21900021
         EJECT                                                          22000000
*/* WTODCM: D (YES,WRITE2,NO,%MM1)    IS WTO INDICATOR ON */            22100021
*****************************************************************       22200021
WTODCM   EQU   *                                                        22300021
         TM    XASSDS,WTOFG        IS THIS A WTO?                       22400021
         BO    WRITE2              BRANCH YES                           22500021
         SPACE 3                                                        22600021
*/* %MM1:   M (,%DD7)                 SET WRITE INST LINE IN DCM */     22700021
*****************************************************************       22800021
         OI    DCMIOCM1,DCMWRINS   SET BIT TO WRITE INST LINE           22900021
         SPACE 3                                                        23000021
*/* %DD7:   D (YES,%PP1,NO,RETURN)    DOES DEVICE HAVE LIGHT PEN */     23100021
*****************************************************************       23200021
         TM    DCMIOUNQ,DCMW2250   DOES DEVICE HAVE A LIGHT PEN?        23300021
         BNO   RETURN              BRANCH NO                            23400021
         SPACE 3                                                        23500021
*/* %PP1:   P (,RETURN)               MOVE ENTER CANCEL INTO MSG LINE   23600021
*/**/                                                                   23700021
*****************************************************************       23800021
         L     WRK3,DCMAINS                                             23900021
         MVC   N59(N15,WRK3),ENCN  MOVE ENTER-CANCEL MSG INTO LINE      24000021
         NI    DCMIOUNQ,TF-DCMINNOR TURN OFF NORMAL LINE BIT            24100021
         OI    DCMIOUNQ,DCMINERR   INDICATE ERROR MSG IN INST LINE      24200021
         SPACE 3                                                        24300021
*/* RETURN: R                         RETURN */                         24400021
*****************************************************************       24500021
RETURN   EQU   *                                                        24600021
         BR    RETR                RETURN TO CALLER                     24700021
         SPACE 3                                                        24800021
*/* MOVECDR: P (,OPDTEST)             MOVE CDR INTO MSG BUFFER */       24900021
*****************************************************************       25000021
MOVECDR  EQU   *                                                        25100021
         MVC   N8(N8,WRK3),XAV     MOVE IN VERB FROM XSA                25200021
         LA    WRK3,N9(WRK3)       INCREMENT DCM PTR AROUND VERB        25300021
         LA    WRK0,N9             INCREMENT VARIABLE TEXT COUNT        25400021
         B     OPDTEST             BRANCH BACK                          25500021
         EJECT                                                          25600000
*/* MOVEOPD: P (,MOVETXT)             MOVE OPERAND INTO MSG BUFFER */   25700021
*****************************************************************       25800021
MOVEOPD  EQU   *                                                        25900021
         L     WRK4,XASTSAVE       ADDRESS OF INVALID OPERAND           26000021
         LA    WRK4,N0(WRK4)       ZERO HIGH ORDER BYTE                 26100021
         LTR   WRK4,WRK4          IS THERE AN INVALID OPERAND   SA68512 26130021
         BZ    MOVETXT            BRANCH NO, MOVE TEXT ONLY     SA68512 26160021
         LR    WRK6,WRK4           ADDRESS OF INVALID OPERAND           26200021
         LA    BALR,N8             MAXIMUM OPERAND LENGTH               26300021
INCROP   EQU   *                                                        26400021
         LA    WRK4,N1(WRK4)       INCREMENT BY ONE                     26500021
         CLI   N0(WRK4),BLK        IS THIS THE END OF THE OPERAND?      26600021
         BE    GETLEN              BRANCH YES                           26700021
         CLI   N0(WRK4),COMMA      IS THIS A COMMA?                     26800021
         BE    GETLEN              BRANCH YES                           26900021
         CLI   N0(WRK4),PARA2      IS THIS A PARENTHSIS                 27000021
         BE    GETLEN              BRANCH YES                           27100021
         BCT   BALR,INCROP         DECREMENT COUNT TEST NEXT CHAR       27200021
GETLEN   EQU   *                                                        27300021
         SR    WRK4,WRK6           LENGTH OF INVALID OPERAND            27400021
         BCTR  WRK4,N0             DECREMENT FOR EXECUTE                27500021
         TM    N5(WRK1),OP2FG      IS THIS THE OPERAND AT THE END MSG   27600021
         BO    OPEND               BRANCH YES                           27700021
         EX    WRK4,OPVAR          INVALID OPERAND INTO MSG TEXT        27800021
         LA    WRK4,N2(WRK4)       INCREMENT FOR EXECUTE AND BLANK      27900021
         AR    WRK3,WRK4           INCREMENT DCM PTR AROUND VERB        28000021
CONTOP   EQU   *                                                        28100021
         AR    WRK0,WRK4           INCREMENT VARIABLE TEXT COUNT        28200021
         B     MOVETXT             RETURN FOR FIXED TEXT                28300021
OPEND    EQU   *                                                        28400021
         EX    WRK4,OPEND1         INVALID OPERAND INTO END OF TEXT     28500021
         LA    WRK4,N1(WRK4)       INCREMENT FOR EXECUTE                28600021
         B     CONTOP              CONTINUE TO BUILD MSG                28700021
***                                                                   * 28800021
***   PREPARE TO WRITE MESSAGE AND FREE CORE                          * 28900021
***                                                                   * 29000021
         SPACE 2                                                        29100000
*/* WRITE2: S (,%WRITE2) WTO:         WRITE ERROR MESSAGE */            29200021
*****************************************************************       29300021
WRITE2   EQU   *                                                        29400021
         L     WRK1,XAX+N4         ADDRESS OF WTO BUFFER                29500021
         LA    WRK6,N4(WRK6)       4 EXTRA BYTES FOR WTO (MCS + LEN)    29600021
         STH   WRK6,N0(WRK1)       LENGTH OF WTO MSG PLUS 4             29700021
         AR    WRK6,WRK1           END OF BUFFER                        29800021
         MVC   N0(N4,WRK6),DRCODES MOVE IN DESC AND ROUTE CODES         29900021
         SR    WRK0,WRK0           CLEAR REG                            30000021
         IC    WRK0,XAU            TERMINAL ID FROM XSA                 30100021
         WTO   MF=(E,(1))          WRITE MESSAGE                        30200021
         EJECT                                                          30300000
*/* %WRITE2: S (,%RET2) FREEMAIN:     RELEASE MSG BUFFER */             30400021
*****************************************************************       30500021
         L     WRK1,XAX+N4         ADDRESS OF AREA FOR FREEMAIN         30600021
         FREEMAIN R,LV=N64,A=(1),SP=SUBP FREE BUFFER AREA               30700021
         SPACE 3                                                        30800021
*/* %RET2:  R                         RETURN */                         30900021
*****************************************************************       31000021
         BR    RETR                RETURN TO CALLER                     31100021
***                                                                   * 31200021
***   GET CORE FOR A MESSAGE THAT IS A WTO                            * 31300021
***                                                                   * 31400021
         SPACE 3                                                        31500021
*/* WRITE1: S (,%WRITE1) GETMAIN: AREA FOR MSG BUFFER */                31600021
*****************************************************************       31700021
WRITE1   EQU   *                                                        31800021
         LA    WRK1,XAX+N4         AREA FOR STORAGE ADDRESS             31900021
         MVC   XAP(N10),GETAREA    MOVE REMOTE PARAMETER LIST TO XSA    32000021
         ST    WRK1,XAD            AREA FOR GETMAIN TO STORE ADDRESS    32100021
         LA    WRK1,XAP            ADDRESS OF REMOTE LIST FOR GETMAIN   32200021
         GETMAIN MF=(E,(1))        GET CORE FOR WTO                     32300021
         LTR   LNKR,LNKR           IS RETURN CODE ZERO                  32400021
         BCR   N7,RETR             BRANCH NO                            32500021
         L     WRK3,XAX+N4         BUFFER ADDRESS                       32600021
         XC    N0(N4,WRK3),N0(WRK3) ZERO FOUR BYTES                     32700021
         SPACE 2                                                        32800000
*/* %WRITE1: M (,BUILDL)              SET WTO INDICATOR ON */           32900021
*****************************************************************       33000021
         OI    XASSDS,WTOFG        SET WTO INDICATOR                    33100021
         OI    N2(WRK3),MCSFG      SET MCS FLAGES FOR WTO               33200021
         LA    WRK3,N4(WRK3)       INCREMENT BUFFER ADDRESS             33300021
         LA    WRK4,N60            LENGTH OF MSG BUFFER                 33400021
         B     BUILDL                                                   33500021
         EJECT                                                          33550000
OPEND1   MVC   N25(N0,WRK3),N0(WRK6) INVALID OPERAND INTO END OF MSG    35500021
BLI      MVC   N1(N0,WRK3),N0(WRK3)  USED TO BLANK INST LINE            35600021
OPVAR    MVC   N8(N0,WRK3),N0(WRK6) INVALID OPERAND INTO MSG            35700021
FXTEXT   MVC   N8(N0,WRK3),N6(WRK1) MOVE FIX TEXT INTO BUFFER           35800021
         SPACE 2                                                        35900000
*/* VARTXT: R                         IEE5903D RT MSG LOAD TWO */       36000021
*****************************************************************       36100021
VARTXT   EQU   *                                                        36200021
         L     WRK4,XAX+N4         SAVE ADDRESS FROM GETMAIN FOR LOAD2  36300021
         MVC   XAX(N8),MSGL2       NAME OF RT MSG LOAD 2                36400021
         LA    WRK1,XAX            REINITIALIZE XSA                     36500021
         ST    WRK1,XAP            POINT XAP TO MODULE NAME IN XAX      36600021
         SR    WRK1,WRK1           STORE ZERO DCB POINTER               36700021
         ST    WRK1,XAD                   IN XAD                        36800021
         XCTL  SF=(E,(XSAR))       XCTL TO SECOND LOAD                  36900021
         SPACE 2                                                        37000000
*/* IEE5603D: END */                                                    37100021
*****************************************************************       37200021
GETAREA  GETMAIN EC,LV=N64,A=VARTXT,SP=SUBP,MF=L GET CORE FOR WTO       37300021
         EJECT                                                          37350000
***                                                                   * 37400021
***  THE FOLLOWING TABLE IS INDEXED BY TWICE THE MSG. CODE. EACH HALF-* 37500021
***  WORD POINTS TO A TAB2 ELEMENT CONTAINING THE APPROPRIATE MESSAGE * 37600021
***                                                                   * 37700021
PREMSG   EQU   6                   BYTES BEFORE MESSAGE TEXT            37800021
TAB1     EQU   *                                                        37900021
         DC    AL2(0)                                                   38000021
         DC    Y(TM01-TAB2-PREMSG)                                      38100021
         DC    Y(TM02-TAB2-PREMSG)                                      38200021
         DC    Y(TM03-TAB2-PREMSG)                                      38300021
         DC    Y(TM04-TAB2-PREMSG)                                      38400021
         DC    Y(TM05-TAB2-PREMSG)                                      38500021
         DC    Y(TM06-TAB2-PREMSG)                                      38600021
         DC    Y(TM07-TAB2-PREMSG)                                      38700021
         DC    Y(TM08-TAB2-PREMSG)                                      38800021
         DC    Y(TM09-TAB2-PREMSG)                                      38900021
         DC    Y(TM10-TAB2-PREMSG)                                      39000021
         DC    Y(TM11-TAB2-PREMSG)                                      39100021
         DC    Y(TM12-TAB2-PREMSG)                                      39200021
         DC    Y(TM13-TAB2-PREMSG)                                      39300021
         DC    Y(TM14-TAB2-PREMSG)                                      39400021
         EJECT                                                          39450000
***                                                                     39500021
***  THE FOLLOWING TABLE CONTAINS A 1-BYTE LENGTH OF PREFORMATTED MSG * 39600021
***  TEXT, 4-BYTE ID FILLER, 1-BYTE OF MSG FLAGS, AND PREFORMATTED    * 39700021
***  MSG TEXT                                                         * 39800021
***                                                                     39900021
TAB2     EQU   *                                                        40000021
         DC    AL1(L'TM01-1)            LENGTH OF FIXED MESSAGE SECTION 40100021
         DC    C'137I'                  MESSAGE ID FILLER               40200021
         DC    X'80'                    MESSAGE TYPE FLAG               40300021
TM01     DC    C'VALID ONLY IN MCS'     FIXED MESSAGE TYPE              40400021
*                                                                       40500021
         DC    AL1(L'TM02-1)                                            40600021
         DC    C'150I'                                                  40700021
         DC    X'00'                                                    40800021
TM02     DC    C'CHANGE OPTIONS IF DESIRED'                             40900021
*                                                                       41000021
         DC    AL1(L'TM03-1)                                            41100021
         DC    C'151I'                                                  41200021
         DC    X'20'                                                    41300021
TM03     DC    C'DELETE REQUEST INCONSISTENT-'                          41400021
*                                                                       41500021
         DC    AL1(L'TM04-1)                                            41600021
         DC    C'156I'                                                  41700021
         DC    X'D0'                                                    41800021
TM04     DC    C'INVALID OPERAND -'                                     41900021
*                                                                       42000021
         DC    AL1(L'TM05-1)                                            42100021
         DC    C'158I'                                                  42200021
         DC    X'20'                                                    42300021
TM05     DC    C'K REQUEST INCONSISTENT-'                               42400021
*                                                                       42500021
         DC    AL1(L'TM06-1)                                            42600021
         DC    C'307I'                                                  42700021
         DC    X'80'                                                    42800021
TM06     DC    C'DELIMITER ERROR'                                       42900021
*                                                                       43000021
         DC    AL1(L'TM07-1)                                            43100021
         DC    C'308I'                                                  43200021
         DC    X'80'                                                    43300021
TM07     DC    C'TERM LENGTH ERROR'                                     43400021
*                                                                       43500021
         DC    AL1(L'TM08-1)                                            43600021
         DC    C'345I'                                                  43700021
         DC    X'80'                                                    43800021
TM08     DC    C'AUTHORITY INVALID'                                     43900021
*                                                                       44000021
         DC    AL1(L'TM09-1)                                            44100021
         DC    C'921I'                                                  44200021
         DC    X'E0'                                                    44300021
TM09     DC    C'REJECTED '                                             44400021
*                                                                       44500021
         DC    AL1(L'TM10-1)                                            44600021
         DC    C'924I'                                                  44700021
         DC    X'20'                                                    44800021
TM10     DC    C'INVALID AREA DEFINITION '                              44900021
*                                                                       45000021
         DC    AL1(L'TM11-1)                                            45100021
         DC    C'925I'                                                  45200021
         DC    X'E0'                                                    45300021
TM11     DC    C'OPERAND '                                              45400021
*                                                                       45500021
         DC    AL1(L'TM12-1)                                            45600021
         DC    C'926I'                                                  45700021
         DC    X'20'                                                    45800021
TM12     DC    C'L=CCA OPERAND INVALID-'                                45900021
*                                                                       46000021
         DC    AL1(L'TM13-1)                                            46100021
         DC    C'927I'                                                  46200021
         DC    X'A0'                                                    46300021
TM13     DC    C'REQUEST AMBIGUOUS-'                                    46400021
*                                                                       46500021
         DC    AL1(L'TM14-1)                                            46600021
         DC    C'931I'                                                  46700021
         DC    X'C0'                                                    46800021
TM14     DC    C'INSUFFICIENT STORAGE FOR COMMAND'                      46900021
*                                                                       47000021
         EJECT                                                          47050000
********                                                              * 47100021
******** CONSTANT USED BY ROUTINE                                     * 47200021
********                                                              * 47300021
MSGL2    DC    C'IGC5903D'         NAME OF SECOND LOAD OF MSG MODULE    47400021
ENCN     DC    C'*ENTER**CANCEL*'  ADDED FOR CRT WITH CURSOR            47500021
FXID     DC    C'IEE'              MESSAGE ID                           47600021
DRCODES  DC    X'0800'             DESCRIPTOR CODE                      47700021
         DC    X'0000'             ROUTING CODE                         47800021
PATCH    DC    C'****PATCH AREA****'                                    47900021
PATCH2   DC    C'IEE5603D-TEST ONLY'                                    48000021
PATCH3   DC    8C' '                                            SA69717 48100021
         EJECT                                                          48200021
DTDCM    DSECT                                                          48300021
         IEECBJH CODE=DI                                                48400021
         EJECT                                                          48500021
DUCM     DSECT                                                          48600021
         IEECUCM                                                        48700021
         EJECT                                                          48800021
DXSA     DSECT                                                          48900021
         IEEXSA                                                         49000021
*  THE XAS OF THE XSA IS USED IN THIS WAY BY THIS ROUTINE               49100021
         ORG   XAS                                                      49200021
XASCID   DS    X                   CONSOLE ID                           49300021
XASDID   DS    C                   DISPLAY AREA ID                      49400021
XASSDS   DS    X                   STATUS DISPLAY FLAGS                 49500021
XASPLS3  DS    X                   RESERVED                             49600021
XASTSAVE DS    X                   SECONDARY ERROR CODE                 49700021
         DS    3X                  ADDRESS OF INVALID OPERAND           49800021
         EJECT                                                          49900021
DCVT     DSECT                                                          50000021
         CVT                                                            50100021
         END                                                            50200021
