         TITLE 'IGCXN07B THIRD LOAD OF CONSOLE SWITCH'                  00300018
IEECNCTX CSECT                                                          00500018
*A562768,C683700                                              MG  M1446 00502021
*A560904-560908                                               MG  M1438 00510021
*C560980                                                      MG  M1422 00520021
*A560720,C560800-560900,A563360,D683800-683920                MG  M0639 00550021
*MODULE CREATED FOR MCS - REL 18                                        00700018
*024000,144000,181000             COMBINE OUTPUT QUEUES          A28030 00800019
         BALR  RBASE,0       ESTABLISH ADDRESSABILITY                   00900018
         USING *,RBASE                                                  01200018
         SSM   *+1    DISABLE                                           01300018
         USING UCM,RUCM                                                 01500018
         USING MCSUCM,RUCMMCS                                           01800018
         L     RWK1,UCMRPYQ        REPLY QUEUE CHAIN                    02100018
         SR    RWK2,RWK2           ZERO COUNTER                  A28030 02300019
         SR    R0,R0               ZERO LAST ENTRY POINTER       A28030 02500019
NEXTRQE  LTR   RWK1,RWK1           CHECK FOR ANY RQE'S                  02700018
         BZ    AROUND              NO REPLIES OUTSTANDING               03000018
         L     RWK3,XRQWQE(RWK1)   WQE ASSOCIATED WITH RQE              03300018
         LA    RWK3,ZERO(RWK3)    CLEAR TJID FIELD FROM REG   BE  M1425 03370021
         LTR   RWK3,RWK3          Q. HAS WQE BEEN GOTTEN YET  BE  M1425 03440021
         BZ    GETNXTRP           NO, GET NEXT RPQE           BE  M1425 03510021
         USING WQEF,RWK3                                                03600018
         TM    WQEMCSF,X'40'  UNIQUE ENTRY ID USED                      03900018
         BZ    CKCDROUT            NO CHECK ROUTING CODES               04200018
         CLC   WQEUCMID(1),XCMID(RFAILOUT)  THIS ID USED                04500018
         BNE   CKCDROUT            NO CHECK ROUTING CODE                04800018
         MVC   WQEUCMID(1),XCMID(RNEWOUT)  CHANGE ID TO NEW             05100018
         B     FOUND                                                    05400018
CKCDROUT L     RLINK,WQEROUT   MOVE ROUTING CODE TO CHECKING REG        05700018
         N     RLINK,XCMRTCD(RFAILOUT)   ROUTING CODE MATCH             06000018
         BC    7,FOUND             YES MATCH OF ROUTING CODES           06300018
GETNXTRP EQU   *                                              BE  M1425 06400021
         L     RWK1,XRQLKP(RWK1)   NEXT RQE                             06600018
         B     NEXTRQE             CHECK THE NEXT RQE                   06900018
FOUND    LTR   RWK2,RWK2           IS THIS FIRST OF A GROUP             07200018
         BNZ   QSTARTED            NO A QUEUE EXISTS                    07500018
         STM   RINPUT,R0,0(RSAVE)      SAVE ALL REGISTERS               07800018
         L     R0,GETQUEUE         MASK FOR GETMAIN                     08100018
         GETMAIN  R,LV=(0)         GET SIZE OF ONE QUEUE                08400018
         LM    R2,R0,4(RSAVE)     RESTORE REGS                          08700018
          LR    RWK4,RINPUT        ADDRESS OF AREA GETMAINED            09000018
         L     RINPUT,0(RSAVE)          RESTORE INPUT REGS              09300018
         XC    0(24,RWK4),0(RWK4)   ZERO QUEUE AREA JUST OBTAINED       09600018
         MVI   20(RWK4),X'C0'   INDICATE EOB FOR DSV                    09700018
         L     RUCME,XCMOUTQ(RFAILOUT)  PTR TO OUTPUT QUEUE             09900018
         LTR   RUCME,RUCME              ANYTHING ON QUEUE               10200018
         BNZ   QEXISTS                  BRANCH IF YES                   10500018
         ST    RWK4,XCMOUTQ(RFAILOUT)   PLACE POINTER ONTO Q            10800018
         B     QSTARTED                 QUEUE STARTED                   11100018
