CTX      TITLE 'EXTERNAL CONTROL ROUTINE-COMMUNICATIONS TASK-CLANCY'    00000417
*STATUS:   CHANGE LEVEL 000                                       MP65* 00001017
*                                                                 MP65* 00001617
*FUNCTION/OPERATION:  SWITCHES THE ACTIVE CONSOLE FROM PRIMARY TO MP65* 00002217
*   ALTERNATE WHEN AN EXTERNAL INTERRUPT IS GENERATED (BY PRESSINGMP65* 00002817
*   THE 'INTERRUPT' INDICATOR ON THE CPU).  THE ATTRIBUTES FIELD  MP65* 00003417
*   IN THE AFFECTED UCM ENTRIES AND THE STATUS FIELD IN THE       MP65* 00004017
*   AFFECTED UCB ENTRIES ARE UPDATED ACCORDINGLY, AND A NEW EIL   MP65* 00004617
*   IS BUILT.                                                     MP65* 00005217
*ENTRY POINTS:                                                    MP65* 00005817
*        IEECVCTX-ENTERED VIA XCTL FROM THE COMMUNICATIONS        MP65* 00006417
*   TASK ROUTER MODULE (IEECVCTR)                                 MP65* 00007017
*INPUT:  NONE                                                     MP65* 00007617
*OUTPUT:  UPDATED UCM, UPDATED UCB, AND NEW EIL                   MP65* 00008217
*EXTERNAL REFERENCES:  CVT, UCB, UCM, EIL, GETMAIN AND FREEMAIN   MP65* 00008817
*EXITS-NORMAL:   XCTL TO PROCESSOR MODULE FOR OPEN/CLOSE          MP65* 00009417
*   BR 14 (RETURN TO SUPERVISOR)                                  MP65* 00010017
*   -ERROR:  N/A                                                  MP65* 00010617
*TABLES/WORK AREAS:  CVT, UCB, UCM, EIL                           MP65* 00011217
*OPERATION:                                                       MP65* 00011817
*   SCAN EACH ENTRY IN UCM LIST OF UNIT CONTROL MODULE MAP (UCM). MP65* 00012417
*   IF 'TEMPORARY' FLAG IS ON, ENTRY HAS ALREADY BEEN CHECKED--   MP65* 00013017
*   SKIP IT.  IF FLAG IS OFF, TURN IT ON, TURN ON 'CLOSE' FLAG.   MP65* 00013617
*   SET UP PARAMETERS FOR PROCESSOR MODULE, AND XCTL TO PROCESSOR MP65* 00014217
*   MODULE TO CLOSE DEVICE IF IT WAS ACTIVE.  WHEN ALL UCM ENTRIESMP65* 00014817
*   HAVE BEEN CHECKED, TURN OFF 'TEMPORARY' FLAG IN EACH ENTRY.   MP65* 00015417
*   IN PASS2, THE UCM LIST IS SCANNED 3 TIMES. IN EACH CASE, THE  MP65* 00016017
*   ENTRY IS NOT CONSIDERED FOR USE AS A CONSOLE IF THE 'EXTERNAL'MP65* 00016617
*   FLAG IS OFF.  IF IT IS ON (IE, THE DEVICE IS SUBJECT TO       MP65* 00017217
*   EXTERNAL INTERRUPT)--                                         MP65* 00017817
*   1.  THE 'ACTIVE/INACTIVE' FLAG IS FLIPPED                     MP65* 00018417
*   2.  IF DEVICE IS INACTIVE (AFTER FLAG HAS BEEN FLIPPED), ITS  MP65* 00019017
*   UCB STATUS IS CHANGED FROM PRIMARY TO ALTERNATE.              MP65* 00019617
*   3.  IF DEVICE IS NOW ACTIVE AND IS SUBJECT TO EXTERNAL        MP65* 00020217
*   INTERRUPT (IE, IT HAD BEEN THE ALTERNATE CONSOLE BEFORE       MP65* 00020817
*   'ACTIVE' FLAG WAS FLIPPED), ITS UCB STATUS IS CHANGED FROM    MP65* 00021417
*   ALTERNATE TO PRIMARY.  THIS IS NOW THE ACTIVE CONSOLE.  A     MP65* 00022017
*   COUNT IS MADE OF ALL ACTIVE ENTRIES (WHETHER OR NOT THEY ARE  MP65* 00022617
*   SUBJECT TO EXTERNAL INTERRUPT) FROM THE NEW EIL COMPANION     MP65* 00023217
*   LIST.                                                         MP65* 00023817
*                                                                 MP65* 00024417
*   AN AREA IS GETMAINED FOR A NEW EIL.  ITS SIZE IS COMPUTED     MP65* 00025017
*   FROM THE COUNT MADE IN PASS2.  THE FIXED ECB POINTERS ARE     MP65* 00025617
*   MOVED FROM THE OLD EIL INTO THE NEW.  AFTER THE NEW EIL HAS   MP65* 00026217
*   BEEN SET UP, THE AREA USED FOR THE OLD EIL IS FREEMAINED.     MP65* 00026817
*                                                                 MP65* 00027417
*   FINALLY, THE EXTERNAL INTERRUPT ECB IS CLEARED AND CTX EXITS. MP65* 00028017
*                                                                 MP65* 00028617
*ATTRIBUTES:  REENTRANT,DISABLED                                  MP65* 00029217
*                                                                 MP65* 00029817
*NOTES: N/A                                                       MP65* 00030417
         EJECT                                                          00032817
