         TITLE 'IGCXL07B  FIRST LOAD OF CONSOLE SWITCH'                 00100021
IEECLCTX CSECT                                                          00200021
*/*IEECLCTX: CHART */                                                   00300021
*/*%START: E (,BEGIN) IEECLCTX */                                       00400021
*MODULE CREATED FOR MCS - REL 18                                        00500021
*MODULE REWRITTEN FOR S21003 - DISPLAY CONSOLE SUPPORT - REL 21  S21003 00600021
         EJECT                                                          00700021
*****                                                             ***** 00800021
*                                                                     * 00900021
* NAME    IEECLCTX - MULTIPLE CONSOLE SUPPORT CONSOLE SWITCHING       * 01000021
*                                                                     * 01100021
*          CONSOLE SWITCH IS MADE UP OF 4 LOADS OF SVC 72             * 01200021
*                                                                     * 01300021
*          CI-505   -    IEECLCTX       SVCLIB   -    IGCXL07B        * 01400021
*                        IEECMCTX                     IGCXM07B        * 01500021
*                        IEECNCTX                     IGCXN07B        * 01600021
*                        IEECOCTX                     IGCXO07B        * 01700021
*                                                                     * 01800021
*          THESE MODULES ARE INCLUDED ONLY IF MULTIPLE CONSOLE SUPPORT* 01900021
*           (MCS) IS GENERATED IN THE SYSTEM -(MFT-MVT-MP)            * 02000021
*                                                                     * 02100021
*                                                                     * 02200021
* FUNCTION                                                            * 02300021
*         1. PERFORM AUTOMATIC CONSOLE SWITCHING WHEN CALLED BY A     * 02400021
*           DEVICE SUPPORT PROCESSOR.                                 * 02500021
*                                                                     * 02600021
*         2. PERFORM MANUAL SWITCHING AS A RESULT OF AN EXTERNAL      * 02700021
*                                                                     * 02800021
*         INTERRUPT                                                   * 02900021
*                                                                     * 03000021
*         3. PERFORM MASTER CONSOLE SWITCHING AS A RESULT OF A        * 03100021
*         VARY MSTCONS COMMAND                                        * 03200021
*                                                                     * 03300021
*         4. SWITCH HARDCOPY  FROM SYSLOG TO A NON-GRAPHICS DEVICE    * 03400021
*                                                                     * 03500021
* INPUT   REGISTER 1 POINTS TO A PASSED PARAMETER LIST WHICH IS       * 03600021
*         IN THE FOLLOWING FORMAT (THIS IS MAPPED BY THE IEECVMUG     * 03700021
*         WITH THE CXSA OPERAND)                                      * 03800021
*                                                                     * 03900021
*         DS   CL4  POINTER TO NAME OF CONSOLE SWITCH ROUTINE         * 04000021
*         DS   CL4  UNUSED                                            * 04100021
*         DS   CL8  NAME OF SWITCH ROUTINE IN EBCDIC                  * 04200021
*         DS   CL1  X'00' CONSOLE SWITCH TO BE PERFORMED              * 04300021
*              CL1  X'02' HARDCOPY TO BE PLACE ON MASTER              * 04400021
*                         OR NON GRAPHICS IF MASTER IS GRAPHIC        * 04500021
*              CL1  X'04' RESULT OF EXTERNAL INTERRUPT                * 04600021
*              CL1  X'08' RESULT OF VARY MSTCONS                      * 04700021
*         DS   CL3  POINTER TO UCM ENTRY OF FAILING CONSOLE OR        * 04800021
*                   NEW MASTER UCM ENTRY IN CASE OF MSTCONS           * 04900021
*                                                                     * 05000021
* OUTPUT                                                              * 05100021
*         ON EXIT TO ANOTHER LOAD OF CONSOLE SWITCH --                * 05200021
*              REG 1 - POINTER TO INPUT PARAMETER LIST (CXSA)         * 05300021
*              REG 2 - POINTER TO INPUT HALF OF NEW CONSOLE           * 05400021
*              REG 3 - POINTER TO GETMAINED AREA                      * 05500021
*              REG 4 - UCM PREFIX BASE                                * 05600021
*              REG 6 - POINTER TO OUTPUT HALF OF NEW CONSOLE          * 05700021
*              REG 7 - POINTER TO OUTPUT HALF OF OLD CONSOLE          * 05800021
*              REG 9 - POINTER TO INPUT HALF OF OLD CONSOLE           * 05900021
*              REG 10- UCM BASE                                       * 06000021
*              REG 14- RETURN REG                                     * 06100021
*                                                                     * 06200021
*         OF THE GROUP OF CONSOLE SWITCH MODULES --                   * 06300021
*              MESSAGE TO NEW CONSOLE IN A SWITCH TELLING HIM OF HIS  * 06400021
*              ATTRIBUTES ON A NORMAL CONSOLE SWITCH                  * 06500021
*                                                                     * 06600021
*              MESSAGE TO NEW CONSOLE  TELLING HIM OF HIS ATTRIBUTES  * 06700021
*              ON A MASTER SWITCH                                     * 06800021
*                                                                     * 06900021
*              MESSAGE TO NEW HARD COPY DEVICE WHEN THE SYSTEM        * 07000021
*              SWITCHES THE HARD COPY DEVICE                          * 07100021
*                                                                     * 07200021
*              MESSAGE TO ALL ACTIVE CONSOLES REQUESTING A VARY       * 07300021
*              MSTCONS COMMAND WHEN THE MASTER AND ALL IT'S ALTERNATES* 07400021
*              ARE DOWN                                               * 07500021
*                                                                     * 07600021
*              RINGING OF CONSOLE ALARM WHEN THERE ARE NO ACTIVE      * 07700021
*              CONSOLES IN THE SYSTEM                                 * 07800021
*                                                                     * 07900021
* EXTERNAL     GETMAIN                                                * 08000021
* REFERENCES                                                          * 08100021
*                                                                     * 08200021
* EXITS        RETURN                                                 * 08300021
*              IGCXM07B                                               * 08400021
*              IGCXO07B                                               * 08500021
*              IGC0I07B                                               * 08600021
*              IGC5107B                                               * 08700021
*              IGC6107B                                               * 08800021
*                                                                     * 08900021
* TABLES       CVT                                                    * 09000021
*              UCM                                                    * 09100021
*              WQE                                                    * 09200021
*              RQE                                                    * 09300021
*              CXSA                                                   * 09400021
*              RDCM                                                   * 09500021
*                                                                     * 09600021
*                                                                     * 09700021
* OPERATION        THIS ROUTINE IS GIVEN CONTROL TO PERFORM A CONSOLE * 09800021
*              SWITCH WHEN A COMM TASK DEVICE SUPPORT PROCESSOR       * 09900021
*              DETERMINES THAT AN UNCORRECTABLE I/O ERROR HAS OCCURED * 10000021
*              ON A CONSOLE DEVICE.  THE DEVICE PROCESSORS XCTL TO    * 10100021
*              THIS MODULE IF THEY ARE TRANSIENT OR ISSUE AN SVC 72   * 10200021
*              WITH A PARAMETER LIST TO TELL THE FIRST LOAD OF SVC 72 * 10300021
*              THAT  A  CONSOLE SWITCH IS TO TAKE  PLACE IF THEY      * 10400021
*              ARE RESIDENT.  THIS ROUTINE IS ALSO GIVEN CONTROL BY   * 10500021
*              THE ROUTER WHEN THE EXTERNAL INTERRUPT ECB HAS BEEN    * 10600021
*              POSTED.  THIS INDICATES THAT A CONSOLE SWITCH FOR THE  * 10700021
*              MASTER CONSOLE IS TO BE PERFORMED.  THE SWITCH IS TO   * 10800021
*              BE MADE TO THE ALTERNATE FOR THE MASTER.  THE CONSOLE  * 10900021
*              SWITCH ROUTINE IS ALSO ENTERED WHEN A VARY MSTCONS     * 11000021
*              COMMAND HAS BEEN ISSUED.  THE ROUTINE IS GIVEN CONTROL * 11100021
*              BY THE COMMAND PROCESSOR TO SWITCH THE MASTER CONSOLE  * 11200021
*              TO ANOTHER SPECIFIED CONSOLE.                          * 11300021
*                  FOR A NORMAL CONSOLE SWITCH THE ALTERNATE CONSOLE  * 11400021
*              FOR THE FAILING CONSOLE HAS THE ATTRIBUTES OF THE      * 11500021
*              FAILING CONSOLE SWITCHED TO IT. ANY UNANSWERED WTOR'S  * 11600021
*              THAT WENT TO THE FAILING CONSOLE A PLACED ON THE NEW   * 11700021
*              CONSOLE'S OUTPUT QUEUE. THE OUTPUT QUEUE OF THE        * 11800021
*              FAILING CONSOLE IS TRANSFERRED TO THE NEW CONSOLE.  THE* 11900021
*              QUEUE IS SCREENED FOR DUPLICATES AND IF ANY EXIST THE  * 12000021
*              ARE REMOVED. IF AN ALTERNATE CONSOLE CANNOT BE FOUND   * 12100021
*              THE MASTER CONSOLE IS USED. IF THE NEW CONSOLE IS A    * 12200021
*              GRAPHICS DEVICE AND THE THE OLD WAS RECEIVING HARDCOPY * 12300021
*              THE SWITCH FOR THE CONSOLE ONLY IS MADE.  THE HARDCOPY * 12400021
*              FUNCTION IS PLACE ON A NON-GRAPHICS DEVICE. THIS IS    * 12500021
*              DONE BY PLACING HARDCOPY ON THE FIRST NON GRAPHIC      * 12600021
*              ALTERNATE OF THE NEW CONSOLE FOUND.  IF NONE IS        * 12700021
*              AVAILABLE THE MASTER AND IT'S ALTERNATES ARE TRIED.  IF* 12800021
*              NONE ARE FOUND THEN THE FIRST ACTIVE NON-GRAPIC CONSOLE* 12900021
*              IS USED. IF ONLY A GRAPHICS CONSOLE EXISTS THIS        * 13000021
*              CONDITION IS INDICATED IN THE UCM. GRAPHICS SUPPORT PUT* 13100021
*              AN EMERGENCY MESSAGE ON THE SCREEN AND GO INTO         * 13200021
*              CONVERSATIONAL MODE.  IF THE FAILING CONSOLE IS THE    * 13300021
*              MASTER AND ALL IT'S ALTERNATES ARE INACTIVE A MESSAGE  * 13400021
*              IS SENT TO ALL ACTIVE CONSOLES REQUESTING A VARY       * 13500021
*              MSTCONS COMMAND.  IF ALL CONSOLES IN THE SYSTEM ARE    * 13600021
*              INACTIVE THE CONSOLE ALARM IS RUNG 3 TIMES IF ONE IS   * 13700021
*              AVAILABLE. THE OPERATOR IS TO MAKE THE LAST MASTER     * 13800021
*              READY AND HIT THE EXTERNAL INTERRUPT KEY. IF THE       * 13900021
*              EXTERNAL INTERRUPT KEY IS HIT IN A NORMAL CONDITION    * 14000021
*              THE FUNCTION IS THE SAME AS                            * 14100021
*              IF A DEVICE PROCESSOR HAD INCURRED AN ERROR ON THE     * 14200021
*              MASTER CONSOLE.                                        * 14300021
*              WHEN A SWITCH IS MADE A MESSAGE IS WRITTEN TO THE NEW  * 14400021
*              CONSOLE TELLING HIM WHO HE TOOK OVER FOR AND WHAT HIS  * 14500021
*              ATTRIBUTES NOW ARE. IF THE HARDCOPY FUNCTION WENT      * 14600021
*              ELSEWHERE A MESSAGE IS SENT TO THAT CONSOLE TELLING    * 14700021
*              HIM HE IS NOW HARDCOPY.                                * 14800021
*                                                                     * 14900021
* ERROR        N/A                                                    * 15000021
*                                                                     * 15100021
* EXITS        RETURN                                                 * 15200021
*********************************************************************** 15300021
         EJECT                                                          15400021
