         TITLE 'IGCXM07B SECOND LOAD OF CONSOLE SWITCH'                 00300018
IEECMCTX CSECT                                                          00500018
*MODULE CREATED FOR MCS - REL 18                                        00700018
         BALR  RBASE,0       ESTABLISH ADDRESSABILITY                   00900018
         USING *,RBASE                                                  01200018
         SSM   *+1    DISABLE                                           01300018
         LR    RWK3,RINPUT        SAVE INPUT REG                        01500018
         USING UCM,RUCM                                                 01800018
         USING MCSUCM,RUCMMCS                                           02100018
OBTAINWQ STM   RINPUT,R0,0(RSAVE)       SAVE REGS                       02400018
         L     R0,WQE2          SIZE OF 2 WQE'S IN SP 255               02700018
         GETMAIN  R,LV=(0)                                              03000018
         LM    R2,R0,4(RSAVE)           RESTORE REGS                    03300018
         LR    RMES,RINPUT              GETMAINED AREA                  03600018
         XC    0(168,RMES),0(RMES) BLANK OUT FIRST WQE AREA     A32561  03660000
         LA    RMES,168(RMES)      UPDATE POINTER               A32561  03720000
         XC    0(168,RMES),0(RMES) BLANK OUT SECOND WQE AREA    A32561  03780000
         LR    RMES,RINPUT                                      A32561  03840000
         USING MESSAGES,RMES                                            03900018
         MVC   SWMSGWQ1(77),DSMSGWQ1   MOVE IN MESSAGE TEXT             04200018
         MVC   SWMSGWQ2(79),DSMSGWQ2   MOVE IN MESSAGE TEXT             04500018
         MVC   SWMSGED1(28),DSMSGED1 MOVE IN WQE INFO                   04800018
         MVC   SWMSGED2(28),DSMSGED2 MOVE IN WQE INFO                   05100018
         L     RWK1,XCMUCB(RUCME) PICK UP ADDRESS OF FAILING INPUT      05400018
         TM    UCMSFLGS+1,X'08'  IS OLD COMPOSITE                       05700018
         BZ    OLDNOCP             NO                                   06000018
         MVC   SWMSG1+OLD(8),COMPOSIT   MOVE IN COMPOSITE INFO          06300018
         MVC   SWMSG1+OLDI(3),UCBNAME(RWK1)  MOVE IN ADDRESS            06600018
         L     RWK1,XCMUCB(RFAILOUT)         OUTPUT UCB                 06900018
         MVC   SWMSG1+OLDO(3),UCBNAME(RWK1)  OLD ADDRESS IN MESSAGE     07200018
         B     GETNEW                        NEW ADDRESS                07500018
OLDNOCP  MVC   SWMSG1+OLD(3),UCBNAME(RWK1)  MOVE IN ADDRESS             07800018
GETNEW   L     RWK1,XCMUCB(RWK)     ADDRESS OF UCM INPUT                08100018
         TM    UCMSFLGS+1,X'20'    NEW CONSOLE CONSOLE COMPOSITE        08400018
         BZ    NEWNOCP                                                  08700018
         MVC   SWMSG1+NEW(8),COMPOSIT  COMPOSITE INFO                   09000018
         MVC   SWMSG1+NEWI(3),UCBNAME(RWK1)  MOVE IN ADDRESS            09300018
         L     RWK1,XCMUCB(RNEWOUT)          OUTPUT UCB ADDRESS         09600018
         MVC   SWMSG1+NEWO(3),UCBNAME(RWK1)  MOVE IN ADDRESS            09900018
         B     VALDCMDS                                                 10200018
NEWNOCP  MVC   SWMSG1+NEW(3),UCBNAME(RWK1) MOVE IN ADDRESS              10500018
VALDCMDS TM    XCMDISP(RNEWOUT),X'10'        OUTPUT ONLY                11100018
         BZ    INPUTDV                       NO                         11400018
         MVC   SWMSG1+VLDCMD(4),NOINPUT      MOVE IN NONE VALID         11700018
         B     ROUTCDE                       CHECK ROUTING CODES        12000018
INPUTDV  TM    XCMAUTH(RWK),X'E0'  ALL COMMANDS VALID                   12300018
         BC    12,SOMEVLD                                               12600018
         MVC   SWMSG1+VLDCMD(3),ALL          MOVE IN ALL                12900018
         B     ROUTCDE                       CHECK ROUTING CODES        13200018
