IEE6803D CSECT                                                          00100021
*/*IEE6803D: CHART */                                                   00200021
*/*HEADER                                                               00700021
*/*         CHART 68      IEE6803D    IGC6803D  KA CONTROL COMMAND      00800021
*/* MODULE FOR SVC 34 ROUTINE */                                        00900021
*    THIS ROUTINE WAS CREATED FOR STATUS DISPLAY SUPPORT,LINE ITEM      00910000
*    21002, OS RELEASE 21.                                              00920000
         TITLE 'IEE6803D IGC6803D SVC 34 K A COMMAND LOAD 2'            00950000
*********************************************************************** 01100021
*                                                                     * 01200021
* STATUS                                                              * 01300021
*    CHANGE LEVEL=0                                                   * 01400021
*                                                                     * 01500021
* FUNCTION                                                            * 01600021
*     TO HANDLE K A,LL,LL... CONTROL COMMAND WHICH CAN                * 01700021
*     BE HANDLED WITHOUT REFERENCING THE TDCM.                        * 01800021
*                                                                     * 01900021
* ENTRY POINT                                                         * 02000021
*    IEE6803D (CSECT NAME)                                            * 02100021
*    IGC6803D (LOAD MODULE NAME)                                      * 02200021
*                                                                     * 02300021
* INPUT                                                               * 02400021
*    REG 2 POINTS TO XSA ( REG LEFT UNTOUCHED BY THIS MOD.)           * 02500021
*    REG 14 CONTAINS RETURN ADDRESS                                   * 02600021
*                                                                     * 02700021
* OUTPUT                                                              * 02800021
*         K A,LL,LL...-TARGET CONSOLE'S SACBS ARE UPDATED             * 02900021
* NOTE: UPDATED STATUS INFORMATION OF SACB BLOCKS IS ISSUED TO SOURCE * 03000021
* CONSOLE DEVICE VIA WTO.                                             * 03100021
*                                                                     * 03200021
* EXTERNAL REFERENCES                                                 * 03300021
*    WTO                                                              * 03400021
*    GETMAIN                                                          * 03500021
*    XCTL                                                             * 03600021
*    FREEMAIN                                                         * 03650021
*                                                                     * 03700021
* EXITS,NORMAL                                                        * 03800021
*    BR   14                                                          * 03900021
*    IEE5603D  TO PUT OUT A MESSAGE (VIA XCTL)                        * 04000021
*                                                                     * 04100021
* EXITS,ERROR                                                         * 04200021
*     IEE5603D TO PROCESS ERROR MESSAGES                              * 04300021
*                                                                     * 04400021
* ATTRIBUTES                                                          * 04500021
*    REFRESHABLE, PRIVILEGED, TYPE 4 SVC                              * 04600021
*                                                                     * 04700021
* TABLES/WORK AREAS                                                   * 04800021
*    UCM, DCM,  XSA ,SACB                                             * 04900021
*    TABLE - INTERNAL TABLE OF SACB ID'S.                             * 04950021
*                                                                     * 05000021
*********************************************************************** 05100021
         EJECT                                                          05200021
