      TITLE 'IMMEDIATE COMMANDS ROUTINE - SET - PART II'                00100021
IEE8603D CSECT                                                          00200021
*********************************************************************** 00400021
*                                                                     * 00500021
*TITLE   IEE8603D   IMMEDIATE COMMANDS ROUTINE - SET - PART II        * 00600021
*                                                                     * 00700021
*FUNCTION: ACCEPTS THE PARAMETERS OF THE SET COMMAND: AUTO, Q, AND    * 00800021
*          PROC, AND PROCEEDS AS FOLLOWS: IF TIME AND/OR DATE HAS     * 00900021
*          BEEN SPECIFIED, PASSES THEM TO THE TIMER MODULE, IEE0903D. * 00950021
*          IF Q AND/OR PROC IS(ARE) SPECIFIED, THE THREE-CHARACTER    * 01000021
*          DEVICE NAME(S) ARE PLACED IN THE APPROPRIATE WORD(S) IN    * 01100021
*          MASTER RESIDENT CORE.  PASSES THE AUTO PARAMETERS, IF      * 01200021
*          SPECIFIED, INTO A BUFFER.  IN ADDITION, POSITIVE SYNTAX    * 01250021
*          CHECKING IS PERFORMED ON KEYWORDS AND PARAMETERS.          * 01300021
*                                                                     * 01400021
*ENTRY POINT: IEE8603D  FROM SET COMMAND MODULE PART I, IEE0603D.     * 01500021
*                                                                     * 01600021
*ATTRIBUTES: REENTRANT, TRANSIENT, READ ONLY AND SELF-RELOCATABLE.    * 01700021
*                                                                     * 01800021
*APPLICABILITY: VARIABLE MEMORY SYSTEM.                               * 01900021
*                                                                     * 02000021
*EXTERNAL REFERENCES: MASTER RESIDENT CORE, USING MACRO IEEBASEA      * 02100021
*                     EXTENDED SAVE AREA(XSA), USING MACRO IEEXSA     * 02200021
*                     COMMUNICATIONS VECTOR TABLE, USING MACRO CVT    * 02300021
*                                                                     * 02400021
*MACROS: POST, XCTL, IEEXSA, CVT, AND IEEBASEA.                       * 02500021
*                                                                     * 02600021
*INPUT: REGISTER 2 POINTING TO THE EXTENDED SAVE AREA WHICH MUST      * 02700021
*        CONTAIN:                                                     * 02800021
*            IN XAE, THE BITS SET IN THE PREVIOUS MODULE, IEE0603D    * 02810021
*            IN XAR, A POINTER TO THE COMMAND BUFFER                  * 02850021
*            IN XAL, A POINTER TO THE PARAMETER LIST (FIRST KEYWORD)  * 02900021
*            IN XAV, THE SPECIFIED DATE                               * 02950021
*            IN XAS, THE SPECIFIED TIME                               * 02960021
*            IN XAU+4, THE PROCESSED KEYWORD COUNTER                  * 02970021
*       REGISTER 10 POINTING TO MASTER RESIDENT CORE(IEEBASEA)    M2081 03000021
*                                                                     * 03100021
*OUTPUT: FOR A NORMAL EXIT(TO IEE0903D, THE TIMER ROUTINE, OR TO  20071 03200021
*          IEE6503D, THE TOD CLOCK TIME ROUTINE)                  20071 03300021
*          REG 6 CONTAINS THE DATE IN BINARY (OR ZEROS IF UNSPECIFIED)* 03400021
*          REG 7 CONTAINS THE DATE IN BINARY (OR ZEROS IF UNSPECIFIED)* 03500021
*          Q AND PROC DEVICENAMES OVERLAY THE Q AND PROC UCB PTRS IN  * 03600021
*           MASTER RESIDENT CORE IF THEY ARE SPECIFIED.               * 03700021
*          THE AUTO COMMANDS, IF SPECIFIED                            * 03750021
*        FOR AN ERROR EXIT (TO IEE0503D, THE MESSAGE ASSEMBLER)       * 03800021
*          REG 2 POINTS TO THE EXTENDED SAVE AREA WHICH CONTAINS      * 03900021
*           IN XAE, THE MESSAGE CODE (SEE ERROR MESSAGES BELOW)       * 04000021
*           IN XAV, THE VERB IN EBCDIC, LEFT ADJUSTED WITH BLANKS     * 04100021
         EJECT                                                          04150021
