         TITLE 'IEE6403D IGC6403D  MSGRT COMMAND HANDLER LOAD TWO'      00100021
*********************************************************************** 00200021
*                                                                     * 00300021
* STATUS -- CHANGE LEVEL 0                                            * 00400021
*                                                                     * 00500021
* FUNCTION -- THIS ROUTINE IS PART OF SVC 34 AND HANDLES A PART OF    * 00600021
*    THE MSGRT COMMAND (MR REF).IT ALSO HANDLES ANY ERROR CONDITIONS  * 00700021
*    FOUND IN THE FIRST LOAD OF THE ROUTE COMMAND.IF AN ERROR CODE    * 00800021
*    IS FOUND AN XCTL IS MADE TO THE ERROR MESSAGE MODULE.IF THE      * 00900021
*    COMMAND IS A MR REF THE ROUTE CONTROL TABLE (RCT) IS SEARCHED    * 01000021
*    AND THE ACTIVE ENTRIES ARE FORMATTED AND DISPLAYED WITH A WTO OR * 01100021
*    IF THE COMMAND WAS ENTERED FROM A CRT THE MESSAGE IS PLACED IN   * 01200021
*    THE DCM FOR DISPLAY IN THE ENTRY AREA. A MESSAGE CODE IS MOVE TO * 01300021
*    THE XSA AND A EXIT IS MADE TO THE MESSAGE MODULE                 * 01400021
*                                                                     * 01500021
* ENTRY POINTS -- IEE6403D                                            * 01600021
*                                                                     * 01700021
* INPUT -- REGISTER TWO ADDRESS OF THE EXTENDED SAVE AREA(XSA)        * 01800021
*          REGISTER ELEVEN ADDRESS OF FIRST VERB OF THE COMMAND       * 01900021
*          REGISTER SIX  ADDRESS OF INVALID OPERAND IF AN EROR CODE   * 02000021
*                                                                     * 02100021
* OUTPUT -- FORMATTED DISPLAY OF THE RCT                              * 02200021
*                                                                     * 02300021
* EXTERNAL REFERENCE -- GETMAIN (SVC  4), FREEMAIN (SVC 5)            * 02400021
*                       XCTL (SVC 7), WTO (SVC 35)                    * 02500021
*                                                                     * 02600021
* EXITS,NORMAL -- RETURN VIA BRANCH REGISTER FOURTEEN                 * 02700021
*                 XCTL TO IEE5603D FOR MESSAGE OUTPUT                 * 02800021
*                                                                     * 02900021
* EXITS,ERROR -- XCTL  TO IEE5603D  FOR ERROR MESSAGE OUTPUT          * 03000021
*                                                                     * 03100021
* TABLES/WORK AREA -- UNIT CONTROL MODULE (UCM)                       * 03200021
*                     ROUTING CONTROL TABLE (RCT)                     * 03300021
*                     EXTENDED SAVE AREA (XSA)                        * 03400021
*                                                                     * 03500021
* ATTRIBUTES -- REENTRANT, TRANSIENT                                  * 03600021
*                                                                     * 03700021
* NOTES -- THIS MODULE WAS CREATED FOR RELEASE 21 TO SUPPORT STATUS   * 03800021
*    DISPLAY SYSTEM'S (SDS) NEW MSGRT (MR) COMMAND WHICH IS A NEW SDS * 03900021
*    FUNCTION. THIS IS THE SECOND LOAD OF THE ROUTE COMMAND HANDLER   * 04000021
*                                                                     * 04100021
*********************************************************************** 04200021
         EJECT                                                          04300021
IEE6403D CSECT                                                          04400021
********                                                              * 04500021
******** REGISTER EQUATES                                             * 04600021
********                                                              * 04700021
WRK0     EQU   0                   WORK REGISTER                        04800021
WRK1     EQU   1                   WORK REGISTER                        04900021
XSAR     EQU   2                   BASE REGISTER FOR THE XSA            05000021
WRK3     EQU   3                   WORK REGISTER                        05100021
WRK4     EQU   4                   WORK REGISTER                        05200021
BALR     EQU   5                   BRANCH AND LINK REGISTER             05300021
WRK6     EQU   6                   WORK REGISTER                        05400021
ENTR     EQU   7                   BASE REGISTER FOR THE UCM ENTRY      05500021
RCTR     EQU   8                   BASE REGISTER FOR THE RCT            05600021
UCMR     EQU   9                   BASE REGISTER FOR THE UCM            05700021
CVTR     EQU   10                  BASE REGISTER FOR THE CVT            05800021
LSTR     EQU   11                  LIST POINTER FROM XSA                05900021
BASR     EQU   12                  ROUTINE BASE REGISTER                06000021
SAVR     EQU   13                  SAVE REGISTER                        06100021
RETR     EQU   14                  RETURN REGISTER                      06200021
LNKR     EQU   15                  LINK REGISTER                        06300021
         EJECT                                                          06350021
