IEE7703D CSECT                                                          00200021
*/*IEE7703D: CHART */                                                   00400021
         SPACE 2                                                        00600021
*    THIS ROUTINE WAS CREATED FOR STATUS DISPLAY SUPPORT,LINE ITEM      00800021
*    21002, OS RELEASE 21.                                              01000021
         TITLE 'IEE7703D IGC7703D SVC 34 K M COMMAND LOAD 4'            01200021
*/*HEADER                                                               01400021
*/*         CHART 77    IEE7703D    IGC7703D  K M CONTROL COMMAND       01600021
*/*MODULE FOR SVC 34 ROUTINE */                                         01800021
         EJECT                                                          02000021
*********************************************************************** 02200021
*                                                                     * 02400021
* STATUS                                                              * 02600021
*    CHANGE LEVEL=0                                                   * 02800021
*                                                                     * 03000021
* FUNCTION                                                            * 03200021
*    TO HANDLE K M  CONTROL COMMAND WHICH CAN BE HANDLED              * 03400021
*    WITHOUT  REFERENCING  THE TRANSIENT DCM (UNLESS                  * 03600021
*    TARGET CONSOLE IS A GRAPHIC DEVICE).                             * 03800021
*    TO HANDLE K V CONTROL COMMAND WHICH CAN ALSO BE HANDLED          * 04000021
*    WITHOUT REFERENCE TO THE TRANSIENT DCM                           * 04200021
*                                                                     * 04400021
* ENTRY POINT                                                         * 04600021
*    IEE7703D (CSECT)                                                 * 04800021
*    IGC7703D LOAD MODULE                                             * 05000021
*                                                                     * 05200021
* INPUT                                                               * 05400021
*    REG 2 POINTS TO XSA ( REG LEFT UNTOUCHED BY THIS MOD.)           * 05600021
*    REG 14 CONTAINS RETURN ADDRESS                                   * 05800021
*                                                                     * 06000021
* OUTPUT                                                              * 06200021
*       1. K M,UTME=NNN  - TIME FIELD IN UCM IS RESET                 * 06400021
*       2. K M,REF OR K M   -MASTER CONSOLE INFO. IS DISPLAYED        * 06600021
*       3. K V,USE=FC OR SD OR MS - THE PROPER BITS ARE SET IN THE    * 06800021
*          UCM ENTRY TO INDICATE THE CONSOLE STATE REQUESTED          * 07000021
*                                                                     * 07200021
* NOTE:  ALL INFORMATION IS DISPLAYED IN THE ENTRY AREA IF TARGET     * 07400021
*        IS A GRAPHIC CONSOLE, ELSE IT IS ISSUED VIA WTO              * 07600021
*                                                                     * 07800021
* EXTERNAL REFERENCES                                                 * 08000021
*    WTO                                                              * 08200021
*    GETMAIN                                                          * 08400021
*    FREEMAIN                                                         * 08600021
*    XCTL                                                             * 08800021
*    POST                                                             * 09000021
*                                                                     * 09200021
* EXITS,NORMAL                                                        * 09400021
*    BR   14                                                          * 09600021
*    IEE5603D  TO PUT OUT A MESSAGE (VIA XCTL)                        * 09800021
*                                                                     * 10000021
* EXITS,ERROR                                                         * 10200021
*     IEE5603D TO PROCESS ERROR MESSAGES                              * 10400021
*                                                                     * 10600021
* ATTRIBUTES                                                          * 10800021
*    REFRESHABLE, PRIVILEGED, TYPE 4 SVC                              * 11000021
*                                                                     * 11200021
* TABLES/WORK AREAS                                                   * 11400021
*    UCM, RDCM, XSA ,TDCM                                             * 11600021
*                                                                     * 11800021
*********************************************************************** 12000021
         EJECT                                                          12200021
