        TITLE 'IEE6703D IGC6703D K AND STOPMN COMMAND HANDLER'          00100021
*********************************************************************** 00200021
*                                                                     * 00300021
* STATUS CHANGE LEVEL 0                                               * 00400021
*                                                                     * 00500021
* FUNCTION   SYNTAX CHECK CONTROL (K) COMMANDS. SCHEDULES K COMMANDS  * 00600021
*    WHICH MUST BE HANDLED USING THE TRANSIENT PORTION OF THE         * 00700021
*    DISPLAY CONTROL MODULE. K COMMANDS WHICH MUST BE HANDLED USING   * 00800021
*    ONLY THE RESIDENT PORTION OF THE DCM ARE HANDLED BY ADDITIONAL   * 00900021
*    LOADS, TO WHICH IEE6703D WILL PASS CONTROL. THIS MODULE ALSO     * 01000021
*    SCHEDULES THE STOPMN COMMAND                                     * 01100021
*                                                                     * 01200021
* ENTRY POINT   IEE6703D TO PROCESS K AND STOPMN COMMANDS             * 01300021
*                                                                     * 01400021
* INPUT         REGISTER 2 POINTS TO XSA.                             * 01500021
*               REGISTER 14 CONTAINS A RETURN ADDRESS                 * 01550021
*                                                                     * 01600021
* OUTPUT        COMMAND PARAMETER LIST IN DCM OR IN A GETMAIN AREA.   * 01700021
*                                                                     * 01800021
* EXTERNAL REFERENCES GETMAIN TO ACQUIRE AREA FOR PARAMETER LIST      * 01900021
*                     XCTL TO OTHER LOADS OF K COMMAND HANDLER        * 01950021
*                     POST FOR DIDOCS TO HANDLE COMMAND               * 01960021
*                                                                     * 02000021
* EXITS,NORMAL  RETURN VIA REGISTER 14 FOR IMMEDIATE PROCESSING OF    * 02100021
*        XCTL TO IEE7703D  PROCESS K V AND K M COMMANDS               * 02400021
*        XCTL TO IEE7803D  PROCESS K C,D AND SYNTAX CHECK THE K A CDR * 02500021
*                                                                     * 02600021
* EXITS,ERROR    IEE5603D TO PROCESS ERROR MESSAGES                   * 02700021
*                                                                     * 02800021
* TABLES/WORKAREAS  EXTENDED SAVE AREA   - XSA                        * 02900021
*                   DEVICE CONTROL TABLE - DCM                        * 02950021
*                   UNIT CONTROL MODULE - UCM                         * 02960021
*                   UNIT CONTROL MODULE ENTRY - UCM ENTRY             * 02970021
*                   SCREEN AREA CONTROL TABLE - SACB                  * 02980021
*                   ROUTED COMMAND PARAMETER LIST - KPARAM            * 02990021
*                                                                     * 03000021
* ATTRIBUTES  REFRESHABLE, PRIVILEGED TYPE 4 SVC                      * 03100021
*                                                                     * 03200021
*********************************************************************** 03300021
         EJECT                                                          03400021
IEE6703D CSECT                                                          03500021
*                                                                     * 03600021
*        REGISTER EQUATES                                             * 03700021
*                                                                     * 03800021
REG0     EQU   0                   WORK REG                             03900021
REG1     EQU   1                   WORK REG                             04000021
XSAREG   EQU   2                   BASE REG FOR XSA                     04100021
KREG     EQU   3                   BASE REG FOR K PARAMETER LIST        04200021
RDCMREG  EQU   4                   BASE REG FOR RESIDENT DCM            04300021
TDCMREG  EQU   5                   BASE REG FOR TRANSIENT DCM           04400021
REG6     EQU   6                   REGISTER CONTAINING OPERAND POINTER  04500021
SWREG    EQU   7                   WORK REG                             04600021
REG7     EQU   7                   WORK REG                             04700021
REG8     EQU   8                   WORK REG                             04800021
UCMREG   EQU   9                   BASE REG FOR UCM ENTRY               04900021
REGA     EQU   10                  BASE REG FOR UCM                     05000021
MODREG   EQU   11                  REG FOR MODULE INDICATOR             05100021
SACBREG  EQU   12                  BASE REG FOR SACB                    05200021
BASEREG  EQU   13                  BASE REG FOR THIS ROUTINE            05300021
REG14    EQU   14                  RETURN REG                           05400021
R15      EQU   15                  LINK REG                             05500021
         EJECT                                                          05600021
