         TITLE 'IEE6303D IGC6303D   MSGRT COMMAND HANDLER LOAD ONE'     00100021
*********************************************************************** 00200021
*                                                                     * 00300021
* STATUS -- CHANGE LEVEL 0                                            * 00400021
*                                                                     * 00500021
* FUNCTION -- THIS ROUTINE IS PART OF SVC 34 AND HANDLES THE MSGRT    * 00600021
*    COMMAND (MR). UPON ENTRY THE COMMAND IS CHECKED FOR SYNTAX ERRORS* 00700021
*    IF THEY EXIST AN ERROR CODE IS SET IN XSA. IF NO SYNTAX ERRORS   * 00800021
*    EXIST THE L=CCA OPERAND IS VERIFIED BY CHECKING THE ID FOR       * 00900021
*    AN UCM ENTRY. IF THE L=CCA CONSOLE ID IS VALID THE ROUTING       * 01000021
*    CONTROL TABLE (RCT) IS INITIALLY CONSTRUCTED OR DYNAMICALLY      * 01100021
*    UPDATED TO INCLUDE THIS COMMAND. A FIELD IN THE REQUESTING CON-  * 01200021
*    SOLE'S UCM ENTRY CONTAINS EITHER ZERO IF THE RCT DOES NOT EXIST  * 01300021
*    OR THE ADDRESS OF THE RCT IF IT ALREADY EXISTS. THE RCT HAS      * 01400021
*    FIXED LENGTH ENTRIES CONSISTING OF A CONTROL BYTE(1), A VERB(2), * 01500021
*    AN OPERAND(2), A CONSOLE ID(1) AND THE CONSOLE AREA(1).          * 01600021
*                                                                     * 01700021
* ENTRY POINTS -- IEE6303D                                            * 01800021
*                                                                     * 01900021
* INPUT -- REGISTER TWO ADDRESS OF THE EXTENDED SAVE AREA (XSA)       * 02000021
*                                                                     * 02100021
* OUTPUT -- UPDATED RCT                                               * 02200021
*                                                                     * 02300021
* EXTERNAL REFERENCE -- XCTL (SVC 7 ), GETMAIN (SVC 4)                * 02400021
*                                                                     * 02500021
* EXITS,NORMAL -- RETURN VIA BRANCH REGISTER FOURTEEN                 * 02600021
*                 XCTL TO IEE6403D FOR MR REF COMMAND                 * 02700021
*                                                                     * 02800021
* EXITS,ERROR -- XCTL  TO IEE6403D  FOR ERROR MESSAGE OUTPUT          * 02900021
*                                                                     * 03000021
* TABLES/WORK AREA -- UNIT CONTROL MODULE (UCM)                       * 03100021
*                     ROUTING CONTROL TABLE (RCT)                     * 03200021
*                     EXTENDED SAVE AREA (XSA)                        * 03300021
*                                                                     * 03400021
* ATTRIBUTES -- REENTRANT, TRANSIENT                                  * 03500021
*                                                                     * 03600021
* NOTES -- THIS MODULE WAS CREATED FOR RELEASE 21 TO SUPPORT STATUS   * 03700021
*    DISPLAY SYSTEM'S (SDS) NEW ROUTE (RT) COMMAND WHICH IS A NEW SDS * 03800021
*    FUNCTION. THIS IS THE FIRST LOAD OF THE MSGRT HANDLER.           * 03900021
*                                                                     * 04000021
*********************************************************************** 04100021
        EJECT                                                           04200021
IEE6303D CSECT                                                          04300021
********                                                              * 04400021
******** REGISTER EQUATES                                             * 04500021
********                                                              * 04600021
WRK0     EQU   0                   WORK REGISTER                        04700021
WRK1     EQU   1                   WORK REGISTER                        04800021
XSAR     EQU   2                   BASE REGISTER FOR THE XSA            04900021
CDRR     EQU   3                   END OF SYNTAX SCAN ADDRESS           04950021
WRK3     EQU   4                   WORK REGISTER                        05000021
WRK4     EQU   5                   WORK REGISTER                        05100021
WRK6     EQU   6                   WORK REGISTER                        05300021
ENTR     EQU   7                   BASE REGISTER FOR UCM ENTRIES        05400021
RCTR     EQU   8                   BASE REGISTER FOR THE RCT            05500021
UCMR     EQU   9                   BASE REGISTER FOR THE UCM            05600021
CVTR     EQU   10                  BASE REGISTER FOR THE CVT            05700021
LSTR     EQU   11                  LIST POINTER FROM XSA                05800021
BASR     EQU   12                  ROUTINE BASE REGISTER                05900021
SAVR     EQU   13                  SAVE REGISTER                        06000021
RETR     EQU   14                  RETURN REGISTER                      06100021
LNKR     EQU   15                  LINK REGISTER                        06200021
         EJECT                                                          06250021