*EXITS: NORMAL      TO EITHER IEE0903D OR IEE6503D                20071 04300021
*       ERROR       TO THE MESSAGE ASSEMBLY MODULE (IEE0503D)         * 04400021
*                                                                     * 04500021
*ERROR MESSAGES: THE FOLLOWING CONDITIONS GENERATE THE INDICATED      * 04700021
*   MESSAGES                                                          * 04800021
*      1.NON-INTERNAL SET COMMAND ISSUED IN TOD CLOCK SYSTEM, OR AT   * 04900021
*        NON-IPL TIME, Q, PROC, OR AUTO KEYWORD(S) WAS(WERE) SPECIFIED* 04960021
*        'IEE305I SET  COMMAND INVALID.'            (CODE=5)      20071 05000021
*      2.MISPLACED PERIODS IN CLOCK OR DATE PARAMETER, OR MISSING     * 05300021
*        RIGHT PARENTHESIS                                            * 05350021
*        'IEE307I SET  DELIMITER ERROR.'            (CODE=7)          * 05400021
*      3.FAILURE TO FIND BLANK, COMMA OR END OF BUFFER AFTER PARAMETER* 05500021
*        'IEE308I SET  TERM LENGTH ERROR.'          (CODE=8)          * 05600021
*      4.KEYWORD NOT FOUND IN KEYWORD TABLE                           * 05700021
*        'IEE309I SET  UNIDENTIFIABLE KEYWORD.'     (CODE=9)          * 05800021
*      5.NO KEYWORD OR NO DATE SPECIFIED AT IPL TIME, OR AT NON-IPL   * 05900021
*        TIME, NO DATE AND/OR CLOCK KEYWORD SPECIFIED                 * 05950021
*        'IEE310I SET  KEYWORD MISSING.'            (CODE=10)         * 06000021
*      6.BLANK AFTER KEYWORD                                          * 06100021
*        'IEE311I SET  PARAMETER MISSING.'          (CODE=11)         * 06200021
*      7.REPEATED KEYWORD                                             * 06300021
*        'IEE312I SET  PARAMETERS CONFLICT.'        (CODE=12)         * 06400021
*                                                                     * 06700021
* NOTE- IF AN ERROR OCCURS IN A SYSTEM WITH THE TOD CLOCK, A CODE 20071 06800021
*       OF EIGHT IS PLACED IN BAIPL(IPL ECB) TO INDICATE TO IPL   20071 06900021
*       THAT AN ERROR OCCURRED ON THE SET COMMAND.                20071 07000021
         EJECT                                                          07100021
*OPERATION:                                                           * 07150021
*   THE INPUT WORK QUEUE AND PROC LIB UCB POINTERS IN MASTER RESIDENT * 07200021
*   CORE(BAQ AND BAPRC) ARE HELD IN THE EXTENDED SAVE AREA.  EACH     * 07300021
*   INCOMING COMMAND HAS ITS LEADING KEYWORD COMPARED WITH A          * 07400021
*   TABLE(KEYTAB) CONTAINING EACH OF THE THREE POSSIBLE KEYWORDS, Q,  * 07500021
*   PROC, AND AUTO.  SUCCESSFUL COMPARSION RESULTS IN TRANSFER BEING  * 07600021
*   MADE, USING KEYTAB, TO THE APPROPRIATE KEYWORD SUBROUTINE.        * 07700021
*   SUCCESSFUL RECOGNITION OF A KEYWORD CAUSES THE SETTING OF AN ID   * 07800021
*   MASK FOR THAT KEYWORD IN THE XSA.  THE SUBROUTINES HANDLING Q AND * 07900021
*   PROC OVERLAY THE Q AND PROC DEVICE NAMES HELD IN THE XSA.  IF 'F' * 08100021
*   IS A SUBPARAMETER OF THE KEYWORD, Q, THE Q-FORMATTING BIT IS      * 08200021
*   TURNED ON.  THE PROCESSED KEYWORD COUNTER IS INCREMENTED BY ONE.  * 08300021
*   RETURNING FROM THE SUBROUTINES, A CHECK IS MADE FOR SUCCESSIVE    * 08350021
*   KEYWORDS.  IF THERE ARE MORE, THE KEYTAB SCAN IS REPEATED.  IF THE* 08400021
*   BUFFER ELEMENT CAN NOT BE FOUND IN THE KEYWORD TABLE, THE BUFFER  * 08450021
*   IS SCANNED FOR THE NEXT VALID KEYWORD.  WHEN THE BUFFER HAS BEEN  * 08460021
*   SCANNED, THE TIME AND DATE, IF SPECIFIED, ARE LOADED INTO         * 08470021
*   REGISTERS 7 AND 6, RESPECTIVELY.  IF IT IS IPL TIME, THE IPL ECB  * 08600021
*   IS POSTED AND Q AND/OR PROC DEVICE NAMES ARE MOVED TO MASTER      * 08700021
*   RESIDENT CORE FROM THE XSA.  THE AUTO KEYWORD INDICATES SOME OR   * 08900021
*   ALL OF THE AUTOMATIC COMMANDS ISSUED BY IEEVIPL ARE TO BE         * 09000021
*   CANCELLED.  THIS MAY BE DONE BY SPECIFYING 'AUTO=NONE', WHICH     * 09100021
*   CANCELS ALL THE AUTOMATICS, OR BY 'AUTO=(SERIES OF Y'S AND N'S)'. * 09200021
*   EACH 'Y' OR 'N' REPRESENTS THE POSITION OF AN AUTOMATIC COMMAND:  * 09300021
*   A 'Y' INDICATES THE ACCEPTANCE OF THE COMMAND; A 'N' INDICATES THE* 09350021
*   REJECTION OF THAT COMMAND.  THE ACCEPTANCE OR REJECTION OF THE    * 09500021
*   AUTOMATICS IS INDICATED IN AN EIGHT BYTE BUFFER LOCAL TO IEEVIPL, * 09600021
*   POINTED TO IN MASTER RESIDENT CORE, IN BACV.  THE FIRST BYTE IS A * 09650021
*   SWITCH INDICATING AT LEAST ONE CANCELLATION.                      * 09700021
         EJECT                                                          10000021