IEECVCTX CSECT                                                          00040000
*REASSEMBLED FOR UCM CHANGES IN REL 18                                  00050018
         BALR  8,0                                                      00060000
         USING *,8                                                      00080000
R0      EQU   0                                                         00100000
R1       EQU   1    NEW EIL BASE                                        00120000
R2       EQU   2    EIL BASE                                            00140000
R3       EQU   3    EIL COUNTER                                         00160000
R4       EQU   4    UCM BASE                                            00180000
R5       EQU   5                                                        00200000
R6       EQU   6                                                        00220000
R7       EQU   7    UCB BASE                                            00240000
R8       EQU   8    BASE                                                00260000
R9       EQU   9                                                        00280000
R10      EQU   10   CVT PTR                                             00300000
R11      EQU   11   UCMVEA                                              00320000
R12      EQU   12   UCMVEZ                                              00340000
R13      EQU   13   UCMVEL                                              00360000
R14      EQU   14                                                       00380000
R15      EQU   15                                                       00400000
*                                                                       00420000
RBLINK  EQU   0                                                         00440000
MULTPROC EQU   X'04'                    MULTIPROCESSOR FLAG        MP65 00450017
X80      EQU   X'80'                                              20061 00455020
         USING CVTDSECT,R10                                             00460000
         USING UCM,R4                                                   00480000
         USING UCB,R7                                                   00500000
         USING EIL,R2                                                   00520000
         USING UCMLIST,R11                                              00540000
         USING NEWEIL,R1                                                00560000
         EJECT                                                          00580000
PASS1    SSM   *+1         DISABLE                                      00600000
         L     R10,CVTPTR                                               00620000
         L     R4,CVTCUCB               LOAD UCM PTR                    00640000
         L     R2,UCMLSTP               LOAD PTR TO EVENT INDICAT. LIST 00660000
        USING EILCL,R12                                                 00680000
         L     R12,EILXTNT              LOAD PTR TO COMPANION LIST      00700000
*                                        WHICH CONTAINS A POINTER FOR   00720000
*                                        EACH ACTIVE (OPEN) UCM ENTRY   00740000
* TEST FOR NO ACTIVE CONSOLE                                       2347 00745014
         TM    EILRMS,X80          IS RMS ECB LAST IN LIST        20061 00750020
         BO    PASS2                   IF SO, SEARCH UCM LIST      2347 00755014
         SR    R9,R9                    INITIALIZE EIL INDEX            00760000
CTXLOOP1 L     R11,EILCL(R9)            LOAD PTR TO NEXT UCM ENTRY.     00780000
*                                       FROM COMPANION LIST             00800000
         TM    UCMSTS,UCMTA            IS TEMPORARY FLAG-A ON           00820000
         BO    FLAGON                   YES - EXAMINE NEXT ACTIVE       00840000