********                                                              * 06300021
******** OTHER EQUATES                                                * 06400021
********                                                              * 06500021
N0       EQU   0                   NUMBER CONSTANT                      06600021
N1       EQU   1                   NUMBER CONSTANT                      06700021
N2       EQU   2                   NUMBER CONSTANT                      06800021
N3       EQU   3                   NUMBER CONSTANT                      06900021
N4       EQU   4                   NUMBER CONSTANT                      07000021
N5       EQU   5                   NUMBER CONSTANT                      07100021
N6       EQU   6                   NUMBER CONSTANT                      07200021
N7       EQU   7                   NUMBER CONSTANT                      07300021
N8       EQU   8                   NUMBER CONSTANT                      07400021
N9       EQU   9                   NUMBER CONSTANT                      07500021
N10      EQU   10                  NUMBER CONSTANT                      07600021
N11      EQU   11                  NUMBER CONSTANT                      07700021
N12      EQU   12                  NUMBER CONSTANT                      07800021
CA       EQU   C'A'                A CONSTANT                           07900021
CI       EQU   C'I'                I CONSTANT                           08000021
CJ       EQU   C'J'                J CONSTANT                           08100021
CR       EQU   C'R'                R CONSTANT                           08200021
CS       EQU   C'S'                S CONSTANT                           08300021
CZ       EQU   C'Z'                Z CONSTANT                           08400021
COMMA    EQU   C','                COMMA CHARACTER                      08500021
PARA2    EQU   C')'                PARENTHSIS CONSTANT                  08600021
PARA1    EQU   C'('                PARENTHSIS CONSTANT                  08700021
BLK      EQU   X'40'               BLANK CONSTANT                       08800021
TF       EQU   X'FF'               FLAG TO TURN OF SWITCHES             08900021
SUBP     EQU   255                 SUBPOOL FOR GETMAIN RCT SECTIONS     09000021
XF0      EQU   X'F0'               NUMBER ZONE                          09100021
EQUAL    EQU   C'='                EQUAL CONSTANT                       09200021
LOPER    EQU   C'L'                L CONSTANT                           09300021
KCDR     EQU   C'K'                K CONSTANT                           09400021
TEND     EQU   X'FF'               TABLE DELIMITER                      09500021
CHARO    EQU   C'O'                LETTER CONSTANT                      09600021
NONCRT   EQU   27                  SECONDARY CODE FOR INVALID K         09700021
ZERO     EQU   X'00'               NUMBER CONSTANT                      09800021
RTCDR    EQU   X'94'               COMMAND CODE FOR ROUTE CDR           09900021
MCSERROR EQU   X'01'               ERROR CODE FOR MCS MSG               10000021
KERROR   EQU   X'0B'               ERROR CODE FOR CRT ONLY MSG          10100021
NCERROR  EQU   X'0E'               ERROR CODE FOR NO CORE MSG           10200021
LIERROR  EQU   X'0C'               ERROR CODE FOR L INVALID MSG         10300021
AIERROR  EQU   X'12'               SECOND ERROR CODE FOR AREA INVALID   10400021
CIERROR  EQU   X'13'               SECOND ERROR CODE FOR CONSOLE INVAL  10500021
RIERROR  EQU   X'08'               ERROR CODE FOR AUTHORITY INVALID     10600021
IOERROR  EQU   X'04'               ERROR CODE FOR INVALID OPERAND       10700021
*********                                                             * 10800021
         EJECT                                                          11000021
*/* IEE6303D: CHART */                                                  11100021
*/* %START: E (,STARTSC)              IEE6303D MR CDR MODULE 1 */       11200021
*******************************************************************     11300021
         BALR  BASR,N0             SET PROGRAM BASE                     11400021
         USING *,BASR              ESTABLISH ADDRESSIBILITY             11500021
         USING DXSA,XSAR           ADDRESSIBILITY OF XSA                11600021
         L     CVTR,CVTPTR         ADDRESS OF CVT                       11700021
         USING DCVT,CVTR           ADDRESSIBILITY OF THE CVT            11800021
         L     UCMR,CVTCUCB        ADDRESS OF UCM FROM CVT              11900021
         USING DUCM,UCMR           ADDRESSIBILITY OF THE UCM            12000021
         TM    UCMMODE,UCMMCS      IS THIS A MCS SYSTEM                 12100021
         BNO   ERROR7              BRANCH NO FOR ERROR MSG              12200021
         SPACE 2                                                        12300021
*/* STARTSC: P (,TESTVB)              GET ADDRESS OF MR VERB FROM XSA   12400021
*/**/                                                                   12500021
*******************************************************************     12600021
STARTSC  EQU   *                                                        12700021
         L     LSTR,XAL            POINTER TO COMMAND PARAMETERS        12800021
         LA    WRK3,N1             ONE FOR SCAN INCREMENT AND BXLE      12900021
         XC    XAS(N4),XAS         CLEAR FLAG BYTES                     13000021
         CLI   N0(LSTR),PARA1      IS THERE MORE THEN ONE VERB          13100021
         BNE   TESTVB              BRANCH NO                            13200021
         OI    XASSDS,XASPRF1      SET VERB PARENTHESIS FLAG            13300021
         AR    LSTR,WRK3           INCREMENT OVER PARENTHESIS           13400021
         ST    LSTR,XAL            UPDATE LIST POINTER PAST PARENTHSIS  13500021
***                                                                   * 13700021
***   TEST FOR THE VERB OF THE MSGRT COMMAND                          * 13800021
***                                                                   * 13900021
         SPACE 2                                                        14000021
*/* TESTVB: D (YES,DISCOM,NO,%MN)     IS THE MR VERB DISPLAY */         14100021
*******************************************************************     14200021
TESTVB   EQU   *                                                        14300021
         CLC   N0(N2,LSTR),DIS     IS THIS A DISPLAY VERB?              14400021
         BE    DISCOM              BRANCH YES                           14500021
         SPACE 2                                                        14600021
*/* %MN:    D (YES,MONCOM,NO,%KK)     IS THE MR VERB MONITOR */         14700021
*******************************************************************     14800021
         CLC   N0(N3,LSTR),MON     IS THIS A MONITOR VERB?              14900021
         BE    MONCOM              BRANCH YES                           15000021
         EJECT                                                          15100021
*/* %KK:    D (YES,DISCONS,NO,RCTMEXT) IS THE MR VERB CONTROL */        15200021
*******************************************************************     15300021
         CLI   N0(LSTR),KCDR       IS THIS A CONTROL (K) VERB?          15400021
         BNE   RCTMEXT             BRANCH NO TO SECOND LOAD             15500021
         OI    XASSDS,XASKFG       SET K COMMAND FLAG                   15600021
         LR    WRK6,LSTR           SAVE ADDRESS OF VERB IN K CDR        15700021
         B     KCDRCHK             BRANCH TO CHECK FOR L OPERAND        15800021
         SPACE 2                                                        15900021