********                                                              * 06400021
******** OTHER EQUATES                                                * 06500021
********                                                              * 06600021
N0       EQU   0                   NUMBER CONSTANT                      06700021
N1       EQU   1                   NUMBER CONSTANT                      06800021
N2       EQU   2                   NUMBER CONSTANT                      06900021
N3       EQU   3                   NUMBER CONSTANT                      07000021
N4       EQU   4                   NUMBER CONSTANT                      07100021
N5       EQU   5                   NUMBER CONSTANT                      07200021
N6       EQU   6                   NUMBER CONSTANT                      07300021
N7       EQU   7                   NUMBER CONSTANT                      07400021
N8       EQU   8                   NUMBER CONSTANT                      07500021
N9       EQU   9                   NUMBER CONSTANT                      07600021
N10      EQU   10                  NUMBER CONSTANT                      07700021
N11      EQU   11                  NUMBER CONSTANT                      07800021
N12      EQU   12                  NUMBER CONSTANT                      07900021
N138     EQU   138                 NUMBER CONSTANT                      08000021
N150     EQU   150                 NUMBER CONSTANT                      08100021
CA       EQU   C'A'                A CONSTANT                           08200021
CI       EQU   C'I'                I CONSTANT                           08300021
CJ       EQU   C'J'                J CONSTANT                           08400021
CR       EQU   C'R'                R CONSTANT                           08500021
CS       EQU   C'S'                S CONSTANT                           08600021
CZ       EQU   C'Z'                Z CONSTANT                           08700021
CHARO    EQU   C'O'                CHARACTER CONSTANT                   08800021
CHARK    EQU   C'K'                CONTROL VERB                         08900021
CHARM    EQU   C'M'                MONITOR VERB                         09000021
COMMA    EQU   C','                COMMA CHARACTER                      09100021
PARA2    EQU   C')'                PARENTHSIS CONSTANT                  09200021
PARA1    EQU   C'('                PARENTHSIS CONSTANT                  09300021
EQUAL    EQU   C'='                CHARACTER CONSTANT                   09400021
BLK      EQU   X'40'               BLANK CONSTANT                       09500021
TF       EQU   X'FF'               FLAG TO TURN OF SWITCHES             09600021
SUBP     EQU   255                 SUBPOOL FOR GETMAIN AND FREEMAIN     09700021
XF0      EQU   X'F0'               NUMBER ZONE                          09800021
ZERO     EQU   0                   TO TEST FOR ERROR CODE PRESENT       09900021
CHGOPT   EQU   2                   ERROR CODE FOR CHANGE OPTIONS MSG    10000021
IOERROR  EQU   4                   ERROR CODE FOR INVALID OPERAND       10100021
KERROR   EQU   11                  ERROR CODE FOR INVALID K MSG         10200021
LIERROR  EQU   12                  ERROR CODE FOR INVALID L OPERAND     10300021
NONCRT   EQU   27                  SECONDARY CODE FOR INVALID K MSG     10400021
KVERB    EQU   X'40'               K CDR FLAG                           10500021
MCSFG    EQU   X'E0'               MCS FLAGS FOR WTO                    10600021
CF0      EQU   X'F0'               NUMBER MSSK                          10700021
XFF      EQU   X'FF'               END OF VERB TABLE                    10800021
MOPD1    EQU   X'08'               OPERAND INTO BUFFER FLAG             10900021
MOPD2    EQU   X'04'               MULTIPLE OPERANDS FLAG               11000021
MVRB1    EQU   X'02'               VERB INTO BUFFER FLAG                11100021
MVRB2    EQU   X'01'               MULTIPLE VERB FLAG                   11200021
***                                                                     11300021
         EJECT                                                          11400021
*/* IEE6403D: CHART */                                                  11500021
*/* %START: E (,STARTSC)              IEE6403D   MSGRT (MR) MODULE TWO  11600021
*/* */                                                                  11700021
*****************************************************************       11800021
         BALR  BASR,N0             SET PROGRAM BASE                     11900021
         USING *,BASR              ESTABLISH ADDRESSIBILITY             12000021
         USING DXSA,XSAR           ADDRESSIBILITY OF XSA                12100021
         USING DSTRCT,RCTR         ADDRESSIBILITY OF RCT                12200021
         L     CVTR,CVTPTR         ADDRESS OF CVT                       12300021
         USING DCVT,CVTR           ADDRESSIBILITY OF THE CVT            12400021
         L     UCMR,CVTCUCB        ADDRESS OF UCM FROM CVT              12500021
         USING DUCM,UCMR           ADDRESSIBILITY OF THE UCM            12600021
         USING UCMLIST,ENTR        ADDRESSIBILITY OF UCM ENTRY          12700021
***                                                                   * 12800021
***   SECOND LOAD OF THE MSGRT HANDLER IS ENTERED FOR TWO CONDITIONS  * 12900021
***   IF AN ERROR CONDITION HAS BEEN FOUND IN THE FIRST LOAD          * 13000021
***   OR IF A MR REF COMMAND HAS BEEN ISSUED                          * 13100021
***                                                                   * 13200021
         SPACE 2                                                        13300021
*/* STARTSC: D (YES,ERROR,NO,REFFMT)  IS THERE AN ERROR CODE IN XSA */  13400021
*****************************************************************       13500021
STARTSC  EQU   *                                                        13600021
         CLI   XAE,ZERO            IS THERE AN ERROR CODE PRESENT?      13700021
         BNE   ERROR               BRANCH YES TO MSG MODULE EXIT        13800021