*                                                                     * 05700021
*        OTHER EQUATES                                                * 05800021
*                                                                     * 05900021
N0       EQU   0                   NUMBER CONSTANT                      06000021
ZERO     EQU   0                   NUMBER CONSTANT                      06100021
N1       EQU   1                   NUMBER CONSTANT                      06200021
ONE      EQU   1                   NUMBER CONSTANT                      06300021
N2       EQU   2                   NUMBER CONSTANT                      06400021
TWO      EQU   2                   NUMBER CONSTANT                      06500021
N3       EQU   3                   NUMBER CONSTANT                      06600021
THREE    EQU   3                   NUMBER CONSTANT                      06700021
N4       EQU   4                   NUMBER CONSTANT                      06800021
FOUR     EQU   4                   NUMBER CONSTANT                      06900021
N5       EQU   5                   NUMBER CONSTANT                      07000021
FIVE     EQU   5                   NUMBER CONSTANT                      07100021
N6       EQU   6                   NUMBER CONSTANT                      07200021
SIX      EQU   6                   NUMBER CONSTANT                      07300021
N7       EQU   7                   NUMBER CONSTANT                      07400021
N8       EQU   8                   NUMBER CONSTANT                      07500021
N9       EQU   9                   NUMBER CONSTANT                      07600021
NINE     EQU   9                   NUMBER CONSTANT                      07700021
TEN      EQU   10                  NUMBER CONSTANT                      07800021
N10      EQU   10                  NUMBER CONSTANT                      07900021
N11      EQU   11                  NUMBER CONSTANT                      08000021
N12      EQU   12                  NUMBER CONSTANT                      08100021
TWELVE   EQU   12                  NUMBER CONSTANT                      08200021
N13      EQU   13                  NUMBER CONSTANT                      08300021
OPFLD    EQU   125                 LENGTH OF OPERAND FIELD              08400021
DCHAR    EQU   C'D'                DISPLAY CONSTANT                     08600021
ECHAR    EQU   C'E'                ERASE CONSTANT                       08700021
FCHAR    EQU   C'F'                FRAME CONSTANT                       08800021
HCHAR    EQU   C'H'                HOLD CONSTANT                        08900021
M        EQU   C'M'                TIME CONSTANT                        09000021
N        EQU   C'N'                DEFINE CONSTANT                      09050021
S        EQU   C'S'                SPECIFICATION CONSTANT               09100021
UCHAR    EQU   C'U'                UPDATE CONSTANT                      09200021
VCHAR    EQU   C'V'                VARY CONSTANT                        09300021
COMMA    EQU   C','                COMMA CONSTANT                       09350021
Z0       EQU   X'00'               ZERO CONSTANT                        09400021
PM       EQU   X'38'               STOPMN CODE                          09500021
BLANK    EQU   X'40'               BLANK CONSTANT                       09600021
CHAIN    EQU   X'84'               POINTER DISPLACEMENT IN K LIST       09700021
POSTCODE EQU   X'FE'               CODE USED IN POSTING UCM ECB         09800021
WAITCODE EQU   X'80'               ECB WAIT CODE                        09900021
REDYCODE EQU   X'00'               ECB READY CODE                       10000021
TF       EQU   X'FF'               MASK FOR TURNING OFF FLAGS           10200021
SUBP     EQU   255                 SUB POOL NUMBER FOR GETMAIN          10300021
T22      EQU   22                  SECOND MSG CODE - SPECIFY DISP ID    10400021
T23      EQU   23                  SECOND MSG CODE - SPECIFY L OPERAND  10500021
T24      EQU   24                  SECOND MSG CODE - ON THIS COMMAND    10600021
         EJECT                                                          10700021
*/* IEE6703D: CHART */                                                  10800021
*/* %START: E (,%PM)                  IEE6703D K AND PM CDR MODULE */   10900021
*********************************************************************   11000021
         BALR  BASEREG,ZERO        SET UP ADDRESSIBILITY                11100021
         USING *,BASEREG           FOR PROGRAM                          11200021
         USING DXSA,XSAREG         EXTENDED SAVEAREA ADDRESSIBILITY     11300021
*                                                                     * 11400021
* GET DCM THROUGH CVT AND UCM                                         * 11500021
*                                                                     * 11600021
         L     REGA,CVTPTR         GET CVT POINTER                      11700021
         USING DCVT,REGA           ADDRESSIBILITY OF CVT                11800021
         L     REGA,CVTCUCB        GET UCM POINTER                      11900021
         DROP  REGA                                                     12000021
         USING UCM,REGA            SET ITS BASE                         12100021
         TM    UCMMODE,UCMMCS      IS THIS A NON MCS SYSTEM   ME        12150021
         BNO   SETSV8              BRANCH YES                 ME        12160021
         L     REG7,UCMVEA         GET LIST POINTER                     12200021
         SR    UCMREG,UCMREG       CLEAR WORK REGISTER                  12300021
         IC    UCMREG,XASCID       GET TARGET CONS ID                   12400021
         BCTR  UCMREG,ZERO         DECREMENT BY ONE                     12500021
         M     REG8,UCMVEZ         MULT ID BY SIZE                      12600021
         AR    UCMREG,REG7         SET PTR TO UCM ENTRY                 12700021
         USING UCMLIST,UCMREG      ADDRESSIBILITY OF UCM ENTRY          12800021
         L     REG6,XAL            GET POINTER TO LIST POSITION         12900021
         LA    REG6,ZERO(REG6)     ELIMINATE HI BYTE                    13000021
         SPACE 3                                                        13100021
*/* %PM:    D (YES,%PPM,NO,CHKKA)     IS THE TARGET A CRT CONSOLE */    13200021
*********************************************************************   13300021
         TM    UCMDISP,UCMDISPC    IS THIS A GRAPHIC CONSOLE            13400021
         BZ    CHKKM               NO, BRANCH                           13500021
         L     RDCMREG,UCMXB       GET DCM                              13600021
         USING RDCM,RDCMREG        ADDRESSIBILITY FOR DCM               13700021
         SR    SWREG,SWREG         INITIALIZE FLAG REGISTER             13800021
         L     TDCMREG,DCMADTRN    GET ADDRESS OF TRAN DCM              13900021
         USING TDCM,TDCMREG        ADDRESSIBILITY OF TRANS DCM          14000021
         LH    MODREG,SDS5         SET CODE FOR SDS INTERFACE 5         14050021
*                                                                     * 14100021
*  CHECK COMMAND IS BEING PASSED, EITHER CONTROL (K) OR STOPMN (PM)   * 14200021
*                                                                     * 14300021
         SPACE 3                                                        14500021
*/* %PPM:   D (YES,TESTOWN,NO,%EE)    IS THIS A STOPMN CDR */           14600021
*********************************************************************   14700021
         CLI   XAN,PM              TEST INDEX IN XSA                    14800021
         BE    TESTOWN             COMMAND IS STOP MONITOR              14900021
         EJECT                                                          15000021
*                                                                     * 15050021
*  TEST IF OPERAND IS E                                               * 15060021
*                                                                     * 15070021
*/* %EE:    D (YES,%EB,NO,CHKKD)      IS THIS COMMAND K E  */           15100021
*********************************************************************   15200021
         CLI   ZERO(REG6),ECHAR    IS OPERAND TO ERASE                  15300021
         BNE   CHKKD               NO, BRANCH TO CHECK FOR DISPLAY      15400021
         SPACE 2                                                        15500021
*/* %EB:    D (YES,KALONE,NO,%EN)    IS THIS OPERAND K E BLANK  */      15600021
*********************************************************************   15700021
         CLI   ONE(REG6),BLANK     IS E ONLY OPERAND                    15800021
         BE    KALONE              YES, BRANCH TO SET MODULE INDICATOR  15900021
         SPACE 2                                                        16000021