* REGISTER EQUATES                                                      15500021
         SPACE                                                          15600021
R0       EQU   0                   WORK REG - MACRO PARAMETER REG       15700021
R1       EQU   1                   REG 1 - MACRO PARAMETER REG          15800021
RINPUT   EQU   1                   POINTER TO PARAMETER LIST            15900021
R2       EQU   2                   REG 2                                16000021
RMCENT   EQU   2                   MASTER CONSOLE UCM ENTRY             16100021
RSAVE    EQU   3                   POINTER TO GETMAINED SAVE AREA       16200021
RUCMP    EQU   4                   UCM PREFIX BASE                      16300021
RWK2     EQU   5                   WORK REG                             16400021
RWK1     EQU   6                   WORK REG                             16500021
ROHALF   EQU   7                   POINTS TO OUTPUT HALF OF             16600021
*                                       COMPOSITE CONSOLE               16700021
*                                       (ZERO IF NOT COMPOSITE)         16800021
*                                       (UCMMCENT)                      16900021
RFCENT   EQU   9                   FAILING CONSOLE UCM ENTRY OR         17000021
*                                       NEW MASTER IF V MSTCONS         17100021
RENTRY   EQU   11                  UCM ENTRY POINTER                    17200021
RSIZE    EQU   12                  BXLE                                 17300021
RLAST    EQU   13                       REGS                            17400021
RWK3     EQU   12                  WORK REGS - NOT TO BE                17500021
RWK4     EQU   13                       USED DURING BXLE                17600021
RBASE    EQU   8                   MODULE BASE                          17700021
RUCM     EQU   10                  UCM BASE                             17800021
RRETURN  EQU   14                  RETURN REG                           17900021
RLINK    EQU   15                  INTERNAL LINK REG                    18000021
         EJECT                                                          18100021
* ESTABLISH ADDRESSABILITY                                              18200021
         BALR  RBASE,N0            ESTABLISH                            18300021
         USING *,RBASE                  MODULE BASE                     18400021
         B     BEGIN               BRANCH AROUND NAME                   18500021
         DC    C'IGCXL07B'         MODULE NAME                          18600021
BEGIN    EQU   *                                                        18700021
*/*BEGIN: P (,%INIT) ESTABLISH ADDRESSABILITY */                        18800021
         SSM   *+1                 DISABLE                              18900021
         L     RUCM,CVTPTR         BASE                                 19000021
         USING CVTDSECT,RUCM            CVT                             19100021
         L     RUCM,CVTCUCB        GET UCM ADDRESS                      19200021
         USING UCM,RUCM            BASE UCM                             19300021
         USING CXSADSEC,RINPUT     BASE CXSA-INPUT PARAMETER LIST       19400021
         LA    RWK1,N4             GET POINTER TO                       19500021
         LR    RUCMP,RUCM               UCM PREFIX                      19600021
         SR    RUCMP,RWK1               FROM THE WORD                   19700021
         L     RUCMP,N0(RUCMP)          BEFORE THE UCM                  19800021
         USING MCSUCM,RUCMP        BASE UCM PREFIX                      19900021
         SPACE 3                                                        20000021
* INITIALIZATION                                                        20100021
*/*%INIT: P (,%RETOPN) INITIALIZE REGISTERS */                          20200021
         SPACE                                                          20300021
         L     RMCENT,UCMMCENT     GET CURRENT MASTER CONSOLE           20400021
*                                       UCM ENTRY POINTER               20500021
         LA    RMCENT,N0(RMCENT)   ZERO HIGH ORDER BYTE                 20600021
         L     RFCENT,CSAUCM       GET UCM ENTRY ADDRESS OF             20700021
*                                       FAILING CONSOLE OR              20800021
*                                       NEW MASTER (V MSTCONS)          20900021
         LA    RFCENT,N0(RFCENT)   ZERO HIGH ORDER BYTE                 21000021
         USING UCMLIST,RFCENT      BASE UCM ENTRY                       21100021
         EJECT                                                          21200021
*    DETERMINE WHAT HAS TO BE DONE                                      21300021
         SPACE                                                          21400021
*/*%RETOPN: D (YES,OPENRTN,NO,) RETURN FROM OPEN */                     21500021
         TM    UCMSFLGS+N1,UCMSYSL  Q. RETURN FROM OPEN                 21600021
         BO    OPENRTN             YES, GO RING ALARM                   21700021