*********************************************************************** 12400021
*                                                                       12600021
*    REGISTERS                                                          12800021
*                                                                       13000021
*********************************************************************** 13200021
RETURN   EQU   14                  SUBROUTINE RETURN REG                13400021
MYBASE   EQU   13                  THIS RTN'S BASE REG                  13600021
SACBPT   EQU   7                   SACB BASE REG                        13800021
UCMBASE  EQU   12                  UCM BASE REG                         14000021
RB       EQU   11                  SUBROUTINE BRANCH REG                14200021
RDCMBASE EQU   10                  RESIDENT DCM BASE REG                14400021
TDCMBASE EQU   9                   TRANSIENT DCM BASE REG               14600021
UCMEBASE EQU   8                                                        14800021
X6       EQU   6                   WORK REG                             15000021
PARMREG  EQU   2                   PARAMETER LIST BASE REG              15200021
X5       EQU   5                   WORK REG                             15400021
KOPS     EQU   4                   OPERAND POINTER                      15600021
R0       EQU   0                   WORK REG                             15800021
R1       EQU   1                   WORK REG                             16000021
R3       EQU   3                   CVT PREFIX REG                       16200021
R4       EQU   4                   WORK REG                             16400021
R5       EQU   5                   WORK REG                             16600021
RE       EQU   14                                                       16800021
RF       EQU   15                 MCSUCM BASE REG                       17000021
*                                                                       17200021
*     ERROR MESSAGE FLAG BIT SETTINGS                                   17400021
*                                                                       17600021
IEE931I  EQU   X'0E'               CORE NOT AVAILABLE                   17800021
IEE156I  EQU   X'04'               INVALID OP                           18000021
OPTIONS  EQU   X'02'               OPTIONS MSG TO WRITE                 18200021
IEE921I2 EQU   X'0B'               NO TIMER                             18400021
IEE921I  EQU   X'09'               REJECTED CMD-TIMER NOT WORKING       18600021
IEE926I  EQU   X'0C'               L OPERAND INVALID                    18650021
IEE345I  EQU   X'08'               INVALID AUTHORITY                    18800021
ERR28    EQU   X'1C'               DEVICE NOT SUPPORTED                 18850021
ERR29    EQU   X'1D'               CC OUTPUT ONLY                       18900021
HARDBIT  EQU   X'04'               TEST FOR OTHER THAN GRAPHIC DEVICES  18950021
IO2260   EQU   C'R'                NAME OF 2260 I/O RTN                 18960021
SIGN     EQU   X'FC'               TO CONVERT EBCDIC CHAR TO SIGN       19000021
MCSMASK  EQU   X'41'               ID PASSED + QUEUE BY ID              19200021
N0       EQU   0                   FIELD INCREMENT                      19400021
N1       EQU   1                   FIELD INCREMENT                      19600021
N2       EQU   2                   FIELD INCREMENT                      19800021
N3       EQU   3                   FIELD INCREMENT                      20000021
N4       EQU   4                   FIELD INCREMENT                      20200021
N5       EQU   5                   FIELD INCREMENT                      20400021
N6       EQU   6                   FIELD INCREMENT                      20600021
N7       EQU   7                   FIELD INCREMENT                      20800021
N8       EQU   8                   FIELD INCREMENT                      21000021
N9       EQU   9                   FIELD INCREMENT                      21200021
NC       EQU   12                  FIELD DISPLACEMENT                   21400021
N21      EQU   21                  FIELD INCREMENT                      21600021
N23      EQU   23                  FIELD DISPLACEMENT                   21800021
N28      EQU   28                  FIELD DISPLACEMENT                   22000021
N32      EQU   32                  MSG SIZE FOR WTO                     22200021
N255     EQU   255                 FIELD INCREMENT                      22400021
PTRCVT   EQU   16                  ADDR OF CVT TABLE                    22600021
BLANK    EQU   C' '                BLANK CHAR                           22800021
ZERO     EQU   X'00'                                                    23000021
NOHDCPY  EQU   X'04'               BIT TO SIGNIFY NO HARD COPY          23200021
CF0      EQU   X'F0'               CONSTANT                             23400021
COMMA    EQU   C','                CONSTANT                             23600021
POSTCOD1 EQU   X'FD'               CODE USED IN POSTING UCM ECB         23800021
VCHAR    EQU   C'V'                VARY COMMAND CONSTANT                23850021
*********************************************************************** 24000021
         EJECT                                                          24200021
*********************************************************************** 24400021
*                                                                       24600021
*    ESTABLISH ADDRESSABILITY                                           24800021
*                                                                       25000021
*********************************************************************** 25200021
*/* E IEE7703D */                                                       25400021
*                                                                       25600021
*    ON ENTRY, REGISTER 2 CONTAINS ADDRESS OF XSA                       25800021
*                                                                       26000021
*/*BASERGS: P (,%NXTSTUP) BASE REGS FOR CVT,UCM,CVT PREFIX,DCM */       26200021
         BALR  MYBASE,N0           ESTABLISH ROUTINE 'S                 26400021
         USING *,MYBASE            BASE REGISTER                        26600021
         USING FAUXSA,PARMREG      ESTABLISH XSA ADDRESSABILITY         26800021
         LA    UCMBASE,PTRCVT      GET CVT POINTER                      27000021
         L     UCMBASE,N0(UCMBASE) LOAD CVT POINTER                     27200021
         USING CVTSECT,UCMBASE     BASE CVT REG                         27400021
         L     UCMBASE,CVTCUCB GET UCM POINTER FROM CVT                 27600021
         USING PMUCM,UCMBASE       ESTABLISH UCM ADDRESSABILITY         27800021
