         TITLE 'IEE8503D - DISPLAY SQA ROUTINE'                         00110021
*********************************************************************** 00120021
*                                                                     * 00150021
* NAME - IEE8503D                                                     * 00200021
*                                                                     * 00250021
* STATUS - 000                                                        * 00300021
*                                                                     * 00350021
* FUNCTION - TO DISPLAY ON THE OPERATOR'S CONSOLE, THE SYSTEM QUEUE   * 00400021
*    AREA IN TERMS OF THE LOW AND HIGH BOUNDARIES, AND THE AMOUNT OF  * 00410021
*    THE FREE CORE WITHIN.                                            * 00420021
*    IN TSO SYSTEMS, SUCH INFORMATION IS ROUTED TO THE TERMINAL  M1598* 00422021
*    THAT INVOKED THE COMMAND.                                   M1598* 00424021
*                                                                     * 00430021
* ENTRY POINT - IEE8503D FROM IEE3503D, DISPLAY COMMAND ROUTER        * 00440021
*                                                                     * 00450021
* INPUT - EXTENDED SAVE AREA, POINTED TO BY REGISTER 2                * 00500021
*                                                                     * 00550021
* OUTPUT - A WTO'ED MESSAGE AS FOLLOWS:                               * 00600021
*              IN MFT: 'IEE051I SQA     LLLLLLLL HHHHHHHH FFFFFF'     * 00610021
*              IN MVT: 'IEE051I SQA         LLLLLK HHHHHK FFFFFF'     * 00650021
*             WHERE: L'S REPRESENTS LOW BOUNDARY                      * 00700021
*                    H'S REPRESENTS HIGH BOUNDARY                     * 00750021
*                    F'S REPRESENTS AMOUNT OF FREE CORE               * 00800021
*                    K'S REPRESENTS NUMBER OF 1024 BLOCKS             * 00810021
*                                                                     * 00850021
* EXTERNAL REFERENCES - COMMUNICATION VECTOR TABLE (IHBABCTL)         * 00900021
*                       MASTER SCHEDULER RESIDENT DATA AREA (IEEBASEB)* 00950021
*                       EXTENDED SAVE AREA (IEEXSA)                   * 01000021
*                                                                     * 01050021
* EXIT, NORMAL - RETURN TO CALLER                                     * 01100021
*                                                                     * 01150021
* EXIT, ERROR - NONE                                                  * 01200021
*                                                                     * 01250021
* TABLES/WORK AREA - EXTENDED SAVE AREA (IEEXSA)                      * 01300021
*                                                                     * 01350021
* ATTRIBUTES - REENTRANT, READ-ONLY                                   * 01400021
*                                                                     * 01450021
* NOTES - THE EXTENDED SAVE AREA IS USED FOR THE MESSAGE OUTPUT.      * 01460021
*         THE FIRST SIXTEEN (16) BYTES OF THE EXTENDED SAVE AREA ARE  * 01500021
*         USED AS THE WORK AREA FOR THE CONVERSION OF DATA TO DECIMAL.* 01510021
*         AFTER ALL DATA HAS BEEN CONVERTED, THE FIRST SIXTEEN BYTES  * 01520021
*         ARE OVERLAID WITH THE FIRST SIXTEEN BYTES OF THE MESSAGE.   * 01530021
*         THE TWO (2) BYTES AFTER THE ABOVE-SAID SIXTEEN BYTES   M1598* 01540021
*         ARE USED AS AN ID INDICATOR FIELD.  AFTER ITS USE AS   M1598* 01542021
*         AN INDICATOR IN MVT AND TSO ENVIRONMENTS, IT IS ALWAYS M1598* 01544021
*         BLANKED OUT AS TO ASSURE A BLANK AREA IN THE OUTPUT.   M1598* 01546021
*         THE ID INDICATOR AND THE WTO CONSOLE ID ARE SAVED     A49991* 01548021
*         AND RESTORED, BEFORE AND AFTER THE 'OUTPUTTING', AS   A49991* 01548421
*         TO MAINTAIN SUCCCESSFUL TPUT AND WTO OUTPUTS IN       A49991* 01548821
*         MULTIPLE DQE ENVIRONMENTS.                            A49991* 01549221
*                                                                     * 01550021
*********************************************************************** 01600021
         EJECT                                                          01650021