*********************************************************************** 05300021
*                                                                       05400021
*    REGISTERS                                                          05500021
*                                                                       05600021
*********************************************************************** 05700021
RETURN   EQU   14                  SUBROUTINE RETURN REG                05800021
MYBASE   EQU   13                  THIS RTN'S BASE REG                  05900021
SACBPT   EQU   7                   SACB BASE REG                        06000021
UCMBASE  EQU   12                  UCM BASE REG                         06100021
RB       EQU   11                  SUBROUTINE BRANCH REG                06200021
RDCMBASE EQU   10                  RESIDENT DCM BASE REG                06300021
TDCMBASE EQU   9                   TRANSIENT DCM BASE REG               06400021
UCMEBASE EQU   8                                                        06500021
X6       EQU   6                   WORK REG                             06600021
PARMREG  EQU   2                   PARAMETER LIST BASE REG              06700021
X5       EQU   5                   WORK REG                             06800021
X4       EQU   4                   WORK REG                             06900021
KOPS     EQU   4                   OPERAND POINTER                      07000021
X3       EQU   3                   WORK REG                             07100021
R0       EQU   0                   WORK REG                             07200021
R1       EQU   1                   WORK REG                             07300021
R3       EQU   3                   WORK REG                             07400021
R4       EQU   4                   WORK REG                             07500021
R5       EQU   5                   WORK REG                             07600021
R6       EQU   6                   WORK REG                             07700021
R7       EQU   7                   WORK REG                             07800021
RE       EQU   14                  RETURN REG                           07900021
RF       EQU   15                  CODE REG                             08000021
*                                                                       08100021
*     MESSAGE FLAG BIT SETTINGS                                         08200021
IEE931I  EQU   X'0E'               INSUF. STORAGE FOR COMMAND           08400021
IEE924   EQU   X'0A'               MAJOR FLAG BIT-INV. AREA DEF.        08500021
IEE924I  EQU   X'11'               DISPLAY IN OR ABOVE AREA             08600021
IEE924I2 EQU   X'10'               AREA TOO SMALL                       08700021
IEE924I3 EQU   X'0F'               SCREEN SIZE EXCEEDED                 08800021
IEE156I  EQU   X'04'               INVALID OPERAND                      08900021
IEE925I  EQU   X'0B'               NOT A CRT                            09000021
IEE26    EQU   26                  MINOR NO CRT MSG FLAG                09100021
IEE926I  EQU   X'0C'               OPERAND INVALID                      09150021
MSGSTRM  EQU   29                                                       09160021
*                                                                       09200021
N0       EQU   0                   FIELD INCREMENT                      09300021
N1       EQU   1                   FIELD INCREMENT                      09400021
N2       EQU   2                   FIELD INCREMENT                      09500021
N3       EQU   3                   FIELD INCREMENT                      09600021
N4       EQU   4                   FIELD INCREMENT                      09700021
N5       EQU   5                    FIELD INCREMENT                     09800021
N6       EQU   6                   FIELD INCREMENT                      09900021
N7       EQU   7                   FIELD INCREMENT                      10000021
N8       EQU   8                   FIELD INCREENT                       10100021
N26      EQU   26                   FIELD INCREMENT                     10200021
N32      EQU   32                  SIZE IN BYTES OF SACB                10300021
N42      EQU   42                  FIELD INCREMENT                      10400021
N49      EQU   49                  FIELD INCREMENT                      10500021
N255     EQU   255                 FIELD INCREMENT                      10600021
PTRCVT   EQU   16                  CVT ADDR                             10700021
N71      EQU   71                  FIELD SIZE                           10800021
N80      EQU   80                  FIELD SIZE                           11000021
BLANK    EQU   C' '                BLANK CHAR                           11100021
CF0      EQU   X'F0'               CONSTANT                             11200021
COMMA    EQU   C','                CONSTANT                             11300021
MCSMASK  EQU   X'41'               ID PASSED + QUEUE BY ID              11400021
K        EQU   C'K'                COMMAND CONSTANT                     11600021
ZERO     EQU   X'00'               CONSTANT                             11700021
SIGN     EQU   X'FC'               USED TO CONVERT F TO C FOR CVB       11800021
DESCR5   EQU   X'08'               DESCRIPTOR 5 MASK                    11850021
NOHDCPY  EQU   4                   TO SIGNIFY NO HARD COPY              11900021
*                                                                       12000021
*********************************************************************** 12100021
         EJECT                                                          12200021
*********************************************************************** 12300021
*/* E IEE6803D */                                                       12400021
*                                                                       12500021
*/*BASERGS: P (,%NXTSTUP) BASE REGS FOR UCM, DCM, SACB */               12600021
*    ESTABLISH ADDRESSABILITY                                           12700021
*                                                                       12800021
*********************************************************************** 12900021
*                                                                       13000021
*    ON ENTRY, REGISTER 2 CONTAINS ADDRESS OF XSA                       13100021
*                                                                       13200021
         BALR  MYBASE,N0           ESTABLISH ROUTINE 'S                 13300021
         USING *,MYBASE            BASE REGISTER                        13400021
         USING FAUXSA,PARMREG      ESTABLISH XSA ADDRESSABILITY         13500021
         LA    UCMBASE,PTRCVT      GET CVT POINTER                      13600021
         L     UCMBASE,N0(UCMBASE) LOAD CVT POINTER                     13700021
         USING CVTSECT,UCMBASE     BASE CVT REG                         13800021
         L     UCMBASE,CVTCUCB GET UCM POINTER FROM CVT                 13900021
         USING PMUCM,UCMBASE       ESTABLISH UCM ADDRESSABILITY         14000021
         USING UCMLIST,UCMEBASE    BASE UCM ENTRY LIST                  14100021
         USING RDCM,RDCMBASE       ESTABLISH RDCM BASE REG              14200021
         USING DCMDSECT,TDCMBASE   BASE TDCM REG                        14300021
         USING DCMACB,SACBPT       BASE SACB REG                        14400021
         SPACE 3                                                        14500021
*                                                                       14600021
*/*%NXTSTUP: P (,%ANALYZ) SAVE RETURN PT,TARGET INFO. */                14700021
         ST    RE,XAP              SAVE RETURN POINTER                  14800021
         SR    R1,R1               CLEAR REG                            14810021
         STH   R1,XAU+N2           CLEAR SAVE AREA FOR LATER            14820021
         MVC   XAU+N4(N4),XAS      SAVE TARGET INFO                     14900021
*                                                                       15200021
*/*%ANALYZ: D (YES,CHKLLRTN,NO,BADKOP) IS COMMMAND K A,LL... */         15300021
*      ANALYZE COMMAND                                                  15400021
*                                                                       15500021
         L     KOPS,XAL            LOAD PT TO OPERANDS                  15600021
         LA    KOPS,N0(KOPS)       CLEAR HIGH ORDER BYTE                15700021
         ST    KOPS,XAS+N4         SAVE OPERAND POINTER                 15750021
*                                                                       17900021
*                                                                       18000021
*                                                                       18100021
CHKLLRTN EQU   *                                                        26000021
*    FIND AND BASE UCM ENTRY                                            26050000
*    INPUT- REG 1-CONSOLE ID RIGHT JUSTIFIED, HIGH ORDER BYTES ZERO     26100000
*    OUTPUT-POINTER TO UCMENTRY SPECIFIED BY CONSOLE ID IN UCMEBASE REG 26150000
*    REG USAGE-DESTROYS CONTENTS OF: REG 0,1,UCMEBASE                   26200000
*/*CHKLLRTN: P (,FINDTAR) LOAD TARGET CONSOLE'S ID */                   26270000
         IC    R1,XAU+N4           LOAD TARGET CC                       26290000