*/*%HCMST: D (YES,HRDCPYSW,NO,) HARDCOPY TO GO ON MASTER */             21800021
         TM    CSACODE,CSAHC       Q. HARDCOPY TO GO ON MASTER          21900021
         BO    HRDCPYSW            YES, GO DO IT                        22000021
*/*%VMST: D (YES,MSTCON,NO,) RESULT OF VARY MSTCONS */                  22100021
         TM    CSACODE,CSAVMST     Q. RESULT OF VARY MSTCONS            22200021
         BO    MSTCON              YES, GO HANDLE                       22300021
*/*%EXTINT: D (YES,EXTERNAL,NO,CONSFAIL) EXTERNAL INTERRUPT */          22400021
         TM    CSACODE,CSAEXTI     Q. EXTERNAL INTERRUPT                22500021
         BO    EXTERNAL            YES, GO HANDLE                       22600021
         SPACE                                                          22700021
CONSFAIL EQU   *                                                        22800021
*    IF THE FAILING CONSOLE IS A COMPOSITE, PUT THE POINTER TO          22900021
*    THE UCM ENTRY FOR THE INPUT HALF IN RFCENT AND THE POINTER         23000021
*    FOR THE OUTPUT HALF IN ROHALF.                                     23100021
*/*CONSFAIL: D (YES,%GETOTHR,NO,PICKALT) IS FAILING CONSOLE COMPOSITE   23200021
*/**/                                                                   23300021
         L     ROHALF,UCMCOMPC     GET POINTER TO OTHER HALF IF         23400021
*                                       COMPOSITE                       23500021
         LTR   ROHALF,ROHALF       Q. FAILING CONSOLE COMPOSITE         23600021
         BZ    PICKALT             NO, GO LOOK FOR ALTERNATE            23700021
*/*%GETOTHR: P (,FLAGCOMP) GET POINTERS TO INPUT AND OUTPUT HALVES OF   23800021
*/*COMPOSITE */                                                         23900021
         TM    UCMATR,UCMOF        Q. FAILING HALF FOR OUTPUT           24000021
         BE    FLAGCOMP            NO, FLAG OUTPUT HALF TESTED          24100021
         XR    ROHALF,RFCENT       YES, PUT THE INPUT HALF IN           24200021
         XR    RFCENT,ROHALF            THE FAILING CONSOLE REG,        24300021
         XR    ROHALF,RFCENT            AND THE OUTPUT HALF IN          24400021
*                                       THE OUTPUT HALF REG             24500021
         DROP  RFCENT                                                   24600021
         USING UCMLIST,ROHALF      BASE OUTPUT HALF UCM ENTRY           24700021
FLAGCOMP EQU   *                                                        24800021
*/*FLAGCOMP: P (,PICKALT) FLAG OUTPUT HALF AS TESTED */                 24900021
         OI    UCMDEVC,UCMDEVCC    FLAG OUTPUT HALF AS TESTED           25000021
         DROP  ROHALF                                                   25100021
         USING UCMLIST,RENTRY                                           25200021
         EJECT                                                          25300021
* SEARCH FOR AN ACTIVE ALTERNATE                                        25400021
PICKALT  EQU   *                                                        25500021
*/*PICKALT: D (YES,%INDMAS,NO,NEXTALT) IS FAILING CONSOLE MASTER */     25600021
         LR    RENTRY,RFCENT       POINT TO ENTRY FOR FAILING           25700021
         CR    RENTRY,RMCENT       Q. FAILING CONSOLE MASTER            25800021
         BNE   NEXTALT             NO, SERACH FOR ALTERNATE             25900021
*/*%INDMAS: P (,NEXTALT) INDICATE SWITCH IS FOR MASTER */               26000021
         OI    UCMSFLGS,UCMSYSD    INDICATE SWITCH IS FOR MASTER        26100021
NEXTALT  EQU   *                   SEARCH FOR ALTERNATE                 26200021
*/*NEXTALT: P (,%NEXT) FLAG CONSOLE AS TESTED */                        26300021
         OI    UCMDEVC,UCMDEVCC    FLAG THIS CONSOLE AS TESTED          26400021
*/*%NEXT: D (YES,%TESTYET,NO,SWTOMAST) IS THERE AN ALTERNATE */         26500021
         L     RENTRY,UCMALTEN     POINT TO ENTRY FOR NEXT              26600021
*                                       ALTERNATE                       26700021
         LTR   RENTRY,RENTRY       Q. IS THERE ONE                      26800021
         BZ    SWTOMAST            NO, TRY TO SWITCH TO MASTER          26900021
*/*%TESTYET: D (YES,SWTOMAST,NO,%TESTACT) HAS IT BEEN TESTED YET */     27000021
         TM    UCMDEVC,UCMDEVCC    Q. HAS ENTRY BEEN TESTED             27100021
         BO    SWTOMAST            YES, TRY TO SWITCH TO MASTER         27200021
*/*%TESTACT: D (YES,ALTFOUND,NO,NEXTALT) IS ALTERNATE ACTIVE */         27300021
         TM    UCMATR,UCMUF        Q. ALTERNATE ACTIVE                  27400021
         BZ    NEXTALT             NO, GET NEXT ALTERNATE               27500021
         TM    UCMSTS,UCMCF       Q. ALT HAVE A CLOSE PENDING BE  M0614 27530021
         BO    NEXTALT               YES, GET NEXT ALTERNATE  BE  M0614 27560021
         SPACE 2                                                        27600021
ALTFOUND EQU   *                                                        27700021
*    IF ALTERNATE TO BE USED IS A CRT, MAKE SURE ITS USE (FULL          27800021
*    CAPABILITY, STATUS DISPLAY, MESSAGE STREAM) IS COMPATIBLE          27900021
*    WITH THE FAILING CONSOLE.  IF IT IS NOT, A STATUS SWITCH           28000021
*    IS FORCED.                                                         28100021
*/*ALTFOUND: D (YES,%TSTFAIL,NO,SETOSW) IS ALTERNATE AN OUTPUT ONLY CRT 28200021
*/* */                                                                  28300021
         TM    UCMDISP,UCMDISPC    Q. ALTERNATE A CRT            S21003 28400021
         BNO   SETOSW              NO, GO SWITCH                 S21003 28500021
         TM    UCMDISP,UCMDISPD    Q. ALTERNATE OUTPUT ONLY      S21003 28600021
         BNO   SETOSW              NO, GO SWITCH                 S21003 28700021
         DROP  RENTRY              BASE                          S21003 28800021
         USING UCMLIST,RFCENT           FAILING CONSOLE          S21003 28900021
*/*%TSTFAIL: D (YES,%FRCMS,NO,FULLCAP) IS FAILING CONSOLE OUTPUT ONLY   29000021
*/**/                                                                   29100021
         TM    UCMDISP,UCMDISPD    Q. FAILING CONSOLE OUTPUT ONLYS21003 29200021
         BNO   FULLCAP             NO, GO FORCE SWITCH OF        S21003 29300021
*                                       ALTERNATE TO FULL        S21003 29400021
*                                       CAPABILITY               S21003 29500021
         DROP  RFCENT              BASE                          S21003 29600021
         USING UCMLIST,RENTRY           ALTERNATE                S21003 29700021
*    FAILING CONSOLE IS OUTPUT ONLY, FORCE ALTERNATE TO BE A     S21003 29800021
*    MESSAGE STREAM TYPE OUTPUT ONLY SINCE THIS TYPE CAN HANDLE  S21003 29900021
*    ALL TYPES OF MESSAGES.                                      S21003 30000021
*/*%FRCMS: P (,SETOSW) INDICATE SWITCH TO MESSAGE STREAM IN UCME        30100021
*/*AND RDCM */                                                          30200021
         OI    UCMDISP,UCMDISPF    INDICATE MESSAGE STREAM       S21003 30300021
         NI    UCMDISP,XFF-UCMDISPG  TURN OFF STATUS DISPLAY BIT S21003 30400021
         L     RWK1,UCMXB          BASE                          S21003 30500021
         USING RDCMDSEC,RWK1            RESIDENT DCM             S21003 30600021
         OI    DCMR3FLG,DCMSTSWT   INDICATE CHANGING STATUS      S21003 30700021
         DROP  RWK1                                              S21003 30800021
         B     SETOSW              GO SWITCH                     S21003 30900021
         SPACE 2                                                        31000021
