         TITLE 'IGCXO07B FOURTH LOAD OF CONSOLE SWITCH'                 00466621
IEECOCTX CSECT                                                          00500018
*C318000,A318500,A431980-434776,A846500-848500                MG  M1418 00550021
*MODULE CREATED FOR MCS - REL 18                                        00700018
* 262000-266000 COPIED AFTER 246000                           BG A46411 00800021
         BALR  RBASE,0       ESTABLISH ADDRESSABILITY                   00900018
         USING *,RBASE                                                  01200018
         SSM   *+1    DISABLE                                           01800018
         USING UCM,RUCM                                                 02400018
         USING MCSUCM,RUCMMCS                                           03900018
         USING CXSADSEC,RINPUT                                          04200018
         TM    CSACODE,MASTRSW    SWITCH FOR MASTER ONLY                04500018
         BO    SWHCPY     SWITCH FOR MASTER ONLY                        04800018
SWAPNDCP OI    XCMDEVC(RFAILOUT),TESTED  MARK AS TESTED                 05100018
         OI    XCMDEVC(RNEWOUT),TESTED   MARK AS TESTED                 05400018
         L     RWK2,XCMALTEN(RNEWOUT)   PICK UP ALTERNATE               05700018
CKALTG   LTR   RWK2,RWK2                ALTERNATE EXIST                 06000018
         BZ    GETMASTG                 NO OBTAIN MASTER                06300018
CHKDEV   EQU   *                                              BE  M1424 06400021
         TM    XCMDEVC(RWK2),TESTED     THIS DEVICE TESTED              06600018
         BO    GETMASTG                 YES GETMASTER                   06900018
         OI    XCMDEVC(RWK2),TESTED     INDICATE TESTED                 07200018
         TM    XCMATR(RWK2),ACTIVE      DEVICE ACTVIE                   07500018
         BZ    NEXTGAL  NO CHECK NEXT                                   07600018
         TM    XCMSTS(RWK2),UCMCF Q. CLOSE PENDING            BE  M0614 07620021
         BO    NEXTGAL               YES, YES, GET NEXT ALT   BE  M0614 07640021
         TM    XCMATR(RWK2),OUTSUPPT   OUTPUT DEVICE                    07700018
         BO    CKFORGR                  YES SEE IF GRAPHICS             07800018
         USING UCMLIST,RWK2                                   BE  M1424 07870021
         L     RWK2,UCMCOMPC      LOAD PTR TO O-HALF OF COMP  BE  M1424 07940021
         B     CHKDEV             BRANCH TO TEST O-HALF       BE  M1424 08010021
NEXTGAL  L     RWK2,XCMALTEN(RWK2)      NOT ACTIVE GET ALTERNATE        08100018
         B     CKALTG                   CHECK ALTERNATE                 08400018
CKFORGR  TM    XCMDISP(RWK2),GRAPHICS   GRAPHICS DEVICE                 08700018
         BO    NEXTGAL                  YES CAN'T USE                   09000018
         B     SWAPGNOW                 NO SWITCH HARDCPY               09300018
GETMASTG TM    UCMSFLGS,SWMAST          WAS THIS A MASTER SW            09600018
         BO    ANYNONGR                 YES FIND ANY NON GRAPHICS       09900018
HRDCPYSW L     RWK2,UCMMCENT           MASTER                           10200018
UCMETEST EQU   *                                              BE  M1424 10230021
         OI    XCMDEVC(RWK2),TESTED  INDICATE TESTED                    10270018
         TM    UCMATR,UCMOF       Q. DEVICE SUPPORT OUTPUT    BE  M1424 10280021
         BO    CHKGRAPH           YES, CHECK ATTRIBUTES       BE  M1424 10290021
         L     RWK2,UCMCOMPC      NO, LOAD PTR TO O-HALF      BE  M1424 10300021
CHKGRAPH EQU   *                                              BE  M1424 10310021
         TM    XCMDISP(RWK2),GRAPHICS   IS THIS GRAPHICS                10340018
         BO    NEXTGAL1           YES, GET ALTERNATE          BE  M1424 10360021
         TM    UCMSTS,UCMCF       Q. CLOSE PENDING            BE  M1424 10380021
         BO    NEXTGAL1           YES, GET ALTERNATE          BE  M1424 10400021
         TM    UCMATR,UCMUF       Q. DEVICE ACTIVE            BE  M1424 10420021
         BO    SWAPGNOW           YES, SWITCH HARDCOPY        BE  M1424 10440021