*/* DISCOM: P (,TABCOMP)              ADDRESS OF DISPLAY CDR TABLE */   16000021
*******************************************************************     16100021
DISCOM   EQU   *                                                        16200021
         LA    WRK1,DISTAB         ADDRESS OF DISPLAY VERB TABLE        16300021
SCANCHK  EQU   *                                                        16400021
         LA    LSTR,N2(LSTR)       INCREMENT TO FIRST VERB              16500021
         CLI   N0(LSTR),PARA1      IS THERE MORE THAN ONE VERB?         16600021
         BNE   DISTAB1             BRANCH NO                            16700021
         OI    XASSDS,XASPRF2      SET OPERAND PARENTHESIS FLAG         16800021
         AR    LSTR,WRK3           INCREMENT TO FIRST OPERAND           16900021
DISTAB1  EQU   *                                                        17000021
         LR    WRK6,LSTR           SAVE ADDRESS OF FIRST OPERAND        17100021
***                                                                   * 17200021
***  TEST THE OPERANDS OF THE MSGRT (MR) VERBS                        * 17300021
***                                                                   * 17400021
DISTABS  EQU   *                                                        17500021
         TM    XASSDS,XASMNFG      IS THIS A MONITOR VERB?              17600021
         BO    TABCOMP             BRANCH YES                           17700021
         CLC   N0(N8,LSTR),CONSOLES IS VERB OPERAND EQUAL TO CONSOLES?  17800021
         BNE   TABCOMP             BRANCH NO                            17900021
         MVI   N0(LSTR),CHARO      CHANGE C OF CONSOLES TO O FOR RCT    18000021
         LA    LSTR,N7(LSTR)       INCREMENT PAST OPERAND               18100021
         SPACE 2                                                        18200021
*/* DISCONS: D (YES,ERROR2,NO,LCHECK) ANY SYNTAX ERRORS IN CDR */       18300021
*******************************************************************     18400021
DISCONS  EQU   *                                                        18500021
         AR    LSTR,WRK3           INCREMENT PAST OPERAND               18600021
         CLI   N0(LSTR),BLK        IS THIS THE END OF THE COMAND        18700021
         BE    ENDSCAN             BRANCH YES                           18800021
         CLI   N0(LSTR),COMMA      IS THERE ANOTHER OPERAND?            18900021
         BE    SINGLED             BRANCH YES                           19000021
         CLI   N0(LSTR),PARA2      IS THIS END OF THE OPERANDS?         19100021
         BNE   ERROR               BRANCH NO                            19200021
         TM    XASSDS,XASPRF2      WAS THERE AN OPENING PARENTHESIS     19300021
         BNO   PARCHK              BRANCH NO                            19400021
         EJECT                                                          19450021
KCDRCHK  EQU   *                                                        19500021
         AR    LSTR,WRK3           INCREMENT PAST PARENTHSIS            19600021
***                                                                   * 19700021
***  WHAT CHARACTER FOLLOWS THE CLOSING OPERAND PARENTHSIS            * 19800021
***                                                                   * 19900021
         CLI   N0(LSTR),BLK        IS THIS THE END?                     20000021
         BE    ENDSCAN             BRANCH YES                           20100021
         SPACE 1                                                        20200021
*/* LCHECK: D (YES,%SL,NO,TABLECK)    IS A L OPERAND PRESENT IN CDR */  20300021
*******************************************************************     20400021
LCHECK   EQU   *                                                        20500021
         CLC   N0(N3,LSTR),CLEQUAL IS THIS THE LOCATION OPERAND?        20600021
         BNE   TESTEND             BRANCH NO                            20700021
         SPACE 1                                                        20800021
*/* %SL:    M (,LFOUND)               SET L PRESENT INDICATOR ON */     20900021
*******************************************************************     21000021
         OI    XASSDS,XASLFG       INDICATE THAT A L=VERB EXITS         21100021
         LA    LSTR,N3(LSTR)       INCREMENT AROUND L=                  21200021
         LR    WRK0,LSTR           SAVE ADDRESS OF L OPERAND            21300021
         LA    WRK4,N3(LSTR)       NUMBER OF PARAMETERS IN L=           21400021
LLOOP    EQU   *                                                        21500021
         CLI   N0(LSTR),BLK        IS THERE A BLANK?                    21600021
         BE    ENDSCAN             BRANCH YES                           21700021
         CLI   N0(LSTR),PARA2      IS THERE AN OPERAND PARENTHESIS?     21800021
         BE    ENDSCAN1            BRANCH YES                           21900021
         BXLE  LSTR,WRK3,LLOOP     INCREMENT LIST PTR AND TRY AGAIN     22000021
         B     ERROR               BRANCH TO INVALID OPERAND MSG        22100021
TESTEND  EQU   *                                                        22200021
         CLI   N0(LSTR),PARA2      IS THIS THE END OF THE VERB?         22300021
         BNE   ERROR               BRANCH NO                            22400021
PARCHK   EQU   *                                                        22500021
         TM    XASSDS,XASPRF1      WAS THERE A VERB PARENTHESIS         22600021
         BNO   ERROR               BRANCH NO                            22700021
ENDSCAN1 EQU   *                                                        22800021
         AR    LSTR,WRK3           INCREMENT LIST POINTER               22900021
ENDSCAN  EQU   *                                                        23000021
         CLI   N0(LSTR),BLK        IS THIS THE LAST MR VERB             23100021
         BNE   ENDSCAN2            BRANCH NO                            23200021
         NI    XASSDS,TF-XASPRF1   TURN OFF VERB PARENTHSIS FLAG        23300021
ENDSCAN2 EQU   *                                                        23400021
         AR    LSTR,WRK3           INCREMENT LIST POINTER               23500021
         LR    CDRR,LSTR           SAVE SCAN END FOR VERB               23600021
         LR    LSTR,WRK0           BEGINNING OF L OPERAND               23700021
         SR    WRK1,WRK1           CLEAR REG FOR CONSOLE ID             23800021
         SR    WRK4,WRK4           CLEAR REG FOR CONSOLE ID             23900021
         IC    WRK4,XAU            SOURCE CONSOLE ID                    24000021
         STC   WRK4,XASCID         EQUALS TARGET CONSOLE ID             24100021
         TM    XASSDS,XASLFG       IS A L OPERAND PRESENT               24200021
         BNO   VALIDX              BRANCH NO                            24300021
         EJECT                                                          24350021