FULLCAP  EQU   *                                                 S21003 31100021
*    FAILING CONSOLE IS FULL CAPABILITY SO FORCE ALTERNATE TO    S21003 31200021
*    SWITCH TO FULL CAPABILITY STATUS   (THIS ASSUMES THE        S21003 31300021
*    ALTERNATE HAS I/O CAPABILITY HARDWARE, SINCE IT SHOULD NOT  S21003 31400021
*    BE THE ALTERNATE OF AN INPUT/OUTPUT CONSOLE OTHERWISE.)     S21003 31500021
*/*FULLCAP: P (,SETOSW) INDICATE SWITCH TO FULL CAPABILITY IN           31600021
*/*UCME AND RDCM */                                                     31700021
         BAL   RLINK,SWFULCAP                                    S21003 31800021
         EJECT                                                          31900021
SETOSW   EQU   *                                                        32000021
*****                                                             ***** 32100021
*    THIS SECTION OF CODE PERFORMS THE ACTUAL CONSOLE SWITCH.         * 32200021
*    RENTRY POINTS TO THE UCM ENTRY OF THE CONSOLE TO BE              * 32300021
*    SWITCHED TO.  RFCENT POINTS TO THE UCM ENTRY OF THE CONSOLE      * 32400021
*    TO BE SWITCHED FROM.                                             * 32500021
*****                                                             ***** 32600021
*/*SETOSW: S (,%CLRDEV) GETMAIN:GET SAVE AREA */                        32700021
         LR    RWK1,RINPUT         SAVE INPUT POINTER                   32800021
         L     R0,SAVEAREA         GET SIZE OF SAVE AREA AND            32900021
*                                       SUBPOOL (SQA)                   33000021
         GETMAIN R,LV=(0)                                               33100021
         LR    RSAVE,RINPUT        SAVE ADDRESS OF GETMAINED            33200021
*                                       SAVE AREA                       33300021
         LR    RINPUT,RWK1         RESTORE INPUT POINTER                33400021
*/*%CLRDEV: P (,%TSTCM) CLEAR DEVICE TESTED FLAGS */                    33500021
         BAL   RLINK,CLEARDVC      CLEAR DEVICE TESTED FLAGS            33600021
*/*%TSTCM: D (YES,,NO,FAILNOCP) IS FAILING CONSOLE COMPOSITE */         33700021
         LTR   ROHALF,ROHALF       Q. FAILING CONSOLE COMPOSITE         33800021
         BZ    FAILNOCP            NO, GO INDICATE INPUT AND            33900021
*                                       OUTPUT ARE SAME                 34000021
*/*%INDCOMP: P (,CKNEW) INDICATE FAILING IS COMPOSITE */                34100021
         OI    UCMSFLGS+N1,UCMSYSM  INDICATE FAILING IS                 34200021
*                                       COMPOSITE                       34300021
         B     CKNEW               GO LOOK AT NEW CONSOLE               34400021
FAILNOCP EQU   *                                                        34500021
*/*FAILNOCP: P (,CKNEW) INDICATE INPUT AND OUTPUT OF FAILING CONSOLE    34600021
*/* ARE SAME */                                                         34700021
         LR    ROHALF,RFCENT       INDICATE INPUT AND OUTPUT OF         34800021
*                                       FAILING CONSOLE ARE SAME        34900021
         SPACE                                                          35000021
CKNEW    EQU   *                                                        35100021
*/*CKNEW: D (YES,,NO,NEWNOTCP) IS NEW CONSOLE COMPOSITE */              35200021
         L     RWK1,UCMCOMPC       GET POINTER TO OTHER HALF OF         35300021
*                                       NEW CONSOLE                     35400021
         LTR   RWK1,RWK1           Q. NEW CONSOLE COMPOSITE             35500021
         BZ    NEWNOTCP            NO, GO INDICATE INPUT AND            35600021
*                                       OUTPUT ARE SAME                 35700021
*/*%INDNWCP: P  INDICATE NEW CONSOLE IS COMPOSITE */                    35800021
         OI    UCMSFLGS+N1,UCMSYSK  INDICATE NEW IS COMPOSITE           35900021
*/*%HNDLNEW: P (,CONTSW) GET POINTERS TO BOTH HALVES OF COMPOSITE */    36000021
         TM    UCMATR,UCMIF        Q. INPUT HALF IN RENTRY              36100021
         BO    CONTSW              YES, GO CONTINUE SWITCH              36200021
         XR    RWK1,RENTRY         PUT NEW INPUT HALF IN RENTRY         36300021
         XR    RENTRY,RWK1              AND NEW OUTPUT HALF             36400021
NEWNOTCP XR    RWK1,RENTRY              IN RWK1                         36500021
*/*NEWNOTCP: P (,CONTSW) INDICATE INPUT AND OUTPUT ARE SAME */          36600021
         SPACE 2                                                        36700021
CONTSW   EQU   *                                                        36800021
*/*CONTSW: P ADD AUTHORITY OF FAILING CONSOLE TO NEW CONSOLE */         36900021
         OC    UCMAUTH-UCMLIST(N2,RENTRY),UCMAUTH-UCMLIST(RFCENT)       37000021
*                                       ADD AUTHORITY OF FAILING        37100021
*                                       CONSOLE TO NEW CONSOLE          37200021
*/*%FCMAS: D (YES,,NO,RTCODES) IS FAILING CONSOLE MASTER */             37300021
         CR    RFCENT,RMCENT       Q. FAILING CONSOLE MASTER            37400021
         BNE   RTCODES             NO, GO PUT ROUTING CODES IN          37500021
*/*%OFMAST: P TURN OFF MASTER IN FAILING CONSOLE */                     37600021
         NI    UCMDISP-UCMLIST(RFCENT),XFF-UCMDISPA  TURN OFF           37700021
*                                       MASTER IN FAILING CONSOLE       37800021
*/*%INDNWMS: P INDICATE NEW CONSOLE IS MASTER AND STORE POINTER IN UCM  37900021
*/*PREFIX*/                                                             38000021
         OI    UCMDISP-UCMLIST(RENTRY),UCMDISPA  INDICATE NEW           38100021
*                                       CONSOLE IS MASTER               38200021
         ST    RENTRY,UCMMCENT     PUT POINTER TO NEW MASTER IN         38300021
*                                       UCM PREFIX                      38400021
RTCODES  EQU   *                                                        38500021
*/*RTCODES: P ADD FAILING CONSOLE'S ROUTING CODES TO NEW CONSOLE */     38600021
         OC    UCMRTCD-UCMLIST(N4,RWK1),UCMRTCD-UCMLIST(ROHALF)         38700021
*                                       ADD FAILING CONSOLE'S           38800021
*                                       ROUTING CODES TO NEW            38900021
*                                       CONSOLE'S                       39000021
*/*%TSTOLHC: D (YES,,NO,CMDS) OLD CONSOLE HARDCOPY */                   39100021
         TM    UCMDISP-UCMLIST(ROHALF),UCMDISPB  Q. OLD CONSOLE         39200021
*                                       HARDCPY                         39300021
         BZ    CMDS                NO, GO TAKE CARE OF COMMANDS         39400021
*/*%TSTVM: D (YES,, NO,GOSWHC) VARY MSTCONS */                          39500021
         TM    CSACODE,CSAVMST     Q. VARY MSTCONS                      39600021
         BZ    GOSWHC              NO, GO TO SWITCH HARDCOPY            39700021
*/*%VMANY: D (YES,GOSWHC,NO,CMDS) ACCEPT VARY MSTCONS FROM ANYONE */    39800021
         TM    UCMMODE,UCMAMFA     Q. ACCEPT V MSTCONS FROM             39900021
*                                       ANYONE                          40000021
         BZ    CMDS                NO, DON'T SWITCH HARDCPY             40100021
GOSWHC   EQU   *                                                        40200021
*/*GOSWHC: D (YES,SWAPHDCP,NO,) NEW CONSOLE CRT */                      40300021
         TM    UCMDISP-UCMLIST(RWK1),UCMDISPC  Q. NEW CONSOLE CRT       40400021
         BO    SWAPHDCP            YES, BRANCH - CAN'T SWITCH           40500021