FINDTAR  EQU   *                                                        26292000
*/*FINDTAR: P (,DCMINIT) FIND UCME FOR CONSOLE'S ID */                  26294000
         SR    R0,R0               CLEAR REG                            26296000
         L     UCMEBASE,UCMVEA     POINT TO FIRST ENTRY                 26298000
         BCTR  R1,ZERO             SUBTRACT ONE FROM CONSOLE ID         26298400
         M     R0,UCMVEZ           MULTIPLY ENTRY SIZE BY REDUCED ID    26298800
         AR    UCMEBASE,R1         POINT TO DESIRED UCM ENTRY           26299200
DCMINIT  EQU   *                                                        26299600
*/*DCMINIT: P (,%TST) INITIALIZE DCM AND SACB POINTERS */               26299700
         L     RDCMBASE,UCMXB           LOAD PT TO RDCM                 26299800
         L     SACBPT,DCMADSDS         LOAD SACB POINTER FROM RDCM      26299900
         L     TDCMBASE,N0(RDCMBASE)   LOAD PT TO TDCM                  26300000
*/*%TST: D (YES,,NO,IEE925) IS CONSOLE DEVICE A CRT */                  26310000
         TM    UCMDISP,UCMDISPC    IS IT A CRT                          26320000
         BNO   IEE925              NOT A CRT-ERROR                      26330000
*/*%MSGSTRM: D (NO,SETUP,YES,ERRORMSG) IS CONSOLE MSG STREAM */         26332000
         TM    UCMDISP,UCMDISPF    IS IT A MSG STREAM CONSOLE           26340000
         BNO   SETUP               NO-                                  26350000
         MVI   XAE,IEE926I         INDICATE INVALID OP                  26360000
         MVI   XAU+N3,MSGSTRM   INDICATE MSG STREAM OUTPUT ONLY         26362000
         B     ERRORMSG                                                 26364000
*/*SETUP: P (,LLLOOP) PRIME REGS FOR LL SYNTAX CHECKING */              26366700
SETUP    EQU   *                                                        26376700
         LA    X6,XAD           GET ADDR OF SAVE LENGTHS AREA           26400021
         SR    R0,R0               CLEAR REG                            26500021
         SR    R1,R1               CLEAR REG                            26600021
         LA    KOPS,N1(KOPS)       BUMP OPERAND POINTER                 26700000
*/*LLLOOP: D (ONE,ONEDIGIT,TWO,TWODIGIT) IS LL ONE DIGIT LONG */        26800021
LLLOOP   EQU   *                                                        26900021
         LA    KOPS,N1(KOPS)       BUMP TO POINT BEYOND COMMA           26950000
         SR    R5,R5               CLEAR REG                            27000021
         XC    XAS(N8),XAS         CLEAR PACKING AREA                   27100021
* NOTE: DIGITS CAN BE ONLY 1 OR 2 DIGITS LONG, RANGING FROM 4-MSG AREA  27150000
*       SIZE IN VALUE.                                                  27160000
         TM    N0(KOPS),CF0        IS DIGIT VALID                       27170000
         BNO   BADKOP              NO - BAD INPUT                       27180000
         CLI   N1(KOPS),BLANK       IS THERE A SECOND DIGIT             27200021
         BE    ONEDIGIT            NO--IT IS A BLANK                    27300021
         CLI   N1(KOPS),COMMA       IS SECOND DIGIT A COMMA             27400021
         BE    ONEDIGIT            YES-IT IS A COMMA                    27450000
         TM    N1(KOPS),CF0        IS SECOND DIGIT VALID                27452000
         BNO   BADKOP              NO - BAD INPUT                       27454000
         CLI   N2(KOPS),BLANK       IS THERE A THIRD DIGIT              27460000
         BE    TWODIGIT            NO--SEE IF IT'S A VALID DIGIT        27500000
         CLI   N2(KOPS),COMMA       IS THERE A THIRD DIGIT              27550000
         BE    TWODIGIT            NO--SEE IF IT'S A VALID DIGIT        27560000
         B     BADKOP              NUMBER IS NO GOOD                    27570000
ONEDIGIT EQU   *                                                        27600021
*/*ONEDIGIT: P (,GOPACK) MOVE DIGIT FOR PACKING */                      27700000
         MVC   XAS+N7(N1),N0(KOPS) MOVE THE DIGIT                       28000021
         LA    KOPS,N1(KOPS)       BUMP POINTER TO NEXT LL              28100000
         B     GOPACK              GO PACK IT                           28200021
*/*TWODIGIT: P (,GOPACK) MOVE DIGITS TO PACKING AREA */                 28300021
TWODIGIT EQU   *                                                        28400021
         MVC   XAS+N6(N2),N0(KOPS) MOVE THE DIGIT                       28500021
         LA    KOPS,N2(KOPS)       BUMP LL POINTER                      28600000