QEXISTS  TM    0(RUCME),X'C0'           LAST OR END OF BLOCK ENTRY      11400018
         BM    LAST                     LAST ENTRY                      11700018
         BO    EOB                      END OF THIS BLOCK               12000018
         LA    RUCME,4(RUCME)            PICK UP NEXT ENTRY             12300018
         B     QEXISTS                  CHECK NEXT QUEUE ENTRY          12600018
EOB      L     RUCME,0(RUCME)           PICK UP NEXT BLOCK              12900018
         B     QEXISTS                  CONTINUE SEARCH                 13200018
LAST     ST    RWK4,4(RUCME)    ADD NEW ON                              13400018
         MVI   4(RUCME),X'C0'  INDICATE EOB                             13600018
         NI    0(RUCME),X'7F'  TURN OFF LAST INDICATOR                  13800018
QSTARTED ST    RWK3,0(RWK4)             PLACE WQE PTR IN QUEUE          14100018
         MVI   0(RWK4),X'01'       ENTRY EXISTS                  A28030 14300019
         LR    R0,RWK4             R0 = LAST ENTRY ADDED         A28030 14500019
         LA    RWK4,4(RWK4)   NEXT ENTRY                                14700018
         L     RWK1,XRQLKP(RWK1)   NEXT RQE                             15000018
         LA    RWK2,1(RWK2)             UPDATE COUNTER                  15300018
         IC    RUCME,0(RWK3)            USE COUNT OF WQE                15600018
         LA    RUCME,1(RUCME)           ADD ONE                         15900018
         STC   RUCME,0(RWK3)       RESTORE USE COUNT                    16200018
         LA    RWK3,5  ENTRIES IN OUTPUT Q                              16500018
         CR    RWK2,RWK3           END OF QUEUE                         16800018
         BNE   NEXTRQE             PICK UP NEXT RQE                     17100018
         LA    RWK3,ENTSIZE  PUT SIZE OF CONSOLE ENTRY IN REG    A36203 17170020
         SR    RWK4,RWK3     GET PTR TO LAST ENTRY PUT IN QUEUE  A36203 17240020
         OI    0(RWK4),X'80' INDICATE LAST WQE ENTRY IN QUEUE    A36203 17310020
         LA    RWK2,0              ZERO COUNTER                         17400018
         B     NEXTRQE             CHECK NEXT RQE                       17700018
AROUND   LTR   R0,R0               TEST FOR RQE'S ADDED          A28030 17800019
         BZ    JBRCTR              NO, BYPASS ORING.NO WORK DONE A28030 17900019
         LR    RGWK2,R0            R15 = ADDR LAST WQE BLOCK     A28030 18000019
         OI    0(RGWK2),X'80'      INDICATE LAST                 A28030 18100019
JBRCTR   L     RUCME,XCMOUTQ(RFAILOUT) OUTPUT QUEUE              A28030 18200019
         LTR   RUCME,RUCME         ANYTHING IN QUEUE                    18600018
         BZ    DUPSRCH       NO CHECK FOR DUPLICATES                    18900018
NEXTQEN  TM    0(RUCME),X'01'      VALID ENTRY                          19200018
         BZ    CKQEND              NO CHECK FOR EOB OR LAST             19500018
         TM    0(RUCME),X'02'  NO LONGER NEEDED ON                      19800018
         BO    CKQEND    YES CHECK FOR END OF QUEUE                     20100018
         L     RWK3,0(RUCME)       PICK UP WQE                          20400018
         TM    ZERO(RUCME),MLWTO   IS THIS AN MLWTO           MG S21002 20450021
         BO    ML1                 YES                        MG S21002 20500021
ML0      EQU   *                                              MG S21002 20600021
         TM    WQEMCSF,X'40'   UNIQUE ID USED FOR THIS WQE              20700018
         BZ    CKQEND              NO                                   21000018
         CLC   WQEUCMID(1),XCMID(RFAILOUT)  ID OF FAILING               21300018
         BNE   CKQEND              NO                                   21600018
         MVC   WQEUCMID(1),XCMID(RNEWOUT)   PLACE NEW ID IN             21900018
         B     CKQEND   CHECK FOR END                                   22000018
NEXTENTR LA    RUCME,4(RUCME)      NEXT ENTRY                           22200018
         B     NEXTQEN             CHECK NEXT ENTRY                     22500018
CKQEND   TM    0(RUCME),X'C0'      CHECK FOR EOB OR LAST                22800018
          BM    SWAPQ              LAST SWAP QUEUE                      23100018
         BO    EOB1                EOB PICK UP NEXT BLOCK               23400018
         B     NEXTENTR            CHECK NEXT                           23700018