*TABLES/WORK AREAS: THE EXTENDED SAVE AREA AS USED INTERNALLY IN      * 10100021
*   IEE8603D IS MAPPED AS FOLLOWS:                                    * 10200021
*                                                                     * 10300021
*  ****************************************************************   * 10400021
*  *XAP                            *XAD                           *   * 10500021
*  *SAVE AREA FOR PTR TO           *                              *   * 10600021
*  *END OF COMMAND BUFFER          *                              *   * 10700021
*  ****************************************************************   * 10800021
*  *XAX                            *XAX+4                         *   * 10900021
*  *SAVE AREA FOR UCB OF           *SAVE AREA FOR UCB OF          *   * 11000021
*  *INPUT WORK QUEUE               *PROCEDURE LIBRARY             *   * 11100021
*  ****************************************************************   * 11200021
*  *XAE    *XAE+1  *               *XAL                           *   * 11300021
*  *K.W. ID*Q BIT  *               *SAVE AREA FOR CURRENT         *   * 11400021
*  *CODE   *MASK   *               *PARAMETER POINTER             *   * 11500021
*  ****************************************************************   * 11600021
*  *XAV                            *XAV+4                         *   * 11700021
*  *                               *DATE IN PACKED                *   * 11800021
*  *                               *DECIMAL                       *   * 11900021
*  ****************************************************************   * 12000021
*  *XAS                            *XAS+4                         *   * 12100021
*  *                               *TIME IN PACKED                *   * 12200021
*  *                               *DECIMAL                       *   * 12300021
*  ****************************************************************   * 12400021
*  *XAU                            *XAU+4  *                      *   * 12450021
*  *                               *KEYWORD*                      *   * 12460021
*  *                               *COUNT  *                      *   * 12470021
*  ****************************************************************   * 12480021
*                                                                     * 12500021
*   A KEYWORD TABLE(KEYTAB), WHICH CONTROLS KEYWORD SCANNING AND      * 12600021
*   KEYWORD SUBROUTINE BRANCHING.                                     * 12700021
*                                                                     * 12800021
*NOTES: Q AND UCB DEVICE NAMES WHEN SPECIFIED ARE NOT SYNTAX CHECKED  * 12900021
*   OR VERIFIED.  THEY ARE MERELY PLACED IN MASTER RESIDENT CORE      * 13000021
*   LEFT-JUSTIFIED IN THE WORDS, BAQ AND BAPRC, WITH A TRAILING BLANK.* 13100021
*                                                                     * 13200021
*CHARACTER SET: THE OPERATION OF THIS MODULE DEPENDS UPON AN INTERNAL * 13300021
*   REPRESENTATION OF THE EXTERNAL CHARACTER SET WHICH IS EQUIVALENT  * 13400021
*   TO THE ONE USED AT ASSEMBLY TIME. THE CODING HAS BEEN ARRANGED SO * 13500021
*   THAT REDEFINITION OF 'CHARACTER' CONSTANTS, BY REASSEMBLY, WILL   * 13600021
*   RESULT IN A CORRECT MODULE FOR THE NEW DEFINITIONS.               * 13700021
*                                                                     * 13800021
*********************************************************************** 13900021
         EJECT                                                          14000021
*      REGISTER ASSIGNMENTS        FUNCTION(S)                          14100021
R1       EQU   1                   BASE FOR CVT AND POST                14200021
R2       EQU   2                   BASE REGISTER FOR XSA                14300021
R3       EQU   3                   CURRENT PARAMETER POINTER AND LINK   14400021
*                                  REGISTER                             14450021
R4       EQU   4                   KEYTAB POINTER AND WORK REGISTER     14500021
R5       EQU   5                   ERROR LINKER AND WORK REGISTER       14600021
R6       EQU   6                   DATE PASSER AND WORK REGISTER        14700021
R7       EQU   7                   TIME PASSER AND WORK REGISTER        14800021
R8       EQU   8                   WORK REGISTER                        14900021
R9       EQU   9                   PARAMETER POINTER AND WORK REGISTER  15000021
R10      EQU   10                  BASE REGISTER FOR MASTER RESIDENT    15100021
*                                  CORE                                 15150021
R11      EQU   11                  WORK REGISTER                        15200021
SBASE    EQU   12                  BASE REGISTER FOR PROGRAM            15300021
R13      EQU   13                                                 20071 15400021
R14      EQU   14                  BRANCH REGISTER                20071 15500021
R15      EQU   15                  XCTL REGISTER                        15600021
*                                                                     * 15700021
* DISPLACEMENTS OF INFORMATION WITHIN KEYWORD TABLE ELEMENTS          * 15800021
*  KEYTBL - KEYWORD TABLE LENGTH (DEFINED AFTER THE TABLE BELOW)      * 15900021
KEYELN   EQU   14                  KEYWORD TABLE ELEMENT LENGTH         16000021
KEYLNG   EQU   0                   DISPLACEMENT OF KEYWORD LENGTH       16100021
KEYDIS   EQU   1                   DISPLACEMENT OF DELIMITER            16200021
KEYWRD   EQU   2                   DISPLACEMENT OF KEYWORD              16300021
KEYBRN   EQU   8                   DISPLACEMENT OF BRANCH               16400021
KEYIDM   EQU   12                  DISPLACEMENT OF ID MASK              16500021
* ERROR CODES FOR MESSAGE MODULE                                        16600021
ERR5     EQU   5                                                  20071 16700021
ERR7     EQU   7                                                        16900021
ERR8     EQU   8                                                        17000021
ERR9     EQU   9                                                        17100021
ERR10    EQU   10                                                       17200021
ERR11    EQU   11                                                       17300021
ERR12    EQU   12                                                       17400021
* PERIOD DISPLACEMENTS FOR DATE AND CLOCK                             * 17600021
D0       EQU   0                                                        17610021
D1       EQU   1                                                        17650021
D2       EQU   2                                                        17700021
D3       EQU   3                                                  20071 18000021
D4       EQU   4                                                  20071 18100021
D6       EQU   6                                                        18150021
D7       EQU   7                                                        18160021
D8       EQU   8                                                  20071 18200021
XFF      EQU   X'FF'                                              20071 18300021
X00      EQU   X'00'                                              20071 18400021
C6       EQU   C'6'                                               20071 18600021
C9       EQU   C'9'                                               20071 18700021
BLANK    EQU   C' '                                                     18750021
COMMA    EQU   C','                                                     18800021
LEFT     EQU   C'('                                                     18850021
RIGHT    EQU   C')'                                                     18900021
SLASH    EQU   C'/'                                                     18950021
NO       EQU   C'N'                                                     19000021
YES      EQU   C'Y'                                                     19050021
BITS     EQU   X'1C'                                                    19100021
ZERO     EQU   X'00'                                                    19150021
ONE      EQU   X'01'                                                    19200021
TWO      EQU   X'02'                                                    19250021
         EJECT                                                          19300021