NEXTGAL1 L     RWK2,XCMALTEN(RWK2) GET ALTERNATE              BE  M1416 10460021
CKALTG1  LTR   RWK2,RWK2                ALTERNATE EXIST                 10500018
         BZ    ANYNONGR                 NO TAKE ANY NON GRAPHICS        10800018
         TM    XCMDEVC(RWK2),TESTED     THIS DEVICE TESTED              11100018
         BNO   UCMETEST           GET ALTERNATE               BE  M1416 12100021
ANYNONGR L     RWK2,UCMVEA         FIRST ENTRY                          14100018
CKACTGR  TM    XCMATR(RWK2),ACTIVE      DEVICE ACTIVE                   14400018
         BZ    NXTGRENT  NO CHECK NEXT                                  14500018
         TM    XCMSTS(RWK2),UCMCF Q. CLOSE PENDING            BE  M0614 14530021
         BO    NXTGRENT              YES, GET NEXT ALT        BE  M0614 14560021
         TM    XCMDEVC(RWK2),TESTED  DEVICE ALREADY TESTED              14600018
         BO    NXTGRENT   YES CHECK NEXT                                14700018
         TM    XCMATR(RWK2),OUTSUPPT  OUTPUT DEVICE                     14800018
         BO    GRAPCK    YES CHECK FOR GRAPHICS                         14900018
NXTGRENT C     RWK2,UCMVEL         LAST ENTRY                           15000018
         BE    NONONGR             YES ONLY GRAPHICS LEFT               15300018
         A     RWK2,UCMVEZ         NEXT ENTRY                           15600018
         B     CKACTGR             CHECK NEXT ENTRY                     15900018
GRAPCK   TM    XCMDISP(RWK2),GRAPHICS                                   16200018
         BO    NXTGRENT            YES GET NEXT ENTRY                   16500018
         B     SWAPGNOW            FOUND                                16800018
NONONGR  OI    UCMMODE,EMERGCY     ONLY GRAPHICS CONSOLES EXIST         17100018
         L     RWK2,UCMMCENT       PLACE HARDCPY ON GRAPHICS            17400018
         TM    UCMATR,UCMOF       Q. DEVICE SUPPORT OUTPUT    BE  M1424 17460021
         BO    SWAPGNOW           YES, TURN OFF TESTED FLAGS  BE  M1424 17520021
         L     RWK2,UCMCOMPC      NO, GET O-HALF OF MASTER    BE  M1424 17580021
         DROP  RWK2                                           BE  M1424 17640021
SWAPGNOW L     RWK1,UCMVEA         FIRST ENTRY                          17700018
SWAPGNW  NI    XCMDEVC(RWK1),MTESTED  CLEAR TESTED                      18000018
         C     RWK1,UCMVEL         LAST ENTRY                           18300018
         BE    CONTGSW             YES                                  18600018
         A     RWK1,UCMVEZ         PICK UP NEXT                         18900018
         B     SWAPGNW                                                  19200018
CONTGSW  STM   RINPUT,R0,0(RSAVE)  SAVE REGS                            19500018
         L     R0,WQE1             ONE WQE  SP= 255                     19800018
         GETMAIN    R,LV=(0)                                            20100018
         LM    R2,R0,4(RSAVE)      RESTORE REGS                         20400018
         MVC   0(44,RINPUT),SWGRWQE  BEGINNING OF MESSAGE               20700018
         MVC   136(32,RINPUT),SWGRWQEE WQE INFO                         21000018
         MVC   XWQUCMID(1,RINPUT),XCMID(RWK2) PLACE ID IN MESSAGE       21300018
         L     RWK3,UCMWQEND       LAST WQE POINTER                     21600018
         LTR   RWK3,RWK3      CHECK TO SEE IF ONE EXISTS                21900018
         BNZ   QON                Q TO LAST MSG               BE  M1417 22000021
         ST    RINPUT,UCMWTOQ     PLACE IN 1ST WQE PTR        BE  M1417 22100021
         B     BUILDMSG                                       BE  M1417 22200021
QON      EQU   *                                              BE  M1417 22300021
         IC    RWK4,0(RWK3)   SAVE USE COUNT                            22500018
         ST    RINPUT,0(RWK3) QUEUE WQE ONTO QUEUE                      22800018
         STC   RWK4,0(RWK3)   RESTORE USE COUNT                         23100018