EOB1     L     RUCME,0(RUCME)      PICK UP NEXT BLOCK                   24000018
         B     NEXTQEN             CHECK NEXT BLOCK                     24300018
SWAPQ    L     RUCME,XCMOUTQ(RFAILOUT)  OUTPUT QUEUE OF OLD             24400018
         LTR   RUCME,RUCME     ANYTHING ON QUEUE                        24500018
         BZ    DUPSRCH      NO CHECK FOR DUPLICATES                     24600018
         L     RWK3,XCMOUTQ(RNEWOUT)  OUTPUT QUEUE OF NEW               24700018
         LTR   RWK3,RWK3           ANY OUTPUT QUEUE                     24900018
         BNZ   YESADDON            YES                                  25200018
         MVC   XCMOUTQ(4,RNEWOUT),XCMOUTQ(RFAILOUT)  ADD OLD Q TO NEW   25500018
         B     DUPSRCH             SEARCH FOR DUPLICATES                25800018
         DROP  RWK3                                                     26100018
YESADDON TM    0(RWK3),X'C0'       LOOK FOR EOB OR LAST                 26400018
         BO    EOB2                EOB                                  26700018
         BM    LAST2               LAST                                 27000018
         LA    RWK3,4(RWK3)        PICK UP NEXT ENTRY                   27300018
         B     YESADDON            CHECK NEXT ENTRY                     27600018
EOB2     L     RWK3,0(RWK3)        PICK UP NEXT BLOCK                   27900018
         B     YESADDON            CHECK NEXT BLOCK                     28200018
LAST2    MVC   5(3,RWK3),XCMOUTQ+1(RFAILOUT)  ADD QUEUE ONTO NEW        28500018
         MVI   4(RWK3),X'C0'  INDICATE EOB                              28800018
         NI    0(RWK3),X'7F'  TURN OFF LAST INDICATOR                   29100018
****                                                             ****** 29400018
*   THE FOLLOWIN CODE SEARCHES FOR DUPLICATE WQE POINTERS ON THE QUEUE* 29700018
*   OF THE NEW DEVICE AFTER A SWITCH.  RUCME POINTS TO THE WQE POINTER* 30000018
*   BEGING CHECKED FOR A DUPLICATE. RWK3 POINTS TO THE PLACE IN THE   * 30300018
*   QUEUE BELOW WHER RUCME POINTS THAT IS BEING CHECKED.              * 30600018
****                                                             ****** 30900018
DUPSRCH  L     RUCME,XCMOUTQ(RNEWOUT)  OUTPUT QUEUE                     31200018
         LA    RWK3,4(RUCME)       FIRST TO BE CHECKED FOR DUPLICATE    31500018
CKDUPNXT TM    0(RUCME),X'C0'       CHECK FOR LAST OR EOB               31600018
         BNZ   NOGOODN    YES CHECK                                     31700018
         TM    0(RUCME),X'01'   VALID ENTRY                             31800018
         BZ    NOGOODEN                 NO                              32100018
         TM    0(RUCME),X'02'  NO LONGER NEEDED ON                      32400018
         BO    NOGOODEN     YES SKIP ENTRY                              32700018
DUPCKNXT TM    0(RWK3),X'01'            TO BE SEARCHED VALID            33000018
         BZ    SREDNOGD        NO CHECK FOR LAST OR EOB                 33100018
         TM    0(RWK3),X'02'  NO LONGER NEEDED ON                       33300018
         BO    SREDNOGD     YES SKIP ENTRY                              33600018
         CLC   1(3,RWK3),1(RUCME)  DUPLICATE                            33900018
         BNE   SREDNOGD                 NO                              34500018
         NI    0(RWK3),X'FE'  YES MARK AS                               34700018
         OI    0(RWK3),X'02'        NO LONGER NEEDED                    34900018
SREDNOGD TM    0(RWK3),X'C0'  CHECK FOR EOB OR LAST                     35900018
         BO    EOB3   EOB                                               36900018
         BM    LAST3        LAST                                        37200018
         LA    RWK3,4(RWK3)             PICK UP NEXT ENTRY              37500018
         B     DUPCKNXT                 CHECK NEXT ENTRY                37800018
EOB3     L     RWK3,0(RWK3)             PICK UP NEXT BLOCK              38100018
         B     DUPCKNXT                 CHECK NEXT BLOCK                38400018