***                                                                   * 13900021
***   TEST FOR THE VERB OF THE MSGRT COMMAND                          * 14000021
***                                                                   * 14100021
         SPACE 2                                                        14200021
*/* REFFMT: D (YES,%DD1,NO,ERROR1)    IS THIS A MR REF COMMAND */       14300021
*****************************************************************       14400021
REFFMT   EQU   *                                                        14500021
         CLC   N0(N4,LSTR),REF     IS THIS A REFERENCE VERB?            14600021
         BNE   ERROR1              BRANCH TO INVALID OPERAND MSG        14700021
         SR    WRK1,WRK1           CLEAR REG                            14800021
         IC    WRK1,XAU            GET SOURCE CONSOLE ID                14900021
         BAL   BALR,FINDUCME       BRANCH TO FIND UCM ENTRY             15000021
         SPACE 2                                                        15100021
*/* %DD1:   D (YES,%PP1,NO,WRITE1)    IS THE CONSOLE A CRT */           15200021
*****************************************************************       15300021
         TM    UCMDISP,UCMDISPC    IS THIS CONSOLE A CRT                15400021
         BNO   WRITE1              BRANCH NO                            15500021
         L     CVTR,UCMXB          ADDRESS OF RESIDENT DCM              15600021
         L     CVTR,N0(CVTR)       ADDRESS OF TRANSIENT DCM             15700021
         USING DTDCM,CVTR          ADDRESSIBILITY OF TRANSIENT DCM      15800021
         EJECT                                                          15900021
*/* %PP1:   P (,BUILDL)               GET ADDRESS OF DCM ENRTY AREA */  16000021
*****************************************************************       16100021
         L     WRK3,DCMAENTR       ADDRESS OF ENTRY AREA OF DCM         16200021
         LH    WRK4,DCMLGNTH       LENGTH OF LINE FROM DCM              16300021
         AR    WRK4,WRK4           TWO LINES IN ENTRY AREA              16400021
BUILDL   EQU   *                                                        16500021
         BAL   BALR,BLINST         BLANK INST. LINE                     16600021
         SR    WRK6,WRK6           CLEAR COUNT REG                      16700021
         MVC   N0(N3,WRK3),RTVB    MOVE MSGRT COMMAND INTO BUFFER       16800021
         LA    WRK3,N3(WRK3)       INCREMENT BUFFER AROUND MR CDR       16900021
         L     RCTR,UCMRCT         ADDRESS OF RCT FROM UCM              17000021
         LA    RCTR,N0(RCTR)       ZERO FLAG BYTE                       17100021
         SPACE 2                                                        17200021
*/* BUILDL: D (YES,SEARACT,NO,DISPLAY2) DOES A RCT EXIST */             17300021
*****************************************************************       17400021
         LTR   RCTR,RCTR           IS THERE A RCT TABLE                 17500021
         BZ    DISPLAY2            BRANCH NO                            17600021
         LA    WRK1,VERTAB         ADDRESS OF VERB TABLE                17700021
         SPACE 2                                                        17800021
*/* SEARACT: D (YES,INCRCT,NO,%DD2)   HAS THIS ENTRY BEEN DISPLAYED */  17900021
*****************************************************************       18000021
SEARACT  EQU   *                                                        18100021
         TM    RCTCODE,RCTRES      HAS THIS ENTRY BEEN DISPLAYED        18200021
         BO    INCRCT              BRANCH YES                           18300021
         SPACE 2                                                        18400021
*/* %DD2:   D (YES,TESTACT,NO,INCRCT) IS THIS ENTRY ACTIVE */           18500021
*****************************************************************       18600021
         TM    RCTCODE,RCTACT      IS THIS ENTRY ACTIVE                 18700021
         BO    TESTACT             BRANCH YES                           18800021
         SPACE 2                                                        18900021
*/* INCRCT: D (YES,NXTPTR,NO,%END)    IS THIS ENTRY CONTINUED */        19000021
*****************************************************************       19100021
INCRCT   EQU   *                                                        19200021
         TM    RCTCODE,RCTCON      IS THIS ENTRY CONTINUED OR THE END   19300021
         BO    NXTPTR              BRANCH IF CONTINUED                  19400021
         SPACE 2                                                        19500021
*/* %END:   D (YES,DISPLAY,NO,%INCR)  IS THIS ENTRY THE END */          19600021
*****************************************************************       19700021
         BM    BUILD1              BRANCH IF END                        19800021
         SPACE 2                                                        19900021
*/* %INCR: M (,SEARACT)               INCREMENT TO NEXT RCT ENTRY */    20000021
*****************************************************************       20100021
         LA    RCTR,RCTLEN(RCTR)   INCREMENT TO NEXT ENTRY              20200021
         B     SEARACT             BRANCH TO CONTINUE SEARCH            20300021
         EJECT                                                          20400021
*/* NXTPTR: P (,SEARACT)              LOAD ADDRESS OF NEXT RCT SECTION  20500021
*/**/                                                                   20600021
*****************************************************************       20700021
NXTPTR   EQU   *                                                        20800021
         L     RCTR,N0(RCTR)       ADDRESS OF NEXT TABLE SECTION        20900021
         B     SEARACT             BRANCH TO CONTINUE SEARCH            21000021