*        NOTE: FOLLOWING 4 INSTRUCTIONS USED FOR TIMER MACRO            28000021
         LA    R3,N0(UCMBASE)      LOAD UCM PT                          28200021
         SH    R3,FOUR             DECR. BY 4                           28400021
         L     R3,N0(R3)           LOAD POINTER TO UCM PREFIX           28600021
         USING MCSUCM,R3           ESTABLISH UCM PREFIX BASE REG        28800021
         USING UCMLIST,UCMEBASE    BASE UCM ENTRY LIST                  29000021
         USING RDCM,RDCMBASE       ESTABLISH RDCM BASE REG              29200021
         USING DCMDSECT,TDCMBASE   BASE TDCM REG                        29400021
         USING DCMACB,SACBPT       BASE SACB REG                        29600021
         ST    RE,XAP              SAVE RETURN POINTER                  29800021
         MVC   XAU+N4(N4),XAS      SAVE TARGET INFO FOR LATER           30000021
         MVI   XAU+N3,ZERO         CLEAR MINOR FLAG BYTE                30200021
         SR    R1,R1               CLEAR REG                            30400021
         IC    R1,XASCID           LOAD TARGET ID                       30600021
*                                                                       30800021
*/*%NXTSTUP: S (,%VARYCDR) FINDUCME: GO FIND SOURCE UCME */             31000021
         BAL   RB,FINDUCME         FIND UCME SOURCE ENTRY ID            31200021
*                                                                       31400021
*      ANALYZE COMMAND TO SEE IF IT IS A K V,USE= COMMAND               31600021
*                                                                       31800021
         L     KOPS,XAL            LOAD PT TO OPERANDS                  32000021
         LA    KOPS,N0(KOPS)       CLEAR HIGH ORDER BYTE                32200021
         ST    KOPS,XAS+N4         SAVE CURSOR POSITION                 32400021
*/* %VARYCDR: D (YES,VALID,NO,CHKTIMER) IS THIS A K V COMMAND */        32600021
         CLI   N0(KOPS),VCHAR      IS THIS A VARY COMMAND               32800021
         BE    VALID               YES, BRANCH                          33000021
         SR    R1,R1               CLEAR REG                            33200021
         IC    R1,XAU              LOAD SOURCE ID                       33400021
         BAL   RB,FINDUCME         FIND UCME SOURCE ENTRY ID            33600021
*/*CHKTIMER: D (NO,IEE921,YES,CHKCONS) IS TIME FEATURE AVAILABLE        33800021
*/* */                                                                  34000021
CHKTIMER EQU   *                                                        34200021
         SR    R0,R0               CLEAR REG                            34400021
         TIME  DEC                                                      34600021
         LTR   R0,R0               IS TIME FEATURE AVAILABLE            34800021
         BZ    IEE921              NO--GO INDIC. ERROR                  35000021
*/*CHKCONS: D (NO,NOTMAST,YES,ANALYZE) IS THIS A MASTER CONSOLE */      35200021
CHKCONS  EQU   *                                                        35400021
         TM    UCMDISP,UCMDISPA    IS IT MASTER CONSOLE                 35600021
         BNO   NOTMAST             NO--ERROR                            35800021
*                                                                       36000021
*/*ANALYZE: D (YES,KMREFRTN,NO,%CONT) IS IT A K M,REF COMMAND */        36200021
         CLC   N0(N2,KOPS),KM         IS IT K M                         36400021
         BE    KMREFRTN            YES-HANDLE AS K M,REF                36600021
         CLC   N0(N6,KOPS),KMREF      IS IT K M,REF                     36800021
         BE    KMREFRTN            YES-HANDLE AS K M,REF                37000021
*/*%CONT: D (YES,TIMERTN,NO,BADKOP) IS IT K M,UTME= COMMAND */          37200021
         CLC   N0(N7,KOPS),KMUTME+N2  IS IT K M,UTME                    37400021
         BE    TIMERTN             YES-HANDLE TIMER                     37600021
*/*BADKOP: P (,STOREOP) INDICATE ERROR MSG IEE156I */                   37800021
BADKOP   EQU   *                                                        38000021
         MVI   XAE,IEE156I      NONE OF ABOVE,SO ITS BAD                38200021
*/*STOREOP: P (,ERRORMSG) STORE BAD OP PT IN XSA */                     38400021
STOREOP  EQU   *                                                        38600021
         ST    KOPS,XAS+N4                                              38800021
STOREOP2 EQU   *                                                        39000021
         MVC   XAS+N4(N1),XAU+N3       MOVE MINOR MSG FLAG BYTE         39200021
*/*ERRORMSG: P (,XCTL) SET UP TO XCTL TO SVC 34 MSG MOD */              39400021
ERRORMSG EQU   *                                                        39600021
         MVC   XAX+N3(N2),FIVESIX MOVE XSA SVC 34 MSG MOD. NAME         39800021
         MVC   XAS(N4),XAU+N4     RESTORE    SAVED TARGET INFO          40000021
