         TITLE 'IEE7603D  -- ROUTING LOCATION MODULE, LOAD 2'           00100021
IEE7603D CSECT                                                          00200021
* C 593000                                                       YM0055 00202021
* A 338300,338600                                                       00205021
*A333500-333992,C334000,C339000,A339600,A601000,D701000       MG  M2091 00210021
*C254000-254500                                                   M0776 00250021
*A360100-360620                                                   M0776 00260021
*A611500                                                          M0776 00270021
* C 103200,103400                                                A56654 00280021
* A 139850,355100-355700                                         A56654 00290021
*/*IEE7603D: CHART */                                                   00300021
*/*%START: E (,BEGIN) IEE7603D */                                       00400021
         EJECT                                                          00500021
*                                                                       00600021
* STATUS  CHANGE LEVEL 0                                                00700021
*                                                                       00800021
* FUNCTION     FURTHER HANDLING OF ROUTING, IF THE COMMAND IS D,        00900021
*    MN, OR PM                                                          01000021
*    1) FURTHER VALIDITY CHECKS THE AREA AND PROVIDES SYSTEM            01100021
*    DEFAULTS IF NO L OPERAND OR RCT DEFAULTS EXIST                     01200021
*    2) FOR D AND MN COMMANDS - RESERVES A DISPLAY AREA IF THE          01300021
*    DISPLAY IS ROUTED TO A CRT CONSOLE                                 01400021
*    3) SETS UP FOR MN PROCESSING FOR DYNAMIC STATUS DISPLAYS           01500021
*                                                                       01600021
* ENTRY POINTS   IEE7603D FROM IEE7503D                                 01700021
*                                                                       01800021
* INPUT                                                                 01900021
*    1) REGISTER 2 - POINTER TO THE XSA                                 02000021
*    2) TARGET CONSOLE ID, AREA ID, AND FLAGS IN THE XAS                02100021
*    FIELD OF THE XSA                                                   02200021
*                                                                       02300021
* OUTPUT                                                                02400021
*    1) TARGET CONSOLE ID, AREA ID, AND FLAGS IN THE XAS FIELD          02500021
*    OF THE XSA                                                         02600021
*    2) ON EXIT TO IEE5503D ONLY -- REGISTER 10 - POINTER TO THE        02700021
*    MASTER SCHEDULER RESIDENT DATA AREA                                02800021
*                                                                       02900021
* EXTERNAL REFERENCES NONE                                              03000021
*                                                                       03100021
* EXITS,NORMAL                                                          03200021
*    IEE0803D VIA XCTL FOR D AND MN                                     03300021
*    IEE5503D VIA XCTL FOR PM                                           03400021
*    RETURN VIA BR 14 FOR MN, IF MN IS ALREADY ACTIVE IN THE SYSTEM     03500021
*                                                                       03600021
* EXITS,ERROR                                                           03700021
*    IEE5603D VIA XCTL FOR ERROR MESSAGES                               03800021
*                                                                       03900021
* TABLES/WORK AREAS                                                     04000021
*    XSA                                                                04100021
*    UCM                                                                04200021
*    RESIDENT DCM (INCLUDING SCREEN AREA CONTROL BLOCKS-SACB'S)         04300021
*    MASTER SCHEDULER RESIDENT AREA - BASEA                             04400021
*                                                                       04500021
* ATTRIBUTES   REENTRANT, REFRESHABLE, PRIVILEGED, TYPE 4 SVC           04600021
*                                                                       04700021
* NOTES   NONE                                                          04800021
         EJECT                                                          04900021
* THIS ROUTINE WAS CREATED FOR STATUS DISPLAY SUPPORT, LINE ITEM 21002, 05000021
*     OS RELEASE 21.                                                    05100021
         SPACE 2                                                        05200021
* REGISTER USAGE                                                        05300021
*        THE REGISTERS WITH AN * ARE RESERVED FOR THE USE               05400021
* INDICATED THROUGHOUT THE MODULE.  THE OTHERS HOLD THE VALUE           05500021
* INDICATED ONLY TEMPORARILY.                                           05600021
REG0     EQU   0                   USED WITH REG1 AS                    05700021
*                                       EVEN/ODD PAIR                   05800021
REG1     EQU   1                   PARAMETER REGISTER FOR INTERNAL      05900021
*                                       SUBROUTINES - USED WITH         06000021
*                                       REG0 AS EVEN/ODD PAIR           06100021
XSABASE  EQU   2                 * BASE REGISTER FOR XSA                06200021
UCMBASE  EQU   3                 * BASE REGISTER FOR UCM                06300021
PARAMPTR EQU   4                   POINTER TO SVC 34 PARAMETER LIST     06400021
INCR     EQU   4                   INCREMENT REG FOR BX (REG 5 IS       06500021
*                                       USED FOR COMPARAND)             06600021
WORKR    EQU   4                   WORK REG, PART OF EVEN/ODD PAIR      06700021
WORK1    EQU   5                   WORK REG, PART OF EVEN/ODD PAIR      06800021
END      EQU   5                   POINTER TO LAST CHARACTER OF         06900021
*                                       COMMAND                         07000021
SOURCEID EQU   5                   SOURCE CONSOLE ID                    07100021
AREA     EQU   6                 * TARGET AREA ID                       07200021
CONSID   EQU   7                 * TARGET CONSOLE ID                    07300021
OPPTR    EQU   8                   POINTS WITHIN OPERAND FIELD OF       07400021
*                                       COMMAND ENTERED                 07500021
RDCMBASE EQU   10                * BASE REGISTER FOR RESIDENT DCM       07600021
R10      EQU   10                  ON EXIT TO IEE5503D ONLY -           07700021
*                                       POINTER TO MASTER               07800021
*                                       SCHEDULER RESIDENT DATA         07900021
*                                       AREA                            08000021
SACBBASE EQU   11                * SCREEN AREA CONTROL BLOCK BASE       08100021
UCMEBASE EQU   12                * BASE REGISTER FOR UCM ENTRY          08200021
*                                       (FIRST SOURCE, THEN TARGET)     08300021
MYBASE   EQU   13                * BASE REGISTER FOR THIS ROUTINE       08400021
RETURNR  EQU   14                * RETURN REGISTER                      08500021
WORK2    EQU   15                  WORK REG                             08600021
LINKR    EQU   15                  LINK REGISTER                        08700021
         EJECT                                                          08800021
* ESTABLISH ADDRESSABILITY                                              08900021
         SPACE 2                                                        09000021
         BALR  MYBASE,E0           BASE THIS                            09100021
         USING *,MYBASE                 MODULE                          09200021
         B     BEGIN               BRANCH AROUND MODULE NAME            09300021
         DC    C'IGC7603D'         MODULE NAME                          09400021
BEGIN    EQU   *                                                        09500021
*/*BEGIN: P (,%TSTRT) ESTABLISH ADDRESSABILITY */                       09600021
         USING DXSA,XSABASE        BASE XSA (POINTER RECEIVED AS        09700021
*                                       INPUT IN REG)                   09800021
         L     WORKR,PTRCVT        GET CVT POINTER                      09900021
         USING DCVT,WORKR          BASE CVT                             10000021
         L     UCMBASE,CVTCUCB     GET UCM POINTER                      10100021
         USING DUCM,UCMBASE        BASE UCM                             10200021
         SPACE                                                          10300021
*/*%TSTRT: D (YES,%TSTA,NO,NORT) IS CONSOLE ALLOWED TO ROUTE */         10302021
         CLC   XAJ(E2),C0          IS COMMAND FROM TSO TERMINAL         10310021
         BNE   TESTOPR             YES-NO ROUTING,GO TEST OPERANDA56654 10320021
         CLI   XAU,E0              IS CONSOLE ID ZERO (NON-MCS)         10330021
         BE    TESTOPR             NON-MCS, GO TEST OPERANDS     A56654 10340021
         SPACE                                                          10350021
         SR    REG1,REG1           CLEAR REG                            10400021
         IC    REG1,XASCID         GET TARGET CONSOLE ID                10500021
         BAL   LINKR,FINDUCME      BASE UCM ENTRY                       10600021
         USING UCMLIST,UCMEBASE    BASE UCM ENTRY                       10700021
         SPACE                                                          10800021
         TM    UCMDISP,UCMDISPC    IS TARGET A CRT                      11200021
         BNO   SKIP                NO, BRANCH AROUND CODE               11300021
         L     RDCMBASE,UCMXB      GET ADDRESS OF RESIDENT DCM          11350021
         USING DRDCM,RDCMBASE      BASE RESIDENT DCM                    11360021
         SPACE                                                          11370021
         SR    REG1,REG1           CLEAR REG                            11400021
         IC    REG1,XASDID         GET AREA ID                          11500021
         BAL   LINKR,FINDSACB      BASE SACB                            11600021
         USING DCMACB,SACBBASE     BASE SCREEN AREA CONTROL BLOCK       11700021
         SPACE                                                          11800021
SKIP     EQU   *                                                        11900021
         EJECT                                                          13500021
*    IF ANY COMMANDS OTHER THAN D, MN, PM ARE PROCESSED BY THIS         13550021
*      MODULE, TESTS FOR THESE SHOULD BE MADE ABOVE THIS POINT          13600021
*/*%TSTA: D (YES,%TSTAC,NO,TSTDSPLY) IS FIRST CHARACTER OF OPERAND A */ 13650021
         L     WORKR,XAL           GET ADDRESS OF OPERANDS              13900021
         CLI   E0(WORKR),A         IS FIRST CHAR OF OPERAND 'A'         13950021
         BNE   TSTDSPLY            NO, SEE IF COMMAND IS DISPLAY        13960021
*/*%TSTAC: D (YES,TSTCMND,NO,ERREXIT) IS OPERAND 'A ' FOR ACTIVE */     13962021
         CLI   E1(WORKR),BLANK     IS OPERAND 'A ' FOR ACTIVE           13970021
         BE    TSTCMND             YES, GO SEE WHAT COMMAND IS          13980021
GOERR04  EQU   *                                                 A56654 13985021
         SPACE                                                          13990021
*    'A' FOLLOWED BY A NON-BLANK CHARACTER IS AN INVALID OPERAND        13992021
         LA    WORKR,E2(WORKR)     POINT TO FIRST CHAR AFTER 'A,'       13994021
         ST    WORKR,XASTSAVE      STORE POINTER TO INVALID            X14700021
                                        OPERAND                         14800021
         B     ERR04               BRANCH TO ERROR ROUTINE              14900021
         EJECT                                                          14910021
TSTCMND  EQU   *                                                        14950021
*/*TSTCMND: D (YES,ACTIVE,NO,%TSTPM) IS COMMAND MONITOR */              14952021
         CLI   XAN,MN              IS COMMAND MONITOR                   14960021
         BE    ACTIVE              YES, BRANCH                          14970021
*/*%TSTPM: D (YES,ACTIVE,NO,TSTDSPLY) STOPMN COMMAND */                 14980021
         CLI   XAN,PM              IS COMMAND STOPMN                    14990021
         BE    ACTIVE              YES, BRANCH                          14992021
         SPACE                                                          14994021
TSTDSPLY EQU   *                                                        14996021
*/*TSTDSPLY: D (YES,DISPLAY,NO,RETURN) DISPLAY COMMAND */               14998021
         CLI   XAN,D               IS COMMAND DISPLAY                   14998421
         BE    DISPLAY             YES, BRANCH TO DISPLAY               14998821
         CLI   XAN,DU              IS COMMAND DISPLAY UNITS             14999221
         BE    DISPLAY             YES, BRANCH TO DISPLAY               14999621
         SPACE                                                          14999721
* ONE OF THE ABOVE BRANCHES SHOULD ALWAYS BE TAKEN                      14999821
         B     RETURN              OTHERWISE RETURN                     14999921
         SPACE 3                                                        15000021
ACTIVE   EQU   *                                                        15100021
*/*ACTIVE: P (,%BRANCH) SET UP MASK FOR 'A ' OPERAND */                 15200021
         LA    WORKR,UCMMSGC       SET UP MSGTYP MASK FOR ACTIVE        15300021
         SLL   WORKR,BYTE               IN THE FIRST HALF WORD          15400021
         STH   WORKR,XAP                OF THE XSA                      15500021
         SPACE 2                                                        15600021
*/*%BRANCH: D (YES,MONITOR,NO,STOPMN) IS COMMAND MONITOR */             15700021
         CLI   XAN,MN              IS COMMAND MONITOR                   15800021
         BE    MONITOR             YES, BRANCH TO HANDLE MONITOR        15900021
         B     STOPMN              NO, BRANCH TO HANDLE STOPMN          16000021
         EJECT                                                          16100021
STOPMN   EQU   *                                                        16200021
* STOPMN HANDLING                                                       16300021
*    CHECK FOR MONITOR TO STOP                                          16400021
*/*STOPMN: D (YES,MNAREA,NO,FINDMNAR) AREA SPECIFIED */                 16500021
         CLI   XASDID,Z            Q. AREA = Z                          16600021
         BE    ERR0914             YES - ERROR -- NOT POSSIBLE         X16700021
                                        TO HAVE A DYNAMIC              X16800021
                                        DISPLAY INLINE                  16900021
         CLI   XASDID,NULL         Q. AREA NULL                         17000021
         BE    FINDMNAR            YES, BRANCH TO FIND AREA WITH       X17100021
                                        MONITOR IN IT                   17200021
         SPACE                                                          17300021
*    SEE IF AREA SPECIFIED HAS SPECIFIED MONITOR IN IT                  17400021
MNAREA   EQU   *                                                        17500021
*/*MNAREA: D (YES,OFFMT,NO,ERREXIT) SPECIFIED MONITOR IN AREA */        17600021
         CLC   DCMAMT(E2),XAP      Q. MASK IN SACB = MASK FOR          X17700021
                                        COMMAND                         17800021
         BE    OFFMT               YES, TURN OFF MSGTYP FLAG            17900021
         B     ERR0914             NO,  BRANCH TO ERROR ROUTINE         18000021
         SPACE                                                          18100021
FINDMNAR EQU   *                                                        18200021
*/*FINDMNAR: D (YES,MNFOUND,NO,ERREXIT) SPECIFIED MN ON                 18300021
*/*                                CONSOLE                    */        18400021
*    LOOK FOR AREA CONTAINING SPECIFIED DYNAMIC DISPLAY                 18500021
         L     SACBBASE,DCMADSDS   GET FIRST SACB ADDRESS               18600021
CONTINU1 EQU   *                                                        18700021
         LTR   SACBBASE,SACBBASE   ANY MORE SACB'S                      18800021
         BZ    ERR0914             NO,  BRANCH TO ERROR ROUTINE         18900021
         TM    DCMASACB,DCMAUSE    DOES SACB DEFINE AN AREA             19000021
         BNO   ERR0914             NO,  BRANCH TO ERROR ROUTINE         19100021
         CLC   DCMAMT(E2),XAP      Q. MASK IN SACB = MASK FOR          X19200021
                                        COMMAND                         19300021
         BE    MNFOUND             YES, BRANCH TO STORE AREA ID         19400021
         L     SACBBASE,DCMACBNX   NO, GET NEXT SACB                    19500021
         B     CONTINU1            CONTINUE SEARCH                      19600021
MNFOUND  EQU   *                                                        19700021
*/*MNFOUND: P (,OFFMT) PUT AREA ID IN XSA */                            19800021
         MVC   XASDID(E1),DCMAID   PUT AREA ID IN XAS                   19900021
OFFMT    EQU   *                                                        20000021
*/*OFFMT: P (,PMEXIT) TURN OFF MESSAGE TYPE FLAG IN TARGET UCM ENTRY */ 20100021
         LH    WORKR,FFFF          REVERSE BITS IN                      20150021
         SH    WORKR,XAP           XAP                                  20160021
         STH   WORKR,XAP           FOR AND'ING                          20170021
         NC    UCMMSG(E2),XAP      TURN OFF MESSAGE TYPE FLAG IN       X20200021
                                        TARGET UCM ENTRY                20300021
         B     PMEXIT              EXIT TO SECOND LOAD OF              X20350021
                                        PM HANDLER                      20360021
         EJECT                                                          21300021
*********************************************************************** 21400021
*                                                                     * 21500021
*        IN THE CASE OF A MONITOR OR DISPLAY COMMAND, A REQUEST       * 21600021
* FOR AN INLINE DISPLAY (AREA=Z) IS HANDLED AND APPROPRIATE EXIT      * 21700021
* TAKEN.  IF AN OUT OF LINE DISPLAY IS REQUESTED, A SPECIFIED         * 21800021
* (BY EITHER THE L OPERAND OR THE ROUTING CONTROL TABLE) TARGET       * 21900021
* AREA IS CHECKED FOR AVAILABILITY.  OR, IF NO AREA IS SPECIFIED,     * 22000021
* A DEFAULT AREA IS PROVIDED.  CERTAIN CONDITIONS ARE THEN SET UP     * 22100021
* FOR THE DISPLAY, AND APPROPRIATE EXIT TAKEN.                        * 22200021
*                                                                     * 22300021
*********************************************************************** 22400021
         SPACE 2                                                        22500021
DISPLAY  EQU   *                   DISPLAY COMMAND                      22600021
*/*DISPLAY: D (YES,SDEXIT,NO,OLREQ) AREA = Z */                         22800021
         CLI   XASDID,Z            IS AREA = Z                          22900021
         BNE   OLREQ               NO, BRANCH TO HANDLE OUT OF          23000021
*                                       LINE REQUEST                    23100021
         B     SDEXIT              EXIT                                 23260021
         SPACE                                                          23600021
MONITOR  EQU   *                   MONITOR COMMAND                      23700021
*/*MONITOR: D (YES,OVER,NO,%CMNDRTD) TARGET A CRT */                    23900021
* IF A NON-CRT REQUESTS A DYNAMIC STATUS DISPLAY FOR ITSELF, THE        24000021
*        REQUEST IS CHANGED TO A REQUEST FOR A STATIC STATUS            24100021
*        DISPLAY (CHANGE FROM MONITOR COMMAND TO DISPLAY COMMAND)       24200021
         TM    UCMDISP,UCMDISPC    IS TARGET CONSOLE A CRT              24300021
         BO    OVER                YES, BRANCH                          24400021
*/*%CMNDRTD: D (YES,ERREXIT,NO,CHANGE) COMMAND ROUTED */                24500021
         CLC   XAU(LNCC),XASCID    IS TARGET SAME AS SOURCE             24600021
         BNE   ERR0925             NO, BRANCH TO ERROR ROUTINE          24700021
*                                       MN CAN BE ROUTED ONLY           24800021
*                                       TO A CRT                        24900021
*/*CHANGE: P (,DEXIT) CHANGE MN TO D */                                 25000021
CHANGE   EQU   *                                                        25060021
         MVI   XAN,D               CHANGE THE VERB CODE IN THE          25100021
*                                       XSA TO THE CODE FOR             25200021
*                                       DISPLAY                         25300021
         B     DEXIT               GO TO DISPLAY ROUTER TO CHECK  M0776 25400021
*                                       FOR REGION BUSY,ETC.      M0776 25450021
         SPACE 2                                                        25600021
OVER     EQU   *                                                        25700021
*/*OVER: D (YES,ERREXIT,NO,CHKFORMN) AREA = Z */                        25800021
         CLI   XASDID,Z            IS AREA = Z                          25900021
         BE    ERR0925             YES, BRANCH TO ERROR ROUTINE         26000021
*                                       MN CANNOT GO INLINE             26100021
         SPACE                                                          26200021
*/*CHKFORMN: D (YES,MNHERE,NO,OLREQ) SPECIFIED MN ALREADY ON            26300021
*/*                                CONSOLE */                           26400021
* CHECK IF SPECIFIED MN IS ALREADY ON CONSOLE (CANNOT LOOK AT           26500021
*    UCMMSG FIELD BECAUSE FLAG IS OFF WHEN IN HOLD MODE)                26600021
         CLI   DCMTOPDS,NULL       Q. ANY DISPLAYS ON SCREEN            26700021
         BE    OLREQ               NO, BRANCH TO CHECK AREA             26800021
         ST    SACBBASE,XAD        SAVE SACB BASE                       26900021
         L     SACBBASE,DCMADSDS   GET POINTER TO FIRST SACB            27000021
CHKFORMN EQU   *                                                        27100021
         CLC   XAP(E2),DCMAMT      DOES THIS AREA HAVE                 X27200021
                                        SPECIFIED MN                    27300021
         BE    MNHERE              YES, BRANCH TO CHECK FURTHER         27400021
         CLC   DCMTOPDS,DCMAID     IS THIS TOP DISPLAY                  27500021
         BE    RESTBASE            YES, GO RESTORE SACB BASE            27600021
         L     SACBBASE,DCMACBNX   BASE NEXT SACB                       27700021
         B     CHKFORMN            CONTINUE SEARCH                      27800021
MNHERE   EQU   *                                                        27900021
*/*MNHERE: D (YES,MNSETUP,NO,ERREXIT) INTERNAL MN FOR K D,U */          28000021
* SPECIFIED MN ALREADY ON TARGET CONSOLE.  THIS IS AN ERROR             28100021
*    UNLESS THE MN IS INTERNALLY ISSUED FOR K D,U PROCESSING            28200021
         L     SACBBASE,XAD        RESTORE SACBBASE                     28300021
         LTR   SACBBASE,SACBBASE   Q. WAS OUT OF LINE AREA             X28400021
                                        SPECIFIED                       28500021
         BZ    ERR0912             NO, ERROR                            28600021
         CLC   DCMAMT(E2),XAP      Q. SPECIFIED MN ALREADY IN          X28700021
                                        AREA                            28800021
         BNE   ERR0912             NO, ERROR                            28900021
         TM    DCMADFLG,DCMAHOLD   Q. HOLD MODE FLAG ON                 29000021
         BO    ERR0912             YES, ERROR - CAN'T GET OUT OF       X29100021
                                        HOLD MODE BY OPERATOR          X29200021
                                        ISSUING MN                      29300021
         B     MNSETUP             GO SET UP FOR MN. THE COMMAND        29400021
*                                       IS EITHER AN INTERNAL MN        29500021
*                                       ISSUED BY THE K D,U             29600021
*                                       PROCESSOR (WHO HAS              29700021
*                                       ALREADY TURNED THE HOLD         29800021
*                                       FLAG OFF) OR A MN               29900021
*                                       IDENTICAL TO THE ONE            30000021
*                                       ALREADY GOING (AND              30100021
*                                       THEREFORE HARMLESS)             30200021
RESTBASE EQU   *                                                        30300021
         L     SACBBASE,XAD        RESTORE SACBBASE                     30400021
         EJECT                                                          30500021
* IF AREA IS SPECIFIED, CHECK IF OK TO USE                              30600021
         SPACE                                                          30700021
OLREQ    EQU   *                   OUT OF LINE REQUEST                  30800021
*/*OLREQ: D (YES,%CHKAREA,NO,DEFAREA) AREA PROVIDED */                  30900021
         CLI   XASDID,NULL         WAS AREA SPECIFIED IN COMMAND        31000021
*                                       OR BY ROUTE DEFAULT             31100021
         BE    DEFAREA             NO, BRANCH TO PROVIDE DEFAULT        31200021
*                                       AREA                            31300021
*/*%CHKAREA: D (YES,ERREXIT,NO,SETUP) DYNAMIC DISPLAY IN AREA */        31400021
         TM    DCMADFLG,DCMADD     CHECK IN SACB (STILL BASED) IF       31500021
*                                       DYNAMIC DISPLAY IS              31600021
*                                       ALREADY IN AREA                 31700021
         BO    ERR1221             YES, BRANCH TO ERROR ROUTINE         31800021
         SPACE 2                                                        31900021
* SET UP FOR DISPLAY                                                    32000021
         SPACE                                                          32100021
SETUP    EQU   *                                                        32200021
*/*SETUP: D (YES,MNSETUP,NO,SDEXIT) MONITOR COMMAND */                  32600021
         CLI   XAN,MN              IS THIS A MONITOR COMMAND            32700021
         BNE   SDEXIT              NO, EXIT                             32900021
         SPACE                                                          33200021
MNSETUP  EQU   *                   SET UP FOR MONITOR COMMAND           33300021
*                                  MCS IS ASSUMED HERE        MG  M2091 33350021
*/*MNSETUP: D (NO,SDEXIT,YES,) IS TIMER WORKING */                      33360021
         LR    WORK1,UCMBASE       GET UCM BASE ADDRESS       MG  M2091 33370021
         SH    WORK1,HFOUR         POINT TO PTR TO UCM PREFIX MG  M2091 33380021
         L     WORK1,ZERO(WORK1)   GET PTR TO UCM PREFIX      MG  M2091 33390021
         USING MCSUCM,WORK1        BASE UCM PREFIX            MG  M2091 33392021
         TM    UCMSFLGS,UCMSYSH    IS TIMER OPERATING         MG  M2091 33394021
         BNO   SDEXIT              NO, DISPLAY WILL NOT BE    MG  M2019 33396021
         DROP  WORK1               CREATED BY MN PROCESSOR    MG  M2091 33398021
*                                  SO DO NOT SET BITS         MG  M2091 33398421
*                                  INDICATING ONE IS GOING    MG  M2091 33398821
*                                  TO BE SENT TO CONSOLE      MG  M2091 33399221
*/* P (,NOTIME) SET MSGTYP FLAG IN UCM ENTRY AND SACB */                33400021
         OC    UCMMSG(E2),XAP      TURN ON APPROPRIATE MESSAGE          33500021
*                                       TYPE FLAG IN TARGET             33600021
*                                       CONSOLE'S UCM ENTRY AND         33700021
         OC    DCMAMT(E2),XAP           THE AREA'S SACB                 33800021
         OI    DCMAFLG1,DCMAHRD+DCMADISP   IND MN A COMING +     A63496X33830021
                                           DISP IN AREA          A63496 33860021
*/*NOTIME: D (YES,MNA,NO,RETURN) MONITOR ACTIVE */                      33900021
NOTIME   EQU   *                                              MG  M2091 33960021
         TM    XAP,UCMMSGC         Q. MONITOR ACTIVE                    34000021
         BO    MNA                 YES, GO SET UP FOR MN ACTIVE         34100021
* CONTROL SHOULD NEVER FALL THROUGH HERE IF MONITOR ACTIVE IS           34200021
*     THE ONLY DYNAMIC STATUS DISPLAY SUPPORTED                         34300021
         B     RETURN              RETURN FROM SVC 34                   34400021
MNA      EQU   *                                                        34500021
*/*MNA: D (YES,RETURN,NO,%ACTIVE) MN A ALREADY IN SYSTEM */             34600021
         USING DCVT,WORKR                                               34700021
         L     WORKR,PTRCVT        GET POINTER TO CVT                   34800021
         L     WORKR,CVTMSER       GET POINTER TO BASEA                 34900021
         USING BASE,WORKR                                               35000021
         TM    BAMONITR,BAMACTVE   IS MN A ALREADY IN THE SYSTEM        35100021
         BO    RETURN              YES, RETURN                          35200021
*/*%ACTIVE: P (,SDEXIT) TURN ON MN A FLAG IN BASEA */                   35300021
         OI    BAMONITR,BAMACTVE   NO, TURN ON BASEA FLAG               35400021
         B     SDEXIT              EXIT                                 35500021
TESTOPR  EQU   *                   HERE TO SYNTAX CHECK OPERANDS A56654 35510021
         L     WORKR,XAL           GET OPERAND ADDRESS           A56654 35520021
         CLI   E0(WORKR),A         IS FIRST CHAR. 'A'            A56654 35530021
         BNE   NORT                NO-TEST FOR MN COMMAND        A56654 35540021
         CLI   E1(WORKR),BLANK     IS IT 'A '                    A56654 35550021
         BE    NORT                YES-TEST FOR MN COMMAND       A56654 35560021
         B     GOERR04             NO-INVALID                    A56654 35570021
         EJECT                                                          35650021
NORT     EQU   *                                                        35652021
*/*NORT: D (YES,CHANGE,NO,%TSTD) IS COMMAND MONITOR */                  35652421
         CLI   XAN,MN              IS COMMAND MONITOR                   35654021
         BE    CHANGE              YES, GO CHANGE IT TO DISPLAY         35656021
*/*%TSTD: D (YES,SDEXIT,NO,ERRRT) IS COMMAND DISPLAY */                 35656421
         CLI   XAN,D               IS COMMAND DISPLAY                   35658021
         BE    SDEXIT              YES, EXIT                            35658421
         CLI   XAN,DU              IS COMMAND DISPLAY UNITS             35658821
         BE    SDEXIT              YES, EXIT                            35659221
         B     ERRRT               ANYTHING BESIDES D OR MN            X35659621
                                        IS REJECTED                     35659721
         EJECT                                                          35659821
*                             EXITS                                     35660021
         SPACE 2                                                        35670021
RETURN   EQU   *                                                        35700021
*/*RETURN: R RETURN */                                                  35800021
         BR    RETURNR             RETURN                               35900021
         DROP  WORKR                                                    36000021
         SPACE 2                                                        36002021
DEXIT    EQU   *                                                  M0776 36010021
*/*DEXIT: R IEE3503D */                                                 36020021
         MVC   XAX+E3(E2),DROUTER  INDICATE EXIT TO DISPLAY       M0776 36050021
*                                      COMMAND ROUTER             M0776 36052021
         B     XCTL                BRANCH TO XCTL                 M0776 36062021
         SPACE 2                                                        36100021
PMEXIT   EQU   *                                                        36150021
*/*PMEXIT: R  IEE5503D */                                               36160021
         USING DCVT,WORKR          BASE CVT                             36170021
         L     WORKR,PTRCVT        GET POINTER TO CVT                   36180021
         L     R10,CVTMSER         GET POINTER TO BASEA                 36190021
         DROP  WORKR                                                    36192021
         MVC   XAX+3(E2),PMHNDLR   INDICATE EXIT TO 2ND LOAD OF         36194021
*                                       STOPMN HANDLER                  36196021
         B     XCTL                BRANCH TO XCTL                       36198021
         SPACE 2                                                        36198421
SDEXIT   EQU   *                                                        36198821
*/*SDEXIT: P (,CSCBEXIT) INDICATE STATUS DISPLAY */                     36198921
         OI    XASSDS,XASSDS1      INDICATE STATUS DISPLAY              36199221
         SPACE                                                          36199621
CSCBEXIT EQU   *                                                        36199721
*/*CSCBEXIT: R IEE0803D */                                              36199821
         MVC   XAX+E3(E2),CSCB     INDICATE EXIT TO CSCB CREATOR        36199921
         SPACE 2                                                        36200021
XCTL     EQU   *                   EXIT                                 36266721
*                                  REINITIALIZE XSA                     36300021
         LA    WORKR,XAX           POINT XAP TO MODULE NAME             36400021
         ST    WORKR,XAP                IN XAX                          36500021
         SR    WORKR,WORKR         STORE ZERO DCB POINTER               36600021
         ST    WORKR,XAD                IN XAD                          36700021
         XCTL  SF=(E,(XSABASE))    XCTL                                 36800021
         EJECT                                                          36900021
*********************************************************************** 37000021
*                                                                     * 37100021
*        IF NO AREA IS SPECIFIED IN THE COMMAND AND NO DEFAULT IS     * 37200021
* FOUND IN THE ROUTING CONTROL TABLE, A DEFAULT AREA IS ESTABLISHED   * 37300021
* AS FOLLOWS:                                                         * 37400021
*        (1) THE BOTTOM-MOST EMPTY AREA                               * 37500021
*        (2) IF NONE EMPTY, THE AREA CONTAINING THE OLDEST STATIC     * 37600021
*            DISPLAY                                                  * 37700021
*        (3) IF NO DISPLAY AREAS AVAILABLE, A MONITOR COMMAND IS      * 37800021
*            REJECTED; A STATIC DISPLAY IS PUT IN LINE                * 37900021
*        (4) IF THE CONSOLE HAS NO MESSAGE STREAM, A DISPLAY COMMAND  * 38000021
*            IS REJECTED                                              * 38100021
*                                                                     * 38200021
*********************************************************************** 38300021
         SPACE 2                                                        38400021
DEFAREA  EQU   *                                                        38500021
*/*DEFAREA: D (YES,MTAREA,NO,MSGSTRM) ANY AREAS DEFINED */              38600021
         L     SACBBASE,DCMADSDS   GET POINTER TO FIRST SACB            38700021
         CLI   DCMTOPAR,E0         ANY AREAS DEFINED FOR TARGET         38800021
*                                       CONSOLE                         38900021
         BNE   MTAREA              YES, BRANCH TO LOOK FOR EMPTY        39000021
*                                       AREA                            39100021
         LA    WORKR,ERR0925       NO,INDICATE ERROR MSG TO USE         39150021
*                                       IF DISPLAY CAN'T BE PUT         39160021
*                                       IN MSG STREAM                   39170021
MSGSTRM  EQU   *                                                        39200021
*/*MSGSTRM: D (YES,ERREXIT,NO,%CHKMSG) MONITOR COMMAND */               39300021
         CLI   XAN,MN              ARE WE WORKING ON A MONITOR          39400021
         BCR   EQ,WORKR            YES, BRANCH TO ERROR ROUTINE         39500021
*/*%CHKMSG: D (YES,%INDZ,NO,ERREXIT) MESSAGE STREAM ON CONSOLE */       39600021
         TM    UCMDISP,UCMDISPE+UCMDISPF MSG STREAM ON CONSOLE          39700021
         BCR   NONEON,WORKR        NO,  BRANCH TO ERROR ROUTINE         39800021
*/*%INDZ: P (,SDEXIT) INDICATE MESSAGE STREAM IN XSA */                 39900021
         MVI   XASDID,Z            INDICATE MSG STREAM IN XSA           40000021
         B     SDEXIT              EXIT                                 40100021
         SPACE                                                          40300021
MTAREA   EQU   *                   LOOK FOR BOTTOM-MOST EMPTY           40400021
*                                       AREA (SACBBASE ALREADY          40500021
*                                       POINTS TO FIRST SACB)           40600021
*/*MTAREA: D (YES,MTFOUND,NO,STATIC) ANY EMPTY AREA */                  40700021
CONTSRCH EQU   *                                                        40800021
         TM    DCMASACB,DCMAUSE    DOES SACB DEFINE AN AREA             40900021
         BNO   STATIC              NO, BRANCH TO LOOK FOR A             41000021
*                                       STATIC DISPLAY TO OVERLAY       41100021
         TM    DCMAFLG1,DCMADISP   Q. AREA CONTAIN DISPLAY              41200021
         BO    PTNEXT              YES, LOOK FOR ANOTHER AREA           41250021
         CLC   DCMAMT(E2),C0       Q. AREA RESERVED FOR MONITOR         41260021
         BNE   PTNEXT              YES, LOOK FOR ANOTHER AREA           41270021
MTFOUND  EQU   *                   EMPTY AREA FOUND TO USE              41282021
*/*MTFOUND: P (,SETUP) PUT ID OF BOTTOMMOST IN XSA */                   41284021
         MVC   XASDID(L'DCMAID),DCMAID PUT ID OF AREA FOUND IN          41286021
*                                       XSA                             41288021
         B     SETUP               BRANCH TO SET UP FOR DISPLAY         41288421
PTNEXT   EQU   *                                                        41290021
         L     SACBBASE,DCMACBNX   POINT TO NEXT SACB                   41400021
         LTR   SACBBASE,SACBBASE   ANY MORE SACB'S                      41500021
         BNZ   CONTSRCH            YES, BRANCH TO CONTINUE SEARCH       41600021
         SPACE                                                          42400021
STATIC   EQU   *                   LOOK FOR THE OLDEST STATIC           42500021
*                                       DISPLAY (IF NO TIMER IN         42600021
*                                       SYSTEM, TIME STAMPS ARE         42700021
*                                       ZERO, THE BOTTOM-MOST           42800021
*                                       STATIC DISPLAY WILL BE          42900021
*                                       OVERLAYED)                      43000021
*/*STATIC: D (YES,DONE,NO,MSGSTRM) ANY STATIC DISPLAY */                43100021
         SR    WORKR,WORKR         ZERO REG TO HOLD POINTER TO          43200021
*                                       SACB OF OLDEST DISPLAY          43300021
         L     SACBBASE,DCMADSDS   POINT TO FIRST SACB                  43400021
NEXT     EQU   *                                                        43500021
         TM    DCMASACB,DCMAUSE    DOES SACB DEFINE AN AREA             43600021
         BZ    DONE                NO, BRANCH TO PUT DISPLAY IN         43700021
*                                       CONSOLE'S MSG STREAM            43800021
         CLC   DCMAMT(E2),C0       Q. AREA RESERVED FOR MONITOR         43850021
         BE    STFOUND             NO, BRANCH TO LOOK AT TIME           44100021
*                                       STAMP                           44200021
UPDATE   EQU   *                                                        44300021
         L     SACBBASE,DCMACBNX   GET POINTER TO NEXT SACB             44400021
         LTR   SACBBASE,SACBBASE   ANY MORE SACB'S                      44500021
         BNZ   NEXT                YES, BRANCH TO LOOK AT NEXT          44600021
*                                       SACB                            44700021
         B     DONE                BRANCH WHEN TIME STAMP OF            44800021
*                                       EVERY DISPLAY HAS BEEN          44900021
*                                       LOOKED AT                       45000021
         SPACE                                                          45100021
STFOUND  EQU   *                   AREA CONTAINING STATIC DISPLAY       45200021
*                                       FOUND                           45300021
         LTR   WORKR,WORKR         IS THIS FIRST STATIC FOUND           45400021
         BNZ   AROUND              NO, BRANCH AROUND                    45500021
         LR    WORKR,SACBBASE      YES, SAVE ITS ADDRESS                45600021
         B     UPDATE              BRANCH TO UPDATE SACB ADDRESS        45700021
AROUND   EQU   *                   SACB ADDRESS PREVIOUSLY SAVED        45800021
         CLC   DCMATIME(L'DCMATIME),DCMATIME-DCMACB(WORKR)  IS          45900021
*                                       THIS DISPLAY OLDER THAN         46000021
*                                       THE ONE SAVED                   46100021
         BH    UPDATE              NO, LOOK AT NEXT SACB                46200021
         LR    WORKR,SACBBASE      YES, SAVE ADDRESS OF THIS SACB       46300021
         B     UPDATE              BRANCH TO LOOK AT NEXT SACB          46400021
DONE     EQU   *                                                        46500021
*/*DONE: P (,SETUP) PUT ID OF OLDEST IN XSA */                          46600021
         LTR   WORKR,WORKR         WAS ANY STATIC DISPLAY FOUND         46700021
         BNZ   PUTOLD              YES, GO PUT ID OF OLDEST IN          46750021
*                                       XSA                             46760021
         LA    WORKR,ERR0913       NO, INDICATE ERROR MSG TO USE        46770021
*                                       IF DISPLAY CAN'T BE PUT         46780021
*                                       IN MSG STREAM                   46790021
         B     MSGSTRM             GO TRY TO PUT THE DISPLAY            46800021
*                                       IN THE MESSAGE STREAM           46900021
PUTOLD   EQU   *                                                        46950021
         LR    SACBBASE,WORKR      YES, BASE SACB FOR AREA              47000021
*                                       CONTAINING OLDEST               47100021
*                                       DISPLAY                         47200021
         MVC   XASDID(L'DCMAID),DCMAID  PUT AREA ID IN XSA              47300021
         B     SETUP               BRANCH TO SET UP FOR DISPLAY         47400021
         EJECT                                                          47500021
*********************************************************************** 47600021
*                                                                     * 47700021
* FIND AND BASE UCM ENTRY SUBROUTINE                                  * 47800021
*    INPUT - REG1 - CONSOLE ID, RIGHT JUSTIFIED                       * 47900021
*                   (HIGH ORDER BYTES MUST BE ZERO)                   * 48000021
*    OUTPUT - POINTER TO UCM ENTRY SPECIFIED BY CONSOLE ID IN         * 48100021
*                   REGISTER UCMEBASE                                 * 48200021
*    REGISTER USAGE - DESTROYS CONTENTS OF FOLLOWING REGS --          * 48300021
*                   REG0, REG1, UCMEBASE                              * 48400021
*                   LINKR IS RETURN REGISTER                          * 48500021
*                                                                     * 48600021
*********************************************************************** 48700021
         SPACE 2                                                        48800021
FINDUCME EQU   *                                                        48900021
         L     UCMEBASE,UCMVEA     POINT TO FIRST ENTRY                 49000021
         BCTR  REG1,ZERO           SUBTRACT ONE FROM CONSOLE ID         49100021
         M     REG0,UCMVEZ         MULTIPLY ENTRY SIZE BY REDUCED       49200021
*                                       ID                              49300021
         AR    UCMEBASE,REG1       POINT TO DESIRED UCM ENTRY           49400021
         BR    LINKR               RETURN FROM SUBROUTINE               49500021
         EJECT                                                          49600021
*********************************************************************** 49700021
*                                                                     * 49800021
* FIND AND BASE SACB SUBROUTINE                                       * 49900021
*    GIVEN A PARTICULAR CRT CONSOLE AND A ONE CHARACTER AREA ID       * 50000021
* THIS SUBROUTINE FINDS AND BASES THE SCREEN AREA CONTROL BLOCK       * 50100021
* (SACB) WHICH MATCHES THAT ID.  IF NONE IS FOUND, A ZERO IS          * 50200021
* RETURNED AS THE BASE.                                               * 50300021
*    INPUT - REG1 - ONE CHARACTER AREA ID IN LOW ORDER BYTE           * 50400021
*                   (HIGH ORDER BYTES MUST BE ZERO)                   * 50500021
*            UCMEBASE - ADDRESS OF UCM ENTRY OF A CRT CONSOLE         * 50600021
*    OUTPUT - SACBBASE - ADDRESS OF SACB WITH MATCHING ID             * 50700021
*                   (ZERO IF NO MATCH)                                * 50800021
*    REGISTER USAGE - DESTROYS CONTENTS OF FOLLOWING REGS --          * 50900021
*                   REG0, SACBBASE, RDCMBASE                          * 51000021
*                   LINKR IS RETURN REGISTER                          * 51100021
*                                                                     * 51200021
*********************************************************************** 51300021
         SPACE 2                                                        51400021
FINDSACB EQU   *                                                        51500021
         SR    REG0,REG0           CLEAR REG                            51600021
         L     RDCMBASE,UCMXB      GET RESIDENT DCM ADDRESS             51700021
         L     SACBBASE,DCMADSDS   GET FIRST SACB ADDRESS               51800021
CONTINUE EQU   *                                                        51900021
         LTR   SACBBASE,SACBBASE   ANY MORE SACB'S                      52000021
         BCR   NOMORE,LINKR        NO, RETURN FROM SUBROUTINE           52100021
         TM    DCMASACB,DCMAUSE    DOES SACB DEFINE AN AREA             52200021
         BNO   ENDOSACB            NO, BRANCH TO RETURN                 52300021
         IC    REG0,DCMAID         GET ID FROM SACB                     52400021
         CR    REG0,REG1           COMPARE WITH PASSED ID               52500021
         BCR   MATCH,LINKR         EQUAL, RETURN FROM SUBROUTINE        52600021
         L     SACBBASE,DCMACBNX   NOT EQUAL, GET NEXT SACB             52700021
         B     CONTINUE            CONTINUE SEARCH                      52800021
ENDOSACB EQU   *                                                        52900021
         SR    SACBBASE,SACBBASE   INDICATE NO SACB MATCH FOUND         53000021
         BR    LINKR               RETURN FROM SUBROUTINE               53100021
         EJECT                                                          53200021
*                             ERROR EXITS                               53300021
         SPACE 2                                                        53400021
ERR04    EQU   *                                                        53500021
         MVI   XAE,MSG04           INDICATE MAJOR ERROR CODE            53600021
         B     ERREXIT             BRANCH TO ERROR EXIT                 53700021
         SPACE                                                          53800021
ERR0912  EQU   *                                                        53900021
         MVI   XASTSAVE,MSG0912    INDICATE MINOR ERROR CODE            54000021
         B     ERR09               BRANCH TO GET MAJOR CODE             54100021
ERR0913  EQU   *                                                        54200021
         MVI   XASTSAVE,MSG0913    INDICATE MINOR ERROR CODE            54300021
         B     ERR09               BRANCH TO GET MAJOR CODE             54400021
ERR0914  EQU   *                                                        54500021
         MVI   XASTSAVE,MSG0914    INDICATE MINOR ERROR CODE            54600021
         B     ERR09               BRANCH TO GET MAJOR CODE             54700021
ERR0925  EQU   *                                                        54800021
         MVI   XASTSAVE,MSG0925    INDICATE MINOR ERROR CODE            54900021
ERR09    EQU   *                                                        55000021
         MVC   XASTSAVE+E1(E3),XAL+E1  MOVE OPERAND POINTER IN          55100021
         MVI   XAE,MSG09           INDICATE MAJOR ERROR CODE            55200021
         B     ERREXIT             BRANCH TO ERROR EXIT                 55300021
         SPACE                                                          55400021
ERR1221  EQU   *                                                        55500021
         MVI   XASTSAVE,MSG1221    INDICATE MINOR ERROR CODE            55600021
ERR12    EQU   *                                                        55700021
         MVI   XAE,MSG12           INDICATE MAJOR ERROR CODE            55800021
         SPACE                                                          55900021
ERREXIT  EQU   *                                                        56000021
*/*ERREXIT: D (YES,DERREXIT,NO,%RTMSG) DISPLAY COMMAND */               56100021
         MVC   XAX+3(E2),RTMSG     XCTL TO ROUTING MSG MODULE           56200021
         CLI   XAN,D               Q. DISPLAY                           56300021
         BE    DERREXIT            YES, BRANCH                          56400021
         CLI   XAN,DU              Q. DISPLAY UNITS                     56500021
         BE    DERREXIT            YES, BRANCH                          56600021
*/*%RTMSG: R IEE5603D */                                                56700021
         B     XCTL                BRANCH TO XCTL                       56800021
         SPACE                                                          56900021
DERREXIT EQU   *                                                        57000021
*/*DERREXIT: P (,%RTMSG) TURN OFF REGION BUSY BIT IF TURNED ON FOR THIS 57100021
*/* COMMAND */                                                          57200021
         TM    XASSDS,XASSDS3      WAS REGION BUSY BIT TURNED ON       X57300021
                                        FOR THIS COMMAND                57400021
         BO    XCTL                NO, XCTL                             57500021
*                                  YES, TURN OFF REGION BUSY BIT       X57600021
                                        SINCE COMMAND IS BEING         X57700021
                                        REJECTED                        57800021
         USING DCVT,WORKR                                               57900021
         L     WORKR,PTRCVT        GET POINTER TO CVT                   58000021
         L     WORKR,CVTMSER       GET POINTER TO BASEA                 58100021
         USING BASE,WORKR                                               58200021
         NI    BASFL,XFF-BADSP     TURN OFF REGION BUSY BIT             58300021
         B     XCTL                BRANCH TO XCTL                       58400021
         DROP  WORKR                                                    58500021
         SPACE 2                                                        58550021
ERRRT    EQU   *                                                        58560021
*/*ERRRT: R IEE0503D */                                                 58570021
         MVI   XAE,MSGCINVD        MOVE IN ERROR CODE                   58580021
         MVC   XAX+E3(E2),MSGMOD   INDICATE EXIT TO MESSAGE MODULE      58590021
         B     XCTL                XCTL                                 58592021
         EJECT                                                          58600021
*********************************************************************** 58700021
*                                                                     * 58800021
*                        MAINTAINANCE AREA                            * 58900021
*                                                                     * 59000021
*********************************************************************** 59100021
         SPACE                                                          59200021
PATCH    DC    CL64'***PATCH AREA-IEE7603D***'                   YM0055 59300021
         EJECT                                                          59400021
*********************************************************************** 59500021
*                                                                     * 59600021
*                             CONSTANTS                               * 59700021
*                                                                     * 59800021
*********************************************************************** 59900021
         SPACE 2                                                        60000021
C0       DC    H'0'                CONSTANT                             60050021
HFOUR    DC    H'4'                CONSTANT                   MG  M2091 60100021
         DS    0H                  TO ALIGN F'S                         60350021
FFFF     DC    X'FFFF'             HALFWORD OF F'S                      60360021
         SPACE                                                          60500021
* MODULE NAMES FOR XCTL -- IGCXX03D -- WHERE XX IS AS FOLLOWS           60600021
MSGMOD   DC    C'05'               SVC 34 MESSAGE MODULE                60650021
CSCB     DC    C'08'               CSCB CREATION ROUTINE - EXIT         60800021
*                                       FOR DISPLAY AND MONITOR         60900021
PMHNDLR  DC    C'55'               STOPMN HANDLER, SECOND LOAD          61000021
RTMSG    DC    C'56'               ROUTING MESSAGE MODULE               61100021
DROUTER  DC    C'35'               DISPLAY COMMAND ROUTER         M0776 61150021
         EJECT                                                          61200021
*********************************************************************** 61300021
*                                                                     * 61400021
*                             EQUATES                                 * 61500021
*                                                                     * 61600021
*********************************************************************** 61700021
         SPACE 2                                                        61800021
ZERO     EQU   0                   ZERO                                 61900021
E0       EQU   0                   CONSTANT                             62000021
E1       EQU   1                   CONSTANT                             62100021
E2       EQU   2                   CONSTANT                             62200021
E3       EQU   3                   CONSTANT                             62300021
F0       EQU   X'F0'               CONSTANT                             62400021
XFF      EQU   X'FF'               TO TURN OFF BITS                     62500021
OFF      EQU   0                   SWITCH OFF                           62600021
ON       EQU   1                   SWITCH ON                            62700021
EQUAL    EQU   C'='                EQUAL SIGN FOR KEYWORD PARAMETER     62800021
BLANK    EQU   C' '                BLANK                                62900021
COMMA    EQU   C','                COMMA                                63000021
Z        EQU   C'Z'                Z - ID OF MESSAGE STREAM AREA        63100021
NULL     EQU   X'00'               CODE INDICATES NO AREA               63200021
*                                       SPECIFIED OR DEFAULT            63300021
*                                       PROVIDED BY ROUTE               63400021
NIBBLE   EQU   4                   4 BITS                               63500021
BYTE     EQU   8                   8 BITS                               63600021
BYT2NIB1 EQU   20                  TWO AND A HALF BYTES (20 BITS)       63700021
DBLWORD  EQU   8                   LENGTH OF A DOUBLE WORD              63800021
NOMORE   EQU   8                   BRANCH ON ZERO                       63900021
MATCH    EQU   8                   BRANCH ON EQUAL                      64000021
NONEON   EQU   8                   BRANCH ON ZERO                       64050021
EQ       EQU   8                   BRANCH ON EQUAL                      64060021
         SPACE                                                          64100021
K        EQU   X'90'               VERB CODE FOR K (CONTROL)            64200021
D        EQU   X'68'               VERB CODE FOR D (DISPLAY)            64300021
DU       EQU   X'50'               VERB CODE FOR D U (DISPLAY          X64400021
                                        UNITS)                          64500021
MN       EQU   X'64'               VERB CODE FOR MN (MONITOR)           64600021
PM       EQU   X'38'               VERB CODE FOR PM (STOPMN)            64700021
         SPACE                                                          64800021
SECCHAR  EQU   1                   SECOND CHARACTER OF A FIELD          64900021
THRDCHAR EQU   2                   THIRD CHARACTER OF A FIELD           65000021
PTRCVT   EQU   16                  LOCATION OF POINTER TO CVT           65100021
A        EQU   C'A'                OPERAND FOR ACTIVE                   65200021
LGTHHDR  EQU   4                   LENGTH OF SVC 34 PARAMETER LIST      65300021
*                                       HEADER                          65400021
LNGTHCC  EQU   2                   LENGTH OF EBCDIC CONSOLE ID          65500021
LNCC     EQU   X'1'                LENGTH OF CONSOLE ID (IN HEX)        65600021
         SPACE                                                          65700021
* ERROR MESSAGE CODES                                                   65800021
MSG04    EQU   04                  IEE156I CM INVALID OPERAND -         65900021
MSG08    EQU   08                  IEE345I CM AUTHORITY INVALID         66000021
MSG09    EQU   09                  IEE921I CM OP REJECTED               66100021
MSG0912  EQU   12                       DISPLAY ALREADY EXISTS          66200021
MSG0913  EQU   13                       DISPLAY AREA BUSY               66300021
MSG0914  EQU   14                       NO MONITOR TO STOP              66400021
MSG0925  EQU   25                       NEEDS DISPLAY AREA              66500021
MSG12    EQU   12                  IEE926I L=CCA OPERAND INVALID        66600021
MSG1218  EQU   18                       CCA NOT AN AREA                 66700021
MSG1219  EQU   19                       CC NOT A CONSOLE                66800021
MSG1220  EQU   20                       CC FULL CAPABILITY              66900021
MSG1221  EQU   21                       DYNAMIC DISPLAY IN AREA         67000021
         SPACE                                                          67050021
MSGCINVD EQU   05                  COMMAND INVALID                      67060021
         EJECT                                                          67100021
DXSA     DSECT                                                          67200021
         IEEXSA                                                         67300021
         SPACE 2                                                        67400021
* THE XAP AND XAD FIELDS OF THE XSA ARE USED AS A DOUBLE WORD           67500021
*     WORK AREA IN THIS MODULE AND ARE REINITIALIZED BEFORE EXIT        67600021
         SPACE                                                          67700021
* THE XAS FIELD OF THE XSA IS USED AS FOLLOWS IN THIS MODULE            67800021
         ORG   XAS                                                      67900021
XASCID   DS    X                   CONSOLE ID                           68000021
XASDID   DS    C                   DISPLAY AREA ID                      68100021
XASSDS   DS    X                   SDS SWITCHES                         68200021
XASSDS1  EQU   X'80'               THIS COMMAND IS A STATUS            X68300021
                                        DISPLAY                         68400021
XASSDS2  EQU   X'40'               L OPERAND IS SPECIFIED ON           X68500021
                                        COMMAND                         68600021
XASSDS3  EQU   X'20'               DONT TURN OFF REGION BUSY BIT        68700021
XASPLS3  DS    X                   RESERVED                             68800021
XASTSAVE DS    X                   ERROR CODE -- MINOR                  68900021
         DS    XL3                 POINTER TO INVALID OPERAND           69000021
         EJECT                                                          69100021
DUCM     DSECT                                                          69200021
         IEECUCM                                                        69300021
         EJECT                                                          69400021
DRDCM    DSECT                                                          69500021
         IEECRDCM DSECT=YES                                             69600021
         EJECT                                                          69700021
         IEEBASEA                                                       69800021
         EJECT                                                          70200021
DCVT     DSECT                                                          70300021
         CVT                                                            70400021
         EJECT                                                          70500021
*/*IEE7603D: END */                                                     70600021
         END                                                            70700021
