IEE6903D CSECT                                                          00100021
*/*IEE6903D: CHART */                                                   00200021
         SPACE 2                                                        00300021
*    THIS ROUTINE WAS CREATED FOR STATUS DISPLAY SUPPORT,LINE ITEM      00400021
*    21002, OS RELEASE 21.                                              00500021
*/*HEADER                                                               00600021
*/*      CHART 69  IEE6903D  IGC6903D  KA CONTROL COMMAND               00700021
*/* MODULE FOR SVC 34 ROUTINE */                                        00800021
         TITLE 'IEE6903D IGC6903D SVC 34 K A COMMAND LOAD 5'            00900021
*********************************************************************** 01000021
*                                                                     * 01100021
* STATUS                                                              * 01200021
*    CHANGE LEVEL=0                                                   * 01300021
*                                                                     * 01400021
* FUNCTION                                                            * 01500021
*    TO HANDLE K A AND K A,REF  CONTROL COMMANDS WHICH CAN BE HANDLED * 01600021
*    WITHOUT  REFERENCING  THE TRANSIENT DCM .                        * 01700021
*    TARGET CONSOLE MUST BE A GRAPHIC DEVICE.                         * 01800021
*                                                                     * 01900021
* ENTRY POINT                                                         * 02000021
*    IEE6903D (CSECT NAME)                                            * 02100021
*    IGC6903D (LOAD MODULE NAME)                                      * 02200021
*                                                                     * 02300021
* INPUT                                                               * 02400021
*    REG 2 POINTS TO XSA ( REG LEFT UNTOUCHED BY THIS MOD.)           * 02500021
*    REG 14 CONTAINS RETURN ADDRESS                                   * 02600021
*                                                                     * 02700021
* OUTPUT                                                              * 02800021
*         K A,REF OR K M  --   SACB INFO. IS DISPLAYED                * 02900021
*         K A,NONE -- ALL SACB'S ARE DESTROYED                        * 03000021
* NOTE:  ALL INFORMATION IS DISPLAYED IN THE ENTRY AREA IF SOURCE     * 03100021
*        IS A GRAPHIC CONSOLE, ELSE IT IS ISSUED VIA WTO.             * 03200021
*                                                                     * 03300021
* EXTERNAL REFERENCES                                                 * 03400021
*    WTO                                                              * 03500021
*    GETMAIN                                                          * 03600021
*    FREEMAIN                                                         * 03700021
*    XCTL                                                             * 03800021
*                                                                     * 03900021
* EXITS,NORMAL                                                        * 04000021
*    BR   14                                                          * 04100021
*    IEE5603D  TO PUT OUT A MESSAGE (VIA XCTL)                        * 04200021
*                                                                     * 04300021
* EXITS,ERROR                                                         * 04400021
*     IEE5603D TO PROCESS ERROR MESSAGES                              * 04500021
*                                                                     * 04600021
* ATTRIBUTES                                                          * 04700021
*    REFRESHABLE, PRIVILEGED, TYPE 4 SVC                              * 04800021
*                                                                     * 04900021
* TABLES/WORK AREAS                                                   * 05000021
*    UCM, RDCM, WQE, XSA ,TDCM ,SACB                                  * 05100021
*                                                                     * 05200021
*********************************************************************** 05300021
         EJECT                                                          05400021
*********************************************************************** 05500021
*                                                                       05600021
*    REGISTERS                                                          05700021
*                                                                       05800021
*********************************************************************** 05900021
RETURN   EQU   14                  SUBROUTINE RETURN REG                06000021
MYBASE   EQU   13                  THIS RTN'S BASE REG                  06100021
SACBPT   EQU   7                   SACB BASE REG                        06200021
UCMBASE  EQU   12                  UCM BASE REG                         06300021
RB       EQU   11                  SUBROUTINE BRANCH REG                06400021
RDCMBASE EQU   10                  RESIDENT DCM BASE REG                06500021
TDCMBASE EQU   9                   TRANSIENT DCM BASE REG               06600021
UCMEBASE EQU   8                                                        06700021
PARMREG  EQU   2                   PARAMETER LIST BASE REG              06800021
X5       EQU   5                   WORK REG                             06900021
X4       EQU   4                   WORK REG                             07000021
KOPS     EQU   4                   OPERAND POINTER                      07100021
R0       EQU   0                   WORK REG                             07200021
R1       EQU   1                   WORK REG                             07300021
R3       EQU   3                   WORK REG                             07400021
R4       EQU   4                   WORK REG                             07500021
R5       EQU   5                   WORK REG                             07600021
R6       EQU   6                   WORK REG                             07700021
R7       EQU   7                   WORK REG                             07800021
RE       EQU   14                  RETURN REG                           07900021
RF       EQU   15                  CODE REG                             08000021
*                                                                       08100021
         EJECT                                                          08200021