*/*GOPACK: P (,%CVB) PACK THE NUMBER */                                 28700021
GOPACK   EQU   *                                                        28800021
         PACK  XAS+N4(N4),XAS+N4(N4)  PACK NUMBER                       28900021
         NI    XAS+N7,SIGN         CONVERT FOX TO CHARLIE               29000021
*/*%CVB: P (,%TESTLL) CONVERT PACKED NUMBER TO BINARY */                29100021
         CVB   R5,XAS              CONVERT IT TO A BINARY NUMBER        29200021
*/*%TESTLL: D (NO,NXTLLTST,YES,ERR3)  NUMBER GREATER THAN MSG AREA */   29300021
         CH    R5,DCMRMSAL         IS LL GREATER THAN MSG AREA          29400021
         BH    ERR3                YES-IT'S AN ERROR                    29500021
*/*NXTLLTST: D (YES,ERR2,NO,DIGITCNT) IS NUMBER LESS THAN FOUR */       29600021
         CH    R5,NOFOUR           IS IT LESS THAN FOUR                 29700021
         BL    ERR2                YES-                                 29800021
*/*DIGITCNT: D (YES,ERR3,NO,BUMPTS)  TOTAL NO. GREATER THAN MSG         29900021
*/*AREA */                                                              30000021
DIGITCNT EQU   *                                                        30100021
         AR    R0,R5               ADD TO LINE COUNTER                  30200021
         CH    R0,DCMRMSAL         DOES LINE COUNT EXCEED MAX. NUMBER   30300021
         BH    ERR3                YES--IT'S AN ERROR                   30400000
*/*BUMPTS: P (,%MORETST) BUMP ALL POINTERS */                           30500000
         STC   R5,N0(R6)           MOVE AREA ID                         30600021
         LA    R6,N1(R6)           BUMP LENGTH SAVE AREA POINTER        30700021
         LA    R1,N1(R1)           BUMP AREA COUNTER                    30800021
*/*%MORETST: D (YES,LLLOOP,NO,LPTEST) ANY MORE LL'S TO DO */            31200000
         CLI   N0(KOPS),BLANK      ANY MORE DIGITS                      31300021
         BNE   LLLOOP              YES-GO HANDLE                        31400000
* NOTE: IF NO SACB'S EXIST, SKIP THE NEXT TWO LOOPS.                    31500021
LPTEST   EQU   *                                                        31550000
*/*LPTEST: D (YES,LOOP,NO,ENDLL) ANY SACB'S DEFINED */                  31560000
         LTR   SACBPT,SACBPT       ANY SACB'S DEFINED                   31600021
         BZ    ENDLL               NO - SKIP NEXT 2 LOOPS               31700021
* THE NEXT LOOP WILL SEARCH FOR SACB ID OF HIGHEST DISPLAY AREA IN USE  31800021
LOOP     EQU   *                                                        31900021
*/*LOOP: D (YES,SAVE,NO,BUMPBLK) DISPLAY IN THIS AREA */                32000021
         TM    DCMAFLG1,DCMADISP   IS A DISPLAY IN THE AREA             32100021
         BNO   BUMPBLK              NO- GO TO NEXT                      32200021
*/*SAVE: P (,BUMPBLK) SAVE THIS AREA'S ID */                            32300021
         MVC   XAU+N2(N1),DCMAID   MOVE SACB ID TO SAVE AREA            32400021
BUMPBLK  EQU   *                                                        32500021
*/*BUMPBLK: D (YES,LOOP,NO,STRT1) ANY MORE AREAS DEFINED */             32600021
         L     SACBPT,N0(SACBPT)   LOAD ADDR OF NEXT SACB               32700021
         LTR   SACBPT,SACBPT       ANY AREA DEFINED                     32800021
         BNZ   LOOP            YES--GO CHK IT OUT                       32900021
STRT1    EQU   *                                                        33000021
*/*STRT1: P (,TSTNXTBL) REINITIALIZE POINTERS */                        33100021
         L     SACBPT,DCMADSDS     LOAD CHAIN START ADDR                33200021
         LA    X3,TABLE            LOAD ADDR OF AREA ID TABLE           33300021
         LA    R5,XAD           GET POINTER TO LENGTHS                  33400021
*    THE FOLLOWING CODE CHECK THAT SACBS ARE REDEFINED ONLY             33500021
*    IF THERE IS NO DISPLAY IN OR ABOVE AREAS                           33600000
TSTNXTBL EQU   *                                                        33700021
*/*TSTNXTBL: D (YES,COMPLL,NO,TSTNXT) USED DISPLAY ABOVE THIS AREA */   33800021
         CLC   XAU+N2(N1),DCMAID   Q. IS BLOCK ABOVE USED AREA          33900021
         BNL   COMPLL              NO - COMPARE LENGTHS                 34000021
*/*TSTNXT: D (YES,COMPLL,NO,BUMP) IS A DISPLAY IN AREA */               34100021
         TM    DCMAFLG1,DCMADISP   IS A DISPLAY IN THE AREA             34200021
         BNO   BUMP                 NO- GO TO NEXT                      34300021
*/*COMPLL: D (YES,BUMP,NO,ERROR) ARE SACB LENGTHS EQUAL */              34400021
COMPLL   EQU   *                                                        34500021
         CLC   DCMALN+N1(N1),N0(R5) YES- COMPARE SACB LENGTHS           34600021
         BNE   ERROR               IF NOT THE SAME IT'S AN ERROR        34700021