SOMEVLD  MVC   SWMSG1+VLDCMD(4),INFO    INFO IS DEFAULT                 13500018
         LA    RWK1,SWMSG1+VLDCMD+4     NEXT SLOT IN MESSAGE            13800018
         TM    XCMAUTH(RWK),X'80'  SYS VALID                            14100018
         BZ    NEXTCMD                  NO                              14400018
         MVC   0(4,RWK1),SYS            MOVE IN SYS VALID               14700018
         LA    RWK1,4(RWK1)             INCREMENT MESSAGE AREA          15000018
NEXTCMD  TM    XCMAUTH(RWK),X'40'  I/O VALID                            15300018
         BZ    NEXTCMD1                 NO                              15600018
         MVC   0(4,RWK1),IO             MOVE IN I/O VALID               15900018
         LA    RWK1,4(RWK1)             INCREMENT MESSAGE AREA          16200018
NEXTCMD1 TM    XCMAUTH(RWK),X'20'  CONSOLE VALID                        16500018
         BZ    ROUTCDE                  NO                              16800018
         MVC   0(5,RWK1),CONS           MOVE IN I/O VALID               17100018
ROUTCDE  LA    RWK1,SWMSG2+ROUTCD  ROUTING AREA OF MESSAGE              17400018
         CLC   XCMRTCD(2,RNEWOUT),ONES ARE ALL SPECIFIED                17700018
         BE    ALLROUTC            YES                                  18000018
         SR    RWK4,RWK4      ZERO REG                                  18300018
         CH    RWK4,XCMRTCD(RNEWOUT) ARE ANY SPECIFIED                  18600018
         BE    NOROUTCD            YES                                  18900018
         LA    RWK2,16             NUMBER OF ROUTING CODES FOR BCT      19200018
         LA    RWK4,ROUTABLE       TABLE OF ROUTING CODES               19500018
         L     RWK3,XCMRTCD(RNEWOUT) PICK UP ROUTING CODES              19800018
NEXTROUT ST    RWK3,UCMRUTCK  CHECKING AREA                             20100018
         TM    UCMRUTCK,X'80'  DOES ROUTING CODE EXIST                  20400018
         BZ    NOTROUT             NO                                   20700018
         MVC   0(3,RWK1),0(RWK4)   MOVE IN ROUTING CODE                 21000018
         LA    RWK1,3(RWK1)        NEXT MESSAGE AREA                    21300018
NOTROUT  LA    RWK4,3(RWK4)        NEXT CODE IN TABLE                   21600018
         SLL   RWK3,1         PICK  UP NEXT ROUTIN CODE                 21900018
         BCT   RWK2,NEXTROUT                                            22200018
TYPECK   TM    XCMDISP(RWK),X'80'  MASTER CONSOLE                       22500018
         BZ    NOMSGMAS               NO                                22800018
         MVI   SWMSG2+TYPE,C'M'       MOVE IN MASTER                    23100018
         B     CKHDCPY                CHECK HARDCPY                     23400018
NOMSGMAS MVI   SWMSG2+TYPE,C'S'       INDICATE SECONDARY                23700018
CKHDCPY  TM    XCMDISP(RNEWOUT),X'40' HARDCPY                           24000018
         BZ    NOHDCPYM               NO                                24300018
         MVI   SWMSG2+HCPY,C'Y'         INDICATE YES HARDCOPY           24600018
         B     QUEUEMSG            GO TO QUEUE THE MESSAGE              24900018
ALLROUTC MVC   0(3,RWK1),ALL       PLACE ALL IN MSG                     25200018
         B     TYPECK              CHECK TYPE                           25500018
NOROUTCD MVC   0(4,RWK1),NONE PLACE NONE IN MESSAGE                     25800018
         B     TYPECK              CHECK TYPE                           26100018