*                                       HARDCOPY TO CRT                 40600021
*/*%INDNWHC: P INDICATE HARDCOPY ON NEW CONSOLE AND STORE POINTER IN    40700021
*/*UCM PREFIX */                                                        40800021
         OI    UCMDISP-UCMLIST(RWK1),UCMDISPB  INDICATE HARDCOPY        40900021
*                                       ON NEW CONSOLE                  41000021
         ST    RWK1,UCMHCUCM       STORE NEW HARDCOPY UCM ENTRY         41100021
*                                       POINTER IN UCM PREFIX           41200021
*/*%OFFHCOD: P (,CMDS) TURN OFF HARDCOPY FOR OLD CONSOLE */             41300021
         NI    UCMDISP-UCMLIST(ROHALF),XFF-UCMDISPB  TURN OFF           41400021
*                                       HARDCOPY FLAG FOR               41500021
*                                       FAILING CONSOLE                 41600021
         SPACE 2                                                        41700021
CMDS     EQU   *                                                        41800021
*/*CMDS: R IEECMCTX */                                                  41900021
         MVI   CSANAME+N4,LOAD2    INDICATE SECOND LOAD OF              42000021
*                                       CONSOLE SWITCH                  42100021
         B     CSXCTL              XCTL                                 42200021
         SPACE                                                          42300021
SWAPHDCP EQU   *                                                        42400021
*/*SWAPHDCP: P (,HRDCPYSW) INDICATE NORMAL HARDCOPY SWITCH */           42500021
         MVI   CSACODE,N0          INDICATE NORMAL HARDCPY SWITCH       42600021
HRDCPYSW EQU   *                                                        42700021
*/*HRDCPYSW: R IEECOCTX */                                              42800021
         MVI   CSANAME+N4,LOAD4    INDICATE FOURTH LOAD OF              42900021
*                                       CONSOLE SWITCH                  43000021
         B     CSXCTL              XCTL                                 43100021
         EJECT                                                          43200021
MSTCON   EQU   *                   VARY MSTCONS HANDLING                43300021
*/*MSTCON: D (YES,%RETURN,NO,%TSTACP) VARY MSTCONS TO ITSELF */         43400021
         CR    RFCENT,RMCENT       Q. VARY MSTCONS TO ITSELF            43500021
*/*%RETURN: R RETURN */                                                 43600021
         BCR   EQUAL,RRETURN       RETURN                               43700021
*/*%TSTACP: D (YES,,NO,MSTCON1) ACCEPT V MSTCONS FROM ANYONE */         43800021
         TM    UCMMODE,UCMAMFA     Q.ACCEPT V MSTCONS FROM ANYONES21003 43900021
         BZ    MSTCON1             NO, CONTINUE                  S21003 44000021
         DROP  RENTRY              BASE                          S21003 44100021
         USING UCMLIST,RMCENT           OLD MASTER               S21003 44200021
*/*%ONOLDAC: P (,MSTCON1) TURN ACTIVE BACK ON IN OLD MASTER (SO IT CAN  44300021
*/* CLOSE) */                                                           44400021
         OI    UCMATR,UCMUF        TURN ON ACTIVE FLAG IN OLD    S21003 44500021
*                                       MASTER (SO IT CAN CLOSE) S21003 44600021
MSTCON1  EQU   *                                                 S21003 44700021
*/*MSTCON1: P POINT NEW CONSOLE POINTER TO CONSOLE SPECIFIED IN COMMAND 44800021
*/* */                                                                  44900021
         LR    RENTRY,RFCENT       MOVE UCM ENTRY POINTER OF            45000021
*                                       MSTCONS SPECIFIED IN            45100021
*                                       COMMAND                         45200021
*/*%MSTCON2: P POINT FAILING CONSOLE POINTER TO OLD MASTER */           45300021
         LR    RFCENT,RMCENT       PUT ADDRESS OF OLD MASTER IN         45400021
*                                       FAILING CONSOLE REG             45500021
         L     ROHALF,UCMCOMPC     GET ADDRESS OF OTHER HALF            45600021
*                                       IF COMPOSITE                    45700021
*/*%SWMST: P (,SETOSW) INDICATE SWITCH IS FOR MASTER */                 45800021
         OI    UCMSFLGS,UCMSYSD    INDICATE SWITCH IS FOR MASTER        45900021
         B     SETOSW              GO SWITCH CONSOLES                   46000021
         EJECT                                                          46100021
SWTOMAST EQU   *                                                        46200021
*/*SWTOMAST: D (YES,SRCHCONS,NO,FAILNOMS) IS FAILING CONSOLE MASTER */  46300021
         CR    RFCENT,RMCENT       Q. FAILING CONSOLE MASTER            46400021
         BE    FRSTPASS           YES, LOOK FOR ACTIVE CONSLE BE  M0602 46520021
FAILNOMS EQU   *                                                        46600021
*/*FAILNOMS: P (,SETOSW) SET POINTER TO NEW CONSOLE TO MASTER */        46700021
         LR    RENTRY,RMCENT       INDICATE SWITCH TO MASTER            46800021
         B     SETOSW              GO SWITCH                            46900021
         SPACE                                                          47000021
*****                                                             ***** 47100021
*    THIS SECTION OF CODE LOOKS FOR ANY ACTIVE INPUT/OUTPUT           * 47200021
*    CONSOLES ON THE SYSTEM. (IF NONE ARE FOUND AND A CRT             * 47300021
*    CONSOLE EXISTS THAT CAN BE USED AS AN INPUT/OUTPUT CONSOLE       * 47400021
*    BUT IS CURRENTLY IN OUTPUT-ONLY MODE, THEN THE CRT IS            * 47500021
*    FORCED TO SWITCH TO FULL CAPABILITY USE.) ONCE AN INPUT/         * 47600021
*    OUTPUT CONSOLE IS FOUND, A MESSAGE IS SENT TO ALL ACTIVE         * 47700021
*    CONSOLES STATING THAT THE MASTER IS DOWN AND A VARY MSTCONS      * 47800021
*    SHOULD BE ISSUED TO ESTABLISH THE MASTER CONSOLE. IF NO          * 47900021
*    ACTIVE INPUT/OUTPUT CONSOLE CAN BE FOUND, A CONSOLE ALARM        * 48000021
*    IS RUNG 3 TIMES TO TELL THE OPERATOR THAT NO ACTIVE              * 48100021
*    CONSOLES ARE ON THE SYSTEM AND THAT HE SHOULD MAKE ONE           * 48200021
*    READY AND HIT THE EXTERNAL INTERRUPT KEY.                        * 48300021
*****                                                             ***** 48400021
FRSTPASS EQU   *                                              BE  M0602 48450021
         SPACE                                                          48500021
         SR    RWK2,RWK2           CLEAR REG FOR SWITCH          S21003 48600021
SRCHCONS EQU   *                   SEARCH UCM ENTRYS                    48700021
*/*SRCHCONS: D (YES,ISSALLMG,NO,%TSTOO) ANY ACTIVE INPUT/OUTPUT         48800021
*/*CONSOLE  */                                                          48900021
         DROP  RMCENT              BASE                                 49000021
         USING UCMLIST,RENTRY           RENTRY                          49100021
         LM    RENTRY,RLAST,UCMVEA LOAD REGS FOR BXLE                   49200021
CKACTVE  EQU   *                                                        49300021
         TM    UCMDISP,UCMDISPA+UCMDISPD Q. OUTPUT ONLY OR MASTER       49400021
         BM    NOGOOD              YES, CANNOT USE - BRANCH             49500021
         L     RWK1,UCMCOMPC       GET POINTER TO OTHER HALF            49600021
         LTR   RWK1,RWK1           Q. COMPOSITE                         49700021
         BZ    TESTACT             NO, GO TEST FOR ACTIVE               49800021
         DROP  RENTRY              BASE OTHER                           49900021
         USING UCMLIST,RWK1             HALF OF COMPOSITE               50000021
         TM    UCMDISP,UCMDISPA    Q. OTHER HALF MASTER                 50100021
         BO    NOGOOD              YES, CANNOT USE - BRANCH             50200021
         DROP  RWK1                BASE                                 50300021
         USING UCMLIST,RENTRY           ORIGINAL ENTRY                  50400021