*********************************************************************** 01700021
*                                                                     * 01750021
*                              MAPPINGS                               * 01800021
*                                                                     * 01850021
*********************************************************************** 01900021
         IHBABCTL                                                       01950021
         EJECT                                                          02050021
         IEEBASEB                                                       02100021
         EJECT                                                          02150021
XSAXSA   DSECT                                                          02200021
         IEEXSA                                                         02250021
         EJECT                                                          02260021
*********************************************************************** 02300021
*                                                                     * 02350021
*                               EQUATES                               * 02400021
*                                                                     * 02450021
*********************************************************************** 02500021
R0       EQU   0                   CONSOLE ID & TERMINAL ID       M1598 02550021
R1       EQU   1                   HIGH ORDER BYTE "CLEARER"           *02600021
                                        AND MESSAGE TEXT POINTER        02610021
R2       EQU   2                   IEEXSA BASE                          02650021
R3       EQU   3                   SQA LOW BOUNDARY STORAGE AND        *02700021
                                        ID INDICATOR SAVE AREA   A49991 02710021
R4       EQU   4                   IEEBASEB BASE                        02750021
R5       EQU   5                   PASSING PARAMETER FOR CNVRTDEC       02800021
R6       EQU   6                   SQA HIGH BOUNDARY STORAGE AND       *02850021
                                        WTO CONSOLE ID SAVE AREA A49991 02860021
R7       EQU   7                   IHBABCTL BASE                        02900021
R8       EQU   8                   SECONDARY CVT BASE & FQE ADDRESSING  02950021
R9       EQU   9                   FQE TOTAL STORAGE                    03000021
R10      EQU   10                  DQE ADDRESSING                       03050021
R11      EQU   11                  RETURN @ FOR CNVRTDEC SUBROUTINE     03100021
R12      EQU   12                  IEE8503D BASE                        03150021
R13      EQU   13                                                       03200021
R14      EQU   14                  RETURN @ FOR CALLER                  03250021
R15      EQU   15                                                       03300021
C0       EQU   0                   CONSTANT OF 0                        03550021
C2       EQU   2                   CONSTANT OF 2                  M1598 03562021
C5       EQU   5                   CONSTANT OF 5                        03570021
C6       EQU   6                   CONSTANT OF 6                        03572021
C8       EQU   8                   CONSTANT OF 8                        03590021
C16      EQU   16                  CONSTANT OF 16                       03602821
C30      EQU   30                  CONSTANT OF 30                 M1598 03604121
ADJUSTER EQU   XAX+7               SIGN BIT ADJUSTER OFFSET             03604221
AFTERID  EQU   XAE+2               XSA MVC'S AFTER ID AREA        M1598 03604521
BLANK    EQU   C' '                BLANK                                03606021
CONVAREA EQU   XAX                 CONVERSION AREA POINTERS             03608021
DATAFQE  EQU   XAS+6               FQE DATA WTO AREA OFFSET             03608421
DQESQES  EQU   4                   OFFSET FOR OBTAINING DQE             03610021
D1024    EQU   10                  DIVISOR FOR OBTAINING 1024 BLOCKS    03650021
FQEAREA  EQU   XAX+2               CONVERTED FQE DATA AREA              03660421
ID       EQU   XAE                 ID INDICATOR FIELD             M1598 03662021
MFT      EQU   X'20'               MFT BITS                             03670021
MFTAREA  EQU   XAX                 CONVERTED MFT DATA AREA              03670121
MFTBLANK EQU   XAV+4               MFT BLANK WTO AREA OFFSET            03670421
MFTHIGH  EQU   XAV+5               MFT HIGH SQA DATA WTO AREA OFFSET    03670821
MFTLOW   EQU   XAN                 MFT LOW SQA DATA WTO AREA OFFSET     03671221
MVTAREA  EQU   XAX+3               CONVERTED MVT DATA AREA              03671421
MVTHIGH  EQU   XAV+7               MVT HIGH SQA DATA WTO AREA OFFSET    03671621
MVTLOW   EQU   XAV                 MVT LOW SQA DATA WTO AREA OFFSET     03672021
SIGNBIT  EQU   X'F0'               UNPACKING SIGN ADJUSTER              03680021
TSOMSG   EQU   XAD                 TSO MESSAGE TEXT POINTER       M1598 03690021
         EJECT                                                          03710021