LAST3    LA    RUCME,4(RUCME)           CHECK NEXT ENTRY FOR DUPLICATE  38700018
         LA    RWK3,4(RUCME)            FIRST TO CHECK                  39000018
         B     CKDUPNXT                 CHECK                           39300018
NOGOODEN TM    0(RUCME),X'C0'           CHECK FOR LAST OR EOB           39600018
NOGOODN  BO    EOB4                                                     39900018
         BM    FINISH   LAST ALL DUPLICATES ELIMINATED                  40200018
         LA    RUCME,4(RUCME)           NEXT ENTRY                      40500018
         LA    RWK3,4(RUCME)            NEXT TO BE CHECKED              40800018
         B     CKDUPNXT            CHECK NEXT ENTRY                     41100018
EOB4     L     RUCME,0(RUCME)      NEXT BLOCK                           41400018
         LA    RWK3,4(RUCME)       FIRST TO CHECK                       41700018
         B     CKDUPNXT                                                 42000018
FINISH   TM    16(RINPUT),X'04'   EXTERNAL SWITCH                       42300018
         BZ    SETCLOSE       NO   FREE                                 42600018
         TM    UCMSFLGS,X'08' NO CONSOLES CONDITION                     42900018
         BZ    SETCLOSE       NO   FREE                                 43200018
         TM    UCMSFLGS+1,X'20'    NEW COMPOSITE                        43500018
         BZ    CKOUTUCB                                                 43800018
         L     RWK1,XCMUCB(RWK)    UCB OF INPUT OF NEW                  44100018
         TM    SRTESTAT(RWK1),X'82'  ONLINE  CONSOLE                    44400018
         BO    OPENPND             YES ALLOCATED PROPERLY               44700018
         TM    SRTESTAT(RWK1),X'02'  CONSOLE BUT NOT ONLINE             45000018
         BO    SETONLIN            YES - INDICATE NOW ACTIVE CONSOLE    45300018
         OI    SRTESTAT(RWK1),X'40' INDICATE CHANGE STATUS              45600018
OPENPND  TM    XCMATR(RWK),X'10'    DEVICE ACTIVE                       45900018
         BO    CKOUTUCB            YES NEED NOT OPEN                    46200018
         OI    XCMSTS(RWK),X'08'   SET OPEN PENDING                     46500018
         B     CKOUTUCB            CHECK OUTPUT UCB                     46800018
SETONLIN OI    SRTESTAT(RWK1),X'80' SET ONLINE                          47100018
         B     OPENPND             SET OPEN PENDING                     47400018
CKOUTUCB L     RWK1,XCMUCB(RNEWOUT) UCB OF NEW OUTPUT                   47700018
         TM    SRTESTAT(RWK1),X'82'  ON LINE  CONSOLE                   48000018
         BO    OPENPNDO     YES  ALLOCATED PROPERLY                     48300018
         TM    SRTESTAT(RWK1),X'02'  CONSONLE BUT NOT ONLINE            48600018
         BO    SETOUTLN       YES  SET ONLINE                           48900018
         OI    SRTESTAT(RWK1),X'40' INDICATE CHANGE STATUS              49200018
OPENPNDO TM    XCMATR(RNEWOUT),X'10'    DEVICE ACTIVE                   49500018
         BO    CKFORCL        YES CHECK TO SEE IF CLOSE TO BE DONE      49800018
         OI    XCMSTS(RWK),X'08'  SET OPEN PENDING                      50100018
CKFORCL  CR    RFAILOUT,RNEWOUT   SAME CONSOLE BE REINSTATED            50400018
         BE    CLEARSF           YES DON'T CLOSE                        50700018
         B     SETCLOSE          NO - CLOSE                             51000018
SETOUTLN OI    SRTESTAT(RWK1),X'80'  SET ONLINE IN UCB                  51300018
         B     OPENPNDO       CHECK TO SEE IF OPEN TO BE DONE           51600018
SETCLOSE TM    16(RINPUT),X'08'  RESULT OF VARY MSTCONS                 51700018
         BZ    SETCLOS1        NO  CLOSE                                51800018
         TM    UCMMODE,X'08'  DID SYSTEM ASK FOR MSTCONS                51900018
         BZ    CLEARSF     NO DON'T CLOSE OLD MASTER                    52000018
         NI    UCMMODE,X'F7'  TURN OFF ACCEPT MSTCONS                   52100018
