         TITLE 'IEECIR51 - MFT COMMAND ANALYZER'                        00500021
IEECIR51 CSECT                                                          01000021
         SPACE 2                                                        01500021
*********************************************************************** 02000021
*                                                                     * 02500021
* STATUS -- CHANGE LEVEL 0                                            * 03000021
*                                                                     * 03500021
* FUNCTION -- THIS ROUTINE IS USED BY THE MASTER PARTITION WAIT MODULE* 04000021
*    IEECIR50 TO ANALYZE COMMANDS. FIRST THE ROUTINE DETERMINES IF IT * 04500021
*    WAS ENTERED BECAUSE OF A MONITOR TIMER INTERRUPT OR FROM A POST  * 05000021
*    OF A NEW COMMAND. IN THE FIRST CASE THE TIMER IS RESET AND CON-  * 05500021
*    TROL IS PASSED TO THE COMMAND PROCESSOR. IN THE OTHER CASE THE   * 06000021
*    CSCB IS CHECKED AND IF IT IS A DEFINE COMMAND CONTROL GOES TO    * 06500021
*    IEEDFIN1. IF IT IS NOT A DEFINE COMMAND THE CSCB IS DECHAINED AND* 07000021
*    CHECKED FOR THE MONITOR COMMAND. IF IT IS A MONITOR COMMAND THE  * 07500021
*    TIMER IS CHECKED TO SEE IF IT IS OPERATING. IF NOT THEN MESSAGE  * 07550021
*    IEF921I IS ISSUED. IF THE TIMER IS OPERATING THEN THE            * 07600021
*    TIME INTERVAL IS GOTTEN FROM THE UCM AND TIMER IS SET. THEN THE  * 08000021
*    ROUTINE CONTINUES AS FOR ALL OTHER COMMANDS AND EXITS TO THE QUE * 08500021
*    MANIPULATION ROUTINES IEESD562.                                  * 09000021
*                                                                     * 09500021
* ENTRY POINTS -- IEECIR51                                            * 10000021
*                                                                     * 10500021
* INPUT -- REGISTER FIVE ADDRESS OF MN A EXIT ROUTINE                   11000021
*          REGISTER THIRTEEN SAVE AREA POINTER                        * 11500021
*          REGISTER FOURTEEN RETURN ADDRESS                           * 12000021
*                                                                     * 12500021
* OUTPUT -- FOR MN A TIME INTERVAL ESTABLISHED WITH STIMER MACRO      * 13000021
*           REGISTER NINE COMMAND CHECK CODE FOUR=ON ZERO=OFF         * 13500021
*           REGISTER = NEGATIVE ON RETURN TO IEECIR50 MEANS SVC 110   * 14000021
*           MUST BE ISSUED ON COMMAND                                 * 14500021
*           REGISTER 1 = POINTER TO CSCB WHEN GOING TO IEESD562       * 14550021
*                                                                     * 15000021
* EXTERNAL REFERENCE -- NONE                                          * 15500021
*                                                                     * 16000021
* EXITS,NORMAL                                                        * 16500021
*         IEESD562 - XCTL FOR COMMANDS HAVING CSCB                    * 17000021
*         IEEDFIN1 - XCTL FOR DEFINE COMMANDS                         * 17500021
*         IEECIR50 - RETURN IF NO COMMAND PENDING                     * 18000021
*                                                                     * 18500021
* EXITS,ERROR -- NONE                                                 * 19000021
*                                                                     * 19500021
* TABLES/WORK AREAS  - COMMAND STRING CONTROL BLOCK (CSCB)            * 20000021
*                      UNIT CONTROL MODULE (UCM)                      * 20500021
*                      MASTER SCHEDULER RESIDENT DATA AREA (BASEB)    * 21000021
*                                                                     * 21500021
* ATTRIBUTES -- REENTRANT                                             * 22000021
*                                                                     * 22500021
* CHARACTER CODE DEPENDENCY -- NONE                                   * 23000021
*                                                                     * 23500021
* NOTES -- THIS MODULE WAS CREATED FOR RELEASE 21 TO SUPPORT STATUS   * 24000021
*    DISPLAY SYSTEM (SDS) NEW MONITER ACTIVE COMMAND. IT IS A SPLIT   * 24500021
*    OF IEECIR50 AND IS A MFT ONLY MODULE.                            * 25000021
*                                                                     * 25500021
*********************************************************************** 26000021
******** REGISTER EQUATES                                             * 26500021
********                                                              * 27000021
* C 790500,815000                                                 21016 27050021
* A 791000-792000,930500                                          21016 27100021
* A 565500,625500,665500,920500                                  A44035 27150021
* C 485000                                                       A44035 27200021
* A (520100-521000,750500-751000,890500-896500,931000-932500)     M2099 27250021
X0       EQU   0                   WORK REG                             27500021
X1       EQU   1                   BASE REG FOR CSCB                    28000021
X2       EQU   2                   BASE REG FOR CVT                     28500021
X3       EQU   3                   BASE REG FOR M.S. DATA AREA (BASEB)  29000021
X4       EQU   4                   WORK REG                             29500021
X5       EQU   5                   SAVE ADDRESS OF MN A EXIT ROUTINE    30000021
X6       EQU   6                   BASE REG FOR UCM PREFIX AREA         30500021
X7       EQU   7                   BASE REG FOR UCM                     31000021
X8       EQU   8                   SAVE TIMER EXIT RETURN ADDRESS       31500021
X9       EQU   9                   COMMAND CHECK CODE FOUR=ON ZERO=OFF  32000021
X10      EQU   10                  WORK REG                             32500021
X11      EQU   11                  BASE REG                             33000021
X12      EQU   12                  WORK REG                             33500021
X13      EQU   13                  SAVE AREA ADDRESS                    34000021
X14      EQU   14                  RETURN ADDRESS                       34500021
X15      EQU   15                  LINK REG                             35000021
******** OTHER  EQUATES                                               * 35500021
********                                                              * 36000021
N0       EQU   0                   NUMBER ZERO                          36500021
N1       EQU   1                   DISPLACEMENT                         37000021
N2       EQU   2                   DISPLACEMENT                         37500021
N3       EQU   3                   DISPLACEMENT                         38000021
N4       EQU   4                   NUMBER FOUR                          38500021
N5       EQU   5                   DISPLACEMENT                         39000021
N7       EQU   7                   DISPLACEMENT                         39500021
CDMBIT   EQU   4                   COMMAND CHECK RETURN CODE            40000021
ECBMASK  EQU   X'C0'               POST AND WAIT FLAGS IN ECB           40500021
TF       EQU   X'FF'               TO TURN OFF FLAGS                    41000021
MONITOR  EQU   X'64'               MN A COMMAND CODE IN CSCB            41500021
*/*IEECIR51: CHART */                                                   42000021
*/*IEECIR51: E (,TEST1) IEECIR51 */                                     42500021
         BALR  X11,N0              SET PROGRAM BASE                     43000021
         USING *,X11               ESTABLISH ADDRESSIBILITY             43500021
         USING CVTD,X2             ADDRESSIBILITY OF COMM.VECTOR TABLE  44000021
         USING BASE,X3             ADDRESSIBILITY OF M.S. DATA AREA     44500021
         USING UCMPRFX,X6          ADDRESSIBITY FOR UCM PREFIX          45000021
         L     X2,CVTPTR           LOAD CVT BASE ADDRESS                45500021
         L     X3,CVTMSER          LOAD M.S. DATA AREA ADDRESS          46000021
         LR    X4,X3               SET UP CHAINING REG                  46500021
         L     X1,BACHN            LOAD CSCB POINTER FROM M.S.DATA AREA 47000021