NOHDCPYM MVI   SWMSG2+HCPY,C'N'                                         26400018
QUEUEMSG MVC   SWMSG1ID(1),XCMID(RNEWOUT)    PLACE ID IN WQE            26700018
         MVC   SWMSG2ID(1),XCMID(RNEWOUT)    OF MESSAGES                27000018
         LA    RWK3,SWMSGWQ2       ADDRESS OF SECOND WQE                27300018
         ST    RWK3,SWMSGWQ1       CHAIN WQE'S                          27600018
         SSM   *+1         DISABLE                                      27900018
         TM    UCMMODE,X'01'    FIXED MODE                              28000018
         BO    FIXEDMOD   YES DON'T INCREMENT                           28100018
         L     RWK3,UCMRQNR  WQE COUNT                                  28200018
         LA    RWK3,2(RWK3)   UP COUNT BY 2                             28500018
         STH   RWK3,UCMWQNR   STORE UPDATED COUNT                       28800018
FIXEDMOD L     RWK3,UCMWQEND  END OF SYSTEM QUEUE                       29100018
         LTR   RWK3,RWK3           ANY NOW QUEUED                       29400018
         BZ    NONEQUED            NO QUEUE FIRST                       29700018
         IC    RWK4,0(RWK3)        SAVE USE COUNT                       30000018
         LA    RINPUT,SWMSGWQ1     FIRST WQE                            30300018
         ST    RINPUT,0(RWK3)      ADD ONTO QUEUE                       30600018
         STC   RWK4,0(RWK3)        RESTORE USE COUNT                    30900018
         LA    RWK3,SWMSGWQ2       SECOND WQE                           31200018
         ST    RWK3,UCMWQEND       STORE IN LAST                        31500018
         B     QONUCME             GO QUEUE ONTO UCM ENTRIES            31800018
NONEQUED LA    RINPUT,SWMSGWQ1     FIRST MESSAGE                        32100018
         ST    RINPUT,UCMWTOQ      PLACE ON FIRST                       32400018
         LA    RWK4,SWMSGWQ2       SECOND                               32700018
         ST    RWK4,UCMWQEND       SECOND IN LAST                       33000018
QONUCME  LR    R2,RUCM             FOR QUEUING ROUTINE                  33300018
         L     RLINK,UCMQRTN      ADDR OF RESIDENT QUEUE ROUTINE        33600018
         LR    RWK4,RRETURN       SAVE RETURN REG                       33900018
         MVC   64(64,RSAVE),UCMSAVE0+4  SAVE Q ROUTINE SAVE AREA        33960018
***    IEECMDSV  MAY HAVE USED UCMSAVE0 DEPENDING ON WHY THE SWITCH     34020018
***  ROUTINE WAS CALLED.  IEECMENQ ALSO USES UCMSAVE0 SO UCMSAVE0 MUST  34080018
****    BE SAVED OVER THIS LINK                                         34140018
         BALR  RRETURN,RLINK       GET MESSAGE QUEUED TO DEVICE         34200018
         LA    RINPUT,WQESIZE(RINPUT)   NEXT MESSAGE                    34500018
         L     RLINK,UCMQRTN    QUEUE ROUTINE ADDR                      34800018
         BALR  RRETURN,RLINK       QUEUE SECOND MESSAGE                 35100018
         LR    RRETURN,RWK4        RESTORE RETURN REGISTER              35400018
         MVC   UCMSAVE0+4(64),64(RSAVE)   RESTOR UCMSAVE0 TO ORIGINAL   35500018
         L     RINPUT,0(RSAVE)     RESTORE INPUT REG                    35700018
         USING CXSADSEC,RINPUT                                          36000018
         TM    CSACODE,X'08'   VARY MSTCONS                             36060018
         BZ    MSTNOT      NO CONTINUE                                  36120018
         TM    UCMMODE,X'08'   DID SYSTEM REQUEST VARY                  36180018
         BO    MSTNOT    YES CONTINUE                                   36240018
         NI    UCMSFLGS+1,X'D7'  CLEAR COMPOSITE INDICATORS             36300018
         NI    UCMSFLGS,X'EF'  CLEAR MASTER INDICATOR                   36360018
         LR    RINPUT,RSAVE                                             36420018
         L     R0,SAVEAREA                                              36480018
         FREEMAIN    R,LV=(0),A=(1)                                     36540018
         MVI   UCMOECB,X'40'   INDICATE WTO TO BE DONE                  36600018
         BR    RRETURN   RETURN                                         36660018