***                                                                   * 21100021
***  BUILD MESSAGE IN DCM INSTRUCTION LINE OR WTO BUFFER                21200021
***                                                                   * 21300021
         SPACE 2                                                        21400021
*/* TESTACT: P (,MOVEOP)              MOVE RCT ENTRY INTO MSG BUFFER */ 21500021
*****************************************************************       21600021
TESTACT  EQU   *                                                        21700021
         CLC   RCTVER(N1),N0(WRK1) IS THIS ENTRY EQUAL TO PRESENT VERB  21800021
         BNE   INCRCT              BRANCH NO                            21900021
         TM    XASSDS,MVRB1        IS VERB IN BUFFER                    22000021
         BO    NOMOVE              BRANCH YES                           22100021
         ST    WRK3,XASTSAVE       SAVE ADDRESS OF VERB                 22200021
         OI    XASSDS,MVRB1        SET VERB IN BUFFER FLAG              22300021
         MVC   N1(N2,WRK3),RCTVER  MOVE VERB INTO BUFFER                22400021
         MVI   N0(WRK3),PARA1      PLACE PARENTHSIS BEFORE VERB         22500021
         LA    WRK6,N1(WRK6)       INCREMENT COUNT REG                  22600021
         CLI   RCTVER,CHARK        IS THIS A CONTROL VERB               22700021
         BE    MOVELOP             BRANCH YES                           22800021
         CLI   RCTVER,CHARM        IS THIS A MONTOR VERB                22900021
         BNE   NOMOVE              BRANCH NO                            23000021
         MVI   N3(WRK3),EQUAL      MOVE EQUAL INTO BUFFER               23100021
         LA    WRK3,N1(WRK3)       INCREMENT BUFFER POINTER             23200021
NOMOVE   EQU   *                                                        23300021
         BAL   BALR,CVTCID         BRANCH TO CONVERT CC TO EBIDIC       23400021
         TM    XASSDS,MOPD1        IS ONE OPERAND IN THE BUFFER         23500021
         BO    TESTCCA             BRANCH YES TO COMPARE CCA            23600021
         LA    WRK3,N3(WRK3)       INCREMENT BUFFER POINTER             23700021
         MVI   N0(WRK3),PARA1      PLACE PARENTHSIS BEFORE OPERAND      23800021
         LA    WRK3,N1(WRK3)       INCREMENT BUFFER POINTER             23900021
         SPACE 2                                                        24000021
*/* MOVEOP: M (,INCRCT)               SET ENTRY DISPLAYED IN RCT ON */  24100021
*****************************************************************       24200021
MOVEOP   EQU   *                                                        24300021
         OI    RCTCODE,RCTRES      SET ENTRY DISPLAYED BIT              24400021
         MVC   N0(N1,WRK3),RCTOPD  MOVE OPERAND INTO BUFFER             24500021
         CLI   N0(WRK3),CHARO      IS THIS THE CONSOLES OPERAND         24600021
         BNE   MCOMMA              BRANCH NO                            24700021
         MVC   N0(N8,WRK3),CONSOLES MOVE CONSOLES INTO BUFFER           24800021
         LA    WRK3,N7(WRK3)       INCREMENT BUFFER POINTER             24900021
         EJECT                                                          24950021
MCOMMA   EQU   *                                                        25000021
         LA    WRK3,N1(WRK3)       INCREMENT AROUND PARENTHSIS          25100021
         MVC   N1(N3,WRK3),CLEQUAL  MOVE COMMA L AND EQUAL INTO BUFFER  25200021
         MVI   N0(WRK3),PARA2      MOVE IN PARENTHSIS                   25300021
NOPARA   EQU   *                                                        25400021
         MVC   N4(N2,WRK3),XAP+N2  MOVE IN CONSOLE ID                   25500021
         MVC   N6(N1,WRK3),RCTAID  MOVE IN AREA ID                      25600021
         OI    XASSDS,MOPD1        SET ONE OPERAND FLAG                 25700021
         B     INCRCT              BRANCH FOR NEXT ENTRY                25800021
MOVELOP  EQU   *                                                        25900021
         OI    RCTCODE,RCTRES      SET ENTRY DISPLAYED BIT              26000021
         LA    WRK6,N1(WRK6)       INCREMENT COUNT OF VERBS             26100021
         LA    WRK3,N1(WRK3)       INCREMENT BUFFER PAST VERB           26200021
         BAL   BALR,CVTCID         BRANCH TO CONVERT CC TO EBIDIC       26300021
         B     MCOMMA              BRANCH TO MOVE IN L OPERAND          26400021
TESTCCA  EQU   *                                                        26500021
         CLC   N4(N2,WRK3),XAP+N2  IS THIS CONSOLE ID EQUAL             26600021
         BNE   INCRCT2             BRANCH NO                            26700021
         CLC   N6(N1,WRK3),RCTAID  IS THIS AREA ID EQUAL                26800021
         BNE   INCRCT2             BRANCH NO                            26900021
         MVI   N0(WRK3),COMMA      MOVE COMMA BETWEEN OPERANDS          27000021
         LA    WRK3,N1(WRK3)       INCREMENT BUFFER POINTER             27100021
         OI    XASSDS,MOPD2        SET MULTIPLE OPERAND FLAG            27200021
         B     MOVEOP              BRANCH TO MOVE IN OPERAND            27300021