*                                        UCM ENTRY                      00860000
         OI    UCMSTS,UCMTA             TURN TA FLAG ON - THIS MEANS    00880000
*                                        THAT THIS ENTRY HAS BEEN EXAM- 00900000
*                                        INED.                          00920000
         TM    UCMATR,UCMXF             IS DEVICE SUBJECT TO EXTERNAL   00940000
*                                       INTERRUPT                       00960000
         BZ    FLAGON                   NO - CHECK FOR LAST CL PTR      00980000
         OI    UCMSTS,UCMCF             TURN CLOSE FLAG ON FOR PROCESOR 01000000
         NI    UCMSTS,255-UCMBUSY TURN OFF BUSY STATUS  BG 42286        01010021
*                                        MODULE                         01020000
         USING SVRBXSA,R15                                              01040000
         L     R15,CVTTCBP              LOAD PTR TO NEW-OLD TCB PTRS    01060000
         L     R15,4(R15)               PTR TO OLD(CUURENT) TCB         01080000
         L     R15,RBLINK(R15)          LOAD PTR TO SVRB                01100000
         LA    R15,96(R15)              PTR TO EXTENDED SAVE AREA       01120000
         DROP  R10                                                      01140000
         LA    R10,8(R15)                                               01160000
         ST    R10,CSANPTR              SET UP XCTL PARAMETERS IN XSA   01180000
         XC    CSADCBP(4),CSADCBP       ZERO DCB PTR IN XSA             01200000
         MVC   CSANAME(8),UCMNAME       PROCESSOR MODULE NAME           01220000
         MVI   CSACODE,CSACLOSE         SET CLOSE FLAG                  01240000
         ST    R4,CSACTLM               STORE UCM PTR (CVTCUCB)         01260000
         ST    R11,CSAUCM               STORE UCM ENTRY PTR             01280000
         LR    R1,R15                   LOAD PTR TO CXSA INTO           01300000
*                                        PROCESSOR'S PARAMETER REGISTER 01320000
         SPACE 2                                                        01340000
         XCTL  SF=(E,(15))             *EXIT TO PROCESSOR MODULE        01360000
         SPACE 2                                                        01380000
FLAGON   LA    R5,EILIOL-EIL(R9,R2)     LOAD ADDR OF I/O COMPLETION ECB 01400000
*                                       CORRESPONDING TO CURRENT COMP-  01420000
*                                       ANION LIST PTR                  01440000
         TM    0(R5),X'80'              TEST FOR LAST I/O ECB PTR.      01460000
         BO    PASS2                    YES - GO TO PASS 2              01480000
         LA    R9,4(R9)                 NO - BUMP INDEX                 01500000
         B     CTXLOOP1                 CHECK NEXT ENTRY                01520000
         SPACE 5                                                        01540000
PASS2    SR    R3,R3                    CLEAR EIL COUNTER               01560000
         LM    R11,R13,UCMVEA           RELOAD BXLE REGISTERS.          01580000
CTXFLIP  NI    UCMSTS,255-UCMTA        TURN OFF TEMPORARY FLAG-A   2347 01590014
         TM    UCMATR,UCMXF            IS EXTERNAL FLAG ON         2347 01600014
         BZ    CTXFNEXT                NO, GET NEXT UCM ENTRY      2347 01610014
         NI    UCMSTS,255-UCMAF NO-TURN OFF ATTN IN ENTRY        A36235 01615020
         XI    UCMATR,UCMUF            FLIP ACTIVE/INACTIVE FLAG   2347 01620014
CTXFNEXT BXLE  R11,R12,CTXFLIP         FALL THRU LAST UCM ENTRY    2347 01630014
         LM    R11,R13,UCMVEA          RE-LOAD BXLE REGISTERS      2347 01640014