*     MESSAGE FLAG BIT SETTINGS                                         08300021
OPTIONS  EQU   X'02'               WRITE OPTIONS MSG                    08400021
IEE931I  EQU   X'0E'               INSUF. STORAGE FOR COMMAND           08500021
IEE156I  EQU   X'04'               INVALID OPERAND                      08600021
IEE925I  EQU   X'0B'               FOR CRT ONLY                         08700021
IEE26    EQU   26                  NO CRT MINOR FLAG BIT                08800021
IEE924I  EQU   X'11'               AREA HAS DIPLAY IN OR ABOVE NSG      08900021
IEE924   EQU   X'0A'               DITTO- MINOR FLAG                    09000021
*                                                                       09100021
N0       EQU   0                   FIELD INCREMENT                      09200021
N1       EQU   1                   FIELD INCREMENT                      09300021
N2       EQU   2                   FIELD INCREMENT                      09400021
N3       EQU   3                   FIELD INCREMENT                      09500021
N4       EQU   4                   FIELD INCREMENT                      09600021
N5       EQU   5                    FIELD INCREMENT                     09700021
N6       EQU   6                   FIELD INCREMENT                      09800021
N7       EQU   7                   FIELD INCREMENT                      09900021
N8       EQU   8                   FIELD INCREENT                       10000021
N42      EQU   42                  FIELD INCREMENT                      10100021
N49      EQU   49                  FIELD INCREMENT                      10200000
N255     EQU   255                 FIELD INCREMENT                      10300021
PTRCVT   EQU   16                  CVT ADDR                             10400021
N72      EQU   70                  FIELD INCREMENT                      10500021
BLANK    EQU   C' '                BLANK CHAR                           10600021
NC       EQU   12                  FIELD INCREMENT                      10700021
N80      EQU   80                  FIELD SIZE                           10800021
CF0      EQU   X'F0'               CONSTANT                             10900021
COMMA    EQU   C','                CONSTANT                             11000021
ZERO     EQU   X'00'               CONSTANT                             11100021
MCSMASK  EQU   X'41'               ID PASSED + QUEUE BY ID              11200021
NOHDCPY  EQU   4                   SIGNIFY NO HARD COPY                 11300021
*                                                                       11400021
*********************************************************************** 11500021
         EJECT                                                          11600021
*********************************************************************** 11700021
*                                                                       11800021
*    ESTABLISH ADDRESSABILITY                                           11900021
*                                                                       12000021
*********************************************************************** 12100021
*/* E IEE6903D */                                                       12200021
*                                                                       12300021
*    ON ENTRY, REGISTER 2 CONTAINS ADDRESS OF XSA                       12400021
*                                                                       12500021
*/*BASEREGS: P (,NXTSTUP) ESTABLISH ADDRESSABILITY */                   12600021
         BALR  MYBASE,N0           ESTABLISH ROUTINE 'S                 12700021
         USING *,MYBASE            BASE REGISTER                        12800021
         USING FAUXSA,PARMREG      ESTABLISH XSA ADDRESSABILITY         12900021
         LA    UCMBASE,PTRCVT      GET CVT POINTER                      13000021
         L     UCMBASE,N0(UCMBASE) LOAD CVT POINTER                     13100021
         USING CVTSECT,UCMBASE     BASE CVT REG                         13200021
         L     UCMBASE,CVTCUCB GET UCM POINTER FROM CVT                 13300021
         USING PMUCM,UCMBASE       ESTABLISH UCM ADDRESSABILITY         13400021
         USING UCMLIST,UCMEBASE    BASE UCM ENTRY LIST                  13500021
         USING RDCM,RDCMBASE       ESTABLISH RDCM BASE REG              13600021
         USING DCMDSECT,TDCMBASE   BASE TDCM REG                        13700021
         USING DCMACB,SACBPT       BASE SACB REG                        13800021
         EJECT                                                          13900021
         ST    RE,XAP             SAVE RETURN POINTER                   14000021
         MVI   XAU+N3,ZERO         ZERO MINOR FLAG BYTE                 14100021
         MVC   XAU+N4(N4),XAS      SAVE TARGET INFO                     14200021
*/*NXTSTUP: S (,ANLYZ) FINDUCME: GO FIND SOURCE UCME */                 14300021
         BAL   RB,FINDUCME         FIND SOURCE ENTRY UCME               14400021
*                                                                       14500021
*      ANALYZE COMMAND                                                  14600021
*                                                                       14700021
*/*ANLYZ: P (,%TST1) LOAD OP POINTER; SAVE CURSOR POSITION */           14800021
         L     KOPS,XAL            LOAD PT TO OPERANDS                  14900021
         LA    KOPS,N0(KOPS)       CLEAR HIGH ORDER BYTE                15000021
         ST    KOPS,XAS+N4         SAVE CURSOR POINTER                  15100021