BUILD1   EQU   *                                                        27400021
         L     WRK4,XASTSAVE       ADDRESS OF VERB                      27500021
         L     RCTR,UCMRCT         LOAD BEGINNING OF RCT                27600021
         TM    XASSDS,MOPD1        WAS AN ENTRY MADE                    27700021
         BNO   NXTTAB              BRANCH NO FOR NEXT VERB SEARCH       27800021
         TM    XASSDS,MOPD2        IS THE MULTIPLE OPERAND FLAG ON      27900021
         BO    ONEOPS              BRANCH YES                           28000021
         MVC   N0(N6,WRK3),N1(WRK3) MOVE L OPERAND OVER ONE             28100021
         CLI   N1(WRK4),CHARK      IS THIS A K COMMAND                  28200021
         BE    ONEOPS1             BRANCH YES                           28300021
         LA    BALR,N5(WRK3)       GET LENGTH OF TEXT                   28400021
         SR    BALR,WRK4           LENGTH FOR EXECUTE                   28500021
         EX    BALR,PARMOVE2       MOVE TEXT TO GET RID OF BLANKS       28600021
         CLI   N1(WRK4),CHARM      IS THIS A TWO CHARACTER VERB MN      28700021
         BNE   DISTYP              BRANCH NO                            28800021
         MVI   N3(WRK4),EQUAL      MOVE EQUAL AFTER TWO CHARACTER VERB  28900021
DISTYP   EQU   *                                                        29000021
         BCTR  WRK3,N0             ADJUST FOR BLANKS REMOVED            29100021
ONEOPS1  EQU   *                                                        29200021
         BCTR  WRK3,N0             ADJUST FOR BLANKS REMOVED            29300021
         EJECT                                                          29350021
ONEOPS   EQU   *                                                        29400021
         LA    WRK3,N6(WRK3)       INCREMENT BUFFER POINTER             29500021
         NI    XASSDS,TF-MOPD1-MOPD2-MVRB1 SET OPD AND VERB FLAGS OFF   29600021
         MVI   N1(WRK3),PARA2      MOVE PARENTHSIS AROUND VERB          29700021
         MVI   N2(WRK3),COMMA      COMMA INTO BUFFER                    29800021
         LA    WRK3,N3(WRK3)       INCREMENT BUFFER POINTER             29900021
         TM    XASSDS,MVRB2        DOES VERB HAVE DIFFERENT ROUTED OPDS 30000021
         BNO   NXTTAB              BRANCH NO                            30100021
         NI    XASSDS,TF-MVRB2     TURN OFF VERB MOVED FLAG             30200021
         B     SEARACT             BRANCH BACK TO SEARCH RCT            30300021
NXTTAB   EQU   *                                                        30400021
         LA    WRK1,N1(WRK1)       INCREMENT VERB TABLE                 30500021
         CLI   N0(WRK1),XFF        IS THIS THE END                      30600021
         BNE   SEARACT             BRANCH NO                            30700021
         LTR   WRK6,WRK6           ARE THERE ANY ACTIVE ENTRIES IN RCT  30800021
         BZ    DISPLAY2            BRANCH NO PUT OUT MESSAGE            30900021
         BCTR  WRK3,N0             DECREMENT BUFFER POINTER             31000021
         MVI   N0(WRK3),BLK        BLANK OUT COMMA CHARACTER            31100021
         CH    WRK6,ONE            IS COUNT OF VERB GREATER THAN ONE    31200021
         BH    DISPLAY             BRANCH YES                           31300021
         BCTR  WRK3,N0             DECREMENT BUFFER POINTER             31400021
         MVI   N0(WRK3),BLK        BLANK OUT PARENTHSIS CHARACTER       31500021
         LR    WRK1,WRK3           END ADDRESS OF                       31600021
         SR    WRK1,WRK4           LENGTH OF VERB TEXT                  31700021
         BCTR  WRK1,N0             DECREMENT COUNT BY ONE               31800021
         EX    WRK1,PARMOVE1       MOVE TO BLANK VERB PARENTHSIS        31900021
         BCTR  WRK3,N0             DECREMENT BUFFER POINTER             32000021
         SPACE 2                                                        32100021
*/* DISPLAY: M (,DISPLAY2)            SET ENTRY DISPLAYED IN RCT OFF */ 32200021
*****************************************************************       32300021
DISPLAY  EQU   *                                                        32400021
         NI    RCTCODE,TF-RCTRES   TURN OF DISPLAYED FLAG IN RCT        32500021
         TM    RCTCODE,RCTCON      IS THIS ENTRY THE END OR CONTINUED   32600021
         BM    DISPLAY2            BRANCH YES END                       32700021
         BO    NXTPTR3             BRANCH YES CONTINUED                 32800021
         LA    RCTR,RCTLEN(RCTR)   INCREMENT TO NEXT ENTRY              32900021
         B     DISPLAY             BRANCH BACK TO SEARCH                33000021