***                                                                   * 24400021
***   FOUND THE L= OPERAND AND NOW MUST CHECK IT FOR VALIDITY         * 24500021
***                                                                   * 24600021
         SPACE 1                                                        24700021
*/* LFOUND: D (YES,%ML,NO,ERROR2)     IS L OPERAND VALID */             24800021
*******************************************************************     24900021
LFOUND   EQU   *                                                        25000021
         TM    N0(LSTR),XF0        IS THE FIRST CHAR  A NUMBER?         25100021
         BNO   STOREA              BRANCH NO                            25200021
         TM    N1(LSTR),XF0        IS THE SECOND CHAR A NUMBER?         25300021
         BO    TWODIGIT            BRANCH YES                           25400021
ONEDIGIT EQU   *                                                        25500021
         PACK  XAP(N8),N0(N1,LSTR) PACK CONSOLE ID IN XSA               25600021
         AR    LSTR,WRK3           INCREMENT LIST POINTER               25700021
         B     CHECKCC             BRANCH TO CONVERT NUMBER             25800021
TWODIGIT EQU   *                                                        25900021
         PACK  XAP(N8),N0(N2,LSTR) PACK CONSOLE ID IN XSA               26000021
         LA    LSTR,N2(LSTR)       INCREMENT LIST POINTER               26100021
CHECKCC  EQU   *                                                        26200021
         USING UCMLIST,ENTR        ADDRESSIBILITY OF UCM ENTRY          26300021
         CVB   WRK4,XAP            CONVERT CONSOLE ID TO BINARY         26400021
         L     ENTR,UCMVEL         LAST UCM ENTRY                       26500021
         IC    WRK1,UCMID          CONSOLE ID FROM LAST ENTRY           26600021
         SPACE 1                                                        26700021
*/* %ML:    P (,TABLECK)              MOVE L OPERAND INTO XSA */        26800021
*******************************************************************     26900021
         STC   WRK4,XASCID         SAVE VALID CONSOLE ID IN XSA         27000021
         CLR   WRK4,WRK1           IS CONSOLE ID FROM CDR VALID         27100021
         BH    ERROR4              BRANCH NO                            27200021
         CLI   N0(LSTR),BLK        IS THIS THE END OF THE COMMAND?      27300021
         BE    VALIDX              BRANCH YES                           27400021
         CLI   N0(LSTR),PARA2      IS THIS THE END OF A VERB?           27500021
         BE    VALIDX             BRANCH NO                             27600021
***                                                                   * 27700021
***  IS AREA ID A VALID ALPHABETIC CHARACTER                          * 27800021
***                                                                   * 27900021
STOREA   EQU   *                                                        28000021
         MVC   XASDID(N1),N0(LSTR) SAVE VALID AREA ID IN XSA            28100021
         CLI   N0(LSTR),CA         IS AREA ID EQUAL OR GREATER THAN A?  28200021
         BL    ERROR1              BRANCH NO                            28300021
         CLI   N0(LSTR),CI         IS AREA ID EQUAL OR LESS THAN I?     28400021
         BNH   STOREA1             BRANCH YES                           28500021
         CLI   N0(LSTR),CJ         IS AREA ID EQUAL OR GREATER THAN J   28600021
         BL    ERROR1              BRANCH NO                            28700021
         CLI   N0(LSTR),CR         IS AREA ID EQUAL OR LESS THAN R      28800021
         BNH   STOREA1             BRANCH YES                           28900021
         CLI   N0(LSTR),CS         IS AREA ID EQUAL OR GREATER THAN S   29000021
         BL    ERROR1              BRANCH NO                            29100021
         CLI   N0(LSTR),CZ         IS AREA ID EQUAL OR LESS THAN Z      29200021
         BH    ERROR1              BRANCH NO                            29300021
STOREA1  EQU   *                                                        29400021
         CLI   N1(LSTR),BLK        IS NEXT CHARACTER A BLANK            29500021
         BE    VALIDX              BRANCH YES                           29600021
         CLI   N1(LSTR),PARA2      IS NEXT CHARACTER A PARENTHSIS       29700021
         BNE   ERROR               BRANCH NO TO OPERAND                 29800021
VALIDX   EQU   *                                                        29900021
         IC    WRK1,XAU            GET SOURCE CONSOLE ID                30000021
         LR    LSTR,WRK1           SAVE SOURCE ID                       30100021
***                                                                   * 30200021
*** FIND AND SET BASE FOR UCM ENTRY - INPUT - WRK1 CONTAINS CONSOLE ID* 30300021
***                                 - OUTPUT - UCM ENTRY SPECIFIED BY * 30400021
***                                            ID IN ENTR REG         * 30500021
***                                                                   * 30600021
FINDUCME EQU   *                                                        30700021
         L     ENTR,UCMVEA         FIRST ENTRY FROM UCM                 30800021
         BCTR  WRK1,N0             SUBRRACT ONE FROM CONSOLE ID         30900021
         M     WRK0,UCMVEZ         MULIPLY ENTRY SIZE BY REDUCED ID     31000021
         AR    ENTR,WRK1           ADDRESS OF DESIRED UCM ENTRY         31100021
         CR    LSTR,WRK4           IS SOURCE SAME AS TARGET             31200021
         BE    KCDRCK              BRANCH YES                           31300021
         TM    UCMAUTH,UCMAUTH3    DOES SOURCE CONSOLE HAVE AUTHORITY   31400021
*                                   TO ROUTINE (MUST HAVE CONS AUTH.)   31500021
         BZ    ERROR6              BRANCH NO                            31600021