SETCLOS1 OI    XCMSTS(RFAILOUT),X'10'  INDICATE CLOSE PENDING           52200018
         NI    XCMSTS(RFAILOUT),X'DF'  TURN OFF BUSY                    52500018
         TM    UCMSFLGS+1,X'08'  FAILING IS COMPOSITE                   52800018
         BZ    CLEARSF             NO                                   53100018
         L     RUCME,XCMCOMPC(RFAILOUT)   OTHER HALF                    53400018
         OI    XCMSTS(RUCME),X'10' SET CLOSE PENDING                    54000018
         MVI   XCMXOR(RUCME),X'82'   TO TURN OFF ACTIVE CONSOLE         54100018
CLEARSF  XC    XCMOUTQ(4,RFAILOUT),XCMOUTQ(RFAILOUT) CLEAR FAIN         54200018
         XC    XCMWLAST(4,RFAILOUT),XCMWLAST(RFAILOUT) CLEAR LAST       54250018
         MVI   XCMXOR(RFAILOUT),X'82'  TO TURN OFF ACTIVE               54300018
         NI    UCMSFLGS+1,X'D7'  CLEAR COMPOSITE INDICATORS             54400018
         NI    UCMSFLGS,X'EF'  CLEAR MASTER SWITCH INDICATOR            54500018
         MVI   UCMOECB,X'40'  INDICATE WTO TO BE DONE                   54700018
         L     R0,FREESAVE   SIZE OF SAVE AREA                          54900018
         LR    RINPUT,RSAVE  SAVE ARE REG                               55200018
         FREEMAIN  R,LV=(0),A=(1)                                       55500018
         BR    RRETURN             RETURN                               55800018
************************************************************* MG S21002 55850021
*THE FOLLOWING CODE HANDLES MLWTO CHAINS FOUND ON THE FAILING MG S21002 55900021
*CONSOLE'S QUEUE                                              MG S21002 56000021
************************************************************* MG S21002 56050021
         SPACE 1                                                        56060021
ML1      EQU   *                                              MG S21002 56070021
         USING UCMLIST,RFAILOUT    BASE CONSOLE ENTRY         MG  M0639 56072021
         XC    UCMMLAST(L5),UCMMLAST   RESET MLWTO            MG  M0639 56080021
         NI    UCMSTS,SWMASK-UCMTC   FLAGS IN ENTRY           MG  M0639 56090021
*        TURN OFF ALL FLAGS IN STATUS CNTRL BYTE 5 EXCEPT 5G & 5H       56090121
         NI    UCMSDS5,SWMASK-UCMSDS5A-UCMSDS5B-UCMSDS5C-UCMSDS5D-UCMSD*56090221
               S5E-UCMSDS5F                                   BE A51819 56090321
         CL    RUCME,UCMWLAST      IN PROCES OF WRITING MLWTO MG  M1438 56090421
         BE    ML3                 YES, NO SWITCH OF MLWTO    MG  M1438 56090821
         L     RLINK,ZERO(RUCME)   BASE MAJOR/MINOR           MG S21002 56092021
         USING MAJMIN,RLINK                                   MG S21002 56094021
         TM    WMJMLTYP,WMJMLTYD   ENDED                      MG S21002 56096021
         BO    ML4                 YES, SWITCH IF NOT SD      MG  M1422 56098021
         TM    WMJMMLW,WMJMMLWH    END OF CHAIN               MG S21002 56098421
         BO    ML3                 YES, NO SWITCH             MG S21002 56098821
         L     RLINK,WMJMMIN       POINT TO FIRST MINOR       MG S21002 56099221
ML2      EQU   *                                              MG S21002 56099621
         LTR   RLINK,RLINK         END OF CHAIN               MG S21002 56099721
         BZ    ML3                 YES, NO SWITCH             MG S21002 56099821
         TM    WMNMLT1,WMNMLT1D    ENDED                      MG S21002 56099921
         BO    ML4                 YES, SWITCH IF NOT SD      MG S21002 56149921
         L     RLINK,WMNMUC1       POINT TO NEXT MINOR        MG S21002 56159921
         LA    RLINK,ZERO(RLINK)   CLEAR USE COUNT            MG S21002 56169921
         B     ML2                 CHECK FOR END OF CHAIN     MG S21002 56179921