*********************************************************************** 03750021
*                                                                     * 03800021
*                           INITIALIZATION                            * 03850021
*                                                                     * 03900021
*********************************************************************** 03950021
IEE8503D CSECT                                                          04000021
* A 050800-050920,055440                                         A52898 04000221
* C 052500                                                       A52898 04000321
* D 050600,05160-052000                                          A52898 04001121
* A 065048-065052                                                A52897 04001221
* D 036600,037000                                                A52897 04001321
* A 015480-015492,027100,028600,062116,062234,062444,            A49991 04001421
* A 063020-063040                                                A49991 04001721
* C 064000-065000                                                 M2711 04011521
* A 004220-004240,015400-015460,035620,036041,036045,036620,      M1598 04017021
* A 036900,042120-042192,042300,062040-062170,062440-062460,      M1598 04022521
* A 063481,065044-065440                                          M1598 04028021
* C 025500,056000,062000                                          M1598 04033521
* D 036040                                                        M1598 04039021
*                                                                A40792 04044521
         BALR  R12,0               ESTABLISH BASE ADDRESSABILITY        04050021
         USING *,R12               PROGRAM BASE                         04100021
         USING XSAXSA,R2           EXTENDED SAVE AREA BASE              04150021
         SR    R0,R0               CLEAR FOR ID INSERTION               04210021
         OC    XAJ(C2),XAJ         IS IT CONSOLE INVOKED COMMAND? M1598 04212021
         BZ    NONTSO              YES, BRANCH TO SAVE CONSOLE ID M1598 04214021
         LH    R0,XAJ              SAVE TERMINAL ID FOR TPUT      M1598 04216021
         STH   R0,ID               PUT ID IN ID FIELD             M1598 04218021
         B     AROUND              GO AROUND WTO LOGIC            M1598 04218421
NONTSO   EQU   *                                                  M1598 04218821
         STH   R0,ID               PUT ZEROES IN ID FIELD         M1598 04219221
         IC    R0,XAU              SAVE CONSOLE ID FOR WTO              04220021
AROUND   EQU   *                                                  M1598 04230021
         L     R7,CVTPTR           OBTAIN HEX 10 OFFSET                 04250021
         USING CVTSECT,R7          COMMUNICATION VECTOR TABLE BASE      04300021
         SSM   ZEROZERO            DISABLE                              04350021
         CLI   CVTDCB,MFT          IS IT MFT ENVIRONMENT?               04400021
         BE    SQAMFT              YES, BRANCH TO MFT SET UP FOR SQA    04450021
         EJECT                                                          04452021
*********************************************************************** 04460021
*                                                                     * 04470021
*                         MVT SET UP FOR SQA                          * 04480021
*                                                                     * 04490021
*********************************************************************** 04492021
         L     R8,CVTABEND         OBTAIN ADDRESS OF SECONDARY CVT      04500021
         USING SCVTSECT,R8         SECONDARY CVT BASE                   04550021
         L     R10,SCVTMSSQ        OBTAIN ADDRESS OF GOVRFLB            04600021
         DROP  R8                                                       04700021
         L     R10,DQESQES(R10)    OBTAIN ADDRESS OF DQE                04750021
         LA    R10,C0(R10)         CLEAR HIGH ORDER BYTE                04760021
