         TITLE 'IEE7503D -- ROUTING LOCATION MODULE'                    00100021
IEE7503D CSECT                                                          00200021
* A 112300-112600                                               SA68512 00250021
*/*IEE7503D: CHART */                                                   00300021
*/*%START: E (,BEGIN) IEE7503D */                                       00400021
         SPACE 2                                                        00500021
* THIS ROUTINE WAS CREATED FOR STATUS DISPLAY SUPPORT, LINE ITEM 21002, 00600021
*    OS RELEASE 21                                                      00700021
         EJECT                                                          00800021
*                                                                       00900021
* STATUS  CHANGE LEVEL 0                                                01000021
*                                                                       01100021
* FUNCTION HANDLES LOCATION (L=CCA) OPERAND AND DEFAULTS                01200021
*    1) LOOKS FOR L OPERAND ON K, PM, D, MN COMMANDS AND REMOVES        01300021
*    IT, IF PRESENT                                                     01400021
*    2) PROVIDES ROUTING DEFAULTS FROM THE ROUTING CONTROL              01500021
*    TABLE (RCT)                                                        01600021
*                                                                       01700021
* ENTRY POINTS IEE7503D                                                 01800021
*                                                                       01900021
* INPUT   REGISTER 2 - POINTER TO THE XSA WHICH POINTS TO               02000021
*    THE COMMAND                                                        02100021
*                                                                       02200021
* OUTPUT  TARGET CONSOLE ID, AREA ID, AND FLAGS IN THE XAS              02300021
*    FIELD OF THE XSA                                                   02400021
*                                                                       02500021
* EXTERNAL REFERENCES NONE                                              02600021
*                                                                       02700021
* EXITS,NORMAL                                                          02800021
*    IEE6703D FOR K VIA XCTL                                            02900021
*    IEE7603D FOR D, MN, PM VIA XCTL                                    03000021
*                                                                       03100021
* EXITS,ERROR                                                           03200021
*    IEE5603D FOR ERROR MESSAGES, VIA XCTL                              03300021
*    IEE0503D FOR TSO ERROR MESSAGE, VIA XCTL                           03350021
*                                                                       03400021
* TABLES/WORK AREAS                                                     03500021
*    XSA                                                                03600021
*    ROUTING CONTROL TABLE - RCT                                        03700021
*    UCM                                                                03800021
*    RESIDENT DCM (INCLUDING SCREEN AREA CONTROL BLOCKS-SACB'S)         03900021
*    MASTER SCHEDULER RESIDENT AREA - BASEA                             04000021
*                                                                       04100021
* ATTRIBUTES REENTRANT, REFRESHABLE, PRIVILEGED, TYPE 4 SVC             04200021
*                                                                       04300021
* NOTES                                                                 04310021
*    FOR TSO                                                            04350021
*         THIS MODULE SHOULD RECEIVE ONLY DISPLAY, MONITOR A, AND       04360021
*    PM A COMMANDS FROM A TSO TERMINAL UNDER OPERATOR, AND              04370021
*    WILL HANDLE THEM AS FOLLOWS:                                       04380021
*    1) ANY COMMAND WITH AN L OPERAND IS REJECTED - 7503D XCTL'S        04390021
*    TO 0503D TO PUT OUT AN ERROR MESSAGE TO THE TERMINAL               04392021
*    2) ANY MONITOR COMMAND IS CHANGED TO A DISPLAY COMMAND             04394021
*    BY 7603D, AND THEN PASSED TO 0803D.                                04396021
*    3) ANY DISPLAY COMMAND IS PASSED TO 0803D BY 7603D                 04398021
*    4) ANY STOPMN COMMAND IS REJECTED - 7603D XCTL'S TO 0503D          04398421
*    5) ANY OTHER COMMAND IS REJECTED - 7603D XCTL'S TO 0503D           04398821
*                                                                       04399221
*    FOR NON-MCS                                                        04399621
*    1) ANY COMMAND WITH AN L OPERAND IS REJECTED - 7503D XCTL'S        04400021
*    TO 0503D TO PUT OUT AN ERROR MESSAGE                               04450021
*    2) ANY CONTROL COMMAND, 7503D XCTL'S TO 6703D                      04460021
*    3) ANY D COMMAND IS PASSED TO 0803D BY 7603D                       04470021
*    4) ANY MN COMMAND IS CHANGED BY 7603D TO D AND PASSED TO 0803D     04480021
*    5) ANY STOPMN COMMAND IS REJECTED - 7603D XCTL'S TO 0503D          04490021
*    6) ANY OTHER COMMAND IS REJECTED - 7603D XCTL'S TO 0503D           04492021
         EJECT                                                          04500021
* REGISTER USAGE                                                        04600021
*        THE REGISTERS WITH AN * ARE RESERVED FOR THE USE               04700021
* INDICATED THROUGHOUT THE MODULE.  THE OTHERS HOLD THE VALUE           04800021
* INDICATED ONLY TEMPORARILY.                                           04900021
REG0     EQU   0                   USED WITH REG1 AS                    05000021
*                                       EVEN/ODD PAIR                   05100021
REG1     EQU   1                   PARAMETER REGISTER FOR INTERNAL      05200021
*                                       SUBROUTINES - USED WITH         05300021
*                                       REG0 AS EVEN/ODD PAIR           05400021
XSABASE  EQU   2                 * BASE REGISTER FOR XSA                05500021
UCMBASE  EQU   3                 * BASE REGISTER FOR UCM                05600021
PARAMPTR EQU   4                   POINTER TO SVC 34 PARAMETER LIST     05700021
INCR     EQU   4                   INCREMENT REG FOR BX (REG 5 IS       05800021
*                                       USED FOR COMPARAND)             05900021
WORKR    EQU   4                   WORK REG, PART OF EVEN/ODD PAIR      06000021
WORK1    EQU   5                   WORK REG, PART OF EVEN/ODD PAIR      06100021
END      EQU   5                   POINTER TO LAST CHARACTER OF         06200021
*                                       COMMAND                         06300021
SOURCEID EQU   5                   SOURCE CONSOLE ID                    06400021
AREA     EQU   6                 * TARGET AREA ID                       06500021
CONSID   EQU   7                 * TARGET CONSOLE ID                    06600021
OPPTR    EQU   8                   POINTS WITHIN OPERAND FIELD OF       06700021
*                                       COMMAND ENTERED                 06800021
RCTSCAN  EQU   9                   WORK REG FOR RCT SCAN                06900021
RDCMBASE EQU   10                * BASE REGISTER FOR RESIDENT DCM       07000021
RCTBASE  EQU   11                * ROUTING CONTROL TABLE BASE           07100021
*                                       (FIRST PART OF MODULE)          07200021
SACBBASE EQU   11                * SCREEN AREA CONTROL BLOCK BASE       07300021
*                                       (SECOND PART OF MODULE)         07400021
UCMEBASE EQU   12                * BASE REGISTER FOR UCM ENTRY          07500021
*                                       (FIRST SOURCE, THEN TARGET)     07600021
MYBASE   EQU   13                * BASE REGISTER FOR THIS ROUTINE       07700021
RETURNR  EQU   14                * RETURN REGISTER                      07800021
WORK2    EQU   15                  WORK REG                             07900021
LINKR    EQU   15                  LINK REGISTER                        08000021
         EJECT                                                          08100021