*/*XCTL: R MESSAGE MOD IEE5603D */                                      40200021
XCTL     EQU   *                                                        40400021
         L     RETURN,XAP          RESTORE RETURN REG                   40600021
         XC    XAD(N4),XAD             ZERO DCB PT                      40800021
         LA    X5,XAX              LOAD NAME POINTER                    41000021
         ST    X5,XAP              RESTORE POINTER                      41200021
         XCTL  SF=(E,(2))         ISSUE XCTL                            41400021
*                                                                       41600021
*/*KMREFRTN: D (YES,GRAPHIC,NO,BUILDWTO) GRAPHIC CONSOLE */             41800021
*                                                                       42000021
KMREFRTN EQU    *                                                       42200021
         TM    UCMDISP,UCMDISPC    IS IT A GRAPHIC CONSOLE              42400021
*    IF NOT A GRAPHIC CONSOLE,ISSUE WTO FOR MESSAGE                     42600021
         BNO   BUILDWTO        GO BUILD MESSAGE                         42800021
*                                                                       43000021
*/*GRAPHIC: P (,%CON) SET MESSAGE UP IN ENTRY AREA */                   43200021
*                                                                       43400021
GRAPHIC  EQU   *                                                        43600021
         L     R1,DCMAENTR         LOAD ADDR OF ENTRY AREA              43800021
         MVI   N0(R1),BLANK        CLEAR ENTRY AREA                     44000021
         LH    R4,DCMLGNTH         LOAD LENGTH OF A LINE                44200021
         BCTR  R4,N0               DECREMENT LENGTH                     44400021
         BCTR  R4,N0               BY TWO                               44600021
         EX    R4,BLANKS           BLANK LINE ONE OF ENTRY AREA         44800021
         MVC   N0(N9,R1),KMUTME   MOVE COMMAND TO ENTRY AREA            45000021
*/*%CON: S (,IOEXIT) CONVERT: CONVERT TIME VALUE TO EBCDIC */           45200021
         BAL   RE,CONVERT         GO CONVERT TIME VALUE                 45400021
         MVC   N9(N3,R1),XAS      MOVE VALUE INTO MSG                   45600021
*/*IOEXIT: P (,ERRORMSG) INDICATE OPTIONS MESSAGE IN XAE */             45800021
IOEXIT   EQU   *                                                        46000021
         MVI   XAE,OPTIONS         SET OPTIONS MSG BIT                  46200021
         LA    R1,N9(R1)           SET CURSOR POSITION                  46400021
         ST    R1,XAS+N4           FOR MSG MODULE                       46600021
         B     ERRORMSG                                                 46800021
*/*TIMERTN: P (,TIMELOOP) POINT TO INPUT TIME VALUE */                  47000021
TIMERTN  EQU   *                                                        47200021
         SR    R1,R1               CLEAR REG                            47400021
         LA    KOPS,N7(KOPS) BUMP PAST M,UTME= PARAMS                   47600021
         ST    KOPS,XAD         SAVE PT IN CASE NUNBER IS BAD           47800021
*/*TIMELOOP: D (YES,CONVERT2,NO,%BUMPVAL) IS DIGIT A BLANK CHAR */      48000021
TIMELOOP EQU   *                                                        48200021
         CLI   N0(KOPS),BLANK      IS DIGIT A BLANK                     48400021
         BE    CONVERT2 NO. IS AT END                                   48600021
         TM    N0(KOPS),CF0  IS THIS A VALID DIGIT            MD  M2088 48650021
         BNO   TIMERR        BRANCH NO FOR ERROR              MD  M2088 48700021
*/*%BUMPVAL: P (,%CHKCNT) BUMP DIGIT PT AND COUNTER */                  48800021
         LA    KOPS,N1(KOPS) BUMP DIGIT PT                              49000021
         LA    R1,N1(R1)           BUMP DIGIT COUNTER                   49200021
*/*%CHKCNT: D (NO,TIMELOOP,YES,TIMERR) DIGIT COUNT GREATER THAN 3 */    49400021
         CH    R1,FOUR             MAX. NO. OF DIGITS IS 3              49600021
         BL    TIMELOOP            MORE DIGITS MAY BE LEFT              49800021
*/*TIMERR: P (,BADKOP) INDICATE INVALID OPERAND */                      50000021
TIMERR   EQU   *                                                        50200021
         L     KOPS,XAD            RESTORE BAD OP PT                    50400021
         B     BADKOP                                                   50600021
*/*CONVERT2: D (YES,PREPARE,NO,TIMERR) ANY VALUE SPECIFIED */           50800021
CONVERT2 EQU   *                                                        51000021
         LTR   R1,R1               ANY DIGITS SPECIFIED                 51200021
         BZ    TIMERR              NO--                                 51400021
*/*PREPARE: P (,LOOPMOVE) CLEAR XSA AREA FOR PACKING NUMBER */          51600021
         XC    XAS(N8),XAS         CLEAR AREA FOR PACK                  51800021
         LA    R5,XAS+N7           LOAD SAVE AREA ADDR                  52000021