*/* %EN:    D (YES,SECMD,NO,%EPFK)    IS THIS OPERAND K E,N  */         16100021
*********************************************************************   16200021
         CLC   ONE(N3,REG6),EN     IS OPERAND E,N                       16300021
         BE    SECMD               YES, BRANCH TO SET MODULE INDICATOR  16400021
         SPACE 2                                                        16500021
*/* %EPFK:  D (YES,SEPFK,NO,%ESEG)    IS THIS OPERAND K E,PFK  */       16600021
*********************************************************************   16700021
         CLC   ONE(N5,REG6),EPFK   IS COMMAND E,PFK                     16800021
         BE    SEPFK               IF YES, BRANCH                       16900021
         SPACE 2                                                        17000021
*/* %ESEG:  D (YES,KALONE,NO,%ED)     IS THIS OPERAND K E,SEG  */       17100021
*********************************************************************   17200021
         CLC   ONE(N5,REG6),ESEG   IS COMMAND E,SEG                     17300021
         BE    KALONE              BRANCH YES TO SET MODULE INDICATOR   17400021
         SPACE 2                                                        17500021
*/* %ED:    D (YES,SETFLG,NO,SEDEL1) IS THIS OPERAND K E,D  */          17600021
*********************************************************************   17700021
         CLC   ONE(N3,REG6),ED     IS OPERAND E,D                       17800021
         BNE   SEDEL1              NO, BRANCH TO SET MODULE INDICATOR   17900021
         SPACE 2                                                        18000021
*/* SETFLG: M (,FLAGSET)              SET NON DYNAMIC INDICATOR */      18100021
*********************************************************************   18200021
SETFLG   LA    SWREG,ONE           SET FLAG TO ONE                      18300021
         B     FLAGSET             BRANCH TO PROCESS OPERAND            18400021
         SPACE 2                                                        18500021
*/* KALONE: P (,TESTL)                SET MODULE CODE TO DELETE 3 */    18600021
*********************************************************************   18700021
KALONE   LH    MODREG,DEL3         GET FOR DELETE 3                     18800021
         B     TESTL               GO CHECK FO L OPERAND                18900021
         EJECT                                                          19000021
*                                                                     * 19100021
* TEST IF THE OPERAND IS D                                            * 19200021
*                                                                     * 19300021
         SPACE 2                                                        19400021
*/* CHKKD:  D (YES,%DB,NO,CHKKS)      IS THIS COMMAND K D  */           19500021
*********************************************************************   19600021
CHKKD    EQU   *                                                        19700021
         LH    MODREG,SDS3         SET CODE FOR SDS INTERFACE 3         19800021
         CLI   ZERO(REG6),DCHAR    IS OPERAND TO DISPLAY                19900021
         BNE   CHKKS               NO, BRANCH TO CHECK FOR SPECIFICAT.  20000021
         SPACE 2                                                        20100021
*/* %DB:    D (YES,SEDEL4,NO,%DN)     IS THIS OPERAND K D BLANK  */     20200021
*********************************************************************   20300021
         CLI   ONE(REG6),BLANK     IS D ONLY OPERAND                    20400021
         BE    SEDEL4              YES, BRANCH TO SET MODULE INDICATOR  20500021
         SPACE 2                                                        20600021
*/* %DN:    D (YES,SEDEL4,NO,%NHOLD)  IS THIS OPERAND K D,N  */         20700021
*********************************************************************   20800021
         CLC   ONE(N3,REG6),EN     IS OPERAND D,N                       20900021
         BE    SEDEL4              BRANCH TO SET DCM BIT                21000021
         SPACE 2                                                        21100021
*/* %NHOLD: D (YES,SEDEL4,NO,%DF)     IS THIS OPERAND K D,N,HOLD  */    21200021
*********************************************************************   21300021
         CLC   ONE(N8,REG6),NHOLD  IS COMMAND D N,HOLD                  21400021
         BE    SEDEL4              BRANCH YES TO SET DCM BIT            21500021
         SPACE 2                                                        21600021
*/* %DF:    D (YES,SETFLG,NO,%DH)     IS THIS OPERAND K D,F  */         21700021
*********************************************************************   21800021
         CLC   ONE(N3,REG6),DF     IS OPERAND D,F                       21900021
         BE    SETFLG              BRANCH TO SET FLAG                   22000021
         SPACE 2                                                        22100021
*/* %DH:    D (YES,FLAGSET,NO,%DU)    IS THIS OPERAND K D,H  */         22200021
*********************************************************************   22300021
         CLC   ONE(N3,REG6),DH     IS COMMAND D,H                       22400021
         BE    FLAGSET             BRANCH TO PROCESS OPERAND            22500021
         SPACE 2                                                        22600021
*/* %DU:    D (YES,FLAGSET,NO,%NPFK)  IS THIS OPERAND K D,U  */         22700021
*********************************************************************   22800021
         CLC   ONE(N3,REG6),DU     IS COMMAND D,U                       22900021
         BE    FLAGSET             BRANCH TO PROCESS OPERAND            23000021
         EJECT                                                          23100021
*/* %NPFK:  D (YES,SEPFK,NO,MSGXX)    IS THIS OPERAND K D,PFK  */       23200021
*********************************************************************   23300021
         CLC   ONE(N5,REG6),EPFK   IS COMMAND D,PFK                     23400021
         BE    SEPFK               YES, BRANCH TO SET MODULE INDICATOR  23500021
         LA    REG6,N2(REG6)       SET OP POINTER                       23600021
         ST    REG6,XASTSAVE       CURSOR ADDRESS FOR MSG RTN           23700021
         B     MSG04               GO SET ERROR CODE                    23800021
         EJECT                                                          23900021
*                                                                     * 24000021
* TEST IF THE OPERAND IS S                                            * 24100021
*                                                                     * 24200021
         SPACE 2                                                        24300021