*/*TEST1: D (NO,COMMINT,YES,%A1) ECB POSTED FOR TIMER */                47500021
         TM    BALAD,ECBMASK       IS ECB STILL IN WAIT STATE?          48000021
         BZ    DISABLE             BRANCH NO TO COMMAND INT RTN. A44035 48500021
*/*%A1: P (,XCTL) STIMER FOR MN A */                                    49000021
         XC    BALAD(N4),BALAD     ZERO ECB                             49500021
         L     X7,CVTCUCB          POINTER TO UCM FROM CVT              50000021
         LA    X6,N4               POINTER TO MCS PREFIX IS             50500021
         LCR   X6,X6               FOUR BYTES BEFORE THE UCM            51000021
         AR    X6,X7               SUBSTRACT FOUR FROM THE UCM          51500021
         L     X6,N0(X6)           LOAD UCM PREFIX ADDRESS              52000021
         LR    X8,X14              SAVE RETURN REG                      52010021
         STIMER REAL,(X5),BINTVL=UCMDTINT SET TIMER WITH INTERVAL FROM  53000021
*                                        UCM PREFIX                     53500021
         SR    X1,X1               SET CSCB POINTER TO ZERO FOR MONITOR 54000021
         LR    X14,X8              SAVE TIMER EXIT ADDRESS              54500021