*/*LOOPMOVE: P (,%CMPARIT) CONVERT NO. TO BINARY AND MULT. BY 100 */    52200021
LOOPMOVE EQU   *                                                        52400021
         BCTR  KOPS,N0             DECREMENT DIGIT POINTER              52600021
         MVC   N0(N1,R5),N0(KOPS)  MOVE A DIGIT                         52800021
         BCTR  R5,N0             DECREMENT DIGIT POINTER                53000021
         BCT   R1,LOOPMOVE         DECREMENT LOOP CONTROL REG           53200021
         PACK  XAS+N4(N4),XAS+N4(N4)  PACK THE DIGITS                   53400021
         NI    XAS+N7,SIGN         MAKE IT A LEGIT SIGN                 53600021
         CVB   R1,XAS              CONVERT NUMBER TO BINARY             53800021
         SR    R0,R0               CLEAR REG                            54000021
         M     R0,HUNS             MULTIPLY IT BY 100                   54200021
*/*%CMPARIT: D (YES,TIMERR,NO,%COMP999) IS NUMBER LESS THAN 3000 */     54400021
         C     R1,X3000           IS VALUE LESS THAN 3000               54600021
         BL    TIMERR              YES-ERROR                            54800021
*/*%COMP999: D (YES,TIMERR,NO,%SAVE) IS NUMBER GREATER THAN 9990 */     55000021
         C     R1,X99900           IS VALUE GREATER THAN 9990           55200021
         BH    TIMERR              YES-ERROR                            55400021
*    SAVE THE NEW TIME VALUE FOR KMUTME SYSTEM TIMER                    55600021
*/*%SAVE: P (,IOEXIT) STORE NEW VALUE IN UCMDTINT */                    55800021
         ST    R1,UCMDTINT         STORE TIME VALUE                     56000021
*   NOTE: ALWAYS RETURN TO SYSTEM WHEN VALUE HAS BEEN STORED            56200021
         B     BRANCH14            NO-                                  56400021
*    NOTE THE TIMER HAS NOT BEEN SET- ONLY, THE NEW VALUE HAS BEEN      56600021
*         INDICATED FOR STOP MONITOR OR START MONITOR ROUTINES.         56800021
*                                                                       57000021
*/*BUILDWTO: P (,%TSTCODE) DO GETMAIN FOR 32 BYTES */                   57200021
BUILDWTO EQU   *                                                        57400021
         LA    R0,N32             LOAD LENGTH OF CORE NEEDED            57600021
         LA    X6,XAS             GET ADDR OF A WORD IN CORE            57800021
         GETMAIN EC,LV=(0),A=(6),SP=255                                 58000021
*/*%TSTCODE: D (YES,%LOAD,NO,MSG931) WAS RETURN CODE GOOD */            58200021
         LTR   RF,RF              TEST RETURN CODE                      58400021
         BNZ   MSG931             ERROR IF NOT ZERO;MEANS NO CORE       58600021
*/*%LOAD: P (,%CONIT) SET UP WTO MESSAGE IEE922I */                     58800021
         L     X6,XAS              LOAD GETMAINED ADDR                  59000021
         LR    R1,X6               SET UP MSG POINTER                   59200021
         XC    N2(N2,R1),N2(R1)    CLEAR MCSFLAGS                       59400021
         OI    N2(R1),MCSMASK      ID PASSED AND QUEUE BY ID FLAGS      59600021
         OI    N3(R1),NOHDCPY      INDICATE NO HARD COPY                59800021
         MVI   N4(R1),BLANK        CLEAR WITH BLANKS                    60000021
         MVC   N5(N23,R1),N4(R1)   GETMAINED CORE                       60200021
         MVC   N4(N7,R1),IEE922I  MOVE MESSAGE NUMBER                   60400021
         LA    R0,N28             LOAD CORE ADDR OF MESSAGE             60600021
         STH   R0,N0(R1)          SAVE LENGTH OF WTO FOR I/O            60800021
         MVC   NC(N9,R1),KMUTME   MOVE COMMAND TO AREA                  61000021
*/*%CONIT: S (,ISSUEIT) CONVERT: CONVERT TIME VALUE TO EBCDIC */        61200021
         BAL   RE,CONVERT          GO CONVERT TIME VALUE                61400021
         MVC   N21(N3,R1),XAS    MOVE EBCDIC TIME VALUE                 61600021
         MVC   N28(N4,R1),DESCR       MOVE DESCRIPTOR CODE              61800021
         SR    R0,R0               CLEAR REG                            62000021
         IC    R0,XAU              GET UCMID                            62200021
*/*ISSUEIT: P (,BRANCH14) ISSUE WTO FOR IEE922I */                      62400021
         WTO   MF=(E,(R1))                                              62600021