*/* CHKKS:  D (YES,TESTL,NO,CHKKN)    IS THIS COMMAND K S  */           24400021
*********************************************************************   24500021
CHKKS    CLI   ZERO(REG6),S        IS OPERAND FOR SPEC                  24600021
         BNE   CHKKN               NO, BRANCH TO CHECK FOR DEFINE       24700021
         LH    MODREG,OPT          SET CODE FOR OPTIONS ROUTINE         24800021
         B     TESTL               BRANCH TO CHECK FOR L OPERAND        24900021
         SPACE 6                                                        25000021
*                                                                     * 25100021
* TEST IF THE OPERAND IS N                                            * 25200021
*                                                                     * 25300021
         SPACE 2                                                        25400021
*/* CHKKN:  D (YES,SEPFK,NO,CHKKV)    IS THIS COMMAND K N,PFK=  */      25500021
*********************************************************************   25600021
CHKKN    CLI   ZERO(REG6),N        IS OPERAND N FOR PFK DEFINITION      25700021
         BE    SEPFK               YES, BRANCH TO SET MODULE INDICATOR  25800021
         SPACE 6                                                        25900021
*                                                                     * 26000021
* TEST IF OPERAND IS V.  BRANCH YES TO IEE7703D TO PROCESS THE CDR    * 26100021
*                                                                     * 26200021
         SPACE 2                                                        26300021
*/* CHKKV:  D (YES,SETSV7,NO,CHKKM)   IS THIS COMMAND K V  */           26400021
*********************************************************************   26500021
CHKKV    CLI   ZERO(REG6),VCHAR    IS V THE OPERAND                     26600021
         BE    SETSV7              BRANCH YES TO IEE7703D               26700021
         EJECT                                                          26750021
*                                                                     * 28600021
*  TEST IF OPERAND IS M   BRANCH YES TO IEE7703D                      * 28700021
*                                                                     * 28800021
         SPACE 2                                                        28900021
*/* CHKKM:  D (YES,SETSV7,NO,SETSV8)  IS THIS COMMAND K M  */           29000021
*********************************************************************   29100021
CHKKM    CLI   ZERO(REG6),M        IS CMD K,M                           29200021
         BE    SETSV7              YES, BRANCH                          29300021
         SPACE 6                                                        29310021
*                                                                     * 29350021
*  BRANCH TO IEE7803D FOR K C,D PROCESSING AND SYNTAX CHECK OF K A CDR* 29400021
*                                                                     * 29450021
         SPACE 3                                                        30500021
*/* SETSV8: P (,EXIT)                 SET MODULE INDICATOR TO K4 */     30600021
*********************************************************************   30700021
SETSV8   MVC   XAX+THREE(TWO),SV8  SET MODULE NAME                      30800021
         SPACE 3                                                        30900021
*/* EXIT:   R                         XCTL TO OTHER K PROCESSORS */     31000021
*********************************************************************   31100021
EXIT     EQU   *                                                        31200021
         XCTL  SF=(E,(XSAREG))     XCTL TO NEXT MODULE                  31300021
         SPACE 3                                                        31310021
*/* SETSV7: P (,EXIT)                 SET MODULE INDICATOR TO K3 */     31350021
*********************************************************************   31360021
SETSV7   EQU   *                                                        31370021
         MVC   XAX+N3(N2),SV7      SET MODULE NAME                      31380021
         B     EXIT                BRANCH TO EXIT                       31390021
         EJECT                                                          31400021
*/* SEDEL1: P (,TESTL)                SET MODULE INDICATOR TO DELETE 1  31600021
*/**/                                                                   31700021
*********************************************************************   31800021
SEDEL1   LH    MODREG,DEL1         SET CODE FOR DELETE 1 ROUTINE        31900021
         SPACE 3                                                        32000021
*/* TESTL:  D (YES,MSGXX,NO,SETDCM)   WAS A L OPERAND SPECIFIED ON CDR  32100021
*/**/                                                                   32200021
*********************************************************************   32300021
TESTL    TM    XASSDS,XASSDS2      WAS L OPERAND SPECIFIED              32400021
         BO    MSG12               YES, BRANCH FOR  MSG EXIT            32500021
         OI    DCMSVC34,DCMTYPE1   IND ADOPN PTR TO ENTRY AREA          32600021
         B     SETDCM              BRANCH TO SET DCM FLAG               32700021
         SPACE 3                                                        32800021
*/* SECMD:  P (,TESTL)                SET MODULE INDICATOR TO COMMAND   32900021
*/*RTN */                                                               33000021
*********************************************************************   33100021
SECMD    LH    MODREG,COMD         SET CODE FOR COMMAND ROUTINE         33200021
         B     TESTL               BRANCH TO CHECK FOR L OPERAND        33300021
         SPACE 3                                                        33400021
*/* SEDEL4: P (,TESTL)                SET MODULE INDICATOR TO DELETE 4  33500021
*/**/                                                                   33600021
*********************************************************************   33700021
SEDEL4   LH    MODREG,DEL4         SET CODE FOR DELETE 4 ROUTINE        33800021
         B     TESTL               BRANCH TO TEST FOR L OPERAND         33900021
         SPACE 3                                                        34000021
*/* SEPFK:  P (,TESTL)                SET MODULE INDICATOR TO PFK 2 */  34100021
*********************************************************************   34200021
SEPFK    LH    MODREG,PFK2         SET CODE FOR PFK 2 ROUTINE           34300021
         B     TESTL               BRANCH TO SET DCM FLAG               34400021
         EJECT                                                          34500021
*/* MSGXX:  P (,MSGEXIT)              SET MSG CODE IN XSA */            34600021
*********************************************************************   34700021
MSG03    EQU   *                                                        34750021
         MVI   XAE,N3              MSG CODE -DELETE INCONSIST           34760021
         B     MSGEXIT             BRANCH TO MSG EXIT                   34770021
MSG04    EQU   *                                                        34800021
         MVI   XAE,FOUR            MSG CODE - INVALID OPERAND           34900021
         B     MSGEXIT             BRANCH TO EXIT                       35000021
MSG05    EQU   *                                                        35100021
         MVI   XAE,FIVE            MSG CODE - K REQUEST INCONSIST       35200021
         B     MSGEXIT             BRANCH TO EXIT                       35300021