KCDRCK   EQU   *                                                        31700021
         TM    XASSDS,XASKFG       IS VERB A K COMMAND                  31800021
         BNO   TABLECK             BRANCH NO                            31900021
         TM    UCMDISP,UCMDISPC    IS CONSOLE A CRT?                    32000021
         BO    ERROR2              BRANCH YES TO ERROR MSG              32100021
         SPACE 2                                                        32200021
*/* TABLECK: D (YES,TESTRCT,NO,STARTRCT) DOES A ROUTE TABLE EXIST */    32300021
*******************************************************************     32400021
TABLECK  EQU   *                                                        32500021
         L     RCTR,UCMRCT         RCT ADDRESS FROM UCM ENTRY           32600021
         L     LSTR,XAL            BEGINNING OF VERB ADDRESS            32700021
         LA    RCTR,N0(RCTR)       ZERO FLAG BYTE                       32800021
         LTR   RCTR,RCTR           DOES A TABLE EXIT?                   32900021
         BNZ   TESTRCT             BRANCH YES                           33000021
         LA    RCTR,UCMRCT         ADDRESS OF RCT IN UCM                33100021
         EJECT                                                          33200021
*/* STARTRCT: S (,BUILDX) GETMAIN:       GET CORE FOR RCT TABLE */      33300021
*******************************************************************     33400021
STARTRCT EQU   *                                                        33500021
***                                                                   * 33600021
***   ROUTINE TO ISSUE GETMAIN FOR RCT SECTION                        * 33700021
***                                                                   * 33800021
GETCORE  EQU   *                                                        33900021
         LA    WRK1,XAX+N4         AREA TO STORE ADDRESS FROM GETMAIN   34000021
         MVC   XAP(N10),GETAREA    MOVE PARAMETER LIST INTO XSA         34100021
         ST    WRK1,XAD            ALTER ADDRESS FOR GETMAIN            34200021
         LA    WRK1,XAP            ADDRESS OF PARAMETER LIST            34300021
         GETMAIN MF=(E,(1))        STORAGE FOR A RCT                    34400021
         LTR   LNKR,LNKR           IS RETURN CODE NON ZERO?             34500021
         BNZ   ERROR3              BRANCH YES                           34600021
         USING DSTRCT,WRK4                                              34700021
         L     WRK4,XAX+N4         ADDRESS OF NEW SECTION OF RCT        34800021
         XC    RCTBEG(RCTTEND-RCTBEG),RCTBEG CLEAR AREA GOTTEN FOR RCT  34900021
         OI    RCTENT6,RCTCON      SET CONTINUE FLAG IN SECTION         35000021
         DROP  WRK4                                                     35100021
         USING DSTRCT,RCTR         ADDRESSIBILITY OF RCT                35200021
***                                                                   * 35300021
***   START BUILDING NEW ENTRIES IN THE RCT                           * 35400021
***                                                                   * 35500021
         MVC   N1(N3,RCTR),XAX+N5 ADDRESS OF RCT INTO UCM               35600021
         LR    RCTR,WRK4           ADDRESS OF CORE GOTTEN FOR RCT       35700021
         SPACE 2                                                        35800021
*/* BUILDX: P (,MOVECA)               BUILD TABLE ENTRY FOR THIS CDR */ 35900021
*******************************************************************     36000021
BUILDX   EQU   *                                                        36100021
         OI    RCTCODE,RCTEND       TURN ON END AND ACTIVE FLAG         36200021
VERBCOD  EQU   *                                                        36300021
         MVC   RCTVER(N2),N0(LSTR)  MOVE ROUTE VERB INTO RCT            36400021
MOVEOP1  EQU   *                                                        36500021
         MVC   RCTOPD(N1),N0(WRK6) MOVE OPERAND INTO RCT                36600021
         SPACE 2                                                        36700021
*/* MOVECA: P (,CONENT)               INSERT L OPERAND FROM XSA */      36800021
*******************************************************************     36900021
MOVECA   EQU   *                                                        37000021
         OI    RCTCODE,RCTACT      SET ENTRY ACTIVE IN RCT              37100021
         MVC   RCTCID(N2),XASCID   MOVE CONSOLE AND AREA ID INTO RCT    37200021
         EJECT                                                          37300021
*/* CONENT: D (YES,OPEREND,NO,%SNA)   DOES CDR HAVE L OPERAND */        37400021
*******************************************************************     37500021
CONENT   EQU   *                                                        37600021
         TM    XASSDS,XASLFG       IS A L OPERAND IN THIS COMMAND       37700021
         BO    CONENT1             BRANCH YES AND LEAVE ACTIVE          37800021
         SPACE 2                                                        37900021
*/* %SNA:   M (,OPEREND)              SET RCT ENTRY NON-ACTIVE */       38000021
*******************************************************************     38100021
         NI    RCTCODE,TF-RCTACT   TURN OFF ACTIVE BIT IN RCT           38200021
CONENT1  EQU   *                                                        38300021
         CLI   N1(WRK6),COMMA      IS NEXT CHARACTER A COMMA?           38400021
         BE    NEWENBK             BRANCH EQUAL                         38500021
         CLI   N1(WRK6),PARA2      IS NEXT CHARACTER A PARENTHSIS?      38600021
         BE    OPEREND             BRANCH EQUAL                         38700021
         CLI   N1(WRK6),BLK        IS NEXT CHARACTER A BLANK            38800021
         BE    OPEREND             BRANCH YES                           38900021
***                                                                   * 39000021
***  ALL OPERANDS ARE REPRESENTED BY THERE FIRST CHARACTER EXCEPT THE * 39100021
***   CONSOLE OPERAND WHICH IS REPRESENTED BY ITS SECOND CHARACTER  O * 39200021
***                                                                   * 39300021
         LA    WRK6,N7(WRK6)       INCREMENT AROUND OPERAND             39400021
         B     CONENT              BRANCH TO CONTINUE                   39500021
         SPACE 2                                                        39600021