*                                                                       15200021
*/*%TST1: D (YES,KAREFRTN,NO,%TST2) K A COMMAND */                      15300021
         CLC   N0(N2,KOPS),KA         IS IT K A                         15400021
         BE    KAREFRTN            YES-GO HANDLE AS K A,REF             15500021
*/*%TST2: D (YES,KAREFRTN,NO,%TST3) K A,REF COMMAND */                  15600021
         CLC   N0(N6,KOPS),KAREF      IS IT K A,REF                     15700021
         BE    KAREFRTN            YES-DITTO                            15800021
*/*%TST3: D (YES,KNONERTN,NO,BADKOP) K A,NONE COMMAND */                15900021
         CLC   N0(N7,KOPS),KANONE     IS IT K A,NONE                    16000000
         BE    KNONERTN            YES-                                 16100021
         LA    KOPS,N2(KOPS)       POINT TO BAD OPERAND                 16150000
         SPACE 2                                                        16200021
*/*BADKOP: P (,STOREOP) INDICATE BAD OPERAND ERROR IEE156I */           16300021
BADKOP   EQU   *                                                        16400021
         MVI   XAE,IEE156I      NONE OF ABOVE,SO ITS BAD                16500021
*/*STOREOP: P (,ERRORMSG) SAVE OP PT; MINOR ERROR MSG FLAGS */          16600021
STOREOP  EQU   *                                                        16700021
         ST    KOPS,XAS+N4         SAVE OPERAND POINTER                 16800021
         MVC   XAS+N4(N1),XAU+N3   MOVE MINOR MSG FLAGS                 16900021
*/*ERRORMSG: P (,XCTL1) RESTORE SVC 34 MSG. MOD. NAME */                17000021
ERRORMSG EQU   *                                                        17100021
         MVC   XAX(N8),IGC5603D     MOVE XSA SVC 34 MSG MOD. NAME       17200021
*/*XCTL1: P (,XCTL) RESTORE XSA POINTERS */                             17300021
XCTL1    EQU   *                                                        17400021
         L     RETURN,XAP          RESTORE RETURN REG ADDR              17500021
         LA    X5,XAX              RESTORE OPERAND                      17600021
         ST    X5,XAP                 POINTER                           17700021
         XC    XAD(N4),XAD         CLEAR DCB ADDR                       17800021
         MVC   XAS(N4),XAU+N4      RESTORE TARGET INFO.                 17900021
XCTL     EQU   *                                                        18000021
*/*XCTL: R RETURN TO IEE5603D */                                        18100021
         XCTL  SF=(E,(2))         ISSUE XCTL                            18200021
*                                                                       18300021
         EJECT                                                          18400021
*/*KAREFRTN: D (YES,GRAPHIC,NO,BUILDWTO) SOURCE A GRAPHIC CONSOLE */    18500021
KAREFRTN EQU   *                                                        18600021
         TM    UCMDISP,UCMDISPC    IS IT A GRAPHIC CONSOLE              18700021
*    IF NOT A GRAPHIC CONSOLE,ISSUE WTO FOR MESSAGE                     18800021
         BNO   BUILDWTO        GO BUILD MESSAGE                         18900021
GRAPHIC  EQU   *                                                        19000021
*/*GRAPHIC: P (,%SET1) LOAD POINTER TO SOURCE ENTRY AREA */             19100021
         L     R6,DCMAENTR         LOAD ADDR OF ENTRY AREA              19200021
         LH    R1,DCMLGNTH         LOAD LENGTH OF A LINE                19300021
*/*%SET1: S (,%SET2) CLEARIT: BLANK ENTRY AREA */                       19400021
         BAL   RB,CLEARIT          GO BLANK IT                          19500021
*/*%SET2: S (,%SET3) TAR: GET TARGET'S UCME */                          19600021
         BAL   RB,TAR          GO GET TARGET UCME                       19700021
*/*%SET3: P (,%SET4) RESTORE REG 1 AS ENTRY AREA POINTER */             19800021
         LR    R1,R6               RESTORE ENTRY AREA POINTER           19900021
*/*%SET4: S (,%SET5) MOVEIN: SET UP AREA LENGTHS IN MESSAGE */          20000021
         BAL   RE,MOVEIN         GO SET AREA LENGTHS INTO MSG           20100021
*/*%SET5: P (,ERRORMSG) INDICATE OPTIONS MSG; SAVE CURSOR POSITION */   20200021
         LA    R1,N4(R1)           BUMP POINTER                         20300021
         ST    R1,XAS+N4           SAVE CURSOR POSITION                 20400021
         MVI   XAE,OPTIONS   SET OPTIONS MSG BIT                        20500021