* MAIN ROUTINE - ESTABLISHES ADDRESSABILITY FOR PROGRAM, XSA, AND     * 19400021
*    MASTER RESIDENT CORE. USES XSA POINTERS TO COMMAND BUFFER AND    * 19500021
*    LEADING KEYWORD TO IDENTIFY THE KEYWORD. THE UCB PTRS FOR Q AND  * 19600021
*    PROC ARE PLACED IN THE XSA FOR OVERLAYING BY Q AND PROC DEVICE-  * 19700021
*    NAMES, IF THEY ARE SPECIFIED. KEYWORD RECOGNITION LEADS TO BRAN- * 19800021
*    CHING TO THE KEYWORD'S SUBROUTINE.                               * 19900021
*                                                                     * 20000021
         BALR  SBASE,D0            ESTABLISH PROGRAM ADDRESSABILITY     20100021
         USING *,SBASE                                                  20200021
         USING XSA,R2              BASE FOR EXTENDED SAVE AREA          20300021
         USING BASE,R10            BASE FOR MASTER RESIDENT CORE        20400021
         SR    R11,R11             CLEAR PROCESSED KEYWORD COUNTER      20410021
         IC    R11,XAU+D4          RESTORE PROCESSED KEYWORD COUNTER    20450021
         L     R9,XAL              USE REGISTER 9 AS POINTER            20500021
         LA    R9,D0(R9)                TO PARAMETER KEYWORD            20600021
         MVC   XAX(D8),BAQ         HOLD UCB PTRS (Q AND PROC)           20900021
         L     R7,XAR              LOAD POINTER TO BUFFER               21000021
         LA    R7,D0(R7)                CONTAINING COMMAND              21100021
         LH    R6,D0(R7)           LOAD BUFFER LENGTH                   21200021
         N     R6,SFFFF-D2         CLEAR POSSIBLE GARBAGE               21300021
         AR    R7,R6               COMPUTE END OF BUFFER AND            21400021
         ST    R7,XAP                   SAVE IN FIRST WORD OF XSA       21500021
         SR    R13,R13             CLEAR COMMA COUNTER                  21600021
         SPACE                                                          21700021
SNEWKY   EQU   *                                                        21800021
         LA    R6,KEYELN           LOAD KEYTAB ELEMENT LENGTH           21900021
*                                       FOR INCREMENT IN BXLE           22000021
         LA    R4,KEYTAB           ADCON OF KEYWORD TABLE               22100021
         LA    R7,KEYTBL(R4)       LOAD KEYWORD TABLE LENGTH            22200021
*                                       FOR COMPARAND IN BXLE           22300021
         SR    R5,R5                                                    22400021
SLOOP    EQU   *                                                        22450021
         IC    R5,KEYLNG(R4)       LOAD LENGTH OF A PARTICULAR KEYWORD  22500021
         EX    R5,SETCLC           IS THIS THE KEYWORD?                 22600021
         BE    SBRANCH             YES, NOW GO CHECK PARAMETER          22700021
         BXLE  R4,R6,SLOOP         RECHECK IF NOT END OF TABLE          22800021
         B     SCOMMA              END OF TABLE, SCAN FOR NEXT KEYWORD  22900021
         SPACE                                                          23000021
SBRANCH  EQU   *                                                        23050021
         LA    R9,D1(R9,R5)        POINT REGISTER TO PARAMETER          23100021
         CLI   D0(R9),BLANK        IS PARAMETER BLANK?                  23200021
         BE    SERR11              YES, ERROR                           23300021
         SPACE                                                          23400021
         SR    R3,R3               POINT A REGISTER TO THE END OF       23500021
         IC    R3,KEYDIS(R4)            PARAMETER                       23600021
         LA    R3,D0(R3,R9)                                             23700021
         C     R3,XAP              IS BUFFER EXCEEDED?                  23800021
         BH    SERR08              YES, ERROR                           23900021
         SPACE                                                          24000021
         SR    R5,R5               NO                                   24100021
         IC    R5,KEYIDM(R4)       PREPARE TO LOAD KEYWORD'S ID MASK    24200021
         EX    R5,SETTMP           IS THIS KEYWORD A REPEAT?            24300021
         BO    SERR12              YES, ERROR                           24400021
         SPACE                                                          24500021
         OC    XAE(D1),KEYIDM(R4)  SAVE KEYWORD'S ID IN XSA             24600021
         ST    R3,XAL              SAVE POINTER TO END OF PARAMETER     24700021
         EX    D0,KEYBRN(R4)       GO TO APPROPRIATE SUBROUTINE         24800021
         SPACE                                                          24850021