BRANCH14 EQU   *                                                        62800021
         L     RETURN,XAP      RESTORE RETURN ADDRESS                   63000021
*/*BRANCH14: R RETURN TO CALLER VIA BR 14 */                            63200021
         BR    RETURN             GO BACK TO SYSTEM                     63400021
*/*MSG931: P (,ERRORMSG) INDICATE IN XAE ERROR MSG IEE931I */           63600021
MSG931   EQU   *                                                        63800021
         MVI   XAE,IEE931I      CORE NOT AVAILABLE                      64000021
         B     ERRORMSG            GO TO PUT OUT MSG                    64200021
*                                                                       64400021
*/* E CONVERT */                                                        64600021
CONVERT  EQU   *                                                        64800021
*/*CNVRT: P (,%RET1) LOAD UTME VALUE AND CONVERT TO EBCDIC */           65000021
         L     R5,UCMDTINT         LOAD UTME VALUE                      65200021
         SR    R4,R4               CLEAR REG                            65400021
         D     R4,HUNS             DIVIDE NUMBER BY HUNDRED             65600021
         CVD   R5,XAS         CONVERT TO DECIMAL                        65800021
         UNPK  XAS(N3),XAS+N6(N2) UNPACK NUMBER                         66000021
         OI    XAS+N2,CF0    FIX SIGN                                   66200021
*/*%RET1: R RETURN TO CALLER */                                         66400021
         BR    RE                                                       66600021
*                                                                       66800021
*/*NOTMAST: P (,ERRORMSG) INDICATE IN XAE ERROR MSG IEE345I */          67000021
NOTMAST  EQU   *                                                        67200021
         MVI   XAE,IEE345I         INDICATE NOT MASTER CONS.            67400021
         B     ERRORMSG                                                 67600021
*                                                                       67800021
*/*IEE921: P (,STOREOP) INDICATE NO TIMER FEATURE IN XAE AND MINOR FLAG 68000021
*/* */                                                                  68200021
IEE921   EQU   *                                                        68400021
         MVI   XAE,IEE921I       INDICATE NO TIMER FEATURE              68600021
         MVI   XAU+N3,IEE921I2     INDICATE NO TIMER                    68800021
         B     STOREOP                                                  69000021
         SPACE 3                                                        69200021
*/* VALID:   D (YES,%FC,NO,BADKOP)     IS THIS VARY CDR VALID */        69400021
VALID    EQU   *                                                        69600021
         LA    KOPS,N1(KOPS)       INCREMENT OPERAND POINTER            69650021
         CLI   N0(KOPS),COMMA      IS NEXT CHARACTER A COMMA            69700021
         BNE   BADKOP              BRANCH NO FOR ERROR                  69750021
         LA    KOPS,N1(KOPS)       INCREMENT OPERAND POINTER            69760021
         CLC   N0(N4,KOPS),USE     IS KEY WORD VALID                    69770021
         BNE   BADKOP              BRANCH NO FOR ERROR                  69780021
         TM    UCMDISP,UCMDISPA    IS THIS CONSOLE MASTER CONSOLE       69790021
         BO    NOTMAST             BRANCH YES FOR ERROR                 69792021
         TM    DCMDEVTY,DCMTY50    IS THIS DEVICE A 2250 -FROM RES. DCM 69794021
         BO    ERRHARD             BRANCH YES FOR ERROR                 69796021
         LA    KOPS,N4(KOPS)       INCREMENT OPERAND POINTER            69798021
         SPACE 3                                                        69798421
*/* %FC:    D (YES,SETFC,NO,%SD)      IS THIS VARY FULL CAPICITY */     69798821
         CLC   N0(N2,KOPS),FC      WAS FC SPECIFIED                     69800021
         BE    SETFC               BRANCH YES                           70000021
         SPACE 3                                                        70200021
*/* %SD:    D (YES,SETSD,NO,%MS)      IS THIS VARY STATUS DISPLAY */    70400021
         CLC   N0(N2,KOPS),SD      WAS SD SPECIFIED                     70600021
         BE    SETSD               BRANCH YES                           70800021
         SPACE 3                                                        71000021
*/* %MS:    D (YES,SETMS,NO,BADKOP)   IS THIS VARY MESSAGE STREAM */    71200021
         CLC   N0(N2,KOPS),MS      WAS MS SPECIFIED                     71400021
         BE    SETMS               BRANCH YES                           71600021
         B     BADKOP              GO SET ERROR CODE                    72400021
         SPACE 3                                                        72600021
*/* SETFC:  M (,SETPOST)              SET FLAGS IN UCM TO INDICATE NEW  72800021
*/*STATUS */                                                            73000021
SETFC    TM    UCMDISP,UCMDISPD    IS CONSOLE HDWARE OUTPUT ONLY        73200021
         BZ    FCCONS              BRANCH NO TO SET FLAGS               73400021
         TM    UCMSDS5,UCMSDS5G    IS CONSOLE REALLY OUTPUT ONLY        73450021
         BZ    OUTERROR            BRANCH YES FOR ERROR                 73500021