CTXALT   TM    UCMATR,UCMXF            IS EXTERNAL FLAG ON         2347 01650014
         BZ    CTXANEXT                NO, GET NEXT UCM ENTRY      2347 01660014
         TM    UCMATR,UCMUF            IS DEVICE NOW ACTIVE        2347 01670014
         BO    CTXANEXT                YES, IGNORE THIS ENTRY      2347 01680014
         L     R7,UCMUCB               GET UCB PTR OF DEVICE       2347 01690014
         OI    SRTESTAT,SRTEDADI       TURN ON ALTERNATE CNSLE BIT 2347 01700014
         NI    SRTESTAT,255-SRTESYSR   TURN OFF PRIMARY BIT        2347 01710014
         TM    UCBTBYT3,X'10'      GRAPHICS DEVICE                 6612 01713017
         BO    CTXANEXT            YES,ATTNTAB REMAINS THE SAME    6612 01716017
         MVI   UCBATI,X'00'            ALTERNATE-ZERO ATTNTAB INDEX2347 01720014
CTXANEXT BXLE  R11,R12,CTXALT          FALL THRU ON LAST UCM ENTRY 2347 01730014
         LM    R11,R13,UCMVEA          RE-LOAD BXLE REGISTERS      2347 01740014
CTXPRIM  L     R10,CVTPTR         LOAD A(CVT)                      MP65 01741017
         USING CVTDSECT,R10                                        MP65 01742017
         TM    CVTDCB,MULTPROC          M65MP?                     MP65 01743017
         BZ    CTXNMP1            NO,PROCEED                       MP65 01744017
*                                 YES--                            MP65 01745017
         TM    UCMATR,UCMXF         IS EXTERNAL FLAG ON            MP65 01746017
         BO    CTXPXON                YES,CHK STATUS,ASSIGN PRIM   MP65 01747017
         TM    UCMATR,UCMUF         NO,IS DEVICE ACTIVE            MP65 01748017
         BO    ADD                    YES,INCR NEW IEL COUNT       MP65 01749017
         B     CTXPNEXT               NO,SKIP THIS ENTRY           MP65 01750017
         SPACE 1                                                   MP65 01751017
CTXNMP1  TM    UCMATR,UCMXF       IS EXTERNAL FLAG ON              MP65 01752017
         BZ    ADD                  NO                             MP65 01753017
CTXPXON  TM    UCMATR,UCMUF       IS DEVICE ACTIVE                 MP65 01754017
         BZ    CTXPNEXT                NO, IGNORE THIS ENTRY       2347 01780014
         L     R7,UCMUCB               GET UCB PTR OF DEVICE       2347 01790014
         OI    SRTESTAT,SRTESYSR       TURN ON PRIMARY CONSOLE BIT 2347 01800014
         NI    SRTESTAT,255-SRTEDADI   TURN OFF ALTERNATE BIT      2347 01810014
         TM    UCMATR,UCMIF            DOES DEVICE SUPPORT ATTN    2347 01820014
         BZ    RESETUCB                NO, SET 0 ATTN TAB INDEX    2347 01830014
         MVI   UCBATI,X'04'            SET ATTNTAB INDEX FOR IOS   2347 01840014
         B     ADD                     ADD 1 TO NEW EIL COUNT      2347 01850014
RESETUCB MVI   UCBATI,X'00'            ATTENTION NOT SUPPORTED -   2347 01860014
*                                           ZERO ATTNTAB INDEX     2347 01870014
ADD      LA    R3,1(R3)                ADD 1 TO NEW EIL COUNT      2347 01880014
CTXPNEXT BXLE  R11,R12,CTXPRIM         FALL THRU ON LAST UCM ENTRY 2347 01890014
         SPACE 3                                                        01980000
         LR    R5,R3                    SAVE COUNT                      02000000
         SLL   R3,3                     RESULT SIZE OF I/O ECB BLOCK    02020000
*                                       COMPANION LIST IN NEW EIL       02040000
         LR    R6,R3                    SAVE THIS SIZE FOR EXECUTING    02060000
*                                       THE BLANKING INSTRUCTION LATER  02080000
         LA    R3,EILIOL-EIL(R3)        ADD SIZE OF CONSTANT AREA -     02100000