* THIS SUBROUTINE IS ENTERED WHEN A VALID KEYWORD IS NOT FOUND IN THE * 24860021
* TABLE.  IT CHECKS FOR THE NEXT COMMA, OUTSIDE ANY PARENTHESES, IF   * 24870021
* ANY.  IF FOUND, THE NEW KEYWORD IS FOUND AFTER THE COMMA.           * 24880021
SCOMMA   EQU   *                                                        24900021
         LA    R9,D1(R9)           INCREMENT TO NEXT BUFFER ELEMENT     24950021
         C     R9,XAP              IS IT END OF BUFFER?                 25000021
         BH    SETOUT              YES, BRANCH                          25050021
         CLI   D0(R9),LEFT         NO, IS IT A LEFT PARENTHESIS?        25100021
         BE    SRIGHT              YES, BRANCH                          25150021
         CLI   D0(R9),COMMA        NO, IS IT A COMMA?                   25200021
         BNE   SCOMMA              NO, CHECK NEXT BUFFER ELEMENT        25250021
         LA    R13,D1(R13)         YES, INCREMENT THE COMMA COUNTER BY  25260021
*                                       ONE                             25270021
         LA    R9,D1(R9)           INCREMENT TO THE NEXT BUFFER ELEMENT 25300021
         B     SNEWKY              BRANCH AND PROCESS THE NEW KEYWORD   25350021
         SPACE                                                          25400021
* THIS SUBROUTINE IS ENTERED WHEN A LEFT PARENTHESIS IS ENCOUNTERED   * 25410021
* IN THE SUBROUTINE ABOVE.  IT LOOKS FOR A RIGHT PARENTHESIS, AND THEN* 25420021
* BRANCHES BACK TO THE SCOMMA SUBROUTINE                              * 25430021
SRIGHT   EQU   *                                                        25450021
         LA    R9,D1(R9)           INCREMENT TO NEXT BUFFER ELEMENT     25500021
         C     R9,XAP              IS IT END OF BUFFER?                 25510021
         BH    SERR07              YES, TAKE ERROR EXIT                 25520021
         CLI   D0(R9),RIGHT        NO, IS IT A RIGHT PARENTHESIS?       25550021
         BNE   SRIGHT              NO, CHECK NEXT BUFFER ELEMENT        25600021
         B     SCOMMA              YES, BRANCH BACK TO SCOMMA           25650021
         EJECT                                                          31600021
* KEYWORD=PROC SUBROUTINE - OVERLAYS THE PROC UCB POINTER HELD IN     * 31700021
*    THE XSA WITH THE THREE CHARACTERS FOLLOWING 'PROC='.             * 31800021
*                                                                     * 31900021
SPROC    EQU   *                                                        32000021
         LA    R11,D1(R11)         INCREMENT PROCESSED KEYWORD COUNTER  32050021
*                                       BY ONE                          32060021
         MVC   XAX+D4(D3),D0(R9)   OVERLAY PROC UCB IN XSA              32100021
         MVI   XAX+D7,BLANK             WITH A BLANK ON RIGHT           32200021
         CLI   D3(R9),SLASH        IS DATA CELL INDICATED?              32300021
         BNE   SETNXT              NO, NEXT KEYWORD                     32400021
         LA    R3,D2(R3)           UPDATE DELIMITER POINTER             32500021
         MVC   XAX+D7(D1),D4(R9)   MOVE IN BIN ID                       32600021
         B     SETNXT              GO CHECK FOR NEXT KEYWORD            32700021
         SPACE                                                          32800021
         SPACE                                                          32900021
* KEYWORD=Q SUBROUTINE - OVERLAYS THE Q UCB PTR HELD IN THE XSA       * 33000021
*    WITH THE THREE CHARACTERS FOLLOWING 'Q='.                        * 33100021
*                                                                     * 33200021
SQ       EQU   *                                                        33300021
         LA    R11,D1(R11)         INCREMENT PROCESSED KEYWORD COUNTER  33350021
*                                       BY ONE                          33360021
         MVI   XAE+D1,ZERO         ZERO Q-FORMAT BIT IN XSA             33400021
         LA    R8,SETNXT                                                33500021
         CLI   D0(R9),LEFT         INDICATE PARAMETER LIST              33600021
         BNE   SQUN                NO, UNITNAME ONLY                    33700021
         LA    R3,D1(R9)           POINT TO CHARACTER AFTER PARENTHESIS 33800021
         BAL   R8,SQF              CHECK FOR Q-FORMATTING               33900021
         LR    R9,R3               POINT TO UNITNAME                    34000021
         BAL   R8,SQUN             MOVE UNITNAME TO XSA                 34100021
         LA    R3,D3(R3)           POINT OVER UNITNAME                  34200021
         BAL   R8,SQF              CHECK FOR Q-FORMATTING               34300021
         CLI   D0(R3),RIGHT        END OF PARAMETER LIST                34400021
         BNE   SERR11              NO, ERROR                            34500021
         LA    R3,D1(R3)           REGISTER POINTS TO END OF PARAMETER  34600021
         B     SETNXT              GO CHECK FOR NEXT KEYWORD            34700021
SQF      EQU   *                                                        34800021
         CLC   D0(D3,R3),SQFCN     Q FORMATTING REQUESTED               34900021
         BCR   D7,R8               NOT Q-FORMATTING, RETURN             35000021
         LA    R3,D3(R3)           REGISTER POINTS TO END OF PARAMETER  35100021
         OI    XAE+D1,BA0          TURN ON Q-FORMAT BIT IN XSA          35200021
         B     SETNXT              GO CHECK FOR NEXT KEYWORD            35300021
SQUN     EQU   *                                                        35400021
         MVC   XAX(D3),D0(R9)      OVERLAY Q UCB IN XSA                 35500021
         MVI   XAX+D3,BLANK             WITH A BLANK ON THE RIGHT       35600021
         BR    R8                  GO TO NEXT FUNCTION                  35700021
         EJECT                                                          35800021