MSG12    EQU   *                                                        35400021
         MVI   XAE,N12             MSG CODE - L OPERAND INVALID         35500021
         MVI   XASTSAVE,T24        SECOND MSG CODE - ON THIS COMMAND    35600021
         B     MSGEXIT             BRANCH TO MESSAGE EXIT               35700021
MSG13    EQU   *                                                        35800021
         MVI   XAE,N13             MSG CODE - K REQUEST AMBIGUOUS       35900021
         SPACE 3                                                        36000021
*/*MSGEXIT: R                         XCTL TO RT AND K MSG RTN */       36100021
*********************************************************************   36200021
MSGEXIT  EQU   *                                                        36300021
         MVC   XAX+THREE(TWO),FV6  RT AND K MSG MODULE NAME             36400021
         B     EXIT                BRANCH TO XCTL                       36500021
         EJECT                                                          36600021
*                                                                     * 36700021
* COMMON SUBROUTINE FOR K D,H OR K D,U PROCESSING - SWREG EQUAL ZERO  * 36800021
*                       K E,D OR K D,F PROCESSING - SWREG EQUAL ONE   * 36900021
         SPACE 2                                                        37000021
*/* FLAGSET: P (,%AAA)                 GET SACB POINTER FROM DCM */     37100021
*********************************************************************   37200021
FLAGSET  L     SACBREG,DCMADSDS    GET SACB POINTER                     37300021
         LR    REG0,REG6           LOAD WITH NON ZERO VALUE             37400021
         ST    REG6,XASTSAVE       CURSOR ADDRESS FOR MSG RTN ON ERROR  37500021
         USING DCMACB,SACBREG      SET BASE FOR SACB                    37600021
         SPACE 2                                                        37700021
*/* %AAA:   D (YES,SACBTEST,NO,AREASPEC) IS THE AREA SPECIFIED Z */     37800021
*********************************************************************   37900021
         CLI   XASDID,Z0           WAS AN AREA SPECIFIED                38000021
         BNE   AREASPEC            YES, BRANCH                          38100021
         SR    REG0,REG0           CLEAR A WORK REGISTER                38200021
         SPACE 2                                                        38300021
*/* SACBTEST: D (YES,%DA,NO,NOUSE)    IS THIS AREA IN USE */            38400021
*********************************************************************   38500021
SACBTEST TM    DCMASACB,DCMAUSE    IS AREA IN USE                       38600021
         BZ    NOUSE               NO, BRANCH                           38700021
         SPACE 2                                                        38800021
*/* %DA:    D (YES,%TTT,NO,SRCACB)    IS A DISPLAY IN THIS AREA */      38900021
*********************************************************************   39000021
         TM    DCMAFLG1,DCMADISP   IS DISPLAY IN AREA                   39100021
         BZ    SRCACB              NO, BRANCH TO TEST OTHER SACB'S      39200021
         SPACE 2                                                        39300021
*/* %TTT:   D (YES,CHECKTOP,NO,%TDD)  IS THIS A NON DYNAMIC REQUEST */  39400021
*********************************************************************   39500021
         LTR   SWREG,SWREG         IS FLAG SET                          39600021
         BNZ   CHEKTOP             YES, BRANCH TO CHECK IF TOP DISPLAY  39700021
         OI    XASPLS3,N1          SET DISPLAY ON SCREEN SWITCH         39800021
         SPACE 1                                                        39900021
*/* %TDD:   D (YES,%ADSV,NO,SRCACB)   IS A DYNAMIC DISPLAY IN           40000021
*/*AREA*/                                                               40100021
*********************************************************************   40200021
         TM    DCMADFLG,DCMADD     IS IT A DYNAMIC DISPLAY              40300021
         BZ    SRCACB              NO, BRANCH TO TEST OTHER SACB'S      40400021
         SPACE 1                                                        40500021
*/* %ADSV:  D (YES,SRCACB,NO,MSGXX)   IS THIS THE FIRST DYNAMIC DISPLAY 40600021
*/* */                                                                  40700021
*********************************************************************   40800021
         LTR   REG0,REG0           WAS AN ADDRESS OF SACB SAVED YET     40900021
         BNZ   LOPER               BRANCH TO SET CODE                   41000021
         LR    REG0,SACBREG        SAVE THIS SACB ADDRESS               41100021
         EJECT                                                          41200021
*/* SRCACB: D (YES,SACBTEST,NO,NOUSE) IS THERE ANOTHER SACB */          41300021
*********************************************************************   41400021
SRCACB   L     SACBREG,DCMACBNX    GET NEXT SACB POINTER                41500021
         LTR   SACBREG,SACBREG     ANY MORE SACB'S                      41600021
         BZ    NOUSE               NO, BRANCH                           41700021
         B     SACBTEST            YES, CONTINUE SEARCH                 41800021
         SPACE 2                                                        41900021
*/* AREASPEC: D (YES,TFLG,NO,%TEND)   IS THE SACB ID EQUAL TO TARGET ID 42000021
*/* */                                                                  42100021
*********************************************************************   42200021
AREASPEC CLC   DCMAID(ONE),XASDID  COMPARE SACB ID WITH THAT SPECIFIED  42300021
         BE    TFLG                BRANCH TO TEST.FLAGS                 42400021
         L     SACBREG,DCMACBNX    GET NEXT SACB                        42500021
         SPACE 2                                                        42600021
*/* %TEND:  D (YES,AREASPEC,NO,NOUSE) IS THERE ANOTHER SACB */          42700021
*********************************************************************   42800021
         LTR   SACBREG,SACBREG     ANY MORE SACB'S                      42900021
         BNZ   AREASPEC            BRANCH YES TO CONTINUE SEARCH        43000021
         B     NODISPA             BRANCH FOR MSG                       43100021
         SPACE 2                                                        43200021
*/* NOUSE:  D (YES,MSGXX,NO,TESTAD)   IS THIS A NON DYNAMIC REQUEST */  43300021
*********************************************************************   43400021
NOUSE    LTR   SWREG,SWREG         IS FLAG SET                          43500021
         BZ    TESTAD              BRANCH AROUND                        43600021
NODISPS  EQU   *                                                        43700021
         MVI   XASTSAVE,N6         SECOND MSG CODE - NO DISP ON SCREEN  43800021