DQELOOP  EQU   *                                                        04770021
         L     R6,DQEBLOCK(R10)    OBTAIN SQA LOW BOUNDARY              04800021
         LA    R6,C0(R6)           CLEAR HIGH ORDER BYTE                04850021
         LR    R3,R6               SAVE FOR CONVERSION LATER            04900021
         L     R1,DQELGTH2(R10)    OBTAIN SQA BLOCK LENGTH              04910021
         LA    R1,C0(R1)           CLEAR HIGH ORDER BYTE                04920021
         AR    R6,R1               OBTAIN SQA HIGH BOUNDARY             04930021
         L     R8,DQEFQE(R10)      OBTAIN FIRST FQE ADDRESS             05000021
         EJECT                                                          05002021
*********************************************************************** 05010021
*                                                                     * 05020021
*                        ADD UP ALL THE FQE'S                         * 05030021
*                                                                     * 05040021
*********************************************************************** 05042021
FQECLEAR EQU   *                                                        05044021
         SR    R9,R9               CLEAR OUT FQE ADDER                  05050021
FQELOOP  EQU   *                                                        05070021
         LA    R8,C0(R8)           CLEAR HIGH ORDER BYTE         A52898 05080021
         LTR   R8,R8               IS THERE AN ADDRESS?          A52898 05090021
         BZ    FQEDONE             NO, GO OUT OF THE LOOP        A52898 05092021
         L     R1,FQELGTH(R8)      OBTAIN FQE LENGTH                    05100021
         LA    R1,C0(R1)           CLEAR HIGH ORDER BYTE                05110021
         AR    R9,R1               ADD UP TO THE FQE ADDER              05120021
         L     R8,FQEFQE(R8)       OBTAIN NEXT FQE ADDRESS              05150021
         B     FQELOOP             YES, BRANCH TO GET NEXT FQE   A52898 05250021
         EJECT                                                          05302021
*********************************************************************** 05517321
*                                                                     * 05520021
*                MVT SET UP FOR CONVERSION AND STORING                * 05530021
*                                                                     * 05540021
*********************************************************************** 05542021
FQEDONE  EQU   *                                                 A52898 05544021
         SSM   FOXFOX              ENABLE                               05550021
         MVC   AFTERID(C30),IDMSG  INSERT MESSAGE AFTER ID AREA   M1598 05600021
         CLI   CVTDCB,MFT          IS IT MFT ENVIRONMENT?               05610021
         BE    MFTSETUP            YES, BRANCH TO MFT SET UP            05620021
         LA    R5,C0(R3)           CLEAR LOW BOUNDARY HIGH ORDER BYTE   05650021
         SRL   R5,D1024            DIVIDE BY 1024                       05700021
         BAL   R11,CNVRTDEC        CONVERT LOW BOUNDARY TO DECIMAL      05750021
         MVC   MVTLOW(C5),MVTAREA  MOVE CONVERTED ADDRESS TO WTO AREA   05800021
         LA    R5,C0(R6)           CLEAR HIGH BOUNDARY HIGH ORDER BYTE  05850021
         SRL   R5,D1024            DIVIDE BY 1024                       05900021
         BAL   R11,CNVRTDEC        CONVERT HIGH BOUNDARY TO DECIMAL     05950021
         MVC   MVTHIGH(C5),MVTAREA MOVE CONVERTED ADDRESS TO WTO AREA   06000021
         EJECT                                                          06010021
*********************************************************************** 06020021
*                                                                     * 06030021
*                FQE SET UP FOR CONVERSION AND STORING                * 06040021
*                                                                     * 06042021
*********************************************************************** 06044021
FQEDATA  EQU   *                                                        06046021
         LA    R5,C0(R9)           CLEAR TOTAL FQE HIGH ORDER BYTE      06050021
         BAL   R11,CNVRTDEC        CONVERT TOTAL FQE TO DECIMAL         06100021
         MVC   DATAFQE(C6),FQEAREA MOVE CONVERTED TOTAL FQE TO WTO AREA 06150021
         MVC   XSA(C16),MESSAGE    INSERT MESSAGE BEFORE ID AREA  M1598 06200021
         EJECT                                                          06202021