BUILDMSG EQU   *                                              BE  M1417 23150021
         L     RWK3,XCMUCB(RWK2)   UCB ADDRESS                          23200018
         MVC   17(3,RINPUT),UCBNAME(RWK3)  MOVE IN ADDRESS              23300018
         ST    RINPUT,UCMWQEND  NEW LAST WQE                            23400018
GOQUEUE  LR    R2,RUCM        FOR QUEUING ROUTINE                       24600018
         TM    UCMMODE,FIXED     FIXED MODE                             24650021
         BO    MODEFIX    YES DON'T INCREMENT                           24700021
         L     RWK4,UCMRQNR       WQE COUNT                             24750021
         LA    RWK4,1(RWK4)    INCREMENT BY ONE                         24800021
         STH   RWK4,UCMWQNR      STORE UPDATED COUNT                    24850021
MODEFIX  EQU   *                                                        24870021
         LR    RWK4,RRETURN   SAVE RETURN REG                           24900018
         L     RLINK,UCMQRTN  ADDR OF RESIDENT QUEUE ROUTINE            25200018
         MVC   64(64,RSAVE),UCMSAVE0+4  SAVE Q ROUTINE SAVE AREA        25260018
***      IEECMDSV MAY HAVE USED UCMSAVE0 DEPENDING ON WHY THE SWITCH    25320018
***      ROUTINE WAS CALLED.  IEECMENQ WHICH WE ARE NOW LINKING TO      25380018
***      ALSO USES UCMSAVE0 SO WE MUST SAVE IT                          25440018
         BALR  RRETURN,RLINK  GET MESSAGE QUEUED TO DEVICE              25500018
         LR    RRETURN,RWK4   RESTORE RETURN REG                        25800018
         MVC   UCMSAVE0+4(64),64(RSAVE) RESTORE UCMSAVE 0 TO ORIGINAL   25900018
         L     RINPUT,0(RSAVE) RESTORE INPUT REG                        26100018
         ST    RWK2,UCMHCUCM INDICATE NEW HCOPY IN UCM        BG A46411 26400021
         OI    XCMDISP(RWK2),X'40' THIS NOW HARDCOPY                    26800018
         TM    CSACODE,MASTRSW  SWITCH FOR MASTER ONLY                  26850018
         BO    RETURN1  YES - SWITCH MADE - SET UP TO RETURN            26900018
         NI    XCMDISP(RFAILOUT),X'BF'  TURN OFF HCPY                   27000018
         L     RWK4,XCMOUTQ(RFAILOUT)   OUTPUT QUEUE OF FAILING         27300018
         LTR   RWK4,RWK4      ANY ON QUEUE                              27600018
         BZ    CMDSA          NO RETURN                                 27900018
         LA    RWK1,0         ZERO COUNTER                              28200018
GENTEST  TM    0(RWK4),VLID  VALID ENTRY                                28400018
         BZ    TESTEOBL      NO CHECK FOR LAST OR EOB                   28600018
         TM    0(RWK4),VLIDONLY  ONLY VALID ON                          28800018
         BO    WQEGET  YES LOOK AT WQE                                  29000018
TESTEOBL TM    0(RWK4),LASTEOB      LAST OR EOB                         29200018
         BM    CMDSA                    LAST ENTRY - RETURN             29400018
         BO    GEOB                     EOB - OBTAIN NEXT BLOCK         29700018
         LA    RWK4,4(RWK4)   PICK UP NEXT ENTRY                        30000018
         B     GENTEST        TEST NEXT ENTRY                           30300018
GEOB     L     RWK4,0(RWK4)   NEXT BLOCK OF ENTRIES                     30600018
         B     GENTEST        TEST NEXT ENTRY                           30900018
WQEGET   L     RWK3,0(RWK4)   PICK UP WQE                               31200018
         TM    XWQEXA(RWK3),HRDCYWQE  WQE QUEUED FOR HARDCOPY           31500018
         BO    ML1            YES MUST MOVE TO NEW CONSOLE    MG  M1418 31800021
CKQEND   EQU   *              ECHECK END OF Q                 MG  M1418 31850021
         TM    0(RWK4),LASTEOB   LAST                                   31900018
         BM    CMDSA    YES RETURN                                      32000018
         LA    RWK4,4(RWK4)   NEXT ENTRY                                32100018
         B     GENTEST        TEST NEXT ENTRY                           32400018