DELORK   EQU   *                                              ME  M2087 43810021
         CLI   N0(REG6),ECHAR      IS THIS AN ERASE OPERAND   ME  M2087 43850021
         BE    MSG03               BRANCH YES FOR DELETE MSG  ME  M2087 43860021
         B     MSG05               BRANCH FOR K REQUEST INCON.ME  M2087 43900021
         SPACE 2                                                        44000021
*/* TFLG:   D (YES,%DP,NO,CDDA)       IS THIS A NON DYNAMIC REQUEST */  44100021
*********************************************************************   44200021
TFLG     LTR   SWREG,SWREG         WAS FLAG SET                         44300021
         BZ    CDDA                NO, CHECK IF DYNAMIC DISPLAY         44400021
         SPACE 2                                                        44500021
*/* %DP:    D (YES,TESTTYP,NO,MSGXX)  IS THERE A DISPLAY IN AREA */     44600021
*********************************************************************   44700021
         TM    DCMAFLG1,DCMADISP   YES, CHECK IF DISPLAY IN AREA        44800021
         BO    TESTTYP             YES, SET MODULE INDICATOR            44900021
NODISPA  EQU   *                                                        45000021
         MVI   XASTSAVE,N7         SECOND MSG CODE - NO DISP IN AREA    45100021
         B     DELORK              GO CHECK OPERAND OF CDR    ME  M2087 45200021
         EJECT                                                          45300021
*/* CDDA:   D (YES,TESTTYP,NO,MSGXX)  IS A DYNAMIC DISPLAY IN           45400021
*/*AREA */                                                              45500021
*********************************************************************   45600021
CDDA     EQU   *                                                        45700021
         TM    DCMAFLG1,DCMADISP   IS THERE A DISPLAY IN THE AREA       45800021
         BNO   NODISPA             BRANCH NO FOR ERROR MSG              45900021
         TM    DCMADFLG,DCMADD     IS DYNAMIC DISPLAY IN AREA           46000021
         BO    TESTTYP             YES, BRANCH TO SET MODULE INDICATOR  46100021
DYDISP   EQU   *                                                        46200021
         MVI   XASTSAVE,TEN        SECOND MSG CODE - DISP IS NOT DYNAMI 46300021
         B     MSG05               GO SET ERROR CODE                    46400021
         SPACE 3                                                        46500021
*/* TESTAD: D (YES,SETID,NO,MSGXX)    WAS A DYNAMIC DISPLAY AREA FOUND  46600021
*/**/                                                                   46700021
*********************************************************************   46800021
TESTAD   EQU   *                                                        46900021
         LTR   REG0,REG0           WAS ADDRESS STORED                   47000021
         BNZ   RESSACB             BRANCH YES                           47100021
         TM    XASPLS3,N1          IS DISPLAY ON SCREEN FLAG SET        47200021
         BO    DYDISP              BRANCH YES                           47300021
         B     NODISPS             BRANCH NO FOR NO DISPLAY MSG         47400021
RESSACB  EQU   *                                                        47500021
         LR    SACBREG,REG0        RESTORE SACB BASE                    47600021
         SPACE 3                                                        47700021
*/* SETID:  P (,TESTTYP)              MOVE SACB ID INTO XSA ID */       47800021
*********************************************************************   47900021
SETID    MVC   XASDID,DCMAID       PUT AREA ID IN XAS                   48000021
         B     TESTTYP             BRANCH TO SET MODULE INDICATOR       48100021
         SPACE 3                                                        48200021
*/* CHECKTOP: D (YES,SETID,NO,MSGXX)  IS THIS ID THE TOP DISPLAY ON     48300021
*/*SCREEN */                                                            48400021
*********************************************************************   48500021
CHEKTOP  CLC   DCMAID(ONE),DCMTOPDS IS THIS THE TOP DISPLAY ON SCREEN   48600021
         BE    SETID               YES, BRANCH                          48700021
LOPER    EQU   *                                                        48800021
         MVI   XASTSAVE,T23        SECOND MSG CODE - SPECIFY L OPERAND  48900021
         B     MSG13               BRANCH TO SET ERROR CODES            49000021
         EJECT                                                          49100021
*/* TESTTYP: D (YES,TESTOWN,NO,%HT) IS THIS A K E,D COMMAND */          49200021
*********************************************************************   49300021
TESTTYP  EQU   *                                                        49400021
         CLI   N2(REG6),DCHAR      IS THIS AN ERASE DISPLAY COMMAND     49500021
         BNE   TESTUD              BRANCH NO                            49600021
         TM    DCMADFLG,DCMADD     IS THIS A DYNAMIC DISPLAY            49650021
         BNO   TESTOWN             BRANCH NO  K E,D IS VALID            49660021
         MVI   XASTSAVE,N4         SECOND MSG CODE -USE STOPMN          49660421
         B     MSG03               BRANCH TO MSG EXIT         ME  M2087 49670421
         SPACE 2                                                        49700021
*/* %HT:    D (YES,UPDATE,NO,%UT)     IS THIS A K D,U COMMAND */        49800021
*********************************************************************   49900021
TESTUD   EQU   *                                                        49950021
         CLI   N2(REG6),UCHAR      IS THIS AN UPDATE DISPLAY COMMAND    50000021
         BE    UPDATE              BRANCH YES                           50100021
         SPACE 2                                                        50200021
*/* %UT:    D (YES,SETHOLD,NO,FRAMLST)    IS THIS A K D,H COMMAND */    50300021
*********************************************************************   50400021
         CLI   N2(REG6),HCHAR      IS THIS A HOLD DISPLAY COMMAND       50500021
         BE    SETHOLD             BRANCH YES                           50600021
*                                                                       50700021
*   THEN THIS IS A DISPLAY FRAMING COMMAND                              50800021
*                                                                       50900021
         TM    DCMAFLG1,DCMAFRPR   IS FRAMING IN PROCESS                51000021
         BNO   FRAMACT             BRANCH NO                            51100021
         MVI   XASTSAVE,N9         SECOND MSG CODE - FRAME NOT COMPLETE 51200021
         B     MSG05               BRANCH TO MSG CODE                   51300021