* KEYWORD=AUTO SUBROUTINE - CANCELS ALL (AUTO=NONE) OR SOME (AUTO=    * 35900021
*   YNNYN) OF THE AUTOMATICS, INDICATING THE REJECTION IN THE EIGHT   * 36000021
*   BYTE BUFFER WHOSE ADDRESS IS IN BACV.                             * 36100021
*        NOTE - THE BUFFER INDICATION IS THE OPPOSITE OF THE COMMAND  * 36200021
*   INDICATION, I.E., IN THE BUFFER, N MEANS ACCEPTANCE AND Y, REJEC- * 36300021
*   TION.                                                             * 36400021
*                                                                     * 36500021
SAUTO    EQU   *                                                        36600021
         LA    R11,D1(R11)         INCREMENT PROCESSED KEYWORD COUNTER  36650021
*                                       BY ONE                          36660021
         L     R8,BACV             POINTER TO AUTO BUFFER               36700021
         LR    R7,R8                                                    36800021
         MVI   D0(R8),ZERO         ZERO STOP INDICATOR                  36900021
         CLC   STNONE(D4),D0(R9)   IS PARAMETER = NONE?                 37000021
         BE    ST7YS               YES, CANCEL AUTOMATICS               37100021
         LA    R6,D7               COUNTER SET TO MAXIMUM               37200021
STYORN   CLI   D0(R9),NO           IS COMMAND TO BE CANCELLED?          37300021
         BE    STSTOP              YES                                  37400021
         CLI   D0(R9),YES          NO, TO BE ACCEPTED?                  37500021
         BE    STPASS              YES,                                 37600021
         C     R9,XAP              NO, IS IT END OF COMMAND BUFFER?     37700021
         BE    STVALD              YES, VALID                           37800021
         CLI   D0(R9),BLANK        NO, IS IT END OF COMMAND?            37900021
         BE    STVALD              YES, VALID                           38000021
         CLI   D0(R9),COMMA        NO, IS IT END OF KEYWORD?            38100021
         BE    STVALD              YES, VALID                           38200021
         B     SERR08              NO, INVALID CHARACTER                38300021
STSTOP   MVI   D1(R7),YES          INSERT Y TO INDICATE STOP            38400021
         MVI   D0(R8),ONE          SET STOP INDICATOR                   38500021
         B     STUPDT                                                   38600021
STPASS   MVI   D1(R7),NO           N INDICATES ACCEPTANCE               38700021
STUPDT   LA    R7,D1(R7)           UPDATE AUTO BUFFER POINTER           38800021
         LA    R9,D1(R9)           UPDATE PARAMETER POINTER             38900021
         BCT   R6,STYORN           IF LESS THAN 7, RESUME               39000021
         B     STBACK              MAXIMUM REACHED = 7                  39100021
STVALD   CH    R6,STSIX            IS THERE A MINIMUM OF ONE?           39200021
         BH    SERR11              NO, NO PARAMETER               M2081 39300021
         SR    R8,R7               DETERMINE NEGATIVE NUMBER            39400021
         AH    R8,STSIX                                                 39500021
         EX    R8,STPADN                                                39600021
STBACK   LR    R3,R9               UPDATE DELIMITER POINTER             39700021
         B     SETNXT              GO CHECK FOR NEXT KEYWORD            39800021
* SET AUTO=NONE MEANS ALL AUTOMATIC COMMANDS ARE CANCELLED            * 39900021
ST7YS    MVI   D0(R8),ONE          SET STOP INDICATOR                   40000021
         MVI   D1(R8),YES          PAD AUTO BUFFER WITH Y'S             40100021
         MVC   D2(D6,R8),D1(R8)    GO CHECK FOR NEXT KEYWORD            40200021
         LA    R9,D4(R9)           POINT R9 TO DELIMITER                40300021
         B     STBACK                                                   40400021
         EJECT                                                          40500021
* RETURNED TO FROM A KEYWORD SUBROUTINE, THIS PORTION OF THE MAIN     * 40600021
*    ROUTINE CHECKS IF THE SET COMMAND IS COMPLETE OR IF THERE ARE    * 40700021
*    MORE KEYWORDS. A COMMA AS DELIMITER RESULTS IN THE RETURN TO     * 40800021
*    THE KEYWORD TABLE SCAN FOR THE NEW KEYWORD. SUCCESSFUL COMPLETION* 40900021
*    LEADS TO 'SETOUT'.                                               * 41000021
*                                                                     * 41100021
SETNXT   EQU   *                                                        41200021
         C     R3,XAP              IS IT VALID END OF BUFFER?           41300021
         BE    SETOUT              YES, END OF SET COMMAND              41400021
         CLI   D0(R3),BLANK        IS NEXT CHARACTER A BLANK?           41500021
         BE    SETOUT              YES, END OF SET COMMAND              41600021
         CLI   D0(R3),COMMA        IS NEXT CHARACTER A COMMA?           41700021
         BNE   SERR08              NO, MUST BE ERROR                    41800021
         LA    R13,D1(R13)         INCREMENT COMMA COUNTER BY ONE       41850021
         LA    R9,D1(R3)           YES, BUMP CURRENT PARAMETER          41900021
         CLI   D0(R9),BLANK        IS NEXT CHARACTER BLANK?             42000021
         BE    SERR07              YES, DELIMITER ERROR                 42100021
         B     SNEWKY              GO CHECK NEXT KEYWORD                42200021
         EJECT                                                          42300021