HCPYWQE  LTR   RWK1,RWK1      QUEUE EXIST                               32700018
         BNZ   GON            YES ADD ON                                33000018
         L     R0,GETQUEUE    ONE OUTPUT QUEUE                          33600018
         GETMAIN    R,LV=(0)                                            33900018
         XC    0(24,RINPUT),0(RINPUT)   ZERO OUT NEW BLOCK              34500018
         MVI   20(RINPUT),X'C0'  INDICATE EOB FOR DSV                   34600018
         L     RGWK2,XCMOUTQ(RWK2)  OUTPUT Q OF NEW CONSOLE FOR HCPY    34800018
         LTR   RGWK2,RGWK2         ANYTHING ON QUEUE                    35100018
         BNZ   GNEXTCK             YES ADD NEW ON                       35400018
         ST    RINPUT,XCMOUTQ(RWK2) PLACE NEW BLOCK ON QUEUE            35700018
         B     GON                 NOW ON QUEUE OF NEW HCPY             36000018
GNEXTCK  TM    0(RGWK2),LASTEOB         LAST OR END OF BLOCK            36300018
         BO    GEOB1                    EOB  OBTAIN NEXT BLOCK          36600018
         BM    GLAST1                   END OF QUEUE - ADD NEW ON       36900018
         LA    RGWK2,4(RGWK2)      NEXT ENTRY                           37200018
         B     GNEXTCK             CHECK NEXT ENTRY                     37500018
GEOB1    L     RGWK2,0(RGWK2)      NEXT BLOCK                           37800018
         B     GNEXTCK             CHECK NEXT BLOCK                     38100018
GLAST1   NI    0(RGWK2),NOTLAST  TURN OFF LAST INDICATOR                38200018
         ST    RINPUT,4(RGWK2)  ADD ON QUEUE                            38300018
         OI    4(RGWK2),LASTEOB  INDICAT EOB                            38400018
GON      ST    RWK3,0(RINPUT)  PLACE WQE POINTER IN BLOCK               38500018
         TM    ZERO(RWK4),MLWTO   MLWTO REQUEUED ?            BE A51824 38550021
         BNO   NOTML              NO-DON'T FLAG ENTRY AS ML   BE A51824 38560021
         OI    ZERO(RINPUT),MLWTO+MLWTOHC ML FOR H. C.        BE A51824 38570021
NOTML    EQU   *                                              BE A51824 38580021
         OI    0(RINPUT),LASTVLID  INDICATE LAST VALID ENTRY            38600018
         LTR   RWK1,RWK1   FIRST ON QUEUE                               38630018
         BZ    SKIPPREV        YES DON'T CLEAR PREVIOUS                 38660018
         LR    RWK3,RINPUT   POINT TO PRESENT BLOCK                     38700018
         LA    RLINK,4    TO GET TO PREVIOUS                            38800018
         SR    RWK3,RLINK    POINTS TO PREVIOUS                         38900018
         NI    0(RWK3),X'7F'   TURN OFF LAST IN PREVIOUS                39000018
SKIPPREV LA    RINPUT,4(RINPUT)  POINT TO NEXT ENTRY                    39600018
         LA    RWK1,1(RWK1)        UPDATE COUNTER                       40200018
         LA    R0,5                CHECK FOR END OF QUEUE               40500018
         CR    RWK1,R0             LAST ONE                             40800018
         BNE   GNEXTEST       NO YET AT END OF QUEUE                    41100018
         LA    RWK1,0         RESET TO ZERO TO INDICATE NEED NEW BLOCK  41400018
GNEXTEST NI    0(RWK4),NULL  MARK OLD ENTRY AS NULL                     41500018
         TM    0(RWK4),LASTEOB  LAST ALONE                              41600018
         BM    CMDSA    YES END                                         41700018
         B     TESTEOBL                                                 42100018
CMDSA    LM    RINPUT,R0,0(RSAVE)  RESTORE REGS                         42300018
         LR    RLINK,RINPUT R 15 POINTS TO PARM LIST FOR XCTL           42500018
         MVC   CSANAME(8),LOAD2  SECOND LOAD OF SWITCH                  42700018
         XCTL  SF=(E,(15))         XCTL TO SECOND LOAD                  42900018
RETURN1  L     R0,FREESAVE   TO FREE SAVE AREA                          42960018
         LR    RINPUT,RSAVE  RESTORE SAVE AREA ADDRESS                  42990018
         NI    UCMSFLGS,NOCPY  TURN OFF HARDCPY SYSLOG                  43020018
         FREEMAIN  R,LV=(0),A=(1)                                       43080018
         BR    RRETURN                                                  43140018