BUMP     EQU   *                                                        34800021
*/*BUMP: D (YES,%BMP,NO,ENDLL) ANOTHER SACB TO CHECK OUT */             34900000
         L     SACBPT,N0(SACBPT)   LOAD ADDR OF NEXT SACB               35000021
         LTR   SACBPT,SACBPT       ANY OTHER AREA DEFINED               35100021
         BZ    ENDLL               NO - LAST SACB INSPECTED             35200021
*/*%BMP: P (,TSTNXTBL) BUMP SACB, AREA ID, LL POINTERS */               35250000
         LA    R5,N1(R5)           BUMP LENGTHS POINTER                 35400021
         BCT   R3,TSTNXTBL  DECREMENT POINTER AND CHK NEXT BLOCK        35500000
         SPACE 2                                                        35550000
*    ALL THE SACBS HAVE BEEN INSPECTED- INITIALIZE TO DESIRED LENGTH    35700021
*/*ENDLL: P (,INCORE2) PRIME POINTERS TO ID TABLE, SACB CHAIN START AND 35800021
*/* LOAD SIZE OF SCREEN */                                              35900021
ENDLL    EQU   *                                                        36000021
         LA    X3,TABLE            LOAD ADDR OF AREA ID TABLE           36100021
         LA    R5,XAD           GET POINTER TO LENGTHS                  36200021
         L     SACBPT,DCMADSDS     LOAD CHAIN START ADDR                36300021
         LA    X6,DCMADSDS         SAVE ADDR OF CHAIN BLOCK ORIGIN      36400000
         LH    R4,DCMRMSAL         LOAD SIZE OF MSG AREA                36600021
         LA    R4,N1(R4)           BUMP IT BY ONE                       36700021
*/*INCORE2: D (NO,GETCORE,YES,%CHK) WERE ANY AREAS DEFINED */           36800021
INCORE2  EQU   *                                                        36900021
         LTR   SACBPT,SACBPT       ANY AREA DEFINED                     37000021
         BZ    GETCORE             YES--GO CHK IT OUT                   37100021
*/*%CHK: D (NO,INITOLD,YES,NXTBLCK) IS THIS AREA BEING USED */          37200021
         TM    DCMAFLG1,DCMADISP   IS SACB BEING USED                   37300021
         BO    NXTBLCK             YES                                  37400021
         LA    RE,INCORE3          PRIME RETURN POINTER                 37500021
         B     INITOLD                                                  37600021
*/*NXTBLCK: P (,INCORE) MOVE PTS TO NEXT SACB ID AND LL */              37700021
NXTBLCK  EQU   *                                                        37800021
         BCTR  X3,N0               DECREMENT ID POINTER                 37900021
         LA    R5,N1(R5)           INCREMENT LL POINTER                 38000021
         SR    R4,R4               CLEAR REG                            38050000
         IC    R4,DCMATOP          INITIALIZE STARTING POINT TO        X38060000
                                        CALCULATE TOP ROW NO.           38070000
         LR    R6,SACBPT           UPDATE POINTER TO PREVIOUS BLOCK     38100021
*/*INCORE: P (,LOOPTST) LOAD NEXT SACB ADDR */                          38200021
INCORE   EQU   *                                                        38300021
         L     SACBPT,N0(SACBPT)   LOAD ADDR OF NEXT SACB               38400021
*/*LOOPTST: D (YES,INCORE2,NO,ZAPSACB) ANY MORE LL'S TO DO */           38500021
         BCT   R1,INCORE2          DECR. SACB LL COUNT                  38600021
REST     EQU   *                                                        38700021
         LR    SACBPT,X6           RESTORE PT TO LAST BLOCK             38800021
         B     ZAPSACB                                                  38900021
*                                                                       39000021
*/*INCORE3: P (,INCORE) RESET SACB                                      39100000
*/*COUNTER */                                                           39200021
INCORE3  EQU   *                                                        39300021
         LA    R1,N1(R1)            RESET SACB COUNTER BY 1             39400000
         B     INCORE                                                   39700000
*                                                                       39800021
*/*ERR2: P (,ERROR2) INDICATE AREA TOO SMALL ERROR MESSAGE */           39900021
ERR2     EQU   *                                                        40000021
         MVI   XAU+N3,IEE924I2     AREA TOO SMALL                       40100021
         BCTR  KOPS,N0             SUBTRACT ONE TO POINT TO            X40150000
                                        BAD OPERAND                     40160000
         B     ERROR2              BRANCH TO ERROR EXIT                 40200000
*/*ERR3: P (,ERROR2) INDICATE SCREEN SIZE EXCEEDED ERROR MESSAGE */     40300021
ERR3     EQU   *                                                        40400021
         MVI   XAU+N3,IEE924I3     SCREEN SIZE EXCEEDED                 40500021
         SH    KOPS,NOFOUR         RESET TO POINT TO LAST NO.           40550000
         TM    N0(KOPS),CF0        DOES IT POINT TO A NUMBER            40560000
         BO    ERROR2              YES, BRANCH TO ERROR EXIT            40570000
         LA    KOPS,N1(KOPS)       POINT TO NUMBER                      40580000
         B     ERROR2              BRANCH TO ERROR EXIT                 40600000