*                                                                       20600021
IOEXIT   EQU   *                                                        20700021
         B     ERRORMSG                                                 20800021
*/* E MOVEIN */                                                         20900021
*/*%MV1: P (,%MV2) SET BRANCH SWITCH REG 15 = 0. */                     21000021
MOVEIN   EQU   *                                                        21100021
         SR    RF,RF               CLEAR SWITCH REG                     21200021
*/*%MV2: P (,SACBLOOP) MOVE 'K A,' INTO MSG */                          21300021
         MVC   N0(N4,R6),KMSG        MOVE  MSG NO.  ID                  21400021
         LA    R6,N4(R6)           BUMP MSG POINTER PAST MSG NO.        21500021
SACBLOOP EQU   *                                                        21600021
*/*SACBLOOP: D (NO,NONERTN,YES,%MV3) ANY SACB AREAS DEFINED */          21700021
         LTR   SACBPT,SACBPT             ANY AREA'S DEFINED             21800021
         BZ    NONERTN           NO--                                   21900021
*/*%MV3: P (,NEXTSACB) INIT. SACB COUNTER TO ZERO */                    22000021
         SR    R3,R3             CLEAR REG                              22100021
NEXTSACB EQU   *                                                        22200021
*/*NEXTSACB: D (YES,%MV4,NO,NEXTBLK) AREA DEFINED HERE */               22300021
         TM    DCMASACB,DCMAUSE  AREA DEFINED HERE                      22400021
         BNO   NEXTBLK           NO--CHK NEXT SACB                      22500021
*/*%MV4: P (,AREA) INCREMENT SACB COUNTER BY 1 */                       22600021
         LA    R3,N1(R3)          BUMP COUNTER                          22700021
AREA     EQU   *                                                        22800021
*/*AREA: D (YES,LL,NO,%MV5) REG 15 SWITCH =0 FOR LENGTHS MSG */         22900021
         LTR   RF,RF               IS IT FOR AREA ID MSG                23000021
         BZ    LL                  NO--GO PUT IN LL                     23100021
*/*%MV5: P (,NEXTBLK) MOVE AREA ID INTO MSG; COMMA;BUMP MSG PT */       23200021
         MVC   N0(R6),DCMAID      YES,MOVE AREA ID INTO MESSAGE         23300021
         MVI   N1(R6),COMMA       MOVE IN COMMA AFTER AREA ID           23400021
         LA    R6,N2(R6)          BUMP MESSAGE POINTER                  23500021
         B     NEXTBLK                                                  23600021
*/*LL: P (,%MV6) LOAD AREA LENGTH FROM SACB */                          23700021
LL       EQU   *                                                        23800021
         SR    R4,R4               CLEAR REG                            23900021
         IC    R4,DCMALN+N1        LOAD LL                              24000021
*/*%MV6: S (,%MV7) EBCDIC: CONVERT AREA LENGTH TO EBCDIC */             24100021
         BAL   R5,EBCDIC           GO CONVERT TO EBCDIC                 24200021
*/*%MV7: P (,NEXTBLK) MOVE LL INTO MSG; COMMA; BUMP MSG PT */           24300021
         MVC   N0(N2,R6),XAS+N1    MOVE LL INTO MESSAGE                 24400021
         MVI   N2(R6),COMMA       MOVE IN COMMA AFTER AREA ID           24500021
         LA    R6,N3(R6)          BUMP MESSAGE POINTER                  24600021
*/*NEXTBLK: P (,%MV8) LOAD POINTER TO NEXT AREA BLOCK */                24700021
NEXTBLK  EQU   *                                                        24800021
         L     R7,N0(R7)          GET POINTER TO NEXT SACB              24900021
*/*%MV8: D (YES,NEXTSACB,NO,%MV9) VALID POINTER */                      25000021
         LTR   R7,R7              IS IT A VALID POINTER                 25100021
         BNZ   NEXTSACB           YES-KEEP ON LOOPING                   25200021
*/*%MV9: D (NO,NONERTN,YES,%MV10) ANY SACB'S DEFINED */                 25300021
         LTR   R3,R3               ANY SACBS                            25400021
         BZ    NONERTN             N0- GO SAY SO                        25500021
*/*%MV10: P (,FINIT) BLANK OUT LAST COMMA */                            25600021
         BCTR  R6,N0              YES-                                  25700021
         MVI   N0(R6),BLANK       MOVE A BLANK INTO LAST BYTE           25800021
         SPACE 2                                                        25900021
*/*FINIT: S (,%MV11) CONVERT: CONVERT CONSOLE ID TO EBCDIC */           26000021
FINIT    EQU   *                                                        26100021
         BAL   R5,CONVERT        GO CONVERT CC TO EBCDIC                26200021