SWHCPY   LR    RWK2,RINPUT   SAVE INPUT REG                             43148018
         L     R0,FREESAVE  SIZE AND SP OF SAVE AREA                    43156018
         GETMAIN  R,LV=(0)                                              43164018
         LR    RSAVE,RINPUT   ADDRESS OF GOTTEN CORE                    43172018
         LR    RINPUT,RWK2   RESTORE INPUT REG                          43180018
         B     HRDCPYSW   PERFORM SWITCH                                43188018
************************************************************* MG  M1418 43198021
*THE FOLLOWING CODE HANDLES MLWTO CHAINS FOUND ON THE FAILING MG  M1418 43198421
*CONSOLE'S QUEUE                                              MG  M1418 43198821
************************************************************* MG  M1418 43199221
         SPACE 1                                                        43199621
ML1      EQU   *                                              MG  M1418 43199721
         USING UCMLIST,RFAILOUT    BASE UCM ENTRY             MG  M1418 43199821
         XC    UCMMLAST(L5),UCMMLAST   RESET MLWTO            MG  M1418 43199921
         NI    UCMSTS,SWMASK-UCMTC   FLAGS IN ENTRY           MG  M1418 43200021
*        TURN OFF ALL FLAGS IN STATUS CNTRL BYTE 5 EXCEPT 5G & 5H       43202021
         NI    UCMSDS5,SWMASK-UCMSDS5A-UCMSDS5B-UCMSDS5C-UCMSDS5D-UCMSD*43204021
               S5E-UCMSDS5F                                   BE A51819 43206021
         TM    ZERO(RWK4),MLWTO    IS THIS ENTRY AN MLWTO     MG  M1418 43210021
         BNO   HCPYWQE             NO, PROCEED NORMALLY       MG  M1418 43220021
         CL    RWK4,UCMWLAST       IN PROCES OF WRITING MLWTO MG  M1438 43249921
         BE    ML3                 YES, NO SWITCH OF MLWTO    MG  M1438 43259921
         USING MAJMIN,RWK3         BASE MAJOR/MINOR           MG  M1418 43279921
         TM    WMJMLTYP,WMJMLTYD   ENDED                      MG  M1418 43289921
         BO    ML4                 YES, SWITCH IF NOT SD      MG  M1418 43291921
         TM    WMJMMLW,WMJMMLWH    END OF CHAIN               MG  M1418 43293921
         BO    ML3                 YES, NO SWITCH             MG  M1418 43295921
         L     RWK3,WMJMMIN        POINT TO FIRST MINOR       MG  M1418 43297921
ML2      EQU   *                                              MG  M1418 43298321
         LTR   RWK3,RWK3           END OF CHAIN               MG  M1418 43298721
         BZ    ML3                 YES, NO SWITCH             MG  M1418 43299121
         TM    WMNMLT1,WMNMLT1D    ENDED                      MG  M1418 43299521
         BO    ML4                 YES, SWITCH IF NOT SD      MG  M1418 43299621
         L     RWK3,WMNMUC1        POINT TO NEXT MINOR        MG  M1418 43299721
         LA    RWK3,ZERO(RWK3)     CLEAR USE COUNT            MG  M1418 43299821
         B     ML2                 CHECK FOR END OF CHAIN     MG  M1418 43349821
ML3      EQU   *                                              MG  M1418 43359821
         OI    ZERO(RWK4),PURGE    PURGE THIS MLWTO           MG  M1418 43369821
         NI    ZERO(RWK4),SWMASK-ENTRY   TURN OFF ENTRY FLAG  MG  M1418 43379821
         B     CKQEND              GET NEXT WQE               MG  M1418 43389821
ML4      EQU   *                                              MG  M1418 43391821
         L     RWK3,ZERO(RWK4)     BASE MAJOR                 MG  M1418 43393821
         TM    WMJMDEC,DCODE8      DESC CODE 8                MG  M1418 43395821
         BNO   HCPYWQE             NO, SWITCH NOT STATUS DISP MG  M1418 43397821
         TM    WMJMDEC+ONE,DCODE9   DESC CODE 9               MG  M1418 43398221
         BNO   HCPYWQE             NO,SWITCH NOT STATUS DISP  MG  M1418 43398621
         DROP  RWK3                                           MG  M1418 43399021
         DROP  RFAILOUT            DROP BASE                  MG  M1418 43399121
         B     ML3                 DO NOT SWITCH MLWTO        MG  M1418 43399421
         SPACE 3                                                        43399521