*        TURN OFF FLAGS IN UCM ENTRY. FLAGS ARE THE MESSAGE STREAM ONLY 73800021
*        ,STATUS DISPLAY ONLY, HARDWARE OUTPUT ONLY AND NOT HARDWARE    73810021
*        OUTPUT ONLY                                                    73820021
FCCONS   EQU   *                                                        73822021
         NI    UCMDISP,N255-UCMDISPF-UCMDISPG-UCMDISPD                  73830021
         NI    UCMSDS5,N255-UCMSDS5G NOT REALLY OUTPUT ONLY             73832021
         OI    UCMATR,UCMIF        INDICATE I/O STATUS TO MCS           73840021
         OI    UCMDISP,UCMDISPE    INDICATE I/O STATUS                  73850021
         B     SETPOST             BRANCH TO CLEAN UP                   74000021
         SPACE 3                                                        74200021
*/* SETSD:  M (,SETPOST)              SET FLAGS IN UCM TO INDICATE NEW  74400021
*/*STATUS */                                                            74600021
SETSD    OI    UCMDISP,UCMDISPG    SET STATUS DISP                      75200021
         NI    UCMDISP,N255-UCMDISPE-UCMDISPF NO LONGER FC OR MS        75250021
         B     SETOUT             BRANCH TO CLEAN UP                    75400021
         SPACE 3                                                        75600021
*/* SETMS:  M (,SETPOST)              SET FLAGS IN UCM TO INDICATE NEW  75800021
*/*STATUS */                                                            76000021
SETMS    EQU   *                                                        76050021
         SR    R0,R0               CLEAR REG                            76450021
         TIME  DEC                 ISSUE TIME MACRO TO CHECK TIMER      76500021
         LTR   R0,R0               IS TIMMER AVAILABLE                  76550021
         BZ    IEE921              BRANCH NO FOR ERROR                  76560021
         TM    UCMMODE,HARDBIT     ANY HARD COPY IN SYSTEM              76570021
         BO    ERRHARD             BRANCH NO FOR ERROR                  76580021
         OI    UCMDISP,UCMDISPF    NO, SET MSG STREAM                   76600021
         NI    UCMDISP,N255-UCMDISPE-UCMDISPG NO LONGER FC OR SD        76650021
SETOUT   EQU   *                                                        76700021
         NI    UCMATR,N255-UCMIF   INDICATE OUTPUT ONLY STATUS TO MCS   76710021
         TM    UCMSDS5,UCMSDS5G    IS DEVICE IN OUTPUT ONLY MODE        76720021
         BO    SETPOST             BRANCH YES                           76730021
         TM    UCMDISP,UCMDISPD    IS THIS AN OUTPUT DEVICE             76750021
         BO    SETPOST             BRANCH YES                           76760021
         OI    UCMDISP,UCMDISPD    FORCE OUTPUT ONLY WITH HDWARE        76770021
         OI    UCMSDS5,UCMSDS5G    SET OUTPUT ONLY BIT ON               76780021
*                                  I/O CAPABILITY                       76790021
*                                                                     * 76800021
* SET UP PARAMETER LIST FOR MODULE TO HANDLE SCREEN CONTROL           * 77000021
* ALSO, SET UP LIST TO HAVE DCM OPTION BITS SET IN TRANSIENT SECTION  * 77200021
* OF THE DCM                                                          * 77400021
*                                                                     * 77600021
         SPACE 3                                                        77800021
*/* SETPOST: S (,RETURN1) POST:       POST THE UCM'S ECB */             78000021
SETPOST  EQU   *                                                        78200021
         OI    DCMR3FLG,DCMSTSWT+DCMKVIP SET CHANGING STATUS FOR I/O    78400021
*                                  AND K V IN PROCESS IN RESD DCM       78450021
         POST  UCMECB,POSTCOD1     POST THE ECB                         78600021
         SPACE 3                                                        78800021
*/* RETURN1: R                        RETURN BR 14 */                   79000021
RETURN1  EQU   *                                                        79200021
         BR    RE                  RETURN TO CALLER                     79400021
OUTERROR EQU   *                                                        79450021
         MVI   XAU+N3,ERR29        SECOND ERROR CODE - OUTPUT ONLY      79500021
         MVI   XAE,IEE926I         ERROR CODE - L OPERAND INVALID       79550021
         B     STOREOP             BRANCH FOR ERROR EXIT                79560021
ERRHARD  EQU   *                                                        79570021
         MVI   XAU+N3,ERR28        SECOND ERROR CODE - DEVICE NOT       79580021
*                                  SUPPORTED                            79582021
         MVI   XAE,IEE921I         ERROR CODE - CM OP REJECTED          79590021
         B     STOREOP             BRANCH FOR ERROR MSG                 79592021