*/*%MV11: R RETURN TO CALLER */                                         26300021
         BR    RE                                                       26400021
*/*NONERTN: P (,FINIT) MOVE 'NONE' WORD INTO MESSAGE */                 26500021
NONERTN  EQU   *                                                        26600021
         MVC   N0(N4,R6),KANONE+N2  MOVE IN WORD NONE                   26700021
         LA    R6,N4(R6)           BUMP MSG LENGTH                      26800021
         B     FINIT               GO MOP UP                            26900021
*                                                                       27000021
         EJECT                                                          27100021
BUILDWTO EQU   *                                                        27200021
*/*BUILDWTO: S (,%BLD2) TAR: GET TARGET CONSOLE'S UCME */               27300021
         BAL   RB,TAR          GO GET TARGET UCME                       27400021
*/*%BLD2: S (,%BLD3) GETMAIN: GET CORE FOR MESSAGE */                   27500021
         BAL   RB,GETMAIN          GET CORE FOR MSG                     27600021
*/*%BLD3: P (,%BLD4) MOVE MESSAGE NO. IEE929I INTO MSG */               27700021
         MVC   N4(N8,R6),IEE929I  MOVE MESSAGE NUMBER                   27800021
         LA    R6,NC(R6)       BUMP MSG PT PAST MSG NO.                 27900021
*/*%BLD4: S (,%BLD5) MOVEIN: PUT DATA INTO MSG */                       28000021
         BAL   RE,MOVEIN           GO PUT DATA INTO MSG                 28100021
*/*%BLD5: P (,WRTWTO) MOVE CONSOLE ID INTO MSG */                       28200021
         MVC   N0(N4,R6),CC        MOVE L=CC INTO MSG                   28300021
         MVC   N4(N2,R6),XAS+N1    STORE CC INTO L= PARAM.              28400021
         LA    R6,N6(R6)           BUMP MSG LENGTH                      28500021
*/*WRTWTO: P (,BRANCH14) SET UP AND ISSUE WTO FOR MESSAGE IEE929I */    28600021
WRTWTO   EQU   *                                                        28700021
         LR    R5,RF               SAVE SWITCH REG                      28800021
         MVC   N0(N4,R6),DESCR     MOVE DESCRIPTOR CODE                 28900021
         SR    R6,R1               GET LENGTH OF MSG                    29000021
         STH   R6,N0(R1)           STORE FOR WTO                        29100021
         MVI   N2(R1),MCSMASK      ID PASSED AND QUEUE BY ID            29300021
         MVI   N3(R1),N0           ZERO SECOND MSCFLGS BYTE             29350021
         LR    R3,R1               SAVE PARAMETER LIST ADDRESS          29400021
         SR    R0,R0               CLEAR REG                            29500021
         IC    R0,XAU              LOAD SOURCE DEVICE ID                29600021
         WTO   MF=(E,(1))                                               29700021
         LA    R0,N80              PASS LENGTH OF LIST                  29750021
         LR    R1,R3               PASS PARAMETER LIST ADDRESS          29752021
         BAL   RB,FREE             FREEMAIN WTO PARAMETER LIST          29760021
BRANCH14 EQU   *                                                        29800021
*/*BRANCH14: D (YES,%BR1,NO,SACBLP) IS REG 15 SWITCH POSITIVE */        29900021
         LTR   R5,R5               IS SWITCH ON                         30000021
         BZ    SACBLP              NO--                                 30100021
*/*%BR1: R RETURN VIA BR 14 */                                          30200021
         L     RETURN,XAP       RESTORE RETURN REG                      30300021
         BR    RETURN             GO BACK TO SYSTEM                     30400021
*/*SACBLP: S (,%LP1) TAR: GET TARGET'S UCME */                          30500021
SACBLP EQU   *                                                          30600021
         BAL   RB,TAR          GO GET TARGET UCME                       30700021
*/*%LP1: S (,%LP2) GETMAIN: GET CORE FOR WTO MSG */                     30800021
         BAL   RB,GETMAIN          GO GET CORE FOR MSG                  30900021