*/*GETCORE: P (,CHKCD) GET 32 BYTES OF CORE */                          40700021
GETCORE  EQU   *                                                        40800021
         ST    X6,XAV+N4           SAVE OLD SACB POINTER                40900000
         SR    R0,R0               CLEAR REG                            41000021
         ST    R1,XAS+N4              SAVE COUNT                        41100021
         LA    R1,N32              LOAD BYTE COUNT WANTED               41200021
         M     R0,XAS+N4           MULTIPLY SACB BY SIZE                41300021
         LR    R0,R1               SET REG COUNT                        41400021
         BAL   RB,GETMAIN          GO DO GETMAIN                        41500021
*/*CHKCD: D (NO,MSG931,YES,GOON) WAS GETMAIN RETURN CODE GOOD */        41600021
         LTR   RF,RF              TEST RETURN CODE                      41700021
         BNZ   MSG931             ERROR IF NOT ZERO;MEANS NO CORE       41800021
*/*GOON: P (,INIT3) PRIME ALL PTS TO INITIALIZE SACB */                 41900021
         L     X6,XAV+N4           RESTORE OLD SACB POINTER             42200000
         L     SACBPT,XAS          LOAD ADDR OF SACB CORE               42300000
         L     R1,XAS+N4              RESTORE COUNTER                   42400021
         B     INIT3          GO INITIALIZE IT                          42500021
         SPACE 2                                                        42600021
ERROR    EQU   *                                                        42700021
*/*ERROR: P (,ERROR2) INDICATE DISPLAY IN OR ABOVE AREA ERROR MSG. */   42800021
         MVI   XAU+N3,IEE924I      DISPLAY IN OR ABOVE AREA             42900021
         SPACE 2                                                        43000021
ERROR2   EQU   *                                                        43100021
*/*ERROR2: P (,STOREOP) INDICATE ERROR MSG ID IEE924 */                 43200021
         MVI   XAE,IEE924          SET ON MAJOR FLAG BIT                43300021
         B     STOREOP                                                  43400021
         SPACE 2                                                        43500021
*/*INIT2: P (,INIT3) BUMP PT FOR GETMAINED CORE SACB */                 43600021
INIT2    EQU   *                                                        43700021
         LA    SACBPT,N32(SACBPT)  BUMP SACB PT TO NEXT BLOCK           43800021
         SPACE 2                                                        43900021
*    SET GETMAINED FLAG BIT ON WHEN SACB CORE IS GETMAINED.             44000000
INIT3    EQU   *                                                        44100021
*/*INIT3: P (,INITOLD) TURN ON GETMAINED BIT IN SACB */                 44200021
         OI    DCMASACB,DCMAGM SET GETMAINED FLAG BIT IN SACB ON        44300021
         LA    RE,INIT2            PRIME RETURN POINTER                 44400021
         SPACE 2                                                        44500021
*/*INITOLD: P (,%NXT) INITIALIZE SACB */                                44600021
INITOLD  EQU   *                                                        44700021
         ST    SACBPT,N0(X6)       SET UP CHAINING OF BLOCKS            44800021
         XC    DCMALN(N26),DCMALN  CLEAR SACB WITH ZEROS                44900021
         LR    X6,SACBPT           SAVE PT TO THIS BLOCK                45000021
         MVC   DCMAID(N1),N0(R3)       MOVE AREA ID INTO SACB           45100021
         BCTR  R3,N0           DECR TABLE POINTER                       45200021
         MVC   DCMALN+N1(N1),N0(R5)   MOVE LL OF AREA INTO SACB         45300021
         LA    R5,N1(R5)           BUMP PT                              45400021
         SH    R4,DCMALN           MINUS NO. OF LINES FOR THIS AREA     45500021
         STC   R4,DCMATOP          SAVE TOP ROW NO. OF AREA IN SACB     45600021
         OI    DCMASACB,DCMAUSE SET IN-USE FLAG BIT IN SACB ON          45700021
         MVC   DCMAFR(N2),F0F0     INITIALIZE FRAME NO.                 45800021
*        SACB AREA SHOULD NOW BE FULLY INITIALIZED FOR USE              45900021
         SPACE 2                                                        46000021
*/*%NXT: D (NO,%RE,YES,ZAPSACB) DOES BLOCK COUNTER = ZERO */            46100021
         BCTR  R1,RETURN           GO CONTINUE SACB INITIALIZATION LOOP 46200021
*/*%RE: R RETURN TO INIT2 OR INCORE3 */                                 46300021
*/*ZAPSACB: P (,SACBLP) ZERO OUT CHAIN PT AND INITIALIZE                46400021
*/*TOP SACB AREA ID IN RDCM */                                          46500021
ZAPSACB  EQU   *                                                        46600021
         ST    R1,DCMACB           ZERO OUT LAST BLOCK'S PT             46700021
         MVC   DCMTOPAR,DCMAID     MOVE TOP SACB AREA ID INTO RDCM      46800021
         L     SACBPT,DCMADSDS     RESET SACB PT                        46850000
         SPACE 2                                                        46900000