TESTACT  EQU   *                                                        50500021
         TM    UCMSTS,UCMCF       Q. CLOSE PENDING            BE  M0614 50530021
         BO    NOGOOD                YES, GET NEXT ALT        BE  M0614 50560021
         TM    UCMATR,UCMUF        Q. CONSOLE ACTIVE                    50600021
         BO    ISSALLMG            YES, GO ISSUE MSG                    50700021
NOGOOD   EQU   *                                                        50800021
         LTR   RWK2,RWK2           Q. FIRST PASS THROUGH SEARCH  S21003 50900021
         BZ    CHKNEXT             YES, GO CHECK NEXT ENTRY      S21003 51000021
*/*%TSTOO: D (YES,FRCFLCAP,NO,RINGBELL) ANY OUTPUT ONLY CRT WITH        51100021
*/*I/O HARDWARE*/                                                       51200021
         TM    UCMDISP,UCMDISPC+UCMDISPD  Q. CRT OUTPUT ONLY     S21003 51300021
         BNO   CHKNEXT             NO, GO CHECK NEXT ENTRY       S21003 51400021
         TM    UCMSDS5,UCMSDS5G    Q. CAN IT BE FULL CAPABILITY  S21003 51500021
         BNO   CHKNEXT            NO, GO CHECK NEXT ENTRY     BE  M1421 51520021
         TM    UCMSTS,UCMCF       Q. CLOSE PENDING            BE  M1421 51540021
         BO    CHKNEXT            YES, GO CHECK NEXT ENTRY    BE  M1421 51560021
         TM    UCMATR,UCMUF       Q. CONSOLE ACTIVE           BE  M1421 51580021
         BO    FRCFLCAP            YES, FORCE FULL CAPABILITY    S21003 51600021
CHKNEXT  EQU   *                                                        51700021
         BXLE  RENTRY,RSIZE,CKACTVE  LOOP THROUGH ALL UCM ENTRIES       51800021
*    IF END OF FIRST PASS, FLIP SWITCH AND START SECOND PASS            51900021
*    IF END OF SECOND PASS, NO GOOD CONSOLE FOUND - GO RING BELL        52000021
         LTR   RWK2,RWK2           Q. FIRST PASS                 S21003 52100021
         BNZ   RINGBELL            NO, GO RING BELL              S21003 52200021
         LA    RWK2,N1             INDICATE SECOND PASS          S21003 52300021
         B     SRCHCONS            GO THROUGH SECOND PASS        S21003 52400021
         SPACE                                                          52500021
FRCFLCAP EQU   *                                                        52600021
*/*FRCFLCAP: P (,ISSALLMG) INDICATE SWITCH TO FULL CAPABILITY IN        52700021
*/*UCME AND RDCM*/                                                      52800021
         BAL   RLINK,SWFULCAP      GO SWITCH TO FULL CAPABILITY  S21003 52900021
         SPACE 2                                                        53000021
ISSALLMG EQU   *                                                        53100021
*    THERE IS AT LEAST ONE ACTIVE INPUT/OUTPUT CONSOLE SO               53200021
*    ISSUE MESSAGE                                                      53300021
*/*ISSALLMG: P INDICATE ACCEPT VARY MSTCONS FROM ANYONE */              53400021
         OI    UCMMODE,UCMAMFA     INDICATE ACCEPT VARY MSTCONS         53500021
*                                       FROM ANYONE                     53600021
         DROP  RENTRY              BASE                                 53700021
         USING UCMLIST,RMCENT           MASTER CONSOLE                  53800021
*/*%OFMSAC: P TURN OFF MASTER'S ACTIVE FLAG */                          53900021
         NI    UCMATR,XFF-UCMUF    TURN OFF MASTER'S ACTIVE FLAG        54000021
*/*%OFFLMS: P TURN OFF FAILING IS MASTER FLAG */                        54100021
         NI    UCMSFLGS,XFF-UCMSYSD  TURN OFF FAILING IS                54200021
*                                       MASTER FLAG                     54300021
*/*%CLRDVTS: P CLEAR ALL DEVICE TESTED FLAGS */                         54400021
         BAL   RLINK,CLEARDVC      CLEAR ALL DEVICE TESTED BITS         54500021
         L     R0,MSGSIZE          GET SIZE AND SUBPOOL (SQA)           54600021
*/*%GM35PAR: S GETMAIN: GET CORE FOR WTO PARAMETER LIST */              54700021
         GETMAIN R,LV=(0)                                               54800021
         MVC   N0(MSGLGTH,R1),SOMEACTV  MOVE IN MSG AND OTHER           54900021
*                                       SVC 35 PARAMETERS               55000021
         LR    RWK1,R1             SAVE PARAMETER LIST ADDRESS          55100021
*/*%ISSWTO: S WTO:ISSUE MSG TO REQUEST V MSTCONS */                     55200021
         SVC   35                  ISSUE MESSAGE                        55300021
         LR    R1,RWK1             POINT TO PARAMETER LIST              55400021
         L     R0,MSGSIZE          GET SIZE AND SUBPOOL (SQA)           55500021
*/*%FREPAR: S FREEMAIN:FREE WTO PARAMETER LIST CORE */                  55600021
         FREEMAIN R,LV=(0),A=(1)                                        55700021
*/*%RET2: R RETURN */                                                   55800021
         BR    RRETURN             RETURN                               55900021
         EJECT                                                          56000021
*    A SEARCH IS MADE THROUGH THE UCM ENTRIES LOOKING FOR AN            56100021
*    ONLINE, UNALLOCATED CONSOLE THAT HAS A BELL.  THE DEVICE IS        56200021
*    OPENED BY XCTL'ING TO ITS PROCESSOR OR OPEN/CLOSE ROUTINE.         56300021
         SPACE                                                          56400021
         DROP  RMCENT              BASE                                 56500021
         USING UCMLIST,RENTRY           UCM ENTRY                       56600021
RINGBELL EQU   *                                                        56700021
*/*RINGBELL: D (YES,RING,NO,CANTRING) ANY CONSOLE WITH A BELL           56800021
*/*AVAILABLE*/                                                          56900021
         LM    RENTRY,RLAST,UCMVEA LOAD REGS FOR BXLE                   57000021
CK1052   EQU   *                                                        57100021
         CLC   UCMNAME+N3(N2),C1052150  Q. 1052 OR 2150                 57200021
         BE    RING                YES, GO RING BELL              20772 57300021
TRYNEXT  EQU   *                                                  20772 57400021
         BXLE  RENTRY,RSIZE,CK1052 LOOK THROUGH ALL ENTRIES       20772 57500021
TRYDIDOC EQU   *                                                  19029 57600021
         LM    RENTRY,RLAST,UCMVEA LOAD REGS FOR BXLE             19029 57700021
CHKDIDOC EQU   *                                                  19029 57800021
         TM    UCMDISP,UCMDISPC    Q. CRT CONSOLE                 19029 57900021
         BNO   DIDLAST             NO, GO LOOK AT NEXT ENTRY      19029 58000021
         L     RWK1,UCMUCB         GET UCB POINTER                19029 58100021
         CLI   N16(RWK1),C2260     Q. 2260                        19029 58200021
         BNO   RING                NO, GO RING BELL (2260 HAS NO  19029 58300021
*                                       BELL)                     19029 58400021
DIDLAST  EQU   *                                                  19029 58500021
         BXLE  RENTRY,RSIZE,CHKDIDOC  LOOK THROUGH ALL ENTRIES    19029 58600021
         B     CANTRING            NO CONSOLE WITH BELL           19029 58700021
*                                       FOUND - BRANCH            19029 58800021
RING     EQU   *                                                  20772 58900021
         L     RWK1,UCMUCB         GET UCB ADDRESS                20772 59000021
         TM    SRTESTAT(RWK1),X80  Q. ONLINE DEVICE               20772 59100021
         BNO   CHKMORE             NO, CHECK REST OF ENTRIES      20772 59200021
         TM    SRTESTAT(RWK1),X08  Q. DEVICE ALLOCATED            20772 59300021
         BO    CHKMORE            YES, CHECK REST OF ENTRIES  BE  M1420 59400021