*/* OPEREND: D (YES,STARTSC,NO,%RET)  DOES CDR HAVE ANOTHER OPERAND */  39700021
*******************************************************************     39800021
OPEREND  EQU   *                                                        39900021
         TM    XASSDS,XASPRF1      IS PARENTHSIS FLAG ON                40000021
         BO    NEXTVRB             BRANCH YES                           40100021
         SPACE 2                                                        40200021
*/* %RET:   R                         RETURN BR 14 */                   40300021
*******************************************************************     40400021
         BR    RETR                RETURN TO CALLER                     40500021
NEXTVRB  EQU   *                                                        40600021
         ST    CDRR,XAL            ADDRESS OF NEXT MSGRT VERB           40700021
         B     STARTSC             BRANCH TO START FOR NEXT VERB        40800021
NEWENBK  EQU   *                                                        40900021
         TM    XASSDS,XASPRF2      IS SECOND PARENTHSIS FLAG ON         41000021
         BNO   OPEREND             BRANCH NO TO END                     41100021
         LA    WRK6,N2(WRK6)       INCREMENT OPERAND POINTER            41200021
         L     RCTR,UCMRCT         STARTING ADDRESS OF RCT              41300021
         EJECT                                                          41350021
***                                                                   * 41400021
***  SEARCH RCT FOR AN EXISTING ENTRY AND OVERLAY CC AND A IF FOUND   * 41500021
***                                                                   * 41600021
         SPACE 2                                                        41700021
*/* TESTRCT: D (YES,MOVECA,NO,LDENT) DOES TABLE CONTAIN THIS CDR */     41800021
*******************************************************************     41900021
TESTRCT  EQU   *                                                        42000021
         CLC   RCTVER(N1),N0(LSTR) DOES VERB IN RCT EQUAL ROUTE VERB    42100021
         BE    CHKOPD              BRANCH YES                           42200021
INCRCT   EQU   *                                                        42300021
         TM    RCTCODE,RCTCON      IS THIS RCT ENTRY THE END OR CONT    42400021
         BO    NXTPTR              BRANCH YES IT IS CONTINUED           42500021
         BM    LDENT               BRANCH YES IT IS END                 42600021
         LA    RCTR,RCTLEN(RCTR)   INCREMENT TO NEXT RCT ENTRY          42700021
         B     TESTRCT             BRANCH TO TEST NEXT ENTRY            42800021
NXTPTR   EQU   *                                                        42900021
         L     RCTR,N0(RCTR)       LOAD ADDRESS OF NEW SECTION          43000021
         B     TESTRCT             BRANCH TO TEST NEXT ENTRY            43100021
CHKOPD   EQU   *                                                        43200021
         CLC   RCTOPD(N1),N0(WRK6) IS OPERANDS EQUAL TO ONE CHARACTER   43300021
         BNE   INCRCT              BRANCH NO TO CHECK NEXT ENTRY        43400021
         B     MOVECA              BRANCH TO INSERT NEW CC AND A        43500021
***                                                                   * 43600021
***  SEARCH RCT FOR NON ACTIVE ENTRIES OR BUILD A NEW ENTRY           * 43700021
***                                                                   * 43800021
         SPACE 2                                                        43900021
*/* LDENT:   P (,SEARACT)                 SEARCH RCT FOR END OR A       44000021
*/*NON-ACTIVE ENTRY */                                                  44100021
*******************************************************************     44200021
LDENT EQU   *                                                           44300021
         L     RCTR,UCMRCT         ADDRESS OF RCT FROM UCM              44400021
         SPACE 2                                                        44500021
*/* SEARACT: D (YES, NXTPTR1,NO,%NAE) IS THIS ENTRY CONTINUED */        44600021
*******************************************************************     44700021
SEARACT  EQU   *                                                        44800021
         TM    RCTCODE,RCTCON      IS THIS ENTRY THE END OR CONTINUED   44900021
         BO    NXTPTR1             BRANCH YES IT IS CONTINUED           45000021
         SPACE 2                                                        45100021
*/* %NAE:   D (YES,BUILDX,NO,%EED)    IS THIS ENTRY NON-ACTIVE */       45200021
*******************************************************************     45300021
         TM    RCTCODE,RCTACT      IS THIS ENTRY ACTIVE                 45400021
         BNO   VERBCOD             BRANCH NO TO CONSTRUCT ENTRY         45500021
         EJECT                                                          45600021
*/* %EED:   D (YES,BUILD1,NO,%IIN)    IS THIS ENTRY THE END */          45700021
*******************************************************************     45800021
         TM    RCTCODE,RCTEND      IS THIS ENTRY THE END                45900021
         BO    BUILD1              BRANCH YES IT IS THE END             46000021
         SPACE 2                                                        46100021
*/* %IIN:   M (,SEARACT)              INCREMENT TO NEXT RCT ENTRY */    46200021
*******************************************************************     46300021
         LA    RCTR,RCTLEN(RCTR)   INCREMENT FOR NEXT ENTRY             46400021
         B     SEARACT             BRANCH TO CONTINUE SEARCH            46500021
         SPACE 2                                                        46600021
*/* NXTPTR1: P (,SEARACT)             LOAD ADDRESS OF NEXT RCT SECTION  46700021
*/**/                                                                   46800021
*******************************************************************     46900021
NXTPTR1  EQU   *                                                        47000021
         L     RCTR,N0(RCTR)       LOAD NEXT SECTION                    47100021
         B     SEARACT             BRANCH TO CONTINUE                   47200021
         SPACE 2                                                        47300021
*/* BUILD1: M (,%CNT)                 TURN OFF END INDICATOR, GET       47400021
*/* NEXT RCT ENTRY */                                                   47500021
*******************************************************************     47600021
BUILD1   EQU   *                                                        47700021
         NI    RCTCODE,TF-RCTEND   TURN OFF END INDICATOR               47800021
         LA    RCTR,RCTLEN(RCTR)   NEXT RCT ENTRY                       47900021
         SPACE 2                                                        48000021