************************************************************* MG  M1418 43399621
ZERO     EQU   0                   DISPLACEMENT               MG  M1418 43420721
L5       EQU   5                   LENGTH FOR CLEARING        MG  M1418 43442021
MLWTO    EQU   X'04'               MLWTO ON SUBQUEUE          MG  M1418 43463121
MLWTOHC  EQU   X'08'               MLWTO Q'ED FOR H. C.       BE A51824 43465121
PURGE    EQU   X'02'               ENTRY NO LONGER NEEDED     MG  M1418 43465521
ENTRY    EQU   X'01'               USEABLE SUBQUEUE ENTRY     MG  M1418 43465921
DCODE8   EQU   X'01'               DESCRIPTOR CODE = 8        MG  M1418 43466321
DCODE9   EQU   X'80'               DESCRIPTOR CODE = 9        MG  M1418 43466421
ONE      EQU   1                   LENGTH AND DISPLACEMENT    MG  M1418 43466521
SWMASK   EQU   255                 MASK FOR ANDING SWITCHES   MG  M1418 43476521
         EJECT                                                          43477621
LOAD2    DC    C'IGCXM07B'         SECOND LOAD OF SWITCH                43488921
*****  MAP OF MESSAGE INDICATING THIS CONSOLE HARDCOPY            ***** 43500018
SWGRWQE  DC    F'0'      POINTER TO NEXT WQE                            43800018
         DC    F'36'   LENGTH OF MESSAGE                                44100018
SWGRWQEM DC    C' IEE142I      NOW RECEIVING HARDCOPY'                  44500018
         DS    0F                                                       45000018
SWGRWQEE DC    X'00000010'  INDICATES BUFFER OBTAINED DYNAMICALLY       45300018
         DC    F'0'      RESERVED FOR RO/RI                             45600018
         DC    F'0'      ID SEQUENCE NUMBER                             45900018
         DC    X'C000'    MCS FLAGS                                     46200018
         DC    H'0'      MSGTYPE FLAGS                                  46500018
         DC    X'40000000'   ROUTING CODE OF 2                          46800018
         DC    F'0'      ENTRY ID                                       47100018
         DC    X'1000'    DESC CODE OF 4                                47400018
         DC    H'0'      RESERVED                                       47700018
         DC    F'0'      TIME ELEMENT                                   48000018
GETQUEUE DC    X'FF000018'         SIZE OF ONE OUTPUT QUEUE IN SYS      48300018
         DS    0D                                                       48600018
         DS    0F                                                       48900018