*                                       RESULT IS TOTAL SIZE OF NEW EIL 02120000
         TM    UCMMODE,UCMFIX      FIXED MODE?                          02140000
         BZ    GOGET               NO. GETMAIN                          02160000
         LA    R1,UCMOPENX         ELSE USE WORK SPACE                  02180000
         B     NOGET                                                    02200000
GOGET    EQU   *                                                        02220000
         LA    0,0(0,R3)                                                02240000
         O     0,MASK255                SET SUBPOOL 255 FOR GETMAIN     02260000
         GETMAIN R,LV=(0)               GET MAIN FOR NEW EIL            02280000
*                                                                       02300000
NOGET    EQU   *                                                        02320000
         MVC   EILSL2(EILIOL-EILSL),EILSL    MOVE OLD SOURCE LIST TO    02340000
*                                            NEW EIL                    02360000
         SLL   R5,2                     MULTIPLY COUNT BY 4 - SIZE OF   02380000
*                                       I/O ECB PTR BLOCK               02400000
         TM    UCMMODE,UCMFIX          FIXED MODE?                      02420000
         BZ    NEWEXT                  GET NEW COMPANION LIST PTR       02440000
*                                      IF NOT FIXED                     02460000
         LA    R5,EILIOL-EILF(R5,R2)   ELSE FIGURE USING OLD EIL BASE   02480000
         B     OLDEXT                                                   02500000
NEWEXT   EQU   *                                                        02520000
         LA    R5,EILIOL2-EILF2(R5,R1)  ADD SIZE OF HEADER - RESULT IS  02540000
*                                       POINTER TO NEW COMPANION LIST   02560000
OLDEXT   EQU   *                                                        02580000
         ST    R5,EILXTNT2              STORE PTR TO NEW COMPANION LIST 02600000
         STC   R3,EILXTNT2              STORE IN NEW EIL                02640000
         BCTR  R6,0                     DECREMENT R6 FOR EXECUTE        02660000
         EX    R6,CLEAREIL              CLEAR I/O ECB BLOCK AND COMP-   02680000
*                                       ANION LIST                      02700000
         B     PASS3                    GO TO PASS 3                    02720000
CLEAREIL XC    EILIOL2(1),EILIOL2       THIS INSTRUCTION, WHICH CLEARS  02740000
*                                       THE ECB PTR BLOCK AND COMPANION 02760000
*                                       LIST, IS THE SUBJECT INSTRUCT-  02780000
*                                       ION OF AN EXECUTE USING REG. 6  02800000
         SPACE 5                                                        02820000
PASS3    EQU   *    THIS PASS LOOKS FOR ACTIVE UCM ENTRIES THAT ARE     02840000
*                   NOT SUBJECT TO EXTERNAL ACTION AND MOVES THEOR      02860000
*                   I/O ECB PTR AND UCM ENTRY PTR FROM THE OLD EIL      02880000
*                   TO THE NEW EIL. WHEN THE LAST SET OF POINTERS       02900000
*                   HAS BEEN MOVED A X'80' IS STORED IN THE HIGH        02920000
*                   ORDER BYTE IN THE NEW EIL OF THE LAST ECB PTR       02940000
*                   MOVED. THE OLD EIL IS THEN FREED AND THE ROUTINE    02960000
*                   EXITS.                                              02980000
         L     R12,EILXTNT              LOAD PTR TO OLD COMPANION LIST  03000000
         L     R5,EILXTNT2              LOAD PTR TO NEW COMPANION LIST  03020000
         SR    R9,R9                    CLEAR OLD EIL INDEX             03040000
         SR    R6,R6                    CLEAR NEW EIL INDEX             03060000
         USING EILCL2,R5                                                03080000
         SR    R3,R3                    ZERO FOR USE IN ZERO COMPARE    03100000
         L     R11,EILCL                LOAD PTR TO NEXT ENTRY FROM     03120000
*                                        COMPANION LIST.                03140000
         LA    R11,0(R11)                                               03160000
         LTR   R11,R11                  TEST FOR ZERO (NO COMPANION     03180000
*                                       LIST AT ALL)                    03200000
         BZ    STOREND                  NO PTRS - MOVE INDICATOR        03220000