*/*XCTL: R XCTL TO IEESD562 */                                          55000021
         LA    X9,CDMBIT           SET ON COMMAND CHECK BIT             55500021
         B     NOTRANS1            GO TO IEESD562                       56000021
*/*COMMINT: D (NO,CHKDFN,YES,TEST3) ANY CSCBS ON CHAIN */               56500021
DISABLE  SSM   *+1                 DISABLE FOR CSCB SEARCH       A44035 56550021
COMMINT  EQU   *                                                        57000021
         USING CSCB,X1             ADDRESSIBILITY OF COMMAND STRING C.B 57500021
         LTR   X1,X1               ARE THERE ANY CSCB?                  58000021
         BZ    CHKDFN              BRANCH NO TO SEE IF DEFINE ISSUED    58500021
*/*TEST3: D (YES,TESTMNA,NO,GETNXT) IS A CSCB PENDING */                59000021
         TM    CHSTS,CHAP          IS A CSCB PENDING?                   59500021
         BO    TESTMNA             BRANCH YES TO TEST FOR MN ACTIVE     60000021
*/*GETNXT: P (,COMMINT) GET NEXT CSCB */                                60500021
         LR    X4,X1               SAVE LAST CSCB PTR FOR DECHAIN       61000021
         L     X1,CHPTR            ADDRESS OF NEXT CSCB                 61500021
         B     COMMINT             BRANCH BACK TO TEST CSCB             62000021
CHKDFN   EQU   *                                                        62500021
         SSM   ENABLE              ENABLE THE SYSTEM             A44350 62550021
*/*CHKDFN: D (NO,RETURN50,YES,DFIN1) WAS A DEFINE CMD ISSUED */         63000021
         TM    BADEFINE,BADFCMD    HAS A DEFINE COMMAND BEEN ISSUED?    63500021
         BZ    RETURN50            BRANCH NO TO RETURN                  64000021
*/*DFIN1: R XCTL TO IEEDFIN1 */                                         64500021
         NI    BADEFINE,X'FF'-BADFCMD TURN OFF DEFINE PENDING           65000021
         LA    X9,CDMBIT           SET COMMAND CHECK CODE ON (FOUR)     65500021
         XCTL  EP=IEEDFIN1         GO TO DEFINE ROUTINE                 66000021
*/*RETURN50: P (,EXIT1) CLEAR R9 */                                     66500021
RETURN50 EQU   *                                                        67000021
         SR    X9,X9               SET COMMAND CHECK R.C TO ZERO FOR 50 67500021
EXIT1    EQU   *                                                        68000021
*/*EXIT1: R BR R14 */                                                   68500021
         BR    X14                 RETURN TO IEECIR50                   69000021
TESTMNA  EQU   *                                                        69500021
         SSM   ENABLE              ENABLE THE SYSTEM             A44035 69550021
*/*TESTMNA: D (NO,GOOUT,YES,MNA) IS THIS A MN A REQUEST */              70000021
         CLI   CHVCD,MONITOR       IS CSCB A MONITOR ACTIVE?            70500021
         BNE   GOOUT               BRANCH NO  TO DECHAIN CSCB           71000021
*/*MNA: P (,GOOUT) STIMER FOR MN A */                                   71500021
         L     X7,CVTCUCB          POINTER TO UCM FROM CVT              72000021
         LA    X6,N4               POINTER TO MCS PREFIX IS             72500021
         LCR   X6,X6               FOUR BYTES BEFORE THE UCM            73000021
         AR    X6,X7               SUBTRACT FOUR FROM THE UCM           73500021
         L     X6,N0(X6)           LOAD UCM PREFIX ADDRESS              74000021
         LR    X8,X14              SAVE RETURN ADDRESS                  74500021
         LR    X7,X1               SAVE CSCB POINTER                    75000021
         TM    UCMSFLGS,UCMSYSH    TEST IF TIMER OPERATIVE        M2099 75050021
         BZ    MNADOWN             BRANCH IF TIMER NOT WORKING    M2099 75100021
         STIMER REAL,(X5),BINTVL=UCMDTINT  SET TIMER WITH INTERVAL FROM 75500021
*                                          UCM PREFIX                   76000021
         LR    X1,X7               RESTORE CSCB POINTER                 76500021
         LR    X14,X8              RESTORE RETURN ADDRESS               77000021
GOOUT    EQU   *                                                        77500021
         MVC   N0(N4,X4),CHPTR                                          78000021
         NI    CHSTS,TF-CHAP                                            78500021
         LA    X9,CDMBIT           SET COMMAND CHECK CODE ON (FOUR)     79000021