*********************************************************************** 06204021
*                                                                     * 06206021
*                          TSO OUTPUT SET UP                          * 06208021
*                                                                     * 06208421
*********************************************************************** 06208821
         CLI   CVTDCB,MFT          IS IT MFT ENVIRONMENT?         M1598 06209221
         BE    WRITEOUT            YES, BRANCH TO CONSOLE WTO     M1598 06209621
         OC    ID(C2),ID           IS IT CONSOLE INVOKED COMMAND? M1598 06210921
         BZ    WRITEOUT            YES, BRANCH TO CONSOLE WTO     M1598 06211221
         LH    R3,ID               SAVE THE ID INDICATOR         A49991 06211621
         LH    R0,MESSAGE          GET MESSAGE LENGTH             M1598 06213221
         SH    R0,FOUR             ELIMINATE WTO INFO'S LENGTH    M1598 06214621
         LH    R1,ID               GET TERMINAL ID                M1598 06216021
         SLL   R1,C16              MOVE INTO HIGH ORDER HALFWORD  M1598 06217421
         OR    R0,R1               "INSERT" INTO REGISTER 0       M1598 06218821
         LA    R1,TSOMSG           OBTAIN TEXT POINTER FOR TPUT   M1598 06220221
         MVC   ID(C2),AFTERID      BLANK OUT ID INDICATOR FIELD   M1598 06221621
         TPUT  (R1),(R0),R         WRITE TO TERMINAL              M1598 06223021
         STH   R3,ID               RESTORE THE ID INDICATOR      A49991 06223421
         B     MOREDQE             BRANCH AROUND WTO              M1598 06224421
         EJECT                                                          06225821
*********************************************************************** 06227221
*                                                                     * 06228621
*                      WRITE TO OPERATOR SET UP                       * 06230021
*                                                                     * 06240021
*********************************************************************** 06242021
WRITEOUT EQU   *                                                  M1598 06244021
         LR    R6,R0               SAVE THE WTO CONSOLE ID       A49991 06244421
         MVC   ID(C2),AFTERID      BLANK OUT ID INDICATOR FIELD   M1598 06246021
         LA    R1,XSA              OBTAIN TEXT POINTER FOR WTO          06250021
         WTO   MF=(E,(1))          WRITE TO OPERATOR                    06300021
         LR    R0,R6               RESTORE THE WTO CONSOLE ID    A49991 06302021
         XC    ID(C2),ID           ZERO OUT ID INDICATOR FIELD   A49991 06304021
         EJECT                                                          06310021
*********************************************************************** 06320021
*                                                                     * 06330021
*                         TEST FOR MORE DQE'S                         * 06340021
*                                                                     * 06342021
*********************************************************************** 06344021
         CLI   CVTDCB,MFT          IS IT MFT ENVIRONMENT?               06346021
         BE    EXIT                YES, BRANCH TO EXIT                  06348021
MOREDQE  EQU   *                                                  M1598 06348121
         L     R10,DQEDQE(R10)     OBTAIN NEXT DQE ADDRESS              06348421
         LA    R10,C0(R10)         CLEAR HIGH ORDER BYTE                06348521
         LTR   R10,R10             IS THERE AN ADDRESS?                 06348821
         BZ    EXIT                NO, BRANCH TO EXIT                   06349221
         SSM   ZEROZERO            DISABLE SYSTEM                       06349621
         B     DQELOOP             BRANCH TO GET NEXT DQE               06349721
EXIT     EQU   *                                                        06349821
         BR    R14                 RETURN TO CALLER                     06350021
         EJECT                                                          06350421