*/*SACBLP: S (,%TSTCODE) GETMAIN: DO GETMAIN FOR 80 BYTES */            46950000
SACBLP EQU   *                                                          47000000
         LA    R0,N80             LOAD LENGTH OF CORE NEEDED            47050000
         BAL   RB,GETMAIN          GO GET CORE                          47100000
*   NOTE: IF CORE IS NOT AVAILABLE, DO NOT WRITE WTO MSG, BUT           47150000
*   RETURN ROUTINE THAT ISSUED SVC 34.                                  47200000
*/*%TSTCODE: D (YES,%WTO,NO,BRANCH14) RETURN CODE GOOD */               47250000
         LTR   RF,RF              TEST RETURN CODE                      47300000
         BNZ   BRANCH14            IF NOT ZERO;MEANS NO CORE            47350000
*/*%WTO: P (,NEXTSACB) SET UP MSG IEE928I AND ISSUE WTO */              47400000
         L     R6,XAS              LOAD GETMAINED ADDR                  47450000
         LR    R1,R6               SAVE POINTER                         47500000
         MVC   N4(L'IEE928I,R6),IEE928I      MOVE MSG INTO GETMAINED    47550000
         LA    R6,N49(R6)        BUMP MESSAGE POINTER                   47600000
         SR    R3,R3               CLEAR COUNTER                        47900000
*/*NEXTSACB: D (NO,NEXTBLK,YES,%BUMPIT) AREA DEFINED FOR THIS SACB */   47950000
NEXTSACB EQU   *                                                        48000000
         TM    DCMASACB,DCMAUSE    AREA DEFINED HERE                    48050000
         BNO   NEXTBLK             NO--CHK NEXT SACB                    48100000
*/*%BUMPIT: P (,NEXTBLK) BUMP CNTR; MOVE AREA ID INTO MSG; BUMP PT */   48150000
         LA    R3,N1(R3)          BUMP COUNTER                          48200000
AREA     EQU   *                                                        48250000
         MVC   N0(N1,R6),DCMAID       MOVE AREA ID INTO MSG             48300000
         MVI   N1(R6),COMMA       MOVE IN COMMA AFTER AREA ID           48350000
         LA    R6,N2(R6)          BUMP MESSAGE POINTER                  48400000
*/*NEXTBLK: D (YES,NEXTSACB,NO,%TEST3) ANY MORE SACB'S */               48450000
NEXTBLK  EQU   *                                                        48500000
         L     SACBPT,N0(SACBPT)  GET POINTER TO NEXT SACB              48550000
         LTR   SACBPT,SACBPT      IS IT A VALID POINTER                 48600000
         BNZ   NEXTSACB           YES-KEEP ON LOOPING                   48650000
         BCTR  R6,N0              GET RID OF EXTRA COMMA                48850021
FINIT    EQU   *                                                        48950000
*/*FINIT: P (,%CNVT) LOAD CONSOLE ID */                                 49000000
         SR    X4,X4               CLEAR REG                            49050000
         IC    X4,XAU+N4           GET TARGET'S CONSOLE ID              49100000
*/*%CNVT: P (,WRTWTO) CONVERT CONSOLE ID FROM HEX TO EBCDIC */          49150000
*    THIS CODE WILL CONVERT HEX  TO EBCDIC                              49200000
         CVD   X4,XAS         CONVERT TO DECIMAL                        49250000
         UNPK  XAS(N3),XAS+N6(N2)  UNPACK NUMBER                        49300000
         OI    XAS+N2,CF0          FIX SIGN                             49350000
         MVC   N42(N2,R1),XAS+N1   PUT CC INTO MSG                      49400000
*/*WRTWTO: P (,BRANCH14) PREPARE AND ISSUE WTO FOR MSG IEE928I */       49450000
WRTWTO   EQU   *                                                        49500000
         SR    R0,R0               CLEAR REG                            49550000
         XC    N1(N3,R6),N1(R6)    ZERO OUT CODE AREA                   49600000
         MVI   N0(R6),DESCR5       MOVE DESCRIPTOR CODE                 49650000
         SR    R6,R1               GET LENGTH OF MSG                    49750000
         STH   R6,N0(R1)           STORE FOR WTO                        49800000
         MVI   N2(R1),MCSMASK      ID PASSED AND QUEUE BY ID FLAGS      49850000
         MVI   N3(R1),N0           ZERO SECOND MCSFLGS BYTE             49900021
         IC    R0,XAU              LOAD SOURCE DEVICE ID                49950000
         LR    R6,R1               SAVE POINTER TO PARAMETER LIST       49952021
         SPACE 2                                                        49960000
         WTO   MF=(E,(1))                                               50000021
*/*%FREE: S (,BRANCH14) FREEMAIN:FREE WTO PARAMETER LIST */             50010021
         FREEMAIN R,SP=N255,LV=N80,A=(R6)                               50020021
*/*BRANCH14: R RETURN TO CALLER VIA BR 14 */                            50050000
BRANCH14 EQU   *                                                        50100000
         L     RETURN,XAP       RESTORE RETURN REG                      50150000
         BR    RETURN             GO BACK TO SYSTEM                     50200000
         EJECT                                                          50460000
GETMAIN  EQU   *                                                        50500000
         LA    R6,XAS             GET ADDR OF A WORD IN CORE            50550000
         GETMAIN EC,LV=(0),A=(6),SP=255                                 50600000
         BR    RB                                                       50650000
         SPACE 2                                                        50700000
*/*MSG931: P (,ERRORMSG) INDICATE CORE NOT AVAILABLE MSG IEE931I */     50750000
MSG931   EQU   *                                                        50800000
         MVI   XAE,IEE931I      CORE NOT AVAILABLE                      50850000
         B     ERRORMSG            GO TO PUT OUT MSG                    50900000
*/*IEE925: P (,ERRORMSG) INDICATE TARGET CONSOLE NOT A CRT ERROR        52200021
*/*MESSAGE */                                                           52300021
IEE925   EQU   *                                                        52400021
         OI    XAE,IEE925I         INDICATE NOT A CRT                   52500021
         OI    XAU+N3,IEE26        DITTO FOR MINOR FLAG                 52600021
         B     ERRORMSG                                                 52700021
         SPACE 3                                                        52710021
*/*BADKOP: P (,STOREOP) INDICATE ERROR IEE156I */                       52750021
BADKOP   EQU   *                                                        52760021
         MVI   XAE,IEE156I      NONE OF ABOVE,SO ITS BAD                52770021
*/*STOREOP: P (,ERRORMSG) SAVE OP POINTER; MINOR FLAGS */               52780021
STOREOP  EQU   *                                                        52790021
         ST    KOPS,XAS+N4         SAVE OPERAND POINTER                 52792021
*/*ERRORMSG: P (,XCTL) RESTORE XSA MSG MOD NAME, COMMAND */             52794021
ERRORMSG EQU   *                                                        52796021
         MVC   XAX(N8),IGC5603D     MOVE XSA SVC 34 MSG MOD. NAME       52798021
         MVC   XAS+N4(N1),XAU+N3   MOVE MINOR MSG FLAGS                 52798421
* NOTE: XAD AND XAV AREAS ARE USED TO SAVE CONVERTED SACB LENGTHS AND   52798821
* MUST  BE RESTORED.                                                    52799221
         CLI   XAV,K               WAS COMMAND = K                      52799621
         BNE   NOTK                NO - SKIP                            52799721
         MVC   XAV+N4(N4),XAV+N3   MOVE IN 4 BLANKS                     52799821
         B     XCTL                SKIP NEXT INSTR.                     52799921
NOTK     EQU   *                                                        52833221
         MVC   XAV+N4(N4),ROL      RESTORE 'CONTROL' WORD               52843221
*/*XCTL: R MESSAGE MOD (IEE5603D) */                                    52853221
XCTL     EQU   *                                                        52863221
         L     RETURN,XAP          RESTORE RETURN REG                   52865221
         LA    X5,XAX              RESTORE OPERAND                      52865621
         ST    X5,XAP                 POINTER                           52866021
         MVC   XAS(N4),XAU+N4      RESTORE TARGET INFO.                 52866421
         XC    XAD(N4),XAD         CLEAR DCB POINTER                    52866521
         XCTL  SF=(E,(2))         ISSUE XCTL                            52866621
         EJECT                                                          52866721
*                                                                       52900021
*    CONSTANTS                                                          53000021
NOFOUR   DC    H'4'                CONSTANT                             53100021
F0F0     DC    XL2'F0F0'           AREA FRAME NUMBER ZERO               53400021
         SPACE 2                                                        53500021
* NOTE: FOLLOWING TABLE IS INTERNAL TO THIS MODULE.                     53550000
*        END OF SACB AREA ID TABLE***                                   53600021
         DC    C'K'                SACB AREA ID                         53700021
         DC    C'J'                SACB AREA ID                         53800021
         DC    C'I'                SACB AREA ID                         53900021
         DC    C'H'                SACB AREA ID                         54000021
         DC    C'G'                SACB AREA ID                         54100021
         DC    C'F'                SACB AREA ID                         54200021
         DC    C'E'                SACB AREA ID                         54300021
         DC    C'D'                SACB AREA ID                         54400021
         DC    C'C'                SACB AREA ID                         54500021
         DC    C'B'                SACB AREA ID                         54600021
TABLE    DC    C'A'                BOTTOM SACB AREA ID                  54700021
         SPACE 2                                                        54800021
IEE928I  DC    CL45'IEE928I DISPLAY AREA ID''S FOR CONSOLE CC ARE'      54900021
IGC5603D DC    C'IGC5603D'         MSG MODULE NAME                      55000000
ROL      DC    C'ROL '             SECOND WORD OF COMMAND 'CONTROL'     55150000
PATCH    DC    CL72'***PATCH AREA - IEE6803D***'                        55200000
         EJECT                                                          55250000
*                                                                       55400021
*    ALL DSECTS FOLLOW THIS POINT                                       55500021
*                                                                       55600021
DCMDSECT DSECT                                                          55700021
         IEECBJH CODE=DI                                                55800021
         EJECT                                                          55900021
PMUCM    DSECT                                                          56000021
         IEECUCM                                                        56100021
RDCM     DSECT                                                          56200021
         IEECRDCM DSECT=YES                                             56300021
FAUXSA   DSECT                                                          56500021
         IEEXSA                                                         56600021
CVTSECT  DSECT                                                          56700021
         CVT                                                            56800021
*********************************************************************** 56900021
*/*IEE6803D: END */                                                     57000021
         END                                                            57100021