WQE1     DC    X'FF0000A8'    ONE WQE FROM SQS                          49200018
FREESAVE DC    X'FF000080'  SIZE AND SUB POOL OF SAVE AREA              49300018
R0       EQU   0    WORK REG                                            49500018
RGWK1    EQU   0         WORK REG WHEN SWITCHING HARDCOPY               49800018
RINPUT   EQU   1    INPUT PARAMETER REGISTER                            50100018
RWK      EQU   2    WORK REGISTER                                       50400018
R2       EQU   2         SAVE REG                                       50700018
RSAVE    EQU   3           SAVE REG                                     51000018
RCVT     EQU   3    CVT REG                                             51300018
RUCMMCS  EQU   4    UCM MCS BASE REG                                    51600018
RWK2     EQU   5    THIRD WORK REGISTER                                 51900018
RNEWOUT  EQU   6    NEW OUTPUT ENTRY REG ON SWITCH                      52200018
RMES     EQU   7    BASE REGISTER FOR MESSAGES                          52500018
RFAILOUT EQU   7    OUTPUT FAILING CONSOLE ENTRY REG                    52800018
RWK1     EQU   8    SECOND WORK REGISTER                                53100018
RUCME    EQU   9    UCM ENTRY REGISTER                                  53400018
RUCM     EQU   10   UCM BASE REGISTER                                   53700018
RBASE    EQU   11   BASE REGISTER                                       54000018
RWK4     EQU   12   WORK REGISTER                                       54300018
RWK3     EQU   13   WORK REGISTER                                       54600018
RRETURN  EQU   14   RETURN REGISTER                                     54900018
RETURNRG EQU   14   RETURN REGISTER                                     55200018
RLINK    EQU   15   LINKING REGISTER                                    55500018
RGWK2    EQU   15        WORK REG WHEN SWITCHING HARDCOPY               55800018
EXTINPUT EQU   4    LOW CORE ADDRESS OF AREA STORED IN BY OPERATOR OF   56100018
*                   NEW MASTER IN A NO CONSOLES CONDITION               56400018
CVTA     EQU   16   CVT ACTUAL ADDRESS                                  56700018
UCBCHA   EQU   4    OFFSET TO CHANNEL AND UNIT ADDRESS IN UCB           57000018
UCBNAME  EQU   13   NAME FIELD OF UCB                                   57300018
OLD      EQU   14   OLD ADDRESS AREA OF SWITCH MESSAGE                  57600018
ROUTCD   EQU   18   ROUTING CODE MESSAGE AREA OF SWMSG2                 57900018
OLDI     EQU   16   OLD INPUT AREA OF SWITCH MESSAGE                    58200018
OLDO     EQU   22   OLD OUTPUT AREA OF SWITCH MESSAGE                   58500018
NEWI     EQU   33   NEW INPUT AREA OF SWITCH MESSAGE                    58800018
NEW      EQU   30   NEW ADDRESS AREA OF SWITCH MESSAGE                  59100018
NEWO     EQU   39   NEW OUTPUT AREA OF SWITCH MESSAGE                   59400018
VLDCMD   EQU   52   VALID COMMAND AREA OF SWITCH MESSAGE                59700018
TYPE     EQU   63   TYPE AREA OF SWMSG2 MESSAGE                         60000018
HCPY     EQU   71   HARDCOPY AREA OF SUMSG2 MESSAGE                     60300018
LASTEOB  EQU   X'C0'     LAST AND END OF BLOCK INDICATOR                60600018
VLID     EQU   X'03'   ACTIVE ENTRY                                     60900018
NOCPY    EQU   X'FD'     USED TO TURN OFF SYSLOG HARDCPY                61000018
OUTSUPPT EQU   X'80'     INDICATES DEVICE HAS OUTPUT SUPPORT            61100018
*  NO LONGER NEEDED NEVER ON WITHOUT ACTIVE ENTRY ALSO                  61200018
MASTRSW  EQU   X'02'     SWITCH FOR MASTER                              61500018
TESTED   EQU   X'20'     INDICATES TESTED FOR SWITCH                    61800018
ACTIVE   EQU   X'10'     INDICATES ACTIVE IN UCMATR FIELD               62100018
GRAPHICS EQU   X'20'     INDICATES GRAPHICS DEVICE                      62400018
SWMAST   EQU   X'10'     MASTER SWITCH INDICATOR  SYSTEM CONTROL FLAGS  62700018
EMERGCY  EQU   X'04'  UCMMODE ONLY GRAPHICS CONSOLES EXIST IN SYSTEM    63000018
HRDCYWQE EQU   X'10'     INDICATES WQE QUEUED FOR HARDCOPY              63300018
TOBEPROC EQU   X'01'     TO BE PROCESSED INDICATOR IN WQE PTR           63600018
LASTIND  EQU   X'80'     LAST INDICATOR IN WQE PTR                      63900018
NULL     EQU   X'FC'    FOR TURNING OFF VALID                           64000018
VLIDONLY EQU   X'01'   VALID  INDICATOR IN WQE POINTER                  64100018
FIXED    EQU   X'01'    INDICATES FIXED MODE                            64150018
MTESTED  EQU   X'DF'  FOR TURNING OFF TESTED IN UCM ENTRY               64200018
NOTLAST  EQU   X'7F'    FOR TURNING OFF LAST INDICATOR                  64300018
LASTVLID EQU   X'81'   LAST VALID ENTRY IN BLOCK                        64400018
***  INDIVIDUAL UCM  ENTRY MAP  ***                                     64500018
XCMECB   EQU   0    I/O COMPLETION ECB                                  64800018
XCMSRB   EQU   4    POINTER TO RESIDENT PROCESSOR MODULE                65100018
XCMDCB   EQU   8    POINTER TO DCB                                      65400018
XCMUCB   EQU   12   POINTER TO UCB                                      65700018
XCMNAME  EQU   16   PROCESSING MODULE NAME                              66000018
XCMSTS   EQU   24      SATAUS FLAGS                                     66300018
XCMATR   EQU   25   ATTRIBUTE FLAGS                                     66600018
XCMID    EQU   26   UNIQUE IDENTIFIER FOR EACH ENTRY                    66900018
XCMXB    EQU   28   POINTER TO DCM FOR GRAPHICS                         67200018
XCMRTCD  EQU   32   ROUTING CODES                                       67500018
XCMOUTQ  EQU   36   POINTER TO OUTPUT QUEUE                             67800018
XCMAUTH  EQU   40   COMMAND CODE AUTHORIZATION                          68100018
XCMDISP  EQU   42   DISPOSITION FLAGS                                   68400018
XCMALTEN EQU   44   POINTER TO ALTERNATE UCM ENTRY                      68700018
XCMOADEN EQU   48            POINTER TO ALTERNATE OUTPUT ENTRY          69000018
XCMWLAST EQU   52   LAST WQE SERVICED IN OUTPUT QUEUE                   69300018
XCMCOMPC EQU   56    POINTER TO OTHER HALF IF A COMPOSITE CONSOLE       69600018
XCMMSG   EQU   60   MESSAGE TYPE FLAGS                                  69900018
XCMXOR   EQU   62   EXCLUSIVE OR FIELD FOR UCB                          70200018
XCMDEVC  EQU   63   DEVICE CONTROL FLAGS                                70500018
XCMINPUT EQU   64   INPUT AREA - FIXED MODE ONLY                        70800018
***  WQE EQUATES  RQE EQUATES                                           71100018
XWQEXA   EQU   136       DISPOSITION FLAGS OF WQE                       71400018
XWQUCMID EQU   156       UCMID FIELD OF WQE                             71700018
XRQLKP   EQU   0         LINK POINTER OF  RQE                           72000018
XRQWQE   EQU   12       WQE POINTER                                     72300018
MESSAGES DSECT                                                     **** 72600018
SWMSGWQ1 DC    F'0'      POINTER TO NEXT WQE                            72900018
         DC    F'73'     MESSAGE LENGTH PLUS 4                          73200018