ML3      SR    1,1                 ZERO OUT COUNT REG             64467 56180221
         L     RWK3,ZERO(RUCME)    LOAD MAJOR WQE PTR             64467 56180521
         SR    RWK1,RWK1                                          64467 56180821
         IC    RWK1,ZERO(RWK3)     SAVE MAJOR USE COUNT           64467 56181121
         L     RWK3,X7C(RWK3)      LOAD MINOR POINTER             64467 56181421
         LTR   RWK3,RWK3           ANY MINORS?                    64467 56181721
         BZ    RNDML               NO, SKIP NEXT STEP             64467 56182021
         SR    RLINK,RLINK                                        64467 56182321
MLLOOP   IC    RLINK,ZERO(RWK3)    SAVE MINOR USE COUNT           64467 56182621
         CR    RLINK,RWK1          ARE MAJ/MIN USE COUNTS EQUAL?  64467 56182921
         BE    DECCNT              YES, GO DECR. MINOR USE CNT    64467 56183221
NXMIN    LA    RWK3,ZERO(RWK3)     CLEAR USE COUNT                64467 56183521
         LA    1,1(1)              BUMP MINOR COUNTER             64467 56183821
         LTR   RWK3,RWK3           IS THIS LAST MINOR?            64467 56184121
         BZ    MLTEND              YES, GET OUT OF LOOP           64467 56184421
         L     RWK3,ZERO(RWK3)     NO, LOAD NEXT MINOR POINTER    64467 56184721
         B     MLLOOP              CHECK NEXT USE COUNT           64467 56185021
DECCNT   LTR   1,1                 IS THIS THE FIRST MINOR        64467 56185321
         BZ    RNDML               MAJ/MIN USE COUNTS ARE EQUAL   64467 56185621
         SH    RLINK,ONE1          DECREMENT MINOR USE COUNT BY 1 64467 56185921
         STC   RLINK,ZERO(RWK3)    STORE NEW USE COUNT IN MINOR   64467 56186221
         B     NXMIN               GO FIND NEXT MINOR             64467 56186521
MLTEND   L     RWK3,ZERO(RUCME)    LOAD MAJOR POINTER FROM CQE    64467 56186821
         STC   RLINK,ZERO(RWK3)    STORE MINOR USE CNT IN MAJOR   64467 56187121
RNDML    OI    ZERO(RUCME),PURGE   PURGE THIS MLWTO               64467 56187421
         NI    ZERO(RUCME),SWMASK-ENTRY   TURN OFF ENTRY FLAG MG S21002 56237221
         B     CKQEND              GET NEXT WQE               MG S21002 56252021
ML4      EQU   *                                              MG S21002 56266821
         L     RLINK,ZERO(RUCME)   BASE MAJOR                 MG  M1446 56276821
         TM    WMJMDEC,DCODE8      DESC CODE 8                MG S21002 56281621
         BNO   ML0                 NO, SWITCH NOT STATUS DISP MG S21002 56296421
         TM    WMJMDEC+ONE,DCODE9   DESC CODE 9               MG S21002 56311221
         BNO   ML0                 NO,SWITCH NOT STATUS DISP  MG S21002 56326021
         DROP  RFAILOUT            DROP BASE                  MG  M0639 56336021
         DROP  RLINK                                          MG S21002 56340821
         B     ML3                 DO NOT SWITCH MLWTO        MG S21002 56355621
         EJECT                                                          56370421
         DS    0F                                                       56385221