* ESTABLISH ADDRESSABILITY                                              08200021
         SPACE 2                                                        08300021
         BALR  MYBASE,0                                                 08400021
         USING *,MYBASE            BASE THIS MODULE                     08500021
BEGIN    EQU   *                                                        08800021
*/*BEGIN: P (,LOOKL) ESTABLISH ADDRESSABILITY */                        08900021
         USING DXSA,XSABASE        BASE XSA (POINTER RECEIVED AS        09000021
*                                       INPUT IN REG)                   09100021
         L     WORKR,PTRCVT        GET CVT POINTER                      09200021
         USING DCVT,WORKR          BASE CVT                             09300021
         L     UCMBASE,CVTCUCB     GET UCM POINTER                      09400021
         USING DUCM,UCMBASE        BASE UCM                             09500021
         USING UCMLIST,UCMEBASE    BASE UCM ENTRY                       09600021
         USING DRDCM,RDCMBASE      BASE RESIDENT DCM                    09700021
         USING DRCT,RCTBASE        BASE ROUTING CONTROL TABLE           09800021
         SPACE 3                                                        09900021
* INITIALIZATION                                                        10000021
         CLI   XAN,D               IS COMMAND DISPLAY                   10100021
         BE    LOOKL               YES, BRANCH AROUND ZEROING           10200021
*                                       XAS -- IEE3503D HAS             10300021
*                                       ALREADY ZEROED OUT XAS          10400021
*                                       AND MAY HAVE SET XASSDS3        10500021
         XC    XAS(DBLWORD),XAS    ZERO OUT XAS                         10600021
         EJECT                                                          10700021
* LOOK FOR L OPERAND ON COMMAND                                         10800021
LOOKL    EQU   *                                                        10900021
*/*LOOKL: D (YES,LFOUND,NO,NOL) L OPERAND PRESENT */                    11000021
         L     OPPTR,XAL           GET OPERAND POINTER FROM XSA         11100021
         LA    OPPTR,E0(OPPTR)     CLEAR HIGH ORDER BYTE                11200021
         LTR   OPPTR,OPPTR         IS THERE A PARAMETER LIST    SA68512 11230021
         BZ    ERR04               BRANCH NO, TO ERROR          SA68512 11260021
         L     PARAMPTR,XAR        GET PARAMETER LIST POINTER           11300021
         LA    PARAMPTR,E0(PARAMPTR)  CLEAR HIGH ORDER BYTE             11400021
*                                  COMPUTE END OF PARAMETER LIST        11500021
         LR    END,PARAMPTR        BEGINNING OF PARAMETER LIST          11600021
         AH    END,E0(PARAMPTR)    ADD LENGTH OF PARAMETER LIST         11700021
         BCTR  END,0               SUBTRACT ONE TO PT TO LAST CHAR      11800021
         LH    INCR,C1             INCREMENT IS ONE                     11900021
EQCOMP   EQU   *                                                        12000021
         CLI   0(OPPTR),EQUAL      SEARCH FOR = SIGN                    12100021
         BE    EQFOUND             IF = FOUND, BRANCH                   12200021
         CLI   0(OPPTR),BLANK      IS CHAR BLANK                        12300021
         BE    NOL                 BRANCH IF YES, END OF OPERAND        12400021
*                                       FIELD                           12500021
NEXTCHAR EQU   *                                                        12600021
         BXLE  OPPTR,INCR,EQCOMP   CHECK NEXT CHAR OF OPERAND           12700021
*                                       (END IS COMPARAND)              12800021
         B     NOL                 BRANCH IF NO L IS FOUND              12900021