* AFTER THE COMMAND'S CONTENTS HAVE BEEN COMPLETELY VERIFIED, THIS    * 42400021
*    SECTION PERFORMS THE FOLLOWING FUNCTIONS: IF IT IS IPL TIME AND  * 42500021
*    THE DATE HAS BEEN SPECIFIED, THE Q AND PROC DEVICENAMES (OR UCB  * 42600021
*    PTRS) ARE RESTORED TO MASTER RESIDENT CORE AND THE IPL ECB IS    * 42700021
*    POST-ED. IPL OR NOT, ANY SPECIFIED TIME  OR DATE IS PACKED IN ITS* 42800021
*    PASSING REGISTER AND CONTROL IS GIVEN TO THE TIMER, IEE0903D.    * 42900021
*                                                                     * 43000021
SETOUT   EQU   *                                                        43100021
         BCTR  R11,D0              DECREMENT PROCESSED KEYWORD COUNTER  43150021
*                                       BY ONE                          43152021
         CR    R11,R13             KEYWORD COUNTER EQUAL TO COMMA       43160021
*                                       COUNTER?                        43162021
         BNE   SERR09              NO, ERROR EXIT                       43170021
         TM    BASFL,BAIN          IS IT IPL TIME?                      43200021
         BO    SNOIPL              NO                                   43300021
         TM    XAE,TWO             YES, IS DATE SET FOR IPL?            43400021
         BZ    SERR10              NO, ERROR                            43500021
         MVC   BAQ(D8),XAX         FILL UCB PTRS AND Q=F BIT            43600021
         MVC   BACV(D1),XAE+D1     MOVE IN Q-FORMAT BIT                 43650021
         POST  BAIPL               POST SUCCESSFUL SET COMMAND          43700021
*                                                                     * 43800021
STIMCH   TM    XAE,ONE             HAS TIME BEEN SET?                   43900021
         BO    STIME7              YES, LOAD REGISTER 7                 44000021
         SR    R7,R7               NO, ZERO REGISTER 7                  44100021
         SPACE                                                          44200021
SDATCH   TM    XAE,TWO             HAS DATE BEEN SET?                   44300021
         BO    SDATE6              YES, LOAD REGISTER 6                 44400021
         SR    R6,R6               NO, ZERO REGISTER 6                  44600021
         SPACE                                                          44700021
SXTRAN   EQU   *                                                  20071 44800021
         MVC   XAX(D8),XLMESG      SET UP BASIC XCTL              20071 44900021
         L     R1,CVTPTR           GET POINTER TO CVT             20071 45000021
         USING SETCVT,R1           ESTABLISH ADDRESSABILITY TO CVT20071 45100021
         TM    CVTOPTB,CVTTOD      IS TOD SUPPORTED?              20071 45200021
         BNO   REGSET              NO, GO TO IEE0903D             20071 45300021
         TM    BASFL,BAIN          IS IT IPL? (0=IPL)             20071 45400021
         BO    SET65               NO, XCTL TO IEE6503D           20071 45500021
* IF IT IS IPL, THE SET COMMAND MUST BE ENTERED IN THE FORM OF A  20071 45600021
* REPLY AND THEN ISSUED INTERNALLY BY THE IPL MODULE.             20071 45700021
         TM    BASFL,BAINTSET      IS IT AN INTERNAL COMMAND?     20071 45800021
         BZ    SERR05              NO, ERROR-MUST BE INTERNAL     20071 45900021
         MVI   BAIPL+D3,X00        SET OK RETURN CODE=00          20071 46000021
SET65    EQU   *                                                  20071 46100021
         MVI   XAX+D3,C6           GO TO IEE6503D                 20071 46200021
         B     SXCTL               BRANCH                         20071 46300021
REGSET   EQU   *                                                  20071 46400021
         MVI   XAX+D4,C9           GO TO IEE0903D                 20071 46500021
SXCTL    SR    R15,R15             SET DCB POINTER TO ZERO              46600021
         ST    R15,XAD                                                  46700021
         LA    R15,XAX             PUT POINTER TO NAME IN LIST          46800021
         ST    R15,XAP                                                  46900021
         LR    R15,R2              PUT POINTER TO LIST IN REGISTER 15   47000021
         NI    BASFL,XFF-BAINTSET                                       47100021
         XCTL  SF=(E,(15))         PASS CONTROL                         47200021
*                                                                     * 47300021
STIME7   L     R7,XAS+D4           PUT TIME IN REGISTER 7               47400021
         B     SDATCH              GO TO THE CHECK FOR DATE             47500021
*                                                                     * 47600021
SDATE6   L     R6,XAV+D4           PUT DATE IN REGISTER 6               47700021
         B     SXTRAN              GO TO THE XCTL TO TIMER MODULE       47800021
*                                                                     * 47900021
SNOIPL   EQU   *                                                        48000021
         TM    XAE,BITS            ARE Q, PROC, OR AUTO SPECIFIED?      48100021
         BZ    STIMCH              NO, CHECK TIME                       48200021
         B     SERR05              YES, ERROR                           48300021
         EJECT                                                          48400021
* THE FOLLOWING INSTRUCTIONS PASS A DESIGNATED ERROR CODE TO THE      * 48500021
*    SET COMMAND ERROR SUBROUTINE, 'SETERR', IN REGISTER 5.           * 48600021
*                                                                     * 48700021
SERR05   BAL   R5,SETERR           ERROR CODE = 5                 20071 48800021
         DC    AL1(ERR5)                                          20071 48900021
*                                                                 20071 49000021
SERR07   BAL   R5,SETERR           ERROR CODE = 7                       49400021
         DC    AL1(ERR7)                                                49500021