GETQUEUE DC    X'FF000018'    SIZE OF UCM OUTPUT QUEUE                  56400018
FREESAVE DC    X'FF000080'  SIZE AND SP OF SAVE AREA                    56700018
ONE1     DC    H'1'                                               64467 56750021
ENTSIZE  EQU   4             SIZE OF ONE ENTRY IN CONSOLE QUEUE  A36203 56800020
R0       EQU   0    WORK REG                                            57000018
RGWK1    EQU   0         WORK REG WHEN SWITCHING HARDCOPY               57300018
RINPUT   EQU   1    INPUT PARAMETER REGISTER                            57600018
RWK      EQU   2    WORK REGISTER                                       57900018
R2       EQU   2         SAVE REG                                       58200018
RSAVE    EQU   3           SAVE REG                                     58500018
RCVT     EQU   3    CVT REG                                             58800018
RUCMMCS  EQU   4    UCM MCS BASE REG                                    59100018
RWK2     EQU   5    THIRD WORK REGISTER                                 59400018
RNEWOUT  EQU   6    NEW OUTPUT ENTRY REG ON SWITCH                      59700018
RMES     EQU   7    BASE REGISTER FOR MESSAGES                          60000018
RFAILOUT EQU   7    OUTPUT FAILING CONSOLE ENTRY REG                    60300018
RWK1     EQU   8    SECOND WORK REGISTER                                60600018
RUCME    EQU   9    UCM ENTRY REGISTER                                  60900018
RUCM     EQU   10   UCM BASE REGISTER                                   61200018
RBASE    EQU   11   BASE REGISTER                                       61500018
RWK4     EQU   12   WORK REGISTER                                       61800018
RWK3     EQU   13   WORK REGISTER                                       62100018
RRETURN  EQU   14   RETURN REGISTER                                     62400018
RETURNRG EQU   14   RETURN REGISTER                                     62700018
RLINK    EQU   15   LINKING REGISTER                                    63000018
RGWK2    EQU   15        WORK REG WHEN SWITCHING HARDCOPY               63300018
EXTINPUT EQU   4    LOW CORE ADDRESS OF AREA STORED IN BY OPERATOR OF   63600018
*                   NEW MASTER IN A NO CONSOLES CONDITION               63900018
CVTA     EQU   16   CVT ACTUAL ADDRESS                                  64200018
SRTESTAT EQU   3    STATUS FIELD OF UCB                                 64500018
UCBCHA   EQU   4    OFFSET TO CHANNEL AND UNIT ADDRESS IN UCB           64800018
UCBNAME  EQU   13   NAME FIELD OF UCB                                   65100018
OLD      EQU   14   OLD ADDRESS AREA OF SWITCH MESSAGE                  65400018
ROUTCD   EQU   18   ROUTING CODE MESSAGE AREA OF SWMSG2                 65700018
OLDI     EQU   16   OLD INPUT AREA OF SWITCH MESSAGE                    66000018
OLDO     EQU   22   OLD OUTPUT AREA OF SWITCH MESSAGE                   66300018
NEWI     EQU   33   NEW INPUT AREA OF SWITCH MESSAGE                    66600018
NEW      EQU   30   NEW ADDRESS AREA OF SWITCH MESSAGE                  66900018
NEWO     EQU   39   NEW OUTPUT AREA OF SWITCH MESSAGE                   67200018
VLDCMD   EQU   52   VALID COMMAND AREA OF SWITCH MESSAGE                67500018
TYPE     EQU   63   TYPE AREA OF SWMSG2 MESSAGE                         67800018
HCPY     EQU   71   HARDCOPY AREA OF SUMSG2 MESSAGE                     68100018
X7C      EQU   124                                                64467 68120021
ZERO     EQU   0                   DISPLACEMENT               MG S21002 68150021
MLWTO    EQU   X'04'               MLWTO ENTRY ON QUEUE       MG S21002 68200021
PURGE    EQU   X'02'               PURGE ENTRY ON QUEUE       MG S21002 68250021
ONE      EQU   1                   DISPLACEMENT               MG S21002 68300021
DCODE8   EQU   X'01'               DESCRIPTOR CODE 8          MG S21002 68350021
DCODE9   EQU   X'80'               DESCRIPTOR CODE 9          MG S21002 68360021
L5       EQU   5                   LENGTH                     MG  M1446 68370021
SWMASK   EQU   255                 FOR ANDING FLAGS OFF       MG S21002 68394021
ENTRY    EQU   X'01'               CONSOLE QUEUE ENTRY FLAG   MG S21002 68396021
***  INDIVIDUAL UCM  ENTRY MAP  ***                                     68400018
XCMECB   EQU   0    I/O COMPLETION ECB                                  68700018
XCMSRB   EQU   4    POINTER TO RESIDENT PROCESSOR MODULE                69000018
XCMDCB   EQU   8    POINTER TO DCB                                      69300018
XCMUCB   EQU   12   POINTER TO UCB                                      69600018
XCMNAME  EQU   16   PROCESSING MODULE NAME                              69900018
XCMSTS   EQU   24      SATAUS FLAGS                                     70200018
XCMATR   EQU   25   ATTRIBUTE FLAGS                                     70500018
XCMID    EQU   26   UNIQUE IDENTIFIER FOR EACH ENTRY                    70800018
XCMXB    EQU   28   POINTER TO DCM FOR GRAPHICS                         71100018
XCMRTCD  EQU   32   ROUTING CODES                                       71400018
XCMOUTQ  EQU   36   POINTER TO OUTPUT QUEUE                             71700018
XCMAUTH  EQU   40   COMMAND CODE AUTHORIZATION                          72000018
XCMDISP  EQU   42   DISPOSITION FLAGS                                   72300018
XCMALTEN EQU   44   POINTER TO ALTERNATE UCM ENTRY                      72600018
XCMOADEN EQU   48            POINTER TO ALTERNATE OUTPUT ENTRY          72900018
XCMWLAST EQU   52   LAST WQE SERVICED IN OUTPUT QUEUE                   73200018
XCMCOMPC EQU   56    POINTER TO OTHER HALF IF A COMPOSITE CONSOLE       73500018
XCMMSG   EQU   60   MESSAGE TYPE FLAGS                                  73800018
XCMXOR   EQU   62   EXCLUSIVE OR FIELD FOR UCB                          74100018
XCMDEVC  EQU   63   DEVICE CONTROL FLAGS                                74400018
XCMINPUT EQU   64   INPUT AREA - FIXED MODE ONLY                        74700018
***  WQE EQUATES  RQE EQUATES                                           75000018
XWQEXA   EQU   136       DISPOSITION FLAGS OF WQE                       75300018
XWQUCMID EQU   156       UCMID FIELD OF WQE                             75600018
XRQLKP   EQU   0         LINK POINTER OF  RQE                           75900018
XRQWQE   EQU   12       WQE POINTER                                     76200018
MESSAGES DSECT                                                     **** 76500018
SWMSGWQ1 DC    F'0'      POINTER TO NEXT WQE                            76800018
         DC    F'73'     MESSAGE LENGTH PLUS 4                          77100018