*/* %CNT:   D (YES,STARTRCT,NO,BUILDX) IS THIS ENTRY CONTINUED */       48100021
*******************************************************************     48200021
         TM    RCTCODE,RCTCON      IS THIS RCT ENTRY CONTINUED          48300021
         BNO   BUILDX              BRANCH NO                            48400021
         B     STARTRCT            BRANCH TO BUILD RCT ENTRY            48500021
         EJECT                                                          48600021
*/* MONCOM: P (,TABCOMP)              ADDRESS OF MONITOR CDR TABLE */   48700021
*******************************************************************     48800021
MONCOM   EQU   *                                                        48900021
         LA    WRK1,MONTAB         ADDRESS OF DISPLAY VERB TABLE        49000021
         OI    XASSDS,XASMNFG      SET MONITOR VERB FLAG                49100021
         AR    LSTR,WRK3           INCREMENT LIST POINTER               49200021
         B     SCANCHK             BRANCH TO CONTINUE SCAN              49300021
SINGLED  EQU   *                                                        49400021
         AR    LSTR,WRK3           INCREMENT LIST POINTER               49500021
         TM    XASSDS,XASMNFG      IS THIS A MONITOR COMMAND?           49600021
         BO    DISTABS             BRANCH YES                           49700021
         LA    WRK1,DISTAB         ADDRESS OF DISPLAY VERB TABLE        49800021
         B     DISTABS             BRANCH TO CHECK NEXT VERB            49900021
         SPACE 2                                                        50300021
*/* TABCOMP: D (YES,DISCONS,NO,ERROR2) ARE THE OPERANDS VALID */        50400021
*******************************************************************     50500021
TABCOMP  EQU   *                                                        50600021
         CLC   N0(N1,LSTR),N0(WRK1) IS OPERAND EQUAL TO TABLE ENTRY?    50700021
         BE    DISCONS             BRANCH YES                           50800021
         AR    WRK1,WRK3           INCREMENT LIST POINTER               50900021
         CLI   N0(WRK1),TEND       IS THIS THE TABLE END?               51000021
         BNE   DISTABS             BRANCH NO FOR NEXT COMPARE           51100021
         BCTR  LSTR,N0             DECREMENT LIST POINTER TO COMMA      51200021
         B     LCHECK              BRANCH NO FOR NEXT COMPARE           51300021
         EJECT                                                          51350021
***                                                                   * 51400021
***  SET FLAGS IN XSA TO INDECATE ERROR HAS OCCURRED IN THE FIRST LOAD* 51500021
***                                                                   * 51600021
         SPACE 2                                                        51700021
*/* ERROR2: P (,RCTMEXT)              SET ERROR CODE IN XSA */          51800021
*******************************************************************     51900021
ERROR2   EQU   *                                                        52000021
         MVI   XAE,KERROR          K CDR WAS ISSUED FROM A CRT          52100021
         B     RCTMEXT             EXIT FOR SECOND LOAD                 52200021
ERROR3   EQU   *                                                        52300021
         MVI   XAE,NCERROR         NO CORE AVAILABLE FOR ROUTE TABLE    52400021
         B     RCTMEXT             EXIT FOR SECOND LOAD                 52500021
ERROR1   EQU   *                                                        52600021
         MVI   XASTSAVE,AIERROR    AREA ID NOT A VALID LETTER           52700021
         B     ERROR5              EXIT FOR SECOND LOAD                 52800021
ERROR4   EQU   *                                                        52900021
         MVI   XASTSAVE,CIERROR    CONSOLE ID NOT VALID                 53000021
ERROR5   EQU   *                                                        53100021
         MVI   XAE,LIERROR         CCA NOT A VALID L OPERAND            53200021
         B     RCTMEXT             EXIT FOR SECOND LOAD                 53300021
ERROR6   EQU   *                                                        53400021
         MVI   XAE,RIERROR         CONSOLE DID NOT HAVE VALID MR AUTHOR 53500021
         B     RCTMEXT             EXIT FOR SECOND LOAD                 53600021
ERROR7   EQU   *                                                        53700021
         MVI   XAE,MCSERROR        MSGRT CDR VALID ONLY IN MCS SYSTEM   53800021
         B     RCTMEXT             EXIT FOR SECOND LOAD                 53900021
ERROR    EQU   *                                                        54000021
         LR    WRK6,LSTR           OPERAND POINTER FOR ERROR MSG        54100021
         MVI   XAE,IOERROR         INVALID OPERAND IN MR CDR            54200021
         EJECT                                                          54250021
***                                                                   * 54300021
***  EXIT FROM FIRST LOAD TO SECOND LOAD OF MSGRT COMMAND HANDLER     * 54400021
***                                                                   * 54500021
         SPACE 2                                                        54600021
*/* RCTMEXT: P (,%EXT)                MOVE ADDRESS OF SECOND LOAD INTO  54700021
*/*XSA */                                                               54800021
*******************************************************************     54900021
RCTMEXT  EQU   *                                                        55000021
         MVC   XAX(N8),RCTM2       NAME OF SECOND LOAD INTO XAX         55100021
         LA    WRK1,XAX            REINITIALIZE XSA                     55200021
         ST    WRK1,XAP            POINT XAP TO MODULE NAME IN XAX      55300021
         SR    WRK1,WRK1           STORE ZERO DCB POINTER               55400021
         ST    WRK1,XAD                   IN XAD                        55500021
         SPACE 2                                                        55600021
*/* %EXT:   R                         IEE6403D MR MSG MODULE 2 */       55700021
*******************************************************************     55800021
         XCTL  SF=(E,(XSAR))        XCTL TO SECOND LOAD                 55900021
         SPACE 2                                                        56100021
*/* IEE6303D: END */                                                    56200021
*******************************************************************     56300021
         EJECT                                                          56400021