*/*GOOUT: P (,DUM) SET R9 POSITIVE */                             21016 79050021
*/*DUM: D (YES,SVC110,NO,DCK) IS COMMAND DUMP? */                 21016 79100021
         CLI   CHVCD,DUMP          IS VERB CODE FOR DUMP          21016 79150021
         BE    SVC110              YES PROCESS IN TRANS AREA      21016 79200021
         CLI   CHVCD,DISPLY        IS VERB CODE FOR DISPLAY             79500021
         BNE   NOTRANS             NO NOT A TRANSIENT MODULE            80000021
         CLC   CHBUF(N4),DCKB      IS COMMAND D C,K                     81000021
*/*DCK: D (YES,SVC110,NO,PFK) IS COMMAND D C,K */                 21016 81500021
         BE    SVC110              YES PROCESS IN TRANS AREA            82000021
*/*PFK: D (YES,SVC110,NO,DU) IS COMMAND D PFK */                        82500021
         CLC   CHBUF(N4),PFKB      IS COMMAND D PFK                     83000021
         BE    SVC110              YES PROCESS IN TRANS AREA            83500021
*/*DU: D (YES,SVC110,NO,NOTRANS) IS COMMAND D UNITS */                  84000021
NOTRANS  EQU   *                                                        84500021
         CLI   CHVCD,UCODE         IS COMMAND D UNITS                   85000021
         BNE   NOTRANS1            NO GO TO IEESD562                    85500021
*/*SVC110: P (,EXIT1) SET R9 NEGATIVE */                                86000021
SVC110   EQU   *                                                        86500021
         LCR   X9,X9               SET R9 NEGATIVE                      87000021
         BR    X14                 RETURN TO CIR 50                     87500021
NOTRANS1 EQU   *                                                        88000021
*/*NOTRANS: R XCTL TO IEESD562 */                                       88500021
         XCTL  EP=IEESD562                                              89000021
MNADOWN  EQU   *                                                  M2099 89050021
         LR    X1,X7               RESTORE THE CSCB POINTER       M2099 89100021
         SR    X10,X10             ZERO OUT REGISTER 10           M2099 89110021
         IC    X10,CHUCMP          SAVE THE CONSOLE ID            M2099 89120021
         MVC   N0(N4,X4),CHPTR     DECHAIN THE CSCB               M2099 89150021
         NI    CHSTS,TF-CHAP       TURN OFF PENDING BIT           M2099 89200021
         OI    CHSTS,CHFC          SET FREECSCB BIT               M2099 89250021
         MGCR  (1),CHAIN           FREE THE CSCB                  M2099 89300021
TIMRDOWN EQU   *                                                  M2099 89350021
         LA    X9,CDMBIT           SET ON COMMAND CHECK BIT       M2099 89400021
         LA    X1,TIMRMSG          TIMER NOT WORKING MSG          M2099 89450021
         LR    X0,X10              GET CONSOLE ID                 M2099 89500021
         WTO   MF=(E,(1))          ISSUE MNA REJECTED MSG         M2099 89550021
         LR    X14,X8              RESTORE RETURN ADDRESS         M2099 89600021
         BR    X14                 RETURN TO CIR50                M2099 89650021
*/*IEECIR51: END */                                                     90000021
DCKB     DC    C'C,K '             DCK COMPARAND                        90500021
PFKB     DC    C'PFK '             PFK COMPARAND                        91000021
UB       DC    C'U '               U COMPARAND PLUS A BLANK             91500021
UC       DC    C'U,'               U COMPARAND                          92000021
ENABLE   DC    X'FFFF'             MASK FOR ENABLE SSM           A44035 92050021
DISPLY   EQU   X'68'               DISPLAY VERB CODE                    92500021
UCODE    EQU   X'50'               D UNITS COMMAND CODE                 93000021
DUMP     EQU   X'AC'               DUMP VERB CODE                 21016 93050021
         DS    0D                                                       93100021
TIMRMSG  WTO   'IEE921I MN A REJECTED, NO TIMER',MF=L,DESC=(5),        *93150021
               MCSFLAG=(RESP,REG0),MSGTYP=ACTIVE                  M2099 93250021
         IEEBASEB                                                       93500021
CSCB     DSECT                                                          94000021
         IEECHAIN                                                       94500021
CVTD     DSECT                                                          95000021
         CVT                                                            95500021
PMUCM    DSECT                                                          96000021
         IEECUCM                                                        96500021
         END                                                            97000021