MSTNOT   LR    RLINK,RINPUT       FOR XCTL                              36720018
         MVC   CSANAME(8),LOAD3   NEXT LOAD TO BE XCTL'D TO             36900018
         XCTL  SF=(E,(15))                                              37200018
*****    DUMMY  WQE'S TO USE AS MAP FOR MESSAGES                 ****** 37500018
DSMSGWQ1 DC    F'0'      POINTER TO NEXT WQE                            37800018
         DC    F'68'    MESSAGE LENGTH                                  38100018
DSMSG1   DC    C' IEE143I OLD=             NEW=         '               38400018
         DC       C'   VALDCMD=                  '                      38700018
DSMSGED1 DS    0F                                                       39000018
         DC    X'00000010'    INDICATES BUFFER OBTAINED DYNAMICALLY     39300018
         DC    F'0'           RESERVED FOR RO/RI                        39600018
         DC    F'0'           ID SEQUENCE NUMBER                        39900018
          DC   X'C000'        MCS FLAGS                                 40200018
         DC    H'0'           MSGTYPE FLAGS                             40500018
         DC    X'40000000'   ROUTING CODE OF 2                          40800018
DSMSG1ID DC    F'0'           ENTRY ID                                  41100018
         DC    X'1000'   DESC CODE OF 4                                 41400018
         DC    H'0'           RESERVED                                  41700018
         DC    F'0'           TIME ELEMENT                              42000018
DSMSGWQ2 DC    F'0'      POINTER TO NEXT WQE                            42300018
         DC    F'71'   LENGTH OF MESSAGE                                42600018
DSMSG2   DC    C' IEE143I ROUTCDE=                       '              42900018
         DC    C'                       T=  H=  '                       43200018
DSMSGED2 DS    0F                                                       43500018
         DC    X'00000010'    INDICATES BUFFER OBTAINED DYNAMICALLY     43800018
         DC    F'0'           RESERVED FOR RO/RI                        44100018
         DC    F'0'           ID SEQUENCE NUMBER                        44400018
         DC    X'C000'        MCS FLAGS                                 44700018
         DC    H'0'           MSGTYPE FLAGS                             45000018
         DC    X'40000000'   ROUTING CODE OF 2                          45300018
DSMSG2ID DC    F'0'           ENTRY ID                                  45600018
         DC    X'1000'   DESC CODE OF 4                                 45900018
         DC    H'0'           RESERVED                                  46200018
         DC    F'0'           TIME ELEMENT                              46500018
ZEROES   DC    F'0'                FULL WORD OF ZEROES FOR COMPARISONS  46800018
WQE2     DC    X'FF000150'    2 WQE'S FROM SP 255                       47100018
SAVEAREA DC    X'FF000080' SIZE OF 32 WORD SAVE AREA IN SP 255          47400018
LOAD3    DC    C'IGCXN07B'      THIRD LOAD OF CONSOLE SWITCH            47700018
BXLEPARM DC    F'9000000'          BXLE PARMETER FOR TIMING LOOP        48000018
         DS    0F                                                       48300018
COMPOSIT DC    C'I-   ,O-'         COMPOSITE MASK FOR SWITCH MESSAGE.   48600018
NOINPUT  DC    C'NONE'             VALID                                48900018
ALL      DC    C'ALL'                COMMANDS                           49200018
INFO     DC    C'INFO'                 FOR                              49500018
SYS      DC    C',SYS'                 SWITCH                           49800018
IO       DC    C',I/O'                  MESSAGE                         50100018
CONS     DC    C',CONS'                                                 50400018
NONE     DC    C'NONE'               OUTPUT                             50700018
ONES     DC    X'FFFFFFFF'    FOR COMPARISONS                           51000018
ROUTABLE DC    C'  1'    TABLE                                          51300018
         DC    C', 2'                                                   51600018
         DC    C', 3'                                                   51900018
         DC    C', 4'      OF                                           52200018
         DC    C', 5'                                                   52500018
         DC    C', 6'                                                   52800018
         DC    C', 7'       ROUTING                                     53100018
         DC    C', 8'                                                   53400018
         DC    C', 9'                                                   53700018
         DC    C',10'        CODES                                      54000018
         DC    C',11'                                                   54300018
         DC    C',12'         FOR                                       54600018
         DC    C',13'                                                   54900018
         DC    C',14'          SWITCH                                   55200018
         DC    C',15'                                                   55500018
         DC    C',16'           MESSAGE                                 55800018