NXTPTR3  EQU   *                                                        33100021
         L     RCTR,N0(RCTR)       NEXT SECTION OF THE RCT              33200021
         B     DISPLAY             BRANCH BACK TO SEARCH                33300021
         EJECT                                                          33400021
*/* DISPLAY2: D (YES,%SET,NO,WRITE2)  IS THE CONSOLE A CRT */           33500021
*****************************************************************       33600021
DISPLAY2 EQU   *                                                        33700021
         LR    WRK6,WRK3           END ADDRESS OF BUFFER                33800021
         TM    UCMDISP,UCMDISPC    IS THIS CONSOLE A CRT                33900021
         BNO   WRITE2              BRANCH NO                            34000021
         SPACE 2                                                        34100021
*/* %SET:  P (,ERROR)                 SET CHANGE OPTIONS MSG CODE IN    34200021
*/*XSA */                                                               34300021
*****************************************************************       34400021
         L     WRK6,DCMAENTR       ADDRESS OF ENTRY AREA OF DCM         34500021
         LA    WRK6,N3(WRK6)       ADDRESS OF CURSOR FOR MSG RTN        34600021
         MVI   XAE,CHGOPT          MSG CODE FOR CHANGE OPTIONS          34700021
         B     ERROR               BRANCH TO PUT OUT MSG                34800021
INCRCT2  EQU   *                                                        34900021
         OI    XASSDS,MVRB2        SET MULTIPLE OPERANDS FLAG           35000021
         B     INCRCT              BRANCH FOR NEXT ENTRY                35100021
CVTCID   EQU   *                                                        35200021
         SR    WRK4,WRK4           CLEAR REG                            35300021
         IC    WRK4,RCTCID         GET CONSOLE ID FROM XSA              35400021
         CVD   WRK4,XAP            CONVERT CONSOLE ID TO DECIMAL        35500021
         UNPK  XAP+N1(N3),XAP+N6(N2) CONVERT TO PRINTABLE CHARACTERS    35600021
         OI    XAP+N3,CF0          CHANGE ZONE TO EBDIC                 35700021
         BR    BALR                BRANCH BACK TO CALLING RTN           35800021
         SPACE 2                                                        35900021
*/* WRITE1: S (,%ID) GETMAIN:         AREA FOR MSG BUFFER */            36000021
*****************************************************************       36100021
WRITE1   EQU   *                                                        36200021
         LA    WRK1,XAX+N4         AREA FOR STORAGE ADDRESS             36300021
         MVC   XAP(N10),GETAREA    MOVE REMOTE PARAMETER LIST TO XSA    36400021
         ST    WRK1,XAD            AREA FOR GETMAIN TO STORE ADDRESS    36500021
         LA    WRK1,XAP            ADDRESS OF REMOTE LIST FOR GETMAIN   36600021
         GETMAIN MF=(E,(1))        GET CORE FOR WTO                     36700021
         LTR   LNKR,LNKR           IS RETURN CODE ZERO                  36800021
         BCR   N7,RETR             BRANCH NO                            36900021
         L     WRK3,XAX+N4         BUFFER ADDRESS                       37000021
         XC    N0(N4,WRK3),N0(WRK3) ZERO FOUR BYTES                     37100021
         OI    N2(WRK3),MCSFG      SET MCS FLAGES FOR WTO               37200021
         LA    WRK3,N4(WRK3)       INCREMENT BUFFER ADDRESS             37300021
         EJECT                                                          37400021
*/* %ID:    P (,BUILDL)               MOVE IN MSG ID FOR WTO */         37500021
*****************************************************************       37600021
         MVC   N0(N8,WRK3),IEE     MESSAGE ID INTO BUFFER               37700021
         LA    WRK3,N8(WRK3)       INCREMENT BUFFER AROUND MSG ID       37800021
         LA    WRK4,N138           LENGTH OF BUFFER REMAINING           37900021
         B     BUILDL              BRANCH TO BUILD MESSAGE              38000021
         SPACE 2                                                        38100021
*/* WRITE2: S (,%FRE) WTO:            WRITE MESSAGE */                  38200021
*****************************************************************       38300021
WRITE2   EQU   *                                                        38400021
         L     WRK3,XAX+N4         ADDRESS OF GETMAINED AREA            38500021
         SR    WRK6,WRK3           GET LENGTH OF BUFFER  TEXT           38600021
         STH   WRK6,N0(WRK3)       LENGTH OF WTO MSG PLUS 4             38700021
         AR    WRK6,WRK3           END OF BUFFER                        38800021
         MVC   N0(N4,WRK6),DRCODES MOVE IN DESC AND ROUTE CODES         38900021
         SR    WRK0,WRK0           CLEAR REG                            39000021
         IC    WRK0,XAU            TERMINAL ID FROM XSA                 39100021
         WTO   MF=(E,(WRK3))       WRITE MESSAGE                        39200021
         SPACE 2                                                        39300021
*/* %FRE:   S (,%RET) FREEMAIN:       FREE MSG BUFFER AREA */           39400021
*****************************************************************       39500021
         L     WRK1,XAX+N4         ADDRESS OF WORD FOR GETMAIN          39600021
         FREEMAIN R,LV=N150,A=(1),SP=SUBP                               39700021
         SPACE 2                                                        39800021