*/*RING: D (YES,ALRDOPEN,NO,%INDOPN) IS CONSOLE OPEN ALREADY */         59500021
         L     RWK2,UCMDCB         PICK UP CONSOLE'S DCB POINTER  20772 59600021
         LTR   RWK2,RWK2           Q. IS THERE A DCB              20772 59700021
         BNZ   ALRDOPEN            YES, DON'T DO OPEN             20772 59800021
         ST    RUCM,CSACTLM        STORE UCM POINTER IN CXSA      M5383 59900021
*/*%INDOPN: P (,%INDNAME) INDICATE OPEN TO RING ALARM */                60000021
         OI    UCMSFLGS+N1,UCMSYSL INDICATE OPEN TO RING ALARM          60100021
         ST    RENTRY,CSAUCM       PUT ENTRY POINTER IN CXSA            60200021
         MVI   CSACODE,CSAOPEN     INDICATE OPEN IN CXSA                60300021
*/*%INDNAME: P (,XCTL) INDICATE XCTL TO MODULE TO OPEN DEVICE */        60400021
         MVC   CSANAME(N8),UCMNAME PUT DEVICE PROCESSOR NAME IN  S21003 60500021
*                                       CXSA                     S21003 60600021
         TM    UCMDISP,UCMDISPC    Q. CRT CONSOLE                S21003 60700021
         BO   CRTXCTL             YES, EXIT TO CRT PROCESSOR  BG A60169 60800021
         MVI   CSANAME+N4,I        NO, CHANGE NAME TO OPEN/CLOSE S21003 60900021
*                                       (IGC0I07B FOR 1052/2150) S21003 61000021
         B     XCTL                GO XCTL TO PROCESSOR TO OPEN  S21003 61100021
