IEE7803D CSECT                                                          00200021
***                                                                     00600021
***  THIS ROUTINE WAS CREATED FOR STATUS DISPLAY SUPPORT,LINE ITEM      00800021
***  21002, OS RELEASE 21.                                              01000021
***                                                                     01200021
* A 370500-373600,616100-617700,858500                           SM4172 01210021
* D 372000,618000,858000                                         SM4172 01220021
         TITLE 'IEE7803D IGC7803D SVC 34 K C,D,ID COMMAND, LOAD 3 '     01400021
*********************************************************************** 01600021
*                                                                     * 01800021
* STATUS                                                              * 02000021
*    CHANGE LEVEL=0                                                   * 02200021
*                                                                     * 02400021
* FUNCTION                                                            * 02600021
*    TO PROCESS K C,D,MLWTOID CONTROL COMMAND WHICH CANCELS AN INLINE * 02800021
*    MLWTO BY PURGING THE UNDISPLAYED MINORS FROM THE OUTPUT QUEUE    * 02900021
*    WITHOUT  REFERENCING  THE TRANSIENT DCM. SYNTAX CHECK THE K A    * 03000021
*    COMMAND AND PASS CONTROL TO ADDITIONAL LOADS TO PROCESS THE CDR  * 03050021
*                                                                     * 03200021
* ENTRY POINT                                                         * 03400021
*    IEE7803D (CSECT)                                                 * 03600021
*    IGC7803D LOAD MODULE                                             * 03800021
*                                                                     * 04000021
* INPUT                                                               * 04200021
*    REG 2 POINTS TO XSA (IT'S LEFT UNTOUCHED BY THIS MODULE)         * 04400021
*    REG 14 CONTAINS RETURN ADDRESS                                   * 04600021
*                                                                     * 04800021
* OUTPUT                                                              * 05000021
*    THE PURGING OF THE UNDISPLAYED MINORS OF A MLWTO                 * 05200021
*                                                                     * 05400021
* EXTERNAL REFERENCES                                                 * 05600021
*    XCTL                                                             * 05800021
*                                                                     * 06000021
* EXITS,NORMAL                                                        * 06200021
*    BR   14  RETURN TO CALLER                                        * 06400021
*    IEE5603D  TO PUT OUT A MESSAGE (VIA XCTL)                        * 06600021
*    IEE6803D  TO PROCESS K A,X,X WHICH DEFINES SCREEN AREAS (XCTL)   * 06650021
*    IEE6903D  TO PROCESS K A,REF WHICH DISPLAYS THE SCREEN AREAS-XCTL* 06700021
*                                                                     * 06800021
* EXITS,ERROR                                                         * 07000021
*    IEE5603D  TO PROCESS ERROR MESSAGES (VIA XCTL)                   * 07200021
*                                                                     * 07400021
* ATTRIBUTES                                                          * 07600021
*    REFRESHABLE, PRIVILEGED, TYPE 4 SVC                              * 07800021
*                                                                     * 08000021
* TABLES/WORK AREAS                                                   * 08200021
*    UCM,  WQE, XSA                                                   * 08400021
*                                                                     * 08600021
*********************************************************************** 08800021
         EJECT                                                          09000021
*********************************************************************** 09200021
*                                                                       09400021
*    REGISTERS                                                          09600021
*                                                                       09800021
*********************************************************************** 10000021
RF       EQU   15                  WORK REGISTER                        10200021
RETURN   EQU   14                  SUBROUTINE RETURN REGISTER           10400021
SAVR     EQU   13                  SAVE REGISTER                        10600021
UCMBASE  EQU   12                  UCM BASE REGISTER                    10800021
MYBASE   EQU   11                  THIS ROUTINES BASE REGISTER          11000021
KOPS     EQU   10                  OPERAND POINTER                      11200021
WRK9     EQU   9                   WORK REGISTER                        11400021
UCMEBASE EQU   8                   BASE REGISTER FOR UCM ENTRY          11600021
R7       EQU   7                   WORK REGISTER                        11800021
R6       EQU   6                   WORK REGISTER                        12000021
X5       EQU   5                   WORK REGISTER                        12200021
R5       EQU   5                   WORK REGISTER                        12400021
MINWQER  EQU   4                   BASE REGISTER FOR MINOR WQE          12600021
X4       EQU   4                   WORK REGISTER                        12800021
WRK3     EQU   3                   WORK REGISTER                        13000021
PARMREG  EQU   2                   PARAMETER LIST BASE REGISTER         13200021
R2       EQU   2                   WORK REGISTER                        13400021
MAJWQER  EQU   1                   BASE REGISTER FOR MAJOR WQE          13600021
R1       EQU   1                   WORK REGISTER                        13800021
R0       EQU   0                   WORK REGISTER                        14000021
***                                                                   * 14200021
*********************************************************************** 14400021
         EJECT                                                          14600021
*********************************************************************** 14800021
*                                                                     * 15000021
*      ESTABLISH ADDRESSABILITY                                       * 15200021
*                                                                     * 15400021
*      ON ENTRY, REGISTER 2 CONTAINS ADDRESS OF XSA                   * 16000021
*                                                                     * 16200021
*********************************************************************** 16250021
         SPACE 1                                                        16400021
*/* IEE7803D: CHART */                                                  16600021
*/* %START: E (,%CDR)                 IEE7803D K CDR MODULE 3 */        16800021
*********************************************************************** 17000021
         BALR  MYBASE,N0           ESTABLISH ROUTINE 'S                 17200021
         USING *,MYBASE            BASE REGISTER                        17400021
         USING FAUXSA,PARMREG      ESTABLISH XSA ADDRESSABILITY         17600021
         L     UCMBASE,CVTPTR      GET CVT POINTER                      17800021
         USING CVTSECT,UCMBASE     BASE CVT REG                         18000021
         L     UCMBASE,CVTCUCB     GET UCM POINTER FROM CVT             18200021
         USING PMUCM,UCMBASE       ESTABLISH UCM ADDRESSABILITY         18400021
         USING UCMLIST,UCMEBASE    BASE UCM ENTRY LIST                  18600021
         USING MAJWQE,MAJWQER      BASE MAJOR WQE REG                   18800021
         USING MINWQE,MINWQER      BASE MINOR WQE REG                   19000021
*                                                                     * 19400021
*  TEST IF CONTROL (K) OPERAND IS C,D   BRANCH YES TO PROCESS         * 19600021
*                                                                     * 19800021
         SPACE 1                                                        20200021
*/* %CDR:   D (YES,KCDRTN,NO,CHKKA)  IS THIS COMMAND K C */             20400021
*********************************************************************** 20600021
         L     KOPS,XAL            LOAD PT TO OPERANDS                  20800021
         LA    KOPS,N0(KOPS)       CLEAR HIGH ORDER BYTE                21000021
         CLC   N0(N3,KOPS),KCD     IS IT A K C,D COMMAND                21200021
         BE    KCDRTN              YES-GO HANDLE IT                     21400021
         TM    UCMMODE,UCMMCS      IS THIS A NON MCS SYSTEM   ME        21402021
         BNO   BADKOP              BRANCH YES FOR ERROR MSG   ME        21404021
         SPACE 2                                                        21410021
*                                                                     * 21450025
*  TEST IF CONTROL (K) OPERAND IS A  BRANCH NO TO ERROR MESSAGE       * 21500021
*                                                                     * 21550025
         SPACE 2                                                        21560021
*/* CHKKA:  D (YES,%KAL,NO,BADKOP)     IS THIS COMMAND K A  */          21570025
*********************************************************************   21580025
CHKKA    CLI   N0(KOPS),KA         IS COMMAND K A                       21590025
         BNE   BADKOP              NO, BRANCH                           21592025
         CLI   N1(KOPS),BLANK      IS A ONLY OPERAND                    21594025
         BE    SETSX9              BRANCH YES FOR K A,REF               21596025
         CLI   N1(KOPS),COMMA      IS A FOLLOWED BY A COMMA             21598025
         BNE   BADKOP              BRANCH NO FOR ERROR MESSAGE          21598425
         EJECT                                                          21598821
*/* %KAL:   D (YES,%SX8,NO,SETSX9)    IS THIS OPERAND K A,LL */         21599225
*********************************************************************   21599625
         TM    N2(KOPS),LLOP       IS IT K A,LL,LL,COMMAND              21599725
         BNO   SETSX9              NO, BRANCH                           21599825
         SPACE 3                                                        21599925
*/* %SX8:   P (,XCTL)                 SET MODULE INDICATOR TO K2 */     21649925
*********************************************************************   21659925
         MVC   XAX+N3(N2),SX8      YES- SET MODULE NAME                 21669925
         B     XCTL                BRANCH TO EXIT                       21679925
         SPACE 3                                                        21689925
*/* SETSX9: P (,XCTL)                 SET MODULE INDICATOR TO K5 */     21698725
*********************************************************************   21699125
SETSX9   MVC   XAX+N3(N2),SX9      PUT CODE IN MODULE NAME              21699525
         B     XCTL                BRANCH TO EXIT                       21699625
         SPACE 3                                                        21699925
*/* BADKOP: P (,ERRORMSG)             MOVE ERROR CODE INTO XSA */       21800021
*********************************************************************** 22000021
BADKOP   EQU   *                   N0--SO IT'S A SYNTAX ERROR           22200021
         MVI   XAE,INOPMSG         INDICATE SYNTAX ERROR                22400021
         ST    KOPS,XASTSAVE       ADDRESS OF INVALID OPERAND FOR MSG   22600021
         B     ERRORMSG            GO TO WRITE ERROR MSG                22800021
***                                                                   * 23000021
***    THIS CODE CHECKS IF AREA ID SPECIFIED IS CORRECT               * 23200021
***                                                                   * 23400021
         SPACE 3                                                        23600021
*/* KCDRTN: D (YES,%CONV,NO,ERRORMSG) IS A MLWTO ID SPECIFIED */        23800021
*********************************************************************** 24000021
KCDRTN   EQU   *                                                        24200021
         LA    KOPS,N3(KOPS)       INCREMENT OPERAND POINTER AROUND CDR 24400021
         CLI   N0(KOPS),BLANK       IS AN MLWTO ID SPECIFIED            24600021
         BE    ERR                  NO  SO IT'S AN ERROR                24800021
         LA    KOPS,N1(KOPS)       INCREMENT OPERAND POINTER TO ID      25000021
         TM    N0(KOPS),XF0        IS THE FIRST CHAR OF MLWTO ID DIGIT  25200021
         BNO   BADKOP              BRANCH NO                            25400021
         TM    N1(KOPS),XF0        IS NEXT CHAR OF ID A DIGIT           25600021
         BO    TWODIGIT            BRANCH YES                           25800021
         PACK  XAP(N8),N0(N1,KOPS) PACK EBCDIC MLWTO ID                 26000021
         B     FINDUCME            BRANCH TO CONVERT NUMBER             26200021
         EJECT                                                          26250021
TWODIGIT EQU   *                                                        26400021
         TM    N2(KOPS),XF0        IS NEXT CHAR OF ID A DIGIT           26600021
         BO    THRDIGIT            BRANCH YES                           26800021
         PACK  XAP(N8),N0(N2,KOPS) PACK EBCDIC MLWTO ID                 27000021
         B     FINDUCME            BRANCH TO CONVERT NUMBER             27200021
THRDIGIT EQU   *                                                        27400021
         PACK  XAP(N8),N0(N3,KOPS) PACK EBCDIC MLWTO ID                 27600021
***                                                                   * 27650021
*** THE MLWTO ID ENTERED IS IN EBCDIC AND MUST BE CONVERTED FOR COMPARE 27700021
***                                                                   * 27750021
         SPACE 2                                                        27800021
*/* %CONV:  P (,%MCS)                 CONVERT ID TO BINARY VALUE */     28000021
*********************************************************************** 28200021
FINDUCME EQU   *                                                        28400021
         CVB   R7,XAP              CONVERT TO BINARY                    28600021
         SPACE 2                                                        28800021
*/* %MCS:   D (YES,%FIND,NO,NOMCS)    IS THIS A MCS SYSTEM */           29000021
*********************************************************************** 29200021
         TM    UCMMODE,MCSINSYS    IS THIS AN MCS SYS                   29400021
         BNO   NOMCS               NO USE OTHER ROUTINE                 29600021
***                                                                     29800021
***  FIND AND BASE UCM ENTRY                                          * 30000021
***  INPUT- REG 1-CONSOLE ID RIGHT JUSTIFIED, HIGH ORDER BYTES ZERO   * 30200021
***  OUTPUT-POINTER TO UCMENTRY SPECIFIED BY CONSOLE ID IN UCMEBASE REG 30400021
***  REG USAGE-DESTROYS CONTENTS OF: REG 0,1,UCMEBASE                 * 30600021
***                                                                   * 30800021
         SPACE 3                                                        31000021
*/* %FIND:  P (,RETEST)               GET CONSOLE'S OUTPUT QUEUE */     31200021
*********************************************************************** 31400021
         SR    R1,R1               CLEAR REG                            31600021
         IC    R1,XASCID           LOAD TARGET ID                       31800021
         L     UCMEBASE,UCMVEA     POINT TO FIRST ENTRY                 32000021
         BCTR  R1,ZERO             SUBTRACT ONE FROM CONSOLE ID         32200021
         M     R0,UCMVEZ           MULTIPLY ENTRY SIZE BY REDUCED ID    32400021
         AR    UCMEBASE,R1         POINT TO DESIRED UCM ENTRY           32600021
         L     X5,UCMOUTQ          GET CONSOLES WQE Q PT                32800021
         LTR   X5,X5               IS IT A VALID ADDR                   33000021
         BZ    BADKOP              BRANCH NO FOR ERROR MSG              33200021
         EJECT                                                          33250021
         SPACE 2                                                        34000021
*/* RETEST: D (YES,%MLWTO,NO,INCQUE)  IS ENTRY IN QUEUE ACTIVE */       34200021
*********************************************************************** 34400021
RETEST   EQU   *                                                        34600021
         TM    N0(X5),X01          IS THIS QUE ENTRY ACTIVE             34800021
         BNO   INCQUE              BRANCH NO FOR NEXT ELEMENT           35000021
         L     MAJWQER,N0(X5)      GET QUE  ELEMENT                     35200021
         LA    MAJWQER,N0(MAJWQER) CLEAR HIGH ORDER BYTE                35400021
         SPACE 2                                                        35600021
*/* %MLWTO: D (YES,%IDEQ,NO,INCQUE)   IS THIS ENTRY A MLWTO */          35800021
*********************************************************************** 36000021
         CLI   WMJMMLW,N0          IS THIS AN MLWTO                     36200021
         BE    INCQUE              BRANCH NO FOR NEXT ELEMENT           36400021
         TM    N0(X5),X08          IS THIS A HARD COPY MLWTO            36600021
         BO    INCQUE              BRANCH YES FOR NEXT ELEMENT          36800021
         L     R6,WMJMMSGN         LOAD WQE MLWTO ID                    37000021
LOOP     EQU   *                                                 SM4172 37050021
         C     R6,B1000            IS ID GREATER THAN 1000?      SM4172 37200021
         BL    COMPARE             NO, GO TO COMPARE             SM4172 37250021
         S     R6,B1000            YES, REDUCE BY 1000           SM4172 37300021
         B     LOOP                TRY AGAIN                     SM4172 37350021
COMPARE  EQU   *                                                 SM4172 37360021
         SPACE 2                                                        37400021
*/* %IDEQ:  D (YES,SETSUBQ,NO,INCQUE) IS ID EQUAL TO WQE ID */          37600021
*********************************************************************** 37800021
         CR    R6,R7               COMPARE THE 2 MLWTO ID'S             38000021
         BE    SETSUBQ             YES-GO SET NOT NEEDED BIT            38200021
         SPACE 2                                                        38400021
*/* INCQUE: D (YES,BUMPSUBQ,NO,%END)  IS THE ENTRY CONTINUED */         38600021
*********************************************************************** 38800021
INCQUE   EQU   *                                                        39000021
         TM    N0(X5),C0           N0  IS IT A POINTER TO A NEW BLOCK   39200021
         BO    BUMPSUBQ            NO  JUST BUMP BLOCK POINTER          39400021
         SPACE 2                                                        39600021
*/* %END:   D (YES,ERRORMSG,NO,%INC)  IS THIS ENTRY THE END */          39800021
*********************************************************************** 40000021
         TM    N0(X5),X80          INDICATOR   FOR END OF LIST ON       40200021
         BO    BADKOP              BRANCH YES                           40400021
         SPACE 2                                                        40600021
*/* %INC:   M (,RETEST)               INCREMENT TO NEXT QUEUE ENTRY */  40800021
*********************************************************************** 41000021
         LA    X5,N4(X5)           INCREMENT Q POINTER TO NEXT ELEMENT  41200021
         B     RETEST              CONTINUE SEARCH                      41400021
         EJECT                                                          41600021
*/* BUMPSUBQ: P (,RETEST)             LOAD ADDR OF NEXT QUEUE SECTION   41800021
*/**/                                                                   42000021
*********************************************************************** 42200021
BUMPSUBQ EQU   *                                                        42400021
         L     X5,N0(X5)           LOAD POINTER TO NEXT SECTION         42600021
         B     RETEST              CONTINUE SEARCH                      42800021
CRTTEST  EQU   *                                                        43000021
         TM    UCMDISP,UCMDISPC    IS THIS CONSOLE A GRAPHIC DEVICE     43200021
         BNO   MINLOOP             BRANCH NO                            43400021
         B     LMLAST              BRANCH FOR NEXT MINOR                43600021
***                                                                   * 43800021
***   SET SUB QUEUE ELEMENT BYTE FLAG BITS FOR DEQUEUEING             * 44000021
***                                                                   * 44200021
         SPACE 3                                                        44400021
*/* SETSUBQ: M (,MINLOOP)             SET BITS FOR DEQUEUE MLWTO */     44600021
*********************************************************************** 44800021
SETSUBQ  EQU   *                                                        45000021
         OI    N0(X5),X02          SET PURGE BIT IN SUBQUEUE            45200021
         NI    N0(X5),N255-X01     TURN OF ACTIVE BIT IN SUBQUEUE       45400021
         OI    UCMSTS,UCMTB        SET DEQUEUE BIT ON IN UCME           45600021
***                                                                     45800021
***    GET MINOR POINTER FROM UCMMLAST AND TEST FOR ZERO                46000021
***                                                                     46200021
         L     MINWQER,UCMMLAST    MINOR POINTER FROM UCME              46400021
         LTR   MINWQER,MINWQER     IS MONOR POINTER ZERO                46600021
         BZ    ENDSRCH             BRANCH YES TO END SEARCH             46800021
         SSM   DISABLE             DISABLE FOR DECREMENTING USE COUNT   47000021
         TM    UCMDISP,UCMDISPE    IS TARGET CONSOLE FULL I/O CAPABILIT 47200021
         BO    CRTTEST             BRANCH YES                           47400021
LMLAST   EQU   *                                                        47600021
         L     MINWQER,N0(MINWQER) UCMMLAST MAY POINT TO THE MINOR THAT 47800021
*                                  WAS JUST WRITTEN AND MAY HAVE USE    48000021
*                                  COUNT DECREMENTED                    48200021
         SPACE 3                                                        48400021
*/* MINLOOP: D (YES,ENDSRCH,NO,%USE)  IS THIS THE LAST WQE ON CHAIN */  48600021
*********************************************************************** 48800021
MINLOOP  EQU   *                                                        49000021
         LA    MINWQER,N0(MINWQER) CLEAR HIGH ODER BYTE OF MINOR WQE    49200021
         LTR   MINWQER,MINWQER     IS IT A VALID POINTER                49400021
         BZ    ENDSRCH             BRANCH NO TO END SCAN                49600021
         SR    X5,X5               CLEAR REG                            49800021
         EJECT                                                          50000021
*/* %USE:   M (,NXTMINOR)             DECREMENT THE WQE USE COUNT */    50200021
*********************************************************************** 50400021
         IC    X5,WMNMUC1          USE COUNT FROM MINOR                 50600021
         BCTR  X5,N0               DECREMENT USE COUNT BY ONE           50800021
         STC   X5,WMNMUC1          STORE NEW COUNT BACK INTO MINOR WQE  51000021
         LTR   X5,X5               IS THE USE COUNT ZERO                51200021
         BZ    SETBITON            BRANCH YES                           51400021
         SPACE 2                                                        51600021
*/* NXTMINOR: P (,MINLOOP)            LOAD ADDRESS OF NEXT MINOR WQE */ 51800021
*********************************************************************** 52000021
NXTMINOR EQU   *                                                        52200021
         L     MINWQER,N0(MINWQER) LOAD POINTER TO NEXT MINOR WQE       52400021
         B     MINLOOP                                                  52600021
SETBITON EQU   *                                                        52800021
         OI    WMJMMLW,WMJMMLWG    TURN THIS BIT ON                     53000021
         B     NXTMINOR            BRANCH BACK TO CHECK MINORS          53200021
         SPACE 2                                                        53400021
*/* ENDSRCH: M (,%RET)                TURN OFF MLWTO ACTIVE INDICATORS  53600021
*/**/                                                                   53800021
*********************************************************************** 54000021
ENDSRCH  EQU   *                                                        54200021
         SSM   ENABLE              ENABLE FOR INTERRUPTS                54400021
         OI    UCMSTS,UCMPF        TURN ON OUTPUT PENDING BIT           54600021
         NI    UCMSTS,N255-UCMTC   TURN OFF WORKING ON INLINE MLWTO BIT 54800021
         NI    UCMSDS5,N255-UCMSDS5A TURN OFF WAITING ON INLINE MLWTO   55000021
         B     NOSUBELS            BRANCH FOR EXIT                      55200021
         SPACE 3                                                        55400021
*/* NOMCS:  D (YES,LOOP1,NO,ERRORMSG) DOES OUTPUT QUEUE EXIST */        55600021
*********************************************************************** 55800021
NOMCS    EQU   *                                                        56000021
         L     X5,UCMWTOQ          GET OUTPUT QUEUE                     56200021
         LA    X5,N0(X5)           CLEAR HI-ORDER BYTE                  56400021
         LTR   X5,X5               DOES AN OUTPUT QUEUE EXIST           56600021
         BZ    BADKOP              NO ERROR MESSAGE                     56800021
         USING MAJWQE,R5           DECLARE BASE                         57000021
         SPACE 3                                                        57200021
*/* LOOP1:  D (YES,LOOKID,NO,LOOP2)   IS ENTRY A MLWTO */               57400021
*********************************************************************** 57600021
LOOP1    EQU   *                                                        57800021
         CLI   WMJMLW,N0           IS THIS AN MLWTO                     58000021
         BNE   LOOKID              YES CHECK THE ID                     58200021
         EJECT                                                          58400021
*/* LOOP2:  P (,%LW)                  ADDRESS OF NEXT WQE */            58600021
*********************************************************************** 58800021
LOOP2    EQU   *                                                        59000021
         L     X5,N0(X5)           GET NEXT WQE                         59200021
         LA    X5,N0(X5)           CLEAR HI-ORDER BYTE                  59400021
         SPACE 2                                                        59600021
*/* %LW:    D (YES,ERRORMSG,NO,LOOP1) IS THIS THE LAST WQE ON THE QUEUE 59800021
*/* */                                                                  60000021
*********************************************************************** 60200021
         LTR   X5,X5               ANY MORE WQE'S                       60400021
         BZ    BADKOP              NO- ERROR MESSAGE                    60600021
         B     LOOP1               CHECK THIS ONE                       60800021
         SPACE 2                                                        61000021
*/* LOOKID: D (YES,IDFOUND,NO,LOOP2)  IS ID EQUAL TO WQE ID */          61200021
*********************************************************************** 61400021
LOOKID   EQU   *                                                        61600021
         L     R6,WMJMSGN          GET MLWTO ID                  SM4172 61610021
LOOPCB2  EQU   *                                                 SM4172 61620021
         C     R6,B1000            IS ID GREATER THAN 1000?      SM4172 61650021
         BL    COMPARE1            NO, GO TO COMPARE1            SM4172 61700021
         S     R6,B1000            YES, REDUCE BY 1000           SM4172 61750021
         B     LOOPCB2             TRY AGAIN                     SM4172 61760021
COMPARE1 EQU   *                                                 SM4172 61770021
         CR    R7,R6               IS PASSED ID EQ TO MLWTO ID   SM4172 61800021
         BNE   LOOP2               NO GET NEXT                          62000021
         SPACE 2                                                        62200021
*/* IDFOUND: M (,%AD)                 SET PURGE INDICATOR IN WQE */     62400021
*********************************************************************** 62600021
IDFOUND  EQU   *                                                        62800021
         NI    WMJMLW,N255-WMJMLWA INDICATE MAJOR NOT DISPLAYED         63000021
         OI    WMJDISP,WMJDISPA    SET PURGE FLAG FOR IO ROUTINES       63200021
         SPACE 2                                                        63400021
*/* %AD:    P (,%LMQ)                 ADDRESS OF MINOR WQE */           63600021
*********************************************************************** 63800021
         L     R6,WMJNXTM          GET MINOR Q POINTER                  64000021
         LA    R6,N0(R6)           CLEAR HI-ORDER BYTE                  64200021
         SPACE 2                                                        64400021
*/* %LMQ:   D (YES,ENDMIN,NO,IDFOUND)  IS THIS THE LAST MINOR WQE */    64600021
*********************************************************************** 64800021
         LTR   R6,R6               IS QUEUE EMPTY                       65000021
         BZ    MAJEND              YES SET END IN MAJOR                 65200021
         USING MINWQE,R6                                                65400021
LOOP3    EQU   *                                                        65600021
         OI    WMNDISP,WMNDISPA    INDICATE PURGE MINOR                 65800021
         L     R5,WMNEXT           GET NEXT MINOR                       66000021
         LA    R5,N0(R5)           CLEAR HI-ORDER BYTE                  66200021
         LTR   R5,R5               ANY MORE MINORS                      66400021
         BZ    ENDMIN              NO SET END IN LAST MINOD             66600021
         LR    R6,R5               SET BASE                             66800021
         B     LOOP3               PURGE THIS MINOR                     67000021
         EJECT                                                          67200021
*/* ENDMIN: M (,%RET)                 SET END INDICATOR IN WQE */       67400021
*********************************************************************** 67600021
ENDMIN   EQU   *                                                        67800021
         OI    WMNLT,WMNLTD        SET END OF MLWTO                     68000021
         B     NOSUBELS            EXIT                                 68200021
MAJEND   EQU   *                                                        68400021
         OI    WMJLTYP,WMJLTYPD    SET END OF MLWTO                     68600021
         B     NOSUBELS            EXIT                                 68800021
         SPACE 3                                                        69000021
*/* %RET:   R                         RETURN  BR 14 */                  69200021
*********************************************************************** 69400021
NOSUBELS EQU   *                                                        69600021
         BR    RETURN              RETURN TO SYSTEM                     69800021
ERR      EQU   *                                                        70000021
         ST    KOPS,XASTSAVE       CURSOR ADDRESS FOR MSG RTN           70200021
         MVI   XAE,IEE927I         MSG ERROR CODE FOR AMBIG. REQUEST    70400021
         MVI   XASTSAVE,SECAMREQ   SECONDARY ERROR CODE FOR MESSAGE     70600021
         SPACE 3                                                        70800021
*/* ERRORMSG: R                       IEE5603D RT AND K MSG MODULE */   71000021
*********************************************************************** 71200021
ERRORMSG EQU   *                                                        71400021
         MVI   XAX+N3,XF5          MOVE INTO XSA SVC 34 MSG MODULE NAME 71600021
         MVI   XAX+N4,XF6          FOR XCTL TO MSG MODULE               71800021
         SPACE 3                                                        72000021
*/* XCTL:    R                         XCTL TO OTHER PROCESSORS */      72050021
XCTL     EQU   *                                                        72200021
         LA    R1,XAX              ADDRESS OF NAME FOR XCTL             72400021
         ST    R1,XAP              PUT ADDRESS IN BEGINNING OF XSA      72600021
         SR    R1,R1               CLEAR REG                            72800021
         ST    R1,XAD              REINITIALIZE THE FIRST DOUBLE WORD   73000021
         LR    RF,R2               SET REG 15                           73200021
         XCTL  SF=(E,(15))         ISSUE XCTL                           73400021
         SPACE 3                                                        73600021
*/* IEE7803D: END */                                                    73800021
*********************************************************************** 73810021
         EJECT                                                          73850021
*********************************************************************** 74000021
***                                                                   * 74200021
***    EQUATES FOR THIS ROUTINE                                       * 74400021
***                                                                     74410025
KA       EQU   C'A'                OPERAND FOR K COMMAND                74420021
LLOP     EQU   X'F0'               MASK TO TEST IF A DIGIT              74450025
BLANK    EQU   C' '                BLANK CHARACTER FOR SYNTAX           74500025
COMMA    EQU   C','                COMMA CHARACTER FOR SYNTAX           74550025
ZERO     EQU   X'00'               ZERO CONSTANT                        74800021
C0       EQU   X'C0'               CONTINUED INDICATOR IN OUTPUT QUE    75000021
MCSINSYS EQU   X'02'               MCS IS IN THE SYSTEM                 75200021
X80      EQU   X'80'               END INDICATOR IN OUTPUT QUE          75400021
X01      EQU   X'01'               ACTIVE BIT IN OUTPUT QUE             75600021
X02      EQU   X'02'               PURGE BIT IN OUTPUT QUE              75800021
X08      EQU   X'08'               HARD COPY BIT IN OUTPUT QUE          76000021
XF0      EQU   X'F0'               MASK FOR TESTING NUMBER VALID        76200021
XF5      EQU   X'F5'               NAME OF ERROR MSG MODULE             76400021
XF6      EQU   X'F6'               NAME OF ERROR MSG MODULE             76600021
INOPMSG  EQU   4                   INVALID K OPERAND MSG IEE156I        76800021
IEE927I  EQU   13                  AMBIG. REQUEST                       77000021
SECAMREQ EQU   22                  SECONDARY ERROR CODE FOR MSG         77200021
PTRCVT   EQU   16                  LOCATION OF PT TO CVT                77600021
SAREA    EQU   4                   DISPLACEMENT OF SACB ADDR IN XAS     77800021
N0       EQU   0                   FIELD INCREMENT                      79850021
N1       EQU   1                   FIELD INCREMENT                      79900021
N2       EQU   2                   FIELD INCREMENT                      79950021
N3       EQU   3                   FIELD INCREMENT                      79960021
N4       EQU   4                   FIELD INCREMENT                      79970021
N5       EQU   5                   FIELD INCREMENT                      79972021
N6       EQU   6                   FIELD INCREMENT                      79974021
N7       EQU   7                   FIELD INCREMENT                      79980021
N8       EQU   8                   FIELD INCREMENT                      80000021
N9       EQU   9                   FIELD INCREMENT                      80200021
NA       EQU   10                  FIELD INCREMENT                      80400021
NB       EQU   11                  FIELD INCREMENT                      80600021
NC       EQU   12                  FIELD INCREMENT                      80800021
ND       EQU   13                  FIELD INCREMENT                      81000021
NE       EQU   14                  FIELD INCREMENT                      81200021
NF       EQU   15                  FIELD INCREMENT                      81400021
N19      EQU   19                  FIELD INCREMENT                      81600021
N25      EQU   25                  FIELD INCREMENT                      81800021
N34      EQU   34                  FIELD INCREMENT                      82000021
N29      EQU   29                  FIELD INCREMENT                      82200021
N38      EQU   38                  FIELD INCRENENT                      82400021
N255     EQU   255                 USED IN NI INSTRUCTIONS TO TURN OFF  84200021
*                                  BITS WHEN USING TM INSTRUCTIONS      84400021
         EJECT                                                          84450021
*********************************************************************** 84600021
*                                                                       84800021
*    CONSTANTS                                                          85000021
*                                                                       85200021
*********************************************************************** 85400021
         DS    0F                  ALIGN ON WORD BOUNDARY               85600021
B1000    DC    F'1000'             HIGHEST MLWTO ID VALUE        SM4172 85850021
KCD      DC    C'C,D'              K COMMAND                            86000021
ENABLE   DC    X'FF'               MASK TO ENALBE                       86200021
DISABLE  DC    X'00'               MASK TO DISABLE                      86400021
SX8      DC    C'68'               K2 RTN NAME                          86450025
SX9      DC    C'69'               K5 RTN NAME                          86500025
PATCH    DC    C'****PATCH AREA****'                                    86600021
PATCH2   DC    C'IEE7803D-TEST ONLY'                                    86800021
PATCH3   DC    36C' '                                                   87000021
         EJECT                                                          87200021
***                                                                     87400021
***    ALL DSECTS FOLLOW THIS POINT                                     87600021
***                                                                     87800021
PMUCM    DSECT                                                          88000021
         IEECUCM                                                        88200021
         EJECT                                                          88400021
MAJWQE   DSECT                                                          88600021
         IEECVMUG WQEMAJ                                                88800021
         EJECT                                                          89000021
MINWQE   DSECT                                                          89200021
         IEECVMUG WQEMIN                                                89400021
         EJECT                                                          89600021
FAUXSA   DSECT                                                          89800021
         IEEXSA                                                         90000021
* THE XAS FIELD OF THE XSA IS USED AS FOLLOWS IN THIS MODULE            90200021
         ORG   XAS                                                      90400021
XASCID   DS    X                   CONSOLE ID                           90600021
XASDID   DS    C                   DISPLAY AREA ID                      90800021
XASSDS   DS    X                   SDS SWITCHES                         91000021
XASPLS3  DS    X                   RESERVED                             91200021
XASTSAVE DS    X                   ERROR CODE -- MINOR                  91400021
         DS    XL3                 POINTER TO INVALID OPERAND           91600021
         EJECT                                                          91800021
CVTSECT  DSECT                                                          92000021
         CVT                                                            92200021
*********************************************************************** 92400021
***                                                                     92600021
         END                                                            92800021