*/*%LP2: P (,%LP3) MOVE MSG ID IEE928I INTO MSG */                      31000021
         MVC   N4(L'IEE928I,R6),IEE928I      MOVE MSG INTO GETMAINED    31100021
         LA    R6,N49(R6)        BUMP MESSAGE POINTER                   31200000
*/*%LP3: P (,%LP4) SET REG 15 SWITCH = 11. */                           31300021
         LH    RF,ELEVEN           SET BR SWITCH                        31400021
*/*%LP4: S (,%LP5) SACBLOOP: PUT AREA ID'S INTO MESSAGE */              31500021
         BAL   RE,SACBLOOP         INIT PTS                             31600021
*/*%LP5: P (,WRTWTO) MOVE CONSOLE ID INTO MESSAGE */                    31700021
         MVC   N42(N2,R1),XAS+N1 MOVE CC INTO MESSAGE                   31800021
         B     WRTWTO              GO WRITE WTO                         31900021
         EJECT                                                          32000021
*/* E GETMAIN */                                                        32100021
GETMAIN  EQU   *                                                        32200021
*/*%GET1: P (,%GET2) LOAD LENGTH OF 80 BYTES */                         32300021
         LA    R0,N80             LOAD LENGTH OF CORE NEEDED            32400021
*/*%GET2: P (,%GET3) LAOD ADDR OF CORE WORD AND ISSUE GETMAIN */        32500021
         LA    R6,XAS             GET ADDR OF A WORD IN CORE            32600021
         GETMAIN EC,LV=(0),A=(6),SP=255                                 32700021
*/*%GET3: D (NO,MSG931,YES,%CLR1) WAS RETURN CODE GOOD */               32800021
         LTR   RF,RF              TEST RETURN CODE                      32900021
         BNZ   MSG931             ERROR IF NOT ZERO;MEANS NO CORE       33000021
         L     R6,XAS              LOAD GETMAINED ADDR                  33100021
         LA    R1,N80                                                   33200021
*/* E CLEARIT */                                                        33300021
CLEARIT  EQU   *                                                        33400021
*/*%CLR1: P (,%CLR2) BLANK AREA: AREA PT =6, COUNT IN 1 */              33500021
         MVI   N0(R6),BLANK        CLEAR AREA                           33600021
         BCTR  R1,N0                                                    33700021
         BCTR  R1,N0               DECREMENT BY 2                       33800021
         EX    R1,BLANKS                                                33900021
         LR    R1,R6               SET MSG POINTER                      34000021
*/*%CLR2: R RETURN TO CALLER */                                         34100021
         BR    RB                  RETURN                               34200021
         SPACE 2                                                        34300021
*/*MSG931: P (,ERRORMSG) INDICATE CORE NOT AVAILABLE ERROR MSG IEE931I  34400021
*/**/                                                                   34500021
MSG931   EQU   *                                                        34600021
         MVI   XAE,IEE931I      CORE NOT AVAILABLE                      34700021
         B     ERRORMSG            GO TO PUT OUT MSG                    34800021
*/*ERROR: P (,ERROR2) INDICATE IN OR ABOVE AREA ERROR MSG */            34900021
ERROR    EQU   *                                                        35000021
         MVI   XAU+N3,IEE924I      DISPLAY IN OR ABOVE AREA             35100021
*/*ERROR2: P (,STOREOP) INDICATE ERROR MESSAGE IEE924I */               35200021
ERROR2   EQU   *                                                        35300021
         MVI   XAE,IEE924          SET ON MAJOR FLAG BIT                35400021
         B     STOREOP                                                  35500021
         EJECT                                                          35600021
*/*KNONERTN: S (,%NONE1) TAR: GET TARGET'S UCME */                      35700021
KNONERTN EQU   *                                                        35800021
         BAL   RB,TAR              GO GET TARGET CONSOLE'S UCME         35900021
*/*%NONE1: D (YES,USEDSACB,NO,SACBLP) ANY AREAS DEFINED */              36000021
         LTR   SACBPT,SACBPT       VALID ADDR IN REG                    36100021
         BZ    SACBLP              NO- NO SACBS DEFINED                 36200021
*     THIS CODE WILL FREEMAIN ANY GETMAINED SACB'S AND REINITIALIZE     36300021
*    PERMANENT SACB'S AND TURN OFF DCMAUSE BIT IN SACB'S                36400021
*/*USEDSACB: D (YES,ERROR,NO,%NONE2) DISPLAY ON SCREEN */               36500000
USEDSACB EQU   *                                                        36600021
         CLI   DCMTOPDS,ZERO       IS THERE A DISPLAY                   36700000
         BNE   ERROR            YES- IT'S AN ERROR                      36800000
*    NOTE CANNOT CHANGE STATUS TILL CHECK IS COMPLETE                   37300021
*/*%NONE2: P (,RESTART) RESET POINTER FOR SACB */                       37400000
         LA    R5,DCMADSDS         PRIME CHAIN BACKWARD POINTER         37600021
         SR    RF,RF               CLEAR REG                            37700021
*/*RESTART: D (YES,FREEMAIN,NO,%NONE4) IS THIS A GETMAINED SACB */      37800021
RESTART  EQU   *                                                        37900021
         TM    DCMASACB,DCMAGM IS IT A GETMAINED SACB                   38000021
         BO    FREEMAIN            YES-                                 38100021
*/*%NONE4: P (,RESTART2) REINITIALIZE SACB */                           38200021
         XC    DCMAROW(NIX),DCMAROW ZERO OUT SACB                       38300021
         NI    DCMASACB,N255-DCMAUSE TURN OFF IN-USE BIT                38400021
         XC    DCMALN(N2),DCMALN   ZERO OUT LENGTH FIELD OF SACB        38500021
         LR    R5,SACBPT           SAVE PREVIOUS BLOCK ADDR             38600021
*/*RESTART2: P (,%NONE5) LOAD POINTER TO NEXT SACB */                   38700021
RESTART2 EQU   *                                                        38800021
         L     SACBPT,N0(SACBPT) LOAD NEXT SACB POINTER                 38900021
*/*%NONE5: D (YES,RESTART,NO,%NONE6) VALID POINTER */                   39000021
         LTR   SACBPT,SACBPT       VALID ADDR                           39100021
         BNZ   RESTART             YES-CONTINUE LOOP                    39200021
         XC    DCMTOPAR(N2),DCMTOPAR ZERO OUT TOP AREA & TOP DISP. ID'S 39250000
*/*%NONE6: D (YES,SACBLP,NO,%NONE7) ANY PERMANENT SACBS */              39300021
         LA    SACBPT,DCMADSDS     LOAD ADDR OF CHAIN START             39400021
         CR    R5,SACBPT           ARE THERE PERMANENT SACBS            39500021
         BNE   SACBLP              YES-                                 39600021
*/*%NONE7: P (,SACBLP) ZERO OUT RDCM SACB POINTER */                    39700021
         XC    DCMADSDS(N4),DCMADSDS ZERO OUT START ADDR                39800021
         B     SACBLP              GO TELL STATUS                       39900021
         SPACE 2                                                        40000021
*/*FREEMAIN: P (,%FREE1) MOVE PT TO NXT BLOCK INTO PREVIOUS BLOCK */    40100021
FREEMAIN EQU   *                                                        40200021
         MVC   N0(N4,R5),N0(SACBPT) MOVE PT TO NXT BLK INTO PREV BLK    40300021
*/*%FREE1: P (,RESTART2) RESET SACB PT; ISSUE FREEMAIN */               40400021
         LR    R1,SACBPT           ADDR OF AREA TO FREE UP              40500021
         LR    SACBPT,R5           RESET SACB POINTER                   40600021
         LA    R0,DCMACBSZ         PASS SACB LENGTH                     40700021
         BAL   RB,FREE             FREEMAIN ONE SACB                    40750021
         B     RESTART2            LOOP                                 40800021
*                                                                       40900021
         SPACE 3                                                        41000021
*/* E CONVERT */                                                        41100021
CONVERT  EQU   *                                                        41200021
*/*%CON1: P (,EBCDIC) LOAD SOURCE CONSOLE ID */                         41300021
         SR    X4,X4               CLEAR REG                            41400021
         IC    X4,XAU+N4             GET CONSOLE ID                     41500021
*    THIS CODE WILL CONVERT HEX  TO EBCDIC                              41600021
*/*EBCDIC: P (,%CON2) CONVERT HEX NUMBER TO EBCDIC */                   41700021
EBCDIC   EQU   *                                                        41800021
         CVD   X4,XAS         CONVERT TO DECIMAL                        41900021
         UNPK  XAS(N3),XAS+N6(N2) UNPACK NUMBER                         42000021
         OI    XAS+N2,CF0    FIX SIGN                                   42100021
*/*%CON2: R RETURN TO CALLER */                                         42200021
         BR    R5                                                       42300021
*                                                                       42400021
         SPACE 3                                                        42450021
FREE     EQU   *                                                        42460021
* THIS ROUTINE IS ENTERED WITH THE FOLLOWING PARAMETERS                 42470021
*   R0 -- LENGTH OF AREA TO BE FREED                                    42480021
*   R1 -- POINTER TO AREA TO BE FREED                                   42490021
*   RB -- LINK REGISTER                                                 42492021
         O     R0,SP255            PUT SQA SUBPOOL IN HIGH              42494021
*                                       ORDER BYTE OF REG 0             42496021
         FREEMAIN R,LV=(0),A=(1)                                        42498021
         BR    RB                  RETURN TO CALLER                     42498421
         EJECT                                                          42500021
*    INPUT- REG 1 HAD CONSOLE ID RIGHT JUSTIFIED, HIGH ORDER BYTES ZERO 42600021
*    OUTPUT- POINTER TO DCMENTRY SPECIFIED BY CONSOLE ID IN UCMEBASE    42700021
*    REG USAGE-DESTROYS CONTENTS OF: REG 0,1,UCMEBASE                   42800021
*/*E FINDUCME */                                                        42900021
FINDUCME EQU   *                                                        43000021
*/*%FND1: P (,FINDTAR) GET SOURCE CONSOLE ID */                         43100021
         SR    R1,R1               CLEAR REG                            43200021
         IC    R1,XAU              LOAD SOURCE ID                       43300021
*/*FINDTAR: P (,DCMINIT) FIND UCME FOR CONSOLE'S ID */                  43400021
FINDTAR  EQU   *                                                        43500021
         SR    R0,R0               CLEAR REG                            43600021
         L     UCMEBASE,UCMVEA     POINT TO FIRST ENTRY                 43700021
         BCTR  R1,ZERO             SUBTRACT ONE FROM CONSOLE ID         43800021
         M     R0,UCMVEZ           MULTIPLY ENTRY SIZE BY REDUCED ID    43900021
         AR    UCMEBASE,R1         POINT TO DESIRED UCM ENTRY           44000021
DCMINIT  EQU   *                                                        44100021
*/*DCMINIT: P (,%FND2) LOAD RDCM,TDCM, SACB PT'S */                     44200021
         L     RDCMBASE,UCMXB           LOAD PT TO RDCM                 44300021
         L     SACBPT,DCMADSDS         LOAD SACB POINTER FROM RDCM      44400021
         L     TDCMBASE,N0(RDCMBASE)   LOAD PT TO TDCM                  44500021
*/*%FND2: R RETURN TO CALLER */                                         44600021
         BR    RB                  RETURN                               44700021
*/* E TAR */                                                            44800021
TAR      EQU   *                                                        44900021
         ST    RB,XAV+N4           SAVE POINTER                         45000021
         SR    R1,R1               CLEAR REG                            45100021
         IC    R1,XAU+N4           LOAD TARGET CC                       45200021
*/*%TR1: S (,%TR2) FINDUCME: GO FIND UCME */                            45300021
         BAL   RB,FINDTAR          GO DO THING                          45400021
*/*%TR2: D (NO,IEE925,YES,%TR3) IS TARGET A CRT */                      45500021
         TM    UCMDISP,UCMDISPC    IS IT A GRAPHIC CRT                  45600021
         BNO   IEE925              NOT A CRT-ERROR                      45700021
*/*%TR3: R RETURN TO CALLER */                                          45800021
         L     RB,XAV+N4           RESTORE RETURN REG                   45900021
         BR    RB                                                       46000021
*/*IEE925: P (,ERRORMSG) INDICATE NOT A CRT ERROR MSG IEE925I */        46100021
IEE925   EQU   *                                                        46200021
         OI    XAE,IEE925I         INDICATE NOT A CRT                   46300021
         OI    XAU+N3,IEE26        INDICATE DITTO FOR MINOR FLAG        46400021
         B     ERRORMSG                                                 46500021
         EJECT                                                          46600021
BLANKS   MVC   N1(N0,R6),N0(R6)    WITH BLANKS                          46700021
*                                                                       46800021
*    CONSTANTS                                                          46900021
         DS    0F                                                       46950021
SP255    DC    X'FF000000'         SQA SUBPOOL                          46960021
ELEVEN   DC    H'11'                                                    47000021
IEE928I  DC    CL45'IEE928I DISPLAY AREA ID''S FOR CONSOLE CC ARE'      47100021
IEE929I  DC    C'IEE929I '                                              47200021
IGC5603D DC    C'IGC5603D'                                              47300021
DESCR    DC    B'00001000000000000000000000000000' DESCRIPTOR CODE+RT   47400021
KMSG     DC    C'K A,'                                                  47500021
CC       DC    C' ,L=  '                                                47600021
KANONE   DC    C'A,NONE '                                               47700021
KA       DC    C'A '                                                    47800021
KAREF    DC    C'A,REF '                                                47900021
PATCH1   DC    C'***PATCH AREA***'                                      48000000
PATCH2   DC    C'IEE6903D-TEST'                                         48100000
PATCH3   DC    36C' '                                                   48150000
*********************************************************************** 48200021
         EJECT                                                          48300021
*                                                                       48400021
*    ALL DSECTS FOLLOW THIS POINT                                       48500021
*                                                                       48600021
DCMDSECT DSECT                                                          48700021
         IEECBJH CODE=DI                                                48800021
         EJECT                                                          48900021
PMUCM    DSECT                                                          49000021
         IEECUCM                                                        49100021
RDCM     DSECT                                                          49200021
         IEECRDCM DSECT=YES                                             49300021
NIX      EQU   DCMACBND-DCMAROW    LENGTH OF SACB TO BE REINIT.         49400021
FAUXSA   DSECT                                                          49500021
         IEEXSA                                                         49600021
CVTSECT  DSECT                                                          49700021
         CVT                                                            49800021
*/*IEE6903D: END */                                                     49900021
*********************************************************************** 50000021
         END                                                            50100021