R0       EQU   0    WORK REG                                            56100018
RGWK1    EQU   0         WORK REG WHEN SWITCHING HARDCOPY               56400018
RINPUT   EQU   1    INPUT PARAMETER REGISTER                            56700018
RWK      EQU   2    WORK REGISTER                                       57000018
R2       EQU   2         SAVE REG                                       57300018
RSAVE    EQU   3           SAVE REG                                     57600018
RCVT     EQU   3    CVT REG                                             57900018
RUCMMCS  EQU   4    UCM MCS BASE REG                                    58200018
RWK2     EQU   5    THIRD WORK REGISTER                                 58500018
RNEWOUT  EQU   6    NEW OUTPUT ENTRY REG ON SWITCH                      58800018
RFAILOUT EQU   7    OUTPUT FAILING CONSOLE ENTRY REG                    59100018
RWK1     EQU   8    SECOND WORK REGISTER                                59400018
RUCME    EQU   9    UCM ENTRY REGISTER                                  59700018
RUCM     EQU   10   UCM BASE REGISTER                                   60000018
RBASE    EQU   11   BASE REGISTER                                       60300018
RWK4     EQU   12   WORK REGISTER                                       60600018
RWK3     EQU   13   WORK REGISTER                                       60900018
RRETURN  EQU   14   RETURN REGISTER                                     61200018
RETURNRG EQU   14   RETURN REGISTER                                     61500018
RLINK    EQU   15   LINKING REGISTER                                    61800018
RMES     EQU   15   BASE ADDRESS OF MESSAGES                            62100018
RGWK2    EQU   15        WORK REG WHEN SWITCHING HARDCOPY               62400018
EXTINPUT EQU   4    LOW CORE ADDRESS OF AREA STORED IN BY OPERATOR OF   62700018
*                   NEW MASTER IN A NO CONSOLES CONDITION               63000018
CVTA     EQU   16   CVT ACTUAL ADDRESS                                  63300018
UCBCHA   EQU   4    OFFSET TO CHANNEL AND UNIT ADDRESS IN UCB           63600018
UCBNAME  EQU   13   NAME FIELD OF UCB                                   63900018
OLD      EQU   13   OLD ADDRESS AREA OF SWITCH MESSAGE                  64200018
ROUTCD   EQU   17   ROUTING CODE MESSAGE AREA OF SWMSG2                 64500018
OLDI     EQU   15   OLD INPUT AREA OF SWITCH MESSAGE                    64800018
OLDO     EQU   21   OLD OUTPUT AREA OF SWITCH MESSAGE                   65100018
NEWI     EQU   32   NEW INPUT AREA OF SWITCH MESSAGE                    65400018
NEW      EQU   30   NEW ADDRESS AREA OF SWITCH MESSAGE                  65700018
NEWO     EQU   38   NEW OUTPUT AREA OF SWITCH MESSAGE                   66000018
VLDCMD   EQU   51   VALID COMMAND AREA OF SWITCH MESSAGE                66300018
TYPE     EQU   65   TYPE AREA OF SWMSG2 MESSAGE                         66600018
HCPY     EQU   69   HARDCOPY AREA OF SWMSG2 MESSAGE                     66900018
***  INDIVIDUAL UCM  ENTRY MAP  ***                                     67200018
XCMECB   EQU   0    I/O COMPLETION ECB                                  67500018
XCMSRB   EQU   4    POINTER TO RESIDENT PROCESSOR MODULE                67800018
XCMDCB   EQU   8    POINTER TO DCB                                      68100018
XCMUCB   EQU   12   POINTER TO UCB                                      68400018
XCMNAME  EQU   16   PROCESSING MODULE NAME                              68700018
XCMSTS   EQU   24      SATAUS FLAGS                                     69000018
XCMATR   EQU   25   ATTRIBUTE FLAGS                                     69300018
XCMID    EQU   26   UNIQUE IDENTIFIER FOR EACH ENTRY                    69600018
XCMXB    EQU   28   POINTER TO DCM FOR GRAPHICS                         69900018
XCMRTCD  EQU   32   ROUTING CODES                                       70200018
XCMOUTQ  EQU   36   POINTER TO OUTPUT QUEUE                             70500018
XCMAUTH  EQU   40   COMMAND CODE AUTHORIZATION                          70800018
XCMDISP  EQU   42   DISPOSITION FLAGS                                   71100018
XCMALTEN EQU   44   POINTER TO ALTERNATE UCM ENTRY                      71400018
XCMOADEN EQU   48            POINTER TO ALTERNATE OUTPUT ENTRY          71700018
XCMWLAST EQU   52   LAST WQE SERVICED IN OUTPUT QUEUE                   72000018
XCMCOMPC EQU   56    POINTER TO OTHER HALF IF A COMPOSITE CONSOLE       72300018
XCMMSG   EQU   60   MESSAGE TYPE FLAGS                                  72600018
XCMXOR   EQU   62   EXCLUSIVE OR FIELD FOR UCB                          72900018
XCMDEVC  EQU   63   DEVICE CONTROL FLAGS                                73200018
XCMINPUT EQU   64   INPUT AREA - FIXED MODE ONLY                        73500018
***  WQE EQUATES  RQE EQUATES                                           73800018
XWQEXA   EQU   136       DISPOSITION FLAGS OF WQE                       74100018
XWQUCMID EQU   156       UCMID FIELD OF WQE                             74400018
XRQLKP   EQU   0         LINK POINTER OF  RQE                           74700018
XRQWQE   EQU   12       WQE POINTER                                     75000018
MESSAGES DSECT                                                     **** 75300018
SWMSGWQ1 DC    F'0'      POINTER TO NEXT WQE                            75600018
         DC    F'69'       MESSAGE LENGTH                               75900018