EQFOUND  EQU   *                                                        13000021
         SH    OPPTR,C2            LOOK AT CHARACTERS BEFORE =          13100021
         CLC   0(L'COMMAL,OPPTR),COMMAL LOOK FOR ,L BEFORE =            13200021
         BE    LFOUND              BRANCH IF L OPERAND FOUND            13300021
         AH    OPPTR,C2            RESET OPERAND POINTER                13400021
         B     NEXTCHAR            BRANCH TO CONTINUE SEARCH            13500021
         EJECT                                                          13600021
LFOUND   EQU   *                                                        13700021
*/*LFOUND: D (YES,%TSTCC,NO,ERRL) IS CONSOLE ALLOWED TO ROUTE */        13750021
         CLC   XAJ(E2),C0          IS COMMAND FROM A TSO TERMINAL       13850021
         BNE   ERRL                YES, BRANCH TO ERROR ROUTINE -      X13860021
                                        NO L OPERAND ALLOWED            13870021
         CLI   XAU,E0              IS CONSOLE ID ZERO (NON-MCS)         13872021
         BE    ERRL                YES, L OPERAND INVALID               13874021
*/*%TSTCC: D (YES,CHECKCC,NO,CCNTSPEC) CC SPECIFIED */                  13880021
         OI    XASSDS,XASSDS2      INDICATE L OPERAND SPECIFIED         13900021
         ST    OPPTR,XASTSAVE      SAVE POINTER TO COMMA BEFORE L       14000021
         AH    OPPTR,C3            POINT TO FIRST CHAR OF ID            14100021
         TM    E0(OPPTR),F0        IS FIRST CHARACTER A NUMBER         X14150021
                                       (FIRST FOR BITS F)               14200021
         BNO   CCNTSPEC            BRANCH IF NOT A NUMBER               14250021
         TM    SECCHAR(OPPTR),F0   IS SECOND CHARACTER A NUMBER         14300021
         BO    TWODIGIT            BRANCH IF TWO-DIGIT NUMBER           14350021
ONEDIGIT EQU   *                                                        15200021
         PACK  XAP(DBLWORD),E0(E1,OPPTR)  PACK THE CONSOLE ID           15300021
         AH    OPPTR,C1            POINT OPPTR TO FIRST CHAR            15400021
*                                       AFTER CONSOLE ID                15500021
         B     CHECKCC             BRANCH TO CHECKCC                    15600021
TWODIGIT EQU   *                                                        15700021
         PACK  XAP(DBLWORD),E0(E2,OPPTR)  PACK THE CONSOLE ID           15800021
         AH    OPPTR,C2            POINT OPPTR TO FIRST CHAR            15900021
*                                       AFTER CONSOLE ID                16000021
CHECKCC  EQU   *                                                        16100021
*/*CHECKCC: P (,%CHKCC) STORE CONSOLE ID IN XSA */                      16200021
*/*%CHKCC: D (YES,TESTA,NO,ERREXIT) CC A CONSOLE */                     16300021
         CVB   CONSID,XAP          CONVERT THE CONSOLE ID TO            16400021
*                                       BINARY                          16500021
         STC   CONSID,XASCID       STORE CONSOLE ID IN XSA              16600021
         L     UCMEBASE,UCMVEL     BASE LAST UCMENTRY                   16700021
         SR    WORKR,WORKR         CLEAR WORK REG                       16800021
         IC    WORKR,UCMID         GET HIGHEST VALID CONSOLE ID         16900021
         CLR   CONSID,WORKR        IS ID FROM COMMAND HIGHER            17000021
         BH    ERR1219             YES, BRANCH TO ERROR ROUTINE         17100021
TESTA    EQU   *                   CHECK IF AREA ID IS SPECIFIED        17200021
*                                  AT THIS POINT OPPTR POINTS TO        17300021
*                                       THE FIRST CHAR AFTER THE        17400021
*                                       CONSOLE ID                      17500021
*/*TESTA: D (YES,STOREA,NO,NOA) IS A SPECIFIED */                       17600021
         CLI   0(OPPTR),BLANK      IS POINTER AT END OF COMMAND         17700021
         BE    NOA                 YES, BRANCH. NO A IS SPECIFIED       17800021
         CLI   0(OPPTR),COMMA      IS POINTER AT END OF OPERAND         17900021
         BNE   STOREA              NO , BRANCH. A IS SPECIFIED          18000021
         SPACE                                                          18100021
NOA      EQU   *                   NO A IS SPECIFIED                    18200021
*/*NOA: P (,REMOVEL) PUT NULL AREA IN XSA */                            18300021
         MVI   XASDID,NULL         INDICATE IN XSA THAT NO AREA         18400021
*                                       IS SPECIFIED                    18500021
         B     REMOVEL             BRANCH TO REMOVE L                   18600021
         SPACE 2                                                        18700021
STOREA   EQU   *                   IT IS ASSUMED THAT THE FIRST         18800021
*                                       CHAR AFTER THE CONSOLE ID       18900021
*                                       (OR AFTER THE = IF CC IS        19000021
*                                       NOT SPECIFIED) IS THE           19100021
*                                       AREA ID. IF THE ID IS NOT       19200021
*                                       VALID IT WILL BE FOUND          19300021
*                                       OUT WHEN LOOKING FOR AN         19400021
*                                       SACB TO MATCH IT.               19500021
*/*STOREA: P (,%MORE) PUT A FROM L OPERAND IN XSA */                    19600021
         MVC   XASDID(L'DCMAID),E0(OPPTR)  MOVE AREA ID INTO XSA        19700021
*/*%MORE: D (YES,ERREXIT,NO,REMOVEL) MORE THAN ONE CHARACTER IN AREA */ 19800021
         LA    OPPTR,E1(OPPTR)     POINT TO CHAR AFTER AREA ID          19900021
         CLI   0(OPPTR),BLANK      IS POINTER AT END OF COMMAND         20000021
         BE    REMOVEL             YES, BRANCH TO REMOVE L              20100021
         CLI   0(OPPTR),COMMA      IS POINTER AT END OF OPERAND         20200021
         BE    REMOVEL             YES, BRANCH TO REMOVE L              20300021
LONGA    EQU   *                   AREA ID IS TOO LONG                  20400021
         L     WORKR,XASTSAVE      GET POINTER TO COMMA BEFORE L        20500021
         LA    WORKR,E1(WORKR)     ADD ONE TO POINT TO L                20600021
         ST    WORKR,XASTSAVE      STORE POINTER TO L                   20700021
         B     ERR04                    BRANCH TO ERROR ROUTINE         20800021
         EJECT                                                          20900021
REMOVEL  EQU   *                   L OPERAND IS REMOVED FROM            21000021
*                                       COMMAND SO THAT OTHER           21100021
*                                       COMMAND HANDLERS WILL NOT       21200021
*                                       SEE IT                          21300021
*                                  AT ENTRY HERE OPPTR POINTS TO        21400021
*                                       THE BLANK OR COMMA WHICH        21500021
*                                       DELIMITS THE L OPERAND.         21600021
*                                       A POINTER TO THE COMMA          21700021
*                                       BEFORE THE L IS SAVED IN        21800021
*                                       XASTSAVE                        21900021
*/*REMOVEL: P (,VALIDITY) REMOVE L OPERAND FROM COMMAND */              22000021
         LR    WORKR,OPPTR         COMPUTE LENGTH OF L OPERAND          22100021
         S     WORKR,XASTSAVE           RESULT IN WORK REG              22200021
         SH    WORKR,C2            SUBTRACT 2 FROM LENGTH FOR           22300021
*                                       PROPAGATE AND EXECUTE           22400021
         CLI   0(OPPTR),BLANK      IS POINTER AT END OF COMMAND         22500021
         BNE   REMOVELC            NO, BRANCH TO MOVE REST              22800021
*                                       OF COMMAND FIELD OVER           22900021
REMOVELB EQU   *                   L OPERAND IS AT END OF COMMAND       23000021
*                                       SO JUST BLANK IT OUT            23100021
         L     WORK1,XASTSAVE      GET ADDRESS OF COMMA BEFORE L        23200021
         MVI   0(WORK1),BLANK      BLANK FIRST BYTE, THEN               23300021
         EX    WORKR,BLANKOUT           PROPAGATE THROUGH REST          23400021
*                                       OF OPERAND                      23500021
         B     VALIDITY            BRANCH TO CHECK CONSOLE AND          23600021
*                                       AREA                            23700021
         SPACE                                                          23800021
REMOVELC EQU   *                   L OPERAND IS NOT LAST OPERAND.       23900021
*                                       REMOVE IT, MOVE THE             24000021
*                                       REST OF THE COMMAND OVER,       24100021
*                                       AND BLANK WHERE COMMAND         24200021
*                                       WAS MOVED FROM                  24300021
         LR    WORK2,END           GET ADDRESS OF LAST CHAR OF          24400021
*                                       COMMAND (STILL CONTAINED        24500021
*                                       IN REG END)                     24600021
         SR    WORK2,OPPTR         CALCULATE LENGTH OF OPERAND          24700021
*                                       FIELD AFTER L OPERAND           24800021
*                                       (MINUS ONE FOR EXECUTE)         24900021
         L     WORK1,XASTSAVE      GET ADDRESS OF COMMA BEFORE L        25000021
         EX    WORK2,MOVEOP        PUSH REST OF OPERANDS OVER           25100021
         LA    WORK1,E1(WORK1)     CALCULATE ADDRESS OF FIELD TO        25200021
         AR    WORK1,WORK2              BE BLANKED                      25300021
*                                  (WORKR STILL CONTAINS ADJUSTED       25400021
*                                       LENGTH OF L OPERAND)            25500021
         MVI   E0(WORK1),BLANK     BLANK FIRST BYTE THEN                25600021
*        EX    WORKR,BLANKOUT           PROPAGATE THROUGH REST          25700021
*                                       OF FIELD                        25800021
         B     VALIDITY            BRANCH TO CHECK CONSOLE AND          25900021
*                                       AREA                            26000021
         SPACE                                                          26100021
MOVEOP   MVC   E0(E0,WORK1),E0(OPPTR)  PUSH REST OF OPERANDS OVER       26200021
BLANKOUT MVC   E1(E0,WORK1),E0(WORK1) BLANK OUT FIELD POINTED TO        26300021
*                                       BY WORK1                        26400021
         EJECT                                                          26500021
NOL      EQU   *                   NO L OPERAND WAS FOUND               26600021
*/*NOL: D (YES,RLM2EXIT,NO,CCNTSPEC) IS COMMAND FROM A TSO TERMINAL */  26610021
         CLC   XAJ(E2),C0          IS COMMAND FROM TSO TERMINAL         26650021
         BNZ   RLM2EXIT            YES, EXIT TO LOAD 2                  26660021
CCNTSPEC EQU   *                   CONSOLE ID NOT SPECIFIED             26670021
         SR    REG1,REG1           CLEAR PARAMETER REG                  26900021
         IC    REG1,XAU            GET SOURCE CONSOLE ID                27000021
*/*%NONMCS: D (YES,CHKCMND,NO,CCNTSPEC) IS SYSTEM NON-MCS */            27050021
         LTR   REG1,REG1           IS CONSOLE ID ZERO (NON-MCS)         27060021
         BZ    CHKCMND             YES, BRANCH                          27062021
*/*CCNTSPEC: P (,TESTENT) GET DEFAULT FROM RCT */                       27070021
         BAL   LINKR,FINDUCME      BASE SOURCE UCM ENTRY                27100021
         L     RCTBASE,UCMRCT      GET RCT POINTER                      27200021
STRIP    LA    RCTBASE,E0(RCTBASE) STRIP HIGH ORDER BYTE                27300021
         LTR   RCTBASE,RCTBASE     IS AN RCT PRESENT                    27400021
         BZ    NOCOMP               NO, USE DEFAULTS                    27500021
ACTEST   TM    RCTCODE,ACFLAG      IS ENTRY ACTIVE                      27600021
         BO    CONCOMP              YES, GO TO COMPARE                  27700021
TESTLAST TM    RCTCODE,ENDFLAG      NO, IS IT LAST ENTRY                27800021
         BO    NEWAREA             NO, LOAD NEXT POINTER                27900021
         BM    NOCOMP              YES, END SEARCH                      28000021
*                                  COMPARE NOT FOUND                    28100021
         LA    RCTBASE,RCTENT2     POINT TO NEXT ENTRY                  28200021
         B     ACTEST              GO TO TEST IT                        28300021
NEWAREA  L     RCTBASE,RCTCODE     LOAD NEW POINTER                     28400021
         B     STRIP               GO TO TEST NEXT AREA                 28500021
CONCOMP  EQU   *                                                        28600021
         CLC   XAV(E1),RCTVER      DO COMMAND AND TABLE MATCH           28700021
         BE    OPTEST               YES, GO TO TEST OPERAND             28800021
         CLC   XAV,CONTROL         IS COMMAND VERB 'CONTROL'            28900021
         BNE   TESTLAST             NO, RETURN TO TABLE SCAN            29000021
         CLI   RCTVER,KCHAR         YES, IS TABLE ENTRY 'K'             29100021
         BNE   TESTLAST             NO, RETURN TO TABLE SCAN            29200021
         B     MATCHOP              YES, BYPASS OPERAND TEST            29300021
OPTEST   EQU   *                                                        29400021
         L     RCTSCAN,XAL         POINT TO OPERAND                     29500021
         CLC   RCTOPD(E1),E0(RCTSCAN)  DOES IT MATCH TABLE              29600021
         BE    MATCHOP              YES, GO TO INSERT VALUES            29700021
         CLC   E0(L'CONSOLES,RCTSCAN),CONSOLES   IS OPERAND 'CONS       29800021
         BNE   TESTLAST             NO, RETURN TO TABLE SCAN            29900021
         CLI   RCTOPD,OCHAR         YES, IS TABLE ENTRY 'O'             30000021
         BNE   TESTLAST             NO, RETURN TO TABLE SCAN            30100021
*                                   YES, GO TO INSERT VALUES            30200021
MATCHOP  EQU   *                                                        30300021
         L     RCTSCAN,RCTBEG+E4   SAVE TABLE ENTRIES                   30400021
         B     TESTENT             GO TO TEST ENTRY                     30500021
NOCOMP   SR    RCTSCAN,RCTSCAN     NO ENTRY FOUND. DUMMY ONE UP         30600021
TESTENT  EQU   *                                                        30700021
*/*TESTENT: D (YES,%STRDA,NO,%STRNULL) IS AREA IN RCT */                30800021
*/*%STRDA: P (,%GETCC) PUT DEFAULT AREA IN XSA */                       30900021
*/*%STRNULL: P (,%GETCC) PUT NULL AREA IN XSA */                        31000021
         LA    RCTSCAN,E0(RCTSCAN) STRIP OFF LEFT BYTE                  31100021
         SRL   RCTSCAN,ONEBYTE     PUT AREA ID IN RIGHT BYTE            31200021
         STC   RCTSCAN,XASDID      STORE AREA ID                        31300021
*                                  (00 IF NONE SPECIFIED)               31400021
*/*%GETCC: D (YES,IDPRES,NO,%STRSRCC) IS CC IN DEFAULT */               31500021
         SRL   RCTSCAN,ONEBYTE     PUT CONSOLE ID IN RIGHT BYTE         31600021
         LTR   RCTSCAN,RCTSCAN     IS AN ID PROVIDED                    31700021
         BNZ   IDPRES               YES, GO TO STORE IT                 31800021
*/*%STRSRCC: P (,LTEST) PUT SOURCE CONSOLE ID IN XSA */                 31900021
         MVC   XASCID(E1),XAU       NO, ENTRY WAS NOT FOUND             32000021
*                                  STORE SOURCE ID IN XSA               32100021
         B     LTEST               SEE IF L OPERAND WAS PRESENT         32200021
IDPRES   STC   RCTSCAN,XASCID      STORE ID FROM TABLE IN XSA           32300021
*/*IDPRES: P (,LTEST) PUT DEFAULT CC ID IN XSA */                       32400021
LTEST    TM    XASSDS,XASSDS2      WAS L OPERAND PRESENT                32500021
*/*LTEST: D (YES,STOREA,NO,VALIDITY) WAS L OPERAND PRESENT */           32600021
         BO    STOREA               YES, GET AREA OPERAND FROM IT       32700021
*                                  FALL THROUGH TO VALIDITY             32800021
         EJECT                                                          32900021
*********************************************************************** 33000021
*                                                                     * 33100021
*        AT ENTRY TO THIS SECTION OF CODE, THE CONSOLE ID AND AREA    * 33200021
* ID HAVE BEEN PUT IN THE XSA, EITHER FROM THE L PARAMETER, THE       * 33300021
* DEFAULTS SPECIFIED BY THE ROUTE COMMAND, OR SYSTEM DEFINED          * 33400021
* DEFAULTS.                                                           * 33500021
*                                                                     * 33600021
*        THIS CODE CHECKS FOR ROUTING AUTHORITY, AND ENSURES THAT     * 33700021
* CC SPECIFIES AN ACTIVE CONSOLE WITH AREA A DEFINED.                 * 33800021
*                                                                     * 33900021
*********************************************************************** 34000021
         SPACE 2                                                        34100021
VALIDITY EQU   *                                                        34200021
         USING DCMACB,SACBBASE     BASE SCREEN AREA CONTROL BLOCK       34300021
         SR    CONSID,CONSID       CLEAR REG                            34400021
         IC    CONSID,XASCID       GET THE TARGET CONSOLE ID            34500021
         SR    SOURCEID,SOURCEID   CLEAR REG                            34600021
         IC    SOURCEID,XAU        GET THE SOURCE CONSOLE ID            34700021
*/*VALIDITY: D (YES,CHKAREA,NO,%TSTAUTH) IS TARGET SAME AS SOURCE */    34800021
         CR    CONSID,SOURCEID     IS TARGET SAME AS SOURCE             34900021
         BE    SRCEQTRG            IF YES, BRANCH                       35000021
         LR    REG1,SOURCEID       PUT SOURCE ID IN PARAMETER REG       35100021
         BAL   LINKR,FINDUCME      GET THE UCM ENTRY ADDRESS OF         35200021
*                                       THE SOURCE AND BASE THE         35300021
*                                       UCM ENTRY                       35400021
*/*%TSTAUTH: D (YES,%TRGACTV,NO,ERREXIT) DOES SOURCE HAVE AUTHORITY TO  35500021
*/* ROUTE */                                                            35600021
         TM    UCMAUTH,UCMAUTH3    DOES SOURCE CONSOLE HAVE             35700021
*                                       AUTHORITY TO ROUTE (MUST        35800021
*                                       HAVE CONS AUTHORITY)            35900021
         BZ    ERR08               NO,  BRANCH TO ERROR ROUTINE         36000021
         LR    REG1,CONSID         PUT TARGET ID IN PARAMETER REG       36100021
         BAL   LINKR,FINDUCME      GET THE UCM ENTRY ADDRESS OF         36200021
*                                       THE TARGET CONSOLE AND          36300021
*                                       BASE THE UCM ENTRY              36400021
*/*%TRGACTV: D (YES,CHKKV,NO,ERREXIT) IS TARGET ACTIVE */               36500021
         TM    UCMATR,UCMUF        IS CONSOLE ACTIVE                    36600021
         BZ    ERR1219             NO,  BRANCH TO ERROR ROUTINE         36700021
*/*CHKKV: D (YES,CHKAREA,NO,CHKFULC) IS COMMAND K V */                  36710021
         CLI   XAN,K               Q. CONTROL COMMAND                   36750021
         BNE   CHKFULC             NO, GO CHECK FOR FULL CAPACITY       36760021
         L     WORKR,XAL           GET POINTER TO 1ST OPERAND           36770021
         CLI   E0(WORKR),V         Q. IS COMMAND K V                    36780021
         BE    CHKAREA             YES, ALLOW ROUTING EVEN IF          X36790021
                                        FULL CAPACITY                   36792021
*/*CHKFULC: D (YES,ERREXIT,NO,CHKAREA) IS TARGET FULL CAPACITY */       36800021
CHKFULC  EQU   *                                                        36850021
         TM    UCMDISP,UCMDISPF+UCMDISPG IS CONSOLE MESSAGE             36900021
*                                       STREAM OR STATUS DISPLAY        37000021
*                                       CONSOLE                         37100021
         BZ    ERR1220             NO,  BRANCH TO ERROR ROUTINE         37200021
*                                       ROUTING IS ALLOWED ONLY         37300021
*                                       TO MESSAGE STREAM OR            37400021
*                                       STATUS DISPLAY CONSOLES         37500021
*                                       (OR ONE'S OWN CONSOLE)          37600021
         B     CHKAREA             BRANCH TO CHECK AREA                 37700021
         SPACE                                                          37800021
SRCEQTRG EQU   *                   SOURCE CONSOLE IS TARGET             37900021
         LR    REG1,CONSID         PUT ID IN PARAMETER REG              38000021
         BAL   LINKR,FINDUCME      GET THE UCM ENTRY ADDRESS OF         38100021
*                                       THE TARGET CONSOLE AND          38200021
*                                       BASE THE UCM ENTRY              38300021
         SPACE 2                                                        38400021
CHKAREA  EQU   *                                                        38500021
* CHECK AREA                                                            38600021
*        FROM THIS POINT ON IN THIS MODULE, UCMEBASE CONTAINS THE       38700021
* ADDRESS OF THE TARGET CONSOLE'S UCM ENTRY.                            38800021
*/*CHKAREA: D (YES,%TSTMS,NO,AREAEXST) IS AREA FIELD NULL */            38900021
         SPACE                                                          39000021
         SR    AREA,AREA           CLEAR REG                            39100021
         IC    AREA,XASDID         GET THE AREA ID                      39200021
         LTR   AREA,AREA           IS AREA FIELD NULL                   39300021
         BNZ   AREAEXST            NO, BRANCH TO SEE IF AREA            39400021
*                                       EXISTS ON TARGET CONSOLE        39500021
*/*%TSTMS: D (YES,SETZ,NO,CHKCMND) IS TARGET MSG STREAM ONLY */         39600021
         TM    UCMDISP,UCMDISPC    IS TARGET CONSOLE A CRT              39700021
         BZ    SETZ                NO, BRANCH TO SET AREA=Z             39800021
         TM    UCMDISP,UCMDISPF    IS TARGET MESSAGE STREAM             39900021
         BZ    CHKCMND             NO, BRANCH TO CHECK THE              40000021
*                                       COMMAND (AREA REMAINS           40100021
*                                       NULL AT THIS POINT IF           40200021
*                                       TARGET IS A STATUS              40300021
*                                       DISPLAY OR FULL CAPACITY        40400021
*                                       CRT CONSOLE)                    40500021
SETZ     EQU   *                                                        40600021
*/*SETZ: P (,CHKCMND) SET AREA = Z IN XSA */                            40700021
         MVI   XASDID,Z            IF TARGET IS NON-CRT OR MSG          40800021
*                                       STREAM ONLY CRT,                40900021
*                                       INDICATE AREA=Z                 41000021
         B     CHKCMND             BRANCH TO CHECK COMMAND              41100021
AREAEXST EQU   *                   AT THIS POINT THE TARGET UCM         41200021
*                                       ENTRY IS STILL BASED            41300021
*                                  FIND OUT IF THE AREA SPECIFIED       41400021
*                                       EXISTS ON THE TARGET            41500021
*/*AREAEXST: D (YES,CHKCMND,NO,ERREXIT) DOES AREA EXIST ON TARGET */    41600021
         TM    UCMDISP,UCMDISPC    IS TARGET A CRT                      41700021
         BO    CRT                 IF YES, BRANCH                       41800021
         CLI   XASDID,Z            IS AREA = Z                          41900021
         BNE   ERR1218             NO,  BRANCH TO ERROR ROUTINE         42000021
         B     CHKCMND             YES, BRANCH TO CHECK COMMAND         42100021
CRT      EQU   *                   TARGET IS A CRT                      42200021
         CLI   XASDID,Z            IS AREA = Z                          42300021
         BNE   OUTOLINE            NO, BRANCH                           42400021
         TM    UCMDISP,UCMDISPG    IS TARGET STATUS DISPLAY ONLY        42500021
         BO    ERR1218             YES, BRANCH TO ERROR ROUTINE         42600021
         B     CHKCMND             NO, BRANCH TO CHECK COMMAND          42700021
OUTOLINE EQU   *                   CHECK IF SPECIFIED OUT OF LINE       42800021
*                                       AREA EXISTS ON TARGET           42900021
         SR    REG1,REG1           CLEAR REG1                           43000021
         IC    REG1,XASDID         PUT AREA ID IN PARAMETER REG         43100021
         BAL   LINKR,FINDSACB      FIND THE SCREEN AREA CONTROL         43200021
*                                       BLOCK FOR THE SPECIFIED         43300021
*                                       AREA. ADDRESS IS PUT IN         43400021
*                                       SACBBASE, ZERO IF NONE          43500021
*                                       FOUND.                          43600021
         LTR   SACBBASE,SACBBASE   IS SPECIFIED AREA DEFINED            43700021
         BZ    ERR1218             NO,  BRANCH TO ERROR ROUTINE         43800021
*                                  FALL THROUGH TO CHKCMND              43900021
         EJECT                                                          44000021
*********************************************************************** 44100021
*                                                                     * 44200021
*    IF THE COMMAND IS CONTROL, EXIT TO THE CONTROL                   * 44300021
* COMMAND HANDLER.  OTHERWISE, EXIT TO THE SECOND LOAD OF THE         * 44400021
* ROUTING LOCATION MODULE.                                            * 44500021
*                                                                     * 44600021
*********************************************************************** 44700021
         SPACE 2                                                        44800021
CHKCMND  EQU   *                                                        44900021
*/*CHKCMND: D (YES,KEXIT,NO,RLM2EXIT) IS COMMAND CONTROL  */            45000021
         CLI   XAN,K               IS COMMAND CONTROL                   45100021
         BE    KEXIT               YES, BRANCH TO K EXIT                45200021
         SPACE                                                          45300021
* EXIT TO SECOND LOAD OF ROUTING LOCATION MODULE                        45400021
RLM2EXIT EQU   *                                                        45450021
*/*RLM2EXIT: R IEE7603D */                                              45500021
         MVC   XAX+3(E2),RLM2      MOVE IN NAME                         45600021
         B     XCTL                BRANCH TO XCTL                       45700021
         SPACE 2                                                        45800021
KEXIT    EQU   *                   EXIT TO CONTROL COMMAND              45900021
*                                       HANDLER                         46000021
*/*KEXIT: R IEE6703D */                                                 46100021
         MVC   XAX+3(E2),KHANDLER  INDICATE EXIT TO K HANDLER           46200021
         SPACE 3                                                        46400021
XCTL     EQU   *                   EXIT                                 46500021
*/*XCTL: R XCTL */                                                      46550021
*                                  REINITIALIZE XSA                     46600021
         LA    WORKR,XAX           POINT XAP TO MODULE NAME             46700021
         ST    WORKR,XAP                IN XAX                          46800021
         SR    WORKR,WORKR         STORE ZERO DCB POINTER               46900021
         ST    WORKR,XAD                IN XAD                          47000021
         XCTL  SF=(E,(XSABASE))    XCTL                                 47100021
         EJECT                                                          47200021
*********************************************************************** 47300021
*                                                                     * 47400021
* FIND AND BASE UCM ENTRY SUBROUTINE                                  * 47500021
*    INPUT - REG1 - CONSOLE ID, RIGHT JUSTIFIED                       * 47600021
*                   (HIGH ORDER BYTES MUST BE ZERO)                   * 47700021
*    OUTPUT - POINTER TO UCM ENTRY SPECIFIED BY CONSOLE ID IN         * 47800021
*                   REGISTER UCMEBASE                                 * 47900021
*    REGISTER USAGE - DESTROYS CONTENTS OF FOLLOWING REGS:            * 48000021
*                   REG0, REG1, UCMEBASE                              * 48100021
*                   LINKR IS RETURN REGISTER                          * 48200021
*                                                                     * 48300021
*********************************************************************** 48400021
         SPACE 2                                                        48500021
FINDUCME EQU   *                                                        48600021
         L     UCMEBASE,UCMVEA     POINT TO FIRST ENTRY                 48700021
         BCTR  REG1,ZERO           SUBTRACT ONE FROM CONSOLE ID         48800021
         M     REG0,UCMVEZ         MULTIPLY ENTRY SIZE BY REDUCED       48900021
*                                       ID                              49000021
         AR    UCMEBASE,REG1       POINT TO DESIRED UCM ENTRY           49100021
         BR    LINKR               RETURN FROM SUBROUTINE               49200021
         EJECT                                                          49300021
*********************************************************************** 49400021
*                                                                     * 49500021
* FIND AND BASE SACB SUBROUTINE                                       * 49600021
*    GIVEN A PARTICULAR CRT CONSOLE AND A ONE CHARACTER AREA ID       * 49700021
* THIS SUBROUTINE FINDS AND BASES THE SCREEN AREA CONTROL BLOCK       * 49800021
* (SACB) WHICH MATCHES THAT ID.  IF NONE IS FOUND, A ZERO IS          * 49900021
* RETURNED AS THE BASE.                                               * 50000021
*    INPUT - REG1 - ONE CHARACTER AREA ID IN LOW ORDER BYTE           * 50100021
*                   (HIGH ORDER BYTES MUST BE ZERO)                   * 50200021
*            UCMEBASE - ADDRESS OF UCM ENTRY OF A CRT CONSOLE         * 50300021
*    OUTPUT - SACBBASE - ADDRESS OF SACB WITH MATCHING ID             * 50400021
*                   (ZERO IF NO MATCH)                                * 50500021
*    REGISTER USAGE - DESTROYS CONTENTS OF FOLLOWING REGS:            * 50600021
*                   REG0, SACBBASE, RDCMBASE                          * 50700021
*                   LINKR IS RETURN REGISTER                          * 50800021
*                                                                     * 50900021
*********************************************************************** 51000021
         SPACE 2                                                        51100021
FINDSACB EQU   *                                                        51200021
         SR    REG0,REG0           CLEAR REG                            51300021
         L     RDCMBASE,UCMXB      GET RESIDENT DCM ADDRESS             51400021
         L     SACBBASE,DCMADSDS   GET FIRST SACB ADDRESS               51500021
CONTINUE EQU   *                                                        51600021
         LTR   SACBBASE,SACBBASE   ANY MORE SACB'S                      51700021
         BCR   NOMORE,LINKR        NO, RETURN FROM SUBROUTINE           51800021
         TM    DCMASACB,DCMAUSE    DOES SACB DEFINE AN AREA             51900021
         BNO   ENDOSACB            NO, BRANCH TO RETURN                 52000021
         IC    REG0,DCMAID         GET ID FROM SACB                     52100021
         CR    REG0,REG1           COMPARE WITH PASSED ID               52200021
         BCR   MATCH,LINKR         EQUAL, RETURN FROM SUBROUTINE        52300021
         L     SACBBASE,DCMACBNX   NOT EQUAL, GET NEXT SACB             52400021
         B     CONTINUE            CONTINUE SEARCH                      52500021
ENDOSACB EQU   *                                                        52600021
         SR    SACBBASE,SACBBASE   INDICATE NO SACB MATCH FOUND         52700021
         BR    LINKR               RETURN FROM SUBROUTINE               52800021
         EJECT                                                          52900021
*                             ERROR EXITS                               53000021
         SPACE 2                                                        53100021
ERR04    EQU   *                                                        53200021
         MVI   XAE,MSG04           INDICATE MAJOR ERROR CODE            53300021
         B     ERREXIT             BRANCH TO ERROR EXIT                 53400021
         SPACE                                                          53500021
ERR08    EQU   *                                                        53600021
         MVI   XAE,MSG08           INDICATE MAJOR ERROR CODE            53700021
         B     ERREXIT             BRANCH TO ERROR EXIT                 53800021
         SPACE                                                          53900021
ERR1218  EQU   *                                                        54000021
         MVI   XASTSAVE,MSG1218    INDICATE MINOR ERROR CODE            54100021
         B     ERR12               BRANCH TO GET MAJOR CODE             54200021
ERR1219  EQU   *                                                        54300021
         MVI   XASTSAVE,MSG1219    INDICATE MINOR ERROR CODE            54400021
         B     ERR12               BRANCH TO GET MAJOR CODE             54500021
ERR1220  EQU   *                                                        54600021
         MVI   XASTSAVE,MSG1220    INDICATE MINOR ERROR CODE            54700021
ERR12    EQU   *                                                        54800021
         MVI   XAE,MSG12           INDICATE MAJOR ERROR CODE            54900021
         L     WORKR,XASTSAVE      GET POINTER TO COMMA BEFORE L        55000021
         AH    WORKR,C1            ADD ONE TO POINT TO L                55100021
         ST    WORKR,XASTSAVE      STORE POINTER TO L                   55200021
         SPACE                                                          55300021
ERREXIT  EQU   *                                                        55400021
*/*ERREXIT: P (,%TSTD) INDICATE EXIT TO ROUTING MESSAGE MODULE -        55450021
*/*IEE5603D*/                                                           55500021
         MVC   XAX+E3(E2),RTMSG     INDICATE ROUTING MSG MODULE         55600021
*/*%TSTD: D (YES,DERREXIT,NO,XCTL) DISPLAY COMMAND */                   55650021
         CLI   XAN,D               Q. DISPLAY                           55700021
         BE    DERREXIT            YES, BRANCH                          55800021
         CLI   XAN,DU              Q. DISPLAY UNITS                     55900021
         BE    DERREXIT            YES, BRANCH                          56000021
         B     XCTL                BRANCH TO XCTL                       56200021
         SPACE                                                          56300021
ERRL     EQU   *                                                        56350021
*/*ERRL: P (,DERREXIT) INDICATE EXIT TO MESSAGE MODULE -IEE0503D  */    56352021
         MVC   XAX+E3(E2),MSGMOD   INDICATE EXIT TO MSG MODULE          56356021
         MVI   XAE,MSGCINVD        MOVE IN ERROR CODE                   56360021
         SPACE                                                          56370021
DERREXIT EQU   *                                                        56400021
*/*DERREXIT: P (,XCTL) TURN OFF REGION BUSY BIT IF TURNED ON FOR THIS   56500021
*/* COMMAND */                                                          56600021
         TM    XASSDS,XASSDS3      WAS REGION BUSY BIT TURNED ON       X56700021
                                        FOR THIS COMMAND                56800021
         BO    XCTL                NO, XCTL                             56900021
*                                  YES, TURN OFF REGION BUSY BIT       X57000021
                                        SINCE COMMAND IS BEING         X57100021
                                        REJECTED                        57200021
         USING DCVT,WORKR                                               57300021
         L     WORKR,PTRCVT        GET POINTER TO CVT                   57400021
         L     WORKR,CVTMSER       GET POINTER TO BASEA                 57500021
         USING BASE,WORKR                                               57600021
         NI    BASFL,XFF-BADSP     TURN OFF REGION BUSY BIT             57700021
         B     XCTL                BRANCH TO XCTL                       57800021
         DROP  WORKR                                                    57900021
         EJECT                                                          58000021
*********************************************************************** 58100021
*                                                                     * 58200021
*                        MAINTAINANCE AREA                            * 58300021
*                                                                     * 58400021
*********************************************************************** 58500021
         SPACE                                                          58600021
PATCH    DC    CL72'***PATCH AREA - IEE7503D***'                        58700000
         EJECT                                                          58800021
*********************************************************************** 58900021
*                                                                     * 59000021
*                             CONSTANTS                               * 59100021
*                                                                     * 59200021
*********************************************************************** 59300021
         SPACE 2                                                        59400021
C0       DC    H'0'           CONSTANT                                  59500021
C1       DC    H'1'           CONSTANT                                  59550021
C2       DC    H'2'           CONSTANT                                  59600021
C3       DC    H'3'           CONSTANT                                  59700021
CONSOLES DC    C'CONSOLES'         CONSOLES OPERAND FOR COMPARE         60000021
CONTROL  DC    C'CONTROL'          CONTROL COMMAND FOR COMPARE          60100021
COMMAL   DC    CL2',L'        LOCATION OPERAND                          60200021
         SPACE                                                          60300021
* MODULE NAMES FOR XCTL -- IGCXX03D -- WHERE XX IS AS FOLLOWS           60400021
RLM2     DC    C'76'               ROUTING LOCATION MODULE, LOAD2       60500021
KHANDLER DC    C'67'               CONTROL COMMAND HANDLER              60600021
RTMSG    DC    C'56'               ROUTING MESSAGE MODULE               61000021
MSGMOD   DC    C'05'               SVC 34 MESSAGE MODULE                61050021
         EJECT                                                          61100021
*********************************************************************** 61200021
*                                                                     * 61300021
*                             EQUATES                                 * 61400021
*                                                                     * 61500021
*********************************************************************** 61600021
         SPACE 2                                                        61700021
ZERO     EQU   0                   ZERO                                 61800021
E0       EQU   0                   CONSTANT                             61900021
E1       EQU   1                   CONSTANT                             62000021
E2       EQU   2                   CONSTANT                             62100021
E3       EQU   3                   CONSTANT                             62150021
E4       EQU   4                   CONSTANT                             62200021
F0       EQU   X'F0'               CONSTANT                             62300021
XFF      EQU   X'FF'               TO TURN OFF BITS                     62400021
OFF      EQU   0                   SWITCH OFF                           62500021
ON       EQU   1                   SWITCH ON                            62600021
ONEBYTE  EQU   8                   NUMBER OF BITS IN BYTE               62700021
EQUAL    EQU   C'='                EQUAL SIGN FOR KEYWORD PARAMETER     62800021
BLANK    EQU   C' '                BLANK                                62900021
KCHAR    EQU   C'K'                CHARACTER K FOR COMPARE              63000021
OCHAR    EQU   C'O'                CHARACTER O FOR COMPARE              63100021
ACFLAG   EQU   X'01'               ACTIVE FLAG IN RCT                   63200021
ENDFLAG  EQU   X'C0'               END OF RCT BLOCK                     63300021
COMMA    EQU   C','                COMMA                                63400021
Z        EQU   C'Z'                Z - ID OF MESSAGE STREAM AREA        63500021
V        EQU   C'V'                CHARACTER V                          63550021
NULL     EQU   X'00'               CODE INDICATES NO AREA               63600021
*                                       SPECIFIED OR DEFAULT            63700021
*                                       PROVIDED BY ROUTE               63800021
NIBBLE   EQU   4                   4 BITS                               63900021
BYTE     EQU   8                   8 BITS                               64000021
BYT2NIB1 EQU   20                  TWO AND A HALF BYTES (20 BITS)       64100021
DBLWORD  EQU   8                   LENGTH OF A DOUBLE WORD              64200021
NOMORE   EQU   8                   BRANCH ON ZERO                       64300021
MATCH    EQU   8                   BRANCH ON EQUAL                      64400021
         SPACE                                                          64500021
K        EQU   X'90'               VERB CODE FOR K (CONTROL)            64600021
D        EQU   X'68'               VERB CODE FOR D (DISPLAY)            64700021
DU       EQU   X'50'               VERB CODE FOR D U (DISPLAY          X64800021
                                        UNITS)                          64900021
MN       EQU   X'64'               VERB CODE FOR MN (MONITOR)           65000021
PM       EQU   X'38'               VERB CODE FOR PM (STOPMN)            65100021
         SPACE                                                          65200021
SECCHAR  EQU   1                   SECOND CHARACTER OF A FIELD          65300021
THRDCHAR EQU   2                   THIRD CHARACTER OF A FIELD           65400021
PTRCVT   EQU   16                  LOCATION OF POINTER TO CVT           65500021
ACTIVE   EQU   C'A'                OPERAND FOR MONITOR ACTIVE           65600021
LGTHHDR  EQU   4                   LENGTH OF SVC 34 PARAMETER LIST      65700021
*                                       HEADER                          65800021
LNGTHCC  EQU   2                   LENGTH OF EBCDIC CONSOLE ID          65900021
LNCC     EQU   X'1'                LENGTH OF CONSOLE ID (IN HEX)        66000021
         SPACE                                                          66100021
* ERROR MESSAGE CODES                                                   66200021
MSG04    EQU   04                  IEE156I CM INVALID OPERAND -         66300021
MSG08    EQU   08                  IEE345I CM AUTHORITY INVALID         66400021
MSG09    EQU   09                  IEE921I CM OP REJECTED               66500021
MSG0912  EQU   12                       DISPLAY ALREADY EXISTS          66600021
MSG0913  EQU   13                       DISPLAY AREA BUSY               66700021
MSG0914  EQU   14                       NO MONITOR TO STOP              66800021
MSG0925  EQU   25                       NEEDS DISPLAY AREA              66900021
MSG12    EQU   12                  IEE926I L=CCA OPERAND INVALID        67000021
MSG1218  EQU   18                       CCA NOT AN AREA                 67100021
MSG1219  EQU   19                       CC NOT A CONSOLE                67200021
MSG1220  EQU   20                       CC FULL CAPABILITY              67300021
MSG1221  EQU   21                       DYNAMIC DISPLAY IN AREA         67400021
         SPACE                                                          67450021
MSGCINVD EQU   05                  COMMAND INVALID                      67460021
         EJECT                                                          67500021
DXSA     DSECT                                                          67600021
         IEEXSA                                                         67700021
         SPACE 2                                                        67800021
* THE XAP AND XAD FIELDS OF THE XSA ARE USED AS A DOUBLE WORD           67900021
*     WORK AREA IN THIS MODULE AND ARE REINITIALIZED BEFORE EXIT        68000021
         SPACE                                                          68100021
* THE XAS FIELD OF THE XSA IS USED AS FOLLOWS IN THIS MODULE            68200021
         ORG   XAS                                                      68300021
XASCID   DS    X                   CONSOLE ID                           68400021
XASDID   DS    C                   DISPLAY AREA ID                      68500021
XASSDS   DS    X                   SDS SWITCHES                         68600021
XASSDS1  EQU   X'80'               THIS COMMAND IS A STATUS            X68700021
                                        DISPLAY                         68800021
XASSDS2  EQU   X'40'               L OPERAND IS SPECIFIED ON           X68900021
                                        COMMAND                         69000021
XASSDS3  EQU   X'20'               DONT TURN OFF REGION BUSY BIT        69100021
XASPLS3  DS    X                   RESERVED                             69200021
XASTSAVE DS    X                   ERROR CODE -- MINOR                  69300021
         DS    XL3                 POINTER TO INVALID OPERAND           69400021
         EJECT                                                          69500021
DRDCM    DSECT                                                          69600021
         IEECRDCM DSECT=YES                                             69700021
         EJECT                                                          69800021
DRCT     DSECT                                                          69900021
         IEECVMAP RCT                                                   70000021
         EJECT                                                          70100021
DUCM     DSECT                                                          70200021
         IEECUCM                                                        70300021
         EJECT                                                          70400021
DCVT     DSECT                                                          70500021
         CVT                                                            70600021
         EJECT                                                          70700021
         IEEBASEA                                                       70800021
         EJECT                                                          70900021
*/*IEE7503D: END */                                                     71000021
         END                                                            71100021