*********************************************************************** 06350821
*                                                                     * 06351221
*                         MFT SET UP FOR SQA                          * 06351621
*                                                                     * 06351721
*********************************************************************** 06351821
SQAMFT   EQU   *                                                        06352621
         L     R4,CVTMSER          OBTAIN M.S. RESIDENT DATA AREA @     06356021
         USING BASE,R4             IEEBASEB BASE                        06356821
         L     R3,BAFTLO           OBTAIN SQA LOW BOUNDARY              06357621
         L     R6,BAFTHI           OBTAIN SQA HIGH BOUNDARY             06358421
         L     R8,BAFTFQE          OBTAIN FIRST FQE ADDRESS             06359221
         B     FQECLEAR            BRANCH TO OBTAIN TOTAL FQE LENGTH    06360021
         SPACE                                                          06360821
         SPACE                                                          06361621
*********************************************************************** 06362421
*                                                                     * 06363221
*                MFT SET UP FOR CONVERSION AND STORING                * 06364021
*                                                                     * 06364821
*********************************************************************** 06365621
MFTSETUP EQU   *                                                        06366021
         LA    R5,C0(R3)           CLEAR LOW BOUNDARY HIGH ORDER BYTE   06366421
         BAL   R11,CNVRTDEC        CONVERT LOW BOUNDARY TO DECIMAL      06367221
         MVC   MFTLOW(C8),MFTAREA  MOVE CONVERTED ADDRESS TO WTO AREA   06368021
         MVI   MFTBLANK,BLANK      MOVE IN BLANK                        06368821
         LA    R5,C0(R6)           CLEAR HIGH BOUNDARY HIGH ORDER BYTE  06369621
         BAL   R11,CNVRTDEC        CONVERT HIGH BOUNDARY TO DECIMAL     06370421
         MVC   MFTHIGH(C8),MFTAREA MOVE CONVERTED ADDRESS TO WTO AREA   06371221
         B     FQEDATA             BRANCH TO OBTAIN FQE DATA            06372021
         SPACE                                                          06372821
         SPACE                                                          06373621
*********************************************************************** 06374421
*                                                                     * 06375221
*                        CONVERSION SUBROUTINE                        * 06376021
*                                                                     * 06376821
*********************************************************************** 06377621
CNVRTDEC EQU   *                                                        06378021
         XC    XSA(C16),XSA        CLEAR OUT WORKSPACE                  06378421
         CVD   R5,CONVAREA         CONVERT TO DECIMAL                   06379221
         MVC   XSA(C8),CONVAREA    SET UP FOR UNPACK                    06380021
         UNPK  XSA(C16),XSA(C8)    UNPACK                               06390021
         OI    ADJUSTER,SIGNBIT    ADJUST SIGN BIT                      06392021
         BR    R11                 RETURN TO CALLER                     06394021
         EJECT                                                          06394421
*********************************************************************** 06396021
*                                                                     * 06398021
*                            WTO LIST FORM                            * 06398421
*                                                                     * 06398821
*********************************************************************** 06399221
MESSAGE  WTO   'IEE051I SQA              K      K       ',             *06400021
               MF=L,DESC=(5),MCSFLAG=(REG0,RESP),MSGTYP=N         M2711 06500021
         SPACE                                                          06502021
         SPACE                                                          06504021
FOUR     DC    H'4'                HALFWORD CONSTANT OF 4         M1598 06504421
FOXFOX   DC    X'FF'               ENABLE BITS                   A52897 06504821
ZEROZERO DC    X'00'               DISABLE BITS                  A52897 06505221
         SPACE                                                          06506021
         SPACE                                                          06508021
*********************************************************************** 06510021
*                                                                     * 06520021
*                           MESSAGE EQUATES                           * 06530021
*                                                                     * 06540021
*********************************************************************** 06542021
IDMSG    EQU   MESSAGE+18          MESSAGE MVC'S AFTER ID AREA    M1598 06544021
         SPACE                                                          06548021
         END                                                            06550021