********                                                              * 56500021
******** CONSTANT USED BY ROUTINE                                     * 56600021
********                                                              * 56700021
DIS      DC    C'D='               DISPLAY VERB                         56710021
GETAREA  GETMAIN EC,LV=RCTTEND-RCTBEG,A=RCTMEXT,SP=SUBP,MF=L            56750021
CONSOLES DC    C'CONSOLES'         CONSOLE OPERAND                      56800021
MONTAB   DC    C'A'                MONITOR OPERAND TABLE                56900021
         DC    X'FF'               TABLE END                            57000021
DISTAB   DC    C'ANUMQC'           DISPLAY OPERAND TABLE                57100021
         DC    X'FF'               TABLE END                            57200021
MON      DC    C'MN='              MONITOR VERB                         57300021
CLEQUAL  DC    C',L='              L OPERAND                            57500021
RCTM2    DC    C'IGC6403D'         NAME OF SECOND LOAD OF MR MSG MODULE 57600021
PATCH    DC    C'****PATCH AREA****'                                    57700021
PATCH2   DC    C'IEE6303D-TEST ONLY'                                    57800021
PATCH3   DC    35C' '                                                   57900021
         EJECT                                                          58000021
DUCM     DSECT                                                          58100021
         IEECUCM                                                        58200021
         EJECT                                                          58300021
DXSA     DSECT                                                          58400021
         IEEXSA                                                         58500021
**                                                                    * 58600021
**  THE XAP AND XAD FIELDS OF THE XSA ARE USED AS A DOUBLE WORD       * 58700021
**   WORK AREA IN THIS MODULE AND ARE RESTORED BEFORE EXIT            * 58800021
**                                                                    * 58900021
**  THE XAS FIELD OF THE XSA IS USED AS FOLLOWS IN THIS MODULE        * 59000021
         ORG   XAS                                                      59100021
XASCID   DS    X                   CONSOLE ID                           59200021
XASDID   DS    C                   DISPLAY AREA ID                      59300021
XASSDS   DS    X                   SDS SWITCHES                         59400021
XASDFG   EQU   X'80'               THE VERB IS A DISPLAY COMMAND        59500021
XASMNFG  EQU   X'40'               THE THE VERB IS A MONITOR COMMAND    59600021
XASKFG   EQU   X'20'               THE VERB IS A K COMMAND              59700021
XASRFG   EQU   X'10'               THE VERB IS A REFERENCE COMMAND      59800021
XASLFG   EQU   X'08'               THE L OPERAND IS PRESENT IN THE VERB 59900021
XASOPFG  EQU   X'04'               THERE IS MORE THAN ONE OPERAND       60000021
XASPRF1  EQU   X'02'               THERE IS MORE THAN ONE VERB          60100021
XASPRF2  EQU   X'01'               THERE IS MORE THAN ONE OPERAND       60200021
XASSDSF  DS    X                   SDS SWITCHES BYTE TWO                60300021
XASTSAVE DS    C                   ONE WORD TEMPORY SAVE AREA           60400021
         DS    3C                  ONE WORD TEMPORY SAVE AREA           60500021
         EJECT                                                          60600021
DCVT     DSECT                                                          60700021
         CVT                                                            60800021
         EJECT                                                          60900021
*********************************************************************** 61000021
*                                                                     * 61100021
*   THE ROUTE COMMAND TABLE IS GOTTEN BY A GETMAIN AND EACH SECTION   * 61200021
*   IS MADE UP OF FIVE ENTRIES PLUS A POINTER TO THE THE NEXT SECTION.* 61300021
*   EACH ENTRY IS EIGHT BYTES LONG, THE FIRST BYTE IS A FLAG, THE NEXT* 61400021
*   TWO BYTES ARE THE OPERAND, THE NEXT THREE BYTES ARE THE VERB, AND * 61500021
*   THE LAST TWO BYTES ARE THE CONSOLE ID IN BINARY PLUS THE AREA ID  * 61600021
*   IN EBCDIC                                                         * 61700021
*                                                                     * 61800021
*                                                                     * 61900021
*********************************************************************** 62000021
DSTRCT   DSECT                                                          62100021
RCTBEG   EQU   *                   ALIGN TABLE ON DOUBLE WORD           62200021
RCTCODE  DS    1C                  FLAGS INDICATING STATUS OF ENTRY     62300021
RCTCON   EQU   X'C0'               FLAG INDICATES END OF SECTION        62400021
RCTEND   EQU   X'80'               FLAG INDICATES LAST DEFINED ENTRY    62500021
RCTRES   EQU   X'02'               FLAG INDICATES ENTRY DISPLAYED       62600021
RCTACT   EQU   X'01'               FLAG INDICATES ENTRY IS DEFINED      62700021
RCTVER   DS    2C                  VERB FROM THE MSGRT COMMAND          62800021
RCTOPD   DS    2C                  OPERAND FROM THE MSGRT COMMAND       62900021
RCTCID   DS    1C                  CONSOLE ID FROM THE MSGRT COMMAND    63000021
RCTAID   DS    1C                  AREA ID FROM THE MSGRT COMMAND       63100021
RCTUNU   DS    1C                  UNUSED BYTE IN TABLE                 63200021
RCTLEN   EQU   8                   LENGTH OF ONE ENTRY OF THE RCT       63300021
RCTENT2  DS    8C                  SECOND ENTRY IN RCT                  63400021
RCTENT3  DS    8C                  THIRD ENTRY IN RCT                   63500021
RCTENT4  DS    8C                  FOURTH ENTRY IN RCT                  63600021
RCTENT5  DS    8C                  FIFTH ENTRY IN RCT                   63700021
RCTENT6  DS    8C                  CONTINUED OR ZERO IF LAST SECTION    63800021
RCTPTR   EQU   RCTENT6             FIRST WORD OF RCT LAST ENTRY HAS     63900021
*                                  ZERO IF LAST OR A POINTER TO NEXT    64000021
RCTTEND  EQU   *                   END OF ONE SECTION OF RCT            64100021
         END                                                            64200021