*                                       DEVICE                   S21003 61200021
CRTXCTL  EQU   *                                              BG A60169 61250021
         MVI   CSANAME+N4,G   CHANGE NAME OF DIDOCS(OPEN/CLOSE G A60169 61260021
*                              (IGC5GO7B)                     BG A60169 61270021
         B     XCTL          YES,EXIT TO CRT PROCESSOR        BG A60169 61280021
CHKMORE  EQU   *                                                  20772 61300021
         TM    UCMDISP,UCMDISPC    Q. CRT CONSOLE                 20772 61400021
         BO    DIDLAST             YES, CONTINUE SEARCHING CRT'S  20772 61500021
         B     TRYNEXT             LOOK FOR A 1052/2150           20772 61600021
         SPACE 3                                                        61700021
*    RETURN FROM OPEN                                                   61800021
*    RING BELL 3 TIMES AND RETURN TO SYSTEM                             61900021
         SPACE                                                          62000021
OPENRTN  EQU   *                                                        62100021
*/*OPENRTN: P INDICATE CLOSE PENDING FOR DEVICE JUST OPENED */          62200021
         LR    RENTRY,RFCENT       GET UCM ENTRY ADDRESS FOR            62300021
*                                       CONSOLE JUST OPENED             62400021
         OI    UCMSTS,UCMCF        INDICATE CLOSE PENDING FOR           62500021
*                                       THIS DEVICE                     62600021
*/*%OFOPAL: P (,ALRDOPEN) TURN OFF OPEN FOR ALARM FLAG */               62700021
         NI    UCMSFLGS+N1,XFF-UCMSYSL  TURN OFF OPEN FOR ALARM         62800021
         SPACE                                                          62900021
ALRDOPEN EQU   *                                                        63000021
*/*ALRDOPEN: P TURN OFF MASTER ACTIVE FLAG */                           63100021
         L     RWK2,UCMDCB         GET DCB POINTER                      63200021
         USING IHADCB,RWK2         BASE DCB                             63300021
         DROP  RENTRY              BASE                                 63400021
         USING UCMLIST,RMCENT           MASTER                          63500021
         NI    UCMATR,XFF-UCMUF    TURN OFF MASTER ACTIVE               63600021
         DROP  RMCENT              BASE CONSOLE FOR                     63700021
         USING UCMLIST,RENTRY           BELL                            63800021
         SR    RSIZE,RSIZE         CLEAR REG                            63900021
         IC    RSIZE,UCMINCR       SET BY NIP FOR EACH MACHINE          64000021
         L     RLAST,BXLEPARM      SET BXLE COMPARAND                   64100021
         LA    RSAVE,N3            BCT COUNTER TO RING ALARM            64200021
*                                       3 TIMES                         64300021
         L     R2,DMICPA           PICK UP CCW PTR            BE  M4918 64350021
RINGONG  EQU   *                                                        64400021
*/*RINGONG: P (,CANTRING) RING BELL THREE TIMES */                      64500021
         LA    RWK1,DMCGONG        POINT                                64600021
         ST    RWK1,DMICPA               IOB TO CCW                     64700021
         LA    R1,DMIOB            POINT TO IOB                         64800021
         SR    RWK1,RWK1           INITIALIZE INDEX FOR TIMING          64900021
*                                       LOOP                            65000021
         ST    RWK1,UCMECB         CLEAR CONSOLE ENTRY'S ECB            65100021
         EXCP  (1)                                                      65200021
         WAIT  ECB=UCMECB                                               65300021
         BXLE  RWK1,RSIZE,*        LOOP THROUGH INSTRUCTION FOR         65400021
*                                       3 SECONDS                       65500021
         BCT   RSAVE,RINGONG       RING ALARM 3 TIMES                   65600021
         ST    R2,DMICPA           RESTORE CCW PTR            BE A50237 65650021
CANTRING EQU   *                                                        65700021
*/*CANTRING: P INDICATE NO CONSOLES EXIST */                            65800021
         OI    UCMSFLGS,UCMSYSE   INDICATE NO CONSOLES EXIST            65900021
*/*%CLDVTES: P CLEAR DEVICE TESTED FLAGS */                             66000021
         BAL   RLINK,CLEARDVC      CLEAR DEVICE TESTED FLAGS            66100021
*/*%OFFSWMS: P TURN OFF SWITCH IS FOR MASTER */                         66200021
         NI    UCMSFLGS,XFF-UCMSYSD  TURN OFF SWITCH IS FOR             66300021
*                                       MASTER                          66400021
*/*%RET3: R RETURN */                                                   66500021
         BR    RRETURN             RETURN                               66600021
         EJECT                                                          66700021
*                        EXTERNAL INTERRUPT                             66800021
         SPACE                                                          66900021
EXTERNAL EQU   *                                                        67000021
*/*EXTERNAL: D (YES,NOCONS,NO,%INDMCFC) NO CONSOLES CONDITION */        67100021
         TM    UCMSFLGS,UCMSYSE    Q. NO CONSOLES CONDITION             67200021
         BO    NOCONS              YES, GO HANDLE NO CONSOLES           67300021
*/*%INDMCFC: P (,CONSFAIL) POINT FAILING CONSOLE POINTER TO MASTER */   67400021
         LR    RFCENT,RMCENT       PUT MASTER UCM ENTRY IN              67500021
*                                       FAILING CONSOLE REG             67600021
         B     CONSFAIL            GO TREAT AS NORMAL CONSOLE           67700021
*                                       SWITCH FROM MASTER              67800021
NOCONS   EQU   *                                                        67900021
*/*NOCONS: P INDICATE POST TO START SYSTEM */                           68000021
         MVI   UCMOECB,X40         INDICATE POST TO START SYSTEM        68100021
         DROP  RENTRY              BASE                                 68200021
         USING UCMLIST,RMCENT           MASTER CONSOLE                  68300021
*/*%MASACT: P FLAG MASTER AS ACTIVE */                                  68400021
         OI    UCMATR,UCMUF        INDICATE MASTER ACTIVE               68500021
*/*%OFFNOCN: P TURN OFF NO CONSOLES FLAG */                             68600021
         NI    UCMSFLGS,XFF-UCMSYSE  TURN OFF NO CONSOLES EXIST         68700021
*/*%RET1: R RETURN */                                                   68800021
         BR    RRETURN             RETURN                               68900021
         DROP  RMCENT                                                   69000021
         USING UCMLIST,RENTRY                                           69100021
         EJECT                                                          69200021
*****                                                             ***** 69300021
*    THIS ROUTINE CLEARS ALL DEVICE TESTED BITS IN UCM ENTRIES        * 69400021
*****                                                             ***** 69500021
         SPACE                                                          69600021
CLEARDVC EQU   *                                                        69700021
         LR    R0,RENTRY           SAVE RENTRY                          69800021
         LM    RENTRY,RLAST,UCMVEA  LOAD REGS FOR BXLE                  69900021
CLEARDV  EQU   *                                                        70000021
         NI    UCMDEVC,XFF-UCMDEVCC  CLEAR DEVICE TESTED FLAG           70100021
         BXLE  RENTRY,RSIZE,CLEARDV  LOOP THROUGH ALL UCM ENTRIES       70200021
         LR    RENTRY,R0           RESTORE RENTRY                       70300021
         BR    RLINK               RETURN FROM SUBROUTINE               70400021
         SPACE 3                                                        70500021
*****                                                             ***** 70600021
*    SWITCH USE OF CRT CONSOLE TO FULL CAPABILITY                     * 70700021
*****                                                             ***** 70800021
         SPACE                                                          70900021
SWFULCAP EQU   *                                                        71000021
         OI    UCMDISP,UCMDISPE    INDICATE FULL CAPABILITY      S21003 71100021
         NI    UCMDISP,XFF-UCMDISPD-UCMDISPF-UCMDISPG            S21003 71200021
*                                       TURN OFF OUTPUT ONLY,    S21003 71300021
*                                       MSG STREAM, AND STATUS   S21003 71400021
*                                       DISPLAY FLAGS            S21003 71500021
         NI    UCMSDS5,XFF-UCMSDS5G  TURN OFF I/O HARDWARE IN    S21003 71600021
*                                       O/O STATUS FLAG          S21003 71700021
         OI    UCMATR,UCMIF        INDICATE ATTENTION SUPPORT    S21003 71800021
         L     RWK1,UCMXB          BASE                          S21003 71900021
         USING RDCMDSEC,RWK1            RESIDENT DCM             S21003 72000021
         OI    DCMR3FLG,DCMSTSWT   INDICATE CHANGING STATUS      S21003 72100021
         DROP  RWK1                                              S21003 72200021
         BR    RLINK               RETURN FROM SUBROUTINE        S21003 72300021
         SPACE 3                                                        72400021
*****                                                             ***** 72500021
*                             XCTL                                    * 72600021
*****                                                             ***** 72700021
         SPACE                                                          72800021
CSXCTL   EQU   *                   EXIT TO OTHER CONSOLE SWITCH         72900021
*                                       MODULES                         73000021
         LR    R2,RENTRY           PUT ADDRESS OF INPUT HALF OF         73100021
*                                       NEW CONSOLE IN REG 2            73200021
XCTL     EQU   *                                                        73300021
*/*XCTL: R XCTL */                                                      73400021
         LR    RLINK,RINPUT        POINT REG 15 TO CXSA                 73500021
         XCTL  SF=(E,(15))                                              73600021
         EJECT                                                          73700021
*                             CONSTANTS                                 73800021
         SPACE                                                          73900021
SOMEACTV DC    X'00'               INDICATES WTO                        74000021
         DC    X'47'               LENGTH+4 OF MESSAGE                  74100021
         DC    X'8400'             BROADCAST TO ALL CONSOLES            74200021
         DC    C'IEE141A  MASTER AND ALL ALTERNATES UNAVAILABLE - '     74300021
         DC    C'ISSUE VARY MSTCONS'                                    74400021
         DC    X'10000000'         DESCRIPTOR CODE OF 4                 74500021
         DC    X'0000'             MSGTYPE = 0                          74600021
         SPACE                                                          74700021
BXLEPARM DC    F'9000000'          BXLE PARAMETER FOR TIMING LOOP       74800021
MSGSIZE  DC    X'FF000050'         80 BYTES IN SUBPOOL 255              74900021
SAVEAREA DC    X'FF000080'         32 WORDS IN SUBPOOL 255              75000021
CLEARADD DC    X'000007FF'         USED TO CLEAR CHA FIELD OF UCB       75100021
C1052150 DC    C'01'               NAME DESIGNATOR FOR 1052/2150        75200021
         EJECT                                                          75300021
*                             EQUATES                                   75400021
         SPACE                                                          75500021
N0       EQU   0                   NUMBER                               75600021
N1       EQU   1                   NUMBER                               75700021
N2       EQU   2                   NUMBER                               75800021
N3       EQU   3                   NUMBER                               75900021
N4       EQU   4                   NUMBER                               76000021
N5       EQU   5                   NUMBER                               76100021
N6       EQU   6                   NUMBER                               76200021
N7       EQU   7                   NUMBER                               76300021
N8       EQU   8                   NUMBER                               76400021
N9       EQU   9                   NUMBER                               76500021
N16      EQU   16                  NUMBER                               76600021
X80      EQU   X'80'               FLAG                                 76700021
X40      EQU   X'40'               FLAG                                 76800021
X08      EQU   X'08'               FLAG                                 76900021
XFF      EQU   X'FF'               TO TURN OFF BITS                     77000021
         SPACE                                                          77100021
MSGLGTH  EQU   77                  LENGTH OF ISSUE V MSTCONS MSG        77200021
SRTESTAT EQU   3                   STATUS FIELD OF UCB                  77300021
LOAD2    EQU   C'M'                IGCXM07B - SECOND LOAD OF            77400021
*                                       CONSOLE SWITCH                  77500021
LOAD4    EQU   C'O'                IGCXO07B - FOURTH LOAD OF            77600021
*                                       CONSOLE SWITCH                  77700021
C2260    EQU   X'11'               2260 DEVICE TYPE               19029 77800021
EQUAL    EQU   8                   BRANCH ON EQUAL                      77900021
I        EQU   C'I'                OPEN/CLOSE ROUTINE                   78000021
G        EQU   C'G'                DIDOCS OPEN/CLOSE ROUTINE  BG A60169 78050021
         EJECT                                                          78100021
UCM      DSECT                                                          78200021
         IEECUCM                                                        78300021
         EJECT                                                          78400021
WQEDSECT DSECT                                                          78500021
         IEECVMUG WQE                                                   78600021
         EJECT                                                          78700021
CVTDSECT DSECT                                                          78800021
         CVT                                                            78900021
         EJECT                                                          79000021
         IEEUCDX MAP                                                    79100021
         EJECT                                                          79200021
RDCMDSEC DSECT                                                          79300021
         IEECRDCM DSECT=YES                                             79400021
         EJECT                                                          79500021
CXSADSEC DSECT                                                          79600021
         IEECVMUG CXSA                                                  79700021
         SPACE 2                                                        79800021
* CONSOLE SWITCH MAPPING OF CXSA                                        79900021
*CSANPTR DS    F                                                        80000021
*CSADCBP DS    F                                                        80100021
*CSANAME DS    CL8                 XCTL NAME                            80200021
*CSAUCM  DS    0F                  FLAGS AND                            80300021
*                                  UCM ENTRY OF FAILING CONSOLE         80400021
*                                       OR NEW MASTER UCM ENTRY         80500021
*                                       (VARY MSTCONS)                  80600021
*CSACODE DS    C                   FLAGS                                80700021
CSACODE1 EQU   X'80'               RESERVED                             80800021
CSACODE2 EQU   X'40'               RESERVED                             80900021
CSACODE3 EQU   X'20'               RESERVED                             81000021
CSACODE4 EQU   X'10'               RESERVED                             81100021
CSAVMST  EQU   X'08'               VARY MSTCONS COMMAND                 81200021
CSAEXTI  EQU   X'04'               EXTERNAL INTERRUPT                   81300021
CSAHC    EQU   X'02'               SWITCH HARDCOPY FROM SYSLOG          81400021
*                                       TO MASTER CONSOLE               81500021
CSACODE8 EQU   X'01'               RESERVED                             81600021
*              X'00'               CONSOLE SWITCH                       81700021
*CSACTLM DS    F                   UCM POINTER                          81800021
*CSAXA   DS    F                                                        81900021
*CSAXB   DS    F                                                        82000021
*CSAXC   DS    D                                                        82100021
*/*IEECLCTX: END */                                                     82200021
         END                                                            82300021