SWMSG1   DC       C'IEEXXXY  OLD=             NEW=         '   TEXT     77400018
         DC       C'   VALDCMD=                 '                       77700018
         ORG   SWMSGWQ1+136                                             78000018
         DC    X'00000010'    INDICATES BUFFER OBTAINED DYNAMICALLY     78300018
         DC    F'0'           RESERVED FOR  RO/RS                       78600018
         DC    F'0'           ID SEQUENCE NUMBER                        78900018
         DC    X'0100'        MCS FLAGS                                 79200018
         DC    H'0'           MSGTYPE FLAGS                             79500018
         DC    F'0'           ROUTING CODES                             79800018
SWMSG1ID DC    F'0'           ENTRY ID                                  80100018
         DC    X'0004'        DESCRIPTOR CODE OF 3                      80400018
         DC    H'0'           RESERVED                                  80700018
         DC    F'0'           TIME ELEMENT                              81000018
SWMSGWQ2 DC    F'0'      POINTER TO NEXT WQE                            81300018
         DC    F'75'     MESSAGE LENGTH PLUS 4                          81600018
SWMSG2   DC       C'IEEXXXX  ROUTCDE=                       ' TEXT      81900018
         DC       C'                 TYPE=   HCPY= '                    82200018
         ORG   SWMSGWQ2+136                                             82500018
         DC    X'00000010'    INDICATES BUFFER OBTAINED DYNAMICALLY     82800018
         DC    F'0'           RESERVED FOR RO/RI                        83100018
         DC    F'0'           ID SEQUENCE NUMBER                        83400018
         DC    X'0100'        MCS FLAGS                                 83700018
         DC    H'0'           MSGTYPE FLAGS                             84000018
         DC    F'0'           ROUTING CODES                             84300018
SWMSG2ID DC    F'0'           ENTRY ID                                  84600018
         DC    X'0004'        DESCRIPTOR CODE OF 3                      84900018
         DC    H'0'           RESERVED                                  85200018
         DC    F'0'           TIME ELEMENT                              85500018
UCM      DSECT                                                          85800018
         IEECUCM                                                        86100018
WQEDSECT DSECT                                                          86400018
         IEECVMUG WQE                                                   86700018
RQEDSECT DSECT                                                          87000018
         IEECVMUG  RQE                                                  87300018
CVTDSECT DSECT                                                          87600018
         CVT                                                            87900018
MAJMIN   DSECT                                                MG S21002 87950021
         IEECVMUG WQEMAJ                                      MG S21002 88000021
         ORG   WMJF                                           MG S21002 88050021
         IEECVMUG WQEMIN                                      MG S21002 88100021
  END                                                                   88200018