*/* %RET:   R                         RETURN BR 14 */                   39900021
*****************************************************************       40000021
         BR    RETR                RETURN TO CALLER                     40100021
***                                                                     40150021
***   BLANK BUFFER FOR MESSAGE                                          40160021
***                                                                     40170021
BLINST   EQU   *                                                        40200021
         BCTR  WRK4,N0             DECREMENT THE LENGTH -               40300021
         BCTR  WRK4,N0             BY TWO                               40400021
         MVI   N0(WRK3),BLK        BLANK FIRST CHARACTER                40500021
         EX    WRK4,BLI            PROPAGATE BLANKS                     40600021
         BR    BALR                RETURN FROM SUBROUTINE               40700021
         EJECT                                                          40750021
***                                                                     40800021
***  FIND AND SET BASE FOR UCM ENTRY - INPUT - WRK1 CONTAINS CONSOLE ID 40900021
***                                  - OUTPUT - UCM ENTRY SPECIFIED BY  41000021
*                                              ID IN ENTR REG           41100021
*                                                                     * 41200021
FINDUCME EQU   *                                                        41300021
         L     ENTR,UCMVEA         FIRST ENTRY FROM UCM                 41400021
         BCTR  WRK1,N0             SUBRRACT ONE FROM CONSOLE ID         41500021
         M     WRK0,UCMVEZ         MULIPLY ENTRY SIZE BY REDUCED ID     41600021
         AR    ENTR,WRK1           ADDRESS OF DESIRED UCM ENTRY         41700021
         BR    BALR                RETURN FROM SUBROUTINE               41800021
         SPACE 2                                                        41900021
*/* ERROR1: P (,ERROR)                SET ERROR CODE IN XSA */          42000021
*****************************************************************       42100021
ERROR1   EQU   *                                                        42200021
         MVI   XAE,IOERROR         ERROR CODE FOR INVALID OPERAND       42300021
         LR    WRK6,LSTR           ADDRESS OF INVALID OPERAND           42400021
         SPACE 2                                                        42500021
*/* ERROR:  P (,EXIT)                 SET SECONDARY CODE IN XSA */      42600021
*****************************************************************       42700021
ERROR    EQU   *                                                        42800021
         CLI   XAE,LIERROR         IS THIS AN INVALID L OPERAND MSG     42900021
         BE    EXIT                BRANCH YES TO MSG MODULE             43000021
         ST    WRK6,XASTSAVE       STORE ADDRESS OF INVALID OPERAND     43100021
         CLI   XAE,KERROR          IS THIS A K ERROR MSG                43200021
         BNE   EXIT                BRANCH NO TO MSG MODULE              43300021
         MVI   XASTSAVE,NONCRT     SET SECONDARY ERROR CODE FOR MSG     43400021
         SPACE 2                                                        43500021
*/* EXIT:   R                         IEE5603D MR MSG MODULE 1 */       43600021
*****************************************************************       43700021
EXIT     EQU   *                                                        43800021
         MVC   XAX(N8),MSGL1    NAME OF MSG MODULE LOAD ONE             43900021
         LA    WRK1,XAX            REINITIALIZE XSA                     44000021
         ST    WRK1,XAP            POINT XAP TO MODULE NAME IN XAX      44100021
         SR    WRK1,WRK1           STORE ZERO DCB POINTER               44200021
         ST    WRK1,XAD                   IN XAD                        44300021
         XCTL  SF=(E,(XSAR))       XCTL TO SECOND LOAD                  44400021
         SPACE 2                                                        44500021
*/* IEE6403D: END */                                                    44600021
*****************************************************************       44700021
BLI      MVC   N1(N0,WRK3),N0(WRK3)  USED TO BLANK INST LINE            44800021
PARMOVE2 MVC   N3(N0,WRK4),N4(WRK4) ELIMINATE PARENTHSIS                44900021
PARMOVE1 MVC   N0(N0,WRK4),N1(WRK4) ELIMINATE PARENTHSIS                45000021
         EJECT                                                          45050021
********                                                              * 45100021
******** CONSTANT USED BY ROUTINE                                     * 45200021
********                                                              * 45300021
REF      DC    C'REF '             REFERENCE VERB                       45400021
CONSOLES DC    C'CONSOLES'         CONSOLES OPERAND IN RCT IS O         45500021
IEE      DC    C'IEE930I '         MESSAGE ID FOR MSGRT REF CDR         45600021
RTVB     DC    C'MR '              MSGRT COMMAND                        45700021
VERTAB   DC    C'DMK'              VERB TABLE                           45800021
         DC    X'FF'               END OF VERB TABLE                    45900021
CLEQUAL  DC    C',L='              L OPERAND                            46000021
MSGL1    DC    C'IGC5603D'         NAME OF MSG MODULE LOAD ONE          46100021
DRCODES  DC    X'0800'             DESCRIPTOR CODES                     46200021
         DC    X'0000'             ROUTING CODES                        46300021