EXTNTEST TM    UCMATR,UCMXF             IS DEVICE SUBJECT TO EXTERNAL   03240000
         BO    ENDTEST                  YES - EXAMINE NEXT UCM ENTRY    03260000
         SPACE 1                                                   MP65 03261017
         L     R10,CVTPTR         LOAD A(CVT)                      MP65 03262017
         USING CVTDSECT,R10                                        MP65 03263017
         TM    CVTDCB,MULTPROC          M65MP?                     MP65 03264017
         BZ    OLDTEST              NO                             MP65 03265017
* FOR M65MP IT CANNOT BE ASSUMED THAT A DEVICE NOT SUBJECT         MP65 03266017
*   TO EXTERNAL IS ALSO ACTIVE,SO FOLLOWING TEST MUST BE MADE      MP65 03267017
*                                                                  MP65 03268017
         TM    UCMATR,UCMUF       NO,IS DEVICE ACTIVE              MP65 03269017
         BZ    ENDTEST            NO,SKIP PROCESSING               MP65 03270017
         SPACE 1                                                   MP65 03271017
*                                                                       03280000
*  IT IS ASSUMED HERE THAT IF THE DEVICE IS NOT SUBJECT TO EXTERNAL     03300000
*  INTERRUPT IT IS ACTIVE, SINCE TO BE OTHERWISE WOULD BE ERRONEOUS9    03320000
*  THE 'NOT EXTERNAL,INACTIVE' CASE WILL BE FLAGGED AT SYSGEN TIME.     03340000
*                                                                       03360000
OLDTEST  EQU   *                                                   MP65 03370017
         C     R3,EILIOL-EIL(R9,R2)     IS I/O ECB PTR IN OLD EIL ZERO  03380000
         BZ    ENDTEST                  YES - MAKE TEST FOR END OF EIL  03400000
         L     R10,EILIOL-EIL(R9,R2)    LOAD I/O ECB PTR AND STORE IN   03420000
         ST    R10,EILIOL2-EILF2(R6,R1)  NEW EIL                        03440000
         LA    R15,0(R6,R1)             INDEX PLUS BASE FOR END         03460000
         L     R10,EILL(R9)             LOAD CORRESPONDING UCM ENTRY    03480000
*                                       PTR FROM OLD EIL                03500000
         ST    R10,EILL2(R6)            STORE IN NEW EIL COMP. LIST     03520000
         LA    R6,4(R6)                 BUMP NEW EIL INDEX              03540000
ENDTEST  LA    R10,EILIOL-EILF(R9,R2)   ABS ADDR OF OLD I/O ECB PTR     03560000
         TM    0(R10),X'80'             LAST ECB PTR                    03580000
         BO    STOREPTR                 YES                             03600000
         LA    R9,4(R9)                 BUMP OLD EIL PTR                03620000
         L     R11,EILL(R9)             LOAD NEXT UCM ENTRY PTR FROM    03640000
*                                       OLD COMPANION LIST              03660000
         B     EXTNTEST                 TEST NEXT UCM ENTRY             03680000
STOREND  MVI   EILRMS2,X'80'       NO I/O ECB PTRS-STOREND        M5297 03700020
*                                       INDICATOR IN WTL ECB PTR        03720000
         B     FREEOLD                                                  03740000
STOREPTR LTR   R6,R6                    WERE ANY I/O ECB PTRS MOVED     03760000
         BZ    STOREND                  NO                              03780000
         MVI   EILIOL2-EILF2(R15),X'80' MOVE 'END OF LIST' INDICATOR    03800000