SWMSG1   DC       C'IEEXXXY  OLD=             NEW=         '   TEXT     73500018
         DC       C'   VALDCMD=                 '                       73800018
         ORG   SWMSGWQ1+136                                             74100018
         DC    X'00000010'    INDICATES BUFFER OBTAINED DYNAMICALLY     74400018
         DC    F'0'           RESERVED FOR  RO/RS                       74700018
         DC    F'0'           ID SEQUENCE NUMBER                        75000018
         DC    X'0100'        MCS FLAGS                                 75300018
         DC    H'0'           MSGTYPE FLAGS                             75600018
         DC    F'0'           ROUTING CODES                             75900018
SWMSG1ID DC    F'0'           ENTRY ID                                  76200018
         DC    X'0004'        DESCRIPTOR CODE OF 3                      76500018
         DC    H'0'           RESERVED                                  76800018
         DC    F'0'           TIME ELEMENT                              77100018
SWMSGWQ2 DC    F'0'      POINTER TO NEXT WQE                            77400018
         DC    F'75'     MESSAGE LENGTH PLUS 4                          77700018
SWMSG2   DC       C'IEEXXXX  ROUTCDE=                       ' TEXT      78000018
         DC       C'                 TYPE=   HCPY= '                    78300018
         ORG   SWMSGWQ2+136                                             78600018
         DC    X'00000010'    INDICATES BUFFER OBTAINED DYNAMICALLY     78900018
         DC    F'0'           RESERVED FOR RO/RI                        79200018
         DC    F'0'           ID SEQUENCE NUMBER                        79500018
         DC    X'0100'        MCS FLAGS                                 79800018
         DC    H'0'           MSGTYPE FLAGS                             80100018
         DC    F'0'           ROUTING CODES                             80400018
SWMSG2ID DC    F'0'           ENTRY ID                                  80700018
         DC    X'0004'        DESCRIPTOR CODE OF 3                      81000018
         DC    H'0'           RESERVED                                  81300018
         DC    F'0'           TIME ELEMENT                              81600018
UCM      DSECT                                                          81900018
         IEECUCM                                                        82200018
WQEDSECT DSECT                                                          82500018
         IEECVMUG WQE                                                   82800018
RQEDSECT DSECT                                                          83100018
         IEECVMUG  RQE                                                  83400018
CVTDSECT DSECT                                                          83700018
         CVT                                                            84000018
CXSADSEC DSECT                                                          84300018
         IEECVMUG CXSA                                                  84600018
         EJECT                                                          84650021
MAJMIN   DSECT                                                MG  M1418 84700021
         IEECVMUG WQEMAJ                                      MG  M1418 84750021
         ORG   WMJF                                           MG  M1418 84800021
         IEECVMUG WQEMIN                                      MG  M1418 84850021
  END                                                                   84900018