FRAMACT  EQU   *                                                        51400021
         TM    DCMAFLG1,DCMADEND   IS THIS THE LAST FRAME               51500021
         BNO   FRAMLST             BRANCH NO                            51600021
         MVI   XASTSAVE,N8         SECOND MSG CODE - LAST FRAME DISPLAY 51700021
         B     MSG05               BRANCH TO MSG CODE                   51800021
         SPACE 3                                                        51900021
*/* FRAMLST: M (,TESTOWN)             SET FRAMING IN PROCESS INDICATOR  52000021
*/**/                                                                   52100021
*********************************************************************   52200021
FRAMLST  EQU   *                                                        52300021
         OI    DCMAFLG1,DCMAFRPR   SET FRAMING IN PROCESS FLAG          52400021
         B     TESTOWN             BRANCH TO BUILD PARAMETER LIST       52500021
         EJECT                                                          52600021
*/* UPDATE: M (,TESTOWN)              TURN OFF HOLD INDICATOR IN SACB*/ 52700021
*********************************************************************   52800021
UPDATE   EQU   *                                                        52900021
         NI    DCMADFLG,TF-DCMAHOLD TURN OFF HOLD FLAG IN THE DCM       53000021
         B     TESTOWN             BRANCH TO BUILD PARAMETER LIST       53100021
         SPACE 3                                                        53200021
*/* SETHOLD: M (,TESTOWN)             SET HOLD INDICATOR IN SACB */     53300021
*********************************************************************   53400021
SETHOLD  EQU   *                                                        53500021
         OI    DCMADFLG,DCMAHOLD   SET ON HOLD FLAG IN DCM              53600021
*                                                                     * 53700021
* BUILD PARAMETER LIST WITH COMMAND AND OPERANDS.  FIRST DETERMINE IF * 53800021
* GETMAIN HAS TO BE ISSUED OR IF THE DCM WILL BE USED FOR THE PARA-   * 53900021
* METER LIST                                                          * 54000021
*                                                                     * 54100021
         SPACE 3                                                        54200021
*/* TESTOWN: D (YES,SETDCM,NO,%KLST) IS TARGET ID EQUAL TO ISSUING ID   54300021
*/**/                                                                   54400021
*********************************************************************   54500021
TESTOWN  EQU   *                                                        54600021
         CLC   XAU(ONE),XASCID     IS THE TARGET ID EQUAL TO THE ISSUE- 54700021
         BE    SETDCM              ING CONSOLE. IF NO, ISSUE GETMAIN.   54800021
         SPACE 3                                                        54900021
*/* %KLST:  P (,SRCLST)               GET ADDRESS OF K LIST   */        55000021
*********************************************************************   55100021
         L     KREG,DCMADKP        GET POINTER TO PARAMETER LIST        55200021
         USING KPARAM,KREG         ADDRESSIBILITY FOR K LIST            55300021
         LA    REG7,DCMADKP        GET ADDRESS OF POINTER               55400021
         SPACE 3                                                        55500021
*/* SRCLST: D (YES,GETAREA,NO,%NT)    IS THIS THE LAST K LIST */        55600021
*********************************************************************   55700021
SRCLST   LTR   KREG,KREG           ANY POINTER EXIST                    55800021
         BZ    GETAREA             BRANCH TO GETMAIN                    55900021
         SPACE 3                                                        56000021
*/* %NT:    P (,SRCLST)               GET ADDRESS OF NEXT K LIST */     56100021
*********************************************************************   56200021
         L     KREG,KCHAIN         GET POINTER TO NEXT K LIST           56300021
         LA    REG7,KCHAIN         GET ITS POINTER                      56400021
         B     SRCLST              BRANCH TO SEARCH LISTS               56500021
         EJECT                                                          56600021
*/* GETAREA: S (,BLDLST) GETMAIN:     GET AREA TO BUILD K LIST */       56700021
*********************************************************************   56800021
GETAREA  EQU   *                                                        56900021
         MVC   XAP(N10),GETARE1    MOVE GETMAIN PARAMETER LIST TO XSA   57000021
         ST    REG7,XAD            ADDRESS OF WORD FOR GETMAIN          57100021
         LA    REG1,XAP            ADDRESS OF LIST FOR GETMAIN          57200021
         GETMAIN  MF=(E,(1))       CONDITIONAL GETMAIN                  57300021
         LTR   R15,R15             WAS GETMAIN OK                       57400021
         BCR   N7,REG14            NO, RETURN TO CALLER                 57500021
         L     KREG,ZERO(REG7)     GET AREA ADDRESS                     57600021
         XC    KFLGS(N7),KFLGS     ZERO FLAG BYTE AND POINTER           57700021
         OI    KFLGS,KGM           INDICATE AREA WAS GETMAINED          57800021
         B     BLDLST              BRANCH TO BUILD PARAMETER LIST       57900021
         SPACE 3                                                        58000021
*/* SETDCM: P (,BLDLST)               GET ADDRESS OF DCM K LIST */      58100021
*********************************************************************   58200021
SETDCM   EQU   *                                                        58300021
         OI    DCMSVC34,DCMMYCMD   SET BIT FOR VALID K COMMAND          58400021
         LA    KREG,DCMINLGN       GET ADDRESS OF DCM PARAM LIST        58500021
         MVI   KFLGS+N2,N0         ZERO FLAG BYTE ONLY                  58550021
         SPACE 3                                                        58700021
*/* BLDLST: P (,%PMT)                  BUILD K LIST */                  58800021
*********************************************************************   58900021
BLDLST   EQU   *                                                        59000021
         MVC   KOPN(OPFLD),ZERO(REG6) MOVE OPERANDS INTO LIST           59100021
         STH   MODREG,KMOD         PUT MODULE INDICATOR IN DCM          59200021
         MVC   KAID(ONE),XASDID    MOVE AREA ID INTO LIST               59300021
         SPACE 3                                                        59400021