ONE      DC    H'1'                VALUE ONE                            46400021
GETAREA  GETMAIN EC,LV=N150,A=EXIT,SP=SUBP,MF=L                         46500021
PATCH    DC    C'****PATCH AREA****'                                    46600021
PATCH2   DC    C'IEE6403D-TEST ONLY'                                    46700021
PATCH3   DC    36C' '                                                   46800021
         EJECT                                                          46900021
DTDCM    DSECT                                                          47000021
         IEECBJH CODE=DI                                                47100021
         EJECT                                                          47200021
DUCM     DSECT                                                          47300021
         IEECUCM                                                        47400021
         EJECT                                                          47500021
DCVT     DSECT                                                          47600021
         CVT                                                            47700021
         EJECT                                                          47800021
DXSA     DSECT                                                          47900021
         IEEXSA                                                         48000021
* THE XAS FIELD OF THE XSA IS USED AS FOLLOWS IN THIS MODULE            48100021
         ORG   XAS                                                      48200021
XASCID   DS    X                   CONSOLE ID                           48300021
XASDID   DS    C                   DISPLAY AREA ID                      48400021
XASSDS   DS    X                   SDS SWITCHES                         48500021
XASSDS1  EQU   X'80'               THIS COMMAND IS A STATUS            X48600021
                                        DISPLAY                         48700021
XASSDS2  EQU   X'40'               L OPERAND IS SPECIFIED ON           X48800021
                                        COMMAND                         48900021
XASDFG   EQU   X'80'               THE VERB IS A DISPLAY COMMAND        49000021
XASMNFG  EQU   X'40'               THE THE VERB IS A MONITOR COMMAND    49100021
XASKFG   EQU   X'20'               THE VERB IS A K COMMAND              49200021
XASRFG   EQU   X'10'               THE VERB IS A REFERENCE COMMAND      49300021
XASLFG   EQU   X'08'               THE L OPERAND IS PRESENT IN THE VERB 49400021
XASOPFG  EQU   X'04'               THERE IS MORE THAN ONE OPERAND       49500021
XASPRF1  EQU   X'02'               THERE IS MORE THAN ONE VERB          49600021
XASPRF2  EQU   X'01'               THERE IS MORE THAN ONE OPERAND       49700021
         DS    X                   RESERVED                             49800021
XASTSAVE DS    C                   ONE WORD TEMPORARY SAVE AREA         49900021
         DS    3C                  ONE WORD TEMPORY SAVE AREA           50000021
         EJECT                                                          50100021
*********************************************************************** 50200021
*                                                                     * 50300021
*   THE MSGRT COMMAND TABLE IS GOTTEN BY A GETMAIN AND EACH SECTION   * 50400021
*   IS MADE UP OF FIVE ENTRIES PLUS A POINTER TO THE THE NEXT SECTION.* 50500021
*   EACH ENTRY IS EIGHT BYTES LONG, THE FIRST BYTE IS A FLAG, THE NEXT* 50600021
*   TWO BYTES ARE THE OPERAND, THE NEXT THREE BYTES ARE THE VERB, AND * 50700021
*   THE LAST TWO BYTES ARE THE CONSOLE ID IN BINARY PLUS THE AREA ID  * 50800021
*   IN EBCDIC                                                         * 50900021
*                                                                     * 51000021
*********************************************************************** 51100021
DSTRCT   DSECT                                                          51200021
RCTBEG   EQU   *                   BEGINNING OF RCT SECTION             51300021
RCTCODE  DS    1C                  FLAGS INDICATING STATUS OF ENTRY     51400021
RCTCON   EQU   X'C0'               FLAG INDICATES END OF ONE SECTION    51500021
RCTEND   EQU   X'80'               FLAG INDICATES LAST DEFINED ENTRY    51600021
RCTRES   EQU   X'02'               FLAG INDICATES ENTRY DISPLAYED       51700021
RCTACT   EQU   X'01'               FLAG INDICATES ENTRY IS ACTIVE       51800021
RCTVER   DS    2C                  VERB FROM THE MSGRT COMMAND          51900021
RCTOPD   DS    2C                  OPERAND FROM THE MSGRT COMMAND       52000021
RCTCID   DS    1C                  CONSOLE ID FROM THE MSGRT COMMAND    52100021
RCTAID   DS    1C                  AREA ID FROM THE MSGRT COMMAND       52200021
RCTUNU   DS    1C                  UNUSED BYTE IN TABLE                 52300021
RCTLEN   EQU   8                   LENGTH OF ONE RCT ENTRY              52400021
RCTENT2  DS    8C                  SECOND ENTRY IN RCT                  52500021
RCTENT3  DS    8C                  THIRD ENTRY IN RCT                   52600021
RCTENT4  DS    8C                  FOURTH ENTRY IN RCT                  52700021
RCTENT5  DS    8C                  FIFTH ENTRY IN RCT                   52800021
RCTENT6  DS    8C                  CONTINUED OR ZERO IF LAST SECTION    52900021
RCTPTRN  EQU   RCTENT6             FIRST FULL WORD POINTER TO NEXT      53000021
*                                  SECTION OR ZERO IF THIS IS LAST      53100021
RCTTEND   EQU   *                   END OF ONE SECTION OF THE RCT       53200021
         END                                                            53300021