*                                       TO H.O. BYTE OF LAST I/O COMP-  03820000
*                                       LETION ECB MOVED TO NEW EIL     03840000
FREEOLD  ST    R1,UCMLSTP               STORE PTR TO THE NEW EIL IN     03860000
*                                       THE RESIDENT UCM HEADER         03880000
         TM    UCMMODE,UCMFIX      FIXED MODE?                          03900000
         BZ    DOFREE                                                   03920000
         ST    R2,UCMLSTP          STORE OLD EIL PTR AS NEW             03940000
         SR    R10,R10             MOVE NEW EIL FROM WPRK AREA          03960000
         IC    R10,EILXTNT2                                             03980000
         BCTR  R10,0              DECREMENT EIL SZE FOR MOVE  BE A44414 04000000
         EX    R10,MOVEIL                                               04020000
         B     ENDED                                                    04040000
MOVEIL   MVC   EILF(1),EILF2       SUBJECT OF EXECUTE MOVE              04060000
DOFREE   EQU   *                                                        04080000
         LR    R1,R2                    PTR TO OLD EIL                  04100000
         LA    R1,0(R1)                                                 04120000
         SR    R10,R10                                                  04140000
         IC    R10,EILXTNT              LOAD OLD EXTENT IN DBLE WORDS   04160000
         O     R10,MASK255              SUBPOOL 255                     04200000
         LR    R0,R10                   FREEMAIN LENGTH REG. IS 0       04220000
         FREEMAIN R,LV=(0),A=(1)        FREE OLD EIL                    04240000
ENDED    EQU   *                                                        04260000
*                                                                       04262017
*  BEFORE RETURNING TO THE ROUTER THE WTO/R OUTPUT QUEUE IS TESTED.     04264017
*  IF BUFFERS ARE PRESENT THE WTO/R ECB IS POSTED SO THAT THE ROUTINE   04266017
*  TO PROCESS THE OUTPUT WILL BE ALERTED.(APAR 16405)                   04268017
         L     R9,UCMWTOQ               LOAD QUEUE POINTER         6405 04270017
         LTR   R9,R9                    TEST AND BRANCH IF ZERO    6405 04272017
         BZ    *+8                      IF NON-ZERO,TURN ON ECB    6405 04274017
         MVI   UCMOECB,X'40'            COMPLETE BIT.              6405 04276017
         XC    UCMXECB(4),UCMXECB       CLEAR EXTERNAL ECB              04280000
         BR    R14                     *RETURN                          04300000
         EJECT                                                          04320000
         DS    0F                                                       04340000
MASK255  DC    X'FF000000'                                              04360000
GETPARAM DC    X'80000000'                                              04380000
UCMBUSY  EQU   X'20'                                         BG A42286  04390021
         SPACE 5                                                        04400000
NEWEIL   DSECT                                                          04420000
EILF2    DS    0D        DISPLACEMENTS FOR NEW EVENT INDICATION LIST    04440000
EILXTNT2 DS    FL1           EXTENT                                     04460000
EILCLP2  DC    AL3(EILCL2)   COMPANION LIST PTR                         04480000
EILXA2   DS    F                                                        04500000
EILSL2   DS    0F            SOURCE LIST- FIXED ECB POINTERS            04520000
EILX2    DS    F               EXTERNAL                                 04540000
EILA2    DS    F               ATTENTION                                04560000
EILWTO2  DS    F               WTO(R)                                   04580000
EILWTL2  DS    F               WTL                                      04600000
EILRMS2  DS    F                   RMS                            20061 04610020
EILIOL2  DS    0F            I/O COMPLETION ECB POINTERS                04620000
EILCL2   DS    0F            COMPANION LIST - PTRS TO UCM ENTRIES       04640000
EILL2    EQU   *             END                                        04660000
*                                                                       04680000
         SPACE 5                                                        04700000
EIL      DSECT                                                          04720000
         IEECVMUG EIL                                                   04740000
         SPACE 5                                                        04760000
SVRBXSA  DSECT                                                          04780000
         IEECVMUG CXSA                                                  04800000
         SPACE 5                                                        04820000
UCM      DSECT                                                          04840000
         IEECUCM                                                        04860000
         SPACE 5                                                        04880000
UCB      DSECT                                                          04900000
         IEFUCBOB                                                       04920000
         SPACE 5                                                        04940000
CVTDSECT DSECT                                                          04960000
         CVT                                                            04980000
         END                                                            05000000