SWMSG1   DC       C'IEEXXXY  OLD=             NEW=         '   TEXT     76200018
         DC       C'   VALDCMD=                 '                       76500018
         ORG   SWMSGWQ1+136                                             76800018
SWMSGED1 DS    0F                                                       77100018
         DC    X'00000010'    INDICATES BUFFER OBTAINED DYNAMICALLY     77400018
         DC    F'0'           RESERVED FOR  RO/RS                       77700018
         DC    F'0'           ID SEQUENCE NUMBER                        78000018
         DC    X'0100'        MCS FLAGS                                 78300018
         DC    H'0'           MSGTYPE FLAGS                             78600018
         DC    F'0'           ROUTING CODES                             78900018
SWMSG1ID DC    F'0'           ENTRY ID                                  79200018
         DC    X'0004'        DESCRIPTOR CODE OF 3                      79500018
         DC    H'0'           RESERVED                                  79800018
         DC    F'0'           TIME ELEMENT                              80100018
SWMSGWQ2 DC    F'0'      POINTER TO NEXT WQE                            80400018
         DC    F'71'       MESSAGE LENGTH                               80700018
SWMSG2   DC       C'IEEXXXX  ROUTCDE=                       ' TEXT      81000018
        DC     C'                       T=  H=  '                       81300018
         ORG   SWMSGWQ2+136                                             81600018
SWMSGED2 DS    0F                                                       81900018
         DC    X'00000010'    INDICATES BUFFER OBTAINED DYNAMICALLY     82200018
         DC    F'0'           RESERVED FOR RO/RI                        82500018
         DC    F'0'           ID SEQUENCE NUMBER                        82800018
         DC    X'0100'        MCS FLAGS                                 83100018
         DC    H'0'           MSGTYPE FLAGS                             83400018
         DC    F'0'           ROUTING CODES                             83700018
SWMSG2ID DC    F'0'           ENTRY ID                                  84000018
         DC    X'0004'        DESCRIPTOR CODE OF 3                      84300018
         DC    H'0'           RESERVED                                  84600018
         DC    F'0'           TIME ELEMENT                              84900018
UCM      DSECT                                                          85200018
         IEECUCM                                                        85500018
WQEDSECT DSECT                                                          85800018
         IEECVMUG WQE                                                   86100018
RQEDSECT DSECT                                                          86400018
         IEECVMUG  RQE                                                  86700018
CXSADSEC DSECT                                                          87000018
         IEECVMUG CXSA                                                  87300018
CVTDSECT DSECT                                                          87600018
         CVT                                                            87900018
  END                                                                   88200018