*                                                                     * 49600021
SERR08   BAL   R5,SETERR           ERROR CODE = 8                       49700021
         DC    AL1(ERR8)                                                49800021
*                                                                     * 49900021
SERR09   BAL   R5,SETERR           ERROR CODE = 9                       50000021
         DC    AL1(ERR9)                                                50100021
*                                                                     * 50200021
SERR10   BAL   R5,SETERR           ERROR CODE =10                       50300021
         DC    AL1(ERR10)                                               50400021
*                                                                     * 50500021
SERR11   BAL   R5,SETERR           ERROR CODE =11                       50600021
         DC    AL1(ERR11)                                               50700021
*                                                                     * 50800021
SERR12   BAL   R5,SETERR           ERROR CODE =12                       50900021
         DC    AL1(ERR12)                                               51000021
         EJECT                                                          51400021
* ERROR SUBROUTINE - RECEIVES IN REGISTER 5 AN ERROR MESSAGE CODE     * 51500021
*    WHICH IS PLACED IN THE XSA (IN XAE). CONTROL GOES TO THE MESSAGE * 51600021
*    ASSEMBLY MODULE, IEE0503D, BY XCTL.                              * 51700021
SETERR   DS    0H                                                       51800021
         MVC   XAV(D8),SETSET      MOVE VERB NAME TO XSA                51900021
         MVC   XAE(D1),D0(R5)      INSERT ERROR CODE                    52000021
         MVC   XAX(D8),XLMESG      MODULE NAME FOR XCTL                 52100021
         L     R1,CVTPTR           GET POINTER TO CVT             M2081 52200021
         USING SETCVT,R1           ESTABLISH ADDRESSABILITY       M2081 52300021
         TM    CVTOPTB,CVTTOD      IS TOD SUPPORTED?              M2081 52400021
         BZ    SXCTL               NO, NO ERROR CODE              M2081 52500021
         LA    R15,D8              SET UP BAD SET RETURN CODE     20071 52600021
         ST    R15,BAIPL           PUT RETURN CODE IN IPL ECB     20071 52700021
         B     SXCTL               GO TO XCTL EXIT                      52800021
         EJECT                                                          52900021
* THE FOLLOWING TABLE CONTROLS THE SCAN OF INCOMING KEYWORDS AND THE  * 53000021
*   BRANCHING TO SPECIFIC KEYWORD SUBROUTINES.                        * 53100021
*                                                                     * 53200021
         DS    0H                                                       53300021
KEYTAB   EQU   *                                                        53400021
         DC    X'1'                KEYWORD LENGTH MINUS ONE             55000021
         DC    X'3'                PARAMETER DELIMITER                  55100021
         DC    C'Q='               KEYWORD                              55200021
         DC    C'    '             FILLER                               55300021
         B     SQ                  SPECIFIC CODING                      55400021
         DC    X'04'               KEYWORD ID MASK PATTERN              55500021
         DS    C                   FILLER                               55600021
*                                                                     * 55700021
         DC    X'4'                KEYWORD LENGTH MINUS ONE             55800021
         DC    X'3'                PARAMETER DELIMITER                  55900021
         DC    C'PROC='            KEYWORD                              56000021
         DC    C' '                FILLER                               56100021
         B     SPROC               SPECIFIC CODING                      56200021
         DC    X'08'               KEYWORD ID MASK PATTERN              56300021
         DS    C                   FILLER                               56400021
*                                                                     * 56500021
         DC    X'4'                KEYWORD LENGTH MINUS ONE             56600021
         DC    X'1'                PARAMETER DELIMITER                  56700021
         DC    C'AUTO='            KEYWORD                              56800021
         DC    C' '                SILLER                               56900021
         B     SAUTO               SPECIFIC CODING                      57000021
         DC    X'10'               KEYWORD ID MASK PATTERN              57100021
ENDTAB   DS    C                   FILLER                               57200021
KEYTBL   EQU   (ENDTAB-KEYTAB)     LENGTH OF TABLE                      57250021
         EJECT                                                          57300021
* CONSTANTS USED BY THE IMMEDIATE COMMANDS ROUTINE                    * 57400021
*                                                                     * 57500021
         DS    0F                                                       57600021
         DC    X'0000'                                                  57700021
SFFFF    DC    X'FFFF'                                                  57800021
*                                                                     * 57900021
XLMESG   DC    C'IGC0503D'         NAME OF MESSAGE MODULE               58000021
*                                                                     * 58100021
SETSET   DC    C'SET     '         VERB FOR MESSAGE MODULE              58600021
STNONE   DC    C'NONE'             PARAMETER FOR SET COMMAND 'AUTO'     58700021
*                                                                     * 58800021
SETCLC   CLC   D0(D1,R9),KEYWRD(R4) COMPARE NEW KEYWORD WITH TABLE      58900021
*                                       KEYWORD                         58950021
SETTMP   TM    XAE,ZERO            TEST ID MASK PATTERN                 59000021
*                                                                     * 59100021
STPADN   MVC   D1(D1,R7),STNNNN    PAD AUTO BUFFER                      59200021
STNNNN   DC    C'NNNNNN'           N'S FOR AUTO BUFFER PADDNG           59300021
STSIX    DC    H'6'                AUTO CONSTANT                        59400021
SQFCN    DC    CL3',F)'            Q=F CONSTANT                         59500021
         EJECT                                                          59600021
SETXSA   DSECT                                                          59700021
         IEEXSA                                                         59800021
         EJECT                                                          59900021
SETCVT   DSECT                                                          60000021
         CVT                                                            60100021
         EJECT                                                          60200021
         IEEBASEA                                                       60300021
         END                                                            60400021