*                                                                       79600021
*/* E FINDUCME */                                                       79800021
*                                                                       80000021
*    FIND AND BASE UCM ENTRY SUBROUTINE                                 80200021
*    INPUT- REG 1-CONSOLE ID RIGHT JUSTIFIED, HIGH ORDER BYTES ZERO     80400021
*    OUTPUT-POINTER TO UCMENTRY SPECIFIED BY CONSOLE ID IN UCMEBASE REG 80600021
*    REG USAGE-DESTROYS CONTENTS OF: REG 0,1,UCMEBASE                   80800021
*                                                                       81000021
FINDUCME EQU   *                                                        81200021
*/*FINDIT: P (,DCMINIT) GET SOURCE UCME ADDRESS */                      81400021
         SR    R0,R0               CLEAR REG                            81600021
         L     UCMEBASE,UCMVEA     POINT TO FIRST ENTRY                 81800021
         BCTR  R1,ZERO             SUBTRACT ONE FROM CONSOLE ID         82000021
         M     R0,UCMVEZ           MULTIPLY ENTRY SIZE BY REDUCED ID    82200021
         AR    UCMEBASE,R1         POINT TO DESIRED UCM ENTRY           82400021
DCMINIT  EQU   *                                                        82600021
*/*DCMINIT: P (,%RET2) PRIME DCM, SACB POINTERS */                      82800021
         L     RDCMBASE,UCMXB           LOAD PT TO RDCM                 83000021
         L     SACBPT,DCMADSDS         LOAD SACB POINTER FROM RDCM      83200021
         L     TDCMBASE,N0(RDCMBASE)   LOAD PT TO TDCM                  83400021
*/*%RET2: R RETURN TO CALLER */                                         83600021
         BR    RB                  RETURN                               83800021
*                                                                       84000021
BLANKS   MVC   N1(N0,R1),N0(R1)   WITH BLANKS                           84200021
*                                                                       84400021
*      CONSTANTS                                                        84600021
FOUR     DC    H'4'                CONSTANT                             84800021
HUNS     DC    F'100'              CONSTANT                             85000021
X3000    DC    F'3000'             CONSTANT                             85200021
X99900   DC    F'99900'            CONSTANT                             85400021
DESCR    DC    B'00001000000000000000000000000000'  DESCR. + RT. CODE   85600021
FIVESIX  DC    C'56'               SVC 34 MSG MOD NAME                  85800021
IEE922I  DC    C'IEE922I'          MSG NAME                             86000021
KM       DC    C'M '                                                    86200021
KMREF    DC    C'M,REF '                                                86400021
KMUTME   DC    C'K M,UTME='                                             86600021
USE      DC    C'USE='             CONSTANT FOR VARY COMMAND            86800021
FC       DC    C'FC'               FULL CAPCITY CONSTANT                87000021
SD       DC    C'SD'               STATUS DISPLAY CONSTANT              87200021
MS       DC    C'MS'               MASTER CONSOLE CONSTANT              87400021
PATCH    DC    C'****PATCH AREA****'                                    87600021
PATCH2   DC    C'IEE7703D-TEST ONLY'                                    87800021
PATCH3   DC    36C' '                                                   88000021
*                                                                       88200021
*    ALL DSECTS FOLLOW THIS POINT                                       88400021
*                                                                       88600021
DCMDSECT DSECT                                                          88800021
         IEECBJH CODE=DI                                                89000021
         EJECT                                                          89200021
PMUCM    DSECT                                                          89400021
         IEECUCM                                                        89600021
RDCM     DSECT                                                          89800021
         IEECRDCM DSECT=YES                                             90000021
FAUXSA   DSECT                                                          90200021
         IEEXSA                                                         90400021
*                                                                       90600021
*  THE XAS FIELD OF THE XSA IS USED AS FOLLOWS IN THIS MODULE           90800021
*                                                                       91000021
         ORG   XAS                                                      91200021
XASCID   DS    X                   CONSOLE ID                           91400021
XASDID   DS    C                   DISPLAY AREA ID                      91600021
XASSDS   DS    X                   SDS SWITCHES                         91800021
XASSDS1  EQU   X'80'               THIS COMMAND IS A STATUS DISPLAY     92000021
XASSDS2  EQU   X'40'               L OPERAND IS SPECIFIED ON COMMAND    92200021
XASPLS3  DS    X                   RESERVED FOR FLAGS                   92400021
XASTSAVE DS    X                   ERROR CODE - MINOR                   92600021
         DS    XL3                 POINTER TO INVAL OPD OR CURSOR POSIT 92800021
CVTSECT  DSECT                                                          93000021
         CVT                                                            93200021
*********************************************************************** 93400021
*/*IEE7703D: END */                                                     93600021
         END                                                            93800021