*/* %PMT:    D (YES,SETMON,NO,%SETK)   IS THIS A STOPMN COMMAND */      59500021
*********************************************************************   59600021
         CLI   XAN,PM              IS COMMAND STOP MONITOR              59700021
         BE    SETMON              YES BRANCH                           59800021
         SPACE 3                                                        59900021
*/* %SETK:  M (,INDSET)               SET K CDR INDICATOR */            60000021
*********************************************************************   60100021
         OI    KFLGS,KK            SET CONTROL COMD INDICATOR           60200021
         B     INDSET              BRANCH TO TEST FOR GETMAIN           60300021
         EJECT                                                          60400021
*/* SETMON: M (,INDSET)               SET PM CDR INDICATOR */           60500021
*********************************************************************   60600021
SETMON   OI    KFLGS,KPM           SET STOPMN INDICATOR                 60700021
         SPACE 2                                                        60800021
*/* INDSET: D (YES,TSTBSY,NO,RETURN)  WAS K LIST GETMAINED */           60900021
*********************************************************************   61000021
INDSET   TM    KFLGS,KGM           WAS AREA GETMAINED                   61100021
         BO    TSTBSY              YES, BRANCH                          61200021
         SPACE 2                                                        61300021
*/* RETURN: R                         RETURN TO CALLER BR 14 */         61400021
*********************************************************************   61500021
RETURN   BR    REG14               RETURN TO CALLER                     61600021
         SPACE 2                                                        61700021
*/* TSTBSY: D (YES,RETURN,NO,%WA)     IS DEVICE BUSY */                 61800021
*********************************************************************   61900021
TSTBSY   TM    UCMSTS,UCMBF        IS DEVICE BUSY                       62000021
         BO    RETURN              YES, BRANCH TO RETURN                62100021
         SPACE 2                                                        62200021
*/* %WA:    D (YES,POST,NO,%RD)       IS DEVICE WAITING */              62300021
*********************************************************************   62400021
         TM    UCMECB,WAITCODE     IS DEVIDE WAITING                    62500021
         BO    POST                YES, BRANCH TO POST                  62600021
         SPACE 3                                                        62700021
*/* %RD:    D (YES,POST,NO,RETURN)    IS DEVICE READY */                62800021
*********************************************************************   62900021
         CLI   UCMECB,REDYCODE     IS DEVICE READY                      63000021
         BNE   RETURN              NO, BRANCH TO RETURN                 63100021
         SPACE 3                                                        63200021
*/* POST:   S (,RETURN) POST:         POST UCM ECB WITH CODE */         63300021
*********************************************************************   63400021
POST     EQU   *                                                        63500021
         POST  UCMECB,POSTCODE     POST UCM ECB WITH CODE               63600021
         BR    REG14               BRANCH TO RETURN                     63700021
         EJECT                                                          63800021
*/* IEE6703D: END */                                                    63900021
*********************************************************************   64000021
GETARE1  GETMAIN  EC,LV=KPLLNGTH,A=POST,MF=L,SP=SUBP GETMAIN LIST       64100021
         EJECT                                                          64200021
*                                                                     * 64300021
*    CONSTANTS USED IN THIS ROUTINE                                   * 64400021
*                                                                     * 64500021
COMD     DC    C'54'               COMMAND RTN NAME                     64600021
DEL1     DC    C'56'               DELETE 1 RTN NAME                    64700021
FV6      EQU   DEL1                RT AND K MSG RTN NAME                64800021
DEL3     DC    C'58'               DELETE 3 RTN NAME                    64900021
DEL4     DC    C'59'               DELETE 4 RTN NAME                    65000021
OPT      DC    C'5A'               OPTIONS RTN NAME                     65100021
PFK2     DC    C'6B'               PFK RTN NAME                         65200021
SDS3     DC    C'6N'               INTERFACE THREE ROUTINE              65300021
SDS5     DC    C'6P'               INTERFACE FIVE ROUTINE               65400021
SV7      DC    C'77'               K4 RTN NAME                          65700021
SV8      DC    C'78'               K3 RTN NAME                          65800021
DF       DC    C',F '              FRAME CONSTANT                       65900021
DH       DC    C',H '              HOLD CONSTANT                        66000021
DU       DC    C',U '              UPDATE CONSTANT                      66100021
ED       DC    C',D '              DISPLAY CONSTANT                     66200021
EN       DC    C',N '              NUMBER CONSTANT                      66300021
NHOLD    DC    C',N,HOLD '         NUMBER HOLD CONSTANT                 66400021
EPFK     DC    C',PFK '            PFK CONSTANT                         66500021
ESEG     DC    C',SEG '            SEGMENT CONSTANT                     66700021
PATCH    DC    C'****PATCH AREA****'                                    66800021
PATCH1   DC    C'IEE6703D-TEST ONLY'                                    66900021
PATCH2   DC    36C' '                                                   67000021
         EJECT                                                          67100021
DXSA     DSECT                                                          67200021
         IEEXSA                                                         67300021
         ORG   XAS                                                      67400021
XASCID   DS    X                   CONSOLE ID                           67500021
XASDID   DS    C                   DISPLAY AREA ID                      67600021
XASSDS   DS    X                   SDS SWITCHES                         67700021
XASSDS1  EQU   X'80'               THIS COMMAND IS A STATUS            X67800021
                                        DISPLAY                         67900021
XASSDS2  EQU   X'40'               L OPERAND IS SPECIFIED ON           X68000021
                                        COMMAND                         68100021
XASPLS3  DS    X                   RESERVED                             68200021
XASTSAVE DS    F                   ONE WORD TEMPORARY SAVE AREA         68300021
         EJECT                                                          68400021
DCVT     DSECT                                                          68500021
         CVT                                                            68600021
         EJECT                                                          68700021
UCM      DSECT                                                          68800021
         IEECUCM                                                        68900021
         EJECT                                                          69000021
RDCM     DSECT                                                          69100021
         IEECRDCM      DSECT=YES                                        69200021
         EJECT                                                          69300021
TDCM     DSECT                                                          69400021
         IEECEJM CODE=DI                                                69500021
         EJECT                                                          69600021
PLIST    DSECT                                                          69700021
         IEECVMAP KPARAM                                                69800021
         EJECT                                                          69900021
         END                                                            70000021
